qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if (!clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 string forcefog;
  36 void WaypointSprite_Load();
  37 void ConsoleCommand_macro_init();
  38 void CSQC_Init(void)
  39 {
  40         prvm_language = cvar_string("prvm_language");
  41 #ifdef USE_FTE
  42 #pragma target ID
  43         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  44         if(!__engine_check)
  45         {
  46                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  47                 localcmd("\ndisconnect\n");
  48                 return;
  49         }
  50 #pragma target FTE
  51 #endif
  52
  53         check_unacceptable_compiler_bugs();
  54
  55 #ifdef WATERMARK
  56         printf(_("^4CSQC Build information: ^1%s\n"), WATERMARK);
  57 #endif
  58
  59         float i;
  60
  61 #ifdef COMPAT_XON050_ENGINE
  62         // old engine lacks implementation of player_localnum
  63         player_localnum = player_localentnum - 1;
  64 #endif
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         draw_endBoldFont();
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = func_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkeyvalue(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //registercommand("hud_configure");
  82         //registercommand("hud_save");
  83         //registercommand("menu_action");
  84
  85         ConsoleCommand_macro_init();
  86
  87         registercvar("hud_usecsqc", "1");
  88         registercvar("scoreboard_columns", "default");
  89
  90         gametype = 0;
  91
  92         // hud_fields uses strunzone on the titles!
  93         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  94                 hud_title[i] = strzone("(null)");
  95
  96         postinit = false;
  97
  98         calledhooks = 0;
  99
 100         teams = Sort_Spawn();
 101         players = Sort_Spawn();
 102
 103         GetTeam(NUM_SPECTATOR, true); // add specs first
 104
 105         // needs to be done so early because of the constants they create
 106         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 107         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 108         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 109         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 110         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 111         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 112         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 113
 114         WaypointSprite_Load();
 115
 116         // precaches
 117         precache_model("null");
 118         precache_sound("misc/hit.wav");
 119         precache_sound("misc/typehit.wav");
 120
 121         Projectile_Precache();
 122         Hook_Precache();
 123         GibSplash_Precache();
 124         Casings_Precache();
 125         DamageInfo_Precache();
 126         Vehicles_Precache();
 127         turrets_precache();
 128         Tuba_Precache();
 129         CSQCPlayer_Precache();
 130
 131         if(autocvar_cl_reticle)
 132         {
 133                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 134                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 135         }
 136
 137         get_mi_min_max_texcoords(1); // try the CLEVER way first
 138         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 139         shortmapname = mi_shortname;
 140
 141         if(precache_pic(minimapname) == "")
 142         {
 143                 // but maybe we have a non-clever minimap
 144                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 145                 if(precache_pic(minimapname) == "")
 146                         minimapname = ""; // FAIL
 147                 else
 148                         get_mi_min_max_texcoords(0); // load new texcoords
 149         }
 150
 151         mi_center = (mi_min + mi_max) * 0.5;
 152         mi_scale = mi_max - mi_min;
 153         minimapname = strzone(minimapname);
 154
 155         WarpZone_Init();
 156
 157         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 158         hud_configure_prev = -1;
 159
 160         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 161 }
 162
 163 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 164 void Shutdown(void)
 165 {
 166 #ifdef USE_FTE
 167 #pragma TARGET id
 168         if(!__engine_check)
 169                 return 0;
 170 #pragma TARGET fte
 171 #endif
 172
 173         WarpZone_Shutdown();
 174
 175         remove(teams);
 176         remove(players);
 177         db_close(binddb);
 178         db_close(tempdb);
 179         if(autocvar_cl_db_saveasdump)
 180                 db_dump(ClientProgsDB, "client.db");
 181         else
 182                 db_save(ClientProgsDB, "client.db");
 183         db_close(ClientProgsDB);
 184
 185         if(camera_active)
 186                 cvar_set("chase_active",ftos(chase_active_backup));
 187
 188         // unset the event chasecam's chase_active
 189         if(autocvar_chase_active < 0)
 190                 cvar_set("chase_active", "0");
 191
 192         if (!isdemo())
 193         {
 194                 if (!(calledhooks & HOOK_START))
 195                         localcmd("\n_cl_hook_gamestart nop\n");
 196                 if (!(calledhooks & HOOK_END))
 197                         localcmd("\ncl_hook_gameend\n");
 198         }
 199 }
 200
 201 .float has_team;
 202 float SetTeam(entity o, float Team)
 203 {
 204         entity tm;
 205         if(teamplay)
 206         {
 207                 switch(Team)
 208                 {
 209                         case -1:
 210                         case NUM_TEAM_1:
 211                         case NUM_TEAM_2:
 212                         case NUM_TEAM_3:
 213                         case NUM_TEAM_4:
 214                                 break;
 215                         default:
 216                                 if(GetTeam(Team, false) == world)
 217                                 {
 218                                         dprintf("trying to switch to unsupported team %d\n", Team);
 219                                         Team = NUM_SPECTATOR;
 220                                 }
 221                                 break;
 222                 }
 223         }
 224         else
 225         {
 226                 switch(Team)
 227                 {
 228                         case -1:
 229                         case 0:
 230                                 break;
 231                         default:
 232                                 if(GetTeam(Team, false) == world)
 233                                 {
 234                                         dprintf("trying to switch to unsupported team %d\n", Team);
 235                                         Team = NUM_SPECTATOR;
 236                                 }
 237                                 break;
 238                 }
 239         }
 240         if(Team == -1) // leave
 241         {
 242                 if(o.has_team)
 243                 {
 244                         tm = GetTeam(o.team, false);
 245                         tm.team_size -= 1;
 246                         o.has_team = 0;
 247                         return TRUE;
 248                 }
 249         }
 250         else
 251         {
 252                 if (!o.has_team)
 253                 {
 254                         o.team = Team;
 255                         tm = GetTeam(Team, true);
 256                         tm.team_size += 1;
 257                         o.has_team = 1;
 258                         return TRUE;
 259                 }
 260                 else if(Team != o.team)
 261                 {
 262                         tm = GetTeam(o.team, false);
 263                         tm.team_size -= 1;
 264                         o.team = Team;
 265                         tm = GetTeam(Team, true);
 266                         tm.team_size += 1;
 267                         return TRUE;
 268                 }
 269         }
 270         return FALSE;
 271 }
 272
 273 void Playerchecker_Think()
 274 {
 275         float i;
 276         entity e;
 277         for(i = 0; i < maxclients; ++i)
 278         {
 279                 e = playerslots[i];
 280                 if(GetPlayerName(i) == "")
 281                 {
 282                         if(e.sort_prev)
 283                         {
 284                                 // player disconnected
 285                                 SetTeam(e, -1);
 286                                 RemovePlayer(e);
 287                                 e.sort_prev = world;
 288                                 //e.gotscores = 0;
 289                         }
 290                 }
 291                 else
 292                 {
 293                         if (!e.sort_prev)
 294                         {
 295                                 // player connected
 296                                 if (!e)
 297                                         playerslots[i] = e = spawn();
 298                                 e.sv_entnum = i;
 299                                 e.ping = 0;
 300                                 e.ping_packetloss = 0;
 301                                 e.ping_movementloss = 0;
 302                                 //e.gotscores = 0; // we might already have the scores...
 303                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 304                                 RegisterPlayer(e);
 305                                 HUD_UpdatePlayerPos(e);
 306                         }
 307                 }
 308         }
 309         self.nextthink = time + 0.2;
 310 }
 311
 312 void Porto_Init();
 313 void TrueAim_Init();
 314 void PostInit(void)
 315 {
 316         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 317
 318         entity playerchecker;
 319         playerchecker = spawn();
 320         playerchecker.think = Playerchecker_Think;
 321         playerchecker.nextthink = time + 0.2;
 322
 323         Porto_Init();
 324         TrueAim_Init();
 325
 326         postinit = true;
 327 }
 328
 329 float button_zoom;
 330
 331 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 332 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 333 // All keys are in ascii.
 334 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 335 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 336 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 337 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 338 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 339 {
 340         float bSkipKey;
 341         bSkipKey = false;
 342
 343         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 344                 return true;
 345
 346         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 347                 return true;
 348
 349         if(menu_visible && menu_action)
 350                 if(menu_action(bInputType, nPrimary, nSecondary))
 351                         return TRUE;
 352
 353         return bSkipKey;
 354 }
 355
 356 // END REQUIRED CSQC FUNCTIONS
 357 // --------------------------------------------------------------------------
 358
 359 // --------------------------------------------------------------------------
 360 // BEGIN OPTIONAL CSQC FUNCTIONS
 361 void Ent_RemoveEntCS()
 362 {
 363         entcs_receiver[self.sv_entnum] = world;
 364 }
 365 void Ent_ReadEntCS()
 366 {
 367         float sf;
 368         InterpolateOrigin_Undo();
 369
 370         self.classname = "entcs_receiver";
 371         sf = ReadByte();
 372
 373         if(sf & 1)
 374                 self.sv_entnum = ReadByte();
 375         if(sf & 2)
 376         {
 377                 self.origin_x = ReadShort();
 378                 self.origin_y = ReadShort();
 379                 self.origin_z = ReadShort();
 380                 setorigin(self, self.origin);
 381         }
 382         if(sf & 4)
 383         {
 384                 self.angles_y = ReadByte() * 360.0 / 256;
 385                 self.angles_x = self.angles_z = 0;
 386         }
 387         if(sf & 8)
 388                 self.healthvalue = ReadByte() * 10;
 389         if(sf & 16)
 390                 self.armorvalue = ReadByte() * 10;
 391
 392         entcs_receiver[self.sv_entnum] = self;
 393         self.entremove = Ent_RemoveEntCS;
 394         self.iflags |= IFLAG_ORIGIN;
 395
 396         InterpolateOrigin_Note();
 397 }
 398
 399 void Ent_Remove();
 400
 401 void Ent_RemovePlayerScore()
 402 {
 403         float i;
 404
 405         if(self.owner)
 406         {
 407                 SetTeam(self.owner, -1);
 408                 self.owner.gotscores = 0;
 409                 for(i = 0; i < MAX_SCORE; ++i)
 410                         self.owner.(scores[i]) = 0; // clear all scores
 411         }
 412 }
 413
 414 void Ent_ReadPlayerScore()
 415 {
 416         float i, n;
 417         float isNew;
 418         entity o;
 419
 420         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 421         // (no I've never heard of M-x replace-string, sed, or anything like that)
 422         isNew = !self.owner; // workaround for DP bug
 423         n = ReadByte()-1;
 424
 425 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 426         if(!isNew && n != self.sv_entnum)
 427         {
 428                 //print("A CSQC entity changed its owner!\n");
 429                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 430                 isNew = true;
 431                 Ent_Remove();
 432                 self.enttype = ENT_CLIENT_SCORES;
 433         }
 434 #endif
 435
 436         self.sv_entnum = n;
 437
 438         if (!(playerslots[self.sv_entnum]))
 439                 playerslots[self.sv_entnum] = spawn();
 440         o = self.owner = playerslots[self.sv_entnum];
 441         o.sv_entnum = self.sv_entnum;
 442         o.gotscores = 1;
 443
 444         //if (!o.sort_prev)
 445         //      RegisterPlayer(o);
 446         //playerchecker will do this for us later, if it has not already done so
 447
 448         float sf, lf;
 449 #if MAX_SCORE <= 8
 450         sf = ReadByte();
 451         lf = ReadByte();
 452 #else
 453         sf = ReadShort();
 454         lf = ReadShort();
 455 #endif
 456         float p;
 457         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 458                 if(sf & p)
 459                 {
 460                         if(lf & p)
 461                                 o.(scores[i]) = ReadInt24_t();
 462                         else
 463                                 o.(scores[i]) = ReadChar();
 464                 }
 465
 466         if(o.sort_prev)
 467                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 468
 469         self.entremove = Ent_RemovePlayerScore;
 470 }
 471
 472 void Ent_ReadTeamScore()
 473 {
 474         float i;
 475         entity o;
 476
 477         self.team = ReadByte();
 478         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 479
 480         float sf, lf;
 481 #if MAX_TEAMSCORE <= 8
 482         sf = ReadByte();
 483         lf = ReadByte();
 484 #else
 485         sf = ReadShort();
 486         lf = ReadShort();
 487 #endif
 488         float p;
 489         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 490                 if(sf & p)
 491                 {
 492                         if(lf & p)
 493                                 o.(teamscores[i]) = ReadInt24_t();
 494                         else
 495                                 o.(teamscores[i]) = ReadChar();
 496                 }
 497
 498         HUD_UpdateTeamPos(o);
 499 }
 500
 501 void Ent_ClientData()
 502 {
 503         float f;
 504         float newspectatee_status;
 505
 506         f = ReadByte();
 507
 508         scoreboard_showscores_force = (f & 1);
 509
 510         if(f & 2)
 511         {
 512                 newspectatee_status = ReadByte();
 513                 if(newspectatee_status == player_localnum + 1)
 514                         newspectatee_status = -1; // observing
 515         }
 516         else
 517                 newspectatee_status = 0;
 518
 519         spectatorbutton_zoom = (f & 4);
 520
 521         if(f & 8)
 522         {
 523                 angles_held_status = 1;
 524                 angles_held_x = ReadAngle();
 525                 angles_held_y = ReadAngle();
 526                 angles_held_z = 0;
 527         }
 528         else
 529                 angles_held_status = 0;
 530
 531         if(newspectatee_status != spectatee_status)
 532         {
 533                 // clear race stuff
 534                 race_laptime = 0;
 535                 race_checkpointtime = 0;
 536         }
 537         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 538         {
 539                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 540                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 541                 )
 542                         prev_p_health = -1;
 543                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 544                         prev_health = -1;
 545         }
 546         spectatee_status = newspectatee_status;
 547
 548         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 549 }
 550
 551 void Ent_Nagger()
 552 {
 553         float nags, i, j, b, f;
 554
 555         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 556
 557         if(!(nags & 4))
 558         {
 559                 if(vote_called_vote)
 560                         strunzone(vote_called_vote);
 561                 vote_called_vote = string_null;
 562                 vote_active = 0;
 563         }
 564         else
 565         {
 566                 vote_active = 1;
 567         }
 568
 569         if(nags & 64)
 570         {
 571                 vote_yescount = ReadByte();
 572                 vote_nocount = ReadByte();
 573                 vote_needed = ReadByte();
 574                 vote_highlighted = ReadChar();
 575         }
 576
 577         if(nags & 128)
 578         {
 579                 if(vote_called_vote)
 580                         strunzone(vote_called_vote);
 581                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 582         }
 583
 584         if(nags & 1)
 585         {
 586                 for(j = 0; j < maxclients; ++j)
 587                         if(playerslots[j])
 588                                 playerslots[j].ready = 1;
 589                 for(i = 1; i <= maxclients; i += 8)
 590                 {
 591                         f = ReadByte();
 592                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 593                                 if (!(f & b))
 594                                         if(playerslots[j])
 595                                                 playerslots[j].ready = 0;
 596                 }
 597         }
 598
 599         ready_waiting = (nags & 1);
 600         ready_waiting_for_me = (nags & 2);
 601         vote_waiting = (nags & 4);
 602         vote_waiting_for_me = (nags & 8);
 603         warmup_stage = (nags & 16);
 604 }
 605
 606 void Ent_RandomSeed()
 607 {
 608         float s;
 609         prandom_debug();
 610         s = ReadShort();
 611         psrandom(s);
 612 }
 613
 614 void Ent_ReadAccuracy(void)
 615 {
 616         float sf, f, w, b;
 617         sf = ReadInt24_t();
 618         if(sf == 0)
 619         {
 620                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 621                         weapon_accuracy[w] = -1;
 622                 return;
 623         }
 624
 625         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 626         {
 627                 if(sf & f)
 628                 {
 629                         b = ReadByte();
 630                         if(b == 0)
 631                                 weapon_accuracy[w] = -1;
 632                         else if(b == 255)
 633                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 634                         else
 635                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 636                 }
 637                 if(f == 0x800000)
 638                         f = 1;
 639                 else
 640                         f *= 2;
 641         }
 642 }
 643
 644 void Spawn_Draw(void)
 645 {
 646         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 647 }
 648
 649 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 650 {
 651         float teamnum = (ReadByte() - 1);
 652         vector spn_origin;
 653         spn_origin_x = ReadShort();
 654         spn_origin_y = ReadShort();
 655         spn_origin_z = ReadShort();
 656
 657         if(is_new)
 658         {
 659                 self.origin = spn_origin;
 660                 setsize(self, PL_MIN, PL_MAX);
 661                 droptofloor();
 662
 663                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 664                 {
 665                         self.mdl = "models/spawnpoint.md3";
 666                         self.colormod = Team_ColorRGB(teamnum);
 667                         precache_model(self.mdl);
 668                         setmodel(self, self.mdl);
 669                         self.drawmask = MASK_NORMAL;
 670                         //self.movetype = MOVETYPE_NOCLIP;
 671                         //self.draw = Spawn_Draw;
 672                 }*/
 673                 if(autocvar_cl_spawn_point_particles)
 674                 {
 675                         if((serverflags & SERVERFLAG_TEAMPLAY))
 676                         {
 677                                 switch(teamnum)
 678                                 {
 679                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 680                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 681                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 682                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 683                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 684                                 }
 685                         }
 686                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 687
 688                         self.draw = Spawn_Draw;
 689                 }
 690         }
 691
 692         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 693 }
 694
 695 void Ent_ReadSpawnEvent(float is_new)
 696 {
 697         // If entnum is 0, ONLY do the local spawn actions
 698         // this way the server can disable the sending of
 699         // spawn origin or such to clients if wanted.
 700         float entnum = ReadByte();
 701
 702         if(entnum)
 703         {
 704                 self.origin_x = ReadShort();
 705                 self.origin_y = ReadShort();
 706                 self.origin_z = ReadShort();
 707
 708                 if(is_new)
 709                 {
 710                         float teamnum = GetPlayerColor(entnum - 1);
 711
 712                         if(autocvar_cl_spawn_event_particles)
 713                         {
 714                                 switch(teamnum)
 715                                 {
 716                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 717                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 718                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 719                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 720                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 721                                 }
 722                         }
 723                         if(autocvar_cl_spawn_event_sound)
 724                         {
 725                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 726                         }
 727                 }
 728         }
 729
 730         // local spawn actions
 731         if(is_new && (!entnum || (entnum == player_localentnum)))
 732         {
 733                 zoomin_effect = 1;
 734                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 735
 736                 if(autocvar_cl_unpress_zoom_on_spawn)
 737                 {
 738                         localcmd("-zoom\n");
 739                         button_zoom = FALSE;
 740                 }
 741         }
 742
 743         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 744 }
 745
 746 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 747 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 748 void Ent_RadarLink();
 749 void Ent_Init();
 750 void Ent_ScoresInfo();
 751 void CSQC_Ent_Update(float bIsNewEntity)
 752 {
 753         float t;
 754         float savetime;
 755         t = ReadByte();
 756
 757         if(autocvar_developer_csqcentities)
 758                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 759
 760         // set up the "time" global for received entities to be correct for interpolation purposes
 761         savetime = time;
 762         if(servertime)
 763         {
 764                 time = servertime;
 765         }
 766         else
 767         {
 768                 serverprevtime = time;
 769                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 770                 time = serverprevtime + serverdeltatime;
 771         }
 772
 773 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 774         if(self.enttype)
 775         {
 776                 if(t != self.enttype || bIsNewEntity)
 777                 {
 778                         //print("A CSQC entity changed its type!\n");
 779                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 780                         Ent_Remove();
 781                         clearentity(self);
 782                         bIsNewEntity = 1;
 783                 }
 784         }
 785         else
 786         {
 787                 if(!bIsNewEntity)
 788                 {
 789                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 790                         bIsNewEntity = 1;
 791                 }
 792         }
 793 #endif
 794         self.enttype = t;
 795         switch(t)
 796         {
 797                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 798                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 799                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 800                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 801                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 802                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 803                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 804                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 805                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 806                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 807                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 808                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 809                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 810                 case ENT_CLIENT_INIT: Ent_Init(); break;
 811                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 812                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 813                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 814                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 815                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 816                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 817                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 818                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 819                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 820                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 821                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 822                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 823                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 824                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 825                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 826                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 827                 case ENT_CLIENT_TURRET: ent_turret(); break;
 828                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 829                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 830                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 831                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 832                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 833                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 834
 835                 default:
 836                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 837                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 838                         break;
 839         }
 840
 841         time = savetime;
 842 }
 843 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 844 // used when an entity changes its type. For an entity that someone interacts
 845 // with others, make sure it can no longer do so.
 846 void Ent_Remove()
 847 {
 848         if(self.entremove)
 849                 self.entremove();
 850
 851         if(self.skeletonindex)
 852         {
 853                 skel_delete(self.skeletonindex);
 854                 self.skeletonindex = 0;
 855         }
 856
 857         if(self.snd_looping > 0)
 858         {
 859                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 860                 self.snd_looping = 0;
 861         }
 862
 863         self.enttype = 0;
 864         self.classname = "";
 865         self.draw = menu_sub_null;
 866         self.entremove = menu_sub_null;
 867         // TODO possibly set more stuff to defaults
 868 }
 869 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 870 void CSQC_Ent_Remove()
 871 {
 872         if(autocvar_developer_csqcentities)
 873                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 874
 875         if(wasfreed(self))
 876         {
 877                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 878                 return;
 879         }
 880         if(self.enttype)
 881                 Ent_Remove();
 882         remove(self);
 883 }
 884
 885 void Gamemode_Init()
 886 {
 887         if (!isdemo())
 888         {
 889                 if(!(calledhooks & HOOK_START))
 890                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 891                 calledhooks |= HOOK_START;
 892         }
 893 }
 894 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 895 void CSQC_Parse_StuffCmd(string strMessage)
 896 {
 897         if(autocvar_developer_csqcentities)
 898                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 899
 900         localcmd(strMessage);
 901 }
 902 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 903 void CSQC_Parse_Print(string strMessage)
 904 {
 905         if(autocvar_developer_csqcentities)
 906                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 907
 908         print(ColorTranslateRGB(strMessage));
 909 }
 910
 911 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 912 void CSQC_Parse_CenterPrint(string strMessage)
 913 {
 914         if(autocvar_developer_csqcentities)
 915                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 916
 917         centerprint_hud(strMessage);
 918 }
 919
 920 string notranslate_fogcmd1 = "\nfog ";
 921 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 922 void Fog_Force()
 923 {
 924         // TODO somehow thwart prvm_globalset client ...
 925
 926         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 927                 { localcmd("\nr_drawfog 0\n"); }
 928         else if(forcefog != "")
 929                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 930 }
 931
 932 void Gamemode_Init();
 933 void Ent_ScoresInfo()
 934 {
 935         float i;
 936         self.classname = "ent_client_scores_info";
 937         gametype = ReadInt24_t();
 938         HUD_ModIcons_SetFunc();
 939         for(i = 0; i < MAX_SCORE; ++i)
 940         {
 941                 scores_label[i] = strzone(ReadString());
 942                 scores_flags[i] = ReadByte();
 943         }
 944         for(i = 0; i < MAX_TEAMSCORE; ++i)
 945         {
 946                 teamscores_label[i] = strzone(ReadString());
 947                 teamscores_flags[i] = ReadByte();
 948         }
 949         HUD_InitScores();
 950         Gamemode_Init();
 951 }
 952
 953 void Ent_Init()
 954 {
 955         self.classname = "ent_client_init";
 956
 957         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 958
 959         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 960         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 961         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 962         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 963         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 964         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 965         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 966         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 967         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 968         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 969         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 970         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 971
 972         if(forcefog)
 973                 strunzone(forcefog);
 974         forcefog = strzone(ReadString());
 975
 976         armorblockpercent = ReadByte() / 255.0;
 977
 978         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 979         g_balance_grenadelauncher_bouncestop = ReadCoord();
 980         g_balance_electro_secondary_bouncefactor = ReadCoord();
 981         g_balance_electro_secondary_bouncestop = ReadCoord();
 982
 983         nex_scope = !ReadByte();
 984         rifle_scope = !ReadByte();
 985
 986         serverflags = ReadByte();
 987
 988         minelayer_maxmines = ReadByte();
 989
 990         hagar_maxrockets = ReadByte();
 991
 992         g_trueaim_minrange = ReadCoord();
 993         g_balance_porto_secondary = ReadByte();
 994
 995         if(!postinit)
 996                 PostInit();
 997 }
 998
 999 void Net_ReadRace()
1000 {
1001         float b;
1002
1003         b = ReadByte();
1004
1005         switch(b)
1006         {
1007                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1008                         race_checkpoint = ReadByte();
1009                         race_time = ReadInt24_t();
1010                         race_previousbesttime = ReadInt24_t();
1011                         if(race_previousbestname)
1012                                 strunzone(race_previousbestname);
1013                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1014
1015                         race_checkpointtime = time;
1016
1017                         if(race_checkpoint == 0 || race_checkpoint == 254)
1018                         {
1019                                 race_penaltyaccumulator = 0;
1020                                 race_laptime = time; // valid
1021                         }
1022
1023                         break;
1024
1025                 case RACE_NET_CHECKPOINT_CLEAR:
1026                         race_laptime = 0;
1027                         race_checkpointtime = 0;
1028                         break;
1029
1030                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1031                         race_laptime = ReadCoord();
1032                         race_checkpointtime = -99999;
1033                         // fall through
1034                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1035                         race_nextcheckpoint = ReadByte();
1036
1037                         race_nextbesttime = ReadInt24_t();
1038                         if(race_nextbestname)
1039                                 strunzone(race_nextbestname);
1040                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1041                         break;
1042
1043                 case RACE_NET_CHECKPOINT_HIT_RACE:
1044                         race_mycheckpoint = ReadByte();
1045                         race_mycheckpointtime = time;
1046                         race_mycheckpointdelta = ReadInt24_t();
1047                         race_mycheckpointlapsdelta = ReadByte();
1048                         if(race_mycheckpointlapsdelta >= 128)
1049                                 race_mycheckpointlapsdelta -= 256;
1050                         if(race_mycheckpointenemy)
1051                                 strunzone(race_mycheckpointenemy);
1052                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1053                         break;
1054
1055                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1056                         race_othercheckpoint = ReadByte();
1057                         race_othercheckpointtime = time;
1058                         race_othercheckpointdelta = ReadInt24_t();
1059                         race_othercheckpointlapsdelta = ReadByte();
1060                         if(race_othercheckpointlapsdelta >= 128)
1061                                 race_othercheckpointlapsdelta -= 256;
1062                         if(race_othercheckpointenemy)
1063                                 strunzone(race_othercheckpointenemy);
1064                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1065                         break;
1066
1067                 case RACE_NET_PENALTY_RACE:
1068                         race_penaltyeventtime = time;
1069                         race_penaltytime = ReadShort();
1070                         //race_penaltyaccumulator += race_penaltytime;
1071                         if(race_penaltyreason)
1072                                 strunzone(race_penaltyreason);
1073                         race_penaltyreason = strzone(ReadString());
1074                         break;
1075
1076                 case RACE_NET_PENALTY_QUALIFYING:
1077                         race_penaltyeventtime = time;
1078                         race_penaltytime = ReadShort();
1079                         race_penaltyaccumulator += race_penaltytime;
1080                         if(race_penaltyreason)
1081                                 strunzone(race_penaltyreason);
1082                         race_penaltyreason = strzone(ReadString());
1083                         break;
1084
1085                 case RACE_NET_SERVER_RECORD:
1086                         race_server_record = ReadInt24_t();
1087                         break;
1088                 case RACE_NET_SPEED_AWARD:
1089                         race_speedaward = ReadInt24_t();
1090                         if(race_speedaward_holder)
1091                                 strunzone(race_speedaward_holder);
1092                         race_speedaward_holder = strzone(ReadString());
1093                         break;
1094                 case RACE_NET_SPEED_AWARD_BEST:
1095                         race_speedaward_alltimebest = ReadInt24_t();
1096                         if(race_speedaward_alltimebest_holder)
1097                                 strunzone(race_speedaward_alltimebest_holder);
1098                         race_speedaward_alltimebest_holder = strzone(ReadString());
1099                         break;
1100                 case RACE_NET_SERVER_RANKINGS:
1101                         float pos, prevpos, del;
1102                         pos = ReadShort();
1103                         prevpos = ReadShort();
1104                         del = ReadShort();
1105
1106                         // move other rankings out of the way
1107                         float i;
1108                         if (prevpos) {
1109                                 for (i=prevpos-1;i>pos-1;--i) {
1110                                         grecordtime[i] = grecordtime[i-1];
1111                                         if(grecordholder[i])
1112                                                 strunzone(grecordholder[i]);
1113                                         grecordholder[i] = strzone(grecordholder[i-1]);
1114                                 }
1115                         } else if (del) { // a record has been deleted by the admin
1116                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1117                                         if (i == RANKINGS_CNT-1) { // clear out last record
1118                                                 grecordtime[i] = 0;
1119                                                 if (grecordholder[i])
1120                                                         strunzone(grecordholder[i]);
1121                                                 grecordholder[i] = string_null;
1122                                         }
1123                                         else {
1124                                                 grecordtime[i] = grecordtime[i+1];
1125                                                 if (grecordholder[i])
1126                                                         strunzone(grecordholder[i]);
1127                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1128                                         }
1129                                 }
1130                         } else { // player has no ranked record yet
1131                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1132                                         grecordtime[i] = grecordtime[i-1];
1133                                         if(grecordholder[i])
1134                                                 strunzone(grecordholder[i]);
1135                                         grecordholder[i] = strzone(grecordholder[i-1]);
1136                                 }
1137                         }
1138
1139                         // store new ranking
1140                         if(grecordholder[pos-1] != "")
1141                                 strunzone(grecordholder[pos-1]);
1142                         grecordholder[pos-1] = strzone(ReadString());
1143                         grecordtime[pos-1] = ReadInt24_t();
1144                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1145                                 race_myrank = pos;
1146                         break;
1147                 case RACE_NET_SERVER_STATUS:
1148                         race_status = ReadShort();
1149                         if(race_status_name)
1150                                 strunzone(race_status_name);
1151                         race_status_name = strzone(ReadString());
1152         }
1153 }
1154
1155 void Net_TeamNagger()
1156 {
1157         teamnagger = 1;
1158 }
1159
1160 void Net_ReadPingPLReport()
1161 {
1162         float e, pi, pl, ml;
1163         e = ReadByte();
1164         pi = ReadShort();
1165         pl = ReadByte();
1166         ml = ReadByte();
1167         if (!(playerslots[e]))
1168                 return;
1169         playerslots[e].ping = pi;
1170         playerslots[e].ping_packetloss = pl / 255.0;
1171         playerslots[e].ping_movementloss = ml / 255.0;
1172 }
1173
1174 void Net_WeaponComplain()
1175 {
1176         complain_weapon = ReadByte();
1177
1178         if(complain_weapon_name)
1179                 strunzone(complain_weapon_name);
1180         complain_weapon_name = strzone(ReadString());
1181
1182         complain_weapon_type = ReadByte();
1183
1184         complain_weapon_time = time;
1185         weapontime = time; // ping the weapon panel
1186
1187         switch(complain_weapon_type)
1188         {
1189                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1190                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1191                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1192         }
1193 }
1194
1195 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1196 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1197 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1198 float CSQC_Parse_TempEntity()
1199 {
1200         float bHandled;
1201                 bHandled  = true;
1202         // Acquire TE ID
1203         float nTEID;
1204                 nTEID = ReadByte();
1205
1206         if(autocvar_developer_csqcentities)
1207                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1208
1209                 // NOTE: Could just do return instead of break...
1210         switch(nTEID)
1211         {
1212                 case TE_CSQC_TARGET_MUSIC:
1213                         Net_TargetMusic();
1214                         bHandled = true;
1215                         break;
1216                 case TE_CSQC_PICTURE:
1217                         Net_MapVote_Picture();
1218                         bHandled = true;
1219                         break;
1220                 case TE_CSQC_RACE:
1221                         Net_ReadRace();
1222                         bHandled = true;
1223                         break;
1224                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1225                         Net_ReadNexgunBeamParticle();
1226                         bHandled = true;
1227                         break;
1228                 case TE_CSQC_TEAMNAGGER:
1229                         Net_TeamNagger();
1230                         bHandled = true;
1231                         break;
1232                 case TE_CSQC_LIGHTNINGARC:
1233                         Net_ReadLightningarc();
1234                         bHandled = true;
1235                         break;
1236                 case TE_CSQC_PINGPLREPORT:
1237                         Net_ReadPingPLReport();
1238                         bHandled = true;
1239                         break;
1240                 case TE_CSQC_WEAPONCOMPLAIN:
1241                         Net_WeaponComplain();
1242                         bHandled = true;
1243                         break;
1244                 case TE_CSQC_VEHICLESETUP:
1245                         Net_VehicleSetup();
1246                         bHandled = true;
1247                         break;
1248                 case TE_CSQC_SVNOTICE:
1249                         cl_notice_read();
1250                         bHandled = true;
1251                         break;
1252                 default:
1253                         // No special logic for this temporary entity; return 0 so the engine can handle it
1254                         bHandled = false;
1255                         break;
1256         }
1257
1258         return bHandled;
1259 }
1260
1261 string getcommandkey(string text, string command)
1262 {
1263         string keys;
1264         float n, j, k, l = 0;
1265
1266         if (!autocvar_hud_showbinds)
1267                 return text;
1268
1269         keys = db_get(binddb, command);
1270         if (keys == "")
1271         {
1272                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1273                 for(j = 0; j < n; ++j)
1274                 {
1275                         k = stof(argv(j));
1276                         if(k != -1)
1277                         {
1278                                 if ("" == keys)
1279                                         keys = keynumtostring(k);
1280                                 else
1281                                         keys = strcat(keys, ", ", keynumtostring(k));
1282
1283                                 ++l;
1284                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1285                                         break;
1286                         }
1287
1288                 }
1289                 if (keys == "")
1290                         keys = "NO_KEY";
1291                 db_put(binddb, command, keys);
1292         }
1293
1294         if (keys == "NO_KEY") {
1295                 if (autocvar_hud_showbinds > 1)
1296                         return sprintf(_("%s (not bound)"), text);
1297                 else
1298                         return text;
1299         }
1300         else if (autocvar_hud_showbinds > 1)
1301                 return sprintf(_("%s (%s)"), text, keys);
1302         else
1303                 return keys;
1304 }