qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = menu_sub_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(FL_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 158         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 159
 160         WaypointSprite_Load();
 161
 162         // precaches
 163         precache_model("null");
 164         precache_sound("misc/hit.wav");
 165         precache_sound("misc/typehit.wav");
 166         if (autocvar_cl_precacheplayermodels)
 167         {
 168                 precache_all_playermodels("models/player/*.zym");
 169                 precache_all_playermodels("models/player/*.dpm");
 170                 precache_all_playermodels("models/player/*.md3");
 171                 precache_all_playermodels("models/player/*.psk");
 172                 precache_all_playermodels("models/player/*.iqm");
 173         }
 174
 175         Projectile_Precache();
 176         Hook_Precache();
 177         GibSplash_Precache();
 178         Casings_Precache();
 179         DamageInfo_Precache();
 180         Vehicles_Precache();
 181         turrets_precache();
 182     Announcer_Precache();
 183         Tuba_Precache();
 184
 185         if(autocvar_cl_reticle)
 186         {
 187                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 188                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 189         }
 190
 191         get_mi_min_max_texcoords(1); // try the CLEVER way first
 192         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 193         shortmapname = mi_shortname;
 194
 195         if(precache_pic(minimapname) == "")
 196         {
 197                 // but maybe we have a non-clever minimap
 198                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 199                 if(precache_pic(minimapname) == "")
 200                         minimapname = ""; // FAIL
 201                 else
 202                         get_mi_min_max_texcoords(0); // load new texcoords
 203         }
 204
 205         mi_center = (mi_min + mi_max) * 0.5;
 206         mi_scale = mi_max - mi_min;
 207         minimapname = strzone(minimapname);
 208
 209         WarpZone_Init();
 210
 211         hud_configure_prev = -1;
 212         tab_panel = -1;
 213
 214         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 215 }
 216
 217 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 218 void Shutdown(void)
 219 {
 220 #ifdef USE_FTE
 221 #pragma TARGET id
 222         if(!__engine_check)
 223                 return 0;
 224 #pragma TARGET fte
 225 #endif
 226
 227         WarpZone_Shutdown();
 228
 229         remove(teams);
 230         remove(players);
 231         db_close(binddb);
 232         db_close(tempdb);
 233         if(autocvar_cl_db_saveasdump)
 234                 db_dump(ClientProgsDB, "client.db");
 235         else
 236                 db_save(ClientProgsDB, "client.db");
 237         db_close(ClientProgsDB);
 238
 239         if(camera_active)
 240                 cvar_set("chase_active",ftos(chase_active_backup));
 241
 242         // unset the event chasecam's chase_active
 243         if(autocvar_chase_active < 0)
 244                 cvar_set("chase_active", "0");
 245
 246         if not(isdemo())
 247         {
 248                 if not(calledhooks & HOOK_START)
 249                         localcmd("\n_cl_hook_gamestart nop\n");
 250                 if not(calledhooks & HOOK_END)
 251                         localcmd("\ncl_hook_gameend\n");
 252         }
 253 }
 254
 255 .float has_team;
 256 float SetTeam(entity o, float Team)
 257 {
 258         entity tm;
 259         if(teamplay)
 260         {
 261                 switch(Team)
 262                 {
 263                         case -1:
 264                         case FL_TEAM_1:
 265                         case FL_TEAM_2:
 266                         case FL_TEAM_3:
 267                         case FL_TEAM_4:
 268                                 break;
 269                         default:
 270                                 if(GetTeam(Team, false) == world)
 271                                 {
 272                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 273                                         Team = FL_SPECTATOR;
 274                                 }
 275                                 break;
 276                 }
 277         }
 278         else
 279         {
 280                 switch(Team)
 281                 {
 282                         case -1:
 283                         case 0:
 284                                 break;
 285                         default:
 286                                 if(GetTeam(Team, false) == world)
 287                                 {
 288                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 289                                         Team = FL_SPECTATOR;
 290                                 }
 291                                 break;
 292                 }
 293         }
 294         if(Team == -1) // leave
 295         {
 296                 if(o.has_team)
 297                 {
 298                         tm = GetTeam(o.team, false);
 299                         tm.team_size -= 1;
 300                         o.has_team = 0;
 301                         return TRUE;
 302                 }
 303         }
 304         else
 305         {
 306                 if not(o.has_team)
 307                 {
 308                         o.team = Team;
 309                         tm = GetTeam(Team, true);
 310                         tm.team_size += 1;
 311                         o.has_team = 1;
 312                         return TRUE;
 313                 }
 314                 else if(Team != o.team)
 315                 {
 316                         tm = GetTeam(o.team, false);
 317                         tm.team_size -= 1;
 318                         o.team = Team;
 319                         tm = GetTeam(Team, true);
 320                         tm.team_size += 1;
 321                         return TRUE;
 322                 }
 323         }
 324         return FALSE;
 325 }
 326
 327 void Playerchecker_Think()
 328 {
 329         float i;
 330         entity e;
 331         for(i = 0; i < maxclients; ++i)
 332         {
 333                 e = playerslots[i];
 334                 if(GetPlayerName(i) == "")
 335                 {
 336                         if(e.sort_prev)
 337                         {
 338                                 // player disconnected
 339                                 SetTeam(e, -1);
 340                                 RemovePlayer(e);
 341                                 e.sort_prev = world;
 342                                 //e.gotscores = 0;
 343                         }
 344                 }
 345                 else
 346                 {
 347                         if not(e.sort_prev)
 348                         {
 349                                 // player connected
 350                                 if not(e)
 351                                         playerslots[i] = e = spawn();
 352                                 e.sv_entnum = i;
 353                                 e.ping = 0;
 354                                 e.ping_packetloss = 0;
 355                                 e.ping_movementloss = 0;
 356                                 //e.gotscores = 0; // we might already have the scores...
 357                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 358                                 RegisterPlayer(e);
 359                                 HUD_UpdatePlayerPos(e);
 360                         }
 361                 }
 362         }
 363         self.nextthink = time + 0.2;
 364 }
 365
 366 void Porto_Init();
 367 void TrueAim_Init();
 368 void PostInit(void)
 369 {
 370         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 371
 372         entity playerchecker;
 373         playerchecker = spawn();
 374         playerchecker.think = Playerchecker_Think;
 375         playerchecker.nextthink = time + 0.2;
 376
 377         Porto_Init();
 378         TrueAim_Init();
 379
 380         postinit = true;
 381 }
 382
 383 float button_zoom;
 384
 385 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 386 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 387 // All keys are in ascii.
 388 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 389 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 390 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 391 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 392 {
 393         float bSkipKey;
 394         bSkipKey = false;
 395
 396         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 397                 return true;
 398
 399         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 400                 return true;
 401
 402         if(menu_visible)
 403                 if(menu_action(bInputType, nPrimary, nSecondary))
 404                         return TRUE;
 405
 406         return bSkipKey;
 407 }
 408
 409 // END REQUIRED CSQC FUNCTIONS
 410 // --------------------------------------------------------------------------
 411
 412 // --------------------------------------------------------------------------
 413 // BEGIN OPTIONAL CSQC FUNCTIONS
 414 void Ent_RemoveEntCS()
 415 {
 416         entcs_receiver[self.sv_entnum] = world;
 417 }
 418 void Ent_ReadEntCS()
 419 {
 420         float sf;
 421         InterpolateOrigin_Undo();
 422
 423         self.classname = "entcs_receiver";
 424         sf = ReadByte();
 425
 426         if(sf & 1)
 427                 self.sv_entnum = ReadByte();
 428         if(sf & 2)
 429         {
 430                 self.origin_x = ReadShort();
 431                 self.origin_y = ReadShort();
 432                 self.origin_z = ReadShort();
 433         }
 434         if(sf & 4)
 435         {
 436                 self.angles_y = ReadByte() * 360.0 / 256;
 437                 self.angles_x = self.angles_z = 0;
 438         }
 439         if(sf & 8)
 440                 self.healthvalue = ReadByte() * 10;
 441         if(sf & 16)
 442                 self.armorvalue = ReadByte() * 10;
 443
 444         entcs_receiver[self.sv_entnum] = self;
 445         self.entremove = Ent_RemoveEntCS;
 446
 447         InterpolateOrigin_Note();
 448 }
 449
 450 void Ent_Remove();
 451
 452 void Ent_RemovePlayerScore()
 453 {
 454         float i;
 455
 456         if(self.owner)
 457         {
 458                 SetTeam(self.owner, -1);
 459                 self.owner.gotscores = 0;
 460                 for(i = 0; i < MAX_SCORE; ++i)
 461                         self.owner.(scores[i]) = 0; // clear all scores
 462         }
 463 }
 464
 465 void Ent_ReadPlayerScore()
 466 {
 467         float i, n;
 468         float isNew;
 469         entity o;
 470
 471         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 472         // (no I've never heard of M-x replace-string, sed, or anything like that)
 473         isNew = !self.owner; // workaround for DP bug
 474         n = ReadByte()-1;
 475
 476 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 477         if(!isNew && n != self.sv_entnum)
 478         {
 479                 //print(_("A CSQC entity changed its owner!\n"));
 480                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 481                 isNew = true;
 482                 Ent_Remove();
 483                 self.enttype = ENT_CLIENT_SCORES;
 484         }
 485 #endif
 486
 487         self.sv_entnum = n;
 488
 489         if not(playerslots[self.sv_entnum])
 490                 playerslots[self.sv_entnum] = spawn();
 491         o = self.owner = playerslots[self.sv_entnum];
 492         o.sv_entnum = self.sv_entnum;
 493         o.gotscores = 1;
 494
 495         //if not(o.sort_prev)
 496         //      RegisterPlayer(o);
 497         //playerchecker will do this for us later, if it has not already done so
 498
 499         float sf, lf;
 500 #if MAX_SCORE <= 8
 501         sf = ReadByte();
 502         lf = ReadByte();
 503 #else
 504         sf = ReadShort();
 505         lf = ReadShort();
 506 #endif
 507         float p;
 508         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 509                 if(sf & p)
 510                 {
 511                         if(lf & p)
 512                                 o.(scores[i]) = ReadInt24_t();
 513                         else
 514                                 o.(scores[i]) = ReadChar();
 515                 }
 516
 517         if(o.sort_prev)
 518                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 519
 520         self.entremove = Ent_RemovePlayerScore;
 521 }
 522
 523 void Ent_ReadTeamScore()
 524 {
 525         float i;
 526         entity o;
 527
 528         self.team = ReadByte();
 529         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 530
 531         float sf, lf;
 532 #if MAX_TEAMSCORE <= 8
 533         sf = ReadByte();
 534         lf = ReadByte();
 535 #else
 536         sf = ReadShort();
 537         lf = ReadShort();
 538 #endif
 539         float p;
 540         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 541                 if(sf & p)
 542                 {
 543                         if(lf & p)
 544                                 o.(teamscores[i]) = ReadInt24_t();
 545                         else
 546                                 o.(teamscores[i]) = ReadChar();
 547                 }
 548
 549         HUD_UpdateTeamPos(o);
 550 }
 551
 552 void Ent_ClientData()
 553 {
 554         float f;
 555         float newspectatee_status;
 556
 557         f = ReadByte();
 558
 559         scoreboard_showscores_force = (f & 1);
 560
 561         if(f & 2)
 562         {
 563                 newspectatee_status = ReadByte();
 564                 if(newspectatee_status == player_localnum + 1)
 565                         newspectatee_status = -1; // observing
 566         }
 567         else
 568                 newspectatee_status = 0;
 569
 570         spectatorbutton_zoom = (f & 4);
 571
 572         if(f & 8)
 573         {
 574                 angles_held_status = 1;
 575                 angles_held_x = ReadAngle();
 576                 angles_held_y = ReadAngle();
 577                 angles_held_z = 0;
 578         }
 579         else
 580                 angles_held_status = 0;
 581
 582         if(newspectatee_status != spectatee_status)
 583         {
 584                 // clear race stuff
 585                 race_laptime = 0;
 586                 race_checkpointtime = 0;
 587         }
 588         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 589         {
 590                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 591                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 592                 )
 593                         prev_p_health = -1;
 594                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 595                         prev_health = -1;
 596         }
 597         spectatee_status = newspectatee_status;
 598
 599         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 600 }
 601
 602 void Ent_Nagger()
 603 {
 604         float nags, i, j, b, f;
 605
 606         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 607
 608         if(!(nags & 4))
 609         {
 610                 if(vote_called_vote)
 611                         strunzone(vote_called_vote);
 612                 vote_called_vote = string_null;
 613                 vote_active = 0;
 614         }
 615         else
 616         {
 617                 vote_active = 1;
 618         }
 619
 620         if(nags & 64)
 621         {
 622                 vote_yescount = ReadByte();
 623                 vote_nocount = ReadByte();
 624                 vote_needed = ReadByte();
 625                 vote_highlighted = ReadChar();
 626         }
 627
 628         if(nags & 128)
 629         {
 630                 if(vote_called_vote)
 631                         strunzone(vote_called_vote);
 632                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 633         }
 634
 635         if(nags & 1)
 636         {
 637                 for(j = 0; j < maxclients; ++j)
 638                         if(playerslots[j])
 639                                 playerslots[j].ready = 1;
 640                 for(i = 1; i <= maxclients; i += 8)
 641                 {
 642                         f = ReadByte();
 643                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 644                                 if not(f & b)
 645                                         if(playerslots[j])
 646                                                 playerslots[j].ready = 0;
 647                 }
 648         }
 649
 650         ready_waiting = (nags & 1);
 651         ready_waiting_for_me = (nags & 2);
 652         vote_waiting = (nags & 4);
 653         vote_waiting_for_me = (nags & 8);
 654         warmup_stage = (nags & 16);
 655 }
 656
 657 void Ent_RandomSeed()
 658 {
 659         float s;
 660         prandom_debug();
 661         s = ReadShort();
 662         psrandom(s);
 663 }
 664
 665 void Ent_ReadAccuracy(void)
 666 {
 667         float sf, f, w, b;
 668         sf = ReadInt24_t();
 669         if(sf == 0)
 670         {
 671                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 672                         weapon_accuracy[w] = -1;
 673                 return;
 674         }
 675
 676         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 677         {
 678                 if(sf & f)
 679                 {
 680                         b = ReadByte();
 681                         if(b == 0)
 682                                 weapon_accuracy[w] = -1;
 683                         else if(b == 255)
 684                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 685                         else
 686                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 687                 }
 688         }
 689 }
 690
 691 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 692 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 693 void Ent_RadarLink();
 694 void Ent_Init();
 695 void Ent_ScoresInfo();
 696 void CSQC_Ent_Update(float bIsNewEntity)
 697 {
 698         float t;
 699         float savetime;
 700         t = ReadByte();
 701
 702         // set up the "time" global for received entities to be correct for interpolation purposes
 703         savetime = time;
 704         if(servertime)
 705         {
 706                 time = servertime;
 707         }
 708         else
 709         {
 710                 serverprevtime = time;
 711                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 712                 time = serverprevtime + serverdeltatime;
 713         }
 714
 715 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 716         if(self.enttype)
 717         {
 718                 if(t != self.enttype || bIsNewEntity)
 719                 {
 720                         //print(_("A CSQC entity changed its type!\n"));
 721                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 722                         Ent_Remove();
 723                         clearentity(self);
 724                         bIsNewEntity = 1;
 725                 }
 726         }
 727         else
 728         {
 729                 if(!bIsNewEntity)
 730                 {
 731                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 732                         bIsNewEntity = 1;
 733                 }
 734         }
 735 #endif
 736         self.enttype = t;
 737         switch(t)
 738         {
 739                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 740                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 741                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 742                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 743                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 744                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 745                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 746                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 747                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 748                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 749                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 750                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 751                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 752                 case ENT_CLIENT_INIT: Ent_Init(); break;
 753                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 754                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 755                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 756                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 757                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 758                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 759                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 760                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 761                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 762                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 763                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 764                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 765                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 766                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 767                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 768                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 769                 case ENT_CLIENT_TURRET: ent_turret(); break;
 770                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 771                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 772                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 773                 default:
 774                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 775                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 776                         break;
 777         }
 778
 779         time = savetime;
 780 }
 781 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 782 // used when an entity changes its type. For an entity that someone interacts
 783 // with others, make sure it can no longer do so.
 784 void Ent_Remove()
 785 {
 786         if(self.entremove)
 787                 self.entremove();
 788
 789         self.enttype = 0;
 790         self.classname = "";
 791         self.draw = menu_sub_null;
 792         self.entremove = menu_sub_null;
 793         // TODO possibly set more stuff to defaults
 794 }
 795 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 796 void CSQC_Ent_Remove()
 797 {
 798         if(wasfreed(self))
 799         {
 800                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 801                 return;
 802         }
 803         if(self.enttype)
 804                 Ent_Remove();
 805         remove(self);
 806 }
 807
 808 void Gamemode_Init()
 809 {
 810         if not(isdemo())
 811         {
 812                 if(!(calledhooks & HOOK_START))
 813                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 814                 calledhooks |= HOOK_START;
 815         }
 816 }
 817 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 818 void CSQC_Parse_StuffCmd(string strMessage)
 819 {
 820         localcmd(strMessage);
 821 }
 822 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 823 void CSQC_Parse_Print(string strMessage)
 824 {
 825         print(ColorTranslateRGB(strMessage));
 826 }
 827
 828 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 829 void CSQC_Parse_CenterPrint(string strMessage)
 830 {
 831         centerprint_hud(strMessage);
 832 }
 833
 834 string notranslate_fogcmd1 = "\nfog ";
 835 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 836 void Fog_Force()
 837 {
 838         // TODO somehow thwart prvm_globalset client ...
 839
 840         if(forcefog != "")
 841                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 842 }
 843
 844 void Gamemode_Init();
 845 void Ent_ScoresInfo()
 846 {
 847         float i;
 848         self.classname = "ent_client_scores_info";
 849         gametype = ReadInt24_t();
 850         for(i = 0; i < MAX_SCORE; ++i)
 851         {
 852                 scores_label[i] = strzone(ReadString());
 853                 scores_flags[i] = ReadByte();
 854         }
 855         for(i = 0; i < MAX_TEAMSCORE; ++i)
 856         {
 857                 teamscores_label[i] = strzone(ReadString());
 858                 teamscores_flags[i] = ReadByte();
 859         }
 860         HUD_InitScores();
 861         Gamemode_Init();
 862 }
 863
 864 void Ent_Init()
 865 {
 866         self.classname = "ent_client_init";
 867
 868         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 869
 870         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 871         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 872         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 873         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 874         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 875         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 876         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 877         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 878         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 879         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 880         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 881         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 882
 883         if(forcefog)
 884                 strunzone(forcefog);
 885         forcefog = strzone(ReadString());
 886
 887         armorblockpercent = ReadByte() / 255.0;
 888
 889         g_weaponswitchdelay = ReadByte() / 255.0;
 890
 891         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 892         g_balance_grenadelauncher_bouncestop = ReadCoord();
 893         g_balance_electro_secondary_bouncefactor = ReadCoord();
 894         g_balance_electro_secondary_bouncestop = ReadCoord();
 895
 896         nex_scope = !ReadByte();
 897         rifle_scope = !ReadByte();
 898
 899         serverflags = ReadByte();
 900
 901         minelayer_maxmines = ReadByte();
 902
 903         hagar_maxrockets = ReadByte();
 904
 905         g_trueaim_minrange = ReadCoord();
 906         g_balance_porto_secondary = ReadByte();
 907
 908         if(!postinit)
 909                 PostInit();
 910 }
 911
 912 void Net_ReadRace()
 913 {
 914         float b;
 915
 916         b = ReadByte();
 917
 918         switch(b)
 919         {
 920                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 921                         race_checkpoint = ReadByte();
 922                         race_time = ReadInt24_t();
 923                         race_previousbesttime = ReadInt24_t();
 924                         if(race_previousbestname)
 925                                 strunzone(race_previousbestname);
 926                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 927
 928                         race_checkpointtime = time;
 929
 930                         if(race_checkpoint == 0 || race_checkpoint == 254)
 931                         {
 932                                 race_penaltyaccumulator = 0;
 933                                 race_laptime = time; // valid
 934                         }
 935
 936                         break;
 937
 938                 case RACE_NET_CHECKPOINT_CLEAR:
 939                         race_laptime = 0;
 940                         race_checkpointtime = 0;
 941                         break;
 942
 943                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 944                         race_laptime = ReadCoord();
 945                         race_checkpointtime = -99999;
 946                         // fall through
 947                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 948                         race_nextcheckpoint = ReadByte();
 949
 950                         race_nextbesttime = ReadInt24_t();
 951                         if(race_nextbestname)
 952                                 strunzone(race_nextbestname);
 953                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 954                         break;
 955
 956                 case RACE_NET_CHECKPOINT_HIT_RACE:
 957                         race_mycheckpoint = ReadByte();
 958                         race_mycheckpointtime = time;
 959                         race_mycheckpointdelta = ReadInt24_t();
 960                         race_mycheckpointlapsdelta = ReadByte();
 961                         if(race_mycheckpointlapsdelta >= 128)
 962                                 race_mycheckpointlapsdelta -= 256;
 963                         if(race_mycheckpointenemy)
 964                                 strunzone(race_mycheckpointenemy);
 965                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 966                         break;
 967
 968                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
 969                         race_othercheckpoint = ReadByte();
 970                         race_othercheckpointtime = time;
 971                         race_othercheckpointdelta = ReadInt24_t();
 972                         race_othercheckpointlapsdelta = ReadByte();
 973                         if(race_othercheckpointlapsdelta >= 128)
 974                                 race_othercheckpointlapsdelta -= 256;
 975                         if(race_othercheckpointenemy)
 976                                 strunzone(race_othercheckpointenemy);
 977                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 978                         break;
 979
 980                 case RACE_NET_PENALTY_RACE:
 981                         race_penaltyeventtime = time;
 982                         race_penaltytime = ReadShort();
 983                         //race_penaltyaccumulator += race_penaltytime;
 984                         if(race_penaltyreason)
 985                                 strunzone(race_penaltyreason);
 986                         race_penaltyreason = strzone(ReadString());
 987                         break;
 988
 989                 case RACE_NET_PENALTY_QUALIFYING:
 990                         race_penaltyeventtime = time;
 991                         race_penaltytime = ReadShort();
 992                         race_penaltyaccumulator += race_penaltytime;
 993                         if(race_penaltyreason)
 994                                 strunzone(race_penaltyreason);
 995                         race_penaltyreason = strzone(ReadString());
 996                         break;
 997
 998                 case RACE_NET_SERVER_RECORD:
 999                         race_server_record = ReadInt24_t();
1000                         break;
1001                 case RACE_NET_SPEED_AWARD:
1002                         race_speedaward = ReadInt24_t();
1003                         if(race_speedaward_holder)
1004                                 strunzone(race_speedaward_holder);
1005                         race_speedaward_holder = strzone(ReadString());
1006                         break;
1007                 case RACE_NET_SPEED_AWARD_BEST:
1008                         race_speedaward_alltimebest = ReadInt24_t();
1009                         if(race_speedaward_alltimebest_holder)
1010                                 strunzone(race_speedaward_alltimebest_holder);
1011                         race_speedaward_alltimebest_holder = strzone(ReadString());
1012                         break;
1013                 case RACE_NET_SERVER_RANKINGS:
1014                         float pos, prevpos, del;
1015                         pos = ReadShort();
1016                         prevpos = ReadShort();
1017                         del = ReadShort();
1018
1019                         // move other rankings out of the way
1020                         float i;
1021                         if (prevpos) {
1022                                 for (i=prevpos-1;i>pos-1;--i) {
1023                                         grecordtime[i] = grecordtime[i-1];
1024                                         if(grecordholder[i])
1025                                                 strunzone(grecordholder[i]);
1026                                         grecordholder[i] = strzone(grecordholder[i-1]);
1027                                 }
1028                         } else if (del) { // a record has been deleted by the admin
1029                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1030                                         if (i == RANKINGS_CNT-1) { // clear out last record
1031                                                 grecordtime[i] = 0;
1032                                                 if (grecordholder[i])
1033                                                         strunzone(grecordholder[i]);
1034                                                 grecordholder[i] = string_null;
1035                                         }
1036                                         else {
1037                                                 grecordtime[i] = grecordtime[i+1];
1038                                                 if (grecordholder[i])
1039                                                         strunzone(grecordholder[i]);
1040                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1041                                         }
1042                                 }
1043                         } else { // player has no ranked record yet
1044                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1045                                         grecordtime[i] = grecordtime[i-1];
1046                                         if(grecordholder[i])
1047                                                 strunzone(grecordholder[i]);
1048                                         grecordholder[i] = strzone(grecordholder[i-1]);
1049                                 }
1050                         }
1051
1052                         // store new ranking
1053                         if(grecordholder[pos-1] != "")
1054                                 strunzone(grecordholder[pos-1]);
1055                         grecordholder[pos-1] = strzone(ReadString());
1056                         grecordtime[pos-1] = ReadInt24_t();
1057                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1058                                 race_myrank = pos;
1059                         break;
1060                 case RACE_NET_SERVER_STATUS:
1061                         race_status = ReadShort();
1062                         if(race_status_name)
1063                                 strunzone(race_status_name);
1064                         race_status_name = strzone(ReadString());
1065         }
1066 }
1067
1068 void Net_ReadSpawn()
1069 {
1070         zoomin_effect = 1;
1071         current_viewzoom = 0.6;
1072 }
1073
1074 void Net_TeamNagger()
1075 {
1076         teamnagger = 1;
1077 }
1078
1079 void Net_ReadPingPLReport()
1080 {
1081         float e, pi, pl, ml;
1082         e = ReadByte();
1083         pi = ReadShort();
1084         pl = ReadByte();
1085         ml = ReadByte();
1086         if not(playerslots[e])
1087                 return;
1088         playerslots[e].ping = pi;
1089         playerslots[e].ping_packetloss = pl / 255.0;
1090         playerslots[e].ping_movementloss = ml / 255.0;
1091 }
1092
1093 void Net_WeaponComplain() {
1094         complain_weapon = ReadByte();
1095
1096         if(complain_weapon_name)
1097                 strunzone(complain_weapon_name);
1098         complain_weapon_name = strzone(ReadString());
1099
1100         complain_weapon_type = ReadByte();
1101
1102         complain_weapon_time = time;
1103         weapontime = time; // ping the weapon panel
1104 }
1105
1106 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1107 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1108 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1109 float CSQC_Parse_TempEntity()
1110 {
1111         float bHandled;
1112                 bHandled  = true;
1113         // Acquire TE ID
1114         float nTEID;
1115                 nTEID = ReadByte();
1116
1117                 // NOTE: Could just do return instead of break...
1118         switch(nTEID)
1119         {
1120                 case TE_CSQC_TARGET_MUSIC:
1121                         Net_TargetMusic();
1122                         bHandled = true;
1123                         break;
1124                 case TE_CSQC_PICTURE:
1125                         Net_MapVote_Picture();
1126                         bHandled = true;
1127                         break;
1128                 case TE_CSQC_RACE:
1129                         Net_ReadRace();
1130                         bHandled = true;
1131                         break;
1132                 case TE_CSQC_SPAWN:
1133                         Net_ReadSpawn();
1134                         bHandled = true;
1135                         break;
1136                 case TE_CSQC_ZCURVEPARTICLES:
1137                         Net_ReadZCurveParticles();
1138                         bHandled = true;
1139                         break;
1140                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1141                         Net_ReadNexgunBeamParticle();
1142                         bHandled = true;
1143                         break;
1144                 case TE_CSQC_TEAMNAGGER:
1145                         Net_TeamNagger();
1146                         bHandled = true;
1147                         break;
1148                 case TE_CSQC_LIGHTNINGARC:
1149                         Net_ReadLightningarc();
1150                         bHandled = true;
1151                         break;
1152                 case TE_CSQC_PINGPLREPORT:
1153                         Net_ReadPingPLReport();
1154                         bHandled = true;
1155                         break;
1156                 case TE_CSQC_ANNOUNCE:
1157                         Announcer_Play(ReadString());
1158                         bHandled = true;
1159                         break;
1160                 case TE_CSQC_KILLNOTIFY:
1161                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1162                         bHandled = true;
1163                         break;
1164                 case TE_CSQC_KILLCENTERPRINT:
1165                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1166                         bHandled = true;
1167                         break;
1168                 case TE_CSQC_CENTERPRINT_GENERIC:
1169                         float id;
1170                         string s;
1171                         id = ReadByte();
1172                         s = ReadString();
1173                         if (id != 0 && s != "")
1174                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1175                         else
1176                                 centerprint_generic(id, s, 0, 0);
1177                         bHandled = true;
1178                         break;
1179                 case TE_CSQC_WEAPONCOMPLAIN:
1180                         Net_WeaponComplain();
1181                         bHandled = true;
1182                         break;
1183                 case TE_CSQC_VEHICLESETUP:
1184                         Net_VehicleSetup();
1185                         bHandled = true;
1186                         break;
1187                 case TE_CSQC_SVNOTICE:
1188                         cl_notice_read();
1189                         bHandled = true;
1190                         break;
1191                 case TE_CSQC_NOTIFICATION:
1192                         Read_Notification();
1193                         bHandled = true;
1194                         break;
1195                 default:
1196                         // No special logic for this temporary entity; return 0 so the engine can handle it
1197                         bHandled = false;
1198                         break;
1199         }
1200
1201         return bHandled;
1202 }
1203
1204 string getcommandkey(string text, string command)
1205 {
1206         string keys;
1207         float n, j, k, l;
1208
1209         if (!autocvar_hud_showbinds)
1210                 return text;
1211
1212         keys = db_get(binddb, command);
1213         if (!keys)
1214         {
1215                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1216                 for(j = 0; j < n; ++j)
1217                 {
1218                         k = stof(argv(j));
1219                         if(k != -1)
1220                         {
1221                                 if ("" == keys)
1222                                         keys = keynumtostring(k);
1223                                 else
1224                                         keys = strcat(keys, ", ", keynumtostring(k));
1225
1226                                 ++l;
1227                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1228                         }
1229
1230                 }
1231                 db_put(binddb, command, keys);
1232         }
1233
1234         if ("" == keys) {
1235                 if (autocvar_hud_showbinds > 1)
1236                         return sprintf(_("%s (not bound)"), text);
1237                 else
1238                         return text;
1239         }
1240         else if (autocvar_hud_showbinds > 1)
1241                 return sprintf(_("%s (%s)"), text, keys);
1242         else
1243                 return keys;
1244 }