qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: %s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+button3");
  95         registercmd("-button3");
  96         registercmd("+button4");
  97         registercmd("-button4");
  98         registercmd("+showscores");registercmd("-showscores");
  99         registercmd("+showaccuracy");registercmd("-showaccuracy");
 100
 101 #ifndef CAMERATEST
 102         if(isdemo())
 103         {
 104 #endif
 105                 registercmd("+forward");registercmd("-forward");
 106                 registercmd("+back");registercmd("-back");
 107                 registercmd("+moveup");registercmd("-moveup");
 108                 registercmd("+movedown");registercmd("-movedown");
 109                 registercmd("+moveright");registercmd("-moveright");
 110                 registercmd("+moveleft");registercmd("-moveleft");
 111                 registercmd("+roll_right");registercmd("-roll_right");
 112                 registercmd("+roll_left");registercmd("-roll_left");
 113 #ifndef CAMERATEST
 114         }
 115 #endif
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 118
 119         gametype = 0;
 120
 121         // hud_fields uses strunzone on the titles!
 122         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 123                 hud_title[i] = strzone("(null)");
 124
 125         postinit = false;
 126
 127         calledhooks = 0;
 128
 129         teams = Sort_Spawn();
 130         players = Sort_Spawn();
 131
 132         GetTeam(COLOR_SPECTATOR, true); // add specs first
 133
 134         RegisterWeapons();
 135
 136         WaypointSprite_Load();
 137
 138         // precaches
 139         precache_sound("misc/hit.wav");
 140         precache_sound("misc/typehit.wav");
 141         Projectile_Precache();
 142         Hook_Precache();
 143         GibSplash_Precache();
 144         Casings_Precache();
 145         DamageInfo_Precache();
 146         if(autocvar_cl_announcer != cl_announcer_prev) {
 147                 Announcer_Precache();
 148                 if(cl_announcer_prev)
 149                         strunzone(cl_announcer_prev);
 150                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 151         }
 152         Tuba_Precache();
 153
 154         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 155         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 156
 157         get_mi_min_max_texcoords(1); // try the CLEVER way first
 158         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 159         shortmapname = mi_shortname;
 160
 161         if(precache_pic(minimapname) == "")
 162         {
 163                 // but maybe we have a non-clever minimap
 164                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 165                 if(precache_pic(minimapname) == "")
 166                         minimapname = ""; // FAIL
 167                 else
 168                         get_mi_min_max_texcoords(0); // load new texcoords
 169         }
 170
 171         mi_center = (mi_min + mi_max) * 0.5;
 172         mi_scale = mi_max - mi_min;
 173         minimapname = strzone(minimapname);
 174
 175         WarpZone_Init();
 176
 177         hud_configure_prev = -1;
 178         tab_panel = -1;
 179 }
 180
 181 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 182 void CSQC_Shutdown(void)
 183 {
 184 #ifdef USE_FTE
 185 #pragma TARGET id
 186         if(!__engine_check)
 187                 return 0;
 188 #pragma TARGET fte
 189 #endif
 190
 191         WarpZone_Shutdown();
 192
 193         remove(teams);
 194         remove(players);
 195         db_close(binddb);
 196         db_close(tempdb);
 197         if(autocvar_cl_db_saveasdump)
 198                 db_dump(ClientProgsDB, "client.db");
 199         else
 200                 db_save(ClientProgsDB, "client.db");
 201         db_close(ClientProgsDB);
 202
 203         cvar_clientsettemp_restore();
 204
 205         if(camera_active)
 206                 cvar_set("chase_active",ftos(chase_active_backup));
 207
 208         if not(isdemo())
 209         {
 210                 if not(calledhooks & HOOK_START)
 211                         localcmd("\n_cl_hook_gamestart nop\n");
 212                 if not(calledhooks & HOOK_END)
 213                         localcmd("\ncl_hook_gameend\n");
 214         }
 215 }
 216
 217 .float has_team;
 218 float SetTeam(entity o, float Team)
 219 {
 220         entity tm;
 221         if(teamplay)
 222         {
 223                 switch(Team)
 224                 {
 225                         case -1:
 226                         case COLOR_TEAM1:
 227                         case COLOR_TEAM2:
 228                         case COLOR_TEAM3:
 229                         case COLOR_TEAM4:
 230                                 break;
 231                         default:
 232                                 if(GetTeam(Team, false) == NULL)
 233                                 {
 234                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 235                                         Team = COLOR_SPECTATOR;
 236                                 }
 237                                 break;
 238                 }
 239         }
 240         else
 241         {
 242                 switch(Team)
 243                 {
 244                         case -1:
 245                         case 0:
 246                                 break;
 247                         default:
 248                                 if(GetTeam(Team, false) == NULL)
 249                                 {
 250                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 251                                         Team = COLOR_SPECTATOR;
 252                                 }
 253                                 break;
 254                 }
 255         }
 256         if(Team == -1) // leave
 257         {
 258                 if(o.has_team)
 259                 {
 260                         tm = GetTeam(o.team, false);
 261                         tm.team_size -= 1;
 262                         o.has_team = 0;
 263                         return TRUE;
 264                 }
 265         }
 266         else
 267         {
 268                 if not(o.has_team)
 269                 {
 270                         o.team = Team;
 271                         tm = GetTeam(Team, true);
 272                         tm.team_size += 1;
 273                         o.has_team = 1;
 274                         return TRUE;
 275                 }
 276                 else if(Team != o.team)
 277                 {
 278                         tm = GetTeam(o.team, false);
 279                         tm.team_size -= 1;
 280                         o.team = Team;
 281                         tm = GetTeam(Team, true);
 282                         tm.team_size += 1;
 283                         return TRUE;
 284                 }
 285         }
 286         return FALSE;
 287 }
 288
 289 void Playerchecker_Think()
 290 {
 291         float i;
 292         entity e;
 293         for(i = 0; i < maxclients; ++i)
 294         {
 295                 e = playerslots[i];
 296                 if(GetPlayerName(i) == "")
 297                 {
 298                         if(e.sort_prev)
 299                         {
 300                                 // player disconnected
 301                                 SetTeam(e, -1);
 302                                 RemovePlayer(e);
 303                                 e.sort_prev = world;
 304                                 //e.gotscores = 0;
 305                         }
 306                 }
 307                 else
 308                 {
 309                         if not(e.sort_prev)
 310                         {
 311                                 // player connected
 312                                 if not(e)
 313                                         playerslots[i] = e = spawn();
 314                                 e.sv_entnum = i;
 315                                 e.ping = 0;
 316                                 e.ping_packetloss = 0;
 317                                 e.ping_movementloss = 0;
 318                                 //e.gotscores = 0; // we might already have the scores...
 319                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 320                                 RegisterPlayer(e);
 321                                 HUD_UpdatePlayerPos(e);
 322                         }
 323                 }
 324         }
 325         self.nextthink = time + 0.2;
 326 }
 327
 328 void Porto_Init();
 329 void TrueAim_Init();
 330 void PostInit(void)
 331 {
 332         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 333
 334         entity playerchecker;
 335         playerchecker = spawn();
 336         playerchecker.think = Playerchecker_Think;
 337         playerchecker.nextthink = time + 0.2;
 338
 339         Porto_Init();
 340         TrueAim_Init();
 341
 342         postinit = true;
 343 }
 344
 345 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 346 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 347 float button_zoom;
 348 void Cmd_HUD_SetFields(float);
 349 void Cmd_HUD_Help(float);
 350 float CSQC_ConsoleCommand(string strMessage)
 351 {
 352         float argc;
 353         // Tokenize String
 354         //argc = tokenize(strMessage);
 355         argc = tokenize_console(strMessage);
 356
 357         // Acquire Command
 358         local string strCmd;
 359         strCmd = argv(0);
 360
 361         if(strCmd == "hud_configure") { // config hud
 362                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 363                 return true;
 364         } else if(strCmd == "hud_save") { // save hud config
 365                 if(argv(1) == "" || argv(2)) {
 366                         print(_("Usage:\n"));
 367                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 368                 }
 369                 else
 370                         HUD_Panel_ExportCfg(argv(1));
 371                 return true;
 372         } else if(strCmd == "+button4") { // zoom
 373                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 374                 if(ignore_plus_zoom)
 375                 {
 376                         --ignore_plus_zoom;
 377                         return false;
 378                 }
 379                 button_zoom = 1;
 380                 return true;
 381         } else if(strCmd == "-button4") { // zoom
 382                 if(ignore_minus_zoom)
 383                 {
 384                         --ignore_minus_zoom;
 385                         return false;
 386                 }
 387                 button_zoom = 0;
 388                 return true;
 389         } else if(strCmd == "+button3") { // secondary
 390                 button_attack2 = 1;
 391                 return false;
 392         } else if(strCmd == "-button3") { // secondary
 393                 button_attack2 = 0;
 394                 return false;
 395         } else if(strCmd == "+showscores") {
 396                 scoreboard_showscores = true;
 397                 return true;
 398         } else if(strCmd == "-showscores") {
 399                 scoreboard_showscores = false;
 400                 return true;
 401         } else if(strCmd == "+showaccuracy") {
 402                 scoreboard_showaccuracy = true;
 403                 return true;
 404         } else if(strCmd == "-showaccuracy") {
 405                 scoreboard_showaccuracy = false;
 406                 return true;
 407         }
 408
 409         if(camera_active)
 410         if(strCmd == "+forward" || strCmd == "-back") {
 411                 ++camera_direction_x;
 412                 return true;
 413         } else if(strCmd == "-forward" || strCmd == "+back") {
 414                 --camera_direction_x;
 415                 return true;
 416         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 417                 --camera_direction_y;
 418                 return true;
 419         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 420                 ++camera_direction_y;
 421                 return true;
 422         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 423                 ++camera_direction_z;
 424                 return true;
 425         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 426                 --camera_direction_z;
 427                 return true;
 428         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 429                 ++camera_roll;
 430                 return true;
 431         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 432                 --camera_roll;
 433                 return true;
 434         }
 435
 436         return false;
 437 }
 438
 439 .vector view_ofs;
 440 entity debug_shotorg;
 441 void ShotOrg_Draw()
 442 {
 443         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 444         self.angles = view_angles;
 445         self.angles_x = -self.angles_x;
 446         if not(self.cnt)
 447                 self.drawmask = MASK_NORMAL;
 448         else
 449                 self.drawmask = 0;
 450 }
 451 void ShotOrg_Draw2D()
 452 {
 453         vector coord2d_topleft, coord2d_topright, coord2d;
 454         string s;
 455         vector fs;
 456
 457         s = vtos(self.view_ofs);
 458         s = substring(s, 1, strlen(s) - 2);
 459         if(tokenize_console(s) == 3)
 460                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 461
 462         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 463         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 464
 465         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 466
 467         coord2d = coord2d_topleft;
 468         if(fs_x < 8)
 469         {
 470                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 471                 fs = '8 8 0';
 472         }
 473         coord2d_y -= fs_y;
 474         coord2d_z = 0;
 475         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 476 }
 477
 478 void ShotOrg_Spawn()
 479 {
 480         debug_shotorg = spawn();
 481         debug_shotorg.draw = ShotOrg_Draw;
 482         debug_shotorg.draw2d = ShotOrg_Draw2D;
 483         debug_shotorg.renderflags = RF_VIEWMODEL;
 484         debug_shotorg.effects = EF_FULLBRIGHT;
 485         precache_model("models/shotorg_adjuster.md3");
 486         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 487         debug_shotorg.scale = 2;
 488         debug_shotorg.view_ofs = '25 8 -8';
 489 }
 490
 491 void DrawDebugModel()
 492 {
 493         if(time - floor(time) > 0.5)
 494         {
 495                 PolyDrawModel(self);
 496                 self.drawmask = 0;
 497         }
 498         else
 499         {
 500                 self.renderflags = 0;
 501                 self.drawmask = MASK_NORMAL;
 502         }
 503 }
 504
 505 void GameCommand(string msg)
 506 {
 507         string s;
 508         float argc;
 509         entity e;
 510         argc = tokenize_console(msg);
 511
 512         if(argv(0) == "help" || argc == 0)
 513         {
 514                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 515                 print(_("  settemp cvar value\n"));
 516                 print(_("  scoreboard_columns_set ...\n"));
 517                 print(_("  scoreboard_columns_help\n"));
 518                 GameCommand_Generic("help");
 519                 return;
 520         }
 521
 522         if(GameCommand_Generic(msg))
 523                 return;
 524
 525         string cmd;
 526         cmd = argv(0);
 527         if(cmd == "mv_download") {
 528                 Cmd_MapVote_MapDownload(argc);
 529         }
 530         else if(cmd == "settemp") {
 531                 cvar_clientsettemp(argv(1), argv(2));
 532         }
 533         else if(cmd == "scoreboard_columns_set") {
 534                 Cmd_HUD_SetFields(argc);
 535         }
 536         else if(cmd == "scoreboard_columns_help") {
 537                 Cmd_HUD_Help(argc);
 538         }
 539 #ifdef BLURTEST
 540         else if(cmd == "blurtest") {
 541                 blurtest_time0 = time;
 542                 blurtest_time1 = time + stof(argv(1));
 543                 blurtest_radius = stof(argv(2));
 544                 blurtest_power = stof(argv(3));
 545         }
 546 #endif
 547         else if(cmd == "shotorg_move") {
 548                 if(!debug_shotorg)
 549                         ShotOrg_Spawn();
 550                 else
 551                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 552                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 553         }
 554         else if(cmd == "shotorg_movez") {
 555                 if(!debug_shotorg)
 556                         ShotOrg_Spawn();
 557                 else
 558                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 559                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 560         }
 561         else if(cmd == "shotorg_set") {
 562                 if(!debug_shotorg)
 563                         ShotOrg_Spawn();
 564                 else
 565                         debug_shotorg.view_ofs = stov(argv(1));
 566                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 567         }
 568         else if(cmd == "shotorg_setz") {
 569                 if(!debug_shotorg)
 570                         ShotOrg_Spawn();
 571                 else
 572                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 573                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 574         }
 575         else if(cmd == "shotorg_toggle_hide") {
 576                 if(debug_shotorg)
 577                 {
 578                         debug_shotorg.cnt = !debug_shotorg.cnt;
 579                 }
 580         }
 581         else if(cmd == "shotorg_end") {
 582                 if(debug_shotorg)
 583                 {
 584                         print(vtos(debug_shotorg.view_ofs), "\n");
 585                         remove(debug_shotorg);
 586                         debug_shotorg = world;
 587                 }
 588                 localcmd("sv_cmd debug_shotorg\n");
 589         }
 590         else if(cmd == "sendcvar") {
 591                 // W_FixWeaponOrder will trash argv, so save what we need.
 592                 string thiscvar;
 593                 thiscvar = strzone(argv(1));
 594                 s = cvar_string(thiscvar);
 595                 if(thiscvar == "cl_weaponpriority")
 596                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 597                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 598                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 599                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 600                 strunzone(thiscvar);
 601         }
 602         else if(cmd == "spawn") {
 603                 s = argv(1);
 604                 e = spawn();
 605                 precache_model(s);
 606                 setmodel(e, s);
 607                 setorigin(e, view_origin);
 608                 e.angles = view_angles;
 609                 e.draw = DrawDebugModel;
 610                 e.classname = "debugmodel";
 611         }
 612     else if(cmd == "vyes")
 613     {
 614         if(uid2name_dialog)
 615         {
 616             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 617             vote_prev = 0;
 618             cvar_set("cl_allow_uid2name", "1");
 619             vote_change = -9999;
 620                         uid2name_dialog = 0;
 621         }
 622         else
 623         {
 624             localcmd("cmd vote yes\n");
 625         }
 626     }
 627     else if(cmd == "vno")
 628     {
 629         if(uid2name_dialog)
 630         {
 631             vote_active = 0;
 632             vote_prev = 0;
 633             cvar_set("cl_allow_uid2name", "0");
 634             vote_change = -9999;
 635                         uid2name_dialog = 0;
 636         }
 637         else
 638         {
 639             localcmd("cmd vote no\n");
 640         }
 641     }
 642
 643         else
 644         {
 645                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 646         }
 647
 648         return;
 649 }
 650
 651 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 652 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 653 // All keys are in ascii.
 654 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 655 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 656 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 657 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 658 {
 659         local float bSkipKey;
 660         bSkipKey = false;
 661
 662         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 663                 return true;
 664
 665         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 666                 return true;
 667
 668         if(menu_visible)
 669                 if(menu_action(bInputType, nPrimary, nSecondary))
 670                         return TRUE;
 671
 672         return bSkipKey;
 673 }
 674
 675 // END REQUIRED CSQC FUNCTIONS
 676 // --------------------------------------------------------------------------
 677
 678 // --------------------------------------------------------------------------
 679 // BEGIN OPTIONAL CSQC FUNCTIONS
 680 void Ent_ReadEntCS()
 681 {
 682         InterpolateOrigin_Undo();
 683
 684         self.classname = "entcs_receiver";
 685         self.sv_entnum = ReadByte() - 1;
 686         self.origin_x = ReadShort();
 687         self.origin_y = ReadShort();
 688         self.origin_z = ReadShort();
 689         self.angles_y = ReadByte() * 360.0 / 256;
 690         self.origin_z = self.angles_x = self.angles_z = 0;
 691
 692         InterpolateOrigin_Note();
 693 }
 694
 695 void Ent_Remove();
 696
 697 void Ent_RemovePlayerScore()
 698 {
 699         float i;
 700
 701         if(self.owner)
 702         {
 703                 SetTeam(self.owner, -1);
 704                 self.owner.gotscores = 0;
 705                 for(i = 0; i < MAX_SCORE; ++i)
 706                         self.owner.(scores[i]) = 0; // clear all scores
 707         }
 708 }
 709
 710 void Ent_ReadPlayerScore()
 711 {
 712         float i, n;
 713         float isNew;
 714         entity o;
 715
 716         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 717         // (no I've never heard of M-x replace-string, sed, or anything like that)
 718         isNew = !self.owner; // workaround for DP bug
 719         n = ReadByte()-1;
 720
 721 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 722         if(!isNew && n != self.sv_entnum)
 723         {
 724                 print(_("A CSQC entity changed its owner!\n"));
 725                 isNew = true;
 726                 Ent_Remove();
 727                 self.enttype = ENT_CLIENT_SCORES;
 728         }
 729 #endif
 730
 731         self.sv_entnum = n;
 732
 733         if not(playerslots[self.sv_entnum])
 734                 playerslots[self.sv_entnum] = spawn();
 735         o = self.owner = playerslots[self.sv_entnum];
 736         o.sv_entnum = self.sv_entnum;
 737         o.gotscores = 1;
 738
 739         //if not(o.sort_prev)
 740         //      RegisterPlayer(o);
 741         //playerchecker will do this for us later, if it has not already done so
 742
 743         float sf, lf;
 744 #if MAX_SCORE <= 8
 745         sf = ReadByte();
 746         lf = ReadByte();
 747 #else
 748         sf = ReadShort();
 749         lf = ReadShort();
 750 #endif
 751         float p;
 752         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 753                 if(sf & p)
 754                 {
 755                         if(lf & p)
 756                                 o.(scores[i]) = ReadInt24_t();
 757                         else
 758                                 o.(scores[i]) = ReadChar();
 759                 }
 760
 761         if(o.sort_prev)
 762                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 763
 764         self.entremove = Ent_RemovePlayerScore;
 765 }
 766
 767 void Ent_ReadTeamScore()
 768 {
 769         float i;
 770         entity o;
 771
 772         self.team = ReadByte();
 773         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 774
 775         float sf, lf;
 776 #if MAX_TEAMSCORE <= 8
 777         sf = ReadByte();
 778         lf = ReadByte();
 779 #else
 780         sf = ReadShort();
 781         lf = ReadShort();
 782 #endif
 783         float p;
 784         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 785                 if(sf & p)
 786                 {
 787                         if(lf & p)
 788                                 o.(teamscores[i]) = ReadInt24_t();
 789                         else
 790                                 o.(teamscores[i]) = ReadChar();
 791                 }
 792
 793         HUD_UpdateTeamPos(o);
 794 }
 795
 796 void Net_Reset()
 797 {
 798 }
 799
 800 void Ent_ClientData()
 801 {
 802         float f;
 803         float newspectatee_status;
 804
 805         f = ReadByte();
 806
 807         scoreboard_showscores_force = (f & 1);
 808
 809         if(f & 2)
 810         {
 811                 newspectatee_status = ReadByte();
 812                 if(newspectatee_status == player_localentnum)
 813                         newspectatee_status = -1; // observing
 814         }
 815         else
 816                 newspectatee_status = 0;
 817
 818         spectatorbutton_zoom = (f & 4);
 819
 820         if(f & 8)
 821         {
 822                 angles_held_status = 1;
 823                 angles_held_x = ReadAngle();
 824                 angles_held_y = ReadAngle();
 825                 angles_held_z = 0;
 826         }
 827         else
 828                 angles_held_status = 0;
 829
 830         if(newspectatee_status != spectatee_status)
 831         {
 832                 float i;
 833
 834                 // clear race stuff
 835                 race_laptime = 0;
 836                 race_checkpointtime = 0;
 837         }
 838         spectatee_status = newspectatee_status;
 839 }
 840
 841 void Ent_Nagger()
 842 {
 843         float nags, i, j, b, f;
 844
 845         nags = ReadByte();
 846
 847         if(nags & 128)
 848         {
 849                 if(vote_called_vote)
 850                         strunzone(vote_called_vote);
 851                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 852         }
 853
 854         if(nags & 1)
 855         {
 856                 for(j = 0; j < maxclients; ++j)
 857                         if(playerslots[j])
 858                                 playerslots[j].ready = 1;
 859                 for(i = 1; i <= maxclients; i += 8)
 860                 {
 861                         f = ReadByte();
 862                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 863                                 if not(f & b)
 864                                         if(playerslots[j])
 865                                                 playerslots[j].ready = 0;
 866                 }
 867         }
 868
 869         ready_waiting = (nags & 1);
 870         ready_waiting_for_me = (nags & 2);
 871         vote_waiting = (nags & 4);
 872         vote_waiting_for_me = (nags & 8);
 873         warmup_stage = (nags & 16);
 874 }
 875
 876 void Ent_RandomSeed()
 877 {
 878         float s;
 879         prandom_debug();
 880         s = ReadShort();
 881         psrandom(s);
 882 }
 883
 884 void Ent_ReadAccuracy(void)
 885 {
 886         float sf, f, w, b;
 887         sf = ReadInt24_t();
 888         if(sf == 0)
 889         {
 890                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 891                         weapon_accuracy[w] = -1;
 892                 return;
 893         }
 894
 895         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 896         {
 897                 if(sf & f)
 898                 {
 899                         b = ReadByte();
 900                         if(b == 0)
 901                                 weapon_accuracy[w] = -1;
 902                         else if(b == 255)
 903                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 904                         else
 905                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 906                 }
 907         }
 908 }
 909
 910 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 911 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 912 void Ent_RadarLink();
 913 void Ent_Init();
 914 void Ent_ScoresInfo();
 915 void(float bIsNewEntity) CSQC_Ent_Update =
 916 {
 917         float t;
 918         float savetime;
 919         t = ReadByte();
 920
 921         // set up the "time" global for received entities to be correct for interpolation purposes
 922         savetime = time;
 923         if(servertime)
 924         {
 925                 time = servertime;
 926         }
 927         else
 928         {
 929                 serverprevtime = time;
 930                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 931                 time = serverprevtime + serverdeltatime;
 932         }
 933
 934 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 935         if(self.enttype)
 936                 if(t != self.enttype)
 937                 {
 938                         print(_("A CSQC entity changed its type!\n"));
 939                         Ent_Remove();
 940                         bIsNewEntity = 1;
 941                 }
 942 #endif
 943         self.enttype = t;
 944         switch(t)
 945         {
 946                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 947                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 948                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 949                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 950                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 951                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 952                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 953                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 954                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 955                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 956                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 957                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 958                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 959                 case ENT_CLIENT_INIT: Ent_Init(); break;
 960                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 961                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 962                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 963                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 964                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 965                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 966                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 967                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 968                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 969                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 970                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 971                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 972                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 973                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 974                 default:
 975                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 976                         break;
 977         }
 978
 979         time = savetime;
 980 };
 981 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 982 // used when an entity changes its type. For an entity that someone interacts
 983 // with others, make sure it can no longer do so.
 984 void Ent_Remove()
 985 {
 986         if(self.entremove)
 987                 self.entremove();
 988
 989         self.enttype = 0;
 990         self.classname = "";
 991         self.draw = menu_sub_null;
 992         self.entremove = menu_sub_null;
 993         // TODO possibly set more stuff to defaults
 994 }
 995 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 996 void CSQC_Ent_Remove()
 997 {
 998         if(self.enttype)
 999                 Ent_Remove();
1000         remove(self);
1001 }
1002
1003 void Gamemode_Init()
1004 {
1005         if not(isdemo())
1006         {
1007                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1008                 calledhooks |= HOOK_START;
1009         }
1010 }
1011 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1012 void CSQC_Parse_StuffCmd(string strMessage)
1013 {
1014         localcmd(strMessage);
1015 }
1016 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1017 void CSQC_Parse_Print(string strMessage)
1018 {
1019         print(ColorTranslateRGB(strMessage));
1020 }
1021
1022 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1023 void CSQC_Parse_CenterPrint(string strMessage)
1024 {
1025         centerprint(strMessage);
1026 }
1027
1028 string notranslate_fogcmd1 = "\nfog ";
1029 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1030 void Fog_Force()
1031 {
1032         // TODO somehow thwart prvm_globalset client ...
1033
1034         if(forcefog != "")
1035                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1036 }
1037
1038 void Gamemode_Init();
1039 void Ent_ScoresInfo()
1040 {
1041         float i;
1042         self.classname = "ent_client_scores_info";
1043         gametype = ReadByte();
1044         for(i = 0; i < MAX_SCORE; ++i)
1045         {
1046                 scores_label[i] = strzone(ReadString());
1047                 scores_flags[i] = ReadByte();
1048         }
1049         for(i = 0; i < MAX_TEAMSCORE; ++i)
1050         {
1051                 teamscores_label[i] = strzone(ReadString());
1052                 teamscores_flags[i] = ReadByte();
1053         }
1054         HUD_InitScores();
1055         Gamemode_Init();
1056 }
1057
1058 void Ent_Init()
1059 {
1060         self.classname = "ent_client_init";
1061
1062         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1063
1064         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1065         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1066         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1067         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1068         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1069         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1070         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1071         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1072         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1073         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1074         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1075         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1076
1077         if(forcefog)
1078                 strunzone(forcefog);
1079         forcefog = strzone(ReadString());
1080
1081         armorblockpercent = ReadByte() / 255.0;
1082
1083         g_weaponswitchdelay = ReadByte() / 255.0;
1084
1085         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1086         g_balance_grenadelauncher_bouncestop = ReadCoord();
1087         g_balance_electro_secondary_bouncefactor = ReadCoord();
1088         g_balance_electro_secondary_bouncestop = ReadCoord();
1089
1090         nex_scope = !ReadByte();
1091         sniperrifle_scope = !ReadByte();
1092
1093         serverflags = ReadByte();
1094
1095         minelayer_maxmines = ReadByte();
1096
1097         g_trueaim_minrange = ReadCoord();
1098
1099         if(!postinit)
1100                 PostInit();
1101 }
1102
1103 void Net_ReadRace()
1104 {
1105         float b;
1106
1107         b = ReadByte();
1108
1109         switch(b)
1110         {
1111                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1112                         race_checkpoint = ReadByte();
1113                         race_time = ReadInt24_t();
1114                         race_previousbesttime = ReadInt24_t();
1115                         if(race_previousbestname)
1116                                 strunzone(race_previousbestname);
1117                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1118
1119                         race_checkpointtime = time;
1120
1121                         if(race_checkpoint == 0 || race_checkpoint == 254)
1122                         {
1123                                 race_penaltyaccumulator = 0;
1124                                 race_laptime = time; // valid
1125                         }
1126
1127                         break;
1128
1129                 case RACE_NET_CHECKPOINT_CLEAR:
1130                         race_laptime = 0;
1131                         race_checkpointtime = 0;
1132                         break;
1133
1134                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1135                         race_laptime = ReadCoord();
1136                         race_checkpointtime = -99999;
1137                         // fall through
1138                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1139                         race_nextcheckpoint = ReadByte();
1140
1141                         race_nextbesttime = ReadInt24_t();
1142                         if(race_nextbestname)
1143                                 strunzone(race_nextbestname);
1144                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1145                         break;
1146
1147                 case RACE_NET_CHECKPOINT_HIT_RACE:
1148                         race_mycheckpoint = ReadByte();
1149                         race_mycheckpointtime = time;
1150                         race_mycheckpointdelta = ReadInt24_t();
1151                         race_mycheckpointlapsdelta = ReadByte();
1152                         if(race_mycheckpointlapsdelta >= 128)
1153                                 race_mycheckpointlapsdelta -= 256;
1154                         if(race_mycheckpointenemy)
1155                                 strunzone(race_mycheckpointenemy);
1156                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1157                         break;
1158
1159                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1160                         race_othercheckpoint = ReadByte();
1161                         race_othercheckpointtime = time;
1162                         race_othercheckpointdelta = ReadInt24_t();
1163                         race_othercheckpointlapsdelta = ReadByte();
1164                         if(race_othercheckpointlapsdelta >= 128)
1165                                 race_othercheckpointlapsdelta -= 256;
1166                         if(race_othercheckpointenemy)
1167                                 strunzone(race_othercheckpointenemy);
1168                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1169                         break;
1170
1171                 case RACE_NET_PENALTY_RACE:
1172                         race_penaltyeventtime = time;
1173                         race_penaltytime = ReadShort();
1174                         //race_penaltyaccumulator += race_penaltytime;
1175                         if(race_penaltyreason)
1176                                 strunzone(race_penaltyreason);
1177                         race_penaltyreason = strzone(ReadString());
1178                         break;
1179
1180                 case RACE_NET_PENALTY_QUALIFYING:
1181                         race_penaltyeventtime = time;
1182                         race_penaltytime = ReadShort();
1183                         race_penaltyaccumulator += race_penaltytime;
1184                         if(race_penaltyreason)
1185                                 strunzone(race_penaltyreason);
1186                         race_penaltyreason = strzone(ReadString());
1187                         break;
1188
1189                 case RACE_NET_SERVER_RECORD:
1190                         race_server_record = ReadInt24_t();
1191                         break;
1192                 case RACE_NET_SPEED_AWARD:
1193                         race_speedaward = ReadInt24_t();
1194                         if(race_speedaward_holder)
1195                                 strunzone(race_speedaward_holder);
1196                         race_speedaward_holder = strzone(ReadString());
1197                         break;
1198                 case RACE_NET_SPEED_AWARD_BEST:
1199                         race_speedaward_alltimebest = ReadInt24_t();
1200                         if(race_speedaward_alltimebest_holder)
1201                                 strunzone(race_speedaward_alltimebest_holder);
1202                         race_speedaward_alltimebest_holder = strzone(ReadString());
1203                         break;
1204                 case RACE_NET_SERVER_RANKINGS:
1205                         float pos, prevpos, del;
1206                         pos = ReadShort();
1207                         prevpos = ReadShort();
1208                         del = ReadShort();
1209
1210                         // move other rankings out of the way
1211                         float i;
1212                         if (prevpos) {
1213                                 for (i=prevpos-1;i>pos-1;--i) {
1214                                         grecordtime[i] = grecordtime[i-1];
1215                                         if(grecordholder[i])
1216                                                 strunzone(grecordholder[i]);
1217                                         grecordholder[i] = strzone(grecordholder[i-1]);
1218                                 }
1219                         } else if (del) { // a record has been deleted by the admin
1220                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1221                                         if (i == RANKINGS_CNT-1) { // clear out last record
1222                                                 grecordtime[i] = 0;
1223                                                 if (grecordholder[i])
1224                                                         strunzone(grecordholder[i]);
1225                                                 grecordholder[i] = string_null;
1226                                         }
1227                                         else {
1228                                                 grecordtime[i] = grecordtime[i+1];
1229                                                 if (grecordholder[i])
1230                                                         strunzone(grecordholder[i]);
1231                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1232                                         }
1233                                 }
1234                         } else { // player has no ranked record yet
1235                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1236                                         grecordtime[i] = grecordtime[i-1];
1237                                         if(grecordholder[i])
1238                                                 strunzone(grecordholder[i]);
1239                                         grecordholder[i] = strzone(grecordholder[i-1]);
1240                                 }
1241                         }
1242
1243                         // store new ranking
1244                         if(grecordholder[pos-1] != "")
1245                                 strunzone(grecordholder[pos-1]);
1246                         grecordholder[pos-1] = strzone(ReadString());
1247                         grecordtime[pos-1] = ReadInt24_t();
1248                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1249                                 race_myrank = pos;
1250                         break;
1251                 case RACE_NET_SERVER_STATUS:
1252                         race_status = ReadShort();
1253                         if(race_status_name)
1254                                 strunzone(race_status_name);
1255                         race_status_name = strzone(ReadString());
1256         }
1257 }
1258
1259 void Net_ReadSpawn()
1260 {
1261         zoomin_effect = 1;
1262         current_viewzoom = 0.6;
1263 }
1264
1265 void Net_TeamNagger()
1266 {
1267         teamnagger = 1;
1268 }
1269
1270 void Net_ReadPingPLReport()
1271 {
1272         float e, pi, pl, ml;
1273         e = ReadByte();
1274         pi = ReadShort();
1275         pl = ReadByte();
1276         ml = ReadByte();
1277         if not(playerslots[e])
1278                 return;
1279         playerslots[e].ping = pi;
1280         playerslots[e].ping_packetloss = pl / 255.0;
1281         playerslots[e].ping_movementloss = ml / 255.0;
1282 }
1283
1284 void Net_VoteDialog(float highlight) {
1285         if(highlight) {
1286                 vote_highlighted = ReadByte();
1287                 return;
1288         }
1289
1290         vote_yescount = ReadByte();
1291         vote_nocount = ReadByte();
1292         vote_needed = ReadByte();
1293         vote_active = 1;
1294 }
1295
1296 void Net_VoteDialogReset() {
1297         vote_active = 0;
1298 }
1299
1300 void Net_Notify() {
1301         float type;
1302         type = ReadByte();
1303
1304         if(type == CSQC_KILLNOTIFY)
1305         {
1306                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1307         }
1308         else if(type == CSQC_CENTERPRINT)
1309         {
1310                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1311         }
1312 }
1313
1314 void Net_WeaponComplain() {
1315         complain_weapon = ReadByte();
1316
1317         if(complain_weapon_name)
1318                 strunzone(complain_weapon_name);
1319         complain_weapon_name = strzone(ReadString());
1320
1321         complain_weapon_type = ReadByte();
1322
1323         complain_weapon_time = time;
1324         weapontime = time; // ping the weapon panel
1325 }
1326
1327 void Net_ShowNames()
1328 {
1329     string thename;
1330     float thehealth, thearmor;
1331
1332     if(shownames_netname)
1333         strunzone(shownames_netname);
1334     thename = strzone(ReadString());
1335     thehealth = ReadByte();
1336     thearmor = ReadByte();
1337
1338     if(autocvar_hud_panel_shownames == 1 && thehealth > 0) // teammates only
1339     {
1340         shownames_netname = thename;
1341         shownames_health = thehealth;
1342         shownames_armor = thearmor;
1343
1344         shownames_time = time + autocvar_hud_panel_shownames_sustain;
1345     }
1346     else if(autocvar_hud_panel_shownames == 2)
1347     {
1348         shownames_netname = thename;
1349         shownames_health = thehealth;
1350         shownames_armor = thearmor;
1351
1352         shownames_time = time + autocvar_hud_panel_shownames_sustain;
1353     }
1354 }
1355
1356 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1357 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1358 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1359 float CSQC_Parse_TempEntity()
1360 {
1361         local float bHandled;
1362                 bHandled  = true;
1363         // Acquire TE ID
1364         local float nTEID;
1365                 nTEID = ReadByte();
1366
1367                 // NOTE: Could just do return instead of break...
1368         switch(nTEID)
1369         {
1370                 case TE_CSQC_TARGET_MUSIC:
1371                         Net_TargetMusic();
1372                         bHandled = true;
1373                         break;
1374                 case TE_CSQC_PICTURE:
1375                         Net_MapVote_Picture();
1376                         bHandled = true;
1377                         break;
1378                 case TE_CSQC_RACE:
1379                         Net_ReadRace();
1380                         bHandled = true;
1381                         break;
1382                 case TE_CSQC_SPAWN:
1383                         Net_ReadSpawn();
1384                         bHandled = true;
1385                         break;
1386                 case TE_CSQC_ZCURVEPARTICLES:
1387                         Net_ReadZCurveParticles();
1388                         bHandled = true;
1389                         break;
1390                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1391                         Net_ReadNexgunBeamParticle();
1392                         bHandled = true;
1393                         break;
1394                 case TE_CSQC_TEAMNAGGER:
1395                         Net_TeamNagger();
1396                         bHandled = true;
1397                         break;
1398                 case TE_CSQC_VOTE:
1399                         Net_VoteDialog(ReadByte());
1400                         bHandled = true;
1401                         break;
1402                 case TE_CSQC_VOTERESET:
1403                         Net_VoteDialogReset();
1404                         bHandled = true;
1405                         break;
1406                 case TE_CSQC_LIGHTNINGARC:
1407                         Net_ReadLightningarc();
1408                         bHandled = true;
1409                         break;
1410                 case TE_CSQC_PINGPLREPORT:
1411                         Net_ReadPingPLReport();
1412                         bHandled = true;
1413                         break;
1414                 case TE_CSQC_ANNOUNCE:
1415                         announce_snd = strzone(ReadString());
1416                         bHandled = true;
1417                         break;
1418                 case TE_CSQC_NOTIFY:
1419                         Net_Notify();
1420                         bHandled = true;
1421                         break;
1422                 case TE_CSQC_WEAPONCOMPLAIN:
1423                         Net_WeaponComplain();
1424                         bHandled = true;
1425                         break;
1426                 case TE_CSQC_SHOWNAMES:
1427             Net_ShowNames();
1428             bHandled = true;
1429             break;
1430                 default:
1431                         // No special logic for this temporary entity; return 0 so the engine can handle it
1432                         bHandled = false;
1433                         break;
1434         }
1435
1436         return bHandled;
1437 }
1438
1439 string getcommandkey(string text, string command)
1440 {
1441         string keys;
1442         float n, j, k, l;
1443
1444         if (!autocvar_hud_showbinds)
1445                 return text;
1446
1447         keys = db_get(binddb, command);
1448         if (!keys)
1449         {
1450                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1451                 for(j = 0; j < n; ++j)
1452                 {
1453                         k = stof(argv(j));
1454                         if(k != -1)
1455                         {
1456                                 if ("" == keys)
1457                                         keys = keynumtostring(k);
1458                                 else
1459                                         keys = strcat(keys, ", ", keynumtostring(k));
1460
1461                                 ++l;
1462                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1463                         }
1464
1465                 }
1466                 db_put(binddb, command, keys);
1467         }
1468
1469         if ("" == keys) {
1470                 if (autocvar_hud_showbinds > 1)
1471                         return sprintf(_("%s (not bound)"), text);
1472                 else
1473                         return text;
1474         }
1475         else if (autocvar_hud_showbinds > 1)
1476                 return sprintf(_("%s (%s)"), text, keys);
1477         else
1478                 return keys;
1479 }