speed up more csqc ent drawing
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / Main.qc
1 // --------------------------------------------------------------------------
2 // BEGIN REQUIRED CSQC FUNCTIONS
3 //include "main.qh"
4
5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
6
7 void cvar_clientsettemp(string cv, string val)
8 {
9         entity e;
10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
11                 if(e.netname == cv)
12                         goto saved;
13         e = spawn();
14         e.classname = "saved_cvar_value";
15         e.netname = strzone(cv);
16         e.message = strzone(cvar_string(cv));
17 :saved
18         cvar_set(cv, val);
19 }
20
21 void cvar_clientsettemp_restore()
22 {
23         entity e;
24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
25                         cvar_set(e.netname, e.message);
26 }
27
28 void() menu_show_error =
29 {
30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
31 };
32
33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
34 // Useful for precaching things
35
36 void() menu_sub_null =
37 {
38 };
39
40 #ifdef USE_FTE
41 float __engine_check;
42 #endif
43
44 string forcefog;
45 string cl_announcer_prev;
46 void WaypointSprite_Load();
47 void CSQC_Init(void)
48 {
49 #ifdef USE_FTE
50 #pragma target ID
51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
52         if(!__engine_check)
53         {
54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
55                 localcmd("\ndisconnect\n");
56                 return;
57         }
58 #pragma target FTE
59 #endif
60         
61         check_unacceptable_compiler_bugs();
62
63 #ifdef WATERMARK
64         print("^4CSQC Build information: ", WATERMARK(), "\n");
65 #endif
66
67         float i;
68         CSQC_CheckEngine();
69
70         binddb = db_create();
71         tempdb = db_create();
72         ClientProgsDB = db_load("client.db");
73         compressShortVector_init();
74
75         drawfont = 0;
76         menu_visible = FALSE;
77         menu_show = menu_show_error;
78         menu_action = menu_sub_null;
79
80         for(i = 0; i < 255; ++i)
81                 if(getplayerkey(i, "viewentity") == "")
82                         break;
83         maxclients = i;
84
85         //ctf_temp_1 = "";
86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
87         //registercmd("ctf_menu");
88         registercmd("ons_map");
89         registercmd("hud_configure");
90         registercmd("hud_save");
91         //registercmd("menu_action");
92
93         registercmd("+button3");
94         registercmd("-button3");
95         registercmd("+button4");
96         registercmd("-button4");
97         registercmd("+showscores");registercmd("-showscores");
98         registercmd("+showaccuracy");registercmd("-showaccuracy");
99
100 #ifndef CAMERATEST
101         if(isdemo())
102         {
103 #endif
104                 registercmd("+forward");registercmd("-forward");
105                 registercmd("+back");registercmd("-back");
106                 registercmd("+moveup");registercmd("-moveup");
107                 registercmd("+movedown");registercmd("-movedown");
108                 registercmd("+moveright");registercmd("-moveright");
109                 registercmd("+moveleft");registercmd("-moveleft");
110                 registercmd("+roll_right");registercmd("-roll_right");
111                 registercmd("+roll_left");registercmd("-roll_left");
112 #ifndef CAMERATEST
113         }
114 #endif
115         registercvar("hud_usecsqc", "1");
116         registercvar("scoreboard_columns", "default", CVAR_SAVE);
117
118         gametype = 0;
119
120         // hud_fields uses strunzone on the titles!
121         for(i = 0; i < MAX_HUD_FIELDS; ++i)
122                 hud_title[i] = strzone("(null)");
123
124         postinit = false;
125
126         calledhooks = 0;
127
128         teams = Sort_Spawn();
129         players = Sort_Spawn();
130
131         GetTeam(COLOR_SPECTATOR, true); // add specs first
132
133         RegisterWeapons();
134
135         WaypointSprite_Load();
136
137         // precaches
138         Projectile_Precache();
139         Hook_Precache();
140         GibSplash_Precache();
141         Casings_Precache();
142         DamageInfo_Precache();
143         if(cvar_string("cl_announcer") != cl_announcer_prev) {
144                 Announcer_Precache();
145                 if(cl_announcer_prev)
146                         strunzone(cl_announcer_prev);
147                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
148         }
149         Tuba_Precache();
150
151         get_mi_min_max_texcoords(1); // try the CLEVER way first
152         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
153         shortmapname = mi_shortname;
154
155         if(precache_pic(minimapname) == "")
156         {
157                 // but maybe we have a non-clever minimap
158                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
159                 if(precache_pic(minimapname) == "")
160                         minimapname = ""; // FAIL
161                 else
162                         get_mi_min_max_texcoords(0); // load new texcoords
163         }
164
165         mi_center = (mi_min + mi_max) * 0.5;
166         mi_scale = mi_max - mi_min;
167         minimapname = strzone(minimapname);
168
169         WarpZone_Init();
170         hud_configure_prev = -1;
171 }
172
173 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
174 void CSQC_Shutdown(void)
175 {
176 #ifdef USE_FTE
177 #pragma TARGET id
178         if(!__engine_check)
179                 return 0;
180 #pragma TARGET fte
181 #endif
182
183         WarpZone_Shutdown();
184
185         remove(teams);
186         remove(players);
187         db_close(binddb);
188         db_close(tempdb);
189         db_save(ClientProgsDB, "client.db");
190         db_close(ClientProgsDB);
191
192         cvar_clientsettemp_restore();
193
194         if(camera_active)
195                 cvar_set("chase_active",ftos(chase_active_backup));
196
197         if not(isdemo())
198         {
199                 if not(calledhooks & HOOK_START)
200                         localcmd("\n_cl_hook_gamestart nop\n");
201                 if not(calledhooks & HOOK_END)
202                         localcmd("\ncl_hook_gameend\n");
203         }
204 }
205
206 .float has_team;
207 float SetTeam(entity o, float Team)
208 {
209         entity tm;
210         if(teamplay)
211         {
212                 switch(Team)
213                 {
214                         case -1:
215                         case COLOR_TEAM1:
216                         case COLOR_TEAM2:
217                         case COLOR_TEAM3:
218                         case COLOR_TEAM4:
219                                 break;
220                         default:
221                                 if(GetTeam(Team, false) == NULL)
222                                 {
223                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
224                                         Team = COLOR_SPECTATOR;
225                                 }
226                                 break;
227                 }
228         }
229         else
230         {
231                 switch(Team)
232                 {
233                         case -1:
234                         case 0:
235                                 break;
236                         default:
237                                 if(GetTeam(Team, false) == NULL)
238                                 {
239                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
240                                         Team = COLOR_SPECTATOR;
241                                 }
242                                 break;
243                 }
244         }
245         if(Team == -1) // leave
246         {
247                 if(o.has_team)
248                 {
249                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
250                         tm = GetTeam(o.team, false);
251                         tm.team_size -= 1;
252                         o.has_team = 0;
253                         return TRUE;
254                 }
255         }
256         else
257         {
258                 if not(o.has_team)
259                 {
260                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
261                         o.team = Team;
262                         tm = GetTeam(Team, true);
263                         tm.team_size += 1;
264                         o.has_team = 1;
265                         return TRUE;
266                 }
267                 else if(Team != o.team)
268                 {
269                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
270                         tm = GetTeam(o.team, false);
271                         tm.team_size -= 1;
272                         o.team = Team;
273                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
274                         tm = GetTeam(Team, true);
275                         tm.team_size += 1;
276                         return TRUE;
277                 }
278         }
279         return FALSE;
280 }
281
282 void Playerchecker_Think()
283 {
284         float i;
285         entity e;
286         for(i = 0; i < maxclients; ++i)
287         {
288                 e = playerslots[i];
289                 if(GetPlayerName(i) == "")
290                 {
291                         if(e.sort_prev)
292                         {
293                                 //print("playerchecker: KILL KILL KILL\n");
294                                 // player disconnected
295                                 SetTeam(e, -1);
296                                 RemovePlayer(e);
297                                 e.sort_prev = world;
298                                 //e.gotscores = 0;
299                         }
300                 }
301                 else
302                 {
303                         if not(e.sort_prev)
304                         {
305                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
306                                 // player connected
307                                 if not(e)
308                                         playerslots[i] = e = spawn();
309                                 e.sv_entnum = i;
310                                 e.ping = 0;
311                                 e.ping_packetloss = 0;
312                                 e.ping_movementloss = 0;
313                                 //e.gotscores = 0; // we might already have the scores...
314                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
315                                 RegisterPlayer(e);
316                                 HUD_UpdatePlayerPos(e);
317                         }
318                 }
319         }
320         self.nextthink = time + 0.2;
321 }
322
323 void Porto_Init();
324 void TrueAim_Init();
325 void PostInit(void)
326 {
327         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
328         localcmd(strcat("\nscoreboard_columns_set ", cvar_string("scoreboard_columns"), ";\n"));
329
330         entity playerchecker;
331         playerchecker = spawn();
332         playerchecker.think = Playerchecker_Think;
333         playerchecker.nextthink = time + 0.2;
334
335         Porto_Init();
336         TrueAim_Init();
337
338         postinit = true;
339 }
340
341 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
342 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
343 float button_zoom;
344 void Cmd_HUD_SetFields(float);
345 void Cmd_HUD_Help(float);
346 float CSQC_ConsoleCommand(string strMessage)
347 {
348         float argc;
349         // Tokenize String
350         //argc = tokenize(strMessage);
351         argc = tokenize_console(strMessage);
352
353         // Acquire Command
354         local string strCmd;
355         strCmd = argv(0);
356
357         if(strCmd == "hud_configure") { // config hud
358                 cvar_set("_hud_configure", ftos(!cvar("_hud_configure")));
359                 return true;
360         } else if(strCmd == "hud_save") { // save hud config
361                 if(argv(1) == "" || argv(2)) {
362                         print("Usage:\n");
363                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
364                 }
365                 else
366                         HUD_Panel_ExportCfg(argv(1));
367                 return true;
368         } else if(strCmd == "+button4") { // zoom
369                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
370                 if(ignore_plus_zoom)
371                 {
372                         --ignore_plus_zoom;
373                         return false;
374                 }
375                 button_zoom = 1;
376                 return true;
377         } else if(strCmd == "-button4") { // zoom
378                 if(ignore_minus_zoom)
379                 {
380                         --ignore_minus_zoom;
381                         return false;
382                 }
383                 button_zoom = 0;
384                 return true;
385         } else if(strCmd == "+button3") { // secondary
386                 button_attack2 = 1;
387                 return false;
388         } else if(strCmd == "-button3") { // secondary
389                 button_attack2 = 0;
390                 return false;
391         } else if(strCmd == "+showscores") {
392                 scoreboard_showscores = true;
393                 return true;
394         } else if(strCmd == "-showscores") {
395                 scoreboard_showscores = false;
396                 return true;
397         } else if(strCmd == "+showaccuracy") {
398                 scoreboard_showaccuracy = true;
399                 return true;
400         } else if(strCmd == "-showaccuracy") {
401                 scoreboard_showaccuracy = false;
402                 return true;
403         }
404
405         if(camera_active)
406         if(strCmd == "+forward" || strCmd == "-back") {
407                 ++camera_direction_x;
408                 return true;
409         } else if(strCmd == "-forward" || strCmd == "+back") {
410                 --camera_direction_x;
411                 return true;
412         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
413                 --camera_direction_y;
414                 return true;
415         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
416                 ++camera_direction_y;
417                 return true;
418         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
419                 ++camera_direction_z;
420                 return true;
421         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
422                 --camera_direction_z;
423                 return true;
424         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
425                 ++camera_roll;
426                 return true;
427         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
428                 --camera_roll;
429                 return true;
430         }
431
432         return false;
433 }
434
435 .vector view_ofs;
436 entity debug_shotorg;
437 void ShotOrg_Draw()
438 {
439         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
440         self.angles = view_angles;
441         self.angles_x = -self.angles_x;
442         if not(self.cnt)
443                 self.drawmask = MASK_NORMAL;
444         else
445                 self.drawmask = 0;
446 }
447 void ShotOrg_Draw2D()
448 {
449         vector coord2d_topleft, coord2d_topright, coord2d;
450         string s;
451         vector fs;
452
453         s = vtos(self.view_ofs);
454         s = substring(s, 1, strlen(s) - 2);
455         if(tokenize_console(s) == 3)
456                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
457
458         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
459         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
460
461         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
462
463         coord2d = coord2d_topleft;
464         if(fs_x < 8)
465         {
466                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
467                 fs = '8 8 0';
468         }
469         coord2d_y -= fs_y;
470         coord2d_z = 0;
471         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
472 }
473
474 void ShotOrg_Spawn()
475 {
476         debug_shotorg = spawn();
477         debug_shotorg.draw = ShotOrg_Draw;
478         debug_shotorg.draw2d = ShotOrg_Draw2D;
479         debug_shotorg.renderflags = RF_VIEWMODEL;
480         debug_shotorg.effects = EF_FULLBRIGHT;
481         precache_model("models/shotorg_adjuster.md3");
482         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
483         debug_shotorg.scale = 2;
484         debug_shotorg.view_ofs = '25 8 -8';
485 }
486
487 void DrawDebugModel()
488 {
489         if(time - floor(time) > 0.5)
490         {
491                 PolyDrawModel(self);
492                 self.drawmask = 0;
493         }
494         else
495         {
496                 self.renderflags = 0;
497                 self.drawmask = MASK_NORMAL;
498         }
499 }
500
501 void GameCommand(string msg)
502 {
503         string s;
504         float argc;
505         entity e;
506         argc = tokenize_console(msg);
507
508         if(argv(0) == "help" || argc == 0)
509         {
510                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
511                 print("  settemp cvar value\n");
512                 print("  scoreboard_columns_set ...\n");
513                 print("  scoreboard_columns_help\n");
514                 GameCommand_Generic("help");
515                 return;
516         }
517
518         if(GameCommand_Generic(msg))
519                 return;
520
521         string cmd;
522         cmd = argv(0);
523         if(cmd == "mv_download") {
524                 Cmd_MapVote_MapDownload(argc);
525         }
526         else if(cmd == "settemp") {
527                 cvar_clientsettemp(argv(1), argv(2));
528         }
529         else if(cmd == "scoreboard_columns_set") {
530                 Cmd_HUD_SetFields(argc);
531         }
532         else if(cmd == "scoreboard_columns_help") {
533                 Cmd_HUD_Help(argc);
534         }
535 #ifdef BLURTEST
536         else if(cmd == "blurtest") {
537                 blurtest_time0 = time;
538                 blurtest_time1 = time + stof(argv(1));
539                 blurtest_radius = stof(argv(2));
540                 blurtest_power = stof(argv(3));
541         }
542 #endif
543         else if(cmd == "shotorg_move") {
544                 if(!debug_shotorg)
545                         ShotOrg_Spawn();
546                 else
547                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
548                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
549         }
550         else if(cmd == "shotorg_movez") {
551                 if(!debug_shotorg)
552                         ShotOrg_Spawn();
553                 else
554                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
555                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
556         }
557         else if(cmd == "shotorg_set") {
558                 if(!debug_shotorg)
559                         ShotOrg_Spawn();
560                 else
561                         debug_shotorg.view_ofs = stov(argv(1));
562                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
563         }
564         else if(cmd == "shotorg_setz") {
565                 if(!debug_shotorg)
566                         ShotOrg_Spawn();
567                 else
568                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
569                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
570         }
571         else if(cmd == "shotorg_toggle_hide") {
572                 if(debug_shotorg)
573                 {
574                         debug_shotorg.cnt = !debug_shotorg.cnt;
575                 }
576         }
577         else if(cmd == "shotorg_end") {
578                 if(debug_shotorg)
579                 {
580                         print(vtos(debug_shotorg.view_ofs), "\n");
581                         remove(debug_shotorg);
582                         debug_shotorg = world;
583                 }
584                 localcmd("sv_cmd debug_shotorg\n");
585         }
586         else if(cmd == "sendcvar") {
587                 // W_FixWeaponOrder will trash argv, so save what we need.
588                 string thiscvar;
589                 thiscvar = strzone(argv(1));
590                 s = cvar_string(thiscvar);
591                 if(thiscvar == "cl_weaponpriority")
592                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
593                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
594                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
595                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
596                 strunzone(thiscvar);
597         }
598         else if(cmd == "spawn") {
599                 s = argv(1);
600                 e = spawn();
601                 precache_model(s);
602                 setmodel(e, s);
603                 setorigin(e, view_origin);
604                 e.angles = view_angles;
605                 e.draw = DrawDebugModel;
606                 e.classname = "debugmodel";
607         }
608         else
609         {
610                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
611         }
612
613         return;
614 }
615
616 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
617 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
618 // All keys are in ascii.
619 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
620 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
621 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
622 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
623 {
624         local float bSkipKey;
625         bSkipKey = false;
626
627         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
628                 return true;
629
630         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
631                 return true;
632
633         if(menu_visible)
634                 if(menu_action(bInputType, nPrimary, nSecondary))
635                         return TRUE;
636         return bSkipKey;
637 }
638
639 // END REQUIRED CSQC FUNCTIONS
640 // --------------------------------------------------------------------------
641
642 // --------------------------------------------------------------------------
643 // BEGIN OPTIONAL CSQC FUNCTIONS
644 void Ent_ReadEntCS()
645 {
646         InterpolateOrigin_Undo();
647
648         self.classname = "entcs_receiver";
649         self.sv_entnum = ReadByte() - 1;
650         self.origin_x = ReadShort();
651         self.origin_y = ReadShort();
652         self.origin_z = ReadShort();
653         self.angles_y = ReadByte() * 360.0 / 256;
654         self.origin_z = self.angles_x = self.angles_z = 0;
655
656         InterpolateOrigin_Note();
657 }
658
659 void Ent_Remove();
660
661 void Ent_RemovePlayerScore()
662 {
663         float i;
664
665         if(self.owner)
666         {
667                 SetTeam(self.owner, -1);
668                 self.owner.gotscores = 0;
669                 for(i = 0; i < MAX_SCORE; ++i)
670                         self.owner.(scores[i]) = 0; // clear all scores
671         }
672 }
673
674 void Ent_ReadPlayerScore()
675 {
676         float i, n;
677         float isNew;
678         entity o;
679
680         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
681         // (no I've never heard of M-x replace-string, sed, or anything like that)
682         isNew = !self.owner; // workaround for DP bug
683         n = ReadByte()-1;
684
685 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
686         if(!isNew && n != self.sv_entnum)
687         {
688                 print("A CSQC entity changed its owner!\n");
689                 isNew = true;
690                 Ent_Remove();
691                 self.enttype = ENT_CLIENT_SCORES;
692         }
693 #endif
694
695         self.sv_entnum = n;
696
697         if not(playerslots[self.sv_entnum])
698                 playerslots[self.sv_entnum] = spawn();
699         o = self.owner = playerslots[self.sv_entnum];
700         o.sv_entnum = self.sv_entnum;
701         o.gotscores = 1;
702
703         //if not(o.sort_prev)
704         //      RegisterPlayer(o);
705         //playerchecker will do this for us later, if it has not already done so
706
707         float sf, lf;
708 #if MAX_SCORE <= 8
709         sf = ReadByte();
710         lf = ReadByte();
711 #else
712         sf = ReadShort();
713         lf = ReadShort();
714 #endif
715         float p;
716         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
717                 if(sf & p)
718                 {
719                         if(lf & p)
720                                 o.(scores[i]) = ReadInt24_t();
721                         else
722                                 o.(scores[i]) = ReadChar();
723                 }
724
725         if(o.sort_prev)
726                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
727
728         self.entremove = Ent_RemovePlayerScore;
729 }
730
731 void Ent_ReadTeamScore()
732 {
733         float i;
734         entity o;
735
736         self.team = ReadByte();
737         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
738
739         float sf, lf;
740 #if MAX_TEAMSCORE <= 8
741         sf = ReadByte();
742         lf = ReadByte();
743 #else
744         sf = ReadShort();
745         lf = ReadShort();
746 #endif
747         float p;
748         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
749                 if(sf & p)
750                 {
751                         if(lf & p)
752                                 o.(teamscores[i]) = ReadInt24_t();
753                         else
754                                 o.(teamscores[i]) = ReadChar();
755                 }
756
757         HUD_UpdateTeamPos(o);
758 }
759
760 void Net_Reset()
761 {
762 }
763
764 void Ent_ClientData()
765 {
766         float f;
767         float newspectatee_status;
768
769         f = ReadByte();
770
771         scoreboard_showscores_force = (f & 1);
772
773         if(f & 2)
774         {
775                 newspectatee_status = ReadByte();
776                 if(newspectatee_status == player_localentnum)
777                         newspectatee_status = -1; // observing
778         }
779         else
780                 newspectatee_status = 0;
781
782         spectatorbutton_zoom = (f & 4);
783
784         if(f & 8)
785         {
786                 angles_held_status = 1;
787                 angles_held_x = ReadAngle();
788                 angles_held_y = ReadAngle();
789                 angles_held_z = 0;
790         }
791         else
792                 angles_held_status = 0;
793
794         if(newspectatee_status != spectatee_status)
795         {
796                 float i;
797                 // clear the weapon accuracy stats
798                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
799                         weapon_hits[i] = 0;
800                         weapon_fired[i] = 0;
801                 }
802
803                 // clear race stuff
804                 race_laptime = 0;
805                 race_checkpointtime = 0;
806         }
807         spectatee_status = newspectatee_status;
808 }
809
810 void Ent_Nagger()
811 {
812         float nags, i, j, b, f;
813
814         nags = ReadByte();
815
816         if(nags & 128)
817         {
818                 if(vote_called_vote)
819                         strunzone(vote_called_vote);
820                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
821         }
822
823         if(nags & 1)
824         {
825                 for(j = 0; j < maxclients; ++j)
826                         if(playerslots[j])
827                                 playerslots[j].ready = 1;
828                 for(i = 1; i <= maxclients; i += 8)
829                 {
830                         f = ReadByte();
831                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
832                                 if not(f & b)
833                                         if(playerslots[j])
834                                                 playerslots[j].ready = 0;
835                 }
836         }
837
838         ready_waiting = (nags & 1);
839         ready_waiting_for_me = (nags & 2);
840         vote_waiting = (nags & 4);
841         vote_waiting_for_me = (nags & 8);
842         warmup_stage = (nags & 16);
843 }
844
845 void Ent_RandomSeed()
846 {
847         float s;
848         prandom_debug();
849         s = ReadShort();
850         psrandom(s);
851 }
852
853 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
854 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
855 void Ent_RadarLink();
856 void Ent_Init();
857 void Ent_ScoresInfo();
858 void(float bIsNewEntity) CSQC_Ent_Update =
859 {
860         float t;
861         float savetime;
862         t = ReadByte();
863
864         // set up the "time" global for received entities to be correct for interpolation purposes
865         savetime = time;
866         if(servertime)
867         {
868                 time = servertime;
869         }
870         else
871         {
872                 serverprevtime = time;
873                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
874                 time = serverprevtime + serverdeltatime;
875         }
876
877 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
878         if(self.enttype)
879                 if(t != self.enttype)
880                 {
881                         print("A CSQC entity changed its type!\n");
882                         Ent_Remove();
883                         bIsNewEntity = 1;
884                 }
885 #endif
886         self.enttype = t;
887         switch(t)
888         {
889                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
890                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
891                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
892                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
893                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
894                 case ENT_CLIENT_LASER: Ent_Laser(); break;
895                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
896                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
897                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
898                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
899                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
900                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
901                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
902                 case ENT_CLIENT_INIT: Ent_Init(); break;
903                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
904                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
905                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
906                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
907                 case ENT_CLIENT_WALL: Ent_Wall(); break;
908                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
909                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
910                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
911                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
912                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
913                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
914                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
915                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
916                 default:
917                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
918                         break;
919         }
920
921         time = savetime;
922 };
923 // Destructor, but does NOT deallocate the entity by calling remove(). Also
924 // used when an entity changes its type. For an entity that someone interacts
925 // with others, make sure it can no longer do so.
926 void Ent_Remove()
927 {
928         if(self.entremove)
929                 self.entremove();
930
931         self.enttype = 0;
932         self.classname = "";
933         self.draw = menu_sub_null;
934         self.entremove = menu_sub_null;
935         // TODO possibly set more stuff to defaults
936 }
937 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
938 void CSQC_Ent_Remove()
939 {
940         if(self.enttype)
941                 Ent_Remove();
942         remove(self);
943 }
944
945 void Gamemode_Init()
946 {
947         if(gametype == GAME_ONSLAUGHT) {
948                 print(strcat("Using ", minimapname, " as minimap.\n"));
949                 precache_pic("gfx/ons-cp-neutral.tga");
950                 precache_pic("gfx/ons-cp-red.tga");
951                 precache_pic("gfx/ons-cp-blue.tga");
952                 precache_pic("gfx/ons-frame.tga");
953                 precache_pic("gfx/ons-frame-team.tga");
954         }
955
956         if not(isdemo())
957         {
958                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
959                 calledhooks |= HOOK_START;
960         }
961 }
962 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
963 void CSQC_Parse_StuffCmd(string strMessage)
964 {
965         localcmd(strMessage);
966 }
967 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
968 void CSQC_Parse_Print(string strMessage)
969 {
970         print(ColorTranslateRGB(strMessage));
971 }
972
973 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
974 void CSQC_Parse_CenterPrint(string strMessage)
975 {
976         centerprint(strMessage);
977 }
978
979 string notranslate_fogcmd1 = "\nfog ";
980 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
981 void Fog_Force()
982 {
983         // TODO somehow thwart prvm_globalset client ...
984
985         if(forcefog != "")
986                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
987 }
988
989 void Gamemode_Init();
990 void Ent_ScoresInfo()
991 {
992         float i;
993         self.classname = "ent_client_scores_info";
994         gametype = ReadByte();
995         for(i = 0; i < MAX_SCORE; ++i)
996         {
997                 scores_label[i] = strzone(ReadString());
998                 scores_flags[i] = ReadByte();
999         }
1000         for(i = 0; i < MAX_TEAMSCORE; ++i)
1001         {
1002                 teamscores_label[i] = strzone(ReadString());
1003                 teamscores_flags[i] = ReadByte();
1004         }
1005         HUD_InitScores();
1006         Gamemode_Init();
1007 }
1008
1009 void Ent_Init()
1010 {
1011         self.classname = "ent_client_init";
1012
1013         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1014
1015         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1016         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1017         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1018         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1019         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1020         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1021         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1022         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1023         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1024         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1025         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1026         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1027
1028         if(forcefog)
1029                 strunzone(forcefog);
1030         forcefog = strzone(ReadString());
1031
1032         armorblockpercent = ReadByte() / 255.0;
1033
1034         g_weaponswitchdelay = ReadByte() / 255.0;
1035
1036         g_balance_grenadelauncher_secondary_bouncefactor = ReadCoord();
1037         g_balance_grenadelauncher_secondary_bouncestop = ReadCoord();
1038
1039         nex_scope = !ReadByte();
1040         campingrifle_scope = !ReadByte();
1041
1042         if(!postinit)
1043                 PostInit();
1044 }
1045
1046 void Net_ReadRace()
1047 {
1048         float b;
1049
1050         b = ReadByte();
1051
1052         switch(b)
1053         {
1054                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1055                         race_checkpoint = ReadByte();
1056                         race_time = ReadInt24_t();
1057                         race_previousbesttime = ReadInt24_t();
1058                         if(race_previousbestname)
1059                                 strunzone(race_previousbestname);
1060                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1061
1062                         race_checkpointtime = time;
1063
1064                         if(race_checkpoint == 0 || race_checkpoint == 254)
1065                         {
1066                                 race_penaltyaccumulator = 0;
1067                                 race_laptime = time; // valid
1068                         }
1069
1070                         break;
1071
1072                 case RACE_NET_CHECKPOINT_CLEAR:
1073                         race_laptime = 0;
1074                         race_checkpointtime = 0;
1075                         break;
1076
1077                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1078                         race_laptime = ReadCoord();
1079                         race_checkpointtime = -99999;
1080                         // fall through
1081                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1082                         race_nextcheckpoint = ReadByte();
1083
1084                         race_nextbesttime = ReadInt24_t();
1085                         if(race_nextbestname)
1086                                 strunzone(race_nextbestname);
1087                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1088                         break;
1089
1090                 case RACE_NET_CHECKPOINT_HIT_RACE:
1091                         race_mycheckpoint = ReadByte();
1092                         race_mycheckpointtime = time;
1093                         race_mycheckpointdelta = ReadInt24_t();
1094                         race_mycheckpointlapsdelta = ReadByte();
1095                         if(race_mycheckpointlapsdelta >= 128)
1096                                 race_mycheckpointlapsdelta -= 256;
1097                         if(race_mycheckpointenemy)
1098                                 strunzone(race_mycheckpointenemy);
1099                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1100                         break;
1101
1102                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1103                         race_othercheckpoint = ReadByte();
1104                         race_othercheckpointtime = time;
1105                         race_othercheckpointdelta = ReadInt24_t();
1106                         race_othercheckpointlapsdelta = ReadByte();
1107                         if(race_othercheckpointlapsdelta >= 128)
1108                                 race_othercheckpointlapsdelta -= 256;
1109                         if(race_othercheckpointenemy)
1110                                 strunzone(race_othercheckpointenemy);
1111                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1112                         break;
1113
1114                 case RACE_NET_PENALTY_RACE:
1115                         race_penaltyeventtime = time;
1116                         race_penaltytime = ReadShort();
1117                         //race_penaltyaccumulator += race_penaltytime;
1118                         if(race_penaltyreason)
1119                                 strunzone(race_penaltyreason);
1120                         race_penaltyreason = strzone(ReadString());
1121                         break;
1122
1123                 case RACE_NET_PENALTY_QUALIFYING:
1124                         race_penaltyeventtime = time;
1125                         race_penaltytime = ReadShort();
1126                         race_penaltyaccumulator += race_penaltytime;
1127                         if(race_penaltyreason)
1128                                 strunzone(race_penaltyreason);
1129                         race_penaltyreason = strzone(ReadString());
1130                         break;
1131
1132                 case RACE_NET_SERVER_RECORD:
1133                         race_server_record = ReadInt24_t();
1134                         break;
1135                 case RACE_NET_SPEED_AWARD:
1136                         race_speedaward = ReadInt24_t();
1137                         if(race_speedaward_holder)
1138                                 strunzone(race_speedaward_holder);
1139                         race_speedaward_holder = strzone(ReadString());
1140                         break;
1141                 case RACE_NET_SPEED_AWARD_BEST:
1142                         race_speedaward_alltimebest = ReadInt24_t();
1143                         if(race_speedaward_alltimebest_holder)
1144                                 strunzone(race_speedaward_alltimebest_holder);
1145                         race_speedaward_alltimebest_holder = strzone(ReadString());
1146                         break;
1147                 case RACE_NET_SERVER_RANKINGS:
1148                         float pos, prevpos, del;
1149                         pos = ReadShort();
1150                         prevpos = ReadShort();
1151                         del = ReadShort();
1152
1153                         // move other rankings out of the way
1154                         float i;
1155                         if (prevpos) {
1156                                 for (i=prevpos-1;i>pos-1;--i) {
1157                                         grecordtime[i] = grecordtime[i-1];
1158                                         if(grecordholder[i])
1159                                                 strunzone(grecordholder[i]);
1160                                         grecordholder[i] = strzone(grecordholder[i-1]);
1161                                 }
1162                         } else if (del) { // a record has been deleted by the admin
1163                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1164                                         if (i == RANKINGS_CNT-1) { // clear out last record
1165                                                 grecordtime[i] = 0;
1166                                                 if (grecordholder[i])
1167                                                         strunzone(grecordholder[i]);
1168                                                 grecordholder[i] = string_null;
1169                                         }
1170                                         else {
1171                                                 grecordtime[i] = grecordtime[i+1];
1172                                                 if (grecordholder[i])
1173                                                         strunzone(grecordholder[i]);
1174                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1175                                         }
1176                                 }
1177                         } else { // player has no ranked record yet
1178                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1179                                         grecordtime[i] = grecordtime[i-1];
1180                                         if(grecordholder[i])
1181                                                 strunzone(grecordholder[i]);
1182                                         grecordholder[i] = strzone(grecordholder[i-1]);
1183                                 }
1184                         }
1185
1186                         // store new ranking
1187                         if(grecordholder[pos-1] != "")
1188                                 strunzone(grecordholder[pos-1]);
1189                         grecordholder[pos-1] = strzone(ReadString());
1190                         grecordtime[pos-1] = ReadInt24_t();
1191                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1192                                 race_myrank = pos;
1193                         break;
1194                 case RACE_NET_SERVER_STATUS:
1195                         race_status = ReadShort();
1196                         if(race_status_name)
1197                                 strunzone(race_status_name);
1198                         race_status_name = strzone(ReadString());
1199         }
1200 }
1201
1202 void Net_ReadSpawn()
1203 {
1204         zoomin_effect = 1;
1205         current_viewzoom = 0.6;
1206 }
1207
1208 void Net_TeamNagger()
1209 {
1210         teamnagger = 1;
1211 }
1212
1213 void Net_ReadPingPLReport()
1214 {
1215         float e, pi, pl, ml;
1216         e = ReadByte();
1217         pi = ReadShort();
1218         pl = ReadByte();
1219         ml = ReadByte();
1220         if not(playerslots[e])
1221                 return;
1222         playerslots[e].ping = pi;
1223         playerslots[e].ping_packetloss = pl / 255.0;
1224         playerslots[e].ping_movementloss = ml / 255.0;
1225 }
1226
1227 void Net_VoteDialog(float highlight) {
1228         if(highlight) {
1229                 vote_highlighted = ReadByte();
1230                 return;
1231         }
1232
1233         vote_yescount = ReadByte();
1234         vote_nocount = ReadByte();
1235         vote_needed = ReadByte();
1236         vote_active = 1;
1237 }
1238
1239 void Net_VoteDialogReset() {
1240         vote_active = 0;
1241 }
1242
1243 void Net_Notify() {
1244         float type;
1245         type = ReadByte();
1246
1247         if(type == CSQC_KILLNOTIFY)
1248         {
1249                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1250         }
1251         else if(type == CSQC_CENTERPRINT)
1252         {
1253                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1254         }
1255 }
1256
1257 void Net_WeaponComplain() {
1258         complain_weapon = ReadByte();
1259
1260         if(complain_weapon_name)
1261                 strunzone(complain_weapon_name);
1262         complain_weapon_name = strzone(ReadString());
1263
1264         complain_weapon_type = ReadByte();
1265
1266         complain_weapon_time = time;
1267         weapontime = time; // ping the weapon panel
1268 }
1269
1270 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1271 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1272 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1273 float CSQC_Parse_TempEntity()
1274 {
1275         local float bHandled;
1276                 bHandled  = true;
1277         // Acquire TE ID
1278         local float nTEID;
1279                 nTEID = ReadByte();
1280
1281                 // NOTE: Could just do return instead of break...
1282         switch(nTEID)
1283         {
1284                 case TE_CSQC_TARGET_MUSIC:
1285                         Net_TargetMusic();
1286                         bHandled = true;
1287                         break;
1288                 case TE_CSQC_PICTURE:
1289                         Net_MapVote_Picture();
1290                         bHandled = true;
1291                         break;
1292                 case TE_CSQC_RACE:
1293                         Net_ReadRace();
1294                         bHandled = true;
1295                         break;
1296                 case TE_CSQC_SPAWN:
1297                         Net_ReadSpawn();
1298                         bHandled = true;
1299                         break;
1300                 case TE_CSQC_ZCURVEPARTICLES:
1301                         Net_ReadZCurveParticles();
1302                         bHandled = true;
1303                         break;
1304                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1305                         Net_ReadNexgunBeamParticle();
1306                         bHandled = true;
1307                         break;
1308                 case TE_CSQC_TEAMNAGGER:
1309                         Net_TeamNagger();
1310                         bHandled = true;
1311                         break;
1312                 case TE_CSQC_VOTE:
1313                         Net_VoteDialog(ReadByte());
1314                         bHandled = true;
1315                         break;
1316                 case TE_CSQC_VOTERESET:
1317                         Net_VoteDialogReset();
1318                         bHandled = true;
1319                         break;
1320                 case TE_CSQC_LIGHTNINGARC:
1321                         Net_ReadLightningarc();
1322                         bHandled = true;
1323                         break;
1324                 case TE_CSQC_PINGPLREPORT:
1325                         Net_ReadPingPLReport();
1326                         bHandled = true;
1327                         break;
1328                 case TE_CSQC_ANNOUNCE:
1329                         announce_snd = strzone(ReadString());
1330                         bHandled = true;
1331                         break;
1332                 case TE_CSQC_NOTIFY:
1333                         Net_Notify();
1334                         bHandled = true;
1335                         break;
1336                 case TE_CSQC_WEAPONCOMPLAIN:
1337                         Net_WeaponComplain();
1338                         bHandled = true;
1339                         break;
1340                 case TE_CSQC_NEX_VELOCITY:
1341                         nex_velocitydependent = ReadByte();
1342                         nex_minvelocity = ReadShort();
1343                         nex_maxvelocity = ReadShort();
1344                         nex_speed_falloff_rate = ReadByte();
1345                         nex_charge = ReadByte();
1346                         nex_charge_rate = ReadByte();
1347                         bHandled = true;
1348                         break;
1349                 case TE_CSQC_CR_MAXBULLETS:
1350                         cr_maxbullets = ReadByte();
1351                         bHandled = true;
1352                         break;
1353                 default:
1354                         // No special logic for this temporary entity; return 0 so the engine can handle it
1355                         bHandled = false;
1356                         break;
1357         }
1358
1359         return bHandled;
1360 }
1361
1362 string getcommandkey(string text, string command)
1363 {
1364         string keys;
1365         float n, j, k, l;
1366
1367         if (!hud_showbinds)
1368                 return text;
1369
1370         keys = db_get(binddb, command);
1371         if (!keys)
1372         {
1373                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1374                 for(j = 0; j < n; ++j)
1375                 {
1376                         k = stof(argv(j));
1377                         if(k != -1)
1378                         {
1379                                 if ("" == keys)
1380                                         keys = keynumtostring(k);
1381                                 else
1382                                         keys = strcat(keys, ", ", keynumtostring(k));
1383
1384                                 ++l;
1385                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1386                         }
1387
1388                 }
1389                 db_put(binddb, command, keys);
1390         }
1391
1392         if ("" == keys) {
1393                 if (hud_showbinds > 1)
1394                         return strcat(text, " (not bound)");
1395                 else
1396                         return text;
1397         }
1398         else if (hud_showbinds > 1)
1399                 return strcat(text, " (", keys, ")");
1400         else
1401                 return keys;
1402 }