initial work on notify panel, some centerprints now will be different depending on...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / Main.qc
1 // --------------------------------------------------------------------------
2 // BEGIN REQUIRED CSQC FUNCTIONS
3 //include "main.qh"
4
5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
6
7 void cvar_clientsettemp(string cv, string val)
8 {
9         entity e;
10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
11                 if(e.netname == cv)
12                         goto saved;
13         e = spawn();
14         e.classname = "saved_cvar_value";
15         e.netname = strzone(cv);
16         e.message = strzone(cvar_string(cv));
17 :saved
18         cvar_set(cv, val);
19 }
20
21 void cvar_clientsettemp_restore()
22 {
23         entity e;
24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
25                         cvar_set(e.netname, e.message);
26 }
27
28 void() menu_show_error =
29 {
30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
31 };
32
33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
34 // Useful for precaching things
35
36 void() menu_sub_null =
37 {
38 };
39
40 #ifdef USE_FTE
41 float __engine_check;
42 #endif
43
44 string forcefog;
45 string cl_announcer_prev;
46 void WaypointSprite_Load();
47 void CSQC_Init(void)
48 {
49 #ifdef USE_FTE
50 #pragma target ID
51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
52         if(!__engine_check)
53         {
54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
55                 localcmd("\ndisconnect\n");
56                 return;
57         }
58 #pragma target FTE
59 #endif
60         
61         check_unacceptable_compiler_bugs();
62
63 #ifdef WATERMARK
64         print("^4CSQC Build information: ", WATERMARK(), "\n");
65 #endif
66
67         float i;
68         CSQC_CheckEngine();
69
70         binddb = db_create();
71         tempdb = db_create();
72         ClientProgsDB = db_load("client.db");
73         compressShortVector_init();
74
75         drawfont = 0;
76         menu_visible = FALSE;
77         menu_show = menu_show_error;
78         menu_action = menu_sub_null;
79
80         for(i = 0; i < 255; ++i)
81                 if(getplayerkey(i, "viewentity") == "")
82                         break;
83         maxclients = i;
84
85         //ctf_temp_1 = "";
86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
87         //registercmd("ctf_menu");
88         registercmd("ons_map");
89         registercmd("hud_configure");
90         registercmd("hud_save");
91         //registercmd("menu_action");
92
93         registercmd("+button3");
94         registercmd("-button3");
95         registercmd("+button4");
96         registercmd("-button4");
97         registercmd("+showaccuracy");registercmd("-showaccuracy");
98
99 #ifndef CAMERATEST
100         if(isdemo())
101         {
102 #endif
103                 registercmd("+forward");registercmd("-forward");
104                 registercmd("+back");registercmd("-back");
105                 registercmd("+moveup");registercmd("-moveup");
106                 registercmd("+movedown");registercmd("-movedown");
107                 registercmd("+moveright");registercmd("-moveright");
108                 registercmd("+moveleft");registercmd("-moveleft");
109                 registercmd("+roll_right");registercmd("-roll_right");
110                 registercmd("+roll_left");registercmd("-roll_left");
111 #ifndef CAMERATEST
112         }
113 #endif
114         registercvar("hud_usecsqc", "1");
115         registercvar("hud_columns", "default", CVAR_SAVE);
116
117         gametype = 0;
118
119         // hud_fields uses strunzone on the titles!
120         for(i = 0; i < MAX_HUD_FIELDS; ++i)
121                 hud_title[i] = strzone("(null)");
122
123         postinit = false;
124
125         calledhooks = 0;
126
127         teams = Sort_Spawn();
128         players = Sort_Spawn();
129
130         GetTeam(COLOR_SPECTATOR, true); // add specs first
131
132         cvar_clientsettemp("_supports_weaponpriority", "1");
133
134         RegisterWeapons();
135
136         WaypointSprite_Load();
137
138         // precaches
139         Projectile_Precache();
140         GibSplash_Precache();
141         Casings_Precache();
142         DamageInfo_Precache();
143         if(cvar_string("cl_announcer") != cl_announcer_prev) {
144                 Announcer_Precache();
145                 if(cl_announcer_prev)
146                         strunzone(cl_announcer_prev);
147                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
148         }
149         Tuba_Precache();
150
151 #ifdef UID
152         {
153                 // find the user ID
154                 string uid;
155                 registercvar("_cl_userid", "", CVAR_SAVE);
156                 uid = cvar_string("_cl_userid");
157                 if(strlen(uid) < 16)
158                 {
159                         uid = "";
160                         for(i = 0; i < 4; ++i)
161                                 uid = strcat(uid, substring(ftos(floor(10000 + random() * 10000)), 1, -1));
162                 }
163                 cvar_set("_cl_userid", uid);
164                 localcmd(strcat("\ncmd uid ", uid, "\n"));
165         }
166 #endif
167
168         get_mi_min_max_texcoords(1); // try the CLEVER way first
169         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
170         shortmapname = mi_shortname;
171
172         if(precache_pic(minimapname) == "")
173         {
174                 // but maybe we have a non-clever minimap
175                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
176                 if(precache_pic(minimapname) == "")
177                         minimapname = ""; // FAIL
178                 else
179                         get_mi_min_max_texcoords(0); // load new texcoords
180         }
181
182         mi_center = (mi_min + mi_max) * 0.5;
183         mi_scale = mi_max - mi_min;
184         minimapname = strzone(minimapname);
185
186         WarpZone_Init();
187 }
188
189 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
190 void CSQC_Shutdown(void)
191 {
192 #ifdef USE_FTE
193 #pragma TARGET id
194         if(!__engine_check)
195                 return 0;
196 #pragma TARGET fte
197 #endif
198
199         WarpZone_Shutdown();
200
201         remove(teams);
202         remove(players);
203         db_close(binddb);
204         db_close(tempdb);
205         db_save(ClientProgsDB, "client.db");
206         db_close(ClientProgsDB);
207
208         cvar_clientsettemp_restore();
209
210         if(camera_active)
211                 cvar_set("chase_active",ftos(chase_active_backup));
212
213         if not(isdemo())
214         {
215                 if not(calledhooks & HOOK_START)
216                         localcmd("\n_cl_hook_gamestart nop;");
217                 if not(calledhooks & HOOK_END)
218                         localcmd("\ncl_hook_gameend;");
219         }
220 }
221
222 .float has_team;
223 float SetTeam(entity o, float Team)
224 {
225         entity tm;
226         if(teamplay)
227         {
228                 switch(Team)
229                 {
230                         case -1:
231                         case COLOR_TEAM1:
232                         case COLOR_TEAM2:
233                         case COLOR_TEAM3:
234                         case COLOR_TEAM4:
235                                 break;
236                         default:
237                                 if(GetTeam(Team, false) == NULL)
238                                 {
239                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
240                                         Team = COLOR_SPECTATOR;
241                                 }
242                                 break;
243                 }
244         }
245         else
246         {
247                 switch(Team)
248                 {
249                         case -1:
250                         case 0:
251                                 break;
252                         default:
253                                 if(GetTeam(Team, false) == NULL)
254                                 {
255                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
256                                         Team = COLOR_SPECTATOR;
257                                 }
258                                 break;
259                 }
260         }
261         if(Team == -1) // leave
262         {
263                 if(o.has_team)
264                 {
265                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
266                         tm = GetTeam(o.team, false);
267                         tm.team_size -= 1;
268                         o.has_team = 0;
269                         return TRUE;
270                 }
271         }
272         else
273         {
274                 if not(o.has_team)
275                 {
276                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
277                         o.team = Team;
278                         tm = GetTeam(Team, true);
279                         tm.team_size += 1;
280                         o.has_team = 1;
281                         return TRUE;
282                 }
283                 else if(Team != o.team)
284                 {
285                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
286                         tm = GetTeam(o.team, false);
287                         tm.team_size -= 1;
288                         o.team = Team;
289                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
290                         tm = GetTeam(Team, true);
291                         tm.team_size += 1;
292                         return TRUE;
293                 }
294         }
295         return FALSE;
296 }
297
298 void Playerchecker_Think()
299 {
300         float i;
301         entity e;
302         for(i = 0; i < maxclients; ++i)
303         {
304                 e = playerslots[i];
305                 if(GetPlayerName(i) == "")
306                 {
307                         if(e.sort_prev)
308                         {
309                                 //print("playerchecker: KILL KILL KILL\n");
310                                 // player disconnected
311                                 SetTeam(e, -1);
312                                 RemovePlayer(e);
313                                 e.sort_prev = world;
314                                 //e.gotscores = 0;
315                         }
316                 }
317                 else
318                 {
319                         if not(e.sort_prev)
320                         {
321                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
322                                 // player connected
323                                 if not(e)
324                                         playerslots[i] = e = spawn();
325                                 e.sv_entnum = i;
326                                 e.ping = 0;
327                                 e.ping_packetloss = 0;
328                                 e.ping_movementloss = 0;
329                                 //e.gotscores = 0; // we might already have the scores...
330                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
331                                 RegisterPlayer(e);
332                                 HUD_UpdatePlayerPos(e);
333                         }
334                 }
335         }
336         self.nextthink = time + 0.2;
337 }
338
339 void Porto_Init();
340 void TrueAim_Init();
341 void PostInit(void)
342 {
343         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
344         localcmd(strcat("\nhud_columns_set ", cvar_string("hud_columns"), ";\n"));
345
346         entity playerchecker;
347         playerchecker = spawn();
348         playerchecker.think = Playerchecker_Think;
349         playerchecker.nextthink = time + 0.2;
350
351         Porto_Init();
352         TrueAim_Init();
353
354         postinit = true;
355 }
356
357 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
358 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
359 float button_zoom;
360 void Cmd_HUD_SetFields(float);
361 void Cmd_HUD_Help(float);
362 float CSQC_ConsoleCommand(string strMessage)
363 {
364         float argc;
365         // Tokenize String
366         //argc = tokenize(strMessage);
367         argc = tokenize_console(strMessage);
368
369         // Acquire Command
370         local string strCmd;
371         strCmd = argv(0);
372
373         if(strCmd == "hud_configure") { // config hud
374                 cvar_set("_hud_configure", ftos(!cvar("_hud_configure")));
375                 return true;
376         } else if(strCmd == "hud_save") { // save hud config
377                 if(argv(1) == "" || argv(2)) {
378                         print("Usage:\n");
379                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
380                 }
381                 else
382                         HUD_Panel_ExportCfg(argv(1));
383                 return true;
384         } else if(strCmd == "+button4") { // zoom
385                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
386                 if(ignore_plus_zoom)
387                 {
388                         --ignore_plus_zoom;
389                         return false;
390                 }
391                 button_zoom = 1;
392                 return true;
393         } else if(strCmd == "-button4") { // zoom
394                 if(ignore_minus_zoom)
395                 {
396                         --ignore_minus_zoom;
397                         return false;
398                 }
399                 button_zoom = 0;
400                 return true;
401         } else if(strCmd == "+button3") { // secondary
402                 button_attack2 = 1;
403                 return false;
404         } else if(strCmd == "-button3") { // secondary
405                 button_attack2 = 0;
406                 return false;
407         } else if(strCmd == "+showscores") {
408                 sb_showscores = true;
409                 return true;
410         } else if(strCmd == "-showscores") {
411                 sb_showscores = false;
412                 return true;
413         } else if(strCmd == "+showaccuracy") {
414                 sb_showaccuracy = true;
415                 return true;
416         } else if(strCmd == "-showaccuracy") {
417                 sb_showaccuracy = false;
418                 return true;
419         }
420
421         if(camera_active)
422         if(strCmd == "+forward" || strCmd == "-back") {
423                 ++camera_direction_x;
424                 return true;
425         } else if(strCmd == "-forward" || strCmd == "+back") {
426                 --camera_direction_x;
427                 return true;
428         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
429                 --camera_direction_y;
430                 return true;
431         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
432                 ++camera_direction_y;
433                 return true;
434         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
435                 ++camera_direction_z;
436                 return true;
437         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
438                 --camera_direction_z;
439                 return true;
440         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
441                 ++camera_roll;
442                 return true;
443         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
444                 --camera_roll;
445                 return true;
446         }
447
448         return false;
449 }
450
451 .vector view_ofs;
452 entity debug_shotorg;
453 void ShotOrg_Draw()
454 {
455         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
456         self.angles = view_angles;
457         self.angles_x = -self.angles_x;
458         if not(self.cnt)
459                 R_AddEntity(self);
460 }
461 void ShotOrg_Draw2D()
462 {
463         vector coord2d_topleft, coord2d_topright, coord2d;
464         string s;
465         vector fs;
466
467         s = vtos(self.view_ofs);
468         s = substring(s, 1, strlen(s) - 2);
469         if(tokenize_console(s) == 3)
470                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
471
472         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
473         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
474
475         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
476
477         coord2d = coord2d_topleft;
478         if(fs_x < 8)
479         {
480                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
481                 fs = '8 8 0';
482         }
483         coord2d_y -= fs_y;
484         coord2d_z = 0;
485         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
486 }
487
488 void ShotOrg_Spawn()
489 {
490         debug_shotorg = spawn();
491         debug_shotorg.draw = ShotOrg_Draw;
492         debug_shotorg.draw2d = ShotOrg_Draw2D;
493         debug_shotorg.renderflags = RF_VIEWMODEL;
494         debug_shotorg.effects = EF_FULLBRIGHT;
495         precache_model("models/shotorg_adjuster.md3");
496         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
497         debug_shotorg.scale = 2;
498         debug_shotorg.view_ofs = '25 8 -8';
499 }
500
501 void DrawDebugModel()
502 {
503         if(time - floor(time) > 0.5)
504         {
505                 PolyDrawModel(self);
506         }
507         else
508         {
509                 self.renderflags = 0;
510                 R_AddEntity(self);
511         }
512 }
513
514 void GameCommand(string msg)
515 {
516         string s;
517         float argc;
518         entity e;
519         argc = tokenize_console(msg);
520
521         if(argv(0) == "help" || argc == 0)
522         {
523                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
524                 print("  settemp cvar value\n");
525                 print("  hud_columns_set ...\n");
526                 print("  hud_columns_help\n");
527                 GameCommand_Generic("help");
528                 return;
529         }
530
531         if(GameCommand_Generic(msg))
532                 return;
533
534         string cmd;
535         cmd = argv(0);
536         if(cmd == "mv_download") {
537                 Cmd_MapVote_MapDownload(argc);
538         }
539         else if(cmd == "settemp") {
540                 cvar_clientsettemp(argv(1), argv(2));
541         }
542         else if(cmd == "hud_columns_set") {
543                 Cmd_HUD_SetFields(argc);
544         }
545         else if(cmd == "hud_columns_help") {
546                 Cmd_HUD_Help(argc);
547         }
548 #ifdef BLURTEST
549         else if(cmd == "blurtest") {
550                 blurtest_time0 = time;
551                 blurtest_time1 = time + stof(argv(1));
552                 blurtest_radius = stof(argv(2));
553                 blurtest_power = stof(argv(3));
554         }
555 #endif
556         else if(cmd == "shotorg_move") {
557                 if(!debug_shotorg)
558                         ShotOrg_Spawn();
559                 else
560                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
561                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
562         }
563         else if(cmd == "shotorg_movez") {
564                 if(!debug_shotorg)
565                         ShotOrg_Spawn();
566                 else
567                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
568                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
569         }
570         else if(cmd == "shotorg_set") {
571                 if(!debug_shotorg)
572                         ShotOrg_Spawn();
573                 else
574                         debug_shotorg.view_ofs = stov(argv(1));
575                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
576         }
577         else if(cmd == "shotorg_setz") {
578                 if(!debug_shotorg)
579                         ShotOrg_Spawn();
580                 else
581                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
582                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
583         }
584         else if(cmd == "shotorg_toggle_hide") {
585                 if(debug_shotorg)
586                 {
587                         debug_shotorg.cnt = !debug_shotorg.cnt;
588                 }
589         }
590         else if(cmd == "shotorg_end") {
591                 if(debug_shotorg)
592                 {
593                         print(vtos(debug_shotorg.view_ofs), "\n");
594                         remove(debug_shotorg);
595                         debug_shotorg = world;
596                 }
597                 localcmd("sv_cmd debug_shotorg\n");
598         }
599         else if(cmd == "sendcvar") {
600                 // W_FixWeaponOrder will trash argv, so save what we need.
601                 string thiscvar;
602                 thiscvar = strzone(argv(1));
603                 s = cvar_string(thiscvar);
604                 if(thiscvar == "cl_weaponpriority")
605                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
606                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
607                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
608                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
609                 strunzone(thiscvar);
610         }
611         else if(cmd == "spawn") {
612                 s = argv(1);
613                 e = spawn();
614                 precache_model(s);
615                 setmodel(e, s);
616                 setorigin(e, view_origin);
617                 e.angles = view_angles;
618                 e.draw = DrawDebugModel;
619                 e.classname = "debugmodel";
620         }
621         else
622         {
623                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
624         }
625
626         return;
627 }
628
629 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
630 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
631 // All keys are in ascii.
632 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
633 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
634 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
635 float hudconf_active;
636 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
637 {
638         local float bSkipKey;
639         bSkipKey = false;
640
641         if(hudconf_active)
642                 if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
643                         return true;
644
645         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
646                 return true;
647
648         if(menu_visible)
649                 if(menu_action(bInputType, nPrimary, nSecondary))
650                         return TRUE;
651         return bSkipKey;
652 }
653
654 // END REQUIRED CSQC FUNCTIONS
655 // --------------------------------------------------------------------------
656
657 // --------------------------------------------------------------------------
658 // BEGIN OPTIONAL CSQC FUNCTIONS
659 void Ent_ReadEntCS()
660 {
661         InterpolateOrigin_Undo();
662
663         self.classname = "entcs_receiver";
664         self.sv_entnum = ReadByte() - 1;
665         self.origin_x = ReadShort();
666         self.origin_y = ReadShort();
667         self.origin_z = ReadShort();
668         self.angles_y = ReadByte() * 360.0 / 256;
669         self.origin_z = self.angles_x = self.angles_z = 0;
670
671         InterpolateOrigin_Note();
672 }
673
674 void Ent_Remove();
675
676 void Ent_RemovePlayerScore()
677 {
678         float i;
679
680         if(self.owner)
681         {
682                 SetTeam(self.owner, -1);
683                 self.owner.gotscores = 0;
684                 for(i = 0; i < MAX_SCORE; ++i)
685                         self.owner.(scores[i]) = 0; // clear all scores
686         }
687 }
688
689 void Ent_ReadPlayerScore()
690 {
691         float i, n;
692         float isNew;
693         entity o;
694
695         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
696         // (no I've never heard of M-x replace-string, sed, or anything like that)
697         isNew = !self.owner; // workaround for DP bug
698         n = ReadByte()-1;
699
700 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
701         if(!isNew && n != self.sv_entnum)
702         {
703                 print("A CSQC entity changed its owner!\n");
704                 isNew = true;
705                 Ent_Remove();
706                 self.enttype = ENT_CLIENT_SCORES;
707         }
708 #endif
709
710         self.sv_entnum = n;
711
712         if not(playerslots[self.sv_entnum])
713                 playerslots[self.sv_entnum] = spawn();
714         o = self.owner = playerslots[self.sv_entnum];
715         o.sv_entnum = self.sv_entnum;
716         o.gotscores = 1;
717
718         //if not(o.sort_prev)
719         //      RegisterPlayer(o);
720         //playerchecker will do this for us later, if it has not already done so
721
722         float sf, lf;
723 #if MAX_SCORE <= 8
724         sf = ReadByte();
725         lf = ReadByte();
726 #else
727         sf = ReadShort();
728         lf = ReadShort();
729 #endif
730         float p;
731         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
732                 if(sf & p)
733                 {
734                         if(lf & p)
735                                 o.(scores[i]) = ReadInt24_t();
736                         else
737                                 o.(scores[i]) = ReadChar();
738                 }
739
740         if(o.sort_prev)
741                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
742
743         self.entremove = Ent_RemovePlayerScore;
744 }
745
746 void Ent_ReadTeamScore()
747 {
748         float i;
749         entity o;
750
751         self.team = ReadByte();
752         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
753
754         float sf, lf;
755 #if MAX_TEAMSCORE <= 8
756         sf = ReadByte();
757         lf = ReadByte();
758 #else
759         sf = ReadShort();
760         lf = ReadShort();
761 #endif
762         float p;
763         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
764                 if(sf & p)
765                 {
766                         if(lf & p)
767                                 o.(teamscores[i]) = ReadInt24_t();
768                         else
769                                 o.(teamscores[i]) = ReadChar();
770                 }
771
772         HUD_UpdateTeamPos(o);
773 }
774
775 void Net_Reset()
776 {
777 }
778
779 void Ent_ClientData()
780 {
781         float f;
782         float newspectatee_status;
783
784         f = ReadByte();
785
786         sb_showscores_force = (f & 1);
787
788         if(f & 2)
789         {
790                 newspectatee_status = ReadByte();
791                 if(newspectatee_status == player_localentnum)
792                         newspectatee_status = -1; // observing
793         }
794         else
795                 newspectatee_status = 0;
796
797         spectatorbutton_zoom = (f & 4);
798
799         if(f & 8)
800         {
801                 angles_held_status = 1;
802                 angles_held_x = ReadAngle();
803                 angles_held_y = ReadAngle();
804                 angles_held_z = 0;
805         }
806         else
807                 angles_held_status = 0;
808
809         if(newspectatee_status != spectatee_status)
810         {
811                 float i;
812                 // clear the weapon accuracy stats
813                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
814                         weapon_hits[i] = 0;
815                         weapon_fired[i] = 0;
816                 }
817
818                 // clear race stuff
819                 race_laptime = 0;
820                 race_checkpointtime = 0;
821         }
822         spectatee_status = newspectatee_status;
823 }
824
825 void Ent_Nagger()
826 {
827         float nags, i, j, b, f;
828
829         nags = ReadByte();
830
831         if(nags & 128)
832         {
833                 if(vote_called_vote)
834                         strunzone(vote_called_vote);
835                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
836         }
837
838         if(nags & 1)
839         {
840                 for(j = 0; j < maxclients; ++j)
841                         if(playerslots[j])
842                                 playerslots[j].ready = 1;
843                 for(i = 1; i <= maxclients; i += 8)
844                 {
845                         f = ReadByte();
846                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
847                                 if not(f & b)
848                                         if(playerslots[j])
849                                                 playerslots[j].ready = 0;
850                 }
851         }
852
853         ready_waiting = (nags & 1);
854         ready_waiting_for_me = (nags & 2);
855         vote_waiting = (nags & 4);
856         vote_waiting_for_me = (nags & 8);
857         warmup_stage = (nags & 16);
858 }
859
860 void Ent_RandomSeed()
861 {
862         float s;
863         prandom_debug();
864         s = ReadShort();
865         psrandom(s);
866 }
867
868 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
869 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
870 void Ent_RadarLink();
871 void Ent_Init();
872 void Ent_ScoresInfo();
873 void(float bIsNewEntity) CSQC_Ent_Update =
874 {
875         float t;
876         float savetime;
877         t = ReadByte();
878
879         // set up the "time" global for received entities to be correct for interpolation purposes
880         savetime = time;
881         if(servertime)
882         {
883                 time = servertime;
884         }
885         else
886         {
887                 serverprevtime = time;
888                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
889                 time = serverprevtime + serverdeltatime;
890         }
891
892 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
893         if(self.enttype)
894                 if(t != self.enttype)
895                 {
896                         print("A CSQC entity changed its type!\n");
897                         Ent_Remove();
898                         bIsNewEntity = 1;
899                 }
900 #endif
901         self.enttype = t;
902         switch(t)
903         {
904                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
905                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
906                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
907                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
908                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
909                 case ENT_CLIENT_LASER: Ent_Laser(); break;
910                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
911                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
912                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
913                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
914                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
915                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
916                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
917                 case ENT_CLIENT_INIT: Ent_Init(); break;
918                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
919                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
920                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
921                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
922                 case ENT_CLIENT_WALL: Ent_Wall(); break;
923                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
924                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
925                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
926                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
927                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
928                 default:
929                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
930                         break;
931         }
932
933         time = savetime;
934 };
935 // Destructor, but does NOT deallocate the entity by calling remove(). Also
936 // used when an entity changes its type. For an entity that someone interacts
937 // with others, make sure it can no longer do so.
938 void Ent_Remove()
939 {
940         if(self.entremove)
941                 self.entremove();
942
943         self.enttype = 0;
944         self.classname = "";
945         self.draw = menu_sub_null;
946         self.entremove = menu_sub_null;
947         // TODO possibly set more stuff to defaults
948 }
949 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
950 void CSQC_Ent_Remove()
951 {
952         if(self.enttype)
953                 Ent_Remove();
954         remove(self);
955 }
956
957 void Gamemode_Init()
958 {
959         if(gametype == GAME_ONSLAUGHT) {
960                 print(strcat("Using ", minimapname, " as minimap.\n"));
961                 precache_pic("gfx/ons-cp-neutral.tga");
962                 precache_pic("gfx/ons-cp-red.tga");
963                 precache_pic("gfx/ons-cp-blue.tga");
964                 precache_pic("gfx/ons-frame.tga");
965                 precache_pic("gfx/ons-frame-team.tga");
966         } else if(gametype == GAME_KEYHUNT) {
967                 precache_pic("gfx/sb_key_carrying");
968                 precache_pic("gfx/sb_key_carrying_outline");
969         }
970
971         if not(isdemo())
972         {
973                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), ";");
974                 calledhooks |= HOOK_START;
975         }
976 }
977 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
978 void CSQC_Parse_StuffCmd(string strMessage)
979 {
980         localcmd(strMessage);
981 }
982 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
983 void CSQC_Parse_Print(string strMessage)
984 {
985         print(ColorTranslateRGB(strMessage));
986 }
987
988 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
989 void CSQC_Parse_CenterPrint(string strMessage)
990 {
991         centerprint(strMessage);
992 }
993
994 string notranslate_fogcmd1 = "\nfog ";
995 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
996 void Fog_Force()
997 {
998         // TODO somehow thwart prvm_globalset client ...
999
1000         if(forcefog != "")
1001                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1002 }
1003
1004 void Gamemode_Init();
1005 void Ent_ScoresInfo()
1006 {
1007         float i;
1008         self.classname = "ent_client_scores_info";
1009         gametype = ReadByte();
1010         for(i = 0; i < MAX_SCORE; ++i)
1011         {
1012                 scores_label[i] = strzone(ReadString());
1013                 scores_flags[i] = ReadByte();
1014         }
1015         for(i = 0; i < MAX_TEAMSCORE; ++i)
1016         {
1017                 teamscores_label[i] = strzone(ReadString());
1018                 teamscores_flags[i] = ReadByte();
1019         }
1020         HUD_InitScores();
1021         Gamemode_Init();
1022 }
1023
1024 void Ent_Init()
1025 {
1026         self.classname = "ent_client_init";
1027
1028         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1029
1030         hook_shotorigin_x = ReadCoord();
1031         hook_shotorigin_y = ReadCoord();
1032         hook_shotorigin_z = ReadCoord();
1033
1034         if(forcefog)
1035                 strunzone(forcefog);
1036         forcefog = strzone(ReadString());
1037
1038         armorblockpercent = ReadByte() / 255.0;
1039
1040         g_weaponswitchdelay = ReadByte() / 255.0;
1041
1042         g_balance_grenadelauncher_secondary_bouncefactor = ReadCoord();
1043         g_balance_grenadelauncher_secondary_bouncestop = ReadCoord();
1044
1045         if(!postinit)
1046                 PostInit();
1047 }
1048
1049 void Net_ReadRace()
1050 {
1051         float b;
1052
1053         b = ReadByte();
1054
1055         switch(b)
1056         {
1057                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1058                         race_checkpoint = ReadByte();
1059                         race_time = ReadInt24_t();
1060                         race_previousbesttime = ReadInt24_t();
1061                         if(race_previousbestname)
1062                                 strunzone(race_previousbestname);
1063                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1064
1065                         race_checkpointtime = time;
1066
1067                         if(race_checkpoint == 0 || race_checkpoint == 254)
1068                         {
1069                                 race_penaltyaccumulator = 0;
1070                                 race_laptime = time; // valid
1071                         }
1072
1073                         break;
1074
1075                 case RACE_NET_CHECKPOINT_CLEAR:
1076                         race_laptime = 0;
1077                         race_checkpointtime = 0;
1078                         break;
1079
1080                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1081                         race_laptime = ReadCoord();
1082                         race_checkpointtime = -99999;
1083                         // fall through
1084                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1085                         race_nextcheckpoint = ReadByte();
1086
1087                         race_nextbesttime = ReadInt24_t();
1088                         if(race_nextbestname)
1089                                 strunzone(race_nextbestname);
1090                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1091                         break;
1092
1093                 case RACE_NET_CHECKPOINT_HIT_RACE:
1094                         race_mycheckpoint = ReadByte();
1095                         race_mycheckpointtime = time;
1096                         race_mycheckpointdelta = ReadInt24_t();
1097                         race_mycheckpointlapsdelta = ReadByte();
1098                         if(race_mycheckpointlapsdelta >= 128)
1099                                 race_mycheckpointlapsdelta -= 256;
1100                         if(race_mycheckpointenemy)
1101                                 strunzone(race_mycheckpointenemy);
1102                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1103                         break;
1104
1105                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1106                         race_othercheckpoint = ReadByte();
1107                         race_othercheckpointtime = time;
1108                         race_othercheckpointdelta = ReadInt24_t();
1109                         race_othercheckpointlapsdelta = ReadByte();
1110                         if(race_othercheckpointlapsdelta >= 128)
1111                                 race_othercheckpointlapsdelta -= 256;
1112                         if(race_othercheckpointenemy)
1113                                 strunzone(race_othercheckpointenemy);
1114                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1115                         break;
1116
1117                 case RACE_NET_PENALTY_RACE:
1118                         race_penaltyeventtime = time;
1119                         race_penaltytime = ReadShort();
1120                         //race_penaltyaccumulator += race_penaltytime;
1121                         if(race_penaltyreason)
1122                                 strunzone(race_penaltyreason);
1123                         race_penaltyreason = strzone(ReadString());
1124                         break;
1125
1126                 case RACE_NET_PENALTY_QUALIFYING:
1127                         race_penaltyeventtime = time;
1128                         race_penaltytime = ReadShort();
1129                         race_penaltyaccumulator += race_penaltytime;
1130                         if(race_penaltyreason)
1131                                 strunzone(race_penaltyreason);
1132                         race_penaltyreason = strzone(ReadString());
1133                         break;
1134
1135                 case RACE_NET_SERVER_RECORD:
1136                         race_server_record = ReadInt24_t();
1137                         break;
1138                 case RACE_NET_SPEED_AWARD:
1139                         race_speedaward = ReadInt24_t();
1140                         if(race_speedaward_holder)
1141                                 strunzone(race_speedaward_holder);
1142                         race_speedaward_holder = strzone(ReadString());
1143                         break;
1144                 case RACE_NET_SPEED_AWARD_BEST:
1145                         race_speedaward_alltimebest = ReadInt24_t();
1146                         if(race_speedaward_alltimebest_holder)
1147                                 strunzone(race_speedaward_alltimebest_holder);
1148                         race_speedaward_alltimebest_holder = strzone(ReadString());
1149                         break;
1150                 case RACE_NET_SERVER_RANKINGS:
1151                         float pos, prevpos, del;
1152                         pos = ReadShort();
1153                         prevpos = ReadShort();
1154                         del = ReadShort();
1155
1156                         // move other rankings out of the way
1157                         float i;
1158                         if (prevpos) {
1159                                 for (i=prevpos-1;i>pos-1;--i) {
1160                                         grecordtime[i] = grecordtime[i-1];
1161                                         if(grecordholder[i])
1162                                                 strunzone(grecordholder[i]);
1163                                         grecordholder[i] = strzone(grecordholder[i-1]);
1164                                 }
1165                         } else if (del) { // a record has been deleted by the admin
1166                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1167                                         if (i == RANKINGS_CNT-1) { // clear out last record
1168                                                 grecordtime[i] = 0;
1169                                                 if (grecordholder[i])
1170                                                         strunzone(grecordholder[i]);
1171                                                 grecordholder[i] = string_null;
1172                                         }
1173                                         else {
1174                                                 grecordtime[i] = grecordtime[i+1];
1175                                                 if (grecordholder[i])
1176                                                         strunzone(grecordholder[i]);
1177                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1178                                         }
1179                                 }
1180                         } else { // player has no ranked record yet
1181                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1182                                         grecordtime[i] = grecordtime[i-1];
1183                                         if(grecordholder[i])
1184                                                 strunzone(grecordholder[i]);
1185                                         grecordholder[i] = strzone(grecordholder[i-1]);
1186                                 }
1187                         }
1188
1189                         // store new ranking
1190                         if(grecordholder[pos-1] != "")
1191                                 strunzone(grecordholder[pos-1]);
1192                         grecordholder[pos-1] = strzone(ReadString());
1193                         grecordtime[pos-1] = ReadInt24_t();
1194                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1195                                 race_myrank = pos;
1196                         break;
1197                 case RACE_NET_SERVER_STATUS:
1198                         race_status = ReadShort();
1199                         if(race_status_name)
1200                                 strunzone(race_status_name);
1201                         race_status_name = strzone(ReadString());
1202         }
1203 }
1204
1205 void Net_ReadSpawn()
1206 {
1207         zoomin_effect = 1;
1208         current_viewzoom = 0.6;
1209 }
1210
1211 void Net_TeamNagger()
1212 {
1213         teamnagger = 1;
1214 }
1215
1216 void Net_ReadPingPLReport()
1217 {
1218         float e, pi, pl, ml;
1219         e = ReadByte();
1220         pi = ReadShort();
1221         pl = ReadByte();
1222         ml = ReadByte();
1223         if not(playerslots[e])
1224                 return;
1225         playerslots[e].ping = pi;
1226         playerslots[e].ping_packetloss = pl / 255.0;
1227         playerslots[e].ping_movementloss = ml / 255.0;
1228 }
1229
1230 void Net_VoteDialog(float highlight) {
1231         if(highlight) {
1232                 vote_highlighted = ReadShort();
1233                 return;
1234         }
1235
1236         vote_yescount = ReadShort();
1237         vote_nocount = ReadShort();
1238         vote_needed = ReadShort();
1239         vote_active = 1;
1240 }
1241
1242 void Net_VoteDialogReset() {
1243         vote_active = 0;
1244 }
1245
1246 void Net_Notify() {
1247         float type;
1248         type = ReadByte();
1249
1250         if(type == CSQC_KILLNOTIFY)
1251         {
1252                 HUD_KillNotify(ReadString(), ReadString(), ReadByte());
1253         }
1254         else if(type == CSQC_CENTERPRINT)
1255         {
1256                 HUD_Centerprint(ReadString(), ReadByte());
1257         }
1258 }
1259
1260 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1261 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1262 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1263 float CSQC_Parse_TempEntity()
1264 {
1265         local float bHandled;
1266                 bHandled  = true;
1267         // Acquire TE ID
1268         local float nTEID;
1269                 nTEID = ReadByte();
1270
1271                 // NOTE: Could just do return instead of break...
1272         switch(nTEID)
1273         {
1274                 case TE_CSQC_TARGET_MUSIC:
1275                         Net_TargetMusic();
1276                         bHandled = true;
1277                         break;
1278                 case TE_CSQC_PICTURE:
1279                         Net_MapVote_Picture();
1280                         bHandled = true;
1281                         break;
1282                 case TE_CSQC_RACE:
1283                         Net_ReadRace();
1284                         bHandled = true;
1285                         break;
1286                 case 13: // TE_BEAM
1287                         Net_GrapplingHook();
1288                         bHandled = true;
1289                         break;
1290                 case TE_CSQC_SPAWN:
1291                         Net_ReadSpawn();
1292                         bHandled = true;
1293                         break;
1294                 case TE_CSQC_ZCURVEPARTICLES:
1295                         Net_ReadZCurveParticles();
1296                         bHandled = true;
1297                         break;
1298                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1299                         Net_ReadNexgunBeamParticle();
1300                         bHandled = true;
1301                         break;
1302                 case TE_CSQC_TEAMNAGGER:
1303                         Net_TeamNagger();
1304                         bHandled = true;
1305                         break;
1306                 case TE_CSQC_VOTE:
1307                         Net_VoteDialog(ReadByte());
1308                         bHandled = true;
1309                         break;
1310                 case TE_CSQC_VOTERESET:
1311                         Net_VoteDialogReset();
1312                         bHandled = true;
1313                         break;
1314                 case TE_CSQC_LIGHTNINGARC:
1315                         Net_ReadLightningarc();
1316                         bHandled = true;
1317                         break;
1318                 case TE_CSQC_PINGPLREPORT:
1319                         Net_ReadPingPLReport();
1320                         bHandled = true;
1321                         break;
1322                 case TE_CSQC_ANNOUNCE:
1323                         announce_snd = strzone(ReadString());
1324                         bHandled = true;
1325                         break;
1326                 case TE_CSQC_NOTIFY:
1327                         Net_Notify();
1328                         bHandled = true;
1329                         break;
1330                 default:
1331                         // No special logic for this temporary entity; return 0 so the engine can handle it
1332                         bHandled = false;
1333                         break;
1334         }
1335
1336         return bHandled;
1337 }
1338
1339 string getcommandkey(string text, string command)
1340 {
1341         string keys;
1342         float n, j, k, l;
1343
1344         if (!hud_showbinds)
1345                 return text;
1346
1347         keys = db_get(binddb, command);
1348         if (!keys)
1349         {
1350                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1351                 for(j = 0; j < n; ++j)
1352                 {
1353                         k = stof(argv(j));
1354                         if(k != -1)
1355                         {
1356                                 if ("" == keys)
1357                                         keys = keynumtostring(k);
1358                                 else
1359                                         keys = strcat(keys, ", ", keynumtostring(k));
1360
1361                                 ++l;
1362                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1363                         }
1364
1365                 }
1366                 db_put(binddb, command, keys);
1367         }
1368
1369         if ("" == keys) {
1370                 if (hud_showbinds > 1)
1371                         return strcat(text, " (not bound)");
1372                 else
1373                         return text;
1374         }
1375         else if (hud_showbinds > 1)
1376                 return strcat(text, " (", keys, ")");
1377         else
1378                 return keys;
1379 }