fix & cleanup cl_vyes
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / Main.qc
1 // --------------------------------------------------------------------------
2 // BEGIN REQUIRED CSQC FUNCTIONS
3 //include "main.qh"
4
5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
6
7 void cvar_clientsettemp(string cv, string val)
8 {
9         entity e;
10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
11                 if(e.netname == cv)
12                         goto saved;
13         e = spawn();
14         e.classname = "saved_cvar_value";
15         e.netname = strzone(cv);
16         e.message = strzone(cvar_string(cv));
17 :saved
18         cvar_set(cv, val);
19 }
20
21 void cvar_clientsettemp_restore()
22 {
23         entity e;
24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
25                         cvar_set(e.netname, e.message);
26 }
27
28 void() menu_show_error =
29 {
30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
31 };
32
33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
34 // Useful for precaching things
35
36 void() menu_sub_null =
37 {
38 };
39
40 #ifdef USE_FTE
41 float __engine_check;
42 #endif
43
44 string forcefog;
45 string cl_announcer_prev;
46 void WaypointSprite_Load();
47 void CSQC_Init(void)
48 {
49 #ifdef USE_FTE
50 #pragma target ID
51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
52         if(!__engine_check)
53         {
54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
55                 localcmd("\ndisconnect\n");
56                 return;
57         }
58 #pragma target FTE
59 #endif
60         
61         check_unacceptable_compiler_bugs();
62
63 #ifdef WATERMARK
64         print("^4CSQC Build information: ", WATERMARK(), "\n");
65 #endif
66
67         float i;
68         CSQC_CheckEngine();
69
70         binddb = db_create();
71         tempdb = db_create();
72         ClientProgsDB = db_load("client.db");
73         compressShortVector_init();
74
75         drawfont = 0;
76         menu_visible = FALSE;
77         menu_show = menu_show_error;
78         menu_action = menu_sub_null;
79
80         for(i = 0; i < 255; ++i)
81                 if(getplayerkey(i, "viewentity") == "")
82                         break;
83         maxclients = i;
84
85         //ctf_temp_1 = "";
86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
87         //registercmd("ctf_menu");
88         registercmd("ons_map");
89         registercmd("hud_configure");
90         registercmd("hud_save");
91         //registercmd("menu_action");
92
93         registercmd("+button3");
94         registercmd("-button3");
95         registercmd("+button4");
96         registercmd("-button4");
97         registercmd("+showscores");registercmd("-showscores");
98         registercmd("+showaccuracy");registercmd("-showaccuracy");
99
100 #ifndef CAMERATEST
101         if(isdemo())
102         {
103 #endif
104                 registercmd("+forward");registercmd("-forward");
105                 registercmd("+back");registercmd("-back");
106                 registercmd("+moveup");registercmd("-moveup");
107                 registercmd("+movedown");registercmd("-movedown");
108                 registercmd("+moveright");registercmd("-moveright");
109                 registercmd("+moveleft");registercmd("-moveleft");
110                 registercmd("+roll_right");registercmd("-roll_right");
111                 registercmd("+roll_left");registercmd("-roll_left");
112 #ifndef CAMERATEST
113         }
114 #endif
115         registercvar("hud_usecsqc", "1");
116         registercvar("scoreboard_columns", "default", CVAR_SAVE);
117
118         gametype = 0;
119
120         // hud_fields uses strunzone on the titles!
121         for(i = 0; i < MAX_HUD_FIELDS; ++i)
122                 hud_title[i] = strzone("(null)");
123
124         postinit = false;
125
126         calledhooks = 0;
127
128         teams = Sort_Spawn();
129         players = Sort_Spawn();
130
131         GetTeam(COLOR_SPECTATOR, true); // add specs first
132
133         RegisterWeapons();
134
135         WaypointSprite_Load();
136
137         // precaches
138         Projectile_Precache();
139         Hook_Precache();
140         GibSplash_Precache();
141         Casings_Precache();
142         DamageInfo_Precache();
143         if(cvar_string("cl_announcer") != cl_announcer_prev) {
144                 Announcer_Precache();
145                 if(cl_announcer_prev)
146                         strunzone(cl_announcer_prev);
147                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
148         }
149         Tuba_Precache();
150
151         get_mi_min_max_texcoords(1); // try the CLEVER way first
152         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
153         shortmapname = mi_shortname;
154
155         if(precache_pic(minimapname) == "")
156         {
157                 // but maybe we have a non-clever minimap
158                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
159                 if(precache_pic(minimapname) == "")
160                         minimapname = ""; // FAIL
161                 else
162                         get_mi_min_max_texcoords(0); // load new texcoords
163         }
164
165         mi_center = (mi_min + mi_max) * 0.5;
166         mi_scale = mi_max - mi_min;
167         minimapname = strzone(minimapname);
168
169         WarpZone_Init();
170         hud_configure_prev = -1;
171 }
172
173 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
174 void CSQC_Shutdown(void)
175 {
176 #ifdef USE_FTE
177 #pragma TARGET id
178         if(!__engine_check)
179                 return 0;
180 #pragma TARGET fte
181 #endif
182
183         WarpZone_Shutdown();
184
185         remove(teams);
186         remove(players);
187         db_close(binddb);
188         db_close(tempdb);
189         if(cvar("cl_db_saveasdump"))
190                 db_dump(ClientProgsDB, "client.db");
191         else
192                 db_save(ClientProgsDB, "client.db");
193         db_close(ClientProgsDB);
194
195         cvar_clientsettemp_restore();
196
197         if(camera_active)
198                 cvar_set("chase_active",ftos(chase_active_backup));
199
200         if not(isdemo())
201         {
202                 if not(calledhooks & HOOK_START)
203                         localcmd("\n_cl_hook_gamestart nop\n");
204                 if not(calledhooks & HOOK_END)
205                         localcmd("\ncl_hook_gameend\n");
206         }
207 }
208
209 .float has_team;
210 float SetTeam(entity o, float Team)
211 {
212         entity tm;
213         if(teamplay)
214         {
215                 switch(Team)
216                 {
217                         case -1:
218                         case COLOR_TEAM1:
219                         case COLOR_TEAM2:
220                         case COLOR_TEAM3:
221                         case COLOR_TEAM4:
222                                 break;
223                         default:
224                                 if(GetTeam(Team, false) == NULL)
225                                 {
226                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
227                                         Team = COLOR_SPECTATOR;
228                                 }
229                                 break;
230                 }
231         }
232         else
233         {
234                 switch(Team)
235                 {
236                         case -1:
237                         case 0:
238                                 break;
239                         default:
240                                 if(GetTeam(Team, false) == NULL)
241                                 {
242                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
243                                         Team = COLOR_SPECTATOR;
244                                 }
245                                 break;
246                 }
247         }
248         if(Team == -1) // leave
249         {
250                 if(o.has_team)
251                 {
252                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
253                         tm = GetTeam(o.team, false);
254                         tm.team_size -= 1;
255                         o.has_team = 0;
256                         return TRUE;
257                 }
258         }
259         else
260         {
261                 if not(o.has_team)
262                 {
263                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
264                         o.team = Team;
265                         tm = GetTeam(Team, true);
266                         tm.team_size += 1;
267                         o.has_team = 1;
268                         return TRUE;
269                 }
270                 else if(Team != o.team)
271                 {
272                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
273                         tm = GetTeam(o.team, false);
274                         tm.team_size -= 1;
275                         o.team = Team;
276                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
277                         tm = GetTeam(Team, true);
278                         tm.team_size += 1;
279                         return TRUE;
280                 }
281         }
282         return FALSE;
283 }
284
285 void Playerchecker_Think()
286 {
287         float i;
288         entity e;
289         for(i = 0; i < maxclients; ++i)
290         {
291                 e = playerslots[i];
292                 if(GetPlayerName(i) == "")
293                 {
294                         if(e.sort_prev)
295                         {
296                                 //print("playerchecker: KILL KILL KILL\n");
297                                 // player disconnected
298                                 SetTeam(e, -1);
299                                 RemovePlayer(e);
300                                 e.sort_prev = world;
301                                 //e.gotscores = 0;
302                         }
303                 }
304                 else
305                 {
306                         if not(e.sort_prev)
307                         {
308                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
309                                 // player connected
310                                 if not(e)
311                                         playerslots[i] = e = spawn();
312                                 e.sv_entnum = i;
313                                 e.ping = 0;
314                                 e.ping_packetloss = 0;
315                                 e.ping_movementloss = 0;
316                                 //e.gotscores = 0; // we might already have the scores...
317                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
318                                 RegisterPlayer(e);
319                                 HUD_UpdatePlayerPos(e);
320                         }
321                 }
322         }
323         self.nextthink = time + 0.2;
324 }
325
326 void Porto_Init();
327 void TrueAim_Init();
328 void PostInit(void)
329 {
330         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
331         localcmd(strcat("\nscoreboard_columns_set ", cvar_string("scoreboard_columns"), ";\n"));
332
333         entity playerchecker;
334         playerchecker = spawn();
335         playerchecker.think = Playerchecker_Think;
336         playerchecker.nextthink = time + 0.2;
337
338         Porto_Init();
339         TrueAim_Init();
340
341         postinit = true;
342 }
343
344 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
345 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
346 float button_zoom;
347 void Cmd_HUD_SetFields(float);
348 void Cmd_HUD_Help(float);
349 float CSQC_ConsoleCommand(string strMessage)
350 {
351         float argc;
352         // Tokenize String
353         //argc = tokenize(strMessage);
354         argc = tokenize_console(strMessage);
355
356         // Acquire Command
357         local string strCmd;
358         strCmd = argv(0);
359
360         if(strCmd == "hud_configure") { // config hud
361                 cvar_set("_hud_configure", ftos(!cvar("_hud_configure")));
362                 return true;
363         } else if(strCmd == "hud_save") { // save hud config
364                 if(argv(1) == "" || argv(2)) {
365                         print("Usage:\n");
366                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
367                 }
368                 else
369                         HUD_Panel_ExportCfg(argv(1));
370                 return true;
371         } else if(strCmd == "+button4") { // zoom
372                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
373                 if(ignore_plus_zoom)
374                 {
375                         --ignore_plus_zoom;
376                         return false;
377                 }
378                 button_zoom = 1;
379                 return true;
380         } else if(strCmd == "-button4") { // zoom
381                 if(ignore_minus_zoom)
382                 {
383                         --ignore_minus_zoom;
384                         return false;
385                 }
386                 button_zoom = 0;
387                 return true;
388         } else if(strCmd == "+button3") { // secondary
389                 button_attack2 = 1;
390                 return false;
391         } else if(strCmd == "-button3") { // secondary
392                 button_attack2 = 0;
393                 return false;
394         } else if(strCmd == "+showscores") {
395                 scoreboard_showscores = true;
396                 return true;
397         } else if(strCmd == "-showscores") {
398                 scoreboard_showscores = false;
399                 return true;
400         } else if(strCmd == "+showaccuracy") {
401                 scoreboard_showaccuracy = true;
402                 return true;
403         } else if(strCmd == "-showaccuracy") {
404                 scoreboard_showaccuracy = false;
405                 return true;
406         }
407
408         if(camera_active)
409         if(strCmd == "+forward" || strCmd == "-back") {
410                 ++camera_direction_x;
411                 return true;
412         } else if(strCmd == "-forward" || strCmd == "+back") {
413                 --camera_direction_x;
414                 return true;
415         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
416                 --camera_direction_y;
417                 return true;
418         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
419                 ++camera_direction_y;
420                 return true;
421         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
422                 ++camera_direction_z;
423                 return true;
424         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
425                 --camera_direction_z;
426                 return true;
427         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
428                 ++camera_roll;
429                 return true;
430         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
431                 --camera_roll;
432                 return true;
433         }
434
435         return false;
436 }
437
438 .vector view_ofs;
439 entity debug_shotorg;
440 void ShotOrg_Draw()
441 {
442         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
443         self.angles = view_angles;
444         self.angles_x = -self.angles_x;
445         if not(self.cnt)
446                 self.drawmask = MASK_NORMAL;
447         else
448                 self.drawmask = 0;
449 }
450 void ShotOrg_Draw2D()
451 {
452         vector coord2d_topleft, coord2d_topright, coord2d;
453         string s;
454         vector fs;
455
456         s = vtos(self.view_ofs);
457         s = substring(s, 1, strlen(s) - 2);
458         if(tokenize_console(s) == 3)
459                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
460
461         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
462         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
463
464         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
465
466         coord2d = coord2d_topleft;
467         if(fs_x < 8)
468         {
469                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
470                 fs = '8 8 0';
471         }
472         coord2d_y -= fs_y;
473         coord2d_z = 0;
474         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
475 }
476
477 void ShotOrg_Spawn()
478 {
479         debug_shotorg = spawn();
480         debug_shotorg.draw = ShotOrg_Draw;
481         debug_shotorg.draw2d = ShotOrg_Draw2D;
482         debug_shotorg.renderflags = RF_VIEWMODEL;
483         debug_shotorg.effects = EF_FULLBRIGHT;
484         precache_model("models/shotorg_adjuster.md3");
485         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
486         debug_shotorg.scale = 2;
487         debug_shotorg.view_ofs = '25 8 -8';
488 }
489
490 void DrawDebugModel()
491 {
492         if(time - floor(time) > 0.5)
493         {
494                 PolyDrawModel(self);
495                 self.drawmask = 0;
496         }
497         else
498         {
499                 self.renderflags = 0;
500                 self.drawmask = MASK_NORMAL;
501         }
502 }
503
504 void GameCommand(string msg)
505 {
506         string s;
507         float argc;
508         entity e;
509         argc = tokenize_console(msg);
510
511         if(argv(0) == "help" || argc == 0)
512         {
513                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
514                 print("  settemp cvar value\n");
515                 print("  scoreboard_columns_set ...\n");
516                 print("  scoreboard_columns_help\n");
517                 GameCommand_Generic("help");
518                 return;
519         }
520
521         if(GameCommand_Generic(msg))
522                 return;
523
524         string cmd;
525         cmd = argv(0);
526         if(cmd == "mv_download") {
527                 Cmd_MapVote_MapDownload(argc);
528         }
529         else if(cmd == "settemp") {
530                 cvar_clientsettemp(argv(1), argv(2));
531         }
532         else if(cmd == "scoreboard_columns_set") {
533                 Cmd_HUD_SetFields(argc);
534         }
535         else if(cmd == "scoreboard_columns_help") {
536                 Cmd_HUD_Help(argc);
537         }
538 #ifdef BLURTEST
539         else if(cmd == "blurtest") {
540                 blurtest_time0 = time;
541                 blurtest_time1 = time + stof(argv(1));
542                 blurtest_radius = stof(argv(2));
543                 blurtest_power = stof(argv(3));
544         }
545 #endif
546         else if(cmd == "shotorg_move") {
547                 if(!debug_shotorg)
548                         ShotOrg_Spawn();
549                 else
550                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
551                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
552         }
553         else if(cmd == "shotorg_movez") {
554                 if(!debug_shotorg)
555                         ShotOrg_Spawn();
556                 else
557                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
558                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
559         }
560         else if(cmd == "shotorg_set") {
561                 if(!debug_shotorg)
562                         ShotOrg_Spawn();
563                 else
564                         debug_shotorg.view_ofs = stov(argv(1));
565                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
566         }
567         else if(cmd == "shotorg_setz") {
568                 if(!debug_shotorg)
569                         ShotOrg_Spawn();
570                 else
571                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
572                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
573         }
574         else if(cmd == "shotorg_toggle_hide") {
575                 if(debug_shotorg)
576                 {
577                         debug_shotorg.cnt = !debug_shotorg.cnt;
578                 }
579         }
580         else if(cmd == "shotorg_end") {
581                 if(debug_shotorg)
582                 {
583                         print(vtos(debug_shotorg.view_ofs), "\n");
584                         remove(debug_shotorg);
585                         debug_shotorg = world;
586                 }
587                 localcmd("sv_cmd debug_shotorg\n");
588         }
589         else if(cmd == "sendcvar") {
590                 // W_FixWeaponOrder will trash argv, so save what we need.
591                 string thiscvar;
592                 thiscvar = strzone(argv(1));
593                 s = cvar_string(thiscvar);
594                 if(thiscvar == "cl_weaponpriority")
595                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
596                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
597                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
598                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
599                 strunzone(thiscvar);
600         }
601         else if(cmd == "spawn") {
602                 s = argv(1);
603                 e = spawn();
604                 precache_model(s);
605                 setmodel(e, s);
606                 setorigin(e, view_origin);
607                 e.angles = view_angles;
608                 e.draw = DrawDebugModel;
609                 e.classname = "debugmodel";
610         }
611     else if(cmd == "vyes")
612     {
613         if(uid2name_dialog)
614         {
615             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
616             vote_prev = 0;
617             cvar_set("cl_allow_uid2name", "1");
618             vote_change = -9999;
619         }
620         else
621         {
622             localcmd("vyes\n");
623         }
624     }
625     else if(cmd == "vno")
626     {
627         if(uid2name_dialog)
628         {
629             vote_active = 0;
630             vote_prev = 0;
631             cvar_set("cl_allow_uid2name", "0");
632             vote_change = -9999;
633         }
634         else
635         {
636             localcmd("vno\n");
637         }
638     }
639
640         else
641         {
642                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
643         }
644
645         return;
646 }
647
648 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
649 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
650 // All keys are in ascii.
651 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
652 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
653 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
654 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
655 {
656         local float bSkipKey;
657         bSkipKey = false;
658
659         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
660                 return true;
661
662         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
663                 return true;
664
665         if(menu_visible)
666                 if(menu_action(bInputType, nPrimary, nSecondary))
667                         return TRUE;
668
669         return bSkipKey;
670 }
671
672 // END REQUIRED CSQC FUNCTIONS
673 // --------------------------------------------------------------------------
674
675 // --------------------------------------------------------------------------
676 // BEGIN OPTIONAL CSQC FUNCTIONS
677 void Ent_ReadEntCS()
678 {
679         InterpolateOrigin_Undo();
680
681         self.classname = "entcs_receiver";
682         self.sv_entnum = ReadByte() - 1;
683         self.origin_x = ReadShort();
684         self.origin_y = ReadShort();
685         self.origin_z = ReadShort();
686         self.angles_y = ReadByte() * 360.0 / 256;
687         self.origin_z = self.angles_x = self.angles_z = 0;
688
689         InterpolateOrigin_Note();
690 }
691
692 void Ent_Remove();
693
694 void Ent_RemovePlayerScore()
695 {
696         float i;
697
698         if(self.owner)
699         {
700                 SetTeam(self.owner, -1);
701                 self.owner.gotscores = 0;
702                 for(i = 0; i < MAX_SCORE; ++i)
703                         self.owner.(scores[i]) = 0; // clear all scores
704         }
705 }
706
707 void Ent_ReadPlayerScore()
708 {
709         float i, n;
710         float isNew;
711         entity o;
712
713         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
714         // (no I've never heard of M-x replace-string, sed, or anything like that)
715         isNew = !self.owner; // workaround for DP bug
716         n = ReadByte()-1;
717
718 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
719         if(!isNew && n != self.sv_entnum)
720         {
721                 print("A CSQC entity changed its owner!\n");
722                 isNew = true;
723                 Ent_Remove();
724                 self.enttype = ENT_CLIENT_SCORES;
725         }
726 #endif
727
728         self.sv_entnum = n;
729
730         if not(playerslots[self.sv_entnum])
731                 playerslots[self.sv_entnum] = spawn();
732         o = self.owner = playerslots[self.sv_entnum];
733         o.sv_entnum = self.sv_entnum;
734         o.gotscores = 1;
735
736         //if not(o.sort_prev)
737         //      RegisterPlayer(o);
738         //playerchecker will do this for us later, if it has not already done so
739
740         float sf, lf;
741 #if MAX_SCORE <= 8
742         sf = ReadByte();
743         lf = ReadByte();
744 #else
745         sf = ReadShort();
746         lf = ReadShort();
747 #endif
748         float p;
749         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
750                 if(sf & p)
751                 {
752                         if(lf & p)
753                                 o.(scores[i]) = ReadInt24_t();
754                         else
755                                 o.(scores[i]) = ReadChar();
756                 }
757
758         if(o.sort_prev)
759                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
760
761         self.entremove = Ent_RemovePlayerScore;
762 }
763
764 void Ent_ReadTeamScore()
765 {
766         float i;
767         entity o;
768
769         self.team = ReadByte();
770         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
771
772         float sf, lf;
773 #if MAX_TEAMSCORE <= 8
774         sf = ReadByte();
775         lf = ReadByte();
776 #else
777         sf = ReadShort();
778         lf = ReadShort();
779 #endif
780         float p;
781         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
782                 if(sf & p)
783                 {
784                         if(lf & p)
785                                 o.(teamscores[i]) = ReadInt24_t();
786                         else
787                                 o.(teamscores[i]) = ReadChar();
788                 }
789
790         HUD_UpdateTeamPos(o);
791 }
792
793 void Net_Reset()
794 {
795 }
796
797 void Ent_ClientData()
798 {
799         float f;
800         float newspectatee_status;
801
802         f = ReadByte();
803
804         scoreboard_showscores_force = (f & 1);
805
806         if(f & 2)
807         {
808                 newspectatee_status = ReadByte();
809                 if(newspectatee_status == player_localentnum)
810                         newspectatee_status = -1; // observing
811         }
812         else
813                 newspectatee_status = 0;
814
815         spectatorbutton_zoom = (f & 4);
816
817         if(f & 8)
818         {
819                 angles_held_status = 1;
820                 angles_held_x = ReadAngle();
821                 angles_held_y = ReadAngle();
822                 angles_held_z = 0;
823         }
824         else
825                 angles_held_status = 0;
826
827         if(newspectatee_status != spectatee_status)
828         {
829                 float i;
830                 // clear the weapon accuracy stats
831                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
832                         weapon_hits[i] = 0;
833                         weapon_fired[i] = 0;
834                 }
835
836                 // clear race stuff
837                 race_laptime = 0;
838                 race_checkpointtime = 0;
839         }
840         spectatee_status = newspectatee_status;
841 }
842
843 void Ent_Nagger()
844 {
845         float nags, i, j, b, f;
846
847         nags = ReadByte();
848
849         if(nags & 128)
850         {
851                 if(vote_called_vote)
852                         strunzone(vote_called_vote);
853                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
854         }
855
856         if(nags & 1)
857         {
858                 for(j = 0; j < maxclients; ++j)
859                         if(playerslots[j])
860                                 playerslots[j].ready = 1;
861                 for(i = 1; i <= maxclients; i += 8)
862                 {
863                         f = ReadByte();
864                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
865                                 if not(f & b)
866                                         if(playerslots[j])
867                                                 playerslots[j].ready = 0;
868                 }
869         }
870
871         ready_waiting = (nags & 1);
872         ready_waiting_for_me = (nags & 2);
873         vote_waiting = (nags & 4);
874         vote_waiting_for_me = (nags & 8);
875         warmup_stage = (nags & 16);
876 }
877
878 void Ent_RandomSeed()
879 {
880         float s;
881         prandom_debug();
882         s = ReadShort();
883         psrandom(s);
884 }
885
886 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
887 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
888 void Ent_RadarLink();
889 void Ent_Init();
890 void Ent_ScoresInfo();
891 void(float bIsNewEntity) CSQC_Ent_Update =
892 {
893         float t;
894         float savetime;
895         t = ReadByte();
896
897         // set up the "time" global for received entities to be correct for interpolation purposes
898         savetime = time;
899         if(servertime)
900         {
901                 time = servertime;
902         }
903         else
904         {
905                 serverprevtime = time;
906                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
907                 time = serverprevtime + serverdeltatime;
908         }
909
910 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
911         if(self.enttype)
912                 if(t != self.enttype)
913                 {
914                         print("A CSQC entity changed its type!\n");
915                         Ent_Remove();
916                         bIsNewEntity = 1;
917                 }
918 #endif
919         self.enttype = t;
920         switch(t)
921         {
922                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
923                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
924                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
925                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
926                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
927                 case ENT_CLIENT_LASER: Ent_Laser(); break;
928                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
929                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
930                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
931                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
932                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
933                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
934                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
935                 case ENT_CLIENT_INIT: Ent_Init(); break;
936                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
937                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
938                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
939                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
940                 case ENT_CLIENT_WALL: Ent_Wall(); break;
941                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
942                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
943                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
944                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
945                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
946                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
947                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
948                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
949                 default:
950                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
951                         break;
952         }
953
954         time = savetime;
955 };
956 // Destructor, but does NOT deallocate the entity by calling remove(). Also
957 // used when an entity changes its type. For an entity that someone interacts
958 // with others, make sure it can no longer do so.
959 void Ent_Remove()
960 {
961         if(self.entremove)
962                 self.entremove();
963
964         self.enttype = 0;
965         self.classname = "";
966         self.draw = menu_sub_null;
967         self.entremove = menu_sub_null;
968         // TODO possibly set more stuff to defaults
969 }
970 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
971 void CSQC_Ent_Remove()
972 {
973         if(self.enttype)
974                 Ent_Remove();
975         remove(self);
976 }
977
978 void Gamemode_Init()
979 {
980         if(gametype == GAME_ONSLAUGHT) {
981                 print(strcat("Using ", minimapname, " as minimap.\n"));
982                 precache_pic("gfx/ons-cp-neutral.tga");
983                 precache_pic("gfx/ons-cp-red.tga");
984                 precache_pic("gfx/ons-cp-blue.tga");
985                 precache_pic("gfx/ons-frame.tga");
986                 precache_pic("gfx/ons-frame-team.tga");
987         }
988
989         if not(isdemo())
990         {
991                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
992                 calledhooks |= HOOK_START;
993         }
994 }
995 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
996 void CSQC_Parse_StuffCmd(string strMessage)
997 {
998         localcmd(strMessage);
999 }
1000 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1001 void CSQC_Parse_Print(string strMessage)
1002 {
1003         print(ColorTranslateRGB(strMessage));
1004 }
1005
1006 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1007 void CSQC_Parse_CenterPrint(string strMessage)
1008 {
1009         centerprint(strMessage);
1010 }
1011
1012 string notranslate_fogcmd1 = "\nfog ";
1013 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1014 void Fog_Force()
1015 {
1016         // TODO somehow thwart prvm_globalset client ...
1017
1018         if(forcefog != "")
1019                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1020 }
1021
1022 void Gamemode_Init();
1023 void Ent_ScoresInfo()
1024 {
1025         float i;
1026         self.classname = "ent_client_scores_info";
1027         gametype = ReadByte();
1028         for(i = 0; i < MAX_SCORE; ++i)
1029         {
1030                 scores_label[i] = strzone(ReadString());
1031                 scores_flags[i] = ReadByte();
1032         }
1033         for(i = 0; i < MAX_TEAMSCORE; ++i)
1034         {
1035                 teamscores_label[i] = strzone(ReadString());
1036                 teamscores_flags[i] = ReadByte();
1037         }
1038         HUD_InitScores();
1039         Gamemode_Init();
1040 }
1041
1042 void Ent_Init()
1043 {
1044         self.classname = "ent_client_init";
1045
1046         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1047
1048         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1049         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1050         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1051         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1052         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1053         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1054         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1055         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1056         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1057         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1058         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1059         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1060
1061         if(forcefog)
1062                 strunzone(forcefog);
1063         forcefog = strzone(ReadString());
1064
1065         armorblockpercent = ReadByte() / 255.0;
1066
1067         g_weaponswitchdelay = ReadByte() / 255.0;
1068
1069         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1070         g_balance_grenadelauncher_bouncestop = ReadCoord();
1071         g_balance_electro_secondary_bouncefactor = ReadCoord();
1072         g_balance_electro_secondary_bouncestop = ReadCoord();
1073
1074         nex_scope = !ReadByte();
1075         campingrifle_scope = !ReadByte();
1076
1077         serverflags = ReadByte();
1078
1079         if(!postinit)
1080                 PostInit();
1081 }
1082
1083 void Net_ReadRace()
1084 {
1085         float b;
1086
1087         b = ReadByte();
1088
1089         switch(b)
1090         {
1091                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1092                         race_checkpoint = ReadByte();
1093                         race_time = ReadInt24_t();
1094                         race_previousbesttime = ReadInt24_t();
1095                         if(race_previousbestname)
1096                                 strunzone(race_previousbestname);
1097                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1098
1099                         race_checkpointtime = time;
1100
1101                         if(race_checkpoint == 0 || race_checkpoint == 254)
1102                         {
1103                                 race_penaltyaccumulator = 0;
1104                                 race_laptime = time; // valid
1105                         }
1106
1107                         break;
1108
1109                 case RACE_NET_CHECKPOINT_CLEAR:
1110                         race_laptime = 0;
1111                         race_checkpointtime = 0;
1112                         break;
1113
1114                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1115                         race_laptime = ReadCoord();
1116                         race_checkpointtime = -99999;
1117                         // fall through
1118                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1119                         race_nextcheckpoint = ReadByte();
1120
1121                         race_nextbesttime = ReadInt24_t();
1122                         if(race_nextbestname)
1123                                 strunzone(race_nextbestname);
1124                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1125                         break;
1126
1127                 case RACE_NET_CHECKPOINT_HIT_RACE:
1128                         race_mycheckpoint = ReadByte();
1129                         race_mycheckpointtime = time;
1130                         race_mycheckpointdelta = ReadInt24_t();
1131                         race_mycheckpointlapsdelta = ReadByte();
1132                         if(race_mycheckpointlapsdelta >= 128)
1133                                 race_mycheckpointlapsdelta -= 256;
1134                         if(race_mycheckpointenemy)
1135                                 strunzone(race_mycheckpointenemy);
1136                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1137                         break;
1138
1139                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1140                         race_othercheckpoint = ReadByte();
1141                         race_othercheckpointtime = time;
1142                         race_othercheckpointdelta = ReadInt24_t();
1143                         race_othercheckpointlapsdelta = ReadByte();
1144                         if(race_othercheckpointlapsdelta >= 128)
1145                                 race_othercheckpointlapsdelta -= 256;
1146                         if(race_othercheckpointenemy)
1147                                 strunzone(race_othercheckpointenemy);
1148                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1149                         break;
1150
1151                 case RACE_NET_PENALTY_RACE:
1152                         race_penaltyeventtime = time;
1153                         race_penaltytime = ReadShort();
1154                         //race_penaltyaccumulator += race_penaltytime;
1155                         if(race_penaltyreason)
1156                                 strunzone(race_penaltyreason);
1157                         race_penaltyreason = strzone(ReadString());
1158                         break;
1159
1160                 case RACE_NET_PENALTY_QUALIFYING:
1161                         race_penaltyeventtime = time;
1162                         race_penaltytime = ReadShort();
1163                         race_penaltyaccumulator += race_penaltytime;
1164                         if(race_penaltyreason)
1165                                 strunzone(race_penaltyreason);
1166                         race_penaltyreason = strzone(ReadString());
1167                         break;
1168
1169                 case RACE_NET_SERVER_RECORD:
1170                         race_server_record = ReadInt24_t();
1171                         break;
1172                 case RACE_NET_SPEED_AWARD:
1173                         race_speedaward = ReadInt24_t();
1174                         if(race_speedaward_holder)
1175                                 strunzone(race_speedaward_holder);
1176                         race_speedaward_holder = strzone(ReadString());
1177                         break;
1178                 case RACE_NET_SPEED_AWARD_BEST:
1179                         race_speedaward_alltimebest = ReadInt24_t();
1180                         if(race_speedaward_alltimebest_holder)
1181                                 strunzone(race_speedaward_alltimebest_holder);
1182                         race_speedaward_alltimebest_holder = strzone(ReadString());
1183                         break;
1184                 case RACE_NET_SERVER_RANKINGS:
1185                         float pos, prevpos, del;
1186                         pos = ReadShort();
1187                         prevpos = ReadShort();
1188                         del = ReadShort();
1189
1190                         // move other rankings out of the way
1191                         float i;
1192                         if (prevpos) {
1193                                 for (i=prevpos-1;i>pos-1;--i) {
1194                                         grecordtime[i] = grecordtime[i-1];
1195                                         if(grecordholder[i])
1196                                                 strunzone(grecordholder[i]);
1197                                         grecordholder[i] = strzone(grecordholder[i-1]);
1198                                 }
1199                         } else if (del) { // a record has been deleted by the admin
1200                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1201                                         if (i == RANKINGS_CNT-1) { // clear out last record
1202                                                 grecordtime[i] = 0;
1203                                                 if (grecordholder[i])
1204                                                         strunzone(grecordholder[i]);
1205                                                 grecordholder[i] = string_null;
1206                                         }
1207                                         else {
1208                                                 grecordtime[i] = grecordtime[i+1];
1209                                                 if (grecordholder[i])
1210                                                         strunzone(grecordholder[i]);
1211                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1212                                         }
1213                                 }
1214                         } else { // player has no ranked record yet
1215                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1216                                         grecordtime[i] = grecordtime[i-1];
1217                                         if(grecordholder[i])
1218                                                 strunzone(grecordholder[i]);
1219                                         grecordholder[i] = strzone(grecordholder[i-1]);
1220                                 }
1221                         }
1222
1223                         // store new ranking
1224                         if(grecordholder[pos-1] != "")
1225                                 strunzone(grecordholder[pos-1]);
1226                         grecordholder[pos-1] = strzone(ReadString());
1227                         grecordtime[pos-1] = ReadInt24_t();
1228                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1229                                 race_myrank = pos;
1230                         break;
1231                 case RACE_NET_SERVER_STATUS:
1232                         race_status = ReadShort();
1233                         if(race_status_name)
1234                                 strunzone(race_status_name);
1235                         race_status_name = strzone(ReadString());
1236         }
1237 }
1238
1239 void Net_ReadSpawn()
1240 {
1241         zoomin_effect = 1;
1242         current_viewzoom = 0.6;
1243 }
1244
1245 void Net_TeamNagger()
1246 {
1247         teamnagger = 1;
1248 }
1249
1250 void Net_ReadPingPLReport()
1251 {
1252         float e, pi, pl, ml;
1253         e = ReadByte();
1254         pi = ReadShort();
1255         pl = ReadByte();
1256         ml = ReadByte();
1257         if not(playerslots[e])
1258                 return;
1259         playerslots[e].ping = pi;
1260         playerslots[e].ping_packetloss = pl / 255.0;
1261         playerslots[e].ping_movementloss = ml / 255.0;
1262 }
1263
1264 void Net_VoteDialog(float highlight) {
1265         if(highlight) {
1266                 vote_highlighted = ReadByte();
1267                 return;
1268         }
1269
1270         vote_yescount = ReadByte();
1271         vote_nocount = ReadByte();
1272         vote_needed = ReadByte();
1273         vote_active = 1;
1274 }
1275
1276 void Net_VoteDialogReset() {
1277         vote_active = 0;
1278 }
1279
1280 void Net_Notify() {
1281         float type;
1282         type = ReadByte();
1283
1284         if(type == CSQC_KILLNOTIFY)
1285         {
1286                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1287         }
1288         else if(type == CSQC_CENTERPRINT)
1289         {
1290                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1291         }
1292 }
1293
1294 void Net_WeaponComplain() {
1295         complain_weapon = ReadByte();
1296
1297         if(complain_weapon_name)
1298                 strunzone(complain_weapon_name);
1299         complain_weapon_name = strzone(ReadString());
1300
1301         complain_weapon_type = ReadByte();
1302
1303         complain_weapon_time = time;
1304         weapontime = time; // ping the weapon panel
1305 }
1306
1307 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1308 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1309 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1310 float CSQC_Parse_TempEntity()
1311 {
1312         local float bHandled;
1313                 bHandled  = true;
1314         // Acquire TE ID
1315         local float nTEID;
1316                 nTEID = ReadByte();
1317
1318                 // NOTE: Could just do return instead of break...
1319         switch(nTEID)
1320         {
1321                 case TE_CSQC_TARGET_MUSIC:
1322                         Net_TargetMusic();
1323                         bHandled = true;
1324                         break;
1325                 case TE_CSQC_PICTURE:
1326                         Net_MapVote_Picture();
1327                         bHandled = true;
1328                         break;
1329                 case TE_CSQC_RACE:
1330                         Net_ReadRace();
1331                         bHandled = true;
1332                         break;
1333                 case TE_CSQC_SPAWN:
1334                         Net_ReadSpawn();
1335                         bHandled = true;
1336                         break;
1337                 case TE_CSQC_ZCURVEPARTICLES:
1338                         Net_ReadZCurveParticles();
1339                         bHandled = true;
1340                         break;
1341                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1342                         Net_ReadNexgunBeamParticle();
1343                         bHandled = true;
1344                         break;
1345                 case TE_CSQC_TEAMNAGGER:
1346                         Net_TeamNagger();
1347                         bHandled = true;
1348                         break;
1349                 case TE_CSQC_VOTE:
1350                         Net_VoteDialog(ReadByte());
1351                         bHandled = true;
1352                         break;
1353                 case TE_CSQC_VOTERESET:
1354                         Net_VoteDialogReset();
1355                         bHandled = true;
1356                         break;
1357                 case TE_CSQC_LIGHTNINGARC:
1358                         Net_ReadLightningarc();
1359                         bHandled = true;
1360                         break;
1361                 case TE_CSQC_PINGPLREPORT:
1362                         Net_ReadPingPLReport();
1363                         bHandled = true;
1364                         break;
1365                 case TE_CSQC_ANNOUNCE:
1366                         announce_snd = strzone(ReadString());
1367                         bHandled = true;
1368                         break;
1369                 case TE_CSQC_NOTIFY:
1370                         Net_Notify();
1371                         bHandled = true;
1372                         break;
1373                 case TE_CSQC_WEAPONCOMPLAIN:
1374                         Net_WeaponComplain();
1375                         bHandled = true;
1376                         break;
1377                 case TE_CSQC_CR_MAXBULLETS:
1378                         cr_maxbullets = ReadByte();
1379                         bHandled = true;
1380                         break;
1381                 default:
1382                         // No special logic for this temporary entity; return 0 so the engine can handle it
1383                         bHandled = false;
1384                         break;
1385         }
1386
1387         return bHandled;
1388 }
1389
1390 string getcommandkey(string text, string command)
1391 {
1392         string keys;
1393         float n, j, k, l;
1394
1395         if (!hud_showbinds)
1396                 return text;
1397
1398         keys = db_get(binddb, command);
1399         if (!keys)
1400         {
1401                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1402                 for(j = 0; j < n; ++j)
1403                 {
1404                         k = stof(argv(j));
1405                         if(k != -1)
1406                         {
1407                                 if ("" == keys)
1408                                         keys = keynumtostring(k);
1409                                 else
1410                                         keys = strcat(keys, ", ", keynumtostring(k));
1411
1412                                 ++l;
1413                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1414                         }
1415
1416                 }
1417                 db_put(binddb, command, keys);
1418         }
1419
1420         if ("" == keys) {
1421                 if (hud_showbinds > 1)
1422                         return strcat(text, " (not bound)");
1423                 else
1424                         return text;
1425         }
1426         else if (hud_showbinds > 1)
1427                 return strcat(text, " (", keys, ")");
1428         else
1429                 return keys;
1430 }