qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = func_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(NUM_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 158         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 159
 160         WaypointSprite_Load();
 161
 162         // precaches
 163         precache_model("null");
 164         precache_sound("misc/hit.wav");
 165         precache_sound("misc/typehit.wav");
 166         if (autocvar_cl_precacheplayermodels)
 167         {
 168                 precache_all_playermodels("models/player/*.zym");
 169                 precache_all_playermodels("models/player/*.dpm");
 170                 precache_all_playermodels("models/player/*.md3");
 171                 precache_all_playermodels("models/player/*.psk");
 172                 precache_all_playermodels("models/player/*.iqm");
 173         }
 174
 175         Projectile_Precache();
 176         Hook_Precache();
 177         GibSplash_Precache();
 178         Casings_Precache();
 179         DamageInfo_Precache();
 180         Vehicles_Precache();
 181         turrets_precache();
 182         Tuba_Precache();
 183         CSQCPlayer_Precache();
 184
 185         if(autocvar_cl_reticle)
 186         {
 187                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 188                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 189         }
 190
 191         get_mi_min_max_texcoords(1); // try the CLEVER way first
 192         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 193         shortmapname = mi_shortname;
 194
 195         if(precache_pic(minimapname) == "")
 196         {
 197                 // but maybe we have a non-clever minimap
 198                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 199                 if(precache_pic(minimapname) == "")
 200                         minimapname = ""; // FAIL
 201                 else
 202                         get_mi_min_max_texcoords(0); // load new texcoords
 203         }
 204
 205         mi_center = (mi_min + mi_max) * 0.5;
 206         mi_scale = mi_max - mi_min;
 207         minimapname = strzone(minimapname);
 208
 209         WarpZone_Init();
 210
 211         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 212         hud_configure_prev = -1;
 213         tab_panel = -1;
 214
 215         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 216 }
 217
 218 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 219 void Shutdown(void)
 220 {
 221 #ifdef USE_FTE
 222 #pragma TARGET id
 223         if(!__engine_check)
 224                 return 0;
 225 #pragma TARGET fte
 226 #endif
 227
 228         WarpZone_Shutdown();
 229
 230         remove(teams);
 231         remove(players);
 232         db_close(binddb);
 233         db_close(tempdb);
 234         if(autocvar_cl_db_saveasdump)
 235                 db_dump(ClientProgsDB, "client.db");
 236         else
 237                 db_save(ClientProgsDB, "client.db");
 238         db_close(ClientProgsDB);
 239
 240         if(camera_active)
 241                 cvar_set("chase_active",ftos(chase_active_backup));
 242
 243         // unset the event chasecam's chase_active
 244         if(autocvar_chase_active < 0)
 245                 cvar_set("chase_active", "0");
 246
 247         if not(isdemo())
 248         {
 249                 if not(calledhooks & HOOK_START)
 250                         localcmd("\n_cl_hook_gamestart nop\n");
 251                 if not(calledhooks & HOOK_END)
 252                         localcmd("\ncl_hook_gameend\n");
 253         }
 254 }
 255
 256 .float has_team;
 257 float SetTeam(entity o, float Team)
 258 {
 259         entity tm;
 260         if(teamplay)
 261         {
 262                 switch(Team)
 263                 {
 264                         case -1:
 265                         case NUM_TEAM_1:
 266                         case NUM_TEAM_2:
 267                         case NUM_TEAM_3:
 268                         case NUM_TEAM_4:
 269                                 break;
 270                         default:
 271                                 if(GetTeam(Team, false) == world)
 272                                 {
 273                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 274                                         Team = NUM_SPECTATOR;
 275                                 }
 276                                 break;
 277                 }
 278         }
 279         else
 280         {
 281                 switch(Team)
 282                 {
 283                         case -1:
 284                         case 0:
 285                                 break;
 286                         default:
 287                                 if(GetTeam(Team, false) == world)
 288                                 {
 289                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 290                                         Team = NUM_SPECTATOR;
 291                                 }
 292                                 break;
 293                 }
 294         }
 295         if(Team == -1) // leave
 296         {
 297                 if(o.has_team)
 298                 {
 299                         tm = GetTeam(o.team, false);
 300                         tm.team_size -= 1;
 301                         o.has_team = 0;
 302                         return TRUE;
 303                 }
 304         }
 305         else
 306         {
 307                 if not(o.has_team)
 308                 {
 309                         o.team = Team;
 310                         tm = GetTeam(Team, true);
 311                         tm.team_size += 1;
 312                         o.has_team = 1;
 313                         return TRUE;
 314                 }
 315                 else if(Team != o.team)
 316                 {
 317                         tm = GetTeam(o.team, false);
 318                         tm.team_size -= 1;
 319                         o.team = Team;
 320                         tm = GetTeam(Team, true);
 321                         tm.team_size += 1;
 322                         return TRUE;
 323                 }
 324         }
 325         return FALSE;
 326 }
 327
 328 void Playerchecker_Think()
 329 {
 330         float i;
 331         entity e;
 332         for(i = 0; i < maxclients; ++i)
 333         {
 334                 e = playerslots[i];
 335                 if(GetPlayerName(i) == "")
 336                 {
 337                         if(e.sort_prev)
 338                         {
 339                                 // player disconnected
 340                                 SetTeam(e, -1);
 341                                 RemovePlayer(e);
 342                                 e.sort_prev = world;
 343                                 //e.gotscores = 0;
 344                         }
 345                 }
 346                 else
 347                 {
 348                         if not(e.sort_prev)
 349                         {
 350                                 // player connected
 351                                 if not(e)
 352                                         playerslots[i] = e = spawn();
 353                                 e.sv_entnum = i;
 354                                 e.ping = 0;
 355                                 e.ping_packetloss = 0;
 356                                 e.ping_movementloss = 0;
 357                                 //e.gotscores = 0; // we might already have the scores...
 358                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 359                                 RegisterPlayer(e);
 360                                 HUD_UpdatePlayerPos(e);
 361                         }
 362                 }
 363         }
 364         self.nextthink = time + 0.2;
 365 }
 366
 367 void Porto_Init();
 368 void TrueAim_Init();
 369 void PostInit(void)
 370 {
 371         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 372
 373         entity playerchecker;
 374         playerchecker = spawn();
 375         playerchecker.think = Playerchecker_Think;
 376         playerchecker.nextthink = time + 0.2;
 377
 378         Porto_Init();
 379         TrueAim_Init();
 380
 381         postinit = true;
 382 }
 383
 384 float button_zoom;
 385
 386 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 387 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 388 // All keys are in ascii.
 389 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 390 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 391 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 392 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 393 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 394 {
 395         float bSkipKey;
 396         bSkipKey = false;
 397
 398         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 399                 return true;
 400
 401         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 402                 return true;
 403
 404         if(menu_visible && menu_action)
 405                 if(menu_action(bInputType, nPrimary, nSecondary))
 406                         return TRUE;
 407
 408         return bSkipKey;
 409 }
 410
 411 // END REQUIRED CSQC FUNCTIONS
 412 // --------------------------------------------------------------------------
 413
 414 // --------------------------------------------------------------------------
 415 // BEGIN OPTIONAL CSQC FUNCTIONS
 416 void Ent_RemoveEntCS()
 417 {
 418         entcs_receiver[self.sv_entnum] = world;
 419 }
 420 void Ent_ReadEntCS()
 421 {
 422         float sf;
 423         InterpolateOrigin_Undo();
 424
 425         self.classname = "entcs_receiver";
 426         sf = ReadByte();
 427
 428         if(sf & 1)
 429                 self.sv_entnum = ReadByte();
 430         if(sf & 2)
 431         {
 432                 self.origin_x = ReadShort();
 433                 self.origin_y = ReadShort();
 434                 self.origin_z = ReadShort();
 435                 setorigin(self, self.origin);
 436         }
 437         if(sf & 4)
 438         {
 439                 self.angles_y = ReadByte() * 360.0 / 256;
 440                 self.angles_x = self.angles_z = 0;
 441         }
 442         if(sf & 8)
 443                 self.healthvalue = ReadByte() * 10;
 444         if(sf & 16)
 445                 self.armorvalue = ReadByte() * 10;
 446
 447         entcs_receiver[self.sv_entnum] = self;
 448         self.entremove = Ent_RemoveEntCS;
 449         self.iflags |= IFLAG_ORIGIN;
 450
 451         InterpolateOrigin_Note();
 452 }
 453
 454 void Ent_Remove();
 455
 456 void Ent_RemovePlayerScore()
 457 {
 458         float i;
 459
 460         if(self.owner)
 461         {
 462                 SetTeam(self.owner, -1);
 463                 self.owner.gotscores = 0;
 464                 for(i = 0; i < MAX_SCORE; ++i)
 465                         self.owner.(scores[i]) = 0; // clear all scores
 466         }
 467 }
 468
 469 void Ent_ReadPlayerScore()
 470 {
 471         float i, n;
 472         float isNew;
 473         entity o;
 474
 475         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 476         // (no I've never heard of M-x replace-string, sed, or anything like that)
 477         isNew = !self.owner; // workaround for DP bug
 478         n = ReadByte()-1;
 479
 480 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 481         if(!isNew && n != self.sv_entnum)
 482         {
 483                 //print(_("A CSQC entity changed its owner!\n"));
 484                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 485                 isNew = true;
 486                 Ent_Remove();
 487                 self.enttype = ENT_CLIENT_SCORES;
 488         }
 489 #endif
 490
 491         self.sv_entnum = n;
 492
 493         if not(playerslots[self.sv_entnum])
 494                 playerslots[self.sv_entnum] = spawn();
 495         o = self.owner = playerslots[self.sv_entnum];
 496         o.sv_entnum = self.sv_entnum;
 497         o.gotscores = 1;
 498
 499         //if not(o.sort_prev)
 500         //      RegisterPlayer(o);
 501         //playerchecker will do this for us later, if it has not already done so
 502
 503         float sf, lf;
 504 #if MAX_SCORE <= 8
 505         sf = ReadByte();
 506         lf = ReadByte();
 507 #else
 508         sf = ReadShort();
 509         lf = ReadShort();
 510 #endif
 511         float p;
 512         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 513                 if(sf & p)
 514                 {
 515                         if(lf & p)
 516                                 o.(scores[i]) = ReadInt24_t();
 517                         else
 518                                 o.(scores[i]) = ReadChar();
 519                 }
 520
 521         if(o.sort_prev)
 522                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 523
 524         self.entremove = Ent_RemovePlayerScore;
 525 }
 526
 527 void Ent_ReadTeamScore()
 528 {
 529         float i;
 530         entity o;
 531
 532         self.team = ReadByte();
 533         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 534
 535         float sf, lf;
 536 #if MAX_TEAMSCORE <= 8
 537         sf = ReadByte();
 538         lf = ReadByte();
 539 #else
 540         sf = ReadShort();
 541         lf = ReadShort();
 542 #endif
 543         float p;
 544         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 545                 if(sf & p)
 546                 {
 547                         if(lf & p)
 548                                 o.(teamscores[i]) = ReadInt24_t();
 549                         else
 550                                 o.(teamscores[i]) = ReadChar();
 551                 }
 552
 553         HUD_UpdateTeamPos(o);
 554 }
 555
 556 void Ent_ClientData()
 557 {
 558         float f;
 559         float newspectatee_status;
 560
 561         f = ReadByte();
 562
 563         scoreboard_showscores_force = (f & 1);
 564
 565         if(f & 2)
 566         {
 567                 newspectatee_status = ReadByte();
 568                 if(newspectatee_status == player_localnum + 1)
 569                         newspectatee_status = -1; // observing
 570         }
 571         else
 572                 newspectatee_status = 0;
 573
 574         spectatorbutton_zoom = (f & 4);
 575
 576         if(f & 8)
 577         {
 578                 angles_held_status = 1;
 579                 angles_held_x = ReadAngle();
 580                 angles_held_y = ReadAngle();
 581                 angles_held_z = 0;
 582         }
 583         else
 584                 angles_held_status = 0;
 585
 586         if(newspectatee_status != spectatee_status)
 587         {
 588                 // clear race stuff
 589                 race_laptime = 0;
 590                 race_checkpointtime = 0;
 591         }
 592         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 593         {
 594                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 595                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 596                 )
 597                         prev_p_health = -1;
 598                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 599                         prev_health = -1;
 600         }
 601         spectatee_status = newspectatee_status;
 602
 603         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 604 }
 605
 606 void Ent_Nagger()
 607 {
 608         float nags, i, j, b, f;
 609
 610         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 611
 612         if(!(nags & 4))
 613         {
 614                 if(vote_called_vote)
 615                         strunzone(vote_called_vote);
 616                 vote_called_vote = string_null;
 617                 vote_active = 0;
 618         }
 619         else
 620         {
 621                 vote_active = 1;
 622         }
 623
 624         if(nags & 64)
 625         {
 626                 vote_yescount = ReadByte();
 627                 vote_nocount = ReadByte();
 628                 vote_needed = ReadByte();
 629                 vote_highlighted = ReadChar();
 630         }
 631
 632         if(nags & 128)
 633         {
 634                 if(vote_called_vote)
 635                         strunzone(vote_called_vote);
 636                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 637         }
 638
 639         if(nags & 1)
 640         {
 641                 for(j = 0; j < maxclients; ++j)
 642                         if(playerslots[j])
 643                                 playerslots[j].ready = 1;
 644                 for(i = 1; i <= maxclients; i += 8)
 645                 {
 646                         f = ReadByte();
 647                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 648                                 if not(f & b)
 649                                         if(playerslots[j])
 650                                                 playerslots[j].ready = 0;
 651                 }
 652         }
 653
 654         ready_waiting = (nags & 1);
 655         ready_waiting_for_me = (nags & 2);
 656         vote_waiting = (nags & 4);
 657         vote_waiting_for_me = (nags & 8);
 658         warmup_stage = (nags & 16);
 659 }
 660
 661 void Ent_RandomSeed()
 662 {
 663         float s;
 664         prandom_debug();
 665         s = ReadShort();
 666         psrandom(s);
 667 }
 668
 669 void Ent_ReadAccuracy(void)
 670 {
 671         float sf, f, w, b;
 672         sf = ReadInt24_t();
 673         if(sf == 0)
 674         {
 675                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 676                         weapon_accuracy[w] = -1;
 677                 return;
 678         }
 679
 680         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 681         {
 682                 if(sf & f)
 683                 {
 684                         b = ReadByte();
 685                         if(b == 0)
 686                                 weapon_accuracy[w] = -1;
 687                         else if(b == 255)
 688                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 689                         else
 690                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 691                 }
 692                 if(f == 0x800000)
 693                         f = 1;
 694                 else
 695                         f *= 2;
 696         }
 697 }
 698
 699 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 700 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 701 void Ent_RadarLink();
 702 void Ent_Init();
 703 void Ent_ScoresInfo();
 704 void CSQC_Ent_Update(float bIsNewEntity)
 705 {
 706         float t;
 707         float savetime;
 708         t = ReadByte();
 709
 710         if(autocvar_developer_csqcentities)
 711                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 712
 713         // set up the "time" global for received entities to be correct for interpolation purposes
 714         savetime = time;
 715         if(servertime)
 716         {
 717                 time = servertime;
 718         }
 719         else
 720         {
 721                 serverprevtime = time;
 722                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 723                 time = serverprevtime + serverdeltatime;
 724         }
 725
 726 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 727         if(self.enttype)
 728         {
 729                 if(t != self.enttype || bIsNewEntity)
 730                 {
 731                         //print(_("A CSQC entity changed its type!\n"));
 732                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 733                         Ent_Remove();
 734                         clearentity(self);
 735                         bIsNewEntity = 1;
 736                 }
 737         }
 738         else
 739         {
 740                 if(!bIsNewEntity)
 741                 {
 742                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 743                         bIsNewEntity = 1;
 744                 }
 745         }
 746 #endif
 747         self.enttype = t;
 748         switch(t)
 749         {
 750                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 751                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 752                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 753                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 754                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 755                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 756                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 757                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 758                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 759                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 760                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 761                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 762                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 763                 case ENT_CLIENT_INIT: Ent_Init(); break;
 764                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 765                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 766                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 767                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 768                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 769                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 770                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 771                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 772                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 773                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 774                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 775                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 776                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 777                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 778                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 779                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 780                 case ENT_CLIENT_TURRET: ent_turret(); break;
 781                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 782                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 783                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 784                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 785                 default:
 786                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 787                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 788                         break;
 789         }
 790
 791         time = savetime;
 792 }
 793 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 794 // used when an entity changes its type. For an entity that someone interacts
 795 // with others, make sure it can no longer do so.
 796 void Ent_Remove()
 797 {
 798         if(self.entremove)
 799                 self.entremove();
 800
 801         if(self.skeletonindex)
 802         {
 803                 skel_delete(self.skeletonindex);
 804                 self.skeletonindex = 0;
 805         }
 806
 807         if(self.snd_looping > 0)
 808         {
 809                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 810                 self.snd_looping = 0;
 811         }
 812
 813         self.enttype = 0;
 814         self.classname = "";
 815         self.draw = menu_sub_null;
 816         self.entremove = menu_sub_null;
 817         // TODO possibly set more stuff to defaults
 818 }
 819 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 820 void CSQC_Ent_Remove()
 821 {
 822         if(autocvar_developer_csqcentities)
 823                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 824
 825         if(wasfreed(self))
 826         {
 827                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 828                 return;
 829         }
 830         if(self.enttype)
 831                 Ent_Remove();
 832         remove(self);
 833 }
 834
 835 void Gamemode_Init()
 836 {
 837         if not(isdemo())
 838         {
 839                 if(!(calledhooks & HOOK_START))
 840                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 841                 calledhooks |= HOOK_START;
 842         }
 843 }
 844 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 845 void CSQC_Parse_StuffCmd(string strMessage)
 846 {
 847         if(autocvar_developer_csqcentities)
 848                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 849
 850         localcmd(strMessage);
 851 }
 852 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 853 void CSQC_Parse_Print(string strMessage)
 854 {
 855         if(autocvar_developer_csqcentities)
 856                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 857
 858         print(ColorTranslateRGB(strMessage));
 859 }
 860
 861 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 862 void CSQC_Parse_CenterPrint(string strMessage)
 863 {
 864         if(autocvar_developer_csqcentities)
 865                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 866
 867         centerprint_hud(strMessage);
 868 }
 869
 870 string notranslate_fogcmd1 = "\nfog ";
 871 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 872 void Fog_Force()
 873 {
 874         // TODO somehow thwart prvm_globalset client ...
 875
 876         if(forcefog != "")
 877                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 878 }
 879
 880 void Gamemode_Init();
 881 void Ent_ScoresInfo()
 882 {
 883         float i;
 884         self.classname = "ent_client_scores_info";
 885         gametype = ReadInt24_t();
 886         for(i = 0; i < MAX_SCORE; ++i)
 887         {
 888                 scores_label[i] = strzone(ReadString());
 889                 scores_flags[i] = ReadByte();
 890         }
 891         for(i = 0; i < MAX_TEAMSCORE; ++i)
 892         {
 893                 teamscores_label[i] = strzone(ReadString());
 894                 teamscores_flags[i] = ReadByte();
 895         }
 896         HUD_InitScores();
 897         Gamemode_Init();
 898 }
 899
 900 void Ent_Init()
 901 {
 902         self.classname = "ent_client_init";
 903
 904         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 905
 906         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 907         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 908         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 909         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 910         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 911         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 912         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 913         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 914         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 915         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 916         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 917         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 918
 919         if(forcefog)
 920                 strunzone(forcefog);
 921         forcefog = strzone(ReadString());
 922
 923         armorblockpercent = ReadByte() / 255.0;
 924
 925         g_weaponswitchdelay = ReadByte() / 255.0;
 926
 927         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 928         g_balance_grenadelauncher_bouncestop = ReadCoord();
 929         g_balance_electro_secondary_bouncefactor = ReadCoord();
 930         g_balance_electro_secondary_bouncestop = ReadCoord();
 931
 932         nex_scope = !ReadByte();
 933         rifle_scope = !ReadByte();
 934
 935         serverflags = ReadByte();
 936
 937         minelayer_maxmines = ReadByte();
 938
 939         hagar_maxrockets = ReadByte();
 940
 941         g_trueaim_minrange = ReadCoord();
 942         g_balance_porto_secondary = ReadByte();
 943
 944         if(!postinit)
 945                 PostInit();
 946 }
 947
 948 void Net_ReadRace()
 949 {
 950         float b;
 951
 952         b = ReadByte();
 953
 954         switch(b)
 955         {
 956                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 957                         race_checkpoint = ReadByte();
 958                         race_time = ReadInt24_t();
 959                         race_previousbesttime = ReadInt24_t();
 960                         if(race_previousbestname)
 961                                 strunzone(race_previousbestname);
 962                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 963
 964                         race_checkpointtime = time;
 965
 966                         if(race_checkpoint == 0 || race_checkpoint == 254)
 967                         {
 968                                 race_penaltyaccumulator = 0;
 969                                 race_laptime = time; // valid
 970                         }
 971
 972                         break;
 973
 974                 case RACE_NET_CHECKPOINT_CLEAR:
 975                         race_laptime = 0;
 976                         race_checkpointtime = 0;
 977                         break;
 978
 979                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 980                         race_laptime = ReadCoord();
 981                         race_checkpointtime = -99999;
 982                         // fall through
 983                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 984                         race_nextcheckpoint = ReadByte();
 985
 986                         race_nextbesttime = ReadInt24_t();
 987                         if(race_nextbestname)
 988                                 strunzone(race_nextbestname);
 989                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 990                         break;
 991
 992                 case RACE_NET_CHECKPOINT_HIT_RACE:
 993                         race_mycheckpoint = ReadByte();
 994                         race_mycheckpointtime = time;
 995                         race_mycheckpointdelta = ReadInt24_t();
 996                         race_mycheckpointlapsdelta = ReadByte();
 997                         if(race_mycheckpointlapsdelta >= 128)
 998                                 race_mycheckpointlapsdelta -= 256;
 999                         if(race_mycheckpointenemy)
1000                                 strunzone(race_mycheckpointenemy);
1001                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1002                         break;
1003
1004                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1005                         race_othercheckpoint = ReadByte();
1006                         race_othercheckpointtime = time;
1007                         race_othercheckpointdelta = ReadInt24_t();
1008                         race_othercheckpointlapsdelta = ReadByte();
1009                         if(race_othercheckpointlapsdelta >= 128)
1010                                 race_othercheckpointlapsdelta -= 256;
1011                         if(race_othercheckpointenemy)
1012                                 strunzone(race_othercheckpointenemy);
1013                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1014                         break;
1015
1016                 case RACE_NET_PENALTY_RACE:
1017                         race_penaltyeventtime = time;
1018                         race_penaltytime = ReadShort();
1019                         //race_penaltyaccumulator += race_penaltytime;
1020                         if(race_penaltyreason)
1021                                 strunzone(race_penaltyreason);
1022                         race_penaltyreason = strzone(ReadString());
1023                         break;
1024
1025                 case RACE_NET_PENALTY_QUALIFYING:
1026                         race_penaltyeventtime = time;
1027                         race_penaltytime = ReadShort();
1028                         race_penaltyaccumulator += race_penaltytime;
1029                         if(race_penaltyreason)
1030                                 strunzone(race_penaltyreason);
1031                         race_penaltyreason = strzone(ReadString());
1032                         break;
1033
1034                 case RACE_NET_SERVER_RECORD:
1035                         race_server_record = ReadInt24_t();
1036                         break;
1037                 case RACE_NET_SPEED_AWARD:
1038                         race_speedaward = ReadInt24_t();
1039                         if(race_speedaward_holder)
1040                                 strunzone(race_speedaward_holder);
1041                         race_speedaward_holder = strzone(ReadString());
1042                         break;
1043                 case RACE_NET_SPEED_AWARD_BEST:
1044                         race_speedaward_alltimebest = ReadInt24_t();
1045                         if(race_speedaward_alltimebest_holder)
1046                                 strunzone(race_speedaward_alltimebest_holder);
1047                         race_speedaward_alltimebest_holder = strzone(ReadString());
1048                         break;
1049                 case RACE_NET_SERVER_RANKINGS:
1050                         float pos, prevpos, del;
1051                         pos = ReadShort();
1052                         prevpos = ReadShort();
1053                         del = ReadShort();
1054
1055                         // move other rankings out of the way
1056                         float i;
1057                         if (prevpos) {
1058                                 for (i=prevpos-1;i>pos-1;--i) {
1059                                         grecordtime[i] = grecordtime[i-1];
1060                                         if(grecordholder[i])
1061                                                 strunzone(grecordholder[i]);
1062                                         grecordholder[i] = strzone(grecordholder[i-1]);
1063                                 }
1064                         } else if (del) { // a record has been deleted by the admin
1065                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1066                                         if (i == RANKINGS_CNT-1) { // clear out last record
1067                                                 grecordtime[i] = 0;
1068                                                 if (grecordholder[i])
1069                                                         strunzone(grecordholder[i]);
1070                                                 grecordholder[i] = string_null;
1071                                         }
1072                                         else {
1073                                                 grecordtime[i] = grecordtime[i+1];
1074                                                 if (grecordholder[i])
1075                                                         strunzone(grecordholder[i]);
1076                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1077                                         }
1078                                 }
1079                         } else { // player has no ranked record yet
1080                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1081                                         grecordtime[i] = grecordtime[i-1];
1082                                         if(grecordholder[i])
1083                                                 strunzone(grecordholder[i]);
1084                                         grecordholder[i] = strzone(grecordholder[i-1]);
1085                                 }
1086                         }
1087
1088                         // store new ranking
1089                         if(grecordholder[pos-1] != "")
1090                                 strunzone(grecordholder[pos-1]);
1091                         grecordholder[pos-1] = strzone(ReadString());
1092                         grecordtime[pos-1] = ReadInt24_t();
1093                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1094                                 race_myrank = pos;
1095                         break;
1096                 case RACE_NET_SERVER_STATUS:
1097                         race_status = ReadShort();
1098                         if(race_status_name)
1099                                 strunzone(race_status_name);
1100                         race_status_name = strzone(ReadString());
1101         }
1102 }
1103
1104 void Net_ReadSpawn()
1105 {
1106         zoomin_effect = 1;
1107         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
1108
1109         if(autocvar_cl_unpress_zoom_on_spawn)
1110         {
1111                 localcmd("-zoom\n");
1112                 button_zoom = FALSE;
1113         }
1114 }
1115
1116 void Net_TeamNagger()
1117 {
1118         teamnagger = 1;
1119 }
1120
1121 void Net_ReadPingPLReport()
1122 {
1123         float e, pi, pl, ml;
1124         e = ReadByte();
1125         pi = ReadShort();
1126         pl = ReadByte();
1127         ml = ReadByte();
1128         if not(playerslots[e])
1129                 return;
1130         playerslots[e].ping = pi;
1131         playerslots[e].ping_packetloss = pl / 255.0;
1132         playerslots[e].ping_movementloss = ml / 255.0;
1133 }
1134
1135 void Net_WeaponComplain()
1136 {
1137         complain_weapon = ReadByte();
1138
1139         if(complain_weapon_name)
1140                 strunzone(complain_weapon_name);
1141         complain_weapon_name = strzone(ReadString());
1142
1143         complain_weapon_type = ReadByte();
1144
1145         complain_weapon_time = time;
1146         weapontime = time; // ping the weapon panel
1147
1148         switch(complain_weapon_type)
1149         {
1150                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1151                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1152                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1153         }
1154 }
1155
1156 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1157 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1158 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1159 float CSQC_Parse_TempEntity()
1160 {
1161         float bHandled;
1162                 bHandled  = true;
1163         // Acquire TE ID
1164         float nTEID;
1165                 nTEID = ReadByte();
1166
1167         if(autocvar_developer_csqcentities)
1168                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1169
1170                 // NOTE: Could just do return instead of break...
1171         switch(nTEID)
1172         {
1173                 case TE_CSQC_TARGET_MUSIC:
1174                         Net_TargetMusic();
1175                         bHandled = true;
1176                         break;
1177                 case TE_CSQC_PICTURE:
1178                         Net_MapVote_Picture();
1179                         bHandled = true;
1180                         break;
1181                 case TE_CSQC_RACE:
1182                         Net_ReadRace();
1183                         bHandled = true;
1184                         break;
1185                 case TE_CSQC_SPAWN:
1186                         Net_ReadSpawn();
1187                         bHandled = true;
1188                         break;
1189                 case TE_CSQC_ZCURVEPARTICLES:
1190                         Net_ReadZCurveParticles();
1191                         bHandled = true;
1192                         break;
1193                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1194                         Net_ReadNexgunBeamParticle();
1195                         bHandled = true;
1196                         break;
1197                 case TE_CSQC_TEAMNAGGER:
1198                         Net_TeamNagger();
1199                         bHandled = true;
1200                         break;
1201                 case TE_CSQC_LIGHTNINGARC:
1202                         Net_ReadLightningarc();
1203                         bHandled = true;
1204                         break;
1205                 case TE_CSQC_PINGPLREPORT:
1206                         Net_ReadPingPLReport();
1207                         bHandled = true;
1208                         break;
1209                 case TE_CSQC_WEAPONCOMPLAIN:
1210                         Net_WeaponComplain();
1211                         bHandled = true;
1212                         break;
1213                 case TE_CSQC_VEHICLESETUP:
1214                         Net_VehicleSetup();
1215                         bHandled = true;
1216                         break;
1217                 case TE_CSQC_SVNOTICE:
1218                         cl_notice_read();
1219                         bHandled = true;
1220                         break;
1221                 default:
1222                         // No special logic for this temporary entity; return 0 so the engine can handle it
1223                         bHandled = false;
1224                         break;
1225         }
1226
1227         return bHandled;
1228 }
1229
1230 string getcommandkey(string text, string command)
1231 {
1232         string keys;
1233         float n, j, k, l = 0;
1234
1235         if (!autocvar_hud_showbinds)
1236                 return text;
1237
1238         keys = db_get(binddb, command);
1239         if (keys == "")
1240         {
1241                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1242                 for(j = 0; j < n; ++j)
1243                 {
1244                         k = stof(argv(j));
1245                         if(k != -1)
1246                         {
1247                                 if ("" == keys)
1248                                         keys = keynumtostring(k);
1249                                 else
1250                                         keys = strcat(keys, ", ", keynumtostring(k));
1251
1252                                 ++l;
1253                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1254                                         break;
1255                         }
1256
1257                 }
1258                 if (keys == "")
1259                         keys = "NO_KEY";
1260                 db_put(binddb, command, keys);
1261         }
1262
1263         if (keys == "NO_KEY") {
1264                 if (autocvar_hud_showbinds > 1)
1265                         return sprintf(_("%s (not bound)"), text);
1266                 else
1267                         return text;
1268         }
1269         else if (autocvar_hud_showbinds > 1)
1270                 return sprintf(_("%s (%s)"), text, keys);
1271         else
1272                 return keys;
1273 }