qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+showscores");registercmd("-showscores");
  95         registercmd("+showaccuracy");registercmd("-showaccuracy");
  96
  97 #ifndef CAMERATEST
  98         if(isdemo())
  99         {
 100 #endif
 101                 registercmd("+forward");registercmd("-forward");
 102                 registercmd("+back");registercmd("-back");
 103                 registercmd("+moveup");registercmd("-moveup");
 104                 registercmd("+movedown");registercmd("-movedown");
 105                 registercmd("+moveright");registercmd("-moveright");
 106                 registercmd("+moveleft");registercmd("-moveleft");
 107                 registercmd("+roll_right");registercmd("-roll_right");
 108                 registercmd("+roll_left");registercmd("-roll_left");
 109 #ifndef CAMERATEST
 110         }
 111 #endif
 112         registercvar("hud_usecsqc", "1");
 113         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 114
 115         gametype = 0;
 116
 117         // hud_fields uses strunzone on the titles!
 118         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 119                 hud_title[i] = strzone("(null)");
 120
 121         postinit = false;
 122
 123         calledhooks = 0;
 124
 125         teams = Sort_Spawn();
 126         players = Sort_Spawn();
 127
 128         GetTeam(COLOR_SPECTATOR, true); // add specs first
 129
 130         RegisterWeapons();
 131
 132         WaypointSprite_Load();
 133
 134         // precaches
 135         precache_sound("misc/hit.wav");
 136         precache_sound("misc/typehit.wav");
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         if(autocvar_cl_announcer != cl_announcer_prev) {
 143                 Announcer_Precache();
 144                 if(cl_announcer_prev)
 145                         strunzone(cl_announcer_prev);
 146                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 147         }
 148         Tuba_Precache();
 149
 150         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 151         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 152
 153         get_mi_min_max_texcoords(1); // try the CLEVER way first
 154         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 155         shortmapname = mi_shortname;
 156
 157         if(precache_pic(minimapname) == "")
 158         {
 159                 // but maybe we have a non-clever minimap
 160                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 161                 if(precache_pic(minimapname) == "")
 162                         minimapname = ""; // FAIL
 163                 else
 164                         get_mi_min_max_texcoords(0); // load new texcoords
 165         }
 166
 167         mi_center = (mi_min + mi_max) * 0.5;
 168         mi_scale = mi_max - mi_min;
 169         minimapname = strzone(minimapname);
 170
 171         WarpZone_Init();
 172
 173         hud_configure_prev = -1;
 174         tab_panel = -1;
 175 }
 176
 177 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 178 void CSQC_Shutdown(void)
 179 {
 180 #ifdef USE_FTE
 181 #pragma TARGET id
 182         if(!__engine_check)
 183                 return 0;
 184 #pragma TARGET fte
 185 #endif
 186
 187         WarpZone_Shutdown();
 188
 189         remove(teams);
 190         remove(players);
 191         db_close(binddb);
 192         db_close(tempdb);
 193         if(autocvar_cl_db_saveasdump)
 194                 db_dump(ClientProgsDB, "client.db");
 195         else
 196                 db_save(ClientProgsDB, "client.db");
 197         db_close(ClientProgsDB);
 198
 199         cvar_clientsettemp_restore();
 200
 201         if(camera_active)
 202                 cvar_set("chase_active",ftos(chase_active_backup));
 203
 204         // unset the event chasecam's chase_active
 205         if(autocvar_chase_active < 0)
 206                 cvar_set("chase_active", "0");
 207
 208         if not(isdemo())
 209         {
 210                 if not(calledhooks & HOOK_START)
 211                         localcmd("\n_cl_hook_gamestart nop\n");
 212                 if not(calledhooks & HOOK_END)
 213                         localcmd("\ncl_hook_gameend\n");
 214         }
 215 }
 216
 217 .float has_team;
 218 float SetTeam(entity o, float Team)
 219 {
 220         entity tm;
 221         if(teamplay)
 222         {
 223                 switch(Team)
 224                 {
 225                         case -1:
 226                         case COLOR_TEAM1:
 227                         case COLOR_TEAM2:
 228                         case COLOR_TEAM3:
 229                         case COLOR_TEAM4:
 230                                 break;
 231                         default:
 232                                 if(GetTeam(Team, false) == NULL)
 233                                 {
 234                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 235                                         Team = COLOR_SPECTATOR;
 236                                 }
 237                                 break;
 238                 }
 239         }
 240         else
 241         {
 242                 switch(Team)
 243                 {
 244                         case -1:
 245                         case 0:
 246                                 break;
 247                         default:
 248                                 if(GetTeam(Team, false) == NULL)
 249                                 {
 250                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 251                                         Team = COLOR_SPECTATOR;
 252                                 }
 253                                 break;
 254                 }
 255         }
 256         if(Team == -1) // leave
 257         {
 258                 if(o.has_team)
 259                 {
 260                         tm = GetTeam(o.team, false);
 261                         tm.team_size -= 1;
 262                         o.has_team = 0;
 263                         return TRUE;
 264                 }
 265         }
 266         else
 267         {
 268                 if not(o.has_team)
 269                 {
 270                         o.team = Team;
 271                         tm = GetTeam(Team, true);
 272                         tm.team_size += 1;
 273                         o.has_team = 1;
 274                         return TRUE;
 275                 }
 276                 else if(Team != o.team)
 277                 {
 278                         tm = GetTeam(o.team, false);
 279                         tm.team_size -= 1;
 280                         o.team = Team;
 281                         tm = GetTeam(Team, true);
 282                         tm.team_size += 1;
 283                         return TRUE;
 284                 }
 285         }
 286         return FALSE;
 287 }
 288
 289 void Playerchecker_Think()
 290 {
 291         float i;
 292         entity e;
 293         for(i = 0; i < maxclients; ++i)
 294         {
 295                 e = playerslots[i];
 296                 if(GetPlayerName(i) == "")
 297                 {
 298                         if(e.sort_prev)
 299                         {
 300                                 // player disconnected
 301                                 SetTeam(e, -1);
 302                                 RemovePlayer(e);
 303                                 e.sort_prev = world;
 304                                 //e.gotscores = 0;
 305                         }
 306                 }
 307                 else
 308                 {
 309                         if not(e.sort_prev)
 310                         {
 311                                 // player connected
 312                                 if not(e)
 313                                         playerslots[i] = e = spawn();
 314                                 e.sv_entnum = i;
 315                                 e.ping = 0;
 316                                 e.ping_packetloss = 0;
 317                                 e.ping_movementloss = 0;
 318                                 //e.gotscores = 0; // we might already have the scores...
 319                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 320                                 RegisterPlayer(e);
 321                                 HUD_UpdatePlayerPos(e);
 322                         }
 323                 }
 324         }
 325         self.nextthink = time + 0.2;
 326 }
 327
 328 void Porto_Init();
 329 void TrueAim_Init();
 330 void PostInit(void)
 331 {
 332         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 333
 334         entity playerchecker;
 335         playerchecker = spawn();
 336         playerchecker.think = Playerchecker_Think;
 337         playerchecker.nextthink = time + 0.2;
 338
 339         Porto_Init();
 340         TrueAim_Init();
 341
 342         postinit = true;
 343 }
 344
 345 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 346 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 347 float button_zoom;
 348 void Cmd_HUD_SetFields(float);
 349 void Cmd_HUD_Help(float);
 350 float CSQC_ConsoleCommand(string strMessage)
 351 {
 352         float argc;
 353         // Tokenize String
 354         //argc = tokenize(strMessage);
 355         argc = tokenize_console(strMessage);
 356
 357         // Acquire Command
 358         local string strCmd;
 359         strCmd = argv(0);
 360
 361         if(strCmd == "hud_configure") { // config hud
 362                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 363                 return true;
 364         } else if(strCmd == "hud_save") { // save hud config
 365                 if(argv(1) == "" || argv(2)) {
 366                         print(_("Usage:\n"));
 367                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 368                 }
 369                 else
 370                         HUD_Panel_ExportCfg(argv(1));
 371                 return true;
 372         } else if(strCmd == "+showscores") {
 373                 scoreboard_showscores = true;
 374                 return true;
 375         } else if(strCmd == "-showscores") {
 376                 scoreboard_showscores = false;
 377                 return true;
 378         } else if(strCmd == "+showaccuracy") {
 379                 scoreboard_showaccuracy = true;
 380                 return true;
 381         } else if(strCmd == "-showaccuracy") {
 382                 scoreboard_showaccuracy = false;
 383                 return true;
 384         }
 385
 386         if(camera_active)
 387         if(strCmd == "+forward" || strCmd == "-back") {
 388                 ++camera_direction_x;
 389                 return true;
 390         } else if(strCmd == "-forward" || strCmd == "+back") {
 391                 --camera_direction_x;
 392                 return true;
 393         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 394                 --camera_direction_y;
 395                 return true;
 396         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 397                 ++camera_direction_y;
 398                 return true;
 399         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 400                 ++camera_direction_z;
 401                 return true;
 402         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 403                 --camera_direction_z;
 404                 return true;
 405         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 406                 ++camera_roll;
 407                 return true;
 408         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 409                 --camera_roll;
 410                 return true;
 411         }
 412
 413         return false;
 414 }
 415
 416 .vector view_ofs;
 417 entity debug_shotorg;
 418 void ShotOrg_Draw()
 419 {
 420         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 421         self.angles = view_angles;
 422         self.angles_x = -self.angles_x;
 423         if not(self.cnt)
 424                 self.drawmask = MASK_NORMAL;
 425         else
 426                 self.drawmask = 0;
 427 }
 428 void ShotOrg_Draw2D()
 429 {
 430         vector coord2d_topleft, coord2d_topright, coord2d;
 431         string s;
 432         vector fs;
 433
 434         s = vtos(self.view_ofs);
 435         s = substring(s, 1, strlen(s) - 2);
 436         if(tokenize_console(s) == 3)
 437                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 438
 439         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 440         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 441
 442         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 443
 444         coord2d = coord2d_topleft;
 445         if(fs_x < 8)
 446         {
 447                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 448                 fs = '8 8 0';
 449         }
 450         coord2d_y -= fs_y;
 451         coord2d_z = 0;
 452         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 453 }
 454
 455 void ShotOrg_Spawn()
 456 {
 457         debug_shotorg = spawn();
 458         debug_shotorg.draw = ShotOrg_Draw;
 459         debug_shotorg.draw2d = ShotOrg_Draw2D;
 460         debug_shotorg.renderflags = RF_VIEWMODEL;
 461         debug_shotorg.effects = EF_FULLBRIGHT;
 462         precache_model("models/shotorg_adjuster.md3");
 463         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 464         debug_shotorg.scale = 2;
 465         debug_shotorg.view_ofs = '25 8 -8';
 466 }
 467
 468 void DrawDebugModel()
 469 {
 470         if(time - floor(time) > 0.5)
 471         {
 472                 PolyDrawModel(self);
 473                 self.drawmask = 0;
 474         }
 475         else
 476         {
 477                 self.renderflags = 0;
 478                 self.drawmask = MASK_NORMAL;
 479         }
 480 }
 481
 482 void GameCommand(string msg)
 483 {
 484         string s;
 485         float argc;
 486         entity e;
 487         argc = tokenize_console(msg);
 488
 489         if(argv(0) == "help" || argc == 0)
 490         {
 491                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 492                 print(_("  settemp cvar value\n"));
 493                 print(_("  scoreboard_columns_set ...\n"));
 494                 print(_("  scoreboard_columns_help\n"));
 495                 GameCommand_Generic("help");
 496                 return;
 497         }
 498
 499         if(GameCommand_Generic(msg))
 500                 return;
 501
 502         string cmd;
 503         cmd = argv(0);
 504         if(cmd == "mv_download") {
 505                 Cmd_MapVote_MapDownload(argc);
 506         }
 507         else if(cmd == "settemp") {
 508                 cvar_clientsettemp(argv(1), argv(2));
 509         }
 510         else if(cmd == "scoreboard_columns_set") {
 511                 Cmd_HUD_SetFields(argc);
 512         }
 513         else if(cmd == "scoreboard_columns_help") {
 514                 Cmd_HUD_Help(argc);
 515         }
 516 #ifdef BLURTEST
 517         else if(cmd == "blurtest") {
 518                 blurtest_time0 = time;
 519                 blurtest_time1 = time + stof(argv(1));
 520                 blurtest_radius = stof(argv(2));
 521                 blurtest_power = stof(argv(3));
 522         }
 523 #endif
 524         else if(cmd == "shotorg_move") {
 525                 if(!debug_shotorg)
 526                         ShotOrg_Spawn();
 527                 else
 528                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 529                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 530         }
 531         else if(cmd == "shotorg_movez") {
 532                 if(!debug_shotorg)
 533                         ShotOrg_Spawn();
 534                 else
 535                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 536                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 537         }
 538         else if(cmd == "shotorg_set") {
 539                 if(!debug_shotorg)
 540                         ShotOrg_Spawn();
 541                 else
 542                         debug_shotorg.view_ofs = stov(argv(1));
 543                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 544         }
 545         else if(cmd == "shotorg_setz") {
 546                 if(!debug_shotorg)
 547                         ShotOrg_Spawn();
 548                 else
 549                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 550                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 551         }
 552         else if(cmd == "shotorg_toggle_hide") {
 553                 if(debug_shotorg)
 554                 {
 555                         debug_shotorg.cnt = !debug_shotorg.cnt;
 556                 }
 557         }
 558         else if(cmd == "shotorg_end") {
 559                 if(debug_shotorg)
 560                 {
 561                         print(vtos(debug_shotorg.view_ofs), "\n");
 562                         remove(debug_shotorg);
 563                         debug_shotorg = world;
 564                 }
 565                 localcmd("sv_cmd debug_shotorg\n");
 566         }
 567         else if(cmd == "sendcvar") {
 568                 // W_FixWeaponOrder will trash argv, so save what we need.
 569                 string thiscvar;
 570                 thiscvar = strzone(argv(1));
 571                 s = cvar_string(thiscvar);
 572                 if(thiscvar == "cl_weaponpriority")
 573                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 574                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 575                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 576                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 577                 strunzone(thiscvar);
 578         }
 579         else if(cmd == "spawn") {
 580                 s = argv(1);
 581                 e = spawn();
 582                 precache_model(s);
 583                 setmodel(e, s);
 584                 setorigin(e, view_origin);
 585                 e.angles = view_angles;
 586                 e.draw = DrawDebugModel;
 587                 e.classname = "debugmodel";
 588         }
 589     else if(cmd == "vyes")
 590     {
 591         if(uid2name_dialog)
 592         {
 593             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 594             vote_prev = 0;
 595             cvar_set("cl_allow_uid2name", "1");
 596             vote_change = -9999;
 597                         uid2name_dialog = 0;
 598         }
 599         else
 600         {
 601             localcmd("cmd vote yes\n");
 602         }
 603     }
 604     else if(cmd == "vno")
 605     {
 606         if(uid2name_dialog)
 607         {
 608             vote_active = 0;
 609             vote_prev = 0;
 610             cvar_set("cl_allow_uid2name", "0");
 611             vote_change = -9999;
 612                         uid2name_dialog = 0;
 613         }
 614         else
 615         {
 616             localcmd("cmd vote no\n");
 617         }
 618     }
 619
 620         else
 621         {
 622                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 623         }
 624
 625         return;
 626 }
 627
 628 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 629 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 630 // All keys are in ascii.
 631 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 632 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 633 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 634 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 635 {
 636         local float bSkipKey;
 637         bSkipKey = false;
 638
 639         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 640                 return true;
 641
 642         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 643                 return true;
 644
 645         if(menu_visible)
 646                 if(menu_action(bInputType, nPrimary, nSecondary))
 647                         return TRUE;
 648
 649         return bSkipKey;
 650 }
 651
 652 // END REQUIRED CSQC FUNCTIONS
 653 // --------------------------------------------------------------------------
 654
 655 // --------------------------------------------------------------------------
 656 // BEGIN OPTIONAL CSQC FUNCTIONS
 657 void Ent_RemoveEntCS()
 658 {
 659         entcs_receiver[self.sv_entnum] = world;
 660 }
 661 void Ent_ReadEntCS()
 662 {
 663         float sf;
 664         InterpolateOrigin_Undo();
 665
 666         self.classname = "entcs_receiver";
 667         sf = ReadByte();
 668
 669         if(sf & 1)
 670                 self.sv_entnum = ReadByte();
 671         if(sf & 2)
 672         {
 673                 self.origin_x = ReadShort();
 674                 self.origin_y = ReadShort();
 675                 self.origin_z = ReadShort();
 676         }
 677         if(sf & 4)
 678         {
 679                 self.angles_y = ReadByte() * 360.0 / 256;
 680                 self.angles_x = self.angles_z = 0;
 681         }
 682         if(sf & 8)
 683                 self.healthvalue = ReadByte() * 10;
 684         if(sf & 16)
 685                 self.armorvalue = ReadByte() * 10;
 686
 687         entcs_receiver[self.sv_entnum] = self;
 688         self.entremove = Ent_RemoveEntCS;
 689
 690         InterpolateOrigin_Note();
 691 }
 692
 693 void Ent_Remove();
 694
 695 void Ent_RemovePlayerScore()
 696 {
 697         float i;
 698
 699         if(self.owner)
 700         {
 701                 SetTeam(self.owner, -1);
 702                 self.owner.gotscores = 0;
 703                 for(i = 0; i < MAX_SCORE; ++i)
 704                         self.owner.(scores[i]) = 0; // clear all scores
 705         }
 706 }
 707
 708 void Ent_ReadPlayerScore()
 709 {
 710         float i, n;
 711         float isNew;
 712         entity o;
 713
 714         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 715         // (no I've never heard of M-x replace-string, sed, or anything like that)
 716         isNew = !self.owner; // workaround for DP bug
 717         n = ReadByte()-1;
 718
 719 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 720         if(!isNew && n != self.sv_entnum)
 721         {
 722                 //print(_("A CSQC entity changed its owner!\n"));
 723                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 724                 isNew = true;
 725                 Ent_Remove();
 726                 self.enttype = ENT_CLIENT_SCORES;
 727         }
 728 #endif
 729
 730         self.sv_entnum = n;
 731
 732         if not(playerslots[self.sv_entnum])
 733                 playerslots[self.sv_entnum] = spawn();
 734         o = self.owner = playerslots[self.sv_entnum];
 735         o.sv_entnum = self.sv_entnum;
 736         o.gotscores = 1;
 737
 738         //if not(o.sort_prev)
 739         //      RegisterPlayer(o);
 740         //playerchecker will do this for us later, if it has not already done so
 741
 742         float sf, lf;
 743 #if MAX_SCORE <= 8
 744         sf = ReadByte();
 745         lf = ReadByte();
 746 #else
 747         sf = ReadShort();
 748         lf = ReadShort();
 749 #endif
 750         float p;
 751         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 752                 if(sf & p)
 753                 {
 754                         if(lf & p)
 755                                 o.(scores[i]) = ReadInt24_t();
 756                         else
 757                                 o.(scores[i]) = ReadChar();
 758                 }
 759
 760         if(o.sort_prev)
 761                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 762
 763         self.entremove = Ent_RemovePlayerScore;
 764 }
 765
 766 void Ent_ReadTeamScore()
 767 {
 768         float i;
 769         entity o;
 770
 771         self.team = ReadByte();
 772         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 773
 774         float sf, lf;
 775 #if MAX_TEAMSCORE <= 8
 776         sf = ReadByte();
 777         lf = ReadByte();
 778 #else
 779         sf = ReadShort();
 780         lf = ReadShort();
 781 #endif
 782         float p;
 783         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 784                 if(sf & p)
 785                 {
 786                         if(lf & p)
 787                                 o.(teamscores[i]) = ReadInt24_t();
 788                         else
 789                                 o.(teamscores[i]) = ReadChar();
 790                 }
 791
 792         HUD_UpdateTeamPos(o);
 793 }
 794
 795 void Ent_ClientData()
 796 {
 797         float f;
 798         float newspectatee_status;
 799
 800         f = ReadByte();
 801
 802         scoreboard_showscores_force = (f & 1);
 803
 804         if(f & 2)
 805         {
 806                 newspectatee_status = ReadByte();
 807                 if(newspectatee_status == player_localentnum)
 808                         newspectatee_status = -1; // observing
 809         }
 810         else
 811                 newspectatee_status = 0;
 812
 813         spectatorbutton_zoom = (f & 4);
 814
 815         if(f & 8)
 816         {
 817                 angles_held_status = 1;
 818                 angles_held_x = ReadAngle();
 819                 angles_held_y = ReadAngle();
 820                 angles_held_z = 0;
 821         }
 822         else
 823                 angles_held_status = 0;
 824
 825         if(newspectatee_status != spectatee_status)
 826         {
 827                 float i;
 828
 829                 // clear race stuff
 830                 race_laptime = 0;
 831                 race_checkpointtime = 0;
 832         }
 833         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 834         {
 835                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 836                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 837                 )
 838                         prev_p_health = -1;
 839                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 840                         prev_health = -1;
 841         }
 842         spectatee_status = newspectatee_status;
 843 }
 844
 845 void Ent_Nagger()
 846 {
 847         float nags, i, j, b, f;
 848
 849         nags = ReadByte();
 850
 851         if(!(nags & 4))
 852         {
 853                 if(vote_called_vote)
 854                         strunzone(vote_called_vote);
 855                 vote_called_vote = string_null;
 856         }
 857
 858         if(nags & 128)
 859         {
 860                 if(vote_called_vote)
 861                         strunzone(vote_called_vote);
 862                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 863         }
 864
 865         if(nags & 1)
 866         {
 867                 for(j = 0; j < maxclients; ++j)
 868                         if(playerslots[j])
 869                                 playerslots[j].ready = 1;
 870                 for(i = 1; i <= maxclients; i += 8)
 871                 {
 872                         f = ReadByte();
 873                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 874                                 if not(f & b)
 875                                         if(playerslots[j])
 876                                                 playerslots[j].ready = 0;
 877                 }
 878         }
 879
 880         ready_waiting = (nags & 1);
 881         ready_waiting_for_me = (nags & 2);
 882         vote_waiting = (nags & 4);
 883         vote_waiting_for_me = (nags & 8);
 884         warmup_stage = (nags & 16);
 885 }
 886
 887 void Ent_RandomSeed()
 888 {
 889         float s;
 890         prandom_debug();
 891         s = ReadShort();
 892         psrandom(s);
 893 }
 894
 895 void Ent_ReadAccuracy(void)
 896 {
 897         float sf, f, w, b;
 898         sf = ReadInt24_t();
 899         if(sf == 0)
 900         {
 901                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 902                         weapon_accuracy[w] = -1;
 903                 return;
 904         }
 905
 906         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 907         {
 908                 if(sf & f)
 909                 {
 910                         b = ReadByte();
 911                         if(b == 0)
 912                                 weapon_accuracy[w] = -1;
 913                         else if(b == 255)
 914                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 915                         else
 916                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 917                 }
 918         }
 919 }
 920
 921 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 922 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 923 void Ent_RadarLink();
 924 void Ent_Init();
 925 void Ent_ScoresInfo();
 926 void(float bIsNewEntity) CSQC_Ent_Update =
 927 {
 928         float t;
 929         float savetime;
 930         t = ReadByte();
 931
 932         // set up the "time" global for received entities to be correct for interpolation purposes
 933         savetime = time;
 934         if(servertime)
 935         {
 936                 time = servertime;
 937         }
 938         else
 939         {
 940                 serverprevtime = time;
 941                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 942                 time = serverprevtime + serverdeltatime;
 943         }
 944
 945 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 946         if(self.enttype)
 947                 if(t != self.enttype)
 948                 {
 949                         //print(_("A CSQC entity changed its type!\n"));
 950                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 951                         Ent_Remove();
 952                         bIsNewEntity = 1;
 953                 }
 954 #endif
 955         self.enttype = t;
 956         switch(t)
 957         {
 958                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 959                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 960                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 961                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 962                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 963                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 964                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 965                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 966                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 967                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 968                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 969                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 970                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 971                 case ENT_CLIENT_INIT: Ent_Init(); break;
 972                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 973                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 974                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 975                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 976                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 977                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 978                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 979                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 980                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 981                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 982                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 983                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 984                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 985                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 986                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 987                 default:
 988                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 989                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 990                         break;
 991         }
 992
 993         time = savetime;
 994 };
 995 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 996 // used when an entity changes its type. For an entity that someone interacts
 997 // with others, make sure it can no longer do so.
 998 void Ent_Remove()
 999 {
1000         if(self.entremove)
1001                 self.entremove();
1002
1003         self.enttype = 0;
1004         self.classname = "";
1005         self.draw = menu_sub_null;
1006         self.entremove = menu_sub_null;
1007         // TODO possibly set more stuff to defaults
1008 }
1009 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1010 void CSQC_Ent_Remove()
1011 {
1012         if(self.enttype)
1013                 Ent_Remove();
1014         remove(self);
1015 }
1016
1017 void Gamemode_Init()
1018 {
1019         if not(isdemo())
1020         {
1021                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1022                 calledhooks |= HOOK_START;
1023         }
1024 }
1025 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1026 void CSQC_Parse_StuffCmd(string strMessage)
1027 {
1028         localcmd(strMessage);
1029 }
1030 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1031 void CSQC_Parse_Print(string strMessage)
1032 {
1033         print(ColorTranslateRGB(strMessage));
1034 }
1035
1036 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1037 void CSQC_Parse_CenterPrint(string strMessage)
1038 {
1039         centerprint(strMessage);
1040 }
1041
1042 string notranslate_fogcmd1 = "\nfog ";
1043 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1044 void Fog_Force()
1045 {
1046         // TODO somehow thwart prvm_globalset client ...
1047
1048         if(forcefog != "")
1049                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1050 }
1051
1052 void Gamemode_Init();
1053 void Ent_ScoresInfo()
1054 {
1055         float i;
1056         self.classname = "ent_client_scores_info";
1057         gametype = ReadByte();
1058         for(i = 0; i < MAX_SCORE; ++i)
1059         {
1060                 scores_label[i] = strzone(ReadString());
1061                 scores_flags[i] = ReadByte();
1062         }
1063         for(i = 0; i < MAX_TEAMSCORE; ++i)
1064         {
1065                 teamscores_label[i] = strzone(ReadString());
1066                 teamscores_flags[i] = ReadByte();
1067         }
1068         HUD_InitScores();
1069         Gamemode_Init();
1070 }
1071
1072 void Ent_Init()
1073 {
1074         self.classname = "ent_client_init";
1075
1076         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1077
1078         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1079         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1080         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1081         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1082         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1083         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1084         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1085         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1086         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1087         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1088         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1089         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1090
1091         if(forcefog)
1092                 strunzone(forcefog);
1093         forcefog = strzone(ReadString());
1094
1095         armorblockpercent = ReadByte() / 255.0;
1096
1097         g_weaponswitchdelay = ReadByte() / 255.0;
1098
1099         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1100         g_balance_grenadelauncher_bouncestop = ReadCoord();
1101         g_balance_electro_secondary_bouncefactor = ReadCoord();
1102         g_balance_electro_secondary_bouncestop = ReadCoord();
1103
1104         nex_scope = !ReadByte();
1105         rifle_scope = !ReadByte();
1106
1107         serverflags = ReadByte();
1108
1109         minelayer_maxmines = ReadByte();
1110
1111         hagar_maxrockets = ReadByte();
1112
1113         g_trueaim_minrange = ReadCoord();
1114
1115         if(!postinit)
1116                 PostInit();
1117 }
1118
1119 void Net_ReadRace()
1120 {
1121         float b;
1122
1123         b = ReadByte();
1124
1125         switch(b)
1126         {
1127                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1128                         race_checkpoint = ReadByte();
1129                         race_time = ReadInt24_t();
1130                         race_previousbesttime = ReadInt24_t();
1131                         if(race_previousbestname)
1132                                 strunzone(race_previousbestname);
1133                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1134
1135                         race_checkpointtime = time;
1136
1137                         if(race_checkpoint == 0 || race_checkpoint == 254)
1138                         {
1139                                 race_penaltyaccumulator = 0;
1140                                 race_laptime = time; // valid
1141                         }
1142
1143                         break;
1144
1145                 case RACE_NET_CHECKPOINT_CLEAR:
1146                         race_laptime = 0;
1147                         race_checkpointtime = 0;
1148                         break;
1149
1150                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1151                         race_laptime = ReadCoord();
1152                         race_checkpointtime = -99999;
1153                         // fall through
1154                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1155                         race_nextcheckpoint = ReadByte();
1156
1157                         race_nextbesttime = ReadInt24_t();
1158                         if(race_nextbestname)
1159                                 strunzone(race_nextbestname);
1160                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1161                         break;
1162
1163                 case RACE_NET_CHECKPOINT_HIT_RACE:
1164                         race_mycheckpoint = ReadByte();
1165                         race_mycheckpointtime = time;
1166                         race_mycheckpointdelta = ReadInt24_t();
1167                         race_mycheckpointlapsdelta = ReadByte();
1168                         if(race_mycheckpointlapsdelta >= 128)
1169                                 race_mycheckpointlapsdelta -= 256;
1170                         if(race_mycheckpointenemy)
1171                                 strunzone(race_mycheckpointenemy);
1172                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1173                         break;
1174
1175                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1176                         race_othercheckpoint = ReadByte();
1177                         race_othercheckpointtime = time;
1178                         race_othercheckpointdelta = ReadInt24_t();
1179                         race_othercheckpointlapsdelta = ReadByte();
1180                         if(race_othercheckpointlapsdelta >= 128)
1181                                 race_othercheckpointlapsdelta -= 256;
1182                         if(race_othercheckpointenemy)
1183                                 strunzone(race_othercheckpointenemy);
1184                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1185                         break;
1186
1187                 case RACE_NET_PENALTY_RACE:
1188                         race_penaltyeventtime = time;
1189                         race_penaltytime = ReadShort();
1190                         //race_penaltyaccumulator += race_penaltytime;
1191                         if(race_penaltyreason)
1192                                 strunzone(race_penaltyreason);
1193                         race_penaltyreason = strzone(ReadString());
1194                         break;
1195
1196                 case RACE_NET_PENALTY_QUALIFYING:
1197                         race_penaltyeventtime = time;
1198                         race_penaltytime = ReadShort();
1199                         race_penaltyaccumulator += race_penaltytime;
1200                         if(race_penaltyreason)
1201                                 strunzone(race_penaltyreason);
1202                         race_penaltyreason = strzone(ReadString());
1203                         break;
1204
1205                 case RACE_NET_SERVER_RECORD:
1206                         race_server_record = ReadInt24_t();
1207                         break;
1208                 case RACE_NET_SPEED_AWARD:
1209                         race_speedaward = ReadInt24_t();
1210                         if(race_speedaward_holder)
1211                                 strunzone(race_speedaward_holder);
1212                         race_speedaward_holder = strzone(ReadString());
1213                         break;
1214                 case RACE_NET_SPEED_AWARD_BEST:
1215                         race_speedaward_alltimebest = ReadInt24_t();
1216                         if(race_speedaward_alltimebest_holder)
1217                                 strunzone(race_speedaward_alltimebest_holder);
1218                         race_speedaward_alltimebest_holder = strzone(ReadString());
1219                         break;
1220                 case RACE_NET_SERVER_RANKINGS:
1221                         float pos, prevpos, del;
1222                         pos = ReadShort();
1223                         prevpos = ReadShort();
1224                         del = ReadShort();
1225
1226                         // move other rankings out of the way
1227                         float i;
1228                         if (prevpos) {
1229                                 for (i=prevpos-1;i>pos-1;--i) {
1230                                         grecordtime[i] = grecordtime[i-1];
1231                                         if(grecordholder[i])
1232                                                 strunzone(grecordholder[i]);
1233                                         grecordholder[i] = strzone(grecordholder[i-1]);
1234                                 }
1235                         } else if (del) { // a record has been deleted by the admin
1236                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1237                                         if (i == RANKINGS_CNT-1) { // clear out last record
1238                                                 grecordtime[i] = 0;
1239                                                 if (grecordholder[i])
1240                                                         strunzone(grecordholder[i]);
1241                                                 grecordholder[i] = string_null;
1242                                         }
1243                                         else {
1244                                                 grecordtime[i] = grecordtime[i+1];
1245                                                 if (grecordholder[i])
1246                                                         strunzone(grecordholder[i]);
1247                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1248                                         }
1249                                 }
1250                         } else { // player has no ranked record yet
1251                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1252                                         grecordtime[i] = grecordtime[i-1];
1253                                         if(grecordholder[i])
1254                                                 strunzone(grecordholder[i]);
1255                                         grecordholder[i] = strzone(grecordholder[i-1]);
1256                                 }
1257                         }
1258
1259                         // store new ranking
1260                         if(grecordholder[pos-1] != "")
1261                                 strunzone(grecordholder[pos-1]);
1262                         grecordholder[pos-1] = strzone(ReadString());
1263                         grecordtime[pos-1] = ReadInt24_t();
1264                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1265                                 race_myrank = pos;
1266                         break;
1267                 case RACE_NET_SERVER_STATUS:
1268                         race_status = ReadShort();
1269                         if(race_status_name)
1270                                 strunzone(race_status_name);
1271                         race_status_name = strzone(ReadString());
1272         }
1273 }
1274
1275 void Net_ReadSpawn()
1276 {
1277         zoomin_effect = 1;
1278         current_viewzoom = 0.6;
1279 }
1280
1281 void Net_TeamNagger()
1282 {
1283         teamnagger = 1;
1284 }
1285
1286 void Net_ReadPingPLReport()
1287 {
1288         float e, pi, pl, ml;
1289         e = ReadByte();
1290         pi = ReadShort();
1291         pl = ReadByte();
1292         ml = ReadByte();
1293         if not(playerslots[e])
1294                 return;
1295         playerslots[e].ping = pi;
1296         playerslots[e].ping_packetloss = pl / 255.0;
1297         playerslots[e].ping_movementloss = ml / 255.0;
1298 }
1299
1300 void Net_VoteDialog(float highlight) {
1301         if(highlight) {
1302                 vote_highlighted = ReadByte();
1303                 return;
1304         }
1305
1306         vote_yescount = ReadByte();
1307         vote_nocount = ReadByte();
1308         vote_needed = ReadByte();
1309         vote_active = 1;
1310 }
1311
1312 void Net_VoteDialogReset() {
1313         vote_active = 0;
1314 }
1315
1316 void Net_Notify() {
1317         float type;
1318         type = ReadByte();
1319
1320         if(type == CSQC_KILLNOTIFY)
1321         {
1322                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1323         }
1324         else if(type == CSQC_CENTERPRINT)
1325         {
1326                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1327         }
1328 }
1329
1330 void Net_WeaponComplain() {
1331         complain_weapon = ReadByte();
1332
1333         if(complain_weapon_name)
1334                 strunzone(complain_weapon_name);
1335         complain_weapon_name = strzone(ReadString());
1336
1337         complain_weapon_type = ReadByte();
1338
1339         complain_weapon_time = time;
1340         weapontime = time; // ping the weapon panel
1341 }
1342
1343 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1344 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1345 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1346 float CSQC_Parse_TempEntity()
1347 {
1348         local float bHandled;
1349                 bHandled  = true;
1350         // Acquire TE ID
1351         local float nTEID;
1352                 nTEID = ReadByte();
1353
1354                 // NOTE: Could just do return instead of break...
1355         switch(nTEID)
1356         {
1357                 case TE_CSQC_TARGET_MUSIC:
1358                         Net_TargetMusic();
1359                         bHandled = true;
1360                         break;
1361                 case TE_CSQC_PICTURE:
1362                         Net_MapVote_Picture();
1363                         bHandled = true;
1364                         break;
1365                 case TE_CSQC_RACE:
1366                         Net_ReadRace();
1367                         bHandled = true;
1368                         break;
1369                 case TE_CSQC_SPAWN:
1370                         Net_ReadSpawn();
1371                         bHandled = true;
1372                         break;
1373                 case TE_CSQC_ZCURVEPARTICLES:
1374                         Net_ReadZCurveParticles();
1375                         bHandled = true;
1376                         break;
1377                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1378                         Net_ReadNexgunBeamParticle();
1379                         bHandled = true;
1380                         break;
1381                 case TE_CSQC_TEAMNAGGER:
1382                         Net_TeamNagger();
1383                         bHandled = true;
1384                         break;
1385                 case TE_CSQC_VOTE:
1386                         Net_VoteDialog(ReadByte());
1387                         bHandled = true;
1388                         break;
1389                 case TE_CSQC_VOTERESET:
1390                         Net_VoteDialogReset();
1391                         bHandled = true;
1392                         break;
1393                 case TE_CSQC_LIGHTNINGARC:
1394                         Net_ReadLightningarc();
1395                         bHandled = true;
1396                         break;
1397                 case TE_CSQC_PINGPLREPORT:
1398                         Net_ReadPingPLReport();
1399                         bHandled = true;
1400                         break;
1401                 case TE_CSQC_ANNOUNCE:
1402                         announce_snd = strzone(ReadString());
1403                         bHandled = true;
1404                         break;
1405                 case TE_CSQC_NOTIFY:
1406                         Net_Notify();
1407                         bHandled = true;
1408                         break;
1409                 case TE_CSQC_WEAPONCOMPLAIN:
1410                         Net_WeaponComplain();
1411                         bHandled = true;
1412                         break;
1413                 default:
1414                         // No special logic for this temporary entity; return 0 so the engine can handle it
1415                         bHandled = false;
1416                         break;
1417         }
1418
1419         return bHandled;
1420 }
1421
1422 string getcommandkey(string text, string command)
1423 {
1424         string keys;
1425         float n, j, k, l;
1426
1427         if (!autocvar_hud_showbinds)
1428                 return text;
1429
1430         keys = db_get(binddb, command);
1431         if (!keys)
1432         {
1433                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1434                 for(j = 0; j < n; ++j)
1435                 {
1436                         k = stof(argv(j));
1437                         if(k != -1)
1438                         {
1439                                 if ("" == keys)
1440                                         keys = keynumtostring(k);
1441                                 else
1442                                         keys = strcat(keys, ", ", keynumtostring(k));
1443
1444                                 ++l;
1445                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1446                         }
1447
1448                 }
1449                 db_put(binddb, command, keys);
1450         }
1451
1452         if ("" == keys) {
1453                 if (autocvar_hud_showbinds > 1)
1454                         return sprintf(_("%s (not bound)"), text);
1455                 else
1456                         return text;
1457         }
1458         else if (autocvar_hud_showbinds > 1)
1459                 return sprintf(_("%s (%s)"), text, keys);
1460         else
1461                 return keys;
1462 }