qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if (!clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         int n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 string forcefog;
  32 void WaypointSprite_Load();
  33 void ConsoleCommand_macro_init();
  34 void CSQC_Init(void)
  35 {
  36         prvm_language = cvar_string("prvm_language");
  37
  38 #ifdef WATERMARK
  39         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  40 #endif
  41
  42         int i;
  43
  44         binddb = db_create();
  45         tempdb = db_create();
  46         ClientProgsDB = db_load("client.db");
  47         compressShortVector_init();
  48
  49         draw_endBoldFont();
  50         menu_visible = false;
  51         menu_show = menu_show_error;
  52         menu_action = func_null;
  53
  54         for(i = 0; i < 255; ++i)
  55                 if(getplayerkeyvalue(i, "viewentity") == "")
  56                         break;
  57         maxclients = i;
  58
  59         //registercommand("hud_configure");
  60         //registercommand("hud_save");
  61         //registercommand("menu_action");
  62
  63         ConsoleCommand_macro_init();
  64
  65         registercvar("hud_usecsqc", "1");
  66         registercvar("scoreboard_columns", "default");
  67
  68         registercvar("cl_nade_type", "3");
  69         registercvar("cl_pokenade_type", "zombie");
  70
  71         gametype = 0;
  72
  73         // hud_fields uses strunzone on the titles!
  74         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  75                 hud_title[i] = strzone("(null)");
  76
  77         Cmd_HUD_SetFields(0);
  78
  79         postinit = false;
  80
  81         calledhooks = 0;
  82
  83         teams = Sort_Spawn();
  84         players = Sort_Spawn();
  85
  86         GetTeam(NUM_SPECTATOR, true); // add specs first
  87
  88         // needs to be done so early because of the constants they create
  89         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
  90         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
  91         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
  92         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
  93         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
  94         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
  95         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
  96
  97         WaypointSprite_Load();
  98
  99         // precaches
 100         precache_model("null");
 101         precache_sound("misc/hit.wav");
 102         precache_sound("misc/typehit.wav");
 103
 104         Projectile_Precache();
 105         Hook_Precache();
 106         GibSplash_Precache();
 107         Casings_Precache();
 108         Vehicles_Precache();
 109         turrets_precache();
 110         Tuba_Precache();
 111         CSQCPlayer_Precache();
 112
 113         if(autocvar_cl_reticle)
 114         {
 115                 precache_pic("gfx/reticle_normal");
 116                 // weapon reticles are precached in weapon files
 117         }
 118
 119         get_mi_min_max_texcoords(1); // try the CLEVER way first
 120         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 121         shortmapname = mi_shortname;
 122
 123         if(precache_pic(minimapname) == "")
 124         {
 125                 // but maybe we have a non-clever minimap
 126                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 127                 if(precache_pic(minimapname) == "")
 128                         minimapname = ""; // FAIL
 129                 else
 130                         get_mi_min_max_texcoords(0); // load new texcoords
 131         }
 132
 133         mi_center = (mi_min + mi_max) * 0.5;
 134         mi_scale = mi_max - mi_min;
 135         minimapname = strzone(minimapname);
 136
 137         WarpZone_Init();
 138
 139         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 140         hud_configure_prev = -1;
 141
 142         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 143 }
 144
 145 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 146 void Shutdown(void)
 147 {
 148         WarpZone_Shutdown();
 149
 150         remove(teams);
 151         remove(players);
 152         db_close(binddb);
 153         db_close(tempdb);
 154         if(autocvar_cl_db_saveasdump)
 155                 db_dump(ClientProgsDB, "client.db");
 156         else
 157                 db_save(ClientProgsDB, "client.db");
 158         db_close(ClientProgsDB);
 159
 160         if(camera_active)
 161                 cvar_set("chase_active",ftos(chase_active_backup));
 162
 163         // unset the event chasecam's chase_active
 164         if(autocvar_chase_active < 0)
 165                 cvar_set("chase_active", "0");
 166
 167         if (!isdemo())
 168         {
 169                 if (!(calledhooks & HOOK_START))
 170                         localcmd("\n_cl_hook_gamestart nop\n");
 171                 if (!(calledhooks & HOOK_END))
 172                         localcmd("\ncl_hook_gameend\n");
 173         }
 174 }
 175
 176 .float has_team;
 177 float SetTeam(entity o, int Team)
 178 {
 179         entity tm;
 180         if(teamplay)
 181         {
 182                 switch(Team)
 183                 {
 184                         case -1:
 185                         case NUM_TEAM_1:
 186                         case NUM_TEAM_2:
 187                         case NUM_TEAM_3:
 188                         case NUM_TEAM_4:
 189                                 break;
 190                         default:
 191                                 if(GetTeam(Team, false) == world)
 192                                 {
 193                                         dprintf("trying to switch to unsupported team %d\n", Team);
 194                                         Team = NUM_SPECTATOR;
 195                                 }
 196                                 break;
 197                 }
 198         }
 199         else
 200         {
 201                 switch(Team)
 202                 {
 203                         case -1:
 204                         case 0:
 205                                 break;
 206                         default:
 207                                 if(GetTeam(Team, false) == world)
 208                                 {
 209                                         dprintf("trying to switch to unsupported team %d\n", Team);
 210                                         Team = NUM_SPECTATOR;
 211                                 }
 212                                 break;
 213                 }
 214         }
 215         if(Team == -1) // leave
 216         {
 217                 if(o.has_team)
 218                 {
 219                         tm = GetTeam(o.team, false);
 220                         tm.team_size -= 1;
 221                         o.has_team = 0;
 222                         return true;
 223                 }
 224         }
 225         else
 226         {
 227                 if (!o.has_team)
 228                 {
 229                         o.team = Team;
 230                         tm = GetTeam(Team, true);
 231                         tm.team_size += 1;
 232                         o.has_team = 1;
 233                         return true;
 234                 }
 235                 else if(Team != o.team)
 236                 {
 237                         tm = GetTeam(o.team, false);
 238                         tm.team_size -= 1;
 239                         o.team = Team;
 240                         tm = GetTeam(Team, true);
 241                         tm.team_size += 1;
 242                         return true;
 243                 }
 244         }
 245         return false;
 246 }
 247
 248 void Playerchecker_Think()
 249 {
 250     int i;
 251         entity e;
 252         for(i = 0; i < maxclients; ++i)
 253         {
 254                 e = playerslots[i];
 255                 if(GetPlayerName(i) == "")
 256                 {
 257                         if(e.sort_prev)
 258                         {
 259                                 // player disconnected
 260                                 SetTeam(e, -1);
 261                                 RemovePlayer(e);
 262                                 e.sort_prev = world;
 263                                 //e.gotscores = 0;
 264                         }
 265                 }
 266                 else
 267                 {
 268                         if (!e.sort_prev)
 269                         {
 270                                 // player connected
 271                                 if (!e)
 272                                         playerslots[i] = e = spawn();
 273                                 e.sv_entnum = i;
 274                                 e.ping = 0;
 275                                 e.ping_packetloss = 0;
 276                                 e.ping_movementloss = 0;
 277                                 //e.gotscores = 0; // we might already have the scores...
 278                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 279                                 RegisterPlayer(e);
 280                                 HUD_UpdatePlayerPos(e);
 281                         }
 282                 }
 283         }
 284         self.nextthink = time + 0.2;
 285 }
 286
 287 void Porto_Init();
 288 void TrueAim_Init();
 289 void PostInit(void)
 290 {
 291         entity playerchecker;
 292         playerchecker = spawn();
 293         playerchecker.think = Playerchecker_Think;
 294         playerchecker.nextthink = time + 0.2;
 295
 296         Porto_Init();
 297         TrueAim_Init();
 298
 299         postinit = true;
 300 }
 301
 302 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 303 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 304 // All keys are in ascii.
 305 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 306 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 307 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 308 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 309 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 310 {
 311         float bSkipKey;
 312         bSkipKey = false;
 313
 314         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 315                 return true;
 316
 317         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 318                 return true;
 319
 320         if(menu_visible && menu_action)
 321                 if(menu_action(bInputType, nPrimary, nSecondary))
 322                         return true;
 323
 324         return bSkipKey;
 325 }
 326
 327 // END REQUIRED CSQC FUNCTIONS
 328 // --------------------------------------------------------------------------
 329
 330 // --------------------------------------------------------------------------
 331 // BEGIN OPTIONAL CSQC FUNCTIONS
 332 void Ent_RemoveEntCS()
 333 {
 334         entcs_receiver[self.sv_entnum] = world;
 335 }
 336 void Ent_ReadEntCS()
 337 {
 338     int sf;
 339         InterpolateOrigin_Undo();
 340
 341         self.classname = "entcs_receiver";
 342         sf = ReadByte();
 343
 344         if(sf & 1)
 345                 self.sv_entnum = ReadByte();
 346         if(sf & 2)
 347         {
 348                 self.origin_x = ReadShort();
 349                 self.origin_y = ReadShort();
 350                 self.origin_z = ReadShort();
 351                 setorigin(self, self.origin);
 352         }
 353         if(sf & 4)
 354         {
 355                 self.angles_y = ReadByte() * 360.0 / 256;
 356                 self.angles_x = self.angles_z = 0;
 357         }
 358         if(sf & 8)
 359                 self.healthvalue = ReadByte() * 10;
 360         if(sf & 16)
 361                 self.armorvalue = ReadByte() * 10;
 362
 363         entcs_receiver[self.sv_entnum] = self;
 364         self.entremove = Ent_RemoveEntCS;
 365         self.iflags |= IFLAG_ORIGIN;
 366
 367         InterpolateOrigin_Note();
 368 }
 369
 370 void Ent_Remove();
 371
 372 void Ent_RemovePlayerScore()
 373 {
 374         float i;
 375
 376         if(self.owner)
 377         {
 378                 SetTeam(self.owner, -1);
 379                 self.owner.gotscores = 0;
 380                 for(i = 0; i < MAX_SCORE; ++i)
 381                         self.owner.(scores[i]) = 0; // clear all scores
 382         }
 383 }
 384
 385 void Ent_ReadPlayerScore()
 386 {
 387         int i, n;
 388         bool isNew;
 389         entity o;
 390
 391         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 392         // (no I've never heard of M-x replace-string, sed, or anything like that)
 393         isNew = !self.owner; // workaround for DP bug
 394         n = ReadByte()-1;
 395
 396 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 397         if(!isNew && n != self.sv_entnum)
 398         {
 399                 //print("A CSQC entity changed its owner!\n");
 400                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 401                 isNew = true;
 402                 Ent_Remove();
 403                 self.enttype = ENT_CLIENT_SCORES;
 404         }
 405 #endif
 406
 407         self.sv_entnum = n;
 408
 409         if (!(playerslots[self.sv_entnum]))
 410                 playerslots[self.sv_entnum] = spawn();
 411         o = self.owner = playerslots[self.sv_entnum];
 412         o.sv_entnum = self.sv_entnum;
 413         o.gotscores = 1;
 414
 415         //if (!o.sort_prev)
 416         //      RegisterPlayer(o);
 417         //playerchecker will do this for us later, if it has not already done so
 418
 419     int sf, lf;
 420 #if MAX_SCORE <= 8
 421         sf = ReadByte();
 422         lf = ReadByte();
 423 #else
 424         sf = ReadShort();
 425         lf = ReadShort();
 426 #endif
 427     int p;
 428         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 429                 if(sf & p)
 430                 {
 431                         if(lf & p)
 432                                 o.(scores[i]) = ReadInt24_t();
 433                         else
 434                                 o.(scores[i]) = ReadChar();
 435                 }
 436
 437         if(o.sort_prev)
 438                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 439
 440         self.entremove = Ent_RemovePlayerScore;
 441 }
 442
 443 void Ent_ReadTeamScore()
 444 {
 445         int i;
 446         entity o;
 447
 448         self.team = ReadByte();
 449         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 450
 451     int sf, lf;
 452 #if MAX_TEAMSCORE <= 8
 453         sf = ReadByte();
 454         lf = ReadByte();
 455 #else
 456         sf = ReadShort();
 457         lf = ReadShort();
 458 #endif
 459         int p;
 460         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 461                 if(sf & p)
 462                 {
 463                         if(lf & p)
 464                                 o.(teamscores[i]) = ReadInt24_t();
 465                         else
 466                                 o.(teamscores[i]) = ReadChar();
 467                 }
 468
 469         HUD_UpdateTeamPos(o);
 470 }
 471
 472 void Ent_ClientData()
 473 {
 474         float newspectatee_status;
 475
 476     int f = ReadByte();
 477
 478         scoreboard_showscores_force = (f & 1);
 479
 480         if(f & 2)
 481         {
 482                 newspectatee_status = ReadByte();
 483                 if(newspectatee_status == player_localnum + 1)
 484                         newspectatee_status = -1; // observing
 485         }
 486         else
 487                 newspectatee_status = 0;
 488
 489         spectatorbutton_zoom = (f & 4);
 490
 491         if(f & 8)
 492         {
 493                 angles_held_status = 1;
 494                 angles_held_x = ReadAngle();
 495                 angles_held_y = ReadAngle();
 496                 angles_held_z = 0;
 497         }
 498         else
 499                 angles_held_status = 0;
 500
 501         if(newspectatee_status != spectatee_status)
 502         {
 503                 // clear race stuff
 504                 race_laptime = 0;
 505                 race_checkpointtime = 0;
 506         }
 507         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 508         {
 509                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 510                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 511                 )
 512                         prev_p_health = -1;
 513                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 514                         prev_health = -1;
 515         }
 516         spectatee_status = newspectatee_status;
 517
 518         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 519 }
 520
 521 void Ent_Nagger()
 522 {
 523     int i, j, b, f;
 524
 525     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 526
 527         if(!(nags & 4))
 528         {
 529                 if(vote_called_vote)
 530                         strunzone(vote_called_vote);
 531                 vote_called_vote = string_null;
 532                 vote_active = 0;
 533         }
 534         else
 535         {
 536                 vote_active = 1;
 537         }
 538
 539         if(nags & 64)
 540         {
 541                 vote_yescount = ReadByte();
 542                 vote_nocount = ReadByte();
 543                 vote_needed = ReadByte();
 544                 vote_highlighted = ReadChar();
 545         }
 546
 547         if(nags & 128)
 548         {
 549                 if(vote_called_vote)
 550                         strunzone(vote_called_vote);
 551                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 552         }
 553
 554         if(nags & 1)
 555         {
 556                 for(j = 0; j < maxclients; ++j)
 557                         if(playerslots[j])
 558                                 playerslots[j].ready = 1;
 559                 for(i = 1; i <= maxclients; i += 8)
 560                 {
 561                         f = ReadByte();
 562                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 563                                 if (!(f & b))
 564                                         if(playerslots[j])
 565                                                 playerslots[j].ready = 0;
 566                 }
 567         }
 568
 569         ready_waiting = (nags & 1);
 570         ready_waiting_for_me = (nags & 2);
 571         vote_waiting = (nags & 4);
 572         vote_waiting_for_me = (nags & 8);
 573         warmup_stage = (nags & 16);
 574 }
 575
 576 void Ent_EliminatedPlayers()
 577 {
 578     int i, j, b, f;
 579
 580     int sf = ReadByte();
 581         if(sf & 1)
 582         {
 583                 for(j = 0; j < maxclients; ++j)
 584                         if(playerslots[j])
 585                                 playerslots[j].eliminated = 1;
 586                 for(i = 1; i <= maxclients; i += 8)
 587                 {
 588                         f = ReadByte();
 589                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 590                                 if (!(f & b))
 591                                         if(playerslots[j])
 592                                                 playerslots[j].eliminated = 0;
 593                 }
 594         }
 595 }
 596
 597 void Ent_RandomSeed()
 598 {
 599         float s;
 600         prandom_debug();
 601         s = ReadShort();
 602         psrandom(s);
 603 }
 604
 605 void Ent_ReadAccuracy(void)
 606 {
 607     int f, w;
 608     int sf = ReadInt24_t();
 609         if(sf == 0)
 610         {
 611                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 612                         weapon_accuracy[w] = -1;
 613                 return;
 614         }
 615
 616         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 617         {
 618                 if(sf & f)
 619                 {
 620             int b = ReadByte();
 621                         if(b == 0)
 622                                 weapon_accuracy[w] = -1;
 623                         else if(b == 255)
 624                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 625                         else
 626                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 627                 }
 628                 if(f == 0x800000)
 629                         f = 1;
 630                 else
 631                         f *= 2;
 632         }
 633 }
 634
 635 void Spawn_Draw(void)
 636 {
 637         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 638 }
 639
 640 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 641 {
 642         float teamnum = (ReadByte() - 1);
 643         vector spn_origin;
 644         spn_origin_x = ReadShort();
 645         spn_origin_y = ReadShort();
 646         spn_origin_z = ReadShort();
 647
 648         if(is_new)
 649         {
 650                 self.origin = spn_origin;
 651                 setsize(self, PL_MIN, PL_MAX);
 652                 droptofloor();
 653
 654                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 655                 {
 656                         self.mdl = "models/spawnpoint.md3";
 657                         self.colormod = Team_ColorRGB(teamnum);
 658                         precache_model(self.mdl);
 659                         setmodel(self, self.mdl);
 660                         self.drawmask = MASK_NORMAL;
 661                         //self.movetype = MOVETYPE_NOCLIP;
 662                         //self.draw = Spawn_Draw;
 663                 }*/
 664                 if(autocvar_cl_spawn_point_particles)
 665                 {
 666                         if((serverflags & SERVERFLAG_TEAMPLAY))
 667                         {
 668                                 switch(teamnum)
 669                                 {
 670                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 671                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 672                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 673                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 674                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 675                                 }
 676                         }
 677                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 678
 679                         self.draw = Spawn_Draw;
 680                 }
 681         }
 682
 683         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 684 }
 685
 686 void Ent_ReadSpawnEvent(float is_new)
 687 {
 688         // If entnum is 0, ONLY do the local spawn actions
 689         // this way the server can disable the sending of
 690         // spawn origin or such to clients if wanted.
 691         float entnum = ReadByte();
 692
 693         if(entnum)
 694         {
 695                 self.origin_x = ReadShort();
 696                 self.origin_y = ReadShort();
 697                 self.origin_z = ReadShort();
 698
 699                 if(is_new)
 700                 {
 701                         float teamnum = GetPlayerColor(entnum - 1);
 702
 703                         if(autocvar_cl_spawn_event_particles)
 704                         {
 705                                 switch(teamnum)
 706                                 {
 707                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 708                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 709                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 710                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 711                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 712                                 }
 713                         }
 714                         if(autocvar_cl_spawn_event_sound)
 715                         {
 716                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 717                         }
 718                 }
 719         }
 720
 721         // local spawn actions
 722         if(is_new && (!entnum || (entnum == player_localentnum)))
 723         {
 724                 zoomin_effect = 1;
 725                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 726
 727                 if(autocvar_cl_unpress_zoom_on_spawn)
 728                 {
 729                         localcmd("-zoom\n");
 730                         button_zoom = false;
 731                 }
 732         }
 733
 734         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 735 }
 736
 737 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 738 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 739 void Ent_RadarLink();
 740 void Ent_Init();
 741 void Ent_ScoresInfo();
 742 void CSQC_Ent_Update(float bIsNewEntity)
 743 {
 744         float t;
 745         float savetime;
 746         t = ReadByte();
 747
 748         if(autocvar_developer_csqcentities)
 749                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 750
 751         // set up the "time" global for received entities to be correct for interpolation purposes
 752         savetime = time;
 753         if(servertime)
 754         {
 755                 time = servertime;
 756         }
 757         else
 758         {
 759                 serverprevtime = time;
 760                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 761                 time = serverprevtime + serverdeltatime;
 762         }
 763
 764 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 765         if(self.enttype)
 766         {
 767                 if(t != self.enttype || bIsNewEntity)
 768                 {
 769                         //print("A CSQC entity changed its type!\n");
 770                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 771                         Ent_Remove();
 772                         clearentity(self);
 773                         bIsNewEntity = 1;
 774                 }
 775         }
 776         else
 777         {
 778                 if(!bIsNewEntity)
 779                 {
 780                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 781                         bIsNewEntity = 1;
 782                 }
 783         }
 784 #endif
 785         self.enttype = t;
 786         switch(t)
 787         {
 788                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 789                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 790                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 791                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 792                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 793                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 794                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 795                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 796                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 797                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 798                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 799                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 800                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 801                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 802                 case ENT_CLIENT_INIT: Ent_Init(); break;
 803                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 804                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 805                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 806                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 807                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 808                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 809                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 810                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 811                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 812                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 813                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 814                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 815                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 816                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 817                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 818                 case ENT_CLIENT_TURRET: ent_turret(); break;
 819                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 820                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 821                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 822                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 823                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 824                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 825                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 826
 827                 default:
 828                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 829                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 830                         break;
 831         }
 832
 833         time = savetime;
 834 }
 835 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 836 // used when an entity changes its type. For an entity that someone interacts
 837 // with others, make sure it can no longer do so.
 838 void Ent_Remove()
 839 {
 840         if(self.entremove)
 841                 self.entremove();
 842
 843         if(self.skeletonindex)
 844         {
 845                 skel_delete(self.skeletonindex);
 846                 self.skeletonindex = 0;
 847         }
 848
 849         if(self.snd_looping > 0)
 850         {
 851                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 852                 self.snd_looping = 0;
 853         }
 854
 855         self.enttype = 0;
 856         self.classname = "";
 857         self.draw = menu_sub_null;
 858         self.entremove = menu_sub_null;
 859         // TODO possibly set more stuff to defaults
 860 }
 861 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 862 void CSQC_Ent_Remove()
 863 {
 864         if(autocvar_developer_csqcentities)
 865                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 866
 867         if(wasfreed(self))
 868         {
 869                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 870                 return;
 871         }
 872         if(self.enttype)
 873                 Ent_Remove();
 874         remove(self);
 875 }
 876
 877 void Gamemode_Init()
 878 {
 879         if (!isdemo())
 880         {
 881                 if(!(calledhooks & HOOK_START))
 882                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 883                 calledhooks |= HOOK_START;
 884         }
 885 }
 886 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 887 void CSQC_Parse_StuffCmd(string strMessage)
 888 {
 889         if(autocvar_developer_csqcentities)
 890                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 891
 892         localcmd(strMessage);
 893 }
 894 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 895 void CSQC_Parse_Print(string strMessage)
 896 {
 897         if(autocvar_developer_csqcentities)
 898                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 899
 900         print(ColorTranslateRGB(strMessage));
 901 }
 902
 903 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 904 void CSQC_Parse_CenterPrint(string strMessage)
 905 {
 906         if(autocvar_developer_csqcentities)
 907                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 908
 909         centerprint_hud(strMessage);
 910 }
 911
 912 string notranslate_fogcmd1 = "\nfog ";
 913 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 914 void Fog_Force()
 915 {
 916         // TODO somehow thwart prvm_globalset client ...
 917
 918         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 919                 { localcmd("\nr_drawfog 0\n"); }
 920         else if(forcefog != "")
 921                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 922 }
 923
 924 void Gamemode_Init();
 925 void Ent_ScoresInfo()
 926 {
 927     int i;
 928         self.classname = "ent_client_scores_info";
 929         gametype = ReadInt24_t();
 930         HUD_ModIcons_SetFunc();
 931         for(i = 0; i < MAX_SCORE; ++i)
 932         {
 933                 if(scores_label[i])
 934                         strunzone(scores_label[i]);
 935                 scores_label[i] = strzone(ReadString());
 936                 scores_flags[i] = ReadByte();
 937         }
 938         for(i = 0; i < MAX_TEAMSCORE; ++i)
 939         {
 940                 if(teamscores_label[i])
 941                         strunzone(teamscores_label[i]);
 942                 teamscores_label[i] = strzone(ReadString());
 943                 teamscores_flags[i] = ReadByte();
 944         }
 945         HUD_InitScores();
 946         Gamemode_Init();
 947 }
 948
 949 void Ent_Init()
 950 {
 951         self.classname = "ent_client_init";
 952
 953         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 954
 955         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 956         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 957         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 958         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 959         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 960         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 961         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 962         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 963
 964         if(forcefog)
 965                 strunzone(forcefog);
 966         forcefog = strzone(ReadString());
 967
 968         armorblockpercent = ReadByte() / 255.0;
 969
 970         g_balance_mortar_bouncefactor = ReadCoord();
 971         g_balance_mortar_bouncestop = ReadCoord();
 972         g_balance_electro_secondary_bouncefactor = ReadCoord();
 973         g_balance_electro_secondary_bouncestop = ReadCoord();
 974
 975         vortex_scope = !ReadByte();
 976         rifle_scope = !ReadByte();
 977
 978         serverflags = ReadByte();
 979
 980         minelayer_maxmines = ReadByte();
 981
 982         hagar_maxrockets = ReadByte();
 983
 984         g_trueaim_minrange = ReadCoord();
 985         g_balance_porto_secondary = ReadByte();
 986
 987         if(!postinit)
 988                 PostInit();
 989 }
 990
 991 void Net_ReadRace()
 992 {
 993         float b;
 994
 995         b = ReadByte();
 996
 997         switch(b)
 998         {
 999                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1000                         race_checkpoint = ReadByte();
1001                         race_time = ReadInt24_t();
1002                         race_previousbesttime = ReadInt24_t();
1003                         if(race_previousbestname)
1004                                 strunzone(race_previousbestname);
1005                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1006
1007                         race_checkpointtime = time;
1008
1009                         if(race_checkpoint == 0 || race_checkpoint == 254)
1010                         {
1011                                 race_penaltyaccumulator = 0;
1012                                 race_laptime = time; // valid
1013                         }
1014
1015                         break;
1016
1017                 case RACE_NET_CHECKPOINT_CLEAR:
1018                         race_laptime = 0;
1019                         race_checkpointtime = 0;
1020                         break;
1021
1022                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1023                         race_laptime = ReadCoord();
1024                         race_checkpointtime = -99999;
1025                         // fall through
1026                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1027                         race_nextcheckpoint = ReadByte();
1028
1029                         race_nextbesttime = ReadInt24_t();
1030                         if(race_nextbestname)
1031                                 strunzone(race_nextbestname);
1032                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1033                         break;
1034
1035                 case RACE_NET_CHECKPOINT_HIT_RACE:
1036                         race_mycheckpoint = ReadByte();
1037                         race_mycheckpointtime = time;
1038                         race_mycheckpointdelta = ReadInt24_t();
1039                         race_mycheckpointlapsdelta = ReadByte();
1040                         if(race_mycheckpointlapsdelta >= 128)
1041                                 race_mycheckpointlapsdelta -= 256;
1042                         if(race_mycheckpointenemy)
1043                                 strunzone(race_mycheckpointenemy);
1044                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1045                         break;
1046
1047                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1048                         race_othercheckpoint = ReadByte();
1049                         race_othercheckpointtime = time;
1050                         race_othercheckpointdelta = ReadInt24_t();
1051                         race_othercheckpointlapsdelta = ReadByte();
1052                         if(race_othercheckpointlapsdelta >= 128)
1053                                 race_othercheckpointlapsdelta -= 256;
1054                         if(race_othercheckpointenemy)
1055                                 strunzone(race_othercheckpointenemy);
1056                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1057                         break;
1058
1059                 case RACE_NET_PENALTY_RACE:
1060                         race_penaltyeventtime = time;
1061                         race_penaltytime = ReadShort();
1062                         //race_penaltyaccumulator += race_penaltytime;
1063                         if(race_penaltyreason)
1064                                 strunzone(race_penaltyreason);
1065                         race_penaltyreason = strzone(ReadString());
1066                         break;
1067
1068                 case RACE_NET_PENALTY_QUALIFYING:
1069                         race_penaltyeventtime = time;
1070                         race_penaltytime = ReadShort();
1071                         race_penaltyaccumulator += race_penaltytime;
1072                         if(race_penaltyreason)
1073                                 strunzone(race_penaltyreason);
1074                         race_penaltyreason = strzone(ReadString());
1075                         break;
1076
1077                 case RACE_NET_SERVER_RECORD:
1078                         race_server_record = ReadInt24_t();
1079                         break;
1080                 case RACE_NET_SPEED_AWARD:
1081                         race_speedaward = ReadInt24_t();
1082                         if(race_speedaward_holder)
1083                                 strunzone(race_speedaward_holder);
1084                         race_speedaward_holder = strzone(ReadString());
1085                         break;
1086                 case RACE_NET_SPEED_AWARD_BEST:
1087                         race_speedaward_alltimebest = ReadInt24_t();
1088                         if(race_speedaward_alltimebest_holder)
1089                                 strunzone(race_speedaward_alltimebest_holder);
1090                         race_speedaward_alltimebest_holder = strzone(ReadString());
1091                         break;
1092                 case RACE_NET_SERVER_RANKINGS:
1093                         float prevpos, del;
1094             int pos = ReadShort();
1095                         prevpos = ReadShort();
1096                         del = ReadShort();
1097
1098                         // move other rankings out of the way
1099             int i;
1100                         if (prevpos) {
1101                                 for (i=prevpos-1;i>pos-1;--i) {
1102                                         grecordtime[i] = grecordtime[i-1];
1103                                         if(grecordholder[i])
1104                                                 strunzone(grecordholder[i]);
1105                                         grecordholder[i] = strzone(grecordholder[i-1]);
1106                                 }
1107                         } else if (del) { // a record has been deleted by the admin
1108                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1109                                         if (i == RANKINGS_CNT-1) { // clear out last record
1110                                                 grecordtime[i] = 0;
1111                                                 if (grecordholder[i])
1112                                                         strunzone(grecordholder[i]);
1113                                                 grecordholder[i] = string_null;
1114                                         }
1115                                         else {
1116                                                 grecordtime[i] = grecordtime[i+1];
1117                                                 if (grecordholder[i])
1118                                                         strunzone(grecordholder[i]);
1119                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1120                                         }
1121                                 }
1122                         } else { // player has no ranked record yet
1123                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1124                                         grecordtime[i] = grecordtime[i-1];
1125                                         if(grecordholder[i])
1126                                                 strunzone(grecordholder[i]);
1127                                         grecordholder[i] = strzone(grecordholder[i-1]);
1128                                 }
1129                         }
1130
1131                         // store new ranking
1132                         if(grecordholder[pos-1] != "")
1133                                 strunzone(grecordholder[pos-1]);
1134                         grecordholder[pos-1] = strzone(ReadString());
1135                         grecordtime[pos-1] = ReadInt24_t();
1136                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1137                                 race_myrank = pos;
1138                         break;
1139                 case RACE_NET_SERVER_STATUS:
1140                         race_status = ReadShort();
1141                         if(race_status_name)
1142                                 strunzone(race_status_name);
1143                         race_status_name = strzone(ReadString());
1144         }
1145 }
1146
1147 void Net_TeamNagger()
1148 {
1149         teamnagger = 1;
1150 }
1151
1152 void Net_ReadPingPLReport()
1153 {
1154         int e, pi, pl, ml;
1155         e = ReadByte();
1156         pi = ReadShort();
1157         pl = ReadByte();
1158         ml = ReadByte();
1159         if (!(playerslots[e]))
1160                 return;
1161         playerslots[e].ping = pi;
1162         playerslots[e].ping_packetloss = pl / 255.0;
1163         playerslots[e].ping_movementloss = ml / 255.0;
1164 }
1165
1166 void Net_WeaponComplain()
1167 {
1168         complain_weapon = ReadByte();
1169
1170         if(complain_weapon_name)
1171                 strunzone(complain_weapon_name);
1172         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1173
1174         complain_weapon_type = ReadByte();
1175
1176         complain_weapon_time = time;
1177         weapontime = time; // ping the weapon panel
1178
1179         switch(complain_weapon_type)
1180         {
1181                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1182                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1183                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1184         }
1185 }
1186
1187 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1188 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1189 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1190 float CSQC_Parse_TempEntity()
1191 {
1192         float bHandled;
1193                 bHandled  = true;
1194         // Acquire TE ID
1195         float nTEID;
1196                 nTEID = ReadByte();
1197
1198         if(autocvar_developer_csqcentities)
1199                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1200
1201                 // NOTE: Could just do return instead of break...
1202         switch(nTEID)
1203         {
1204                 case TE_CSQC_TARGET_MUSIC:
1205                         Net_TargetMusic();
1206                         bHandled = true;
1207                         break;
1208                 case TE_CSQC_PICTURE:
1209                         Net_MapVote_Picture();
1210                         bHandled = true;
1211                         break;
1212                 case TE_CSQC_RACE:
1213                         Net_ReadRace();
1214                         bHandled = true;
1215                         break;
1216                 case TE_CSQC_VORTEXBEAMPARTICLE:
1217                         Net_ReadVortexBeamParticle();
1218                         bHandled = true;
1219                         break;
1220                 case TE_CSQC_TEAMNAGGER:
1221                         Net_TeamNagger();
1222                         bHandled = true;
1223                         break;
1224                 case TE_CSQC_ARC:
1225                         Net_ReadArc();
1226                         bHandled = true;
1227                         break;
1228                 case TE_CSQC_PINGPLREPORT:
1229                         Net_ReadPingPLReport();
1230                         bHandled = true;
1231                         break;
1232                 case TE_CSQC_WEAPONCOMPLAIN:
1233                         Net_WeaponComplain();
1234                         bHandled = true;
1235                         break;
1236                 case TE_CSQC_VEHICLESETUP:
1237                         Net_VehicleSetup();
1238                         bHandled = true;
1239                         break;
1240                 case TE_CSQC_SVNOTICE:
1241                         cl_notice_read();
1242                         bHandled = true;
1243                         break;
1244                 case TE_CSQC_SHOCKWAVEPARTICLE:
1245                         Net_ReadShockwaveParticle();
1246                         bHandled = true;
1247                         break;
1248                 default:
1249                         // No special logic for this temporary entity; return 0 so the engine can handle it
1250                         bHandled = false;
1251                         break;
1252         }
1253
1254         return bHandled;
1255 }
1256
1257 string getcommandkey(string text, string command)
1258 {
1259         string keys;
1260         float n, j, k, l = 0;
1261
1262         if (!autocvar_hud_showbinds)
1263                 return text;
1264
1265         keys = db_get(binddb, command);
1266         if (keys == "")
1267         {
1268                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1269                 for(j = 0; j < n; ++j)
1270                 {
1271                         k = stof(argv(j));
1272                         if(k != -1)
1273                         {
1274                                 if ("" == keys)
1275                                         keys = keynumtostring(k);
1276                                 else
1277                                         keys = strcat(keys, ", ", keynumtostring(k));
1278
1279                                 ++l;
1280                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1281                                         break;
1282                         }
1283
1284                 }
1285                 if (keys == "")
1286                         keys = "NO_KEY";
1287                 db_put(binddb, command, keys);
1288         }
1289
1290         if (keys == "NO_KEY") {
1291                 if (autocvar_hud_showbinds > 1)
1292                         return sprintf(_("%s (not bound)"), text);
1293                 else
1294                         return text;
1295         }
1296         else if (autocvar_hud_showbinds > 1)
1297                 return sprintf("%s (%s)", text, keys);
1298         else
1299                 return keys;
1300 }