qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+button3");
  95         registercmd("-button3");
  96         registercmd("+button4");
  97         registercmd("-button4");
  98         registercmd("+showscores");registercmd("-showscores");
  99         registercmd("+showaccuracy");registercmd("-showaccuracy");
 100
 101 #ifndef CAMERATEST
 102         if(isdemo())
 103         {
 104 #endif
 105                 registercmd("+forward");registercmd("-forward");
 106                 registercmd("+back");registercmd("-back");
 107                 registercmd("+moveup");registercmd("-moveup");
 108                 registercmd("+movedown");registercmd("-movedown");
 109                 registercmd("+moveright");registercmd("-moveright");
 110                 registercmd("+moveleft");registercmd("-moveleft");
 111                 registercmd("+roll_right");registercmd("-roll_right");
 112                 registercmd("+roll_left");registercmd("-roll_left");
 113 #ifndef CAMERATEST
 114         }
 115 #endif
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 118
 119         gametype = 0;
 120
 121         // hud_fields uses strunzone on the titles!
 122         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 123                 hud_title[i] = strzone("(null)");
 124
 125         postinit = false;
 126
 127         calledhooks = 0;
 128
 129         teams = Sort_Spawn();
 130         players = Sort_Spawn();
 131
 132         GetTeam(COLOR_SPECTATOR, true); // add specs first
 133
 134         RegisterWeapons();
 135
 136         WaypointSprite_Load();
 137
 138         // precaches
 139         precache_sound("misc/hit.wav");
 140         precache_sound("misc/typehit.wav");
 141         Projectile_Precache();
 142         Hook_Precache();
 143         GibSplash_Precache();
 144         Casings_Precache();
 145         DamageInfo_Precache();
 146         if(autocvar_cl_announcer != cl_announcer_prev) {
 147                 Announcer_Precache();
 148                 if(cl_announcer_prev)
 149                         strunzone(cl_announcer_prev);
 150                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 151         }
 152         Tuba_Precache();
 153
 154         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 155         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 156
 157         get_mi_min_max_texcoords(1); // try the CLEVER way first
 158         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 159         shortmapname = mi_shortname;
 160
 161         if(precache_pic(minimapname) == "")
 162         {
 163                 // but maybe we have a non-clever minimap
 164                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 165                 if(precache_pic(minimapname) == "")
 166                         minimapname = ""; // FAIL
 167                 else
 168                         get_mi_min_max_texcoords(0); // load new texcoords
 169         }
 170
 171         mi_center = (mi_min + mi_max) * 0.5;
 172         mi_scale = mi_max - mi_min;
 173         minimapname = strzone(minimapname);
 174
 175         WarpZone_Init();
 176         hud_configure_prev = -1;
 177 }
 178
 179 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 180 void CSQC_Shutdown(void)
 181 {
 182 #ifdef USE_FTE
 183 #pragma TARGET id
 184         if(!__engine_check)
 185                 return 0;
 186 #pragma TARGET fte
 187 #endif
 188
 189         WarpZone_Shutdown();
 190
 191         remove(teams);
 192         remove(players);
 193         db_close(binddb);
 194         db_close(tempdb);
 195         if(autocvar_cl_db_saveasdump)
 196                 db_dump(ClientProgsDB, "client.db");
 197         else
 198                 db_save(ClientProgsDB, "client.db");
 199         db_close(ClientProgsDB);
 200
 201         cvar_clientsettemp_restore();
 202
 203         if(camera_active)
 204                 cvar_set("chase_active",ftos(chase_active_backup));
 205
 206         // unset the event chasecam's chase_active
 207         if(autocvar_chase_active < 0)
 208                 cvar_set("chase_active", "0");
 209
 210         if not(isdemo())
 211         {
 212                 if not(calledhooks & HOOK_START)
 213                         localcmd("\n_cl_hook_gamestart nop\n");
 214                 if not(calledhooks & HOOK_END)
 215                         localcmd("\ncl_hook_gameend\n");
 216         }
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, float Team)
 221 {
 222         entity tm;
 223         if(teamplay)
 224         {
 225                 switch(Team)
 226                 {
 227                         case -1:
 228                         case COLOR_TEAM1:
 229                         case COLOR_TEAM2:
 230                         case COLOR_TEAM3:
 231                         case COLOR_TEAM4:
 232                                 break;
 233                         default:
 234                                 if(GetTeam(Team, false) == NULL)
 235                                 {
 236                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 237                                         Team = COLOR_SPECTATOR;
 238                                 }
 239                                 break;
 240                 }
 241         }
 242         else
 243         {
 244                 switch(Team)
 245                 {
 246                         case -1:
 247                         case 0:
 248                                 break;
 249                         default:
 250                                 if(GetTeam(Team, false) == NULL)
 251                                 {
 252                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 253                                         Team = COLOR_SPECTATOR;
 254                                 }
 255                                 break;
 256                 }
 257         }
 258         if(Team == -1) // leave
 259         {
 260                 if(o.has_team)
 261                 {
 262                         tm = GetTeam(o.team, false);
 263                         tm.team_size -= 1;
 264                         o.has_team = 0;
 265                         return TRUE;
 266                 }
 267         }
 268         else
 269         {
 270                 if not(o.has_team)
 271                 {
 272                         o.team = Team;
 273                         tm = GetTeam(Team, true);
 274                         tm.team_size += 1;
 275                         o.has_team = 1;
 276                         return TRUE;
 277                 }
 278                 else if(Team != o.team)
 279                 {
 280                         tm = GetTeam(o.team, false);
 281                         tm.team_size -= 1;
 282                         o.team = Team;
 283                         tm = GetTeam(Team, true);
 284                         tm.team_size += 1;
 285                         return TRUE;
 286                 }
 287         }
 288         return FALSE;
 289 }
 290
 291 void Playerchecker_Think()
 292 {
 293         float i;
 294         entity e;
 295         for(i = 0; i < maxclients; ++i)
 296         {
 297                 e = playerslots[i];
 298                 if(GetPlayerName(i) == "")
 299                 {
 300                         if(e.sort_prev)
 301                         {
 302                                 // player disconnected
 303                                 SetTeam(e, -1);
 304                                 RemovePlayer(e);
 305                                 e.sort_prev = world;
 306                                 //e.gotscores = 0;
 307                         }
 308                 }
 309                 else
 310                 {
 311                         if not(e.sort_prev)
 312                         {
 313                                 // player connected
 314                                 if not(e)
 315                                         playerslots[i] = e = spawn();
 316                                 e.sv_entnum = i;
 317                                 e.ping = 0;
 318                                 e.ping_packetloss = 0;
 319                                 e.ping_movementloss = 0;
 320                                 //e.gotscores = 0; // we might already have the scores...
 321                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 322                                 RegisterPlayer(e);
 323                                 HUD_UpdatePlayerPos(e);
 324                         }
 325                 }
 326         }
 327         self.nextthink = time + 0.2;
 328 }
 329
 330 void Porto_Init();
 331 void TrueAim_Init();
 332 void PostInit(void)
 333 {
 334         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 335
 336         entity playerchecker;
 337         playerchecker = spawn();
 338         playerchecker.think = Playerchecker_Think;
 339         playerchecker.nextthink = time + 0.2;
 340
 341         Porto_Init();
 342         TrueAim_Init();
 343
 344         postinit = true;
 345 }
 346
 347 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 348 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 349 float button_zoom;
 350 void Cmd_HUD_SetFields(float);
 351 void Cmd_HUD_Help(float);
 352 float CSQC_ConsoleCommand(string strMessage)
 353 {
 354         float argc;
 355         // Tokenize String
 356         //argc = tokenize(strMessage);
 357         argc = tokenize_console(strMessage);
 358
 359         // Acquire Command
 360         local string strCmd;
 361         strCmd = argv(0);
 362
 363         if(strCmd == "hud_configure") { // config hud
 364                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 365                 return true;
 366         } else if(strCmd == "hud_save") { // save hud config
 367                 if(argv(1) == "" || argv(2)) {
 368                         print(_("Usage:\n"));
 369                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 370                 }
 371                 else
 372                         HUD_Panel_ExportCfg(argv(1));
 373                 return true;
 374         } else if(strCmd == "+button4") { // zoom
 375                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 376                 if(ignore_plus_zoom)
 377                 {
 378                         --ignore_plus_zoom;
 379                         return false;
 380                 }
 381                 button_zoom = 1;
 382                 return true;
 383         } else if(strCmd == "-button4") { // zoom
 384                 if(ignore_minus_zoom)
 385                 {
 386                         --ignore_minus_zoom;
 387                         return false;
 388                 }
 389                 button_zoom = 0;
 390                 return true;
 391         } else if(strCmd == "+button3") { // secondary
 392                 button_attack2 = 1;
 393                 return false;
 394         } else if(strCmd == "-button3") { // secondary
 395                 button_attack2 = 0;
 396                 return false;
 397         } else if(strCmd == "+showscores") {
 398                 scoreboard_showscores = true;
 399                 return true;
 400         } else if(strCmd == "-showscores") {
 401                 scoreboard_showscores = false;
 402                 return true;
 403         } else if(strCmd == "+showaccuracy") {
 404                 scoreboard_showaccuracy = true;
 405                 return true;
 406         } else if(strCmd == "-showaccuracy") {
 407                 scoreboard_showaccuracy = false;
 408                 return true;
 409         }
 410
 411         if(camera_active)
 412         if(strCmd == "+forward" || strCmd == "-back") {
 413                 ++camera_direction_x;
 414                 return true;
 415         } else if(strCmd == "-forward" || strCmd == "+back") {
 416                 --camera_direction_x;
 417                 return true;
 418         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 419                 --camera_direction_y;
 420                 return true;
 421         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 422                 ++camera_direction_y;
 423                 return true;
 424         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 425                 ++camera_direction_z;
 426                 return true;
 427         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 428                 --camera_direction_z;
 429                 return true;
 430         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 431                 ++camera_roll;
 432                 return true;
 433         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 434                 --camera_roll;
 435                 return true;
 436         }
 437
 438         return false;
 439 }
 440
 441 .vector view_ofs;
 442 entity debug_shotorg;
 443 void ShotOrg_Draw()
 444 {
 445         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 446         self.angles = view_angles;
 447         self.angles_x = -self.angles_x;
 448         if not(self.cnt)
 449                 self.drawmask = MASK_NORMAL;
 450         else
 451                 self.drawmask = 0;
 452 }
 453 void ShotOrg_Draw2D()
 454 {
 455         vector coord2d_topleft, coord2d_topright, coord2d;
 456         string s;
 457         vector fs;
 458
 459         s = vtos(self.view_ofs);
 460         s = substring(s, 1, strlen(s) - 2);
 461         if(tokenize_console(s) == 3)
 462                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 463
 464         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 465         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 466
 467         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 468
 469         coord2d = coord2d_topleft;
 470         if(fs_x < 8)
 471         {
 472                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 473                 fs = '8 8 0';
 474         }
 475         coord2d_y -= fs_y;
 476         coord2d_z = 0;
 477         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 478 }
 479
 480 void ShotOrg_Spawn()
 481 {
 482         debug_shotorg = spawn();
 483         debug_shotorg.draw = ShotOrg_Draw;
 484         debug_shotorg.draw2d = ShotOrg_Draw2D;
 485         debug_shotorg.renderflags = RF_VIEWMODEL;
 486         debug_shotorg.effects = EF_FULLBRIGHT;
 487         precache_model("models/shotorg_adjuster.md3");
 488         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 489         debug_shotorg.scale = 2;
 490         debug_shotorg.view_ofs = '25 8 -8';
 491 }
 492
 493 void DrawDebugModel()
 494 {
 495         if(time - floor(time) > 0.5)
 496         {
 497                 PolyDrawModel(self);
 498                 self.drawmask = 0;
 499         }
 500         else
 501         {
 502                 self.renderflags = 0;
 503                 self.drawmask = MASK_NORMAL;
 504         }
 505 }
 506
 507 void GameCommand(string msg)
 508 {
 509         string s;
 510         float argc;
 511         entity e;
 512         argc = tokenize_console(msg);
 513
 514         if(argv(0) == "help" || argc == 0)
 515         {
 516                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 517                 print(_("  settemp cvar value\n"));
 518                 print(_("  scoreboard_columns_set ...\n"));
 519                 print(_("  scoreboard_columns_help\n"));
 520                 GameCommand_Generic("help");
 521                 return;
 522         }
 523
 524         if(GameCommand_Generic(msg))
 525                 return;
 526
 527         string cmd;
 528         cmd = argv(0);
 529         if(cmd == "mv_download") {
 530                 Cmd_MapVote_MapDownload(argc);
 531         }
 532         else if(cmd == "settemp") {
 533                 cvar_clientsettemp(argv(1), argv(2));
 534         }
 535         else if(cmd == "scoreboard_columns_set") {
 536                 Cmd_HUD_SetFields(argc);
 537         }
 538         else if(cmd == "scoreboard_columns_help") {
 539                 Cmd_HUD_Help(argc);
 540         }
 541 #ifdef BLURTEST
 542         else if(cmd == "blurtest") {
 543                 blurtest_time0 = time;
 544                 blurtest_time1 = time + stof(argv(1));
 545                 blurtest_radius = stof(argv(2));
 546                 blurtest_power = stof(argv(3));
 547         }
 548 #endif
 549         else if(cmd == "shotorg_move") {
 550                 if(!debug_shotorg)
 551                         ShotOrg_Spawn();
 552                 else
 553                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 554                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 555         }
 556         else if(cmd == "shotorg_movez") {
 557                 if(!debug_shotorg)
 558                         ShotOrg_Spawn();
 559                 else
 560                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 561                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 562         }
 563         else if(cmd == "shotorg_set") {
 564                 if(!debug_shotorg)
 565                         ShotOrg_Spawn();
 566                 else
 567                         debug_shotorg.view_ofs = stov(argv(1));
 568                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 569         }
 570         else if(cmd == "shotorg_setz") {
 571                 if(!debug_shotorg)
 572                         ShotOrg_Spawn();
 573                 else
 574                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 575                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 576         }
 577         else if(cmd == "shotorg_toggle_hide") {
 578                 if(debug_shotorg)
 579                 {
 580                         debug_shotorg.cnt = !debug_shotorg.cnt;
 581                 }
 582         }
 583         else if(cmd == "shotorg_end") {
 584                 if(debug_shotorg)
 585                 {
 586                         print(vtos(debug_shotorg.view_ofs), "\n");
 587                         remove(debug_shotorg);
 588                         debug_shotorg = world;
 589                 }
 590                 localcmd("sv_cmd debug_shotorg\n");
 591         }
 592         else if(cmd == "sendcvar") {
 593                 // W_FixWeaponOrder will trash argv, so save what we need.
 594                 string thiscvar;
 595                 thiscvar = strzone(argv(1));
 596                 s = cvar_string(thiscvar);
 597                 if(thiscvar == "cl_weaponpriority")
 598                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 599                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 600                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 601                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 602                 strunzone(thiscvar);
 603         }
 604         else if(cmd == "spawn") {
 605                 s = argv(1);
 606                 e = spawn();
 607                 precache_model(s);
 608                 setmodel(e, s);
 609                 setorigin(e, view_origin);
 610                 e.angles = view_angles;
 611                 e.draw = DrawDebugModel;
 612                 e.classname = "debugmodel";
 613         }
 614     else if(cmd == "vyes")
 615     {
 616         if(uid2name_dialog)
 617         {
 618             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 619             vote_prev = 0;
 620             cvar_set("cl_allow_uid2name", "1");
 621             vote_change = -9999;
 622         }
 623         else
 624         {
 625             localcmd("cmd vote yes\n");
 626         }
 627     }
 628     else if(cmd == "vno")
 629     {
 630         if(uid2name_dialog)
 631         {
 632             vote_active = 0;
 633             vote_prev = 0;
 634             cvar_set("cl_allow_uid2name", "0");
 635             vote_change = -9999;
 636         }
 637         else
 638         {
 639             localcmd("cmd vote no\n");
 640         }
 641     }
 642
 643         else
 644         {
 645                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 646         }
 647
 648         return;
 649 }
 650
 651 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 652 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 653 // All keys are in ascii.
 654 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 655 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 656 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 657 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 658 {
 659         local float bSkipKey;
 660         bSkipKey = false;
 661
 662         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 663                 return true;
 664
 665         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 666                 return true;
 667
 668         if(menu_visible)
 669                 if(menu_action(bInputType, nPrimary, nSecondary))
 670                         return TRUE;
 671
 672         return bSkipKey;
 673 }
 674
 675 // END REQUIRED CSQC FUNCTIONS
 676 // --------------------------------------------------------------------------
 677
 678 // --------------------------------------------------------------------------
 679 // BEGIN OPTIONAL CSQC FUNCTIONS
 680 void Ent_ReadEntCS()
 681 {
 682         InterpolateOrigin_Undo();
 683
 684         self.classname = "entcs_receiver";
 685         self.sv_entnum = ReadByte() - 1;
 686         self.origin_x = ReadShort();
 687         self.origin_y = ReadShort();
 688         self.origin_z = ReadShort();
 689         self.angles_y = ReadByte() * 360.0 / 256;
 690         self.origin_z = self.angles_x = self.angles_z = 0;
 691
 692         InterpolateOrigin_Note();
 693 }
 694
 695 void Ent_Remove();
 696
 697 void Ent_RemovePlayerScore()
 698 {
 699         float i;
 700
 701         if(self.owner)
 702         {
 703                 SetTeam(self.owner, -1);
 704                 self.owner.gotscores = 0;
 705                 for(i = 0; i < MAX_SCORE; ++i)
 706                         self.owner.(scores[i]) = 0; // clear all scores
 707         }
 708 }
 709
 710 void Ent_ReadPlayerScore()
 711 {
 712         float i, n;
 713         float isNew;
 714         entity o;
 715
 716         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 717         // (no I've never heard of M-x replace-string, sed, or anything like that)
 718         isNew = !self.owner; // workaround for DP bug
 719         n = ReadByte()-1;
 720
 721 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 722         if(!isNew && n != self.sv_entnum)
 723         {
 724                 print(_("A CSQC entity changed its owner!\n"));
 725                 isNew = true;
 726                 Ent_Remove();
 727                 self.enttype = ENT_CLIENT_SCORES;
 728         }
 729 #endif
 730
 731         self.sv_entnum = n;
 732
 733         if not(playerslots[self.sv_entnum])
 734                 playerslots[self.sv_entnum] = spawn();
 735         o = self.owner = playerslots[self.sv_entnum];
 736         o.sv_entnum = self.sv_entnum;
 737         o.gotscores = 1;
 738
 739         //if not(o.sort_prev)
 740         //      RegisterPlayer(o);
 741         //playerchecker will do this for us later, if it has not already done so
 742
 743         float sf, lf;
 744 #if MAX_SCORE <= 8
 745         sf = ReadByte();
 746         lf = ReadByte();
 747 #else
 748         sf = ReadShort();
 749         lf = ReadShort();
 750 #endif
 751         float p;
 752         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 753                 if(sf & p)
 754                 {
 755                         if(lf & p)
 756                                 o.(scores[i]) = ReadInt24_t();
 757                         else
 758                                 o.(scores[i]) = ReadChar();
 759                 }
 760
 761         if(o.sort_prev)
 762                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 763
 764         self.entremove = Ent_RemovePlayerScore;
 765 }
 766
 767 void Ent_ReadTeamScore()
 768 {
 769         float i;
 770         entity o;
 771
 772         self.team = ReadByte();
 773         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 774
 775         float sf, lf;
 776 #if MAX_TEAMSCORE <= 8
 777         sf = ReadByte();
 778         lf = ReadByte();
 779 #else
 780         sf = ReadShort();
 781         lf = ReadShort();
 782 #endif
 783         float p;
 784         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 785                 if(sf & p)
 786                 {
 787                         if(lf & p)
 788                                 o.(teamscores[i]) = ReadInt24_t();
 789                         else
 790                                 o.(teamscores[i]) = ReadChar();
 791                 }
 792
 793         HUD_UpdateTeamPos(o);
 794 }
 795
 796 void Net_Reset()
 797 {
 798 }
 799
 800 void Ent_ClientData()
 801 {
 802         float f;
 803         float newspectatee_status;
 804
 805         f = ReadByte();
 806
 807         scoreboard_showscores_force = (f & 1);
 808
 809         if(f & 2)
 810         {
 811                 newspectatee_status = ReadByte();
 812                 if(newspectatee_status == player_localentnum)
 813                         newspectatee_status = -1; // observing
 814         }
 815         else
 816                 newspectatee_status = 0;
 817
 818         spectatorbutton_zoom = (f & 4);
 819
 820         if(f & 8)
 821         {
 822                 angles_held_status = 1;
 823                 angles_held_x = ReadAngle();
 824                 angles_held_y = ReadAngle();
 825                 angles_held_z = 0;
 826         }
 827         else
 828                 angles_held_status = 0;
 829
 830         if(newspectatee_status != spectatee_status)
 831         {
 832                 float i;
 833
 834                 // clear race stuff
 835                 race_laptime = 0;
 836                 race_checkpointtime = 0;
 837         }
 838         spectatee_status = newspectatee_status;
 839 }
 840
 841 void Ent_Nagger()
 842 {
 843         float nags, i, j, b, f;
 844
 845         nags = ReadByte();
 846
 847         if(nags & 128)
 848         {
 849                 if(vote_called_vote)
 850                         strunzone(vote_called_vote);
 851                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 852         }
 853
 854         if(nags & 1)
 855         {
 856                 for(j = 0; j < maxclients; ++j)
 857                         if(playerslots[j])
 858                                 playerslots[j].ready = 1;
 859                 for(i = 1; i <= maxclients; i += 8)
 860                 {
 861                         f = ReadByte();
 862                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 863                                 if not(f & b)
 864                                         if(playerslots[j])
 865                                                 playerslots[j].ready = 0;
 866                 }
 867         }
 868
 869         ready_waiting = (nags & 1);
 870         ready_waiting_for_me = (nags & 2);
 871         vote_waiting = (nags & 4);
 872         vote_waiting_for_me = (nags & 8);
 873         warmup_stage = (nags & 16);
 874 }
 875
 876 void Ent_RandomSeed()
 877 {
 878         float s;
 879         prandom_debug();
 880         s = ReadShort();
 881         psrandom(s);
 882 }
 883
 884 void Ent_ReadAccuracy(void)
 885 {
 886         float sf, f, w, b;
 887         sf = ReadInt24_t();
 888         if(sf == 0)
 889         {
 890                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 891                         weapon_accuracy[w] = -1;
 892                 return;
 893         }
 894
 895         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 896         {
 897                 if(sf & f)
 898                 {
 899                         b = ReadByte();
 900                         if(b == 0)
 901                                 weapon_accuracy[w] = -1;
 902                         else if(b == 255)
 903                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 904                         else
 905                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 906                 }
 907         }
 908 }
 909
 910 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 911 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 912 void Ent_RadarLink();
 913 void Ent_Init();
 914 void Ent_ScoresInfo();
 915 void(float bIsNewEntity) CSQC_Ent_Update =
 916 {
 917         float t;
 918         float savetime;
 919         t = ReadByte();
 920
 921         // set up the "time" global for received entities to be correct for interpolation purposes
 922         savetime = time;
 923         if(servertime)
 924         {
 925                 time = servertime;
 926         }
 927         else
 928         {
 929                 serverprevtime = time;
 930                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 931                 time = serverprevtime + serverdeltatime;
 932         }
 933
 934 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 935         if(self.enttype)
 936                 if(t != self.enttype)
 937                 {
 938                         print(_("A CSQC entity changed its type!\n"));
 939                         Ent_Remove();
 940                         bIsNewEntity = 1;
 941                 }
 942 #endif
 943         self.enttype = t;
 944         switch(t)
 945         {
 946                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 947                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 948                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 949                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 950                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 951                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 952                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 953                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 954                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 955                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 956                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 957                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 958                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 959                 case ENT_CLIENT_INIT: Ent_Init(); break;
 960                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 961                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 962                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 963                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 964                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 965                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 966                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 967                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 968                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 969                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 970                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 971                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 972                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 973                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 974                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 975                 default:
 976                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 977                         break;
 978         }
 979
 980         time = savetime;
 981 };
 982 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 983 // used when an entity changes its type. For an entity that someone interacts
 984 // with others, make sure it can no longer do so.
 985 void Ent_Remove()
 986 {
 987         if(self.entremove)
 988                 self.entremove();
 989
 990         self.enttype = 0;
 991         self.classname = "";
 992         self.draw = menu_sub_null;
 993         self.entremove = menu_sub_null;
 994         // TODO possibly set more stuff to defaults
 995 }
 996 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 997 void CSQC_Ent_Remove()
 998 {
 999         if(self.enttype)
1000                 Ent_Remove();
1001         remove(self);
1002 }
1003
1004 void Gamemode_Init()
1005 {
1006         if(gametype == GAME_ONSLAUGHT) {
1007                 print(strcat("Using ", minimapname, " as minimap.\n"));
1008                 precache_pic("gfx/ons-cp-neutral.tga");
1009                 precache_pic("gfx/ons-cp-red.tga");
1010                 precache_pic("gfx/ons-cp-blue.tga");
1011                 precache_pic("gfx/ons-frame.tga");
1012                 precache_pic("gfx/ons-frame-team.tga");
1013         }
1014
1015         if not(isdemo())
1016         {
1017                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1018                 calledhooks |= HOOK_START;
1019         }
1020 }
1021 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1022 void CSQC_Parse_StuffCmd(string strMessage)
1023 {
1024         localcmd(strMessage);
1025 }
1026 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1027 void CSQC_Parse_Print(string strMessage)
1028 {
1029         print(ColorTranslateRGB(strMessage));
1030 }
1031
1032 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1033 void CSQC_Parse_CenterPrint(string strMessage)
1034 {
1035         centerprint(strMessage);
1036 }
1037
1038 string notranslate_fogcmd1 = "\nfog ";
1039 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1040 void Fog_Force()
1041 {
1042         // TODO somehow thwart prvm_globalset client ...
1043
1044         if(forcefog != "")
1045                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1046 }
1047
1048 void Gamemode_Init();
1049 void Ent_ScoresInfo()
1050 {
1051         float i;
1052         self.classname = "ent_client_scores_info";
1053         gametype = ReadByte();
1054         for(i = 0; i < MAX_SCORE; ++i)
1055         {
1056                 scores_label[i] = strzone(ReadString());
1057                 scores_flags[i] = ReadByte();
1058         }
1059         for(i = 0; i < MAX_TEAMSCORE; ++i)
1060         {
1061                 teamscores_label[i] = strzone(ReadString());
1062                 teamscores_flags[i] = ReadByte();
1063         }
1064         HUD_InitScores();
1065         Gamemode_Init();
1066 }
1067
1068 void Ent_Init()
1069 {
1070         self.classname = "ent_client_init";
1071
1072         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1073
1074         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1075         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1076         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1077         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1078         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1079         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1080         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1081         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1082         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1083         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1084         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1085         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1086
1087         if(forcefog)
1088                 strunzone(forcefog);
1089         forcefog = strzone(ReadString());
1090
1091         armorblockpercent = ReadByte() / 255.0;
1092
1093         g_weaponswitchdelay = ReadByte() / 255.0;
1094
1095         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1096         g_balance_grenadelauncher_bouncestop = ReadCoord();
1097         g_balance_electro_secondary_bouncefactor = ReadCoord();
1098         g_balance_electro_secondary_bouncestop = ReadCoord();
1099
1100         nex_scope = !ReadByte();
1101         sniperrifle_scope = !ReadByte();
1102
1103         serverflags = ReadByte();
1104
1105         minelayer_maxmines = ReadByte();
1106
1107         hagar_maxrockets = ReadByte();
1108
1109         g_trueaim_minrange = ReadCoord();
1110
1111         if(!postinit)
1112                 PostInit();
1113 }
1114
1115 void Net_ReadRace()
1116 {
1117         float b;
1118
1119         b = ReadByte();
1120
1121         switch(b)
1122         {
1123                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1124                         race_checkpoint = ReadByte();
1125                         race_time = ReadInt24_t();
1126                         race_previousbesttime = ReadInt24_t();
1127                         if(race_previousbestname)
1128                                 strunzone(race_previousbestname);
1129                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1130
1131                         race_checkpointtime = time;
1132
1133                         if(race_checkpoint == 0 || race_checkpoint == 254)
1134                         {
1135                                 race_penaltyaccumulator = 0;
1136                                 race_laptime = time; // valid
1137                         }
1138
1139                         break;
1140
1141                 case RACE_NET_CHECKPOINT_CLEAR:
1142                         race_laptime = 0;
1143                         race_checkpointtime = 0;
1144                         break;
1145
1146                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1147                         race_laptime = ReadCoord();
1148                         race_checkpointtime = -99999;
1149                         // fall through
1150                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1151                         race_nextcheckpoint = ReadByte();
1152
1153                         race_nextbesttime = ReadInt24_t();
1154                         if(race_nextbestname)
1155                                 strunzone(race_nextbestname);
1156                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1157                         break;
1158
1159                 case RACE_NET_CHECKPOINT_HIT_RACE:
1160                         race_mycheckpoint = ReadByte();
1161                         race_mycheckpointtime = time;
1162                         race_mycheckpointdelta = ReadInt24_t();
1163                         race_mycheckpointlapsdelta = ReadByte();
1164                         if(race_mycheckpointlapsdelta >= 128)
1165                                 race_mycheckpointlapsdelta -= 256;
1166                         if(race_mycheckpointenemy)
1167                                 strunzone(race_mycheckpointenemy);
1168                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1169                         break;
1170
1171                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1172                         race_othercheckpoint = ReadByte();
1173                         race_othercheckpointtime = time;
1174                         race_othercheckpointdelta = ReadInt24_t();
1175                         race_othercheckpointlapsdelta = ReadByte();
1176                         if(race_othercheckpointlapsdelta >= 128)
1177                                 race_othercheckpointlapsdelta -= 256;
1178                         if(race_othercheckpointenemy)
1179                                 strunzone(race_othercheckpointenemy);
1180                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1181                         break;
1182
1183                 case RACE_NET_PENALTY_RACE:
1184                         race_penaltyeventtime = time;
1185                         race_penaltytime = ReadShort();
1186                         //race_penaltyaccumulator += race_penaltytime;
1187                         if(race_penaltyreason)
1188                                 strunzone(race_penaltyreason);
1189                         race_penaltyreason = strzone(ReadString());
1190                         break;
1191
1192                 case RACE_NET_PENALTY_QUALIFYING:
1193                         race_penaltyeventtime = time;
1194                         race_penaltytime = ReadShort();
1195                         race_penaltyaccumulator += race_penaltytime;
1196                         if(race_penaltyreason)
1197                                 strunzone(race_penaltyreason);
1198                         race_penaltyreason = strzone(ReadString());
1199                         break;
1200
1201                 case RACE_NET_SERVER_RECORD:
1202                         race_server_record = ReadInt24_t();
1203                         break;
1204                 case RACE_NET_SPEED_AWARD:
1205                         race_speedaward = ReadInt24_t();
1206                         if(race_speedaward_holder)
1207                                 strunzone(race_speedaward_holder);
1208                         race_speedaward_holder = strzone(ReadString());
1209                         break;
1210                 case RACE_NET_SPEED_AWARD_BEST:
1211                         race_speedaward_alltimebest = ReadInt24_t();
1212                         if(race_speedaward_alltimebest_holder)
1213                                 strunzone(race_speedaward_alltimebest_holder);
1214                         race_speedaward_alltimebest_holder = strzone(ReadString());
1215                         break;
1216                 case RACE_NET_SERVER_RANKINGS:
1217                         float pos, prevpos, del;
1218                         pos = ReadShort();
1219                         prevpos = ReadShort();
1220                         del = ReadShort();
1221
1222                         // move other rankings out of the way
1223                         float i;
1224                         if (prevpos) {
1225                                 for (i=prevpos-1;i>pos-1;--i) {
1226                                         grecordtime[i] = grecordtime[i-1];
1227                                         if(grecordholder[i])
1228                                                 strunzone(grecordholder[i]);
1229                                         grecordholder[i] = strzone(grecordholder[i-1]);
1230                                 }
1231                         } else if (del) { // a record has been deleted by the admin
1232                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1233                                         if (i == RANKINGS_CNT-1) { // clear out last record
1234                                                 grecordtime[i] = 0;
1235                                                 if (grecordholder[i])
1236                                                         strunzone(grecordholder[i]);
1237                                                 grecordholder[i] = string_null;
1238                                         }
1239                                         else {
1240                                                 grecordtime[i] = grecordtime[i+1];
1241                                                 if (grecordholder[i])
1242                                                         strunzone(grecordholder[i]);
1243                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1244                                         }
1245                                 }
1246                         } else { // player has no ranked record yet
1247                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1248                                         grecordtime[i] = grecordtime[i-1];
1249                                         if(grecordholder[i])
1250                                                 strunzone(grecordholder[i]);
1251                                         grecordholder[i] = strzone(grecordholder[i-1]);
1252                                 }
1253                         }
1254
1255                         // store new ranking
1256                         if(grecordholder[pos-1] != "")
1257                                 strunzone(grecordholder[pos-1]);
1258                         grecordholder[pos-1] = strzone(ReadString());
1259                         grecordtime[pos-1] = ReadInt24_t();
1260                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1261                                 race_myrank = pos;
1262                         break;
1263                 case RACE_NET_SERVER_STATUS:
1264                         race_status = ReadShort();
1265                         if(race_status_name)
1266                                 strunzone(race_status_name);
1267                         race_status_name = strzone(ReadString());
1268         }
1269 }
1270
1271 void Net_ReadSpawn()
1272 {
1273         zoomin_effect = 1;
1274         current_viewzoom = 0.6;
1275 }
1276
1277 void Net_TeamNagger()
1278 {
1279         teamnagger = 1;
1280 }
1281
1282 void Net_ReadPingPLReport()
1283 {
1284         float e, pi, pl, ml;
1285         e = ReadByte();
1286         pi = ReadShort();
1287         pl = ReadByte();
1288         ml = ReadByte();
1289         if not(playerslots[e])
1290                 return;
1291         playerslots[e].ping = pi;
1292         playerslots[e].ping_packetloss = pl / 255.0;
1293         playerslots[e].ping_movementloss = ml / 255.0;
1294 }
1295
1296 void Net_VoteDialog(float highlight) {
1297         if(highlight) {
1298                 vote_highlighted = ReadByte();
1299                 return;
1300         }
1301
1302         vote_yescount = ReadByte();
1303         vote_nocount = ReadByte();
1304         vote_needed = ReadByte();
1305         vote_active = 1;
1306 }
1307
1308 void Net_VoteDialogReset() {
1309         vote_active = 0;
1310 }
1311
1312 void Net_Notify() {
1313         float type;
1314         type = ReadByte();
1315
1316         if(type == CSQC_KILLNOTIFY)
1317         {
1318                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1319         }
1320         else if(type == CSQC_CENTERPRINT)
1321         {
1322                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1323         }
1324 }
1325
1326 void Net_WeaponComplain() {
1327         complain_weapon = ReadByte();
1328
1329         if(complain_weapon_name)
1330                 strunzone(complain_weapon_name);
1331         complain_weapon_name = strzone(ReadString());
1332
1333         complain_weapon_type = ReadByte();
1334
1335         complain_weapon_time = time;
1336         weapontime = time; // ping the weapon panel
1337 }
1338
1339 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1340 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1341 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1342 float CSQC_Parse_TempEntity()
1343 {
1344         local float bHandled;
1345                 bHandled  = true;
1346         // Acquire TE ID
1347         local float nTEID;
1348                 nTEID = ReadByte();
1349
1350                 // NOTE: Could just do return instead of break...
1351         switch(nTEID)
1352         {
1353                 case TE_CSQC_TARGET_MUSIC:
1354                         Net_TargetMusic();
1355                         bHandled = true;
1356                         break;
1357                 case TE_CSQC_PICTURE:
1358                         Net_MapVote_Picture();
1359                         bHandled = true;
1360                         break;
1361                 case TE_CSQC_RACE:
1362                         Net_ReadRace();
1363                         bHandled = true;
1364                         break;
1365                 case TE_CSQC_SPAWN:
1366                         Net_ReadSpawn();
1367                         bHandled = true;
1368                         break;
1369                 case TE_CSQC_ZCURVEPARTICLES:
1370                         Net_ReadZCurveParticles();
1371                         bHandled = true;
1372                         break;
1373                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1374                         Net_ReadNexgunBeamParticle();
1375                         bHandled = true;
1376                         break;
1377                 case TE_CSQC_TEAMNAGGER:
1378                         Net_TeamNagger();
1379                         bHandled = true;
1380                         break;
1381                 case TE_CSQC_VOTE:
1382                         Net_VoteDialog(ReadByte());
1383                         bHandled = true;
1384                         break;
1385                 case TE_CSQC_VOTERESET:
1386                         Net_VoteDialogReset();
1387                         bHandled = true;
1388                         break;
1389                 case TE_CSQC_LIGHTNINGARC:
1390                         Net_ReadLightningarc();
1391                         bHandled = true;
1392                         break;
1393                 case TE_CSQC_PINGPLREPORT:
1394                         Net_ReadPingPLReport();
1395                         bHandled = true;
1396                         break;
1397                 case TE_CSQC_ANNOUNCE:
1398                         announce_snd = strzone(ReadString());
1399                         bHandled = true;
1400                         break;
1401                 case TE_CSQC_NOTIFY:
1402                         Net_Notify();
1403                         bHandled = true;
1404                         break;
1405                 case TE_CSQC_WEAPONCOMPLAIN:
1406                         Net_WeaponComplain();
1407                         bHandled = true;
1408                         break;
1409                 default:
1410                         // No special logic for this temporary entity; return 0 so the engine can handle it
1411                         bHandled = false;
1412                         break;
1413         }
1414
1415         return bHandled;
1416 }
1417
1418 string getcommandkey(string text, string command)
1419 {
1420         string keys;
1421         float n, j, k, l;
1422
1423         if (!hud_showbinds)
1424                 return text;
1425
1426         keys = db_get(binddb, command);
1427         if (!keys)
1428         {
1429                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1430                 for(j = 0; j < n; ++j)
1431                 {
1432                         k = stof(argv(j));
1433                         if(k != -1)
1434                         {
1435                                 if ("" == keys)
1436                                         keys = keynumtostring(k);
1437                                 else
1438                                         keys = strcat(keys, ", ", keynumtostring(k));
1439
1440                                 ++l;
1441                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1442                         }
1443
1444                 }
1445                 db_put(binddb, command, keys);
1446         }
1447
1448         if ("" == keys) {
1449                 if (hud_showbinds > 1)
1450                         return sprintf(_("%s (not bound)"), text);
1451                 else
1452                         return text;
1453         }
1454         else if (hud_showbinds > 1)
1455                 return sprintf(_("%s (%s)"), text, keys);
1456         else
1457                 return keys;
1458 }