sv_db_saveasdump and cl_db_saveasdump cvars
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / Main.qc
1 // --------------------------------------------------------------------------
2 // BEGIN REQUIRED CSQC FUNCTIONS
3 //include "main.qh"
4
5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
6
7 void cvar_clientsettemp(string cv, string val)
8 {
9         entity e;
10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
11                 if(e.netname == cv)
12                         goto saved;
13         e = spawn();
14         e.classname = "saved_cvar_value";
15         e.netname = strzone(cv);
16         e.message = strzone(cvar_string(cv));
17 :saved
18         cvar_set(cv, val);
19 }
20
21 void cvar_clientsettemp_restore()
22 {
23         entity e;
24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
25                         cvar_set(e.netname, e.message);
26 }
27
28 void() menu_show_error =
29 {
30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
31 };
32
33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
34 // Useful for precaching things
35
36 void() menu_sub_null =
37 {
38 };
39
40 #ifdef USE_FTE
41 float __engine_check;
42 #endif
43
44 string forcefog;
45 string cl_announcer_prev;
46 void WaypointSprite_Load();
47 void CSQC_Init(void)
48 {
49 #ifdef USE_FTE
50 #pragma target ID
51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
52         if(!__engine_check)
53         {
54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
55                 localcmd("\ndisconnect\n");
56                 return;
57         }
58 #pragma target FTE
59 #endif
60         
61         check_unacceptable_compiler_bugs();
62
63 #ifdef WATERMARK
64         print("^4CSQC Build information: ", WATERMARK(), "\n");
65 #endif
66
67         float i;
68         CSQC_CheckEngine();
69
70         binddb = db_create();
71         tempdb = db_create();
72         ClientProgsDB = db_load("client.db");
73         compressShortVector_init();
74
75         drawfont = 0;
76         menu_visible = FALSE;
77         menu_show = menu_show_error;
78         menu_action = menu_sub_null;
79
80         for(i = 0; i < 255; ++i)
81                 if(getplayerkey(i, "viewentity") == "")
82                         break;
83         maxclients = i;
84
85         //ctf_temp_1 = "";
86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
87         //registercmd("ctf_menu");
88         registercmd("ons_map");
89         registercmd("hud_configure");
90         registercmd("hud_save");
91         //registercmd("menu_action");
92
93         registercmd("+button3");
94         registercmd("-button3");
95         registercmd("+button4");
96         registercmd("-button4");
97         registercmd("+showscores");registercmd("-showscores");
98         registercmd("+showaccuracy");registercmd("-showaccuracy");
99
100 #ifndef CAMERATEST
101         if(isdemo())
102         {
103 #endif
104                 registercmd("+forward");registercmd("-forward");
105                 registercmd("+back");registercmd("-back");
106                 registercmd("+moveup");registercmd("-moveup");
107                 registercmd("+movedown");registercmd("-movedown");
108                 registercmd("+moveright");registercmd("-moveright");
109                 registercmd("+moveleft");registercmd("-moveleft");
110                 registercmd("+roll_right");registercmd("-roll_right");
111                 registercmd("+roll_left");registercmd("-roll_left");
112 #ifndef CAMERATEST
113         }
114 #endif
115         registercvar("hud_usecsqc", "1");
116         registercvar("scoreboard_columns", "default", CVAR_SAVE);
117
118         gametype = 0;
119
120         // hud_fields uses strunzone on the titles!
121         for(i = 0; i < MAX_HUD_FIELDS; ++i)
122                 hud_title[i] = strzone("(null)");
123
124         postinit = false;
125
126         calledhooks = 0;
127
128         teams = Sort_Spawn();
129         players = Sort_Spawn();
130
131         GetTeam(COLOR_SPECTATOR, true); // add specs first
132
133         RegisterWeapons();
134
135         WaypointSprite_Load();
136
137         // precaches
138         Projectile_Precache();
139         Hook_Precache();
140         GibSplash_Precache();
141         Casings_Precache();
142         DamageInfo_Precache();
143         if(cvar_string("cl_announcer") != cl_announcer_prev) {
144                 Announcer_Precache();
145                 if(cl_announcer_prev)
146                         strunzone(cl_announcer_prev);
147                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
148         }
149         Tuba_Precache();
150
151         get_mi_min_max_texcoords(1); // try the CLEVER way first
152         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
153         shortmapname = mi_shortname;
154
155         if(precache_pic(minimapname) == "")
156         {
157                 // but maybe we have a non-clever minimap
158                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
159                 if(precache_pic(minimapname) == "")
160                         minimapname = ""; // FAIL
161                 else
162                         get_mi_min_max_texcoords(0); // load new texcoords
163         }
164
165         mi_center = (mi_min + mi_max) * 0.5;
166         mi_scale = mi_max - mi_min;
167         minimapname = strzone(minimapname);
168
169         WarpZone_Init();
170         hud_configure_prev = -1;
171 }
172
173 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
174 void CSQC_Shutdown(void)
175 {
176 #ifdef USE_FTE
177 #pragma TARGET id
178         if(!__engine_check)
179                 return 0;
180 #pragma TARGET fte
181 #endif
182
183         WarpZone_Shutdown();
184
185         remove(teams);
186         remove(players);
187         db_close(binddb);
188         db_close(tempdb);
189         if(cvar("cl_db_saveasdump"))
190                 db_dump(ClientProgsDB, "client.db");
191         else
192                 db_save(ClientProgsDB, "client.db");
193         db_close(ClientProgsDB);
194
195         cvar_clientsettemp_restore();
196
197         if(camera_active)
198                 cvar_set("chase_active",ftos(chase_active_backup));
199
200         if not(isdemo())
201         {
202                 if not(calledhooks & HOOK_START)
203                         localcmd("\n_cl_hook_gamestart nop\n");
204                 if not(calledhooks & HOOK_END)
205                         localcmd("\ncl_hook_gameend\n");
206         }
207 }
208
209 .float has_team;
210 float SetTeam(entity o, float Team)
211 {
212         entity tm;
213         if(teamplay)
214         {
215                 switch(Team)
216                 {
217                         case -1:
218                         case COLOR_TEAM1:
219                         case COLOR_TEAM2:
220                         case COLOR_TEAM3:
221                         case COLOR_TEAM4:
222                                 break;
223                         default:
224                                 if(GetTeam(Team, false) == NULL)
225                                 {
226                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
227                                         Team = COLOR_SPECTATOR;
228                                 }
229                                 break;
230                 }
231         }
232         else
233         {
234                 switch(Team)
235                 {
236                         case -1:
237                         case 0:
238                                 break;
239                         default:
240                                 if(GetTeam(Team, false) == NULL)
241                                 {
242                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
243                                         Team = COLOR_SPECTATOR;
244                                 }
245                                 break;
246                 }
247         }
248         if(Team == -1) // leave
249         {
250                 if(o.has_team)
251                 {
252                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
253                         tm = GetTeam(o.team, false);
254                         tm.team_size -= 1;
255                         o.has_team = 0;
256                         return TRUE;
257                 }
258         }
259         else
260         {
261                 if not(o.has_team)
262                 {
263                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
264                         o.team = Team;
265                         tm = GetTeam(Team, true);
266                         tm.team_size += 1;
267                         o.has_team = 1;
268                         return TRUE;
269                 }
270                 else if(Team != o.team)
271                 {
272                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
273                         tm = GetTeam(o.team, false);
274                         tm.team_size -= 1;
275                         o.team = Team;
276                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
277                         tm = GetTeam(Team, true);
278                         tm.team_size += 1;
279                         return TRUE;
280                 }
281         }
282         return FALSE;
283 }
284
285 void Playerchecker_Think()
286 {
287         float i;
288         entity e;
289         for(i = 0; i < maxclients; ++i)
290         {
291                 e = playerslots[i];
292                 if(GetPlayerName(i) == "")
293                 {
294                         if(e.sort_prev)
295                         {
296                                 //print("playerchecker: KILL KILL KILL\n");
297                                 // player disconnected
298                                 SetTeam(e, -1);
299                                 RemovePlayer(e);
300                                 e.sort_prev = world;
301                                 //e.gotscores = 0;
302                         }
303                 }
304                 else
305                 {
306                         if not(e.sort_prev)
307                         {
308                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
309                                 // player connected
310                                 if not(e)
311                                         playerslots[i] = e = spawn();
312                                 e.sv_entnum = i;
313                                 e.ping = 0;
314                                 e.ping_packetloss = 0;
315                                 e.ping_movementloss = 0;
316                                 //e.gotscores = 0; // we might already have the scores...
317                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
318                                 RegisterPlayer(e);
319                                 HUD_UpdatePlayerPos(e);
320                         }
321                 }
322         }
323         self.nextthink = time + 0.2;
324 }
325
326 void Porto_Init();
327 void TrueAim_Init();
328 void PostInit(void)
329 {
330         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
331         localcmd(strcat("\nscoreboard_columns_set ", cvar_string("scoreboard_columns"), ";\n"));
332
333         entity playerchecker;
334         playerchecker = spawn();
335         playerchecker.think = Playerchecker_Think;
336         playerchecker.nextthink = time + 0.2;
337
338         Porto_Init();
339         TrueAim_Init();
340
341         postinit = true;
342 }
343
344 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
345 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
346 float button_zoom;
347 void Cmd_HUD_SetFields(float);
348 void Cmd_HUD_Help(float);
349 float CSQC_ConsoleCommand(string strMessage)
350 {
351         float argc;
352         // Tokenize String
353         //argc = tokenize(strMessage);
354         argc = tokenize_console(strMessage);
355
356         // Acquire Command
357         local string strCmd;
358         strCmd = argv(0);
359
360         if(strCmd == "hud_configure") { // config hud
361                 cvar_set("_hud_configure", ftos(!cvar("_hud_configure")));
362                 return true;
363         } else if(strCmd == "hud_save") { // save hud config
364                 if(argv(1) == "" || argv(2)) {
365                         print("Usage:\n");
366                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
367                 }
368                 else
369                         HUD_Panel_ExportCfg(argv(1));
370                 return true;
371         } else if(strCmd == "+button4") { // zoom
372                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
373                 if(ignore_plus_zoom)
374                 {
375                         --ignore_plus_zoom;
376                         return false;
377                 }
378                 button_zoom = 1;
379                 return true;
380         } else if(strCmd == "-button4") { // zoom
381                 if(ignore_minus_zoom)
382                 {
383                         --ignore_minus_zoom;
384                         return false;
385                 }
386                 button_zoom = 0;
387                 return true;
388         } else if(strCmd == "+button3") { // secondary
389                 button_attack2 = 1;
390                 return false;
391         } else if(strCmd == "-button3") { // secondary
392                 button_attack2 = 0;
393                 return false;
394         } else if(strCmd == "+showscores") {
395                 scoreboard_showscores = true;
396                 return true;
397         } else if(strCmd == "-showscores") {
398                 scoreboard_showscores = false;
399                 return true;
400         } else if(strCmd == "+showaccuracy") {
401                 scoreboard_showaccuracy = true;
402                 return true;
403         } else if(strCmd == "-showaccuracy") {
404                 scoreboard_showaccuracy = false;
405                 return true;
406         }
407
408         if(camera_active)
409         if(strCmd == "+forward" || strCmd == "-back") {
410                 ++camera_direction_x;
411                 return true;
412         } else if(strCmd == "-forward" || strCmd == "+back") {
413                 --camera_direction_x;
414                 return true;
415         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
416                 --camera_direction_y;
417                 return true;
418         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
419                 ++camera_direction_y;
420                 return true;
421         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
422                 ++camera_direction_z;
423                 return true;
424         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
425                 --camera_direction_z;
426                 return true;
427         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
428                 ++camera_roll;
429                 return true;
430         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
431                 --camera_roll;
432                 return true;
433         }
434
435         return false;
436 }
437
438 .vector view_ofs;
439 entity debug_shotorg;
440 void ShotOrg_Draw()
441 {
442         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
443         self.angles = view_angles;
444         self.angles_x = -self.angles_x;
445         if not(self.cnt)
446                 self.drawmask = MASK_NORMAL;
447         else
448                 self.drawmask = 0;
449 }
450 void ShotOrg_Draw2D()
451 {
452         vector coord2d_topleft, coord2d_topright, coord2d;
453         string s;
454         vector fs;
455
456         s = vtos(self.view_ofs);
457         s = substring(s, 1, strlen(s) - 2);
458         if(tokenize_console(s) == 3)
459                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
460
461         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
462         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
463
464         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
465
466         coord2d = coord2d_topleft;
467         if(fs_x < 8)
468         {
469                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
470                 fs = '8 8 0';
471         }
472         coord2d_y -= fs_y;
473         coord2d_z = 0;
474         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
475 }
476
477 void ShotOrg_Spawn()
478 {
479         debug_shotorg = spawn();
480         debug_shotorg.draw = ShotOrg_Draw;
481         debug_shotorg.draw2d = ShotOrg_Draw2D;
482         debug_shotorg.renderflags = RF_VIEWMODEL;
483         debug_shotorg.effects = EF_FULLBRIGHT;
484         precache_model("models/shotorg_adjuster.md3");
485         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
486         debug_shotorg.scale = 2;
487         debug_shotorg.view_ofs = '25 8 -8';
488 }
489
490 void DrawDebugModel()
491 {
492         if(time - floor(time) > 0.5)
493         {
494                 PolyDrawModel(self);
495                 self.drawmask = 0;
496         }
497         else
498         {
499                 self.renderflags = 0;
500                 self.drawmask = MASK_NORMAL;
501         }
502 }
503
504 void GameCommand(string msg)
505 {
506         string s;
507         float argc;
508         entity e;
509         argc = tokenize_console(msg);
510
511         if(argv(0) == "help" || argc == 0)
512         {
513                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
514                 print("  settemp cvar value\n");
515                 print("  scoreboard_columns_set ...\n");
516                 print("  scoreboard_columns_help\n");
517                 GameCommand_Generic("help");
518                 return;
519         }
520
521         if(GameCommand_Generic(msg))
522                 return;
523
524         string cmd;
525         cmd = argv(0);
526         if(cmd == "mv_download") {
527                 Cmd_MapVote_MapDownload(argc);
528         }
529         else if(cmd == "settemp") {
530                 cvar_clientsettemp(argv(1), argv(2));
531         }
532         else if(cmd == "scoreboard_columns_set") {
533                 Cmd_HUD_SetFields(argc);
534         }
535         else if(cmd == "scoreboard_columns_help") {
536                 Cmd_HUD_Help(argc);
537         }
538 #ifdef BLURTEST
539         else if(cmd == "blurtest") {
540                 blurtest_time0 = time;
541                 blurtest_time1 = time + stof(argv(1));
542                 blurtest_radius = stof(argv(2));
543                 blurtest_power = stof(argv(3));
544         }
545 #endif
546         else if(cmd == "shotorg_move") {
547                 if(!debug_shotorg)
548                         ShotOrg_Spawn();
549                 else
550                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
551                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
552         }
553         else if(cmd == "shotorg_movez") {
554                 if(!debug_shotorg)
555                         ShotOrg_Spawn();
556                 else
557                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
558                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
559         }
560         else if(cmd == "shotorg_set") {
561                 if(!debug_shotorg)
562                         ShotOrg_Spawn();
563                 else
564                         debug_shotorg.view_ofs = stov(argv(1));
565                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
566         }
567         else if(cmd == "shotorg_setz") {
568                 if(!debug_shotorg)
569                         ShotOrg_Spawn();
570                 else
571                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
572                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
573         }
574         else if(cmd == "shotorg_toggle_hide") {
575                 if(debug_shotorg)
576                 {
577                         debug_shotorg.cnt = !debug_shotorg.cnt;
578                 }
579         }
580         else if(cmd == "shotorg_end") {
581                 if(debug_shotorg)
582                 {
583                         print(vtos(debug_shotorg.view_ofs), "\n");
584                         remove(debug_shotorg);
585                         debug_shotorg = world;
586                 }
587                 localcmd("sv_cmd debug_shotorg\n");
588         }
589         else if(cmd == "sendcvar") {
590                 // W_FixWeaponOrder will trash argv, so save what we need.
591                 string thiscvar;
592                 thiscvar = strzone(argv(1));
593                 s = cvar_string(thiscvar);
594                 if(thiscvar == "cl_weaponpriority")
595                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
596                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
597                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
598                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
599                 strunzone(thiscvar);
600         }
601         else if(cmd == "spawn") {
602                 s = argv(1);
603                 e = spawn();
604                 precache_model(s);
605                 setmodel(e, s);
606                 setorigin(e, view_origin);
607                 e.angles = view_angles;
608                 e.draw = DrawDebugModel;
609                 e.classname = "debugmodel";
610         }
611         else
612         {
613                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
614         }
615
616         return;
617 }
618
619 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
620 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
621 // All keys are in ascii.
622 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
623 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
624 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
625 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
626 {
627         local float bSkipKey;
628         bSkipKey = false;
629
630         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
631                 return true;
632
633         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
634                 return true;
635
636         if(menu_visible)
637                 if(menu_action(bInputType, nPrimary, nSecondary))
638                         return TRUE;
639         return bSkipKey;
640 }
641
642 // END REQUIRED CSQC FUNCTIONS
643 // --------------------------------------------------------------------------
644
645 // --------------------------------------------------------------------------
646 // BEGIN OPTIONAL CSQC FUNCTIONS
647 void Ent_ReadEntCS()
648 {
649         InterpolateOrigin_Undo();
650
651         self.classname = "entcs_receiver";
652         self.sv_entnum = ReadByte() - 1;
653         self.origin_x = ReadShort();
654         self.origin_y = ReadShort();
655         self.origin_z = ReadShort();
656         self.angles_y = ReadByte() * 360.0 / 256;
657         self.origin_z = self.angles_x = self.angles_z = 0;
658
659         InterpolateOrigin_Note();
660 }
661
662 void Ent_Remove();
663
664 void Ent_RemovePlayerScore()
665 {
666         float i;
667
668         if(self.owner)
669         {
670                 SetTeam(self.owner, -1);
671                 self.owner.gotscores = 0;
672                 for(i = 0; i < MAX_SCORE; ++i)
673                         self.owner.(scores[i]) = 0; // clear all scores
674         }
675 }
676
677 void Ent_ReadPlayerScore()
678 {
679         float i, n;
680         float isNew;
681         entity o;
682
683         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
684         // (no I've never heard of M-x replace-string, sed, or anything like that)
685         isNew = !self.owner; // workaround for DP bug
686         n = ReadByte()-1;
687
688 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
689         if(!isNew && n != self.sv_entnum)
690         {
691                 print("A CSQC entity changed its owner!\n");
692                 isNew = true;
693                 Ent_Remove();
694                 self.enttype = ENT_CLIENT_SCORES;
695         }
696 #endif
697
698         self.sv_entnum = n;
699
700         if not(playerslots[self.sv_entnum])
701                 playerslots[self.sv_entnum] = spawn();
702         o = self.owner = playerslots[self.sv_entnum];
703         o.sv_entnum = self.sv_entnum;
704         o.gotscores = 1;
705
706         //if not(o.sort_prev)
707         //      RegisterPlayer(o);
708         //playerchecker will do this for us later, if it has not already done so
709
710         float sf, lf;
711 #if MAX_SCORE <= 8
712         sf = ReadByte();
713         lf = ReadByte();
714 #else
715         sf = ReadShort();
716         lf = ReadShort();
717 #endif
718         float p;
719         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
720                 if(sf & p)
721                 {
722                         if(lf & p)
723                                 o.(scores[i]) = ReadInt24_t();
724                         else
725                                 o.(scores[i]) = ReadChar();
726                 }
727
728         if(o.sort_prev)
729                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
730
731         self.entremove = Ent_RemovePlayerScore;
732 }
733
734 void Ent_ReadTeamScore()
735 {
736         float i;
737         entity o;
738
739         self.team = ReadByte();
740         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
741
742         float sf, lf;
743 #if MAX_TEAMSCORE <= 8
744         sf = ReadByte();
745         lf = ReadByte();
746 #else
747         sf = ReadShort();
748         lf = ReadShort();
749 #endif
750         float p;
751         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
752                 if(sf & p)
753                 {
754                         if(lf & p)
755                                 o.(teamscores[i]) = ReadInt24_t();
756                         else
757                                 o.(teamscores[i]) = ReadChar();
758                 }
759
760         HUD_UpdateTeamPos(o);
761 }
762
763 void Net_Reset()
764 {
765 }
766
767 void Ent_ClientData()
768 {
769         float f;
770         float newspectatee_status;
771
772         f = ReadByte();
773
774         scoreboard_showscores_force = (f & 1);
775
776         if(f & 2)
777         {
778                 newspectatee_status = ReadByte();
779                 if(newspectatee_status == player_localentnum)
780                         newspectatee_status = -1; // observing
781         }
782         else
783                 newspectatee_status = 0;
784
785         spectatorbutton_zoom = (f & 4);
786
787         if(f & 8)
788         {
789                 angles_held_status = 1;
790                 angles_held_x = ReadAngle();
791                 angles_held_y = ReadAngle();
792                 angles_held_z = 0;
793         }
794         else
795                 angles_held_status = 0;
796
797         if(newspectatee_status != spectatee_status)
798         {
799                 float i;
800                 // clear the weapon accuracy stats
801                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
802                         weapon_hits[i] = 0;
803                         weapon_fired[i] = 0;
804                 }
805
806                 // clear race stuff
807                 race_laptime = 0;
808                 race_checkpointtime = 0;
809         }
810         spectatee_status = newspectatee_status;
811 }
812
813 void Ent_Nagger()
814 {
815         float nags, i, j, b, f;
816
817         nags = ReadByte();
818
819         if(nags & 128)
820         {
821                 if(vote_called_vote)
822                         strunzone(vote_called_vote);
823                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
824         }
825
826         if(nags & 1)
827         {
828                 for(j = 0; j < maxclients; ++j)
829                         if(playerslots[j])
830                                 playerslots[j].ready = 1;
831                 for(i = 1; i <= maxclients; i += 8)
832                 {
833                         f = ReadByte();
834                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
835                                 if not(f & b)
836                                         if(playerslots[j])
837                                                 playerslots[j].ready = 0;
838                 }
839         }
840
841         ready_waiting = (nags & 1);
842         ready_waiting_for_me = (nags & 2);
843         vote_waiting = (nags & 4);
844         vote_waiting_for_me = (nags & 8);
845         warmup_stage = (nags & 16);
846 }
847
848 void Ent_RandomSeed()
849 {
850         float s;
851         prandom_debug();
852         s = ReadShort();
853         psrandom(s);
854 }
855
856 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
857 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
858 void Ent_RadarLink();
859 void Ent_Init();
860 void Ent_ScoresInfo();
861 void(float bIsNewEntity) CSQC_Ent_Update =
862 {
863         float t;
864         float savetime;
865         t = ReadByte();
866
867         // set up the "time" global for received entities to be correct for interpolation purposes
868         savetime = time;
869         if(servertime)
870         {
871                 time = servertime;
872         }
873         else
874         {
875                 serverprevtime = time;
876                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
877                 time = serverprevtime + serverdeltatime;
878         }
879
880 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
881         if(self.enttype)
882                 if(t != self.enttype)
883                 {
884                         print("A CSQC entity changed its type!\n");
885                         Ent_Remove();
886                         bIsNewEntity = 1;
887                 }
888 #endif
889         self.enttype = t;
890         switch(t)
891         {
892                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
893                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
894                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
895                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
896                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
897                 case ENT_CLIENT_LASER: Ent_Laser(); break;
898                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
899                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
900                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
901                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
902                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
903                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
904                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
905                 case ENT_CLIENT_INIT: Ent_Init(); break;
906                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
907                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
908                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
909                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
910                 case ENT_CLIENT_WALL: Ent_Wall(); break;
911                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
912                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
913                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
914                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
915                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
916                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
917                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
918                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
919                 default:
920                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
921                         break;
922         }
923
924         time = savetime;
925 };
926 // Destructor, but does NOT deallocate the entity by calling remove(). Also
927 // used when an entity changes its type. For an entity that someone interacts
928 // with others, make sure it can no longer do so.
929 void Ent_Remove()
930 {
931         if(self.entremove)
932                 self.entremove();
933
934         self.enttype = 0;
935         self.classname = "";
936         self.draw = menu_sub_null;
937         self.entremove = menu_sub_null;
938         // TODO possibly set more stuff to defaults
939 }
940 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
941 void CSQC_Ent_Remove()
942 {
943         if(self.enttype)
944                 Ent_Remove();
945         remove(self);
946 }
947
948 void Gamemode_Init()
949 {
950         if(gametype == GAME_ONSLAUGHT) {
951                 print(strcat("Using ", minimapname, " as minimap.\n"));
952                 precache_pic("gfx/ons-cp-neutral.tga");
953                 precache_pic("gfx/ons-cp-red.tga");
954                 precache_pic("gfx/ons-cp-blue.tga");
955                 precache_pic("gfx/ons-frame.tga");
956                 precache_pic("gfx/ons-frame-team.tga");
957         }
958
959         if not(isdemo())
960         {
961                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
962                 calledhooks |= HOOK_START;
963         }
964 }
965 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
966 void CSQC_Parse_StuffCmd(string strMessage)
967 {
968         localcmd(strMessage);
969 }
970 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
971 void CSQC_Parse_Print(string strMessage)
972 {
973         print(ColorTranslateRGB(strMessage));
974 }
975
976 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
977 void CSQC_Parse_CenterPrint(string strMessage)
978 {
979         centerprint(strMessage);
980 }
981
982 string notranslate_fogcmd1 = "\nfog ";
983 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
984 void Fog_Force()
985 {
986         // TODO somehow thwart prvm_globalset client ...
987
988         if(forcefog != "")
989                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
990 }
991
992 void Gamemode_Init();
993 void Ent_ScoresInfo()
994 {
995         float i;
996         self.classname = "ent_client_scores_info";
997         gametype = ReadByte();
998         for(i = 0; i < MAX_SCORE; ++i)
999         {
1000                 scores_label[i] = strzone(ReadString());
1001                 scores_flags[i] = ReadByte();
1002         }
1003         for(i = 0; i < MAX_TEAMSCORE; ++i)
1004         {
1005                 teamscores_label[i] = strzone(ReadString());
1006                 teamscores_flags[i] = ReadByte();
1007         }
1008         HUD_InitScores();
1009         Gamemode_Init();
1010 }
1011
1012 void Ent_Init()
1013 {
1014         self.classname = "ent_client_init";
1015
1016         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1017
1018         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1019         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1020         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1021         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1022         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1023         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1024         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1025         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1026         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1027         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1028         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1029         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1030
1031         if(forcefog)
1032                 strunzone(forcefog);
1033         forcefog = strzone(ReadString());
1034
1035         armorblockpercent = ReadByte() / 255.0;
1036
1037         g_weaponswitchdelay = ReadByte() / 255.0;
1038
1039         g_balance_grenadelauncher_secondary_bouncefactor = ReadCoord();
1040         g_balance_grenadelauncher_secondary_bouncestop = ReadCoord();
1041
1042         nex_scope = !ReadByte();
1043         campingrifle_scope = !ReadByte();
1044
1045         if(!postinit)
1046                 PostInit();
1047 }
1048
1049 void Net_ReadRace()
1050 {
1051         float b;
1052
1053         b = ReadByte();
1054
1055         switch(b)
1056         {
1057                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1058                         race_checkpoint = ReadByte();
1059                         race_time = ReadInt24_t();
1060                         race_previousbesttime = ReadInt24_t();
1061                         if(race_previousbestname)
1062                                 strunzone(race_previousbestname);
1063                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1064
1065                         race_checkpointtime = time;
1066
1067                         if(race_checkpoint == 0 || race_checkpoint == 254)
1068                         {
1069                                 race_penaltyaccumulator = 0;
1070                                 race_laptime = time; // valid
1071                         }
1072
1073                         break;
1074
1075                 case RACE_NET_CHECKPOINT_CLEAR:
1076                         race_laptime = 0;
1077                         race_checkpointtime = 0;
1078                         break;
1079
1080                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1081                         race_laptime = ReadCoord();
1082                         race_checkpointtime = -99999;
1083                         // fall through
1084                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1085                         race_nextcheckpoint = ReadByte();
1086
1087                         race_nextbesttime = ReadInt24_t();
1088                         if(race_nextbestname)
1089                                 strunzone(race_nextbestname);
1090                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1091                         break;
1092
1093                 case RACE_NET_CHECKPOINT_HIT_RACE:
1094                         race_mycheckpoint = ReadByte();
1095                         race_mycheckpointtime = time;
1096                         race_mycheckpointdelta = ReadInt24_t();
1097                         race_mycheckpointlapsdelta = ReadByte();
1098                         if(race_mycheckpointlapsdelta >= 128)
1099                                 race_mycheckpointlapsdelta -= 256;
1100                         if(race_mycheckpointenemy)
1101                                 strunzone(race_mycheckpointenemy);
1102                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1103                         break;
1104
1105                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1106                         race_othercheckpoint = ReadByte();
1107                         race_othercheckpointtime = time;
1108                         race_othercheckpointdelta = ReadInt24_t();
1109                         race_othercheckpointlapsdelta = ReadByte();
1110                         if(race_othercheckpointlapsdelta >= 128)
1111                                 race_othercheckpointlapsdelta -= 256;
1112                         if(race_othercheckpointenemy)
1113                                 strunzone(race_othercheckpointenemy);
1114                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1115                         break;
1116
1117                 case RACE_NET_PENALTY_RACE:
1118                         race_penaltyeventtime = time;
1119                         race_penaltytime = ReadShort();
1120                         //race_penaltyaccumulator += race_penaltytime;
1121                         if(race_penaltyreason)
1122                                 strunzone(race_penaltyreason);
1123                         race_penaltyreason = strzone(ReadString());
1124                         break;
1125
1126                 case RACE_NET_PENALTY_QUALIFYING:
1127                         race_penaltyeventtime = time;
1128                         race_penaltytime = ReadShort();
1129                         race_penaltyaccumulator += race_penaltytime;
1130                         if(race_penaltyreason)
1131                                 strunzone(race_penaltyreason);
1132                         race_penaltyreason = strzone(ReadString());
1133                         break;
1134
1135                 case RACE_NET_SERVER_RECORD:
1136                         race_server_record = ReadInt24_t();
1137                         break;
1138                 case RACE_NET_SPEED_AWARD:
1139                         race_speedaward = ReadInt24_t();
1140                         if(race_speedaward_holder)
1141                                 strunzone(race_speedaward_holder);
1142                         race_speedaward_holder = strzone(ReadString());
1143                         break;
1144                 case RACE_NET_SPEED_AWARD_BEST:
1145                         race_speedaward_alltimebest = ReadInt24_t();
1146                         if(race_speedaward_alltimebest_holder)
1147                                 strunzone(race_speedaward_alltimebest_holder);
1148                         race_speedaward_alltimebest_holder = strzone(ReadString());
1149                         break;
1150                 case RACE_NET_SERVER_RANKINGS:
1151                         float pos, prevpos, del;
1152                         pos = ReadShort();
1153                         prevpos = ReadShort();
1154                         del = ReadShort();
1155
1156                         // move other rankings out of the way
1157                         float i;
1158                         if (prevpos) {
1159                                 for (i=prevpos-1;i>pos-1;--i) {
1160                                         grecordtime[i] = grecordtime[i-1];
1161                                         if(grecordholder[i])
1162                                                 strunzone(grecordholder[i]);
1163                                         grecordholder[i] = strzone(grecordholder[i-1]);
1164                                 }
1165                         } else if (del) { // a record has been deleted by the admin
1166                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1167                                         if (i == RANKINGS_CNT-1) { // clear out last record
1168                                                 grecordtime[i] = 0;
1169                                                 if (grecordholder[i])
1170                                                         strunzone(grecordholder[i]);
1171                                                 grecordholder[i] = string_null;
1172                                         }
1173                                         else {
1174                                                 grecordtime[i] = grecordtime[i+1];
1175                                                 if (grecordholder[i])
1176                                                         strunzone(grecordholder[i]);
1177                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1178                                         }
1179                                 }
1180                         } else { // player has no ranked record yet
1181                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1182                                         grecordtime[i] = grecordtime[i-1];
1183                                         if(grecordholder[i])
1184                                                 strunzone(grecordholder[i]);
1185                                         grecordholder[i] = strzone(grecordholder[i-1]);
1186                                 }
1187                         }
1188
1189                         // store new ranking
1190                         if(grecordholder[pos-1] != "")
1191                                 strunzone(grecordholder[pos-1]);
1192                         grecordholder[pos-1] = strzone(ReadString());
1193                         grecordtime[pos-1] = ReadInt24_t();
1194                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1195                                 race_myrank = pos;
1196                         break;
1197                 case RACE_NET_SERVER_STATUS:
1198                         race_status = ReadShort();
1199                         if(race_status_name)
1200                                 strunzone(race_status_name);
1201                         race_status_name = strzone(ReadString());
1202         }
1203 }
1204
1205 void Net_ReadSpawn()
1206 {
1207         zoomin_effect = 1;
1208         current_viewzoom = 0.6;
1209 }
1210
1211 void Net_TeamNagger()
1212 {
1213         teamnagger = 1;
1214 }
1215
1216 void Net_ReadPingPLReport()
1217 {
1218         float e, pi, pl, ml;
1219         e = ReadByte();
1220         pi = ReadShort();
1221         pl = ReadByte();
1222         ml = ReadByte();
1223         if not(playerslots[e])
1224                 return;
1225         playerslots[e].ping = pi;
1226         playerslots[e].ping_packetloss = pl / 255.0;
1227         playerslots[e].ping_movementloss = ml / 255.0;
1228 }
1229
1230 void Net_VoteDialog(float highlight) {
1231         if(highlight) {
1232                 vote_highlighted = ReadByte();
1233                 return;
1234         }
1235
1236         vote_yescount = ReadByte();
1237         vote_nocount = ReadByte();
1238         vote_needed = ReadByte();
1239         vote_active = 1;
1240 }
1241
1242 void Net_VoteDialogReset() {
1243         vote_active = 0;
1244 }
1245
1246 void Net_Notify() {
1247         float type;
1248         type = ReadByte();
1249
1250         if(type == CSQC_KILLNOTIFY)
1251         {
1252                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1253         }
1254         else if(type == CSQC_CENTERPRINT)
1255         {
1256                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1257         }
1258 }
1259
1260 void Net_WeaponComplain() {
1261         complain_weapon = ReadByte();
1262
1263         if(complain_weapon_name)
1264                 strunzone(complain_weapon_name);
1265         complain_weapon_name = strzone(ReadString());
1266
1267         complain_weapon_type = ReadByte();
1268
1269         complain_weapon_time = time;
1270         weapontime = time; // ping the weapon panel
1271 }
1272
1273 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1274 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1275 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1276 float CSQC_Parse_TempEntity()
1277 {
1278         local float bHandled;
1279                 bHandled  = true;
1280         // Acquire TE ID
1281         local float nTEID;
1282                 nTEID = ReadByte();
1283
1284                 // NOTE: Could just do return instead of break...
1285         switch(nTEID)
1286         {
1287                 case TE_CSQC_TARGET_MUSIC:
1288                         Net_TargetMusic();
1289                         bHandled = true;
1290                         break;
1291                 case TE_CSQC_PICTURE:
1292                         Net_MapVote_Picture();
1293                         bHandled = true;
1294                         break;
1295                 case TE_CSQC_RACE:
1296                         Net_ReadRace();
1297                         bHandled = true;
1298                         break;
1299                 case TE_CSQC_SPAWN:
1300                         Net_ReadSpawn();
1301                         bHandled = true;
1302                         break;
1303                 case TE_CSQC_ZCURVEPARTICLES:
1304                         Net_ReadZCurveParticles();
1305                         bHandled = true;
1306                         break;
1307                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1308                         Net_ReadNexgunBeamParticle();
1309                         bHandled = true;
1310                         break;
1311                 case TE_CSQC_TEAMNAGGER:
1312                         Net_TeamNagger();
1313                         bHandled = true;
1314                         break;
1315                 case TE_CSQC_VOTE:
1316                         Net_VoteDialog(ReadByte());
1317                         bHandled = true;
1318                         break;
1319                 case TE_CSQC_VOTERESET:
1320                         Net_VoteDialogReset();
1321                         bHandled = true;
1322                         break;
1323                 case TE_CSQC_LIGHTNINGARC:
1324                         Net_ReadLightningarc();
1325                         bHandled = true;
1326                         break;
1327                 case TE_CSQC_PINGPLREPORT:
1328                         Net_ReadPingPLReport();
1329                         bHandled = true;
1330                         break;
1331                 case TE_CSQC_ANNOUNCE:
1332                         announce_snd = strzone(ReadString());
1333                         bHandled = true;
1334                         break;
1335                 case TE_CSQC_NOTIFY:
1336                         Net_Notify();
1337                         bHandled = true;
1338                         break;
1339                 case TE_CSQC_WEAPONCOMPLAIN:
1340                         Net_WeaponComplain();
1341                         bHandled = true;
1342                         break;
1343                 case TE_CSQC_CR_MAXBULLETS:
1344                         cr_maxbullets = ReadByte();
1345                         bHandled = true;
1346                         break;
1347                 default:
1348                         // No special logic for this temporary entity; return 0 so the engine can handle it
1349                         bHandled = false;
1350                         break;
1351         }
1352
1353         return bHandled;
1354 }
1355
1356 string getcommandkey(string text, string command)
1357 {
1358         string keys;
1359         float n, j, k, l;
1360
1361         if (!hud_showbinds)
1362                 return text;
1363
1364         keys = db_get(binddb, command);
1365         if (!keys)
1366         {
1367                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1368                 for(j = 0; j < n; ++j)
1369                 {
1370                         k = stof(argv(j));
1371                         if(k != -1)
1372                         {
1373                                 if ("" == keys)
1374                                         keys = keynumtostring(k);
1375                                 else
1376                                         keys = strcat(keys, ", ", keynumtostring(k));
1377
1378                                 ++l;
1379                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1380                         }
1381
1382                 }
1383                 db_put(binddb, command, keys);
1384         }
1385
1386         if ("" == keys) {
1387                 if (hud_showbinds > 1)
1388                         return strcat(text, " (not bound)");
1389                 else
1390                         return text;
1391         }
1392         else if (hud_showbinds > 1)
1393                 return strcat(text, " (", keys, ")");
1394         else
1395                 return keys;
1396 }