qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: %s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+button3");
  95         registercmd("-button3");
  96         registercmd("+button4");
  97         registercmd("-button4");
  98         registercmd("+showscores");registercmd("-showscores");
  99         registercmd("+showaccuracy");registercmd("-showaccuracy");
 100
 101 #ifndef CAMERATEST
 102         if(isdemo())
 103         {
 104 #endif
 105                 registercmd("+forward");registercmd("-forward");
 106                 registercmd("+back");registercmd("-back");
 107                 registercmd("+moveup");registercmd("-moveup");
 108                 registercmd("+movedown");registercmd("-movedown");
 109                 registercmd("+moveright");registercmd("-moveright");
 110                 registercmd("+moveleft");registercmd("-moveleft");
 111                 registercmd("+roll_right");registercmd("-roll_right");
 112                 registercmd("+roll_left");registercmd("-roll_left");
 113 #ifndef CAMERATEST
 114         }
 115 #endif
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 118
 119         gametype = 0;
 120
 121         // hud_fields uses strunzone on the titles!
 122         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 123                 hud_title[i] = strzone("(null)");
 124
 125         postinit = false;
 126
 127         calledhooks = 0;
 128
 129         teams = Sort_Spawn();
 130         players = Sort_Spawn();
 131
 132         GetTeam(COLOR_SPECTATOR, true); // add specs first
 133
 134         RegisterWeapons();
 135
 136         WaypointSprite_Load();
 137
 138         // precaches
 139         Projectile_Precache();
 140         Hook_Precache();
 141         GibSplash_Precache();
 142         Casings_Precache();
 143         DamageInfo_Precache();
 144         if(autocvar_cl_announcer != cl_announcer_prev) {
 145                 Announcer_Precache();
 146                 if(cl_announcer_prev)
 147                         strunzone(cl_announcer_prev);
 148                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 149         }
 150         Tuba_Precache();
 151
 152         get_mi_min_max_texcoords(1); // try the CLEVER way first
 153         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 154         shortmapname = mi_shortname;
 155
 156         if(precache_pic(minimapname) == "")
 157         {
 158                 // but maybe we have a non-clever minimap
 159                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 160                 if(precache_pic(minimapname) == "")
 161                         minimapname = ""; // FAIL
 162                 else
 163                         get_mi_min_max_texcoords(0); // load new texcoords
 164         }
 165
 166         mi_center = (mi_min + mi_max) * 0.5;
 167         mi_scale = mi_max - mi_min;
 168         minimapname = strzone(minimapname);
 169
 170         WarpZone_Init();
 171         hud_configure_prev = -1;
 172 }
 173
 174 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 175 void CSQC_Shutdown(void)
 176 {
 177 #ifdef USE_FTE
 178 #pragma TARGET id
 179         if(!__engine_check)
 180                 return 0;
 181 #pragma TARGET fte
 182 #endif
 183
 184         WarpZone_Shutdown();
 185
 186         remove(teams);
 187         remove(players);
 188         db_close(binddb);
 189         db_close(tempdb);
 190         if(autocvar_cl_db_saveasdump)
 191                 db_dump(ClientProgsDB, "client.db");
 192         else
 193                 db_save(ClientProgsDB, "client.db");
 194         db_close(ClientProgsDB);
 195
 196         cvar_clientsettemp_restore();
 197
 198         if(camera_active)
 199                 cvar_set("chase_active",ftos(chase_active_backup));
 200
 201         if not(isdemo())
 202         {
 203                 if not(calledhooks & HOOK_START)
 204                         localcmd("\n_cl_hook_gamestart nop\n");
 205                 if not(calledhooks & HOOK_END)
 206                         localcmd("\ncl_hook_gameend\n");
 207         }
 208 }
 209
 210 .float has_team;
 211 float SetTeam(entity o, float Team)
 212 {
 213         entity tm;
 214         if(teamplay)
 215         {
 216                 switch(Team)
 217                 {
 218                         case -1:
 219                         case COLOR_TEAM1:
 220                         case COLOR_TEAM2:
 221                         case COLOR_TEAM3:
 222                         case COLOR_TEAM4:
 223                                 break;
 224                         default:
 225                                 if(GetTeam(Team, false) == NULL)
 226                                 {
 227                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 228                                         Team = COLOR_SPECTATOR;
 229                                 }
 230                                 break;
 231                 }
 232         }
 233         else
 234         {
 235                 switch(Team)
 236                 {
 237                         case -1:
 238                         case 0:
 239                                 break;
 240                         default:
 241                                 if(GetTeam(Team, false) == NULL)
 242                                 {
 243                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 244                                         Team = COLOR_SPECTATOR;
 245                                 }
 246                                 break;
 247                 }
 248         }
 249         if(Team == -1) // leave
 250         {
 251                 if(o.has_team)
 252                 {
 253                         tm = GetTeam(o.team, false);
 254                         tm.team_size -= 1;
 255                         o.has_team = 0;
 256                         return TRUE;
 257                 }
 258         }
 259         else
 260         {
 261                 if not(o.has_team)
 262                 {
 263                         o.team = Team;
 264                         tm = GetTeam(Team, true);
 265                         tm.team_size += 1;
 266                         o.has_team = 1;
 267                         return TRUE;
 268                 }
 269                 else if(Team != o.team)
 270                 {
 271                         tm = GetTeam(o.team, false);
 272                         tm.team_size -= 1;
 273                         o.team = Team;
 274                         tm = GetTeam(Team, true);
 275                         tm.team_size += 1;
 276                         return TRUE;
 277                 }
 278         }
 279         return FALSE;
 280 }
 281
 282 void Playerchecker_Think()
 283 {
 284         float i;
 285         entity e;
 286         for(i = 0; i < maxclients; ++i)
 287         {
 288                 e = playerslots[i];
 289                 if(GetPlayerName(i) == "")
 290                 {
 291                         if(e.sort_prev)
 292                         {
 293                                 // player disconnected
 294                                 SetTeam(e, -1);
 295                                 RemovePlayer(e);
 296                                 e.sort_prev = world;
 297                                 //e.gotscores = 0;
 298                         }
 299                 }
 300                 else
 301                 {
 302                         if not(e.sort_prev)
 303                         {
 304                                 // player connected
 305                                 if not(e)
 306                                         playerslots[i] = e = spawn();
 307                                 e.sv_entnum = i;
 308                                 e.ping = 0;
 309                                 e.ping_packetloss = 0;
 310                                 e.ping_movementloss = 0;
 311                                 //e.gotscores = 0; // we might already have the scores...
 312                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 313                                 RegisterPlayer(e);
 314                                 HUD_UpdatePlayerPos(e);
 315                         }
 316                 }
 317         }
 318         self.nextthink = time + 0.2;
 319 }
 320
 321 void Porto_Init();
 322 void TrueAim_Init();
 323 void PostInit(void)
 324 {
 325         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 326
 327         entity playerchecker;
 328         playerchecker = spawn();
 329         playerchecker.think = Playerchecker_Think;
 330         playerchecker.nextthink = time + 0.2;
 331
 332         Porto_Init();
 333         TrueAim_Init();
 334
 335         postinit = true;
 336 }
 337
 338 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 339 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 340 float button_zoom;
 341 void Cmd_HUD_SetFields(float);
 342 void Cmd_HUD_Help(float);
 343 float CSQC_ConsoleCommand(string strMessage)
 344 {
 345         float argc;
 346         // Tokenize String
 347         //argc = tokenize(strMessage);
 348         argc = tokenize_console(strMessage);
 349
 350         // Acquire Command
 351         local string strCmd;
 352         strCmd = argv(0);
 353
 354         if(strCmd == "hud_configure") { // config hud
 355                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 356                 return true;
 357         } else if(strCmd == "hud_save") { // save hud config
 358                 if(argv(1) == "" || argv(2)) {
 359                         print(_("Usage:\n"));
 360                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 361                 }
 362                 else
 363                         HUD_Panel_ExportCfg(argv(1));
 364                 return true;
 365         } else if(strCmd == "+button4") { // zoom
 366                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 367                 if(ignore_plus_zoom)
 368                 {
 369                         --ignore_plus_zoom;
 370                         return false;
 371                 }
 372                 button_zoom = 1;
 373                 return true;
 374         } else if(strCmd == "-button4") { // zoom
 375                 if(ignore_minus_zoom)
 376                 {
 377                         --ignore_minus_zoom;
 378                         return false;
 379                 }
 380                 button_zoom = 0;
 381                 return true;
 382         } else if(strCmd == "+button3") { // secondary
 383                 button_attack2 = 1;
 384                 return false;
 385         } else if(strCmd == "-button3") { // secondary
 386                 button_attack2 = 0;
 387                 return false;
 388         } else if(strCmd == "+showscores") {
 389                 scoreboard_showscores = true;
 390                 return true;
 391         } else if(strCmd == "-showscores") {
 392                 scoreboard_showscores = false;
 393                 return true;
 394         } else if(strCmd == "+showaccuracy") {
 395                 scoreboard_showaccuracy = true;
 396                 return true;
 397         } else if(strCmd == "-showaccuracy") {
 398                 scoreboard_showaccuracy = false;
 399                 return true;
 400         }
 401
 402         if(camera_active)
 403         if(strCmd == "+forward" || strCmd == "-back") {
 404                 ++camera_direction_x;
 405                 return true;
 406         } else if(strCmd == "-forward" || strCmd == "+back") {
 407                 --camera_direction_x;
 408                 return true;
 409         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 410                 --camera_direction_y;
 411                 return true;
 412         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 413                 ++camera_direction_y;
 414                 return true;
 415         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 416                 ++camera_direction_z;
 417                 return true;
 418         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 419                 --camera_direction_z;
 420                 return true;
 421         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 422                 ++camera_roll;
 423                 return true;
 424         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 425                 --camera_roll;
 426                 return true;
 427         }
 428
 429         return false;
 430 }
 431
 432 .vector view_ofs;
 433 entity debug_shotorg;
 434 void ShotOrg_Draw()
 435 {
 436         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 437         self.angles = view_angles;
 438         self.angles_x = -self.angles_x;
 439         if not(self.cnt)
 440                 self.drawmask = MASK_NORMAL;
 441         else
 442                 self.drawmask = 0;
 443 }
 444 void ShotOrg_Draw2D()
 445 {
 446         vector coord2d_topleft, coord2d_topright, coord2d;
 447         string s;
 448         vector fs;
 449
 450         s = vtos(self.view_ofs);
 451         s = substring(s, 1, strlen(s) - 2);
 452         if(tokenize_console(s) == 3)
 453                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 454
 455         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 456         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 457
 458         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 459
 460         coord2d = coord2d_topleft;
 461         if(fs_x < 8)
 462         {
 463                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 464                 fs = '8 8 0';
 465         }
 466         coord2d_y -= fs_y;
 467         coord2d_z = 0;
 468         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 469 }
 470
 471 void ShotOrg_Spawn()
 472 {
 473         debug_shotorg = spawn();
 474         debug_shotorg.draw = ShotOrg_Draw;
 475         debug_shotorg.draw2d = ShotOrg_Draw2D;
 476         debug_shotorg.renderflags = RF_VIEWMODEL;
 477         debug_shotorg.effects = EF_FULLBRIGHT;
 478         precache_model("models/shotorg_adjuster.md3");
 479         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 480         debug_shotorg.scale = 2;
 481         debug_shotorg.view_ofs = '25 8 -8';
 482 }
 483
 484 void DrawDebugModel()
 485 {
 486         if(time - floor(time) > 0.5)
 487         {
 488                 PolyDrawModel(self);
 489                 self.drawmask = 0;
 490         }
 491         else
 492         {
 493                 self.renderflags = 0;
 494                 self.drawmask = MASK_NORMAL;
 495         }
 496 }
 497
 498 void GameCommand(string msg)
 499 {
 500         string s;
 501         float argc;
 502         entity e;
 503         argc = tokenize_console(msg);
 504
 505         if(argv(0) == "help" || argc == 0)
 506         {
 507                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 508                 print(_("  settemp cvar value\n"));
 509                 print(_("  scoreboard_columns_set ...\n"));
 510                 print(_("  scoreboard_columns_help\n"));
 511                 GameCommand_Generic("help");
 512                 return;
 513         }
 514
 515         if(GameCommand_Generic(msg))
 516                 return;
 517
 518         string cmd;
 519         cmd = argv(0);
 520         if(cmd == "mv_download") {
 521                 Cmd_MapVote_MapDownload(argc);
 522         }
 523         else if(cmd == "settemp") {
 524                 cvar_clientsettemp(argv(1), argv(2));
 525         }
 526         else if(cmd == "scoreboard_columns_set") {
 527                 Cmd_HUD_SetFields(argc);
 528         }
 529         else if(cmd == "scoreboard_columns_help") {
 530                 Cmd_HUD_Help(argc);
 531         }
 532 #ifdef BLURTEST
 533         else if(cmd == "blurtest") {
 534                 blurtest_time0 = time;
 535                 blurtest_time1 = time + stof(argv(1));
 536                 blurtest_radius = stof(argv(2));
 537                 blurtest_power = stof(argv(3));
 538         }
 539 #endif
 540         else if(cmd == "shotorg_move") {
 541                 if(!debug_shotorg)
 542                         ShotOrg_Spawn();
 543                 else
 544                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 545                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 546         }
 547         else if(cmd == "shotorg_movez") {
 548                 if(!debug_shotorg)
 549                         ShotOrg_Spawn();
 550                 else
 551                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 552                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 553         }
 554         else if(cmd == "shotorg_set") {
 555                 if(!debug_shotorg)
 556                         ShotOrg_Spawn();
 557                 else
 558                         debug_shotorg.view_ofs = stov(argv(1));
 559                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 560         }
 561         else if(cmd == "shotorg_setz") {
 562                 if(!debug_shotorg)
 563                         ShotOrg_Spawn();
 564                 else
 565                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 566                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 567         }
 568         else if(cmd == "shotorg_toggle_hide") {
 569                 if(debug_shotorg)
 570                 {
 571                         debug_shotorg.cnt = !debug_shotorg.cnt;
 572                 }
 573         }
 574         else if(cmd == "shotorg_end") {
 575                 if(debug_shotorg)
 576                 {
 577                         print(vtos(debug_shotorg.view_ofs), "\n");
 578                         remove(debug_shotorg);
 579                         debug_shotorg = world;
 580                 }
 581                 localcmd("sv_cmd debug_shotorg\n");
 582         }
 583         else if(cmd == "sendcvar") {
 584                 // W_FixWeaponOrder will trash argv, so save what we need.
 585                 string thiscvar;
 586                 thiscvar = strzone(argv(1));
 587                 s = cvar_string(thiscvar);
 588                 if(thiscvar == "cl_weaponpriority")
 589                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 590                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 591                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 592                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 593                 strunzone(thiscvar);
 594         }
 595         else if(cmd == "spawn") {
 596                 s = argv(1);
 597                 e = spawn();
 598                 precache_model(s);
 599                 setmodel(e, s);
 600                 setorigin(e, view_origin);
 601                 e.angles = view_angles;
 602                 e.draw = DrawDebugModel;
 603                 e.classname = "debugmodel";
 604         }
 605     else if(cmd == "vyes")
 606     {
 607         if(uid2name_dialog)
 608         {
 609             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 610             vote_prev = 0;
 611             cvar_set("cl_allow_uid2name", "1");
 612             vote_change = -9999;
 613         }
 614         else
 615         {
 616             localcmd("cmd vote yes\n");
 617         }
 618     }
 619     else if(cmd == "vno")
 620     {
 621         if(uid2name_dialog)
 622         {
 623             vote_active = 0;
 624             vote_prev = 0;
 625             cvar_set("cl_allow_uid2name", "0");
 626             vote_change = -9999;
 627         }
 628         else
 629         {
 630             localcmd("cmd vote no\n");
 631         }
 632     }
 633
 634         else
 635         {
 636                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 637         }
 638
 639         return;
 640 }
 641
 642 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 643 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 644 // All keys are in ascii.
 645 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 646 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 647 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 648 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 649 {
 650         local float bSkipKey;
 651         bSkipKey = false;
 652
 653         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 654                 return true;
 655
 656         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 657                 return true;
 658
 659         if(menu_visible)
 660                 if(menu_action(bInputType, nPrimary, nSecondary))
 661                         return TRUE;
 662
 663         return bSkipKey;
 664 }
 665
 666 // END REQUIRED CSQC FUNCTIONS
 667 // --------------------------------------------------------------------------
 668
 669 // --------------------------------------------------------------------------
 670 // BEGIN OPTIONAL CSQC FUNCTIONS
 671 void Ent_ReadEntCS()
 672 {
 673         InterpolateOrigin_Undo();
 674
 675         self.classname = "entcs_receiver";
 676         self.sv_entnum = ReadByte() - 1;
 677         self.origin_x = ReadShort();
 678         self.origin_y = ReadShort();
 679         self.origin_z = ReadShort();
 680         self.angles_y = ReadByte() * 360.0 / 256;
 681         self.origin_z = self.angles_x = self.angles_z = 0;
 682
 683         InterpolateOrigin_Note();
 684 }
 685
 686 void Ent_Remove();
 687
 688 void Ent_RemovePlayerScore()
 689 {
 690         float i;
 691
 692         if(self.owner)
 693         {
 694                 SetTeam(self.owner, -1);
 695                 self.owner.gotscores = 0;
 696                 for(i = 0; i < MAX_SCORE; ++i)
 697                         self.owner.(scores[i]) = 0; // clear all scores
 698         }
 699 }
 700
 701 void Ent_ReadPlayerScore()
 702 {
 703         float i, n;
 704         float isNew;
 705         entity o;
 706
 707         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 708         // (no I've never heard of M-x replace-string, sed, or anything like that)
 709         isNew = !self.owner; // workaround for DP bug
 710         n = ReadByte()-1;
 711
 712 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 713         if(!isNew && n != self.sv_entnum)
 714         {
 715                 print(_("A CSQC entity changed its owner!\n"));
 716                 isNew = true;
 717                 Ent_Remove();
 718                 self.enttype = ENT_CLIENT_SCORES;
 719         }
 720 #endif
 721
 722         self.sv_entnum = n;
 723
 724         if not(playerslots[self.sv_entnum])
 725                 playerslots[self.sv_entnum] = spawn();
 726         o = self.owner = playerslots[self.sv_entnum];
 727         o.sv_entnum = self.sv_entnum;
 728         o.gotscores = 1;
 729
 730         //if not(o.sort_prev)
 731         //      RegisterPlayer(o);
 732         //playerchecker will do this for us later, if it has not already done so
 733
 734         float sf, lf;
 735 #if MAX_SCORE <= 8
 736         sf = ReadByte();
 737         lf = ReadByte();
 738 #else
 739         sf = ReadShort();
 740         lf = ReadShort();
 741 #endif
 742         float p;
 743         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 744                 if(sf & p)
 745                 {
 746                         if(lf & p)
 747                                 o.(scores[i]) = ReadInt24_t();
 748                         else
 749                                 o.(scores[i]) = ReadChar();
 750                 }
 751
 752         if(o.sort_prev)
 753                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 754
 755         self.entremove = Ent_RemovePlayerScore;
 756 }
 757
 758 void Ent_ReadTeamScore()
 759 {
 760         float i;
 761         entity o;
 762
 763         self.team = ReadByte();
 764         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 765
 766         float sf, lf;
 767 #if MAX_TEAMSCORE <= 8
 768         sf = ReadByte();
 769         lf = ReadByte();
 770 #else
 771         sf = ReadShort();
 772         lf = ReadShort();
 773 #endif
 774         float p;
 775         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 776                 if(sf & p)
 777                 {
 778                         if(lf & p)
 779                                 o.(teamscores[i]) = ReadInt24_t();
 780                         else
 781                                 o.(teamscores[i]) = ReadChar();
 782                 }
 783
 784         HUD_UpdateTeamPos(o);
 785 }
 786
 787 void Net_Reset()
 788 {
 789 }
 790
 791 void Ent_ClientData()
 792 {
 793         float f;
 794         float newspectatee_status;
 795
 796         f = ReadByte();
 797
 798         scoreboard_showscores_force = (f & 1);
 799
 800         if(f & 2)
 801         {
 802                 newspectatee_status = ReadByte();
 803                 if(newspectatee_status == player_localentnum)
 804                         newspectatee_status = -1; // observing
 805         }
 806         else
 807                 newspectatee_status = 0;
 808
 809         spectatorbutton_zoom = (f & 4);
 810
 811         if(f & 8)
 812         {
 813                 angles_held_status = 1;
 814                 angles_held_x = ReadAngle();
 815                 angles_held_y = ReadAngle();
 816                 angles_held_z = 0;
 817         }
 818         else
 819                 angles_held_status = 0;
 820
 821         if(newspectatee_status != spectatee_status)
 822         {
 823                 float i;
 824
 825                 // clear race stuff
 826                 race_laptime = 0;
 827                 race_checkpointtime = 0;
 828         }
 829         spectatee_status = newspectatee_status;
 830 }
 831
 832 void Ent_Nagger()
 833 {
 834         float nags, i, j, b, f;
 835
 836         nags = ReadByte();
 837
 838         if(nags & 128)
 839         {
 840                 if(vote_called_vote)
 841                         strunzone(vote_called_vote);
 842                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 843         }
 844
 845         if(nags & 1)
 846         {
 847                 for(j = 0; j < maxclients; ++j)
 848                         if(playerslots[j])
 849                                 playerslots[j].ready = 1;
 850                 for(i = 1; i <= maxclients; i += 8)
 851                 {
 852                         f = ReadByte();
 853                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 854                                 if not(f & b)
 855                                         if(playerslots[j])
 856                                                 playerslots[j].ready = 0;
 857                 }
 858         }
 859
 860         ready_waiting = (nags & 1);
 861         ready_waiting_for_me = (nags & 2);
 862         vote_waiting = (nags & 4);
 863         vote_waiting_for_me = (nags & 8);
 864         warmup_stage = (nags & 16);
 865 }
 866
 867 void Ent_RandomSeed()
 868 {
 869         float s;
 870         prandom_debug();
 871         s = ReadShort();
 872         psrandom(s);
 873 }
 874
 875 void Ent_ReadAccuracy(void)
 876 {
 877         float sf, f, w, b;
 878         sf = ReadInt24_t();
 879         if(sf == 0)
 880         {
 881                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 882                         weapon_accuracy[w] = -1;
 883                 return;
 884         }
 885
 886         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 887         {
 888                 if(sf & f)
 889                 {
 890                         b = ReadByte();
 891                         if(b == 0)
 892                                 weapon_accuracy[w] = -1;
 893                         else if(b == 255)
 894                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 895                         else
 896                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 897                 }
 898         }
 899 }
 900
 901 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 902 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 903 void Ent_RadarLink();
 904 void Ent_Init();
 905 void Ent_ScoresInfo();
 906 void(float bIsNewEntity) CSQC_Ent_Update =
 907 {
 908         float t;
 909         float savetime;
 910         t = ReadByte();
 911
 912         // set up the "time" global for received entities to be correct for interpolation purposes
 913         savetime = time;
 914         if(servertime)
 915         {
 916                 time = servertime;
 917         }
 918         else
 919         {
 920                 serverprevtime = time;
 921                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 922                 time = serverprevtime + serverdeltatime;
 923         }
 924
 925 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 926         if(self.enttype)
 927                 if(t != self.enttype)
 928                 {
 929                         print(_("A CSQC entity changed its type!\n"));
 930                         Ent_Remove();
 931                         bIsNewEntity = 1;
 932                 }
 933 #endif
 934         self.enttype = t;
 935         switch(t)
 936         {
 937                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 938                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 939                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 940                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 941                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 942                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 943                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 944                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 945                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 946                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 947                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 948                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 949                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 950                 case ENT_CLIENT_INIT: Ent_Init(); break;
 951                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 952                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 953                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 954                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 955                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 956                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 957                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 958                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 959                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 960                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 961                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 962                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 963                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 964                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 965                 default:
 966                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 967                         break;
 968         }
 969
 970         time = savetime;
 971 };
 972 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 973 // used when an entity changes its type. For an entity that someone interacts
 974 // with others, make sure it can no longer do so.
 975 void Ent_Remove()
 976 {
 977         if(self.entremove)
 978                 self.entremove();
 979
 980         self.enttype = 0;
 981         self.classname = "";
 982         self.draw = menu_sub_null;
 983         self.entremove = menu_sub_null;
 984         // TODO possibly set more stuff to defaults
 985 }
 986 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 987 void CSQC_Ent_Remove()
 988 {
 989         if(self.enttype)
 990                 Ent_Remove();
 991         remove(self);
 992 }
 993
 994 void Gamemode_Init()
 995 {
 996         if(gametype == GAME_ONSLAUGHT) {
 997                 print(strcat("Using ", minimapname, " as minimap.\n"));
 998                 precache_pic("gfx/ons-cp-neutral.tga");
 999                 precache_pic("gfx/ons-cp-red.tga");
1000                 precache_pic("gfx/ons-cp-blue.tga");
1001                 precache_pic("gfx/ons-frame.tga");
1002                 precache_pic("gfx/ons-frame-team.tga");
1003         }
1004
1005         if not(isdemo())
1006         {
1007                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1008                 calledhooks |= HOOK_START;
1009         }
1010 }
1011 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1012 void CSQC_Parse_StuffCmd(string strMessage)
1013 {
1014         localcmd(strMessage);
1015 }
1016 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1017 void CSQC_Parse_Print(string strMessage)
1018 {
1019         print(ColorTranslateRGB(strMessage));
1020 }
1021
1022 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1023 void CSQC_Parse_CenterPrint(string strMessage)
1024 {
1025         centerprint(strMessage);
1026 }
1027
1028 string notranslate_fogcmd1 = "\nfog ";
1029 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1030 void Fog_Force()
1031 {
1032         // TODO somehow thwart prvm_globalset client ...
1033
1034         if(forcefog != "")
1035                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1036 }
1037
1038 void Gamemode_Init();
1039 void Ent_ScoresInfo()
1040 {
1041         float i;
1042         self.classname = "ent_client_scores_info";
1043         gametype = ReadByte();
1044         for(i = 0; i < MAX_SCORE; ++i)
1045         {
1046                 scores_label[i] = strzone(ReadString());
1047                 scores_flags[i] = ReadByte();
1048         }
1049         for(i = 0; i < MAX_TEAMSCORE; ++i)
1050         {
1051                 teamscores_label[i] = strzone(ReadString());
1052                 teamscores_flags[i] = ReadByte();
1053         }
1054         HUD_InitScores();
1055         Gamemode_Init();
1056 }
1057
1058 void Ent_Init()
1059 {
1060         self.classname = "ent_client_init";
1061
1062         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1063
1064         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1065         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1066         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1067         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1068         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1069         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1070         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1071         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1072         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1073         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1074         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1075         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1076
1077         if(forcefog)
1078                 strunzone(forcefog);
1079         forcefog = strzone(ReadString());
1080
1081         armorblockpercent = ReadByte() / 255.0;
1082
1083         g_weaponswitchdelay = ReadByte() / 255.0;
1084
1085         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1086         g_balance_grenadelauncher_bouncestop = ReadCoord();
1087         g_balance_electro_secondary_bouncefactor = ReadCoord();
1088         g_balance_electro_secondary_bouncestop = ReadCoord();
1089
1090         nex_scope = !ReadByte();
1091         sniperrifle_scope = !ReadByte();
1092
1093         serverflags = ReadByte();
1094
1095         g_trueaim_minrange = ReadCoord();
1096
1097         if(!postinit)
1098                 PostInit();
1099 }
1100
1101 void Net_ReadRace()
1102 {
1103         float b;
1104
1105         b = ReadByte();
1106
1107         switch(b)
1108         {
1109                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1110                         race_checkpoint = ReadByte();
1111                         race_time = ReadInt24_t();
1112                         race_previousbesttime = ReadInt24_t();
1113                         if(race_previousbestname)
1114                                 strunzone(race_previousbestname);
1115                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1116
1117                         race_checkpointtime = time;
1118
1119                         if(race_checkpoint == 0 || race_checkpoint == 254)
1120                         {
1121                                 race_penaltyaccumulator = 0;
1122                                 race_laptime = time; // valid
1123                         }
1124
1125                         break;
1126
1127                 case RACE_NET_CHECKPOINT_CLEAR:
1128                         race_laptime = 0;
1129                         race_checkpointtime = 0;
1130                         break;
1131
1132                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1133                         race_laptime = ReadCoord();
1134                         race_checkpointtime = -99999;
1135                         // fall through
1136                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1137                         race_nextcheckpoint = ReadByte();
1138
1139                         race_nextbesttime = ReadInt24_t();
1140                         if(race_nextbestname)
1141                                 strunzone(race_nextbestname);
1142                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1143                         break;
1144
1145                 case RACE_NET_CHECKPOINT_HIT_RACE:
1146                         race_mycheckpoint = ReadByte();
1147                         race_mycheckpointtime = time;
1148                         race_mycheckpointdelta = ReadInt24_t();
1149                         race_mycheckpointlapsdelta = ReadByte();
1150                         if(race_mycheckpointlapsdelta >= 128)
1151                                 race_mycheckpointlapsdelta -= 256;
1152                         if(race_mycheckpointenemy)
1153                                 strunzone(race_mycheckpointenemy);
1154                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1155                         break;
1156
1157                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1158                         race_othercheckpoint = ReadByte();
1159                         race_othercheckpointtime = time;
1160                         race_othercheckpointdelta = ReadInt24_t();
1161                         race_othercheckpointlapsdelta = ReadByte();
1162                         if(race_othercheckpointlapsdelta >= 128)
1163                                 race_othercheckpointlapsdelta -= 256;
1164                         if(race_othercheckpointenemy)
1165                                 strunzone(race_othercheckpointenemy);
1166                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1167                         break;
1168
1169                 case RACE_NET_PENALTY_RACE:
1170                         race_penaltyeventtime = time;
1171                         race_penaltytime = ReadShort();
1172                         //race_penaltyaccumulator += race_penaltytime;
1173                         if(race_penaltyreason)
1174                                 strunzone(race_penaltyreason);
1175                         race_penaltyreason = strzone(ReadString());
1176                         break;
1177
1178                 case RACE_NET_PENALTY_QUALIFYING:
1179                         race_penaltyeventtime = time;
1180                         race_penaltytime = ReadShort();
1181                         race_penaltyaccumulator += race_penaltytime;
1182                         if(race_penaltyreason)
1183                                 strunzone(race_penaltyreason);
1184                         race_penaltyreason = strzone(ReadString());
1185                         break;
1186
1187                 case RACE_NET_SERVER_RECORD:
1188                         race_server_record = ReadInt24_t();
1189                         break;
1190                 case RACE_NET_SPEED_AWARD:
1191                         race_speedaward = ReadInt24_t();
1192                         if(race_speedaward_holder)
1193                                 strunzone(race_speedaward_holder);
1194                         race_speedaward_holder = strzone(ReadString());
1195                         break;
1196                 case RACE_NET_SPEED_AWARD_BEST:
1197                         race_speedaward_alltimebest = ReadInt24_t();
1198                         if(race_speedaward_alltimebest_holder)
1199                                 strunzone(race_speedaward_alltimebest_holder);
1200                         race_speedaward_alltimebest_holder = strzone(ReadString());
1201                         break;
1202                 case RACE_NET_SERVER_RANKINGS:
1203                         float pos, prevpos, del;
1204                         pos = ReadShort();
1205                         prevpos = ReadShort();
1206                         del = ReadShort();
1207
1208                         // move other rankings out of the way
1209                         float i;
1210                         if (prevpos) {
1211                                 for (i=prevpos-1;i>pos-1;--i) {
1212                                         grecordtime[i] = grecordtime[i-1];
1213                                         if(grecordholder[i])
1214                                                 strunzone(grecordholder[i]);
1215                                         grecordholder[i] = strzone(grecordholder[i-1]);
1216                                 }
1217                         } else if (del) { // a record has been deleted by the admin
1218                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1219                                         if (i == RANKINGS_CNT-1) { // clear out last record
1220                                                 grecordtime[i] = 0;
1221                                                 if (grecordholder[i])
1222                                                         strunzone(grecordholder[i]);
1223                                                 grecordholder[i] = string_null;
1224                                         }
1225                                         else {
1226                                                 grecordtime[i] = grecordtime[i+1];
1227                                                 if (grecordholder[i])
1228                                                         strunzone(grecordholder[i]);
1229                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1230                                         }
1231                                 }
1232                         } else { // player has no ranked record yet
1233                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1234                                         grecordtime[i] = grecordtime[i-1];
1235                                         if(grecordholder[i])
1236                                                 strunzone(grecordholder[i]);
1237                                         grecordholder[i] = strzone(grecordholder[i-1]);
1238                                 }
1239                         }
1240
1241                         // store new ranking
1242                         if(grecordholder[pos-1] != "")
1243                                 strunzone(grecordholder[pos-1]);
1244                         grecordholder[pos-1] = strzone(ReadString());
1245                         grecordtime[pos-1] = ReadInt24_t();
1246                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1247                                 race_myrank = pos;
1248                         break;
1249                 case RACE_NET_SERVER_STATUS:
1250                         race_status = ReadShort();
1251                         if(race_status_name)
1252                                 strunzone(race_status_name);
1253                         race_status_name = strzone(ReadString());
1254         }
1255 }
1256
1257 void Net_ReadSpawn()
1258 {
1259         zoomin_effect = 1;
1260         current_viewzoom = 0.6;
1261 }
1262
1263 void Net_TeamNagger()
1264 {
1265         teamnagger = 1;
1266 }
1267
1268 void Net_ReadPingPLReport()
1269 {
1270         float e, pi, pl, ml;
1271         e = ReadByte();
1272         pi = ReadShort();
1273         pl = ReadByte();
1274         ml = ReadByte();
1275         if not(playerslots[e])
1276                 return;
1277         playerslots[e].ping = pi;
1278         playerslots[e].ping_packetloss = pl / 255.0;
1279         playerslots[e].ping_movementloss = ml / 255.0;
1280 }
1281
1282 void Net_VoteDialog(float highlight) {
1283         if(highlight) {
1284                 vote_highlighted = ReadByte();
1285                 return;
1286         }
1287
1288         vote_yescount = ReadByte();
1289         vote_nocount = ReadByte();
1290         vote_needed = ReadByte();
1291         vote_active = 1;
1292 }
1293
1294 void Net_VoteDialogReset() {
1295         vote_active = 0;
1296 }
1297
1298 void Net_Notify() {
1299         float type;
1300         type = ReadByte();
1301
1302         if(type == CSQC_KILLNOTIFY)
1303         {
1304                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1305         }
1306         else if(type == CSQC_CENTERPRINT)
1307         {
1308                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1309         }
1310 }
1311
1312 void Net_WeaponComplain() {
1313         complain_weapon = ReadByte();
1314
1315         if(complain_weapon_name)
1316                 strunzone(complain_weapon_name);
1317         complain_weapon_name = strzone(ReadString());
1318
1319         complain_weapon_type = ReadByte();
1320
1321         complain_weapon_time = time;
1322         weapontime = time; // ping the weapon panel
1323 }
1324
1325 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1326 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1327 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1328 float CSQC_Parse_TempEntity()
1329 {
1330         local float bHandled;
1331                 bHandled  = true;
1332         // Acquire TE ID
1333         local float nTEID;
1334                 nTEID = ReadByte();
1335
1336                 // NOTE: Could just do return instead of break...
1337         switch(nTEID)
1338         {
1339                 case TE_CSQC_TARGET_MUSIC:
1340                         Net_TargetMusic();
1341                         bHandled = true;
1342                         break;
1343                 case TE_CSQC_PICTURE:
1344                         Net_MapVote_Picture();
1345                         bHandled = true;
1346                         break;
1347                 case TE_CSQC_RACE:
1348                         Net_ReadRace();
1349                         bHandled = true;
1350                         break;
1351                 case TE_CSQC_SPAWN:
1352                         Net_ReadSpawn();
1353                         bHandled = true;
1354                         break;
1355                 case TE_CSQC_ZCURVEPARTICLES:
1356                         Net_ReadZCurveParticles();
1357                         bHandled = true;
1358                         break;
1359                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1360                         Net_ReadNexgunBeamParticle();
1361                         bHandled = true;
1362                         break;
1363                 case TE_CSQC_TEAMNAGGER:
1364                         Net_TeamNagger();
1365                         bHandled = true;
1366                         break;
1367                 case TE_CSQC_VOTE:
1368                         Net_VoteDialog(ReadByte());
1369                         bHandled = true;
1370                         break;
1371                 case TE_CSQC_VOTERESET:
1372                         Net_VoteDialogReset();
1373                         bHandled = true;
1374                         break;
1375                 case TE_CSQC_LIGHTNINGARC:
1376                         Net_ReadLightningarc();
1377                         bHandled = true;
1378                         break;
1379                 case TE_CSQC_PINGPLREPORT:
1380                         Net_ReadPingPLReport();
1381                         bHandled = true;
1382                         break;
1383                 case TE_CSQC_ANNOUNCE:
1384                         announce_snd = strzone(ReadString());
1385                         bHandled = true;
1386                         break;
1387                 case TE_CSQC_NOTIFY:
1388                         Net_Notify();
1389                         bHandled = true;
1390                         break;
1391                 case TE_CSQC_WEAPONCOMPLAIN:
1392                         Net_WeaponComplain();
1393                         bHandled = true;
1394                         break;
1395                 default:
1396                         // No special logic for this temporary entity; return 0 so the engine can handle it
1397                         bHandled = false;
1398                         break;
1399         }
1400
1401         return bHandled;
1402 }
1403
1404 string getcommandkey(string text, string command)
1405 {
1406         string keys;
1407         float n, j, k, l;
1408
1409         if (!hud_showbinds)
1410                 return text;
1411
1412         keys = db_get(binddb, command);
1413         if (!keys)
1414         {
1415                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1416                 for(j = 0; j < n; ++j)
1417                 {
1418                         k = stof(argv(j));
1419                         if(k != -1)
1420                         {
1421                                 if ("" == keys)
1422                                         keys = keynumtostring(k);
1423                                 else
1424                                         keys = strcat(keys, ", ", keynumtostring(k));
1425
1426                                 ++l;
1427                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1428                         }
1429
1430                 }
1431                 db_put(binddb, command, keys);
1432         }
1433
1434         if ("" == keys) {
1435                 if (hud_showbinds > 1)
1436                         return sprintf(_("%s (not bound)"), text);
1437                 else
1438                         return text;
1439         }
1440         else if (hud_showbinds > 1)
1441                 return sprintf(_("%s (%s)"), text, keys);
1442         else
1443                 return keys;
1444 }