qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = func_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(FL_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 158         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 159
 160         WaypointSprite_Load();
 161
 162         // precaches
 163         precache_model("null");
 164         precache_sound("misc/hit.wav");
 165         precache_sound("misc/typehit.wav");
 166         if (autocvar_cl_precacheplayermodels)
 167         {
 168                 precache_all_playermodels("models/player/*.zym");
 169                 precache_all_playermodels("models/player/*.dpm");
 170                 precache_all_playermodels("models/player/*.md3");
 171                 precache_all_playermodels("models/player/*.psk");
 172                 precache_all_playermodels("models/player/*.iqm");
 173         }
 174
 175         Projectile_Precache();
 176         Hook_Precache();
 177         GibSplash_Precache();
 178         Casings_Precache();
 179         DamageInfo_Precache();
 180         Vehicles_Precache();
 181         turrets_precache();
 182     Announcer_Precache();
 183         Tuba_Precache();
 184         CSQCPlayer_Precache();
 185
 186         if(autocvar_cl_reticle)
 187         {
 188                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 189                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 190         }
 191
 192         get_mi_min_max_texcoords(1); // try the CLEVER way first
 193         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 194         shortmapname = mi_shortname;
 195
 196         if(precache_pic(minimapname) == "")
 197         {
 198                 // but maybe we have a non-clever minimap
 199                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 200                 if(precache_pic(minimapname) == "")
 201                         minimapname = ""; // FAIL
 202                 else
 203                         get_mi_min_max_texcoords(0); // load new texcoords
 204         }
 205
 206         mi_center = (mi_min + mi_max) * 0.5;
 207         mi_scale = mi_max - mi_min;
 208         minimapname = strzone(minimapname);
 209
 210         WarpZone_Init();
 211
 212         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 213         hud_configure_prev = -1;
 214         tab_panel = -1;
 215
 216         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 217 }
 218
 219 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 220 void Shutdown(void)
 221 {
 222 #ifdef USE_FTE
 223 #pragma TARGET id
 224         if(!__engine_check)
 225                 return 0;
 226 #pragma TARGET fte
 227 #endif
 228
 229         WarpZone_Shutdown();
 230
 231         remove(teams);
 232         remove(players);
 233         db_close(binddb);
 234         db_close(tempdb);
 235         if(autocvar_cl_db_saveasdump)
 236                 db_dump(ClientProgsDB, "client.db");
 237         else
 238                 db_save(ClientProgsDB, "client.db");
 239         db_close(ClientProgsDB);
 240
 241         if(camera_active)
 242                 cvar_set("chase_active",ftos(chase_active_backup));
 243
 244         // unset the event chasecam's chase_active
 245         if(autocvar_chase_active < 0)
 246                 cvar_set("chase_active", "0");
 247
 248         if not(isdemo())
 249         {
 250                 if not(calledhooks & HOOK_START)
 251                         localcmd("\n_cl_hook_gamestart nop\n");
 252                 if not(calledhooks & HOOK_END)
 253                         localcmd("\ncl_hook_gameend\n");
 254         }
 255 }
 256
 257 .float has_team;
 258 float SetTeam(entity o, float Team)
 259 {
 260         entity tm;
 261         if(teamplay)
 262         {
 263                 switch(Team)
 264                 {
 265                         case -1:
 266                         case FL_TEAM_1:
 267                         case FL_TEAM_2:
 268                         case FL_TEAM_3:
 269                         case FL_TEAM_4:
 270                                 break;
 271                         default:
 272                                 if(GetTeam(Team, false) == world)
 273                                 {
 274                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 275                                         Team = FL_SPECTATOR;
 276                                 }
 277                                 break;
 278                 }
 279         }
 280         else
 281         {
 282                 switch(Team)
 283                 {
 284                         case -1:
 285                         case 0:
 286                                 break;
 287                         default:
 288                                 if(GetTeam(Team, false) == world)
 289                                 {
 290                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 291                                         Team = FL_SPECTATOR;
 292                                 }
 293                                 break;
 294                 }
 295         }
 296         if(Team == -1) // leave
 297         {
 298                 if(o.has_team)
 299                 {
 300                         tm = GetTeam(o.team, false);
 301                         tm.team_size -= 1;
 302                         o.has_team = 0;
 303                         return TRUE;
 304                 }
 305         }
 306         else
 307         {
 308                 if not(o.has_team)
 309                 {
 310                         o.team = Team;
 311                         tm = GetTeam(Team, true);
 312                         tm.team_size += 1;
 313                         o.has_team = 1;
 314                         return TRUE;
 315                 }
 316                 else if(Team != o.team)
 317                 {
 318                         tm = GetTeam(o.team, false);
 319                         tm.team_size -= 1;
 320                         o.team = Team;
 321                         tm = GetTeam(Team, true);
 322                         tm.team_size += 1;
 323                         return TRUE;
 324                 }
 325         }
 326         return FALSE;
 327 }
 328
 329 void Playerchecker_Think()
 330 {
 331         float i;
 332         entity e;
 333         for(i = 0; i < maxclients; ++i)
 334         {
 335                 e = playerslots[i];
 336                 if(GetPlayerName(i) == "")
 337                 {
 338                         if(e.sort_prev)
 339                         {
 340                                 // player disconnected
 341                                 SetTeam(e, -1);
 342                                 RemovePlayer(e);
 343                                 e.sort_prev = world;
 344                                 //e.gotscores = 0;
 345                         }
 346                 }
 347                 else
 348                 {
 349                         if not(e.sort_prev)
 350                         {
 351                                 // player connected
 352                                 if not(e)
 353                                         playerslots[i] = e = spawn();
 354                                 e.sv_entnum = i;
 355                                 e.ping = 0;
 356                                 e.ping_packetloss = 0;
 357                                 e.ping_movementloss = 0;
 358                                 //e.gotscores = 0; // we might already have the scores...
 359                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 360                                 RegisterPlayer(e);
 361                                 HUD_UpdatePlayerPos(e);
 362                         }
 363                 }
 364         }
 365         self.nextthink = time + 0.2;
 366 }
 367
 368 void Porto_Init();
 369 void TrueAim_Init();
 370 void PostInit(void)
 371 {
 372         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 373
 374         entity playerchecker;
 375         playerchecker = spawn();
 376         playerchecker.think = Playerchecker_Think;
 377         playerchecker.nextthink = time + 0.2;
 378
 379         Porto_Init();
 380         TrueAim_Init();
 381
 382         postinit = true;
 383 }
 384
 385 float button_zoom;
 386
 387 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 388 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 389 // All keys are in ascii.
 390 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 391 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 392 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 393 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 394 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 395 {
 396         float bSkipKey;
 397         bSkipKey = false;
 398
 399         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 400                 return true;
 401
 402         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 403                 return true;
 404
 405         if(menu_visible && menu_action)
 406                 if(menu_action(bInputType, nPrimary, nSecondary))
 407                         return TRUE;
 408
 409         return bSkipKey;
 410 }
 411
 412 // END REQUIRED CSQC FUNCTIONS
 413 // --------------------------------------------------------------------------
 414
 415 // --------------------------------------------------------------------------
 416 // BEGIN OPTIONAL CSQC FUNCTIONS
 417 void Ent_RemoveEntCS()
 418 {
 419         entcs_receiver[self.sv_entnum] = world;
 420 }
 421 void Ent_ReadEntCS()
 422 {
 423         float sf;
 424         InterpolateOrigin_Undo();
 425
 426         self.classname = "entcs_receiver";
 427         sf = ReadByte();
 428
 429         if(sf & 1)
 430                 self.sv_entnum = ReadByte();
 431         if(sf & 2)
 432         {
 433                 self.origin_x = ReadShort();
 434                 self.origin_y = ReadShort();
 435                 self.origin_z = ReadShort();
 436                 setorigin(self, self.origin);
 437         }
 438         if(sf & 4)
 439         {
 440                 self.angles_y = ReadByte() * 360.0 / 256;
 441                 self.angles_x = self.angles_z = 0;
 442         }
 443         if(sf & 8)
 444                 self.healthvalue = ReadByte() * 10;
 445         if(sf & 16)
 446                 self.armorvalue = ReadByte() * 10;
 447
 448         entcs_receiver[self.sv_entnum] = self;
 449         self.entremove = Ent_RemoveEntCS;
 450         self.iflags |= IFLAG_ORIGIN;
 451
 452         InterpolateOrigin_Note();
 453 }
 454
 455 void Ent_Remove();
 456
 457 void Ent_RemovePlayerScore()
 458 {
 459         float i;
 460
 461         if(self.owner)
 462         {
 463                 SetTeam(self.owner, -1);
 464                 self.owner.gotscores = 0;
 465                 for(i = 0; i < MAX_SCORE; ++i)
 466                         self.owner.(scores[i]) = 0; // clear all scores
 467         }
 468 }
 469
 470 void Ent_ReadPlayerScore()
 471 {
 472         float i, n;
 473         float isNew;
 474         entity o;
 475
 476         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 477         // (no I've never heard of M-x replace-string, sed, or anything like that)
 478         isNew = !self.owner; // workaround for DP bug
 479         n = ReadByte()-1;
 480
 481 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 482         if(!isNew && n != self.sv_entnum)
 483         {
 484                 //print(_("A CSQC entity changed its owner!\n"));
 485                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 486                 isNew = true;
 487                 Ent_Remove();
 488                 self.enttype = ENT_CLIENT_SCORES;
 489         }
 490 #endif
 491
 492         self.sv_entnum = n;
 493
 494         if not(playerslots[self.sv_entnum])
 495                 playerslots[self.sv_entnum] = spawn();
 496         o = self.owner = playerslots[self.sv_entnum];
 497         o.sv_entnum = self.sv_entnum;
 498         o.gotscores = 1;
 499
 500         //if not(o.sort_prev)
 501         //      RegisterPlayer(o);
 502         //playerchecker will do this for us later, if it has not already done so
 503
 504         float sf, lf;
 505 #if MAX_SCORE <= 8
 506         sf = ReadByte();
 507         lf = ReadByte();
 508 #else
 509         sf = ReadShort();
 510         lf = ReadShort();
 511 #endif
 512         float p;
 513         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 514                 if(sf & p)
 515                 {
 516                         if(lf & p)
 517                                 o.(scores[i]) = ReadInt24_t();
 518                         else
 519                                 o.(scores[i]) = ReadChar();
 520                 }
 521
 522         if(o.sort_prev)
 523                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 524
 525         self.entremove = Ent_RemovePlayerScore;
 526 }
 527
 528 void Ent_ReadTeamScore()
 529 {
 530         float i;
 531         entity o;
 532
 533         self.team = ReadByte();
 534         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 535
 536         float sf, lf;
 537 #if MAX_TEAMSCORE <= 8
 538         sf = ReadByte();
 539         lf = ReadByte();
 540 #else
 541         sf = ReadShort();
 542         lf = ReadShort();
 543 #endif
 544         float p;
 545         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 546                 if(sf & p)
 547                 {
 548                         if(lf & p)
 549                                 o.(teamscores[i]) = ReadInt24_t();
 550                         else
 551                                 o.(teamscores[i]) = ReadChar();
 552                 }
 553
 554         HUD_UpdateTeamPos(o);
 555 }
 556
 557 void Ent_ClientData()
 558 {
 559         float f;
 560         float newspectatee_status;
 561
 562         f = ReadByte();
 563
 564         scoreboard_showscores_force = (f & 1);
 565
 566         if(f & 2)
 567         {
 568                 newspectatee_status = ReadByte();
 569                 if(newspectatee_status == player_localnum + 1)
 570                         newspectatee_status = -1; // observing
 571         }
 572         else
 573                 newspectatee_status = 0;
 574
 575         spectatorbutton_zoom = (f & 4);
 576
 577         if(f & 8)
 578         {
 579                 angles_held_status = 1;
 580                 angles_held_x = ReadAngle();
 581                 angles_held_y = ReadAngle();
 582                 angles_held_z = 0;
 583         }
 584         else
 585                 angles_held_status = 0;
 586
 587         if(newspectatee_status != spectatee_status)
 588         {
 589                 // clear race stuff
 590                 race_laptime = 0;
 591                 race_checkpointtime = 0;
 592         }
 593         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 594         {
 595                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 596                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 597                 )
 598                         prev_p_health = -1;
 599                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 600                         prev_health = -1;
 601         }
 602         spectatee_status = newspectatee_status;
 603
 604         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 605 }
 606
 607 void Ent_Nagger()
 608 {
 609         float nags, i, j, b, f;
 610
 611         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 612
 613         if(!(nags & 4))
 614         {
 615                 if(vote_called_vote)
 616                         strunzone(vote_called_vote);
 617                 vote_called_vote = string_null;
 618                 vote_active = 0;
 619         }
 620         else
 621         {
 622                 vote_active = 1;
 623         }
 624
 625         if(nags & 64)
 626         {
 627                 vote_yescount = ReadByte();
 628                 vote_nocount = ReadByte();
 629                 vote_needed = ReadByte();
 630                 vote_highlighted = ReadChar();
 631         }
 632
 633         if(nags & 128)
 634         {
 635                 if(vote_called_vote)
 636                         strunzone(vote_called_vote);
 637                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 638         }
 639
 640         if(nags & 1)
 641         {
 642                 for(j = 0; j < maxclients; ++j)
 643                         if(playerslots[j])
 644                                 playerslots[j].ready = 1;
 645                 for(i = 1; i <= maxclients; i += 8)
 646                 {
 647                         f = ReadByte();
 648                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 649                                 if not(f & b)
 650                                         if(playerslots[j])
 651                                                 playerslots[j].ready = 0;
 652                 }
 653         }
 654
 655         ready_waiting = (nags & 1);
 656         ready_waiting_for_me = (nags & 2);
 657         vote_waiting = (nags & 4);
 658         vote_waiting_for_me = (nags & 8);
 659         warmup_stage = (nags & 16);
 660 }
 661
 662 void Ent_RandomSeed()
 663 {
 664         float s;
 665         prandom_debug();
 666         s = ReadShort();
 667         psrandom(s);
 668 }
 669
 670 void Ent_ReadAccuracy(void)
 671 {
 672         float sf, f, w, b;
 673         sf = ReadInt24_t();
 674         if(sf == 0)
 675         {
 676                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 677                         weapon_accuracy[w] = -1;
 678                 return;
 679         }
 680
 681         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 682         {
 683                 if(sf & f)
 684                 {
 685                         b = ReadByte();
 686                         if(b == 0)
 687                                 weapon_accuracy[w] = -1;
 688                         else if(b == 255)
 689                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 690                         else
 691                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 692                 }
 693                 if(f == 0x800000)
 694                         f = 1;
 695                 else
 696                         f *= 2;
 697         }
 698 }
 699
 700 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 701 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 702 void Ent_RadarLink();
 703 void Ent_Init();
 704 void Ent_ScoresInfo();
 705 void CSQC_Ent_Update(float bIsNewEntity)
 706 {
 707         float t;
 708         float savetime;
 709         t = ReadByte();
 710
 711         if(autocvar_developer_csqcentities)
 712                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 713
 714         // set up the "time" global for received entities to be correct for interpolation purposes
 715         savetime = time;
 716         if(servertime)
 717         {
 718                 time = servertime;
 719         }
 720         else
 721         {
 722                 serverprevtime = time;
 723                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 724                 time = serverprevtime + serverdeltatime;
 725         }
 726
 727 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 728         if(self.enttype)
 729         {
 730                 if(t != self.enttype || bIsNewEntity)
 731                 {
 732                         //print(_("A CSQC entity changed its type!\n"));
 733                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 734                         Ent_Remove();
 735                         clearentity(self);
 736                         bIsNewEntity = 1;
 737                 }
 738         }
 739         else
 740         {
 741                 if(!bIsNewEntity)
 742                 {
 743                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 744                         bIsNewEntity = 1;
 745                 }
 746         }
 747 #endif
 748         self.enttype = t;
 749         switch(t)
 750         {
 751                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 752                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 753                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 754                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 755                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 756                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 757                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 758                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 759                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 760                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 761                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 762                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 763                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 764                 case ENT_CLIENT_INIT: Ent_Init(); break;
 765                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 766                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 767                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 768                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 769                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 770                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 771                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 772                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 773                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 774                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 775                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 776                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 777                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 778                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 779                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 780                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 781                 case ENT_CLIENT_TURRET: ent_turret(); break;
 782                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 783                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 784                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 785                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 786                 default:
 787                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 788                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 789                         break;
 790         }
 791
 792         time = savetime;
 793 }
 794 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 795 // used when an entity changes its type. For an entity that someone interacts
 796 // with others, make sure it can no longer do so.
 797 void Ent_Remove()
 798 {
 799         if(self.entremove)
 800                 self.entremove();
 801
 802         if(self.skeletonindex)
 803         {
 804                 skel_delete(self.skeletonindex);
 805                 self.skeletonindex = 0;
 806         }
 807
 808         if(self.snd_looping > 0)
 809         {
 810                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 811                 self.snd_looping = 0;
 812         }
 813
 814         self.enttype = 0;
 815         self.classname = "";
 816         self.draw = menu_sub_null;
 817         self.entremove = menu_sub_null;
 818         // TODO possibly set more stuff to defaults
 819 }
 820 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 821 void CSQC_Ent_Remove()
 822 {
 823         if(autocvar_developer_csqcentities)
 824                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 825
 826         if(wasfreed(self))
 827         {
 828                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 829                 return;
 830         }
 831         if(self.enttype)
 832                 Ent_Remove();
 833         remove(self);
 834 }
 835
 836 void Gamemode_Init()
 837 {
 838         if not(isdemo())
 839         {
 840                 if(!(calledhooks & HOOK_START))
 841                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 842                 calledhooks |= HOOK_START;
 843         }
 844 }
 845 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 846 void CSQC_Parse_StuffCmd(string strMessage)
 847 {
 848         if(autocvar_developer_csqcentities)
 849                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 850
 851         localcmd(strMessage);
 852 }
 853 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 854 void CSQC_Parse_Print(string strMessage)
 855 {
 856         if(autocvar_developer_csqcentities)
 857                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 858
 859         print(ColorTranslateRGB(strMessage));
 860 }
 861
 862 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 863 void CSQC_Parse_CenterPrint(string strMessage)
 864 {
 865         if(autocvar_developer_csqcentities)
 866                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 867
 868         centerprint_hud(strMessage);
 869 }
 870
 871 string notranslate_fogcmd1 = "\nfog ";
 872 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 873 void Fog_Force()
 874 {
 875         // TODO somehow thwart prvm_globalset client ...
 876
 877         if(forcefog != "")
 878                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 879 }
 880
 881 void Gamemode_Init();
 882 void Ent_ScoresInfo()
 883 {
 884         float i;
 885         self.classname = "ent_client_scores_info";
 886         gametype = ReadInt24_t();
 887         for(i = 0; i < MAX_SCORE; ++i)
 888         {
 889                 scores_label[i] = strzone(ReadString());
 890                 scores_flags[i] = ReadByte();
 891         }
 892         for(i = 0; i < MAX_TEAMSCORE; ++i)
 893         {
 894                 teamscores_label[i] = strzone(ReadString());
 895                 teamscores_flags[i] = ReadByte();
 896         }
 897         HUD_InitScores();
 898         Gamemode_Init();
 899 }
 900
 901 void Ent_Init()
 902 {
 903         self.classname = "ent_client_init";
 904
 905         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 906
 907         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 908         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 909         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 910         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 911         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 912         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 913         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 914         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 915         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 916         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 917         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 918         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 919
 920         if(forcefog)
 921                 strunzone(forcefog);
 922         forcefog = strzone(ReadString());
 923
 924         armorblockpercent = ReadByte() / 255.0;
 925
 926         g_weaponswitchdelay = ReadByte() / 255.0;
 927
 928         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 929         g_balance_grenadelauncher_bouncestop = ReadCoord();
 930         g_balance_electro_secondary_bouncefactor = ReadCoord();
 931         g_balance_electro_secondary_bouncestop = ReadCoord();
 932
 933         nex_scope = !ReadByte();
 934         rifle_scope = !ReadByte();
 935
 936         serverflags = ReadByte();
 937
 938         minelayer_maxmines = ReadByte();
 939
 940         hagar_maxrockets = ReadByte();
 941
 942         g_trueaim_minrange = ReadCoord();
 943         g_balance_porto_secondary = ReadByte();
 944
 945         if(!postinit)
 946                 PostInit();
 947 }
 948
 949 void Net_ReadRace()
 950 {
 951         float b;
 952
 953         b = ReadByte();
 954
 955         switch(b)
 956         {
 957                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 958                         race_checkpoint = ReadByte();
 959                         race_time = ReadInt24_t();
 960                         race_previousbesttime = ReadInt24_t();
 961                         if(race_previousbestname)
 962                                 strunzone(race_previousbestname);
 963                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 964
 965                         race_checkpointtime = time;
 966
 967                         if(race_checkpoint == 0 || race_checkpoint == 254)
 968                         {
 969                                 race_penaltyaccumulator = 0;
 970                                 race_laptime = time; // valid
 971                         }
 972
 973                         break;
 974
 975                 case RACE_NET_CHECKPOINT_CLEAR:
 976                         race_laptime = 0;
 977                         race_checkpointtime = 0;
 978                         break;
 979
 980                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 981                         race_laptime = ReadCoord();
 982                         race_checkpointtime = -99999;
 983                         // fall through
 984                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 985                         race_nextcheckpoint = ReadByte();
 986
 987                         race_nextbesttime = ReadInt24_t();
 988                         if(race_nextbestname)
 989                                 strunzone(race_nextbestname);
 990                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 991                         break;
 992
 993                 case RACE_NET_CHECKPOINT_HIT_RACE:
 994                         race_mycheckpoint = ReadByte();
 995                         race_mycheckpointtime = time;
 996                         race_mycheckpointdelta = ReadInt24_t();
 997                         race_mycheckpointlapsdelta = ReadByte();
 998                         if(race_mycheckpointlapsdelta >= 128)
 999                                 race_mycheckpointlapsdelta -= 256;
1000                         if(race_mycheckpointenemy)
1001                                 strunzone(race_mycheckpointenemy);
1002                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1003                         break;
1004
1005                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1006                         race_othercheckpoint = ReadByte();
1007                         race_othercheckpointtime = time;
1008                         race_othercheckpointdelta = ReadInt24_t();
1009                         race_othercheckpointlapsdelta = ReadByte();
1010                         if(race_othercheckpointlapsdelta >= 128)
1011                                 race_othercheckpointlapsdelta -= 256;
1012                         if(race_othercheckpointenemy)
1013                                 strunzone(race_othercheckpointenemy);
1014                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1015                         break;
1016
1017                 case RACE_NET_PENALTY_RACE:
1018                         race_penaltyeventtime = time;
1019                         race_penaltytime = ReadShort();
1020                         //race_penaltyaccumulator += race_penaltytime;
1021                         if(race_penaltyreason)
1022                                 strunzone(race_penaltyreason);
1023                         race_penaltyreason = strzone(ReadString());
1024                         break;
1025
1026                 case RACE_NET_PENALTY_QUALIFYING:
1027                         race_penaltyeventtime = time;
1028                         race_penaltytime = ReadShort();
1029                         race_penaltyaccumulator += race_penaltytime;
1030                         if(race_penaltyreason)
1031                                 strunzone(race_penaltyreason);
1032                         race_penaltyreason = strzone(ReadString());
1033                         break;
1034
1035                 case RACE_NET_SERVER_RECORD:
1036                         race_server_record = ReadInt24_t();
1037                         break;
1038                 case RACE_NET_SPEED_AWARD:
1039                         race_speedaward = ReadInt24_t();
1040                         if(race_speedaward_holder)
1041                                 strunzone(race_speedaward_holder);
1042                         race_speedaward_holder = strzone(ReadString());
1043                         break;
1044                 case RACE_NET_SPEED_AWARD_BEST:
1045                         race_speedaward_alltimebest = ReadInt24_t();
1046                         if(race_speedaward_alltimebest_holder)
1047                                 strunzone(race_speedaward_alltimebest_holder);
1048                         race_speedaward_alltimebest_holder = strzone(ReadString());
1049                         break;
1050                 case RACE_NET_SERVER_RANKINGS:
1051                         float pos, prevpos, del;
1052                         pos = ReadShort();
1053                         prevpos = ReadShort();
1054                         del = ReadShort();
1055
1056                         // move other rankings out of the way
1057                         float i;
1058                         if (prevpos) {
1059                                 for (i=prevpos-1;i>pos-1;--i) {
1060                                         grecordtime[i] = grecordtime[i-1];
1061                                         if(grecordholder[i])
1062                                                 strunzone(grecordholder[i]);
1063                                         grecordholder[i] = strzone(grecordholder[i-1]);
1064                                 }
1065                         } else if (del) { // a record has been deleted by the admin
1066                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1067                                         if (i == RANKINGS_CNT-1) { // clear out last record
1068                                                 grecordtime[i] = 0;
1069                                                 if (grecordholder[i])
1070                                                         strunzone(grecordholder[i]);
1071                                                 grecordholder[i] = string_null;
1072                                         }
1073                                         else {
1074                                                 grecordtime[i] = grecordtime[i+1];
1075                                                 if (grecordholder[i])
1076                                                         strunzone(grecordholder[i]);
1077                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1078                                         }
1079                                 }
1080                         } else { // player has no ranked record yet
1081                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1082                                         grecordtime[i] = grecordtime[i-1];
1083                                         if(grecordholder[i])
1084                                                 strunzone(grecordholder[i]);
1085                                         grecordholder[i] = strzone(grecordholder[i-1]);
1086                                 }
1087                         }
1088
1089                         // store new ranking
1090                         if(grecordholder[pos-1] != "")
1091                                 strunzone(grecordholder[pos-1]);
1092                         grecordholder[pos-1] = strzone(ReadString());
1093                         grecordtime[pos-1] = ReadInt24_t();
1094                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1095                                 race_myrank = pos;
1096                         break;
1097                 case RACE_NET_SERVER_STATUS:
1098                         race_status = ReadShort();
1099                         if(race_status_name)
1100                                 strunzone(race_status_name);
1101                         race_status_name = strzone(ReadString());
1102         }
1103 }
1104
1105 void Net_ReadSpawn()
1106 {
1107         zoomin_effect = 1;
1108         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
1109 }
1110
1111 void Net_TeamNagger()
1112 {
1113         teamnagger = 1;
1114 }
1115
1116 void Net_ReadPingPLReport()
1117 {
1118         float e, pi, pl, ml;
1119         e = ReadByte();
1120         pi = ReadShort();
1121         pl = ReadByte();
1122         ml = ReadByte();
1123         if not(playerslots[e])
1124                 return;
1125         playerslots[e].ping = pi;
1126         playerslots[e].ping_packetloss = pl / 255.0;
1127         playerslots[e].ping_movementloss = ml / 255.0;
1128 }
1129
1130 void Net_WeaponComplain() {
1131         complain_weapon = ReadByte();
1132
1133         if(complain_weapon_name)
1134                 strunzone(complain_weapon_name);
1135         complain_weapon_name = strzone(ReadString());
1136
1137         complain_weapon_type = ReadByte();
1138
1139         complain_weapon_time = time;
1140         weapontime = time; // ping the weapon panel
1141 }
1142
1143 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1144 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1145 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1146 float CSQC_Parse_TempEntity()
1147 {
1148         float bHandled;
1149                 bHandled  = true;
1150         // Acquire TE ID
1151         float nTEID;
1152                 nTEID = ReadByte();
1153
1154         if(autocvar_developer_csqcentities)
1155                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1156
1157                 // NOTE: Could just do return instead of break...
1158         switch(nTEID)
1159         {
1160                 case TE_CSQC_TARGET_MUSIC:
1161                         Net_TargetMusic();
1162                         bHandled = true;
1163                         break;
1164                 case TE_CSQC_PICTURE:
1165                         Net_MapVote_Picture();
1166                         bHandled = true;
1167                         break;
1168                 case TE_CSQC_RACE:
1169                         Net_ReadRace();
1170                         bHandled = true;
1171                         break;
1172                 case TE_CSQC_SPAWN:
1173                         Net_ReadSpawn();
1174                         bHandled = true;
1175                         break;
1176                 case TE_CSQC_ZCURVEPARTICLES:
1177                         Net_ReadZCurveParticles();
1178                         bHandled = true;
1179                         break;
1180                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1181                         Net_ReadNexgunBeamParticle();
1182                         bHandled = true;
1183                         break;
1184                 case TE_CSQC_TEAMNAGGER:
1185                         Net_TeamNagger();
1186                         bHandled = true;
1187                         break;
1188                 case TE_CSQC_LIGHTNINGARC:
1189                         Net_ReadLightningarc();
1190                         bHandled = true;
1191                         break;
1192                 case TE_CSQC_PINGPLREPORT:
1193                         Net_ReadPingPLReport();
1194                         bHandled = true;
1195                         break;
1196                 case TE_CSQC_ANNOUNCE:
1197                         Announcer_Play(ReadString());
1198                         bHandled = true;
1199                         break;
1200                 case TE_CSQC_KILLNOTIFY:
1201                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1202                         bHandled = true;
1203                         break;
1204                 case TE_CSQC_CENTERPRINT_GENERIC:
1205                         float id;
1206                         string s;
1207                         id = ReadByte();
1208                         s = ReadString();
1209                         if (id != 0 && s != "")
1210                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1211                         else
1212                                 centerprint_generic(id, s, 0, 0);
1213                         bHandled = true;
1214                         break;
1215                 case TE_CSQC_WEAPONCOMPLAIN:
1216                         Net_WeaponComplain();
1217                         bHandled = true;
1218                         break;
1219                 case TE_CSQC_VEHICLESETUP:
1220                         Net_VehicleSetup();
1221                         bHandled = true;
1222                         break;
1223                 case TE_CSQC_SVNOTICE:
1224                         cl_notice_read();
1225                         bHandled = true;
1226                         break;
1227                 default:
1228                         // No special logic for this temporary entity; return 0 so the engine can handle it
1229                         bHandled = false;
1230                         break;
1231         }
1232
1233         return bHandled;
1234 }
1235
1236 string getcommandkey(string text, string command)
1237 {
1238         string keys;
1239         float n, j, k, l = 0;
1240
1241         if (!autocvar_hud_showbinds)
1242                 return text;
1243
1244         keys = db_get(binddb, command);
1245         if (keys == "")
1246         {
1247                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1248                 for(j = 0; j < n; ++j)
1249                 {
1250                         k = stof(argv(j));
1251                         if(k != -1)
1252                         {
1253                                 if ("" == keys)
1254                                         keys = keynumtostring(k);
1255                                 else
1256                                         keys = strcat(keys, ", ", keynumtostring(k));
1257
1258                                 ++l;
1259                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1260                                         break;
1261                         }
1262
1263                 }
1264                 if (keys == "")
1265                         keys = "NO_KEY";
1266                 db_put(binddb, command, keys);
1267         }
1268
1269         if (keys == "NO_KEY") {
1270                 if (autocvar_hud_showbinds > 1)
1271                         return sprintf(_("%s (not bound)"), text);
1272                 else
1273                         return text;
1274         }
1275         else if (autocvar_hud_showbinds > 1)
1276                 return sprintf(_("%s (%s)"), text, keys);
1277         else
1278                 return keys;
1279 }