Merge remote-tracking branch 'origin/master' into terencehill/cursormode
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / Main.qc
1 // --------------------------------------------------------------------------
2 // BEGIN REQUIRED CSQC FUNCTIONS
3 //include "main.qh"
4
5 entity clearentity_ent;
6 void clearentity(entity e)
7 {
8         if not(clearentity_ent)
9         {
10                 clearentity_ent = spawn();
11                 clearentity_ent.classname = "clearentity";
12         }
13         float n = e.entnum;
14         copyentity(clearentity_ent, e);
15         e.entnum = n;
16 }
17
18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
19 void menu_show_error()
20 {
21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
22 }
23
24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
25 // Useful for precaching things
26
27 void menu_sub_null()
28 {
29 }
30
31 #ifdef USE_FTE
32 float __engine_check;
33 #endif
34
35 void precache_playermodel(string m)
36 {
37         string f;
38
39         if(substring(m, -9,5) == "_lod1")
40                 return;
41         if(substring(m, -9,5) == "_lod2")
42                 return;
43         precache_model(m);
44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
45         if(fexists(f))
46                 precache_model(f);
47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
48         if(fexists(f))
49                 precache_model(f);
50
51         /*
52         float globhandle, i, n;
53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
54         if (globhandle < 0)
55                 return;
56         n = search_getsize(globhandle);
57         for (i = 0; i < n; ++i)
58         {
59                 //print(search_getfilename(globhandle, i), "\n");
60                 f = search_getfilename(globhandle, i);
61                 PrecachePlayerSounds(f);
62         }
63         search_end(globhandle);
64         */
65 }
66 void precache_all_playermodels(string pattern)
67 {
68         float globhandle, i, n;
69         string f;
70
71         globhandle = search_begin(pattern, TRUE, FALSE);
72         if (globhandle < 0)
73                 return;
74         n = search_getsize(globhandle);
75         for (i = 0; i < n; ++i)
76         {
77                 //print(search_getfilename(globhandle, i), "\n");
78                 f = search_getfilename(globhandle, i);
79                 precache_playermodel(f);
80         }
81         search_end(globhandle);
82 }
83
84 string forcefog;
85 void WaypointSprite_Load();
86 void ConsoleCommand_macro_init();
87 void CSQC_Init(void)
88 {
89         prvm_language = cvar_string("prvm_language");
90 #ifdef USE_FTE
91 #pragma target ID
92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
93         if(!__engine_check)
94         {
95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
96                 localcmd("\ndisconnect\n");
97                 return;
98         }
99 #pragma target FTE
100 #endif
101
102         check_unacceptable_compiler_bugs();
103
104 #ifdef WATERMARK
105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
106 #endif
107
108         float i;
109
110 #ifdef COMPAT_XON050_ENGINE
111         // old engine lacks implementation of player_localnum
112         player_localnum = player_localentnum - 1;
113 #endif
114
115         binddb = db_create();
116         tempdb = db_create();
117         ClientProgsDB = db_load("client.db");
118         compressShortVector_init();
119
120         draw_endBoldFont();
121         menu_visible = FALSE;
122         menu_show = menu_show_error;
123         menu_action = menu_sub_null;
124
125         for(i = 0; i < 255; ++i)
126                 if(getplayerkeyvalue(i, "viewentity") == "")
127                         break;
128         maxclients = i;
129
130         //registercommand("hud_configure");
131         //registercommand("hud_save");
132         //registercommand("menu_action");
133         
134         ConsoleCommand_macro_init();
135
136         registercvar("hud_usecsqc", "1");
137         registercvar("scoreboard_columns", "default");
138
139         gametype = 0;
140
141         // hud_fields uses strunzone on the titles!
142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
143                 hud_title[i] = strzone("(null)");
144
145         postinit = false;
146
147         calledhooks = 0;
148
149         teams = Sort_Spawn();
150         players = Sort_Spawn();
151
152         GetTeam(COLOR_SPECTATOR, true); // add specs first
153
154         // needs to be done so early because of the constants they create
155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
157
158         WaypointSprite_Load();
159
160         // precaches
161         precache_model("null");
162         precache_sound("misc/hit.wav");
163         precache_sound("misc/typehit.wav");
164         if (autocvar_cl_precacheplayermodels)
165         {
166                 precache_all_playermodels("models/player/*.zym");
167                 precache_all_playermodels("models/player/*.dpm");
168                 precache_all_playermodels("models/player/*.md3");
169                 precache_all_playermodels("models/player/*.psk");
170                 precache_all_playermodels("models/player/*.iqm");
171         }
172
173         Projectile_Precache();
174         Hook_Precache();
175         GibSplash_Precache();
176         Casings_Precache();
177         DamageInfo_Precache();
178         Vehicles_Precache();
179         turrets_precache();
180     Announcer_Precache();
181         Tuba_Precache();
182         
183         if(autocvar_cl_reticle)
184         {
185                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
186                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
187         }
188         
189         get_mi_min_max_texcoords(1); // try the CLEVER way first
190         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
191         shortmapname = mi_shortname;
192
193         if(precache_pic(minimapname) == "")
194         {
195                 // but maybe we have a non-clever minimap
196                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
197                 if(precache_pic(minimapname) == "")
198                         minimapname = ""; // FAIL
199                 else
200                         get_mi_min_max_texcoords(0); // load new texcoords
201         }
202
203         mi_center = (mi_min + mi_max) * 0.5;
204         mi_scale = mi_max - mi_min;
205         minimapname = strzone(minimapname);
206
207         WarpZone_Init();
208
209         hud_configure_prev = -1;
210         tab_panel = -1;
211
212         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
213 }
214
215 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
216 void Shutdown(void)
217 {
218 #ifdef USE_FTE
219 #pragma TARGET id
220         if(!__engine_check)
221                 return 0;
222 #pragma TARGET fte
223 #endif
224
225         WarpZone_Shutdown();
226
227         remove(teams);
228         remove(players);
229         db_close(binddb);
230         db_close(tempdb);
231         if(autocvar_cl_db_saveasdump)
232                 db_dump(ClientProgsDB, "client.db");
233         else
234                 db_save(ClientProgsDB, "client.db");
235         db_close(ClientProgsDB);
236
237         if(camera_active)
238                 cvar_set("chase_active",ftos(chase_active_backup));
239
240         // unset the event chasecam's chase_active
241         if(autocvar_chase_active < 0)
242                 cvar_set("chase_active", "0");
243
244         if not(isdemo())
245         {
246                 if not(calledhooks & HOOK_START)
247                         localcmd("\n_cl_hook_gamestart nop\n");
248                 if not(calledhooks & HOOK_END)
249                         localcmd("\ncl_hook_gameend\n");
250         }
251 }
252
253 .float has_team;
254 float SetTeam(entity o, float Team)
255 {
256         entity tm;
257         if(teamplay)
258         {
259                 switch(Team)
260                 {
261                         case -1:
262                         case COLOR_TEAM1:
263                         case COLOR_TEAM2:
264                         case COLOR_TEAM3:
265                         case COLOR_TEAM4:
266                                 break;
267                         default:
268                                 if(GetTeam(Team, false) == world)
269                                 {
270                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
271                                         Team = COLOR_SPECTATOR;
272                                 }
273                                 break;
274                 }
275         }
276         else
277         {
278                 switch(Team)
279                 {
280                         case -1:
281                         case 0:
282                                 break;
283                         default:
284                                 if(GetTeam(Team, false) == world)
285                                 {
286                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
287                                         Team = COLOR_SPECTATOR;
288                                 }
289                                 break;
290                 }
291         }
292         if(Team == -1) // leave
293         {
294                 if(o.has_team)
295                 {
296                         tm = GetTeam(o.team, false);
297                         tm.team_size -= 1;
298                         o.has_team = 0;
299                         return TRUE;
300                 }
301         }
302         else
303         {
304                 if not(o.has_team)
305                 {
306                         o.team = Team;
307                         tm = GetTeam(Team, true);
308                         tm.team_size += 1;
309                         o.has_team = 1;
310                         return TRUE;
311                 }
312                 else if(Team != o.team)
313                 {
314                         tm = GetTeam(o.team, false);
315                         tm.team_size -= 1;
316                         o.team = Team;
317                         tm = GetTeam(Team, true);
318                         tm.team_size += 1;
319                         return TRUE;
320                 }
321         }
322         return FALSE;
323 }
324
325 void Playerchecker_Think()
326 {
327         float i;
328         entity e;
329         for(i = 0; i < maxclients; ++i)
330         {
331                 e = playerslots[i];
332                 if(GetPlayerName(i) == "")
333                 {
334                         if(e.sort_prev)
335                         {
336                                 // player disconnected
337                                 SetTeam(e, -1);
338                                 RemovePlayer(e);
339                                 e.sort_prev = world;
340                                 //e.gotscores = 0;
341                         }
342                 }
343                 else
344                 {
345                         if not(e.sort_prev)
346                         {
347                                 // player connected
348                                 if not(e)
349                                         playerslots[i] = e = spawn();
350                                 e.sv_entnum = i;
351                                 e.ping = 0;
352                                 e.ping_packetloss = 0;
353                                 e.ping_movementloss = 0;
354                                 //e.gotscores = 0; // we might already have the scores...
355                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
356                                 RegisterPlayer(e);
357                                 HUD_UpdatePlayerPos(e);
358                         }
359                 }
360         }
361         self.nextthink = time + 0.2;
362 }
363
364 void Porto_Init();
365 void TrueAim_Init();
366 void PostInit(void)
367 {
368         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
369
370         entity playerchecker;
371         playerchecker = spawn();
372         playerchecker.think = Playerchecker_Think;
373         playerchecker.nextthink = time + 0.2;
374
375         Porto_Init();
376         TrueAim_Init();
377
378         postinit = true;
379 }
380
381 float button_zoom;
382
383 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
384 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
385 // All keys are in ascii.
386 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
387 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
388 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
389 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
390 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
391 {
392         float bSkipKey;
393         bSkipKey = false;
394
395         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
396                 return true;
397
398         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
399                 return true;
400
401         if(menu_visible)
402                 if(menu_action(bInputType, nPrimary, nSecondary))
403                         return TRUE;
404
405         return bSkipKey;
406 }
407
408 // END REQUIRED CSQC FUNCTIONS
409 // --------------------------------------------------------------------------
410
411 // --------------------------------------------------------------------------
412 // BEGIN OPTIONAL CSQC FUNCTIONS
413 void Ent_RemoveEntCS()
414 {
415         entcs_receiver[self.sv_entnum] = world;
416 }
417 void Ent_ReadEntCS()
418 {
419         float sf;
420         InterpolateOrigin_Undo();
421
422         self.classname = "entcs_receiver";
423         sf = ReadByte();
424
425         if(sf & 1)
426                 self.sv_entnum = ReadByte();
427         if(sf & 2)
428         {
429                 self.origin_x = ReadShort();
430                 self.origin_y = ReadShort();
431                 self.origin_z = ReadShort();
432         }
433         if(sf & 4)
434         {
435                 self.angles_y = ReadByte() * 360.0 / 256;
436                 self.angles_x = self.angles_z = 0;
437         }
438         if(sf & 8)
439                 self.healthvalue = ReadByte() * 10;
440         if(sf & 16)
441                 self.armorvalue = ReadByte() * 10;
442
443         entcs_receiver[self.sv_entnum] = self;
444         self.entremove = Ent_RemoveEntCS;
445
446         InterpolateOrigin_Note();
447 }
448
449 void Ent_Remove();
450
451 void Ent_RemovePlayerScore()
452 {
453         float i;
454
455         if(self.owner)
456         {
457                 SetTeam(self.owner, -1);
458                 self.owner.gotscores = 0;
459                 for(i = 0; i < MAX_SCORE; ++i)
460                         self.owner.(scores[i]) = 0; // clear all scores
461         }
462 }
463
464 void Ent_ReadPlayerScore()
465 {
466         float i, n;
467         float isNew;
468         entity o;
469
470         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
471         // (no I've never heard of M-x replace-string, sed, or anything like that)
472         isNew = !self.owner; // workaround for DP bug
473         n = ReadByte()-1;
474
475 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
476         if(!isNew && n != self.sv_entnum)
477         {
478                 //print(_("A CSQC entity changed its owner!\n"));
479                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
480                 isNew = true;
481                 Ent_Remove();
482                 self.enttype = ENT_CLIENT_SCORES;
483         }
484 #endif
485
486         self.sv_entnum = n;
487
488         if not(playerslots[self.sv_entnum])
489                 playerslots[self.sv_entnum] = spawn();
490         o = self.owner = playerslots[self.sv_entnum];
491         o.sv_entnum = self.sv_entnum;
492         o.gotscores = 1;
493
494         //if not(o.sort_prev)
495         //      RegisterPlayer(o);
496         //playerchecker will do this for us later, if it has not already done so
497
498         float sf, lf;
499 #if MAX_SCORE <= 8
500         sf = ReadByte();
501         lf = ReadByte();
502 #else
503         sf = ReadShort();
504         lf = ReadShort();
505 #endif
506         float p;
507         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
508                 if(sf & p)
509                 {
510                         if(lf & p)
511                                 o.(scores[i]) = ReadInt24_t();
512                         else
513                                 o.(scores[i]) = ReadChar();
514                 }
515
516         if(o.sort_prev)
517                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
518
519         self.entremove = Ent_RemovePlayerScore;
520 }
521
522 void Ent_ReadTeamScore()
523 {
524         float i;
525         entity o;
526
527         self.team = ReadByte();
528         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
529
530         float sf, lf;
531 #if MAX_TEAMSCORE <= 8
532         sf = ReadByte();
533         lf = ReadByte();
534 #else
535         sf = ReadShort();
536         lf = ReadShort();
537 #endif
538         float p;
539         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
540                 if(sf & p)
541                 {
542                         if(lf & p)
543                                 o.(teamscores[i]) = ReadInt24_t();
544                         else
545                                 o.(teamscores[i]) = ReadChar();
546                 }
547
548         HUD_UpdateTeamPos(o);
549 }
550
551 void Ent_ClientData()
552 {
553         float f;
554         float newspectatee_status;
555
556         f = ReadByte();
557
558         scoreboard_showscores_force = (f & 1);
559
560         if(f & 2)
561         {
562                 newspectatee_status = ReadByte();
563                 if(newspectatee_status == player_localnum + 1)
564                         newspectatee_status = -1; // observing
565         }
566         else
567                 newspectatee_status = 0;
568
569         spectatorbutton_zoom = (f & 4);
570
571         if(f & 8)
572         {
573                 angles_held_status = 1;
574                 angles_held_x = ReadAngle();
575                 angles_held_y = ReadAngle();
576                 angles_held_z = 0;
577         }
578         else
579                 angles_held_status = 0;
580
581         if(newspectatee_status != spectatee_status)
582         {
583                 // clear race stuff
584                 race_laptime = 0;
585                 race_checkpointtime = 0;
586         }
587         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
588         {
589                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
590                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
591                 )
592                         prev_p_health = -1;
593                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
594                         prev_health = -1;
595         }
596         spectatee_status = newspectatee_status;
597
598         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
599 }
600
601 void Ent_Nagger()
602 {
603         float nags, i, j, b, f;
604
605         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
606
607         if(!(nags & 4))
608         {
609                 if(vote_called_vote)
610                         strunzone(vote_called_vote);
611                 vote_called_vote = string_null;
612                 vote_active = 0;
613         }
614         else
615         {
616                 vote_active = 1;
617         }
618
619         if(nags & 64)
620         {
621                 vote_yescount = ReadByte();
622                 vote_nocount = ReadByte();
623                 vote_needed = ReadByte();
624                 vote_highlighted = ReadChar();
625         }
626
627         if(nags & 128)
628         {
629                 if(vote_called_vote)
630                         strunzone(vote_called_vote);
631                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
632         }
633
634         if(nags & 1)
635         {
636                 for(j = 0; j < maxclients; ++j)
637                         if(playerslots[j])
638                                 playerslots[j].ready = 1;
639                 for(i = 1; i <= maxclients; i += 8)
640                 {
641                         f = ReadByte();
642                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
643                                 if not(f & b)
644                                         if(playerslots[j])
645                                                 playerslots[j].ready = 0;
646                 }
647         }
648
649         ready_waiting = (nags & 1);
650         ready_waiting_for_me = (nags & 2);
651         vote_waiting = (nags & 4);
652         vote_waiting_for_me = (nags & 8);
653         warmup_stage = (nags & 16);
654 }
655
656 void Ent_RandomSeed()
657 {
658         float s;
659         prandom_debug();
660         s = ReadShort();
661         psrandom(s);
662 }
663
664 void Ent_ReadAccuracy(void)
665 {
666         float sf, f, w, b;
667         sf = ReadInt24_t();
668         if(sf == 0)
669         {
670                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
671                         weapon_accuracy[w] = -1;
672                 return;
673         }
674
675         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
676         {
677                 if(sf & f)
678                 {
679                         b = ReadByte();
680                         if(b == 0)
681                                 weapon_accuracy[w] = -1;
682                         else if(b == 255)
683                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
684                         else
685                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
686                 }
687                 if(f == 0x800000)
688                         f = 1;
689                 else
690                         f *= 2;
691         }
692 }
693
694 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
695 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
696 void Ent_RadarLink();
697 void Ent_Init();
698 void Ent_ScoresInfo();
699 void CSQC_Ent_Update(float bIsNewEntity)
700 {
701         float t;
702         float savetime;
703         t = ReadByte();
704
705         if(autocvar_developer_csqcentities)
706                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
707
708         // set up the "time" global for received entities to be correct for interpolation purposes
709         savetime = time;
710         if(servertime)
711         {
712                 time = servertime;
713         }
714         else
715         {
716                 serverprevtime = time;
717                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
718                 time = serverprevtime + serverdeltatime;
719         }
720
721 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
722         if(self.enttype)
723         {
724                 if(t != self.enttype || bIsNewEntity)
725                 {
726                         //print(_("A CSQC entity changed its type!\n"));
727                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
728                         Ent_Remove();
729                         clearentity(self);
730                         bIsNewEntity = 1;
731                 }
732         }
733         else
734         {
735                 if(!bIsNewEntity)
736                 {
737                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
738                         bIsNewEntity = 1;
739                 }
740         }
741 #endif
742         self.enttype = t;
743         switch(t)
744         {
745                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
746                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
747                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
748                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
749                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
750                 case ENT_CLIENT_LASER: Ent_Laser(); break;
751                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
752                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
753                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
754                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
755                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
756                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
757                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
758                 case ENT_CLIENT_INIT: Ent_Init(); break;
759                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
760                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
761                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
762                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
763                 case ENT_CLIENT_WALL: Ent_Wall(); break;
764                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
765                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
766                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
767                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
768                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
769                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
770                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
771                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
772                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
773                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
774                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
775                 case ENT_CLIENT_TURRET: ent_turret(); break; 
776                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
777                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;  
778                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;  
779                 default:
780                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
781                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
782                         break;
783         }
784
785         time = savetime;
786 }
787 // Destructor, but does NOT deallocate the entity by calling remove(). Also
788 // used when an entity changes its type. For an entity that someone interacts
789 // with others, make sure it can no longer do so.
790 void Ent_Remove()
791 {
792         if(self.entremove)
793                 self.entremove();
794
795         self.enttype = 0;
796         self.classname = "";
797         self.draw = menu_sub_null;
798         self.entremove = menu_sub_null;
799         // TODO possibly set more stuff to defaults
800 }
801 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
802 void CSQC_Ent_Remove()
803 {
804         if(autocvar_developer_csqcentities)
805                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
806
807         if(wasfreed(self))
808         {
809                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
810                 return;
811         }
812         if(self.enttype)
813                 Ent_Remove();
814         remove(self);
815 }
816
817 void Gamemode_Init()
818 {
819         if not(isdemo())
820         {
821                 if(!(calledhooks & HOOK_START))
822                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
823                 calledhooks |= HOOK_START;
824         }
825 }
826 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
827 void CSQC_Parse_StuffCmd(string strMessage)
828 {
829         if(autocvar_developer_csqcentities)
830                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
831
832         localcmd(strMessage);
833 }
834 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
835 void CSQC_Parse_Print(string strMessage)
836 {
837         if(autocvar_developer_csqcentities)
838                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
839
840         print(ColorTranslateRGB(strMessage));
841 }
842
843 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
844 void CSQC_Parse_CenterPrint(string strMessage)
845 {
846         if(autocvar_developer_csqcentities)
847                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
848
849         centerprint_hud(strMessage);
850 }
851
852 string notranslate_fogcmd1 = "\nfog ";
853 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
854 void Fog_Force()
855 {
856         // TODO somehow thwart prvm_globalset client ...
857
858         if(forcefog != "")
859                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
860 }
861
862 void Gamemode_Init();
863 void Ent_ScoresInfo()
864 {
865         float i;
866         self.classname = "ent_client_scores_info";
867         gametype = ReadInt24_t();
868         for(i = 0; i < MAX_SCORE; ++i)
869         {
870                 scores_label[i] = strzone(ReadString());
871                 scores_flags[i] = ReadByte();
872         }
873         for(i = 0; i < MAX_TEAMSCORE; ++i)
874         {
875                 teamscores_label[i] = strzone(ReadString());
876                 teamscores_flags[i] = ReadByte();
877         }
878         HUD_InitScores();
879         Gamemode_Init();
880 }
881
882 void Ent_Init()
883 {
884         self.classname = "ent_client_init";
885
886         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
887
888         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
889         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
890         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
891         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
892         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
893         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
894         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
895         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
896         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
897         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
898         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
899         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
900
901         if(forcefog)
902                 strunzone(forcefog);
903         forcefog = strzone(ReadString());
904
905         armorblockpercent = ReadByte() / 255.0;
906
907         g_weaponswitchdelay = ReadByte() / 255.0;
908
909         g_balance_grenadelauncher_bouncefactor = ReadCoord();
910         g_balance_grenadelauncher_bouncestop = ReadCoord();
911         g_balance_electro_secondary_bouncefactor = ReadCoord();
912         g_balance_electro_secondary_bouncestop = ReadCoord();
913
914         nex_scope = !ReadByte();
915         rifle_scope = !ReadByte();
916
917         serverflags = ReadByte();
918
919         minelayer_maxmines = ReadByte();
920
921         hagar_maxrockets = ReadByte();
922
923         g_trueaim_minrange = ReadCoord();
924         g_balance_porto_secondary = ReadByte();
925
926         if(!postinit)
927                 PostInit();
928 }
929
930 void Net_ReadRace()
931 {
932         float b;
933
934         b = ReadByte();
935
936         switch(b)
937         {
938                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
939                         race_checkpoint = ReadByte();
940                         race_time = ReadInt24_t();
941                         race_previousbesttime = ReadInt24_t();
942                         if(race_previousbestname)
943                                 strunzone(race_previousbestname);
944                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
945
946                         race_checkpointtime = time;
947
948                         if(race_checkpoint == 0 || race_checkpoint == 254)
949                         {
950                                 race_penaltyaccumulator = 0;
951                                 race_laptime = time; // valid
952                         }
953
954                         break;
955
956                 case RACE_NET_CHECKPOINT_CLEAR:
957                         race_laptime = 0;
958                         race_checkpointtime = 0;
959                         break;
960
961                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
962                         race_laptime = ReadCoord();
963                         race_checkpointtime = -99999;
964                         // fall through
965                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
966                         race_nextcheckpoint = ReadByte();
967
968                         race_nextbesttime = ReadInt24_t();
969                         if(race_nextbestname)
970                                 strunzone(race_nextbestname);
971                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
972                         break;
973
974                 case RACE_NET_CHECKPOINT_HIT_RACE:
975                         race_mycheckpoint = ReadByte();
976                         race_mycheckpointtime = time;
977                         race_mycheckpointdelta = ReadInt24_t();
978                         race_mycheckpointlapsdelta = ReadByte();
979                         if(race_mycheckpointlapsdelta >= 128)
980                                 race_mycheckpointlapsdelta -= 256;
981                         if(race_mycheckpointenemy)
982                                 strunzone(race_mycheckpointenemy);
983                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
984                         break;
985
986                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
987                         race_othercheckpoint = ReadByte();
988                         race_othercheckpointtime = time;
989                         race_othercheckpointdelta = ReadInt24_t();
990                         race_othercheckpointlapsdelta = ReadByte();
991                         if(race_othercheckpointlapsdelta >= 128)
992                                 race_othercheckpointlapsdelta -= 256;
993                         if(race_othercheckpointenemy)
994                                 strunzone(race_othercheckpointenemy);
995                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
996                         break;
997
998                 case RACE_NET_PENALTY_RACE:
999                         race_penaltyeventtime = time;
1000                         race_penaltytime = ReadShort();
1001                         //race_penaltyaccumulator += race_penaltytime;
1002                         if(race_penaltyreason)
1003                                 strunzone(race_penaltyreason);
1004                         race_penaltyreason = strzone(ReadString());
1005                         break;
1006
1007                 case RACE_NET_PENALTY_QUALIFYING:
1008                         race_penaltyeventtime = time;
1009                         race_penaltytime = ReadShort();
1010                         race_penaltyaccumulator += race_penaltytime;
1011                         if(race_penaltyreason)
1012                                 strunzone(race_penaltyreason);
1013                         race_penaltyreason = strzone(ReadString());
1014                         break;
1015
1016                 case RACE_NET_SERVER_RECORD:
1017                         race_server_record = ReadInt24_t();
1018                         break;
1019                 case RACE_NET_SPEED_AWARD:
1020                         race_speedaward = ReadInt24_t();
1021                         if(race_speedaward_holder)
1022                                 strunzone(race_speedaward_holder);
1023                         race_speedaward_holder = strzone(ReadString());
1024                         break;
1025                 case RACE_NET_SPEED_AWARD_BEST:
1026                         race_speedaward_alltimebest = ReadInt24_t();
1027                         if(race_speedaward_alltimebest_holder)
1028                                 strunzone(race_speedaward_alltimebest_holder);
1029                         race_speedaward_alltimebest_holder = strzone(ReadString());
1030                         break;
1031                 case RACE_NET_SERVER_RANKINGS:
1032                         float pos, prevpos, del;
1033                         pos = ReadShort();
1034                         prevpos = ReadShort();
1035                         del = ReadShort();
1036
1037                         // move other rankings out of the way
1038                         float i;
1039                         if (prevpos) {
1040                                 for (i=prevpos-1;i>pos-1;--i) {
1041                                         grecordtime[i] = grecordtime[i-1];
1042                                         if(grecordholder[i])
1043                                                 strunzone(grecordholder[i]);
1044                                         grecordholder[i] = strzone(grecordholder[i-1]);
1045                                 }
1046                         } else if (del) { // a record has been deleted by the admin
1047                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1048                                         if (i == RANKINGS_CNT-1) { // clear out last record
1049                                                 grecordtime[i] = 0;
1050                                                 if (grecordholder[i])
1051                                                         strunzone(grecordholder[i]);
1052                                                 grecordholder[i] = string_null;
1053                                         }
1054                                         else {
1055                                                 grecordtime[i] = grecordtime[i+1];
1056                                                 if (grecordholder[i])
1057                                                         strunzone(grecordholder[i]);
1058                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1059                                         }
1060                                 }
1061                         } else { // player has no ranked record yet
1062                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1063                                         grecordtime[i] = grecordtime[i-1];
1064                                         if(grecordholder[i])
1065                                                 strunzone(grecordholder[i]);
1066                                         grecordholder[i] = strzone(grecordholder[i-1]);
1067                                 }
1068                         }
1069
1070                         // store new ranking
1071                         if(grecordholder[pos-1] != "")
1072                                 strunzone(grecordholder[pos-1]);
1073                         grecordholder[pos-1] = strzone(ReadString());
1074                         grecordtime[pos-1] = ReadInt24_t();
1075                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1076                                 race_myrank = pos;
1077                         break;
1078                 case RACE_NET_SERVER_STATUS:
1079                         race_status = ReadShort();
1080                         if(race_status_name)
1081                                 strunzone(race_status_name);
1082                         race_status_name = strzone(ReadString());
1083         }
1084 }
1085
1086 void Net_ReadSpawn()
1087 {
1088         zoomin_effect = 1;
1089         current_viewzoom = 0.6;
1090 }
1091
1092 void Net_TeamNagger()
1093 {
1094         teamnagger = 1;
1095 }
1096
1097 void Net_ReadPingPLReport()
1098 {
1099         float e, pi, pl, ml;
1100         e = ReadByte();
1101         pi = ReadShort();
1102         pl = ReadByte();
1103         ml = ReadByte();
1104         if not(playerslots[e])
1105                 return;
1106         playerslots[e].ping = pi;
1107         playerslots[e].ping_packetloss = pl / 255.0;
1108         playerslots[e].ping_movementloss = ml / 255.0;
1109 }
1110
1111 void Net_WeaponComplain() {
1112         complain_weapon = ReadByte();
1113
1114         if(complain_weapon_name)
1115                 strunzone(complain_weapon_name);
1116         complain_weapon_name = strzone(ReadString());
1117
1118         complain_weapon_type = ReadByte();
1119
1120         complain_weapon_time = time;
1121         weapontime = time; // ping the weapon panel
1122 }
1123
1124 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1125 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1126 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1127 float CSQC_Parse_TempEntity()
1128 {
1129         float bHandled;
1130                 bHandled  = true;
1131         // Acquire TE ID
1132         float nTEID;
1133                 nTEID = ReadByte();
1134
1135         if(autocvar_developer_csqcentities)
1136                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1137
1138                 // NOTE: Could just do return instead of break...
1139         switch(nTEID)
1140         {
1141                 case TE_CSQC_TARGET_MUSIC:
1142                         Net_TargetMusic();
1143                         bHandled = true;
1144                         break;
1145                 case TE_CSQC_PICTURE:
1146                         Net_MapVote_Picture();
1147                         bHandled = true;
1148                         break;
1149                 case TE_CSQC_RACE:
1150                         Net_ReadRace();
1151                         bHandled = true;
1152                         break;
1153                 case TE_CSQC_SPAWN:
1154                         Net_ReadSpawn();
1155                         bHandled = true;
1156                         break;
1157                 case TE_CSQC_ZCURVEPARTICLES:
1158                         Net_ReadZCurveParticles();
1159                         bHandled = true;
1160                         break;
1161                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1162                         Net_ReadNexgunBeamParticle();
1163                         bHandled = true;
1164                         break;
1165                 case TE_CSQC_TEAMNAGGER:
1166                         Net_TeamNagger();
1167                         bHandled = true;
1168                         break;
1169                 case TE_CSQC_LIGHTNINGARC:
1170                         Net_ReadLightningarc();
1171                         bHandled = true;
1172                         break;
1173                 case TE_CSQC_PINGPLREPORT:
1174                         Net_ReadPingPLReport();
1175                         bHandled = true;
1176                         break;
1177                 case TE_CSQC_ANNOUNCE:
1178                         Announcer_Play(ReadString());
1179                         bHandled = true;
1180                         break;
1181                 case TE_CSQC_KILLNOTIFY:
1182                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1183                         bHandled = true;
1184                         break;
1185                 case TE_CSQC_KILLCENTERPRINT:
1186                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1187                         bHandled = true;
1188                         break;
1189                 case TE_CSQC_CENTERPRINT_GENERIC:
1190                         float id;
1191                         string s;
1192                         id = ReadByte();
1193                         s = ReadString();
1194                         if (id != 0 && s != "")
1195                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1196                         else
1197                                 centerprint_generic(id, s, 0, 0);
1198                         bHandled = true;
1199                         break;
1200                 case TE_CSQC_WEAPONCOMPLAIN:
1201                         Net_WeaponComplain();
1202                         bHandled = true;
1203                         break;
1204                 case TE_CSQC_VEHICLESETUP:
1205                         Net_VehicleSetup();
1206                         bHandled = true;
1207                         break;
1208                 case TE_CSQC_SVNOTICE:
1209                         cl_notice_read();
1210                         bHandled = true;
1211                         break;
1212                 default:
1213                         // No special logic for this temporary entity; return 0 so the engine can handle it
1214                         bHandled = false;
1215                         break;
1216         }
1217
1218         return bHandled;
1219 }
1220
1221 string getcommandkey(string text, string command)
1222 {
1223         string keys;
1224         float n, j, k, l;
1225
1226         if (!autocvar_hud_showbinds)
1227                 return text;
1228
1229         keys = db_get(binddb, command);
1230         if (!keys)
1231         {
1232                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1233                 for(j = 0; j < n; ++j)
1234                 {
1235                         k = stof(argv(j));
1236                         if(k != -1)
1237                         {
1238                                 if ("" == keys)
1239                                         keys = keynumtostring(k);
1240                                 else
1241                                         keys = strcat(keys, ", ", keynumtostring(k));
1242
1243                                 ++l;
1244                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1245                         }
1246
1247                 }
1248                 db_put(binddb, command, keys);
1249         }
1250
1251         if ("" == keys) {
1252                 if (autocvar_hud_showbinds > 1)
1253                         return sprintf(_("%s (not bound)"), text);
1254                 else
1255                         return text;
1256         }
1257         else if (autocvar_hud_showbinds > 1)
1258                 return sprintf(_("%s (%s)"), text, keys);
1259         else
1260                 return keys;
1261 }