qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if (!clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 string forcefog;
  32 void WaypointSprite_Load();
  33 void ConsoleCommand_macro_init();
  34 void CSQC_Init(void)
  35 {
  36         prvm_language = cvar_string("prvm_language");
  37
  38 #ifdef WATERMARK
  39         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  40 #endif
  41
  42         float i;
  43
  44         binddb = db_create();
  45         tempdb = db_create();
  46         ClientProgsDB = db_load("client.db");
  47         compressShortVector_init();
  48
  49         draw_endBoldFont();
  50         menu_visible = FALSE;
  51         menu_show = menu_show_error;
  52         menu_action = func_null;
  53
  54         for(i = 0; i < 255; ++i)
  55                 if(getplayerkeyvalue(i, "viewentity") == "")
  56                         break;
  57         maxclients = i;
  58
  59         //registercommand("hud_configure");
  60         //registercommand("hud_save");
  61         //registercommand("menu_action");
  62
  63         ConsoleCommand_macro_init();
  64
  65         registercvar("hud_usecsqc", "1");
  66         registercvar("scoreboard_columns", "default");
  67
  68         registercvar("cl_nade_type", "3");
  69         registercvar("cl_pokenade_type", "zombie");
  70
  71         gametype = 0;
  72
  73         // hud_fields uses strunzone on the titles!
  74         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  75                 hud_title[i] = strzone("(null)");
  76
  77         Cmd_HUD_SetFields(0);
  78
  79         postinit = false;
  80
  81         calledhooks = 0;
  82
  83         teams = Sort_Spawn();
  84         players = Sort_Spawn();
  85
  86         GetTeam(NUM_SPECTATOR, true); // add specs first
  87
  88         // needs to be done so early because of the constants they create
  89         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
  90         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
  91         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
  92         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
  93         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
  94         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
  95         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
  96
  97         WaypointSprite_Load();
  98
  99         // precaches
 100         precache_model("null");
 101         precache_sound("misc/hit.wav");
 102         precache_sound("misc/typehit.wav");
 103
 104         Projectile_Precache();
 105         Hook_Precache();
 106         GibSplash_Precache();
 107         Casings_Precache();
 108         Vehicles_Precache();
 109         turrets_precache();
 110         Tuba_Precache();
 111         CSQCPlayer_Precache();
 112
 113         if(autocvar_cl_reticle)
 114         {
 115                 precache_pic("gfx/reticle_normal");
 116                 // weapon reticles are precached in weapon files
 117         }
 118
 119         get_mi_min_max_texcoords(1); // try the CLEVER way first
 120         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 121         shortmapname = mi_shortname;
 122
 123         if(precache_pic(minimapname) == "")
 124         {
 125                 // but maybe we have a non-clever minimap
 126                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 127                 if(precache_pic(minimapname) == "")
 128                         minimapname = ""; // FAIL
 129                 else
 130                         get_mi_min_max_texcoords(0); // load new texcoords
 131         }
 132
 133         mi_center = (mi_min + mi_max) * 0.5;
 134         mi_scale = mi_max - mi_min;
 135         minimapname = strzone(minimapname);
 136
 137         WarpZone_Init();
 138
 139         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 140         hud_configure_prev = -1;
 141
 142         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 143 }
 144
 145 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 146 void Shutdown(void)
 147 {
 148         WarpZone_Shutdown();
 149
 150         remove(teams);
 151         remove(players);
 152         db_close(binddb);
 153         db_close(tempdb);
 154         if(autocvar_cl_db_saveasdump)
 155                 db_dump(ClientProgsDB, "client.db");
 156         else
 157                 db_save(ClientProgsDB, "client.db");
 158         db_close(ClientProgsDB);
 159
 160         if(camera_active)
 161                 cvar_set("chase_active",ftos(chase_active_backup));
 162
 163         // unset the event chasecam's chase_active
 164         if(autocvar_chase_active < 0)
 165                 cvar_set("chase_active", "0");
 166
 167         if (!isdemo())
 168         {
 169                 if (!(calledhooks & HOOK_START))
 170                         localcmd("\n_cl_hook_gamestart nop\n");
 171                 if (!(calledhooks & HOOK_END))
 172                         localcmd("\ncl_hook_gameend\n");
 173         }
 174 }
 175
 176 .float has_team;
 177 float SetTeam(entity o, float Team)
 178 {
 179         entity tm;
 180         if(teamplay)
 181         {
 182                 switch(Team)
 183                 {
 184                         case -1:
 185                         case NUM_TEAM_1:
 186                         case NUM_TEAM_2:
 187                         case NUM_TEAM_3:
 188                         case NUM_TEAM_4:
 189                                 break;
 190                         default:
 191                                 if(GetTeam(Team, false) == world)
 192                                 {
 193                                         dprintf("trying to switch to unsupported team %d\n", Team);
 194                                         Team = NUM_SPECTATOR;
 195                                 }
 196                                 break;
 197                 }
 198         }
 199         else
 200         {
 201                 switch(Team)
 202                 {
 203                         case -1:
 204                         case 0:
 205                                 break;
 206                         default:
 207                                 if(GetTeam(Team, false) == world)
 208                                 {
 209                                         dprintf("trying to switch to unsupported team %d\n", Team);
 210                                         Team = NUM_SPECTATOR;
 211                                 }
 212                                 break;
 213                 }
 214         }
 215         if(Team == -1) // leave
 216         {
 217                 if(o.has_team)
 218                 {
 219                         tm = GetTeam(o.team, false);
 220                         tm.team_size -= 1;
 221                         o.has_team = 0;
 222                         return TRUE;
 223                 }
 224         }
 225         else
 226         {
 227                 if (!o.has_team)
 228                 {
 229                         o.team = Team;
 230                         tm = GetTeam(Team, true);
 231                         tm.team_size += 1;
 232                         o.has_team = 1;
 233                         return TRUE;
 234                 }
 235                 else if(Team != o.team)
 236                 {
 237                         tm = GetTeam(o.team, false);
 238                         tm.team_size -= 1;
 239                         o.team = Team;
 240                         tm = GetTeam(Team, true);
 241                         tm.team_size += 1;
 242                         return TRUE;
 243                 }
 244         }
 245         return FALSE;
 246 }
 247
 248 void Playerchecker_Think()
 249 {
 250         float i;
 251         entity e;
 252         for(i = 0; i < maxclients; ++i)
 253         {
 254                 e = playerslots[i];
 255                 if(GetPlayerName(i) == "")
 256                 {
 257                         if(e.sort_prev)
 258                         {
 259                                 // player disconnected
 260                                 SetTeam(e, -1);
 261                                 RemovePlayer(e);
 262                                 e.sort_prev = world;
 263                                 //e.gotscores = 0;
 264                         }
 265                 }
 266                 else
 267                 {
 268                         if (!e.sort_prev)
 269                         {
 270                                 // player connected
 271                                 if (!e)
 272                                         playerslots[i] = e = spawn();
 273                                 e.sv_entnum = i;
 274                                 e.ping = 0;
 275                                 e.ping_packetloss = 0;
 276                                 e.ping_movementloss = 0;
 277                                 //e.gotscores = 0; // we might already have the scores...
 278                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 279                                 RegisterPlayer(e);
 280                                 HUD_UpdatePlayerPos(e);
 281                         }
 282                 }
 283         }
 284         self.nextthink = time + 0.2;
 285 }
 286
 287 void Porto_Init();
 288 void TrueAim_Init();
 289 void PostInit(void)
 290 {
 291         entity playerchecker;
 292         playerchecker = spawn();
 293         playerchecker.think = Playerchecker_Think;
 294         playerchecker.nextthink = time + 0.2;
 295
 296         Porto_Init();
 297         TrueAim_Init();
 298
 299         postinit = true;
 300 }
 301
 302 float button_zoom;
 303
 304 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 305 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 306 // All keys are in ascii.
 307 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 308 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 309 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 310 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 311 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 312 {
 313         float bSkipKey;
 314         bSkipKey = false;
 315
 316         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 317                 return true;
 318
 319         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 320                 return true;
 321
 322         if(menu_visible && menu_action)
 323                 if(menu_action(bInputType, nPrimary, nSecondary))
 324                         return TRUE;
 325
 326         return bSkipKey;
 327 }
 328
 329 // END REQUIRED CSQC FUNCTIONS
 330 // --------------------------------------------------------------------------
 331
 332 // --------------------------------------------------------------------------
 333 // BEGIN OPTIONAL CSQC FUNCTIONS
 334 void Ent_RemoveEntCS()
 335 {
 336         entcs_receiver[self.sv_entnum] = world;
 337 }
 338 void Ent_ReadEntCS()
 339 {
 340         float sf;
 341         InterpolateOrigin_Undo();
 342
 343         self.classname = "entcs_receiver";
 344         sf = ReadByte();
 345
 346         if(sf & 1)
 347                 self.sv_entnum = ReadByte();
 348         if(sf & 2)
 349         {
 350                 self.origin_x = ReadShort();
 351                 self.origin_y = ReadShort();
 352                 self.origin_z = ReadShort();
 353                 setorigin(self, self.origin);
 354         }
 355         if(sf & 4)
 356         {
 357                 self.angles_y = ReadByte() * 360.0 / 256;
 358                 self.angles_x = self.angles_z = 0;
 359         }
 360         if(sf & 8)
 361                 self.healthvalue = ReadByte() * 10;
 362         if(sf & 16)
 363                 self.armorvalue = ReadByte() * 10;
 364
 365         entcs_receiver[self.sv_entnum] = self;
 366         self.entremove = Ent_RemoveEntCS;
 367         self.iflags |= IFLAG_ORIGIN;
 368
 369         InterpolateOrigin_Note();
 370 }
 371
 372 void Ent_Remove();
 373
 374 void Ent_RemovePlayerScore()
 375 {
 376         float i;
 377
 378         if(self.owner)
 379         {
 380                 SetTeam(self.owner, -1);
 381                 self.owner.gotscores = 0;
 382                 for(i = 0; i < MAX_SCORE; ++i)
 383                         self.owner.(scores[i]) = 0; // clear all scores
 384         }
 385 }
 386
 387 void Ent_ReadPlayerScore()
 388 {
 389         float i, n;
 390         float isNew;
 391         entity o;
 392
 393         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 394         // (no I've never heard of M-x replace-string, sed, or anything like that)
 395         isNew = !self.owner; // workaround for DP bug
 396         n = ReadByte()-1;
 397
 398 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 399         if(!isNew && n != self.sv_entnum)
 400         {
 401                 //print("A CSQC entity changed its owner!\n");
 402                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 403                 isNew = true;
 404                 Ent_Remove();
 405                 self.enttype = ENT_CLIENT_SCORES;
 406         }
 407 #endif
 408
 409         self.sv_entnum = n;
 410
 411         if (!(playerslots[self.sv_entnum]))
 412                 playerslots[self.sv_entnum] = spawn();
 413         o = self.owner = playerslots[self.sv_entnum];
 414         o.sv_entnum = self.sv_entnum;
 415         o.gotscores = 1;
 416
 417         //if (!o.sort_prev)
 418         //      RegisterPlayer(o);
 419         //playerchecker will do this for us later, if it has not already done so
 420
 421         float sf, lf;
 422 #if MAX_SCORE <= 8
 423         sf = ReadByte();
 424         lf = ReadByte();
 425 #else
 426         sf = ReadShort();
 427         lf = ReadShort();
 428 #endif
 429         float p;
 430         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 431                 if(sf & p)
 432                 {
 433                         if(lf & p)
 434                                 o.(scores[i]) = ReadInt24_t();
 435                         else
 436                                 o.(scores[i]) = ReadChar();
 437                 }
 438
 439         if(o.sort_prev)
 440                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 441
 442         self.entremove = Ent_RemovePlayerScore;
 443 }
 444
 445 void Ent_ReadTeamScore()
 446 {
 447         float i;
 448         entity o;
 449
 450         self.team = ReadByte();
 451         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 452
 453         float sf, lf;
 454 #if MAX_TEAMSCORE <= 8
 455         sf = ReadByte();
 456         lf = ReadByte();
 457 #else
 458         sf = ReadShort();
 459         lf = ReadShort();
 460 #endif
 461         float p;
 462         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 463                 if(sf & p)
 464                 {
 465                         if(lf & p)
 466                                 o.(teamscores[i]) = ReadInt24_t();
 467                         else
 468                                 o.(teamscores[i]) = ReadChar();
 469                 }
 470
 471         HUD_UpdateTeamPos(o);
 472 }
 473
 474 void Ent_ClientData()
 475 {
 476         float f;
 477         float newspectatee_status;
 478
 479         f = ReadByte();
 480
 481         scoreboard_showscores_force = (f & 1);
 482
 483         if(f & 2)
 484         {
 485                 newspectatee_status = ReadByte();
 486                 if(newspectatee_status == player_localnum + 1)
 487                         newspectatee_status = -1; // observing
 488         }
 489         else
 490                 newspectatee_status = 0;
 491
 492         spectatorbutton_zoom = (f & 4);
 493
 494         if(f & 8)
 495         {
 496                 angles_held_status = 1;
 497                 angles_held_x = ReadAngle();
 498                 angles_held_y = ReadAngle();
 499                 angles_held_z = 0;
 500         }
 501         else
 502                 angles_held_status = 0;
 503
 504         if(newspectatee_status != spectatee_status)
 505         {
 506                 // clear race stuff
 507                 race_laptime = 0;
 508                 race_checkpointtime = 0;
 509         }
 510         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 511         {
 512                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 513                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 514                 )
 515                         prev_p_health = -1;
 516                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 517                         prev_health = -1;
 518         }
 519         spectatee_status = newspectatee_status;
 520
 521         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 522 }
 523
 524 void Ent_Nagger()
 525 {
 526         float nags, i, j, b, f;
 527
 528         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 529
 530         if(!(nags & 4))
 531         {
 532                 if(vote_called_vote)
 533                         strunzone(vote_called_vote);
 534                 vote_called_vote = string_null;
 535                 vote_active = 0;
 536         }
 537         else
 538         {
 539                 vote_active = 1;
 540         }
 541
 542         if(nags & 64)
 543         {
 544                 vote_yescount = ReadByte();
 545                 vote_nocount = ReadByte();
 546                 vote_needed = ReadByte();
 547                 vote_highlighted = ReadChar();
 548         }
 549
 550         if(nags & 128)
 551         {
 552                 if(vote_called_vote)
 553                         strunzone(vote_called_vote);
 554                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 555         }
 556
 557         if(nags & 1)
 558         {
 559                 for(j = 0; j < maxclients; ++j)
 560                         if(playerslots[j])
 561                                 playerslots[j].ready = 1;
 562                 for(i = 1; i <= maxclients; i += 8)
 563                 {
 564                         f = ReadByte();
 565                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 566                                 if (!(f & b))
 567                                         if(playerslots[j])
 568                                                 playerslots[j].ready = 0;
 569                 }
 570         }
 571
 572         ready_waiting = (nags & 1);
 573         ready_waiting_for_me = (nags & 2);
 574         vote_waiting = (nags & 4);
 575         vote_waiting_for_me = (nags & 8);
 576         warmup_stage = (nags & 16);
 577 }
 578
 579 void Ent_EliminatedPlayers()
 580 {
 581         float sf, i, j, b, f;
 582
 583         sf = ReadByte();
 584         if(sf & 1)
 585         {
 586                 for(j = 0; j < maxclients; ++j)
 587                         if(playerslots[j])
 588                                 playerslots[j].eliminated = 1;
 589                 for(i = 1; i <= maxclients; i += 8)
 590                 {
 591                         f = ReadByte();
 592                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 593                                 if (!(f & b))
 594                                         if(playerslots[j])
 595                                                 playerslots[j].eliminated = 0;
 596                 }
 597         }
 598 }
 599
 600 void Ent_RandomSeed()
 601 {
 602         float s;
 603         prandom_debug();
 604         s = ReadShort();
 605         psrandom(s);
 606 }
 607
 608 void Ent_ReadAccuracy(void)
 609 {
 610         float sf, f, w, b;
 611         sf = ReadInt24_t();
 612         if(sf == 0)
 613         {
 614                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 615                         weapon_accuracy[w] = -1;
 616                 return;
 617         }
 618
 619         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 620         {
 621                 if(sf & f)
 622                 {
 623                         b = ReadByte();
 624                         if(b == 0)
 625                                 weapon_accuracy[w] = -1;
 626                         else if(b == 255)
 627                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 628                         else
 629                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 630                 }
 631                 if(f == 0x800000)
 632                         f = 1;
 633                 else
 634                         f *= 2;
 635         }
 636 }
 637
 638 void Spawn_Draw(void)
 639 {
 640         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 641 }
 642
 643 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 644 {
 645         float teamnum = (ReadByte() - 1);
 646         vector spn_origin;
 647         spn_origin_x = ReadShort();
 648         spn_origin_y = ReadShort();
 649         spn_origin_z = ReadShort();
 650
 651         if(is_new)
 652         {
 653                 self.origin = spn_origin;
 654                 setsize(self, PL_MIN, PL_MAX);
 655                 droptofloor();
 656
 657                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 658                 {
 659                         self.mdl = "models/spawnpoint.md3";
 660                         self.colormod = Team_ColorRGB(teamnum);
 661                         precache_model(self.mdl);
 662                         setmodel(self, self.mdl);
 663                         self.drawmask = MASK_NORMAL;
 664                         //self.movetype = MOVETYPE_NOCLIP;
 665                         //self.draw = Spawn_Draw;
 666                 }*/
 667                 if(autocvar_cl_spawn_point_particles)
 668                 {
 669                         if((serverflags & SERVERFLAG_TEAMPLAY))
 670                         {
 671                                 switch(teamnum)
 672                                 {
 673                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 674                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 675                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 676                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 677                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 678                                 }
 679                         }
 680                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 681
 682                         self.draw = Spawn_Draw;
 683                 }
 684         }
 685
 686         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 687 }
 688
 689 void Ent_ReadSpawnEvent(float is_new)
 690 {
 691         // If entnum is 0, ONLY do the local spawn actions
 692         // this way the server can disable the sending of
 693         // spawn origin or such to clients if wanted.
 694         float entnum = ReadByte();
 695
 696         if(entnum)
 697         {
 698                 self.origin_x = ReadShort();
 699                 self.origin_y = ReadShort();
 700                 self.origin_z = ReadShort();
 701
 702                 if(is_new)
 703                 {
 704                         float teamnum = GetPlayerColor(entnum - 1);
 705
 706                         if(autocvar_cl_spawn_event_particles)
 707                         {
 708                                 switch(teamnum)
 709                                 {
 710                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 711                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 712                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 713                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 714                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 715                                 }
 716                         }
 717                         if(autocvar_cl_spawn_event_sound)
 718                         {
 719                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 720                         }
 721                 }
 722         }
 723
 724         // local spawn actions
 725         if(is_new && (!entnum || (entnum == player_localentnum)))
 726         {
 727                 zoomin_effect = 1;
 728                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 729
 730                 if(autocvar_cl_unpress_zoom_on_spawn)
 731                 {
 732                         localcmd("-zoom\n");
 733                         button_zoom = FALSE;
 734                 }
 735         }
 736
 737         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 738 }
 739
 740 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 741 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 742 void Ent_RadarLink();
 743 void Ent_Init();
 744 void Ent_ScoresInfo();
 745 void CSQC_Ent_Update(float bIsNewEntity)
 746 {
 747         float t;
 748         float savetime;
 749         t = ReadByte();
 750
 751         if(autocvar_developer_csqcentities)
 752                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 753
 754         // set up the "time" global for received entities to be correct for interpolation purposes
 755         savetime = time;
 756         if(servertime)
 757         {
 758                 time = servertime;
 759         }
 760         else
 761         {
 762                 serverprevtime = time;
 763                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 764                 time = serverprevtime + serverdeltatime;
 765         }
 766
 767 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 768         if(self.enttype)
 769         {
 770                 if(t != self.enttype || bIsNewEntity)
 771                 {
 772                         //print("A CSQC entity changed its type!\n");
 773                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 774                         Ent_Remove();
 775                         clearentity(self);
 776                         bIsNewEntity = 1;
 777                 }
 778         }
 779         else
 780         {
 781                 if(!bIsNewEntity)
 782                 {
 783                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 784                         bIsNewEntity = 1;
 785                 }
 786         }
 787 #endif
 788         self.enttype = t;
 789         switch(t)
 790         {
 791                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 792                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 793                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 794                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 795                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 796                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 797                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 798                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 799                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 800                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 801                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 802                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 803                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 804                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 805                 case ENT_CLIENT_INIT: Ent_Init(); break;
 806                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 807                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 808                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 809                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 810                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 811                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 812                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 813                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 814                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 815                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 816                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 817                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 818                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 819                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 820                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 821                 case ENT_CLIENT_TURRET: ent_turret(); break;
 822                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 823                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 824                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 825                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 826                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 827                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 828                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 829
 830                 default:
 831                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 832                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 833                         break;
 834         }
 835
 836         time = savetime;
 837 }
 838 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 839 // used when an entity changes its type. For an entity that someone interacts
 840 // with others, make sure it can no longer do so.
 841 void Ent_Remove()
 842 {
 843         if(self.entremove)
 844                 self.entremove();
 845
 846         if(self.skeletonindex)
 847         {
 848                 skel_delete(self.skeletonindex);
 849                 self.skeletonindex = 0;
 850         }
 851
 852         if(self.snd_looping > 0)
 853         {
 854                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 855                 self.snd_looping = 0;
 856         }
 857
 858         self.enttype = 0;
 859         self.classname = "";
 860         self.draw = menu_sub_null;
 861         self.entremove = menu_sub_null;
 862         // TODO possibly set more stuff to defaults
 863 }
 864 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 865 void CSQC_Ent_Remove()
 866 {
 867         if(autocvar_developer_csqcentities)
 868                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 869
 870         if(wasfreed(self))
 871         {
 872                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 873                 return;
 874         }
 875         if(self.enttype)
 876                 Ent_Remove();
 877         remove(self);
 878 }
 879
 880 void Gamemode_Init()
 881 {
 882         if (!isdemo())
 883         {
 884                 if(!(calledhooks & HOOK_START))
 885                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 886                 calledhooks |= HOOK_START;
 887         }
 888 }
 889 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 890 void CSQC_Parse_StuffCmd(string strMessage)
 891 {
 892         if(autocvar_developer_csqcentities)
 893                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 894
 895         localcmd(strMessage);
 896 }
 897 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 898 void CSQC_Parse_Print(string strMessage)
 899 {
 900         if(autocvar_developer_csqcentities)
 901                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 902
 903         print(ColorTranslateRGB(strMessage));
 904 }
 905
 906 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 907 void CSQC_Parse_CenterPrint(string strMessage)
 908 {
 909         if(autocvar_developer_csqcentities)
 910                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 911
 912         centerprint_hud(strMessage);
 913 }
 914
 915 string notranslate_fogcmd1 = "\nfog ";
 916 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 917 void Fog_Force()
 918 {
 919         // TODO somehow thwart prvm_globalset client ...
 920
 921         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 922                 { localcmd("\nr_drawfog 0\n"); }
 923         else if(forcefog != "")
 924                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 925 }
 926
 927 void Gamemode_Init();
 928 void Ent_ScoresInfo()
 929 {
 930         float i;
 931         self.classname = "ent_client_scores_info";
 932         gametype = ReadInt24_t();
 933         HUD_ModIcons_SetFunc();
 934         for(i = 0; i < MAX_SCORE; ++i)
 935         {
 936                 if(scores_label[i])
 937                         strunzone(scores_label[i]);
 938                 scores_label[i] = strzone(ReadString());
 939                 scores_flags[i] = ReadByte();
 940         }
 941         for(i = 0; i < MAX_TEAMSCORE; ++i)
 942         {
 943                 if(teamscores_label[i])
 944                         strunzone(teamscores_label[i]);
 945                 teamscores_label[i] = strzone(ReadString());
 946                 teamscores_flags[i] = ReadByte();
 947         }
 948         HUD_InitScores();
 949         Gamemode_Init();
 950 }
 951
 952 void Ent_Init()
 953 {
 954         self.classname = "ent_client_init";
 955
 956         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 957
 958         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 959         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 960         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 961         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 962         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 963         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 964         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 965         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 966
 967         if(forcefog)
 968                 strunzone(forcefog);
 969         forcefog = strzone(ReadString());
 970
 971         armorblockpercent = ReadByte() / 255.0;
 972
 973         g_balance_mortar_bouncefactor = ReadCoord();
 974         g_balance_mortar_bouncestop = ReadCoord();
 975         g_balance_electro_secondary_bouncefactor = ReadCoord();
 976         g_balance_electro_secondary_bouncestop = ReadCoord();
 977
 978         vortex_scope = !ReadByte();
 979         rifle_scope = !ReadByte();
 980
 981         serverflags = ReadByte();
 982
 983         minelayer_maxmines = ReadByte();
 984
 985         hagar_maxrockets = ReadByte();
 986
 987         g_trueaim_minrange = ReadCoord();
 988         g_balance_porto_secondary = ReadByte();
 989
 990         if(!postinit)
 991                 PostInit();
 992 }
 993
 994 void Net_ReadRace()
 995 {
 996         float b;
 997
 998         b = ReadByte();
 999
1000         switch(b)
1001         {
1002                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1003                         race_checkpoint = ReadByte();
1004                         race_time = ReadInt24_t();
1005                         race_previousbesttime = ReadInt24_t();
1006                         if(race_previousbestname)
1007                                 strunzone(race_previousbestname);
1008                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1009
1010                         race_checkpointtime = time;
1011
1012                         if(race_checkpoint == 0 || race_checkpoint == 254)
1013                         {
1014                                 race_penaltyaccumulator = 0;
1015                                 race_laptime = time; // valid
1016                         }
1017
1018                         break;
1019
1020                 case RACE_NET_CHECKPOINT_CLEAR:
1021                         race_laptime = 0;
1022                         race_checkpointtime = 0;
1023                         break;
1024
1025                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1026                         race_laptime = ReadCoord();
1027                         race_checkpointtime = -99999;
1028                         // fall through
1029                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1030                         race_nextcheckpoint = ReadByte();
1031
1032                         race_nextbesttime = ReadInt24_t();
1033                         if(race_nextbestname)
1034                                 strunzone(race_nextbestname);
1035                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1036                         break;
1037
1038                 case RACE_NET_CHECKPOINT_HIT_RACE:
1039                         race_mycheckpoint = ReadByte();
1040                         race_mycheckpointtime = time;
1041                         race_mycheckpointdelta = ReadInt24_t();
1042                         race_mycheckpointlapsdelta = ReadByte();
1043                         if(race_mycheckpointlapsdelta >= 128)
1044                                 race_mycheckpointlapsdelta -= 256;
1045                         if(race_mycheckpointenemy)
1046                                 strunzone(race_mycheckpointenemy);
1047                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1048                         break;
1049
1050                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1051                         race_othercheckpoint = ReadByte();
1052                         race_othercheckpointtime = time;
1053                         race_othercheckpointdelta = ReadInt24_t();
1054                         race_othercheckpointlapsdelta = ReadByte();
1055                         if(race_othercheckpointlapsdelta >= 128)
1056                                 race_othercheckpointlapsdelta -= 256;
1057                         if(race_othercheckpointenemy)
1058                                 strunzone(race_othercheckpointenemy);
1059                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1060                         break;
1061
1062                 case RACE_NET_PENALTY_RACE:
1063                         race_penaltyeventtime = time;
1064                         race_penaltytime = ReadShort();
1065                         //race_penaltyaccumulator += race_penaltytime;
1066                         if(race_penaltyreason)
1067                                 strunzone(race_penaltyreason);
1068                         race_penaltyreason = strzone(ReadString());
1069                         break;
1070
1071                 case RACE_NET_PENALTY_QUALIFYING:
1072                         race_penaltyeventtime = time;
1073                         race_penaltytime = ReadShort();
1074                         race_penaltyaccumulator += race_penaltytime;
1075                         if(race_penaltyreason)
1076                                 strunzone(race_penaltyreason);
1077                         race_penaltyreason = strzone(ReadString());
1078                         break;
1079
1080                 case RACE_NET_SERVER_RECORD:
1081                         race_server_record = ReadInt24_t();
1082                         break;
1083                 case RACE_NET_SPEED_AWARD:
1084                         race_speedaward = ReadInt24_t();
1085                         if(race_speedaward_holder)
1086                                 strunzone(race_speedaward_holder);
1087                         race_speedaward_holder = strzone(ReadString());
1088                         break;
1089                 case RACE_NET_SPEED_AWARD_BEST:
1090                         race_speedaward_alltimebest = ReadInt24_t();
1091                         if(race_speedaward_alltimebest_holder)
1092                                 strunzone(race_speedaward_alltimebest_holder);
1093                         race_speedaward_alltimebest_holder = strzone(ReadString());
1094                         break;
1095                 case RACE_NET_SERVER_RANKINGS:
1096                         float pos, prevpos, del;
1097                         pos = ReadShort();
1098                         prevpos = ReadShort();
1099                         del = ReadShort();
1100
1101                         // move other rankings out of the way
1102                         float i;
1103                         if (prevpos) {
1104                                 for (i=prevpos-1;i>pos-1;--i) {
1105                                         grecordtime[i] = grecordtime[i-1];
1106                                         if(grecordholder[i])
1107                                                 strunzone(grecordholder[i]);
1108                                         grecordholder[i] = strzone(grecordholder[i-1]);
1109                                 }
1110                         } else if (del) { // a record has been deleted by the admin
1111                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1112                                         if (i == RANKINGS_CNT-1) { // clear out last record
1113                                                 grecordtime[i] = 0;
1114                                                 if (grecordholder[i])
1115                                                         strunzone(grecordholder[i]);
1116                                                 grecordholder[i] = string_null;
1117                                         }
1118                                         else {
1119                                                 grecordtime[i] = grecordtime[i+1];
1120                                                 if (grecordholder[i])
1121                                                         strunzone(grecordholder[i]);
1122                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1123                                         }
1124                                 }
1125                         } else { // player has no ranked record yet
1126                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1127                                         grecordtime[i] = grecordtime[i-1];
1128                                         if(grecordholder[i])
1129                                                 strunzone(grecordholder[i]);
1130                                         grecordholder[i] = strzone(grecordholder[i-1]);
1131                                 }
1132                         }
1133
1134                         // store new ranking
1135                         if(grecordholder[pos-1] != "")
1136                                 strunzone(grecordholder[pos-1]);
1137                         grecordholder[pos-1] = strzone(ReadString());
1138                         grecordtime[pos-1] = ReadInt24_t();
1139                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1140                                 race_myrank = pos;
1141                         break;
1142                 case RACE_NET_SERVER_STATUS:
1143                         race_status = ReadShort();
1144                         if(race_status_name)
1145                                 strunzone(race_status_name);
1146                         race_status_name = strzone(ReadString());
1147         }
1148 }
1149
1150 void Net_TeamNagger()
1151 {
1152         teamnagger = 1;
1153 }
1154
1155 void Net_ReadPingPLReport()
1156 {
1157         float e, pi, pl, ml;
1158         e = ReadByte();
1159         pi = ReadShort();
1160         pl = ReadByte();
1161         ml = ReadByte();
1162         if (!(playerslots[e]))
1163                 return;
1164         playerslots[e].ping = pi;
1165         playerslots[e].ping_packetloss = pl / 255.0;
1166         playerslots[e].ping_movementloss = ml / 255.0;
1167 }
1168
1169 void Net_WeaponComplain()
1170 {
1171         complain_weapon = ReadByte();
1172
1173         if(complain_weapon_name)
1174                 strunzone(complain_weapon_name);
1175         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1176
1177         complain_weapon_type = ReadByte();
1178
1179         complain_weapon_time = time;
1180         weapontime = time; // ping the weapon panel
1181
1182         switch(complain_weapon_type)
1183         {
1184                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1185                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1186                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1187         }
1188 }
1189
1190 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1191 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1192 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1193 float CSQC_Parse_TempEntity()
1194 {
1195         float bHandled;
1196                 bHandled  = true;
1197         // Acquire TE ID
1198         float nTEID;
1199                 nTEID = ReadByte();
1200
1201         if(autocvar_developer_csqcentities)
1202                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1203
1204                 // NOTE: Could just do return instead of break...
1205         switch(nTEID)
1206         {
1207                 case TE_CSQC_TARGET_MUSIC:
1208                         Net_TargetMusic();
1209                         bHandled = true;
1210                         break;
1211                 case TE_CSQC_PICTURE:
1212                         Net_MapVote_Picture();
1213                         bHandled = true;
1214                         break;
1215                 case TE_CSQC_RACE:
1216                         Net_ReadRace();
1217                         bHandled = true;
1218                         break;
1219                 case TE_CSQC_VORTEXBEAMPARTICLE:
1220                         Net_ReadVortexBeamParticle();
1221                         bHandled = true;
1222                         break;
1223                 case TE_CSQC_TEAMNAGGER:
1224                         Net_TeamNagger();
1225                         bHandled = true;
1226                         break;
1227                 case TE_CSQC_ARC:
1228                         Net_ReadArc();
1229                         bHandled = true;
1230                         break;
1231                 case TE_CSQC_PINGPLREPORT:
1232                         Net_ReadPingPLReport();
1233                         bHandled = true;
1234                         break;
1235                 case TE_CSQC_WEAPONCOMPLAIN:
1236                         Net_WeaponComplain();
1237                         bHandled = true;
1238                         break;
1239                 case TE_CSQC_VEHICLESETUP:
1240                         Net_VehicleSetup();
1241                         bHandled = true;
1242                         break;
1243                 case TE_CSQC_SVNOTICE:
1244                         cl_notice_read();
1245                         bHandled = true;
1246                         break;
1247                 case TE_CSQC_SHOCKWAVEPARTICLE:
1248                         Net_ReadShockwaveParticle();
1249                         bHandled = true;
1250                         break;
1251                 default:
1252                         // No special logic for this temporary entity; return 0 so the engine can handle it
1253                         bHandled = false;
1254                         break;
1255         }
1256
1257         return bHandled;
1258 }
1259
1260 string getcommandkey(string text, string command)
1261 {
1262         string keys;
1263         float n, j, k, l = 0;
1264
1265         if (!autocvar_hud_showbinds)
1266                 return text;
1267
1268         keys = db_get(binddb, command);
1269         if (keys == "")
1270         {
1271                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1272                 for(j = 0; j < n; ++j)
1273                 {
1274                         k = stof(argv(j));
1275                         if(k != -1)
1276                         {
1277                                 if ("" == keys)
1278                                         keys = keynumtostring(k);
1279                                 else
1280                                         keys = strcat(keys, ", ", keynumtostring(k));
1281
1282                                 ++l;
1283                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1284                                         break;
1285                         }
1286
1287                 }
1288                 if (keys == "")
1289                         keys = "NO_KEY";
1290                 db_put(binddb, command, keys);
1291         }
1292
1293         if (keys == "NO_KEY") {
1294                 if (autocvar_hud_showbinds > 1)
1295                         return sprintf(_("%s (not bound)"), text);
1296                 else
1297                         return text;
1298         }
1299         else if (autocvar_hud_showbinds > 1)
1300                 return sprintf("%s (%s)", text, keys);
1301         else
1302                 return keys;
1303 }