qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63         float i;
  64         CSQC_CheckEngine();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         drawfont = 0;
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = menu_sub_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkey(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //ctf_temp_1 = "";
  82         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  83         //registercmd("ctf_menu");
  84         registercmd("ons_map");
  85         //registercmd("menu_action");
  86
  87         registercmd("+button3");
  88         registercmd("-button3");
  89         registercmd("+button4");
  90         registercmd("-button4");
  91         registercmd("+showaccuracy");registercmd("-showaccuracy");
  92
  93 #ifndef CAMERATEST
  94         if(isdemo())
  95         {
  96 #endif
  97                 registercmd("+forward");registercmd("-forward");
  98                 registercmd("+back");registercmd("-back");
  99                 registercmd("+moveup");registercmd("-moveup");
 100                 registercmd("+movedown");registercmd("-movedown");
 101                 registercmd("+moveright");registercmd("-moveright");
 102                 registercmd("+moveleft");registercmd("-moveleft");
 103                 registercmd("+roll_right");registercmd("-roll_right");
 104                 registercmd("+roll_left");registercmd("-roll_left");
 105 #ifndef CAMERATEST
 106         }
 107 #endif
 108         registercvar("hud_usecsqc", "1");
 109         registercvar("hud_columns", "default", CVAR_SAVE);
 110
 111         gametype = 0;
 112
 113         // hud_fields uses strunzone on the titles!
 114         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 115                 hud_title[i] = strzone("(null)");
 116
 117         postinit = false;
 118
 119         calledhooks = 0;
 120
 121         teams = Sort_Spawn();
 122         players = Sort_Spawn();
 123
 124         GetTeam(COLOR_SPECTATOR, true); // add specs first
 125
 126         cvar_clientsettemp("_supports_weaponpriority", "1");
 127
 128         RegisterWeapons();
 129
 130         WaypointSprite_Load();
 131
 132         // precaches
 133         Projectile_Precache();
 134         GibSplash_Precache();
 135         Casings_Precache();
 136         DamageInfo_Precache();
 137         if(cvar_string("cl_announcer") != cl_announcer_prev) {
 138                 Announcer_Precache();
 139                 if(cl_announcer_prev)
 140                         strunzone(cl_announcer_prev);
 141                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
 142         }
 143         Tuba_Precache();
 144
 145 #ifdef UID
 146         {
 147                 // find the user ID
 148                 string uid;
 149                 registercvar("_cl_userid", "", CVAR_SAVE);
 150                 uid = cvar_string("_cl_userid");
 151                 if(strlen(uid) < 16)
 152                 {
 153                         uid = "";
 154                         for(i = 0; i < 4; ++i)
 155                                 uid = strcat(uid, substring(ftos(floor(10000 + random() * 10000)), 1, -1));
 156                 }
 157                 cvar_set("_cl_userid", uid);
 158                 localcmd(strcat("\ncmd uid ", uid, "\n"));
 159         }
 160 #endif
 161
 162         get_mi_min_max_texcoords(1); // try the CLEVER way first
 163         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 164         shortmapname = mi_shortname;
 165
 166         if(precache_pic(minimapname) == "")
 167         {
 168                 // but maybe we have a non-clever minimap
 169                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 170                 if(precache_pic(minimapname) == "")
 171                         minimapname = ""; // FAIL
 172                 else
 173                         get_mi_min_max_texcoords(0); // load new texcoords
 174         }
 175
 176         mi_center = (mi_min + mi_max) * 0.5;
 177         mi_scale = mi_max - mi_min;
 178         minimapname = strzone(minimapname);
 179
 180         WarpZone_Init();
 181 }
 182
 183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 184 void CSQC_Shutdown(void)
 185 {
 186 #ifdef USE_FTE
 187 #pragma TARGET id
 188         if(!__engine_check)
 189                 return 0;
 190 #pragma TARGET fte
 191 #endif
 192
 193         WarpZone_Shutdown();
 194
 195         remove(teams);
 196         remove(players);
 197         db_close(binddb);
 198         db_close(tempdb);
 199         db_save(ClientProgsDB, "client.db");
 200         db_close(ClientProgsDB);
 201
 202         cvar_clientsettemp_restore();
 203
 204         if(camera_active)
 205                 cvar_set("chase_active",ftos(chase_active_backup));
 206
 207         if not(isdemo())
 208         {
 209                 if not(calledhooks & HOOK_START)
 210                         localcmd("\n_cl_hook_gamestart nop;");
 211                 if not(calledhooks & HOOK_END)
 212                         localcmd("\ncl_hook_gameend;");
 213         }
 214 }
 215
 216 .float has_team;
 217 float SetTeam(entity o, float Team)
 218 {
 219         entity tm;
 220         if(teamplay)
 221         {
 222                 switch(Team)
 223                 {
 224                         case -1:
 225                         case COLOR_TEAM1:
 226                         case COLOR_TEAM2:
 227                         case COLOR_TEAM3:
 228                         case COLOR_TEAM4:
 229                                 break;
 230                         default:
 231                                 if(GetTeam(Team, false) == NULL)
 232                                 {
 233                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 234                                         Team = COLOR_SPECTATOR;
 235                                 }
 236                                 break;
 237                 }
 238         }
 239         else
 240         {
 241                 switch(Team)
 242                 {
 243                         case -1:
 244                         case 0:
 245                                 break;
 246                         default:
 247                                 if(GetTeam(Team, false) == NULL)
 248                                 {
 249                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 250                                         Team = COLOR_SPECTATOR;
 251                                 }
 252                                 break;
 253                 }
 254         }
 255         if(Team == -1) // leave
 256         {
 257                 if(o.has_team)
 258                 {
 259                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 260                         tm = GetTeam(o.team, false);
 261                         tm.team_size -= 1;
 262                         o.has_team = 0;
 263                         return TRUE;
 264                 }
 265         }
 266         else
 267         {
 268                 if not(o.has_team)
 269                 {
 270                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 271                         o.team = Team;
 272                         tm = GetTeam(Team, true);
 273                         tm.team_size += 1;
 274                         o.has_team = 1;
 275                         return TRUE;
 276                 }
 277                 else if(Team != o.team)
 278                 {
 279                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 280                         tm = GetTeam(o.team, false);
 281                         tm.team_size -= 1;
 282                         o.team = Team;
 283                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         return TRUE;
 287                 }
 288         }
 289         return FALSE;
 290 }
 291
 292 void Playerchecker_Think()
 293 {
 294         float i;
 295         entity e;
 296         for(i = 0; i < maxclients; ++i)
 297         {
 298                 e = playerslots[i];
 299                 if(GetPlayerName(i) == "")
 300                 {
 301                         if(e.sort_prev)
 302                         {
 303                                 //print("playerchecker: KILL KILL KILL\n");
 304                                 // player disconnected
 305                                 SetTeam(e, -1);
 306                                 RemovePlayer(e);
 307                                 e.sort_prev = world;
 308                                 //e.gotscores = 0;
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if not(e.sort_prev)
 314                         {
 315                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 316                                 // player connected
 317                                 if not(e)
 318                                         playerslots[i] = e = spawn();
 319                                 e.sv_entnum = i;
 320                                 e.ping = 0;
 321                                 e.ping_packetloss = 0;
 322                                 e.ping_movementloss = 0;
 323                                 //e.gotscores = 0; // we might already have the scores...
 324                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 325                                 RegisterPlayer(e);
 326                                 HUD_UpdatePlayerPos(e);
 327                         }
 328                 }
 329         }
 330         self.nextthink = time + 0.2;
 331 }
 332
 333 void Porto_Init();
 334 void TrueAim_Init();
 335 void PostInit(void)
 336 {
 337         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 338         localcmd(strcat("\nhud_columns_set ", cvar_string("hud_columns"), ";\n"));
 339
 340         entity playerchecker;
 341         playerchecker = spawn();
 342         playerchecker.think = Playerchecker_Think;
 343         playerchecker.nextthink = time + 0.2;
 344
 345         Porto_Init();
 346         TrueAim_Init();
 347
 348         postinit = true;
 349 }
 350
 351 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 352 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 353 float button_zoom;
 354 void Cmd_HUD_SetFields(float);
 355 void Cmd_HUD_Help(float);
 356 float CSQC_ConsoleCommand(string strMessage)
 357 {
 358         float argc;
 359         // Tokenize String
 360         //argc = tokenize(strMessage);
 361         argc = tokenize_console(strMessage);
 362
 363         // Acquire Command
 364         local string strCmd;
 365         strCmd = argv(0);
 366
 367         if(strCmd == "+button4") { // zoom
 368                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 369                 if(ignore_plus_zoom)
 370                 {
 371                         --ignore_plus_zoom;
 372                         return false;
 373                 }
 374                 button_zoom = 1;
 375                 return true;
 376         } else if(strCmd == "-button4") { // zoom
 377                 if(ignore_minus_zoom)
 378                 {
 379                         --ignore_minus_zoom;
 380                         return false;
 381                 }
 382                 button_zoom = 0;
 383                 return true;
 384         } else if(strCmd == "+button3") { // secondary
 385                 button_attack2 = 1;
 386                 return false;
 387         } else if(strCmd == "-button3") { // secondary
 388                 button_attack2 = 0;
 389                 return false;
 390         } else if(strCmd == "+showscores") {
 391                 sb_showscores = true;
 392                 return true;
 393         } else if(strCmd == "-showscores") {
 394                 sb_showscores = false;
 395                 return true;
 396         } else if(strCmd == "+showaccuracy") {
 397                 sb_showaccuracy = true;
 398                 return true;
 399         } else if(strCmd == "-showaccuracy") {
 400                 sb_showaccuracy = false;
 401                 return true;
 402         }
 403
 404         if(camera_active)
 405         if(strCmd == "+forward" || strCmd == "-back") {
 406                 ++camera_direction_x;
 407                 return true;
 408         } else if(strCmd == "-forward" || strCmd == "+back") {
 409                 --camera_direction_x;
 410                 return true;
 411         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 412                 --camera_direction_y;
 413                 return true;
 414         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 415                 ++camera_direction_y;
 416                 return true;
 417         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 418                 ++camera_direction_z;
 419                 return true;
 420         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 421                 --camera_direction_z;
 422                 return true;
 423         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 424                 ++camera_roll;
 425                 return true;
 426         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 427                 --camera_roll;
 428                 return true;
 429         }
 430
 431         return false;
 432 }
 433
 434 .vector view_ofs;
 435 entity debug_shotorg;
 436 void ShotOrg_Draw()
 437 {
 438         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 439         self.angles = view_angles;
 440         self.angles_x = -self.angles_x;
 441         if not(self.cnt)
 442                 R_AddEntity(self);
 443 }
 444 void ShotOrg_Draw2D()
 445 {
 446         vector coord2d_topleft, coord2d_topright, coord2d;
 447         string s;
 448         vector fs;
 449
 450         s = vtos(self.view_ofs);
 451         s = substring(s, 1, strlen(s) - 2);
 452         if(tokenize_console(s) == 3)
 453                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 454
 455         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 456         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 457
 458         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 459
 460         coord2d = coord2d_topleft;
 461         if(fs_x < 8)
 462         {
 463                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 464                 fs = '8 8 0';
 465         }
 466         coord2d_y -= fs_y;
 467         coord2d_z = 0;
 468         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 469 }
 470
 471 void ShotOrg_Spawn()
 472 {
 473         debug_shotorg = spawn();
 474         debug_shotorg.draw = ShotOrg_Draw;
 475         debug_shotorg.draw2d = ShotOrg_Draw2D;
 476         debug_shotorg.renderflags = RF_VIEWMODEL;
 477         debug_shotorg.effects = EF_FULLBRIGHT;
 478         precache_model("models/shotorg_adjuster.md3");
 479         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 480         debug_shotorg.scale = 2;
 481         debug_shotorg.view_ofs = '25 8 -8';
 482 }
 483
 484 void DrawDebugModel()
 485 {
 486         if(time - floor(time) > 0.5)
 487         {
 488                 PolyDrawModel(self);
 489         }
 490         else
 491         {
 492                 self.renderflags = 0;
 493                 R_AddEntity(self);
 494         }
 495 }
 496
 497 void GameCommand(string msg)
 498 {
 499         string s;
 500         float argc;
 501         entity e;
 502         argc = tokenize_console(msg);
 503
 504         if(argv(0) == "help" || argc == 0)
 505         {
 506                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 507                 print("  settemp cvar value\n");
 508                 print("  radar\n");
 509                 print("  hud_columns_set ...\n");
 510                 print("  hud_columns_help\n");
 511                 GameCommand_Generic("help");
 512                 return;
 513         }
 514
 515         if(GameCommand_Generic(msg))
 516                 return;
 517
 518         string cmd;
 519         cmd = argv(0);
 520         if(cmd == "mv_download") {
 521                 Cmd_MapVote_MapDownload(argc);
 522         }
 523         else if(cmd == "settemp") {
 524                 cvar_clientsettemp(argv(1), argv(2));
 525         }
 526         else if(cmd == "radar") {
 527                 ons_showmap = !ons_showmap;
 528         }
 529         else if(cmd == "hud_columns_set") {
 530                 Cmd_HUD_SetFields(argc);
 531         }
 532         else if(cmd == "hud_columns_help") {
 533                 Cmd_HUD_Help(argc);
 534         }
 535 #ifdef BLURTEST
 536         else if(cmd == "blurtest") {
 537                 blurtest_time0 = time;
 538                 blurtest_time1 = time + stof(argv(1));
 539                 blurtest_radius = stof(argv(2));
 540                 blurtest_power = stof(argv(3));
 541         }
 542 #endif
 543         else if(cmd == "shotorg_move") {
 544                 if(!debug_shotorg)
 545                         ShotOrg_Spawn();
 546                 else
 547                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 548                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 549         }
 550         else if(cmd == "shotorg_movez") {
 551                 if(!debug_shotorg)
 552                         ShotOrg_Spawn();
 553                 else
 554                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 555                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 556         }
 557         else if(cmd == "shotorg_set") {
 558                 if(!debug_shotorg)
 559                         ShotOrg_Spawn();
 560                 else
 561                         debug_shotorg.view_ofs = stov(argv(1));
 562                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 563         }
 564         else if(cmd == "shotorg_setz") {
 565                 if(!debug_shotorg)
 566                         ShotOrg_Spawn();
 567                 else
 568                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 569                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 570         }
 571         else if(cmd == "shotorg_toggle_hide") {
 572                 if(debug_shotorg)
 573                 {
 574                         debug_shotorg.cnt = !debug_shotorg.cnt;
 575                 }
 576         }
 577         else if(cmd == "shotorg_end") {
 578                 if(debug_shotorg)
 579                 {
 580                         print(vtos(debug_shotorg.view_ofs), "\n");
 581                         remove(debug_shotorg);
 582                         debug_shotorg = world;
 583                 }
 584                 localcmd("sv_cmd debug_shotorg\n");
 585         }
 586         else if(cmd == "sendcvar") {
 587                 s = cvar_string(argv(1));
 588                 if(argv(1) == "cl_weaponpriority")
 589                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 590                 else if(substring(argv(1), 0, 17) == "cl_weaponpriority" && strlen(argv(1)) == 18)
 591                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 592                 localcmd("cmd sentcvar ", argv(1), " \"", s, "\"\n");
 593         }
 594         else if(cmd == "spawn") {
 595                 s = argv(1);
 596                 e = spawn();
 597                 precache_model(s);
 598                 setmodel(e, s);
 599                 setorigin(e, view_origin);
 600                 e.angles = view_angles;
 601                 e.draw = DrawDebugModel;
 602                 e.classname = "debugmodel";
 603         }
 604         else
 605         {
 606                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 607         }
 608
 609         return;
 610 }
 611
 612 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 613 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 614 // All keys are in ascii.
 615 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 616 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 617 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 618 float hudconf_active;
 619 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 620 {
 621         local float bSkipKey;
 622         bSkipKey = false;
 623
 624         if(hudconf_active)
 625                 if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 626                         return true;
 627
 628         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 629                 return true;
 630
 631         if(menu_visible)
 632                 if(menu_action(bInputType, nPrimary, nSecondary))
 633                         return TRUE;
 634         return bSkipKey;
 635 }
 636
 637 // END REQUIRED CSQC FUNCTIONS
 638 // --------------------------------------------------------------------------
 639
 640 // --------------------------------------------------------------------------
 641 // BEGIN OPTIONAL CSQC FUNCTIONS
 642 void Ent_ReadEntCS()
 643 {
 644         InterpolateOrigin_Undo();
 645
 646         self.classname = "entcs_receiver";
 647         self.sv_entnum = ReadByte() - 1;
 648         self.origin_x = ReadShort();
 649         self.origin_y = ReadShort();
 650         self.origin_z = ReadShort();
 651         self.angles_y = ReadByte() * 360.0 / 256;
 652         self.origin_z = self.angles_x = self.angles_z = 0;
 653
 654         InterpolateOrigin_Note();
 655 }
 656
 657 void Ent_Remove();
 658
 659 void Ent_RemovePlayerScore()
 660 {
 661         float i;
 662
 663         if(self.owner)
 664         {
 665                 SetTeam(self.owner, -1);
 666                 self.owner.gotscores = 0;
 667                 for(i = 0; i < MAX_SCORE; ++i)
 668                         self.owner.(scores[i]) = 0; // clear all scores
 669         }
 670 }
 671
 672 void Ent_ReadPlayerScore()
 673 {
 674         float i, n;
 675         float isNew;
 676         entity o;
 677
 678         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 679         // (no I've never heard of M-x replace-string, sed, or anything like that)
 680         isNew = !self.owner; // workaround for DP bug
 681         n = ReadByte()-1;
 682
 683 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 684         if(!isNew && n != self.sv_entnum)
 685         {
 686                 print("A CSQC entity changed its owner!\n");
 687                 isNew = true;
 688                 Ent_Remove();
 689                 self.enttype = ENT_CLIENT_SCORES;
 690         }
 691 #endif
 692
 693         self.sv_entnum = n;
 694
 695         if not(playerslots[self.sv_entnum])
 696                 playerslots[self.sv_entnum] = spawn();
 697         o = self.owner = playerslots[self.sv_entnum];
 698         o.sv_entnum = self.sv_entnum;
 699         o.gotscores = 1;
 700
 701         //if not(o.sort_prev)
 702         //      RegisterPlayer(o);
 703         //playerchecker will do this for us later, if it has not already done so
 704
 705         float sf, lf;
 706 #if MAX_SCORE <= 8
 707         sf = ReadByte();
 708         lf = ReadByte();
 709 #else
 710         sf = ReadShort();
 711         lf = ReadShort();
 712 #endif
 713         float p;
 714         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 715                 if(sf & p)
 716                 {
 717                         if(lf & p)
 718                                 o.(scores[i]) = ReadInt24_t();
 719                         else
 720                                 o.(scores[i]) = ReadChar();
 721                 }
 722
 723         if(o.sort_prev)
 724                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 725
 726         self.entremove = Ent_RemovePlayerScore;
 727 }
 728
 729 void Ent_ReadTeamScore()
 730 {
 731         float i;
 732         entity o;
 733
 734         self.team = ReadByte();
 735         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 736
 737         float sf, lf;
 738 #if MAX_TEAMSCORE <= 8
 739         sf = ReadByte();
 740         lf = ReadByte();
 741 #else
 742         sf = ReadShort();
 743         lf = ReadShort();
 744 #endif
 745         float p;
 746         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 747                 if(sf & p)
 748                 {
 749                         if(lf & p)
 750                                 o.(teamscores[i]) = ReadInt24_t();
 751                         else
 752                                 o.(teamscores[i]) = ReadChar();
 753                 }
 754
 755         HUD_UpdateTeamPos(o);
 756 }
 757
 758 void Net_Reset()
 759 {
 760 }
 761
 762 void Ent_ClientData()
 763 {
 764         float f;
 765         float newspectatee_status;
 766
 767         f = ReadByte();
 768
 769         sb_showscores_force = (f & 1);
 770
 771         if(f & 2)
 772         {
 773                 newspectatee_status = ReadByte();
 774                 if(newspectatee_status == player_localentnum)
 775                         newspectatee_status = -1; // observing
 776         }
 777         else
 778                 newspectatee_status = 0;
 779
 780         spectatorbutton_zoom = (f & 4);
 781
 782         if(f & 8)
 783         {
 784                 angles_held_status = 1;
 785                 angles_held_x = ReadAngle();
 786                 angles_held_y = ReadAngle();
 787                 angles_held_z = 0;
 788         }
 789         else
 790                 angles_held_status = 0;
 791
 792         if(newspectatee_status != spectatee_status)
 793         {
 794                 float i;
 795                 // clear the weapon accuracy stats
 796                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
 797                         weapon_hits[i] = 0;
 798                         weapon_fired[i] = 0;
 799                 }
 800
 801                 // clear race stuff
 802                 race_laptime = 0;
 803                 race_checkpointtime = 0;
 804         }
 805         spectatee_status = newspectatee_status;
 806 }
 807
 808 void Ent_Nagger()
 809 {
 810         float nags, i, j, b, f;
 811
 812         nags = ReadByte();
 813
 814         if(nags & 128)
 815         {
 816                 if(vote_called_vote)
 817                         strunzone(vote_called_vote);
 818                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 819         }
 820
 821         if(nags & 1)
 822         {
 823                 for(j = 0; j < maxclients; ++j)
 824                         if(playerslots[j])
 825                                 playerslots[j].ready = 1;
 826                 for(i = 1; i <= maxclients; i += 8)
 827                 {
 828                         f = ReadByte();
 829                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 830                                 if not(f & b)
 831                                         if(playerslots[j])
 832                                                 playerslots[j].ready = 0;
 833                 }
 834         }
 835
 836         ready_waiting = (nags & 1);
 837         ready_waiting_for_me = (nags & 2);
 838         vote_waiting = (nags & 4);
 839         vote_waiting_for_me = (nags & 8);
 840         warmup_stage = (nags & 16);
 841 }
 842
 843 void Ent_RandomSeed()
 844 {
 845         float s;
 846         prandom_debug();
 847         s = ReadShort();
 848         psrandom(s);
 849 }
 850
 851 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 852 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 853 void Ent_RadarLink();
 854 void Ent_Init();
 855 void Ent_ScoresInfo();
 856 void(float bIsNewEntity) CSQC_Ent_Update =
 857 {
 858         float t;
 859         float savetime;
 860         t = ReadByte();
 861
 862         // set up the "time" global for received entities to be correct for interpolation purposes
 863         savetime = time;
 864         if(servertime)
 865         {
 866                 time = servertime;
 867         }
 868         else
 869         {
 870                 serverprevtime = time;
 871                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 872                 time = serverprevtime + serverdeltatime;
 873         }
 874
 875 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 876         if(self.enttype)
 877                 if(t != self.enttype)
 878                 {
 879                         print("A CSQC entity changed its type!\n");
 880                         Ent_Remove();
 881                         bIsNewEntity = 1;
 882                 }
 883 #endif
 884         self.enttype = t;
 885         switch(t)
 886         {
 887                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 888                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 889                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 890                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 891                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 892                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 893                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 894                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 895                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 896                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 897                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 898                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 899                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 900                 case ENT_CLIENT_INIT: Ent_Init(); break;
 901                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 902                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 903                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 904                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 905                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 906                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 907                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 908                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 909                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 910                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 911                 default:
 912                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 913                         break;
 914         }
 915
 916         time = savetime;
 917 };
 918 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 919 // used when an entity changes its type. For an entity that someone interacts
 920 // with others, make sure it can no longer do so.
 921 void Ent_Remove()
 922 {
 923         if(self.entremove)
 924                 self.entremove();
 925
 926         self.enttype = 0;
 927         self.classname = "";
 928         self.draw = menu_sub_null;
 929         self.entremove = menu_sub_null;
 930         // TODO possibly set more stuff to defaults
 931 }
 932 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 933 void CSQC_Ent_Remove()
 934 {
 935         if(self.enttype)
 936                 Ent_Remove();
 937         remove(self);
 938 }
 939
 940 void Gamemode_Init()
 941 {
 942         if(gametype == GAME_ONSLAUGHT) {
 943                 print(strcat("Using ", minimapname, " as minimap.\n"));
 944                 precache_pic("gfx/ons-cp-neutral.tga");
 945                 precache_pic("gfx/ons-cp-red.tga");
 946                 precache_pic("gfx/ons-cp-blue.tga");
 947                 precache_pic("gfx/ons-frame.tga");
 948                 precache_pic("gfx/ons-frame-team.tga");
 949         } else if(gametype == GAME_KEYHUNT) {
 950                 precache_pic("gfx/sb_key_carrying");
 951                 precache_pic("gfx/sb_key_carrying_outline");
 952         }
 953
 954         if not(isdemo())
 955         {
 956                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), ";");
 957                 calledhooks |= HOOK_START;
 958         }
 959 }
 960 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 961 void CSQC_Parse_StuffCmd(string strMessage)
 962 {
 963         localcmd(strMessage);
 964 }
 965 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 966 void CSQC_Parse_Print(string strMessage)
 967 {
 968         print(ColorTranslateRGB(strMessage));
 969 }
 970
 971 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
 972 void CSQC_Parse_CenterPrint(string strMessage)
 973 {
 974         centerprint(strMessage);
 975 }
 976
 977 string notranslate_fogcmd1 = "\nfog ";
 978 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 979 void Fog_Force()
 980 {
 981         // TODO somehow thwart prvm_globalset client ...
 982
 983         if(forcefog != "")
 984                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 985 }
 986
 987 void Gamemode_Init();
 988 void Ent_ScoresInfo()
 989 {
 990         float i;
 991         self.classname = "ent_client_scores_info";
 992         gametype = ReadByte();
 993         for(i = 0; i < MAX_SCORE; ++i)
 994         {
 995                 scores_label[i] = strzone(ReadString());
 996                 scores_flags[i] = ReadByte();
 997         }
 998         for(i = 0; i < MAX_TEAMSCORE; ++i)
 999         {
1000                 teamscores_label[i] = strzone(ReadString());
1001                 teamscores_flags[i] = ReadByte();
1002         }
1003         HUD_InitScores();
1004         Gamemode_Init();
1005 }
1006
1007 void Ent_Init()
1008 {
1009         self.classname = "ent_client_init";
1010
1011         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1012
1013         hook_shotorigin_x = ReadCoord();
1014         hook_shotorigin_y = ReadCoord();
1015         hook_shotorigin_z = ReadCoord();
1016
1017         if(forcefog)
1018                 strunzone(forcefog);
1019         forcefog = strzone(ReadString());
1020
1021         armorblockpercent = ReadByte() / 255.0;
1022
1023         g_weaponswitchdelay = ReadByte() / 255.0;
1024
1025         if(!postinit)
1026                 PostInit();
1027 }
1028
1029 void Net_ReadRace()
1030 {
1031         float b;
1032
1033         b = ReadByte();
1034
1035         switch(b)
1036         {
1037                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1038                         race_checkpoint = ReadByte();
1039                         race_time = ReadInt24_t();
1040                         race_previousbesttime = ReadInt24_t();
1041                         if(race_previousbestname)
1042                                 strunzone(race_previousbestname);
1043                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1044
1045                         race_checkpointtime = time;
1046
1047                         if(race_checkpoint == 0 || race_checkpoint == 254)
1048                         {
1049                                 race_penaltyaccumulator = 0;
1050                                 race_laptime = time; // valid
1051                         }
1052
1053                         break;
1054
1055                 case RACE_NET_CHECKPOINT_CLEAR:
1056                         race_laptime = 0;
1057                         race_checkpointtime = 0;
1058                         break;
1059
1060                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1061                         race_laptime = ReadCoord();
1062                         race_checkpointtime = -99999;
1063                         // fall through
1064                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1065                         race_nextcheckpoint = ReadByte();
1066
1067                         race_nextbesttime = ReadInt24_t();
1068                         if(race_nextbestname)
1069                                 strunzone(race_nextbestname);
1070                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1071                         break;
1072
1073                 case RACE_NET_CHECKPOINT_HIT_RACE:
1074                         race_mycheckpoint = ReadByte();
1075                         race_mycheckpointtime = time;
1076                         race_mycheckpointdelta = ReadInt24_t();
1077                         race_mycheckpointlapsdelta = ReadByte();
1078                         if(race_mycheckpointlapsdelta >= 128)
1079                                 race_mycheckpointlapsdelta -= 256;
1080                         if(race_mycheckpointenemy)
1081                                 strunzone(race_mycheckpointenemy);
1082                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1083                         break;
1084
1085                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1086                         race_othercheckpoint = ReadByte();
1087                         race_othercheckpointtime = time;
1088                         race_othercheckpointdelta = ReadInt24_t();
1089                         race_othercheckpointlapsdelta = ReadByte();
1090                         if(race_othercheckpointlapsdelta >= 128)
1091                                 race_othercheckpointlapsdelta -= 256;
1092                         if(race_othercheckpointenemy)
1093                                 strunzone(race_othercheckpointenemy);
1094                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1095                         break;
1096
1097                 case RACE_NET_PENALTY_RACE:
1098                         race_penaltyeventtime = time;
1099                         race_penaltytime = ReadShort();
1100                         //race_penaltyaccumulator += race_penaltytime;
1101                         if(race_penaltyreason)
1102                                 strunzone(race_penaltyreason);
1103                         race_penaltyreason = strzone(ReadString());
1104                         break;
1105
1106                 case RACE_NET_PENALTY_QUALIFYING:
1107                         race_penaltyeventtime = time;
1108                         race_penaltytime = ReadShort();
1109                         race_penaltyaccumulator += race_penaltytime;
1110                         if(race_penaltyreason)
1111                                 strunzone(race_penaltyreason);
1112                         race_penaltyreason = strzone(ReadString());
1113                         break;
1114
1115                 case RACE_NET_SERVER_RECORD:
1116                         race_server_record = ReadInt24_t();
1117                         break;
1118                 case RACE_NET_SPEED_AWARD:
1119                         race_speedaward = ReadInt24_t();
1120                         if(race_speedaward_holder)
1121                                 strunzone(race_speedaward_holder);
1122                         race_speedaward_holder = strzone(ReadString());
1123                         break;
1124                 case RACE_NET_SPEED_AWARD_BEST:
1125                         race_speedaward_alltimebest = ReadInt24_t();
1126                         if(race_speedaward_alltimebest_holder)
1127                                 strunzone(race_speedaward_alltimebest_holder);
1128                         race_speedaward_alltimebest_holder = strzone(ReadString());
1129                         break;
1130                 case RACE_NET_SERVER_RANKINGS:
1131                         float pos, prevpos, del;
1132                         pos = ReadShort();
1133                         prevpos = ReadShort();
1134                         del = ReadShort();
1135
1136                         // move other rankings out of the way
1137                         float i;
1138                         if (prevpos) {
1139                                 for (i=prevpos-1;i>pos-1;--i) {
1140                                         grecordtime[i] = grecordtime[i-1];
1141                                         if(grecordholder[i])
1142                                                 strunzone(grecordholder[i]);
1143                                         grecordholder[i] = strzone(grecordholder[i-1]);
1144                                 }
1145                         } else if (del) { // a record has been deleted by the admin
1146                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1147                                         if (i == RANKINGS_CNT-1) { // clear out last record
1148                                                 grecordtime[i] = 0;
1149                                                 if (grecordholder[i])
1150                                                         strunzone(grecordholder[i]);
1151                                                 grecordholder[i] = string_null;
1152                                         }
1153                                         else {
1154                                                 grecordtime[i] = grecordtime[i+1];
1155                                                 if (grecordholder[i])
1156                                                         strunzone(grecordholder[i]);
1157                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1158                                         }
1159                                 }
1160                         } else { // player has no ranked record yet
1161                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1162                                         grecordtime[i] = grecordtime[i-1];
1163                                         if(grecordholder[i])
1164                                                 strunzone(grecordholder[i]);
1165                                         grecordholder[i] = strzone(grecordholder[i-1]);
1166                                 }
1167                         }
1168
1169                         // store new ranking
1170                         if(grecordholder[pos-1] != "")
1171                                 strunzone(grecordholder[pos-1]);
1172                         grecordholder[pos-1] = strzone(ReadString());
1173                         grecordtime[pos-1] = ReadInt24_t();
1174                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1175                                 race_myrank = pos;
1176                         break;
1177                 case RACE_NET_SERVER_STATUS:
1178                         race_status = ReadShort();
1179                         if(race_status_name)
1180                                 strunzone(race_status_name);
1181                         race_status_name = strzone(ReadString());
1182         }
1183 }
1184
1185 void Net_ReadSpawn()
1186 {
1187         zoomin_effect = 1;
1188         current_viewzoom = 0.6;
1189 }
1190
1191 void Net_TeamNagger()
1192 {
1193         teamnagger = 1;
1194 }
1195
1196 void Net_ReadPingPLReport()
1197 {
1198         float e, pi, pl, ml;
1199         e = ReadByte();
1200         pi = ReadShort();
1201         pl = ReadByte();
1202         ml = ReadByte();
1203         if not(playerslots[e])
1204                 return;
1205         playerslots[e].ping = pi;
1206         playerslots[e].ping_packetloss = pl / 255.0;
1207         playerslots[e].ping_movementloss = ml / 255.0;
1208 }
1209
1210 void Net_VoteDialog(float highlight) {
1211         if(highlight) {
1212                 vote_highlighted = ReadShort();
1213                 return;
1214         }
1215
1216         vote_yescount = ReadShort();
1217         vote_nocount = ReadShort();
1218         vote_needed = ReadShort();
1219         vote_active = 1;
1220 }
1221
1222 void Net_VoteDialogReset() {
1223         vote_active = 0;
1224 }
1225
1226 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1227 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1228 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1229 float CSQC_Parse_TempEntity()
1230 {
1231         local float bHandled;
1232                 bHandled  = true;
1233         // Acquire TE ID
1234         local float nTEID;
1235                 nTEID = ReadByte();
1236
1237                 // NOTE: Could just do return instead of break...
1238         switch(nTEID)
1239         {
1240                 case TE_CSQC_TARGET_MUSIC:
1241                         Net_TargetMusic();
1242                         bHandled = true;
1243                         break;
1244                 case TE_CSQC_PICTURE:
1245                         Net_MapVote_Picture();
1246                         bHandled = true;
1247                         break;
1248                 case TE_CSQC_RACE:
1249                         Net_ReadRace();
1250                         bHandled = true;
1251                         break;
1252                 case 13: // TE_BEAM
1253                         Net_GrapplingHook();
1254                         bHandled = true;
1255                         break;
1256                 case TE_CSQC_SPAWN:
1257                         Net_ReadSpawn();
1258                         bHandled = true;
1259                         break;
1260                 case TE_CSQC_ZCURVEPARTICLES:
1261                         Net_ReadZCurveParticles();
1262                         bHandled = true;
1263                         break;
1264                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1265                         Net_ReadNexgunBeamParticle();
1266                         bHandled = true;
1267                         break;
1268                 case TE_CSQC_TEAMNAGGER:
1269                         Net_TeamNagger();
1270                         bHandled = true;
1271                         break;
1272                 case TE_CSQC_VOTE:
1273                         Net_VoteDialog(ReadByte());
1274                         bHandled = true;
1275                         break;
1276                 case TE_CSQC_VOTERESET:
1277                         Net_VoteDialogReset();
1278                         bHandled = true;
1279                         break;
1280                 case TE_CSQC_LIGHTNINGARC:
1281                         Net_ReadLightningarc();
1282                         bHandled = true;
1283                         break;
1284                 case TE_CSQC_PINGPLREPORT:
1285                         Net_ReadPingPLReport();
1286                         bHandled = true;
1287                         break;
1288                 case TE_CSQC_ANNOUNCE:
1289                         announce_snd = strzone(ReadString());
1290                         bHandled = true;
1291                         break;
1292                 default:
1293                         // No special logic for this temporary entity; return 0 so the engine can handle it
1294                         bHandled = false;
1295                         break;
1296         }
1297
1298         return bHandled;
1299 }
1300
1301 string getcommandkey(string text, string command)
1302 {
1303         string keys;
1304         float n, j, k, l;
1305
1306         if (!hud_showbinds)
1307                 return text;
1308
1309         keys = db_get(binddb, command);
1310         if (!keys)
1311         {
1312                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1313                 for(j = 0; j < n; ++j)
1314                 {
1315                         k = stof(argv(j));
1316                         if(k != -1)
1317                         {
1318                                 if ("" == keys)
1319                                         keys = keynumtostring(k);
1320                                 else
1321                                         keys = strcat(keys, ", ", keynumtostring(k));
1322
1323                                 ++l;
1324                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1325                         }
1326
1327                 }
1328                 db_put(binddb, command, keys);
1329         }
1330
1331         if ("" == keys) {
1332                 if (hud_showbinds > 1)
1333                         return strcat(text, " (not bound)");
1334                 else
1335                         return text;
1336         }
1337         else if (hud_showbinds > 1)
1338                 return strcat(text, " (", keys, ")");
1339         else
1340                 return keys;
1341 }