qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = func_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(COLOR_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157
 158         WaypointSprite_Load();
 159
 160         // precaches
 161         precache_model("null");
 162         precache_sound("misc/hit.wav");
 163         precache_sound("misc/typehit.wav");
 164         if (autocvar_cl_precacheplayermodels)
 165         {
 166                 precache_all_playermodels("models/player/*.zym");
 167                 precache_all_playermodels("models/player/*.dpm");
 168                 precache_all_playermodels("models/player/*.md3");
 169                 precache_all_playermodels("models/player/*.psk");
 170                 precache_all_playermodels("models/player/*.iqm");
 171         }
 172
 173         Projectile_Precache();
 174         Hook_Precache();
 175         GibSplash_Precache();
 176         Casings_Precache();
 177         DamageInfo_Precache();
 178         Vehicles_Precache();
 179         turrets_precache();
 180     Announcer_Precache();
 181         Tuba_Precache();
 182         CSQCPlayer_Precache();
 183
 184         if(autocvar_cl_reticle)
 185         {
 186                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 187                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 188         }
 189
 190         get_mi_min_max_texcoords(1); // try the CLEVER way first
 191         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 192         shortmapname = mi_shortname;
 193
 194         if(precache_pic(minimapname) == "")
 195         {
 196                 // but maybe we have a non-clever minimap
 197                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 198                 if(precache_pic(minimapname) == "")
 199                         minimapname = ""; // FAIL
 200                 else
 201                         get_mi_min_max_texcoords(0); // load new texcoords
 202         }
 203
 204         mi_center = (mi_min + mi_max) * 0.5;
 205         mi_scale = mi_max - mi_min;
 206         minimapname = strzone(minimapname);
 207
 208         WarpZone_Init();
 209
 210         hud_configure_prev = -1;
 211         tab_panel = -1;
 212
 213         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 214 }
 215
 216 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 217 void Shutdown(void)
 218 {
 219 #ifdef USE_FTE
 220 #pragma TARGET id
 221         if(!__engine_check)
 222                 return 0;
 223 #pragma TARGET fte
 224 #endif
 225
 226         WarpZone_Shutdown();
 227
 228         remove(teams);
 229         remove(players);
 230         db_close(binddb);
 231         db_close(tempdb);
 232         if(autocvar_cl_db_saveasdump)
 233                 db_dump(ClientProgsDB, "client.db");
 234         else
 235                 db_save(ClientProgsDB, "client.db");
 236         db_close(ClientProgsDB);
 237
 238         if(camera_active)
 239                 cvar_set("chase_active",ftos(chase_active_backup));
 240
 241         // unset the event chasecam's chase_active
 242         if(autocvar_chase_active < 0)
 243                 cvar_set("chase_active", "0");
 244
 245         if not(isdemo())
 246         {
 247                 if not(calledhooks & HOOK_START)
 248                         localcmd("\n_cl_hook_gamestart nop\n");
 249                 if not(calledhooks & HOOK_END)
 250                         localcmd("\ncl_hook_gameend\n");
 251         }
 252 }
 253
 254 .float has_team;
 255 float SetTeam(entity o, float Team)
 256 {
 257         entity tm;
 258         if(teamplay)
 259         {
 260                 switch(Team)
 261                 {
 262                         case -1:
 263                         case COLOR_TEAM1:
 264                         case COLOR_TEAM2:
 265                         case COLOR_TEAM3:
 266                         case COLOR_TEAM4:
 267                                 break;
 268                         default:
 269                                 if(GetTeam(Team, false) == world)
 270                                 {
 271                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 272                                         Team = COLOR_SPECTATOR;
 273                                 }
 274                                 break;
 275                 }
 276         }
 277         else
 278         {
 279                 switch(Team)
 280                 {
 281                         case -1:
 282                         case 0:
 283                                 break;
 284                         default:
 285                                 if(GetTeam(Team, false) == world)
 286                                 {
 287                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 288                                         Team = COLOR_SPECTATOR;
 289                                 }
 290                                 break;
 291                 }
 292         }
 293         if(Team == -1) // leave
 294         {
 295                 if(o.has_team)
 296                 {
 297                         tm = GetTeam(o.team, false);
 298                         tm.team_size -= 1;
 299                         o.has_team = 0;
 300                         return TRUE;
 301                 }
 302         }
 303         else
 304         {
 305                 if not(o.has_team)
 306                 {
 307                         o.team = Team;
 308                         tm = GetTeam(Team, true);
 309                         tm.team_size += 1;
 310                         o.has_team = 1;
 311                         return TRUE;
 312                 }
 313                 else if(Team != o.team)
 314                 {
 315                         tm = GetTeam(o.team, false);
 316                         tm.team_size -= 1;
 317                         o.team = Team;
 318                         tm = GetTeam(Team, true);
 319                         tm.team_size += 1;
 320                         return TRUE;
 321                 }
 322         }
 323         return FALSE;
 324 }
 325
 326 void Playerchecker_Think()
 327 {
 328         float i;
 329         entity e;
 330         for(i = 0; i < maxclients; ++i)
 331         {
 332                 e = playerslots[i];
 333                 if(GetPlayerName(i) == "")
 334                 {
 335                         if(e.sort_prev)
 336                         {
 337                                 // player disconnected
 338                                 SetTeam(e, -1);
 339                                 RemovePlayer(e);
 340                                 e.sort_prev = world;
 341                                 //e.gotscores = 0;
 342                         }
 343                 }
 344                 else
 345                 {
 346                         if not(e.sort_prev)
 347                         {
 348                                 // player connected
 349                                 if not(e)
 350                                         playerslots[i] = e = spawn();
 351                                 e.sv_entnum = i;
 352                                 e.ping = 0;
 353                                 e.ping_packetloss = 0;
 354                                 e.ping_movementloss = 0;
 355                                 //e.gotscores = 0; // we might already have the scores...
 356                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 357                                 RegisterPlayer(e);
 358                                 HUD_UpdatePlayerPos(e);
 359                         }
 360                 }
 361         }
 362         self.nextthink = time + 0.2;
 363 }
 364
 365 void Porto_Init();
 366 void TrueAim_Init();
 367 void PostInit(void)
 368 {
 369         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 370
 371         entity playerchecker;
 372         playerchecker = spawn();
 373         playerchecker.think = Playerchecker_Think;
 374         playerchecker.nextthink = time + 0.2;
 375
 376         Porto_Init();
 377         TrueAim_Init();
 378
 379         postinit = true;
 380 }
 381
 382 float button_zoom;
 383
 384 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 385 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 386 // All keys are in ascii.
 387 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 388 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 389 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 390 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 391 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 392 {
 393         float bSkipKey;
 394         bSkipKey = false;
 395
 396         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 397                 return true;
 398
 399         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 400                 return true;
 401
 402         if(menu_visible && menu_action)
 403                 if(menu_action(bInputType, nPrimary, nSecondary))
 404                         return TRUE;
 405
 406         return bSkipKey;
 407 }
 408
 409 // END REQUIRED CSQC FUNCTIONS
 410 // --------------------------------------------------------------------------
 411
 412 // --------------------------------------------------------------------------
 413 // BEGIN OPTIONAL CSQC FUNCTIONS
 414 void Ent_RemoveEntCS()
 415 {
 416         entcs_receiver[self.sv_entnum] = world;
 417 }
 418 void Ent_ReadEntCS()
 419 {
 420         float sf;
 421         InterpolateOrigin_Undo();
 422
 423         self.classname = "entcs_receiver";
 424         sf = ReadByte();
 425
 426         if(sf & 1)
 427                 self.sv_entnum = ReadByte();
 428         if(sf & 2)
 429         {
 430                 self.origin_x = ReadShort();
 431                 self.origin_y = ReadShort();
 432                 self.origin_z = ReadShort();
 433                 setorigin(self, self.origin);
 434         }
 435         if(sf & 4)
 436         {
 437                 self.angles_y = ReadByte() * 360.0 / 256;
 438                 self.angles_x = self.angles_z = 0;
 439         }
 440         if(sf & 8)
 441                 self.healthvalue = ReadByte() * 10;
 442         if(sf & 16)
 443                 self.armorvalue = ReadByte() * 10;
 444
 445         entcs_receiver[self.sv_entnum] = self;
 446         self.entremove = Ent_RemoveEntCS;
 447
 448         InterpolateOrigin_Note();
 449 }
 450
 451 void Ent_Remove();
 452
 453 void Ent_RemovePlayerScore()
 454 {
 455         float i;
 456
 457         if(self.owner)
 458         {
 459                 SetTeam(self.owner, -1);
 460                 self.owner.gotscores = 0;
 461                 for(i = 0; i < MAX_SCORE; ++i)
 462                         self.owner.(scores[i]) = 0; // clear all scores
 463         }
 464 }
 465
 466 void Ent_ReadPlayerScore()
 467 {
 468         float i, n;
 469         float isNew;
 470         entity o;
 471
 472         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 473         // (no I've never heard of M-x replace-string, sed, or anything like that)
 474         isNew = !self.owner; // workaround for DP bug
 475         n = ReadByte()-1;
 476
 477 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 478         if(!isNew && n != self.sv_entnum)
 479         {
 480                 //print(_("A CSQC entity changed its owner!\n"));
 481                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 482                 isNew = true;
 483                 Ent_Remove();
 484                 self.enttype = ENT_CLIENT_SCORES;
 485         }
 486 #endif
 487
 488         self.sv_entnum = n;
 489
 490         if not(playerslots[self.sv_entnum])
 491                 playerslots[self.sv_entnum] = spawn();
 492         o = self.owner = playerslots[self.sv_entnum];
 493         o.sv_entnum = self.sv_entnum;
 494         o.gotscores = 1;
 495
 496         //if not(o.sort_prev)
 497         //      RegisterPlayer(o);
 498         //playerchecker will do this for us later, if it has not already done so
 499
 500         float sf, lf;
 501 #if MAX_SCORE <= 8
 502         sf = ReadByte();
 503         lf = ReadByte();
 504 #else
 505         sf = ReadShort();
 506         lf = ReadShort();
 507 #endif
 508         float p;
 509         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 510                 if(sf & p)
 511                 {
 512                         if(lf & p)
 513                                 o.(scores[i]) = ReadInt24_t();
 514                         else
 515                                 o.(scores[i]) = ReadChar();
 516                 }
 517
 518         if(o.sort_prev)
 519                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 520
 521         self.entremove = Ent_RemovePlayerScore;
 522 }
 523
 524 void Ent_ReadTeamScore()
 525 {
 526         float i;
 527         entity o;
 528
 529         self.team = ReadByte();
 530         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 531
 532         float sf, lf;
 533 #if MAX_TEAMSCORE <= 8
 534         sf = ReadByte();
 535         lf = ReadByte();
 536 #else
 537         sf = ReadShort();
 538         lf = ReadShort();
 539 #endif
 540         float p;
 541         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 542                 if(sf & p)
 543                 {
 544                         if(lf & p)
 545                                 o.(teamscores[i]) = ReadInt24_t();
 546                         else
 547                                 o.(teamscores[i]) = ReadChar();
 548                 }
 549
 550         HUD_UpdateTeamPos(o);
 551 }
 552
 553 void Ent_ClientData()
 554 {
 555         float f;
 556         float newspectatee_status;
 557
 558         f = ReadByte();
 559
 560         scoreboard_showscores_force = (f & 1);
 561
 562         if(f & 2)
 563         {
 564                 newspectatee_status = ReadByte();
 565                 if(newspectatee_status == player_localnum + 1)
 566                         newspectatee_status = -1; // observing
 567         }
 568         else
 569                 newspectatee_status = 0;
 570
 571         spectatorbutton_zoom = (f & 4);
 572
 573         if(f & 8)
 574         {
 575                 angles_held_status = 1;
 576                 angles_held_x = ReadAngle();
 577                 angles_held_y = ReadAngle();
 578                 angles_held_z = 0;
 579         }
 580         else
 581                 angles_held_status = 0;
 582
 583         if(newspectatee_status != spectatee_status)
 584         {
 585                 // clear race stuff
 586                 race_laptime = 0;
 587                 race_checkpointtime = 0;
 588         }
 589         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 590         {
 591                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 592                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 593                 )
 594                         prev_p_health = -1;
 595                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 596                         prev_health = -1;
 597         }
 598         spectatee_status = newspectatee_status;
 599
 600         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 601 }
 602
 603 void Ent_Nagger()
 604 {
 605         float nags, i, j, b, f;
 606
 607         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 608
 609         if(!(nags & 4))
 610         {
 611                 if(vote_called_vote)
 612                         strunzone(vote_called_vote);
 613                 vote_called_vote = string_null;
 614                 vote_active = 0;
 615         }
 616         else
 617         {
 618                 vote_active = 1;
 619         }
 620
 621         if(nags & 64)
 622         {
 623                 vote_yescount = ReadByte();
 624                 vote_nocount = ReadByte();
 625                 vote_needed = ReadByte();
 626                 vote_highlighted = ReadChar();
 627         }
 628
 629         if(nags & 128)
 630         {
 631                 if(vote_called_vote)
 632                         strunzone(vote_called_vote);
 633                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 634         }
 635
 636         if(nags & 1)
 637         {
 638                 for(j = 0; j < maxclients; ++j)
 639                         if(playerslots[j])
 640                                 playerslots[j].ready = 1;
 641                 for(i = 1; i <= maxclients; i += 8)
 642                 {
 643                         f = ReadByte();
 644                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 645                                 if not(f & b)
 646                                         if(playerslots[j])
 647                                                 playerslots[j].ready = 0;
 648                 }
 649         }
 650
 651         ready_waiting = (nags & 1);
 652         ready_waiting_for_me = (nags & 2);
 653         vote_waiting = (nags & 4);
 654         vote_waiting_for_me = (nags & 8);
 655         warmup_stage = (nags & 16);
 656 }
 657
 658 void Ent_RandomSeed()
 659 {
 660         float s;
 661         prandom_debug();
 662         s = ReadShort();
 663         psrandom(s);
 664 }
 665
 666 void Ent_ReadAccuracy(void)
 667 {
 668         float sf, f, w, b;
 669         sf = ReadInt24_t();
 670         if(sf == 0)
 671         {
 672                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 673                         weapon_accuracy[w] = -1;
 674                 return;
 675         }
 676
 677         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 678         {
 679                 if(sf & f)
 680                 {
 681                         b = ReadByte();
 682                         if(b == 0)
 683                                 weapon_accuracy[w] = -1;
 684                         else if(b == 255)
 685                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 686                         else
 687                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 688                 }
 689                 if(f == 0x800000)
 690                         f = 1;
 691                 else
 692                         f *= 2;
 693         }
 694 }
 695
 696 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 697 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 698 void Ent_RadarLink();
 699 void Ent_Init();
 700 void Ent_ScoresInfo();
 701 void CSQC_Ent_Update(float bIsNewEntity)
 702 {
 703         float t;
 704         float savetime;
 705         t = ReadByte();
 706
 707         if(autocvar_developer_csqcentities)
 708                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 709
 710         // set up the "time" global for received entities to be correct for interpolation purposes
 711         savetime = time;
 712         if(servertime)
 713         {
 714                 time = servertime;
 715         }
 716         else
 717         {
 718                 serverprevtime = time;
 719                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 720                 time = serverprevtime + serverdeltatime;
 721         }
 722
 723 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 724         if(self.enttype)
 725         {
 726                 if(t != self.enttype || bIsNewEntity)
 727                 {
 728                         //print(_("A CSQC entity changed its type!\n"));
 729                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 730                         Ent_Remove();
 731                         clearentity(self);
 732                         bIsNewEntity = 1;
 733                 }
 734         }
 735         else
 736         {
 737                 if(!bIsNewEntity)
 738                 {
 739                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 740                         bIsNewEntity = 1;
 741                 }
 742         }
 743 #endif
 744         self.enttype = t;
 745         switch(t)
 746         {
 747                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 748                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 749                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 750                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 751                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 752                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 753                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 754                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 755                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 756                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 757                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 758                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 759                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 760                 case ENT_CLIENT_INIT: Ent_Init(); break;
 761                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 762                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 763                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 764                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 765                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 766                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 767                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 768                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 769                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 770                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 771                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 772                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 773                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 774                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 775                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 776                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 777                 case ENT_CLIENT_TURRET: ent_turret(); break;
 778                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 779                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 780                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 781                 default:
 782                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 783                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 784                         break;
 785         }
 786
 787         time = savetime;
 788 }
 789 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 790 // used when an entity changes its type. For an entity that someone interacts
 791 // with others, make sure it can no longer do so.
 792 void Ent_Remove()
 793 {
 794         if(self.entremove)
 795                 self.entremove();
 796
 797         if(self.skeletonindex)
 798         {
 799                 skel_delete(self.skeletonindex);
 800                 self.skeletonindex = 0;
 801         }
 802
 803         if(self.snd_looping > 0)
 804         {
 805                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 806                 self.snd_looping = 0;
 807         }
 808
 809         self.enttype = 0;
 810         self.classname = "";
 811         self.draw = menu_sub_null;
 812         self.entremove = menu_sub_null;
 813         // TODO possibly set more stuff to defaults
 814 }
 815 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 816 void CSQC_Ent_Remove()
 817 {
 818         if(autocvar_developer_csqcentities)
 819                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 820
 821         if(wasfreed(self))
 822         {
 823                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 824                 return;
 825         }
 826         if(self.enttype)
 827                 Ent_Remove();
 828         remove(self);
 829 }
 830
 831 void Gamemode_Init()
 832 {
 833         if not(isdemo())
 834         {
 835                 if(!(calledhooks & HOOK_START))
 836                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 837                 calledhooks |= HOOK_START;
 838         }
 839 }
 840 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 841 void CSQC_Parse_StuffCmd(string strMessage)
 842 {
 843         if(autocvar_developer_csqcentities)
 844                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 845
 846         localcmd(strMessage);
 847 }
 848 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 849 void CSQC_Parse_Print(string strMessage)
 850 {
 851         if(autocvar_developer_csqcentities)
 852                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 853
 854         print(ColorTranslateRGB(strMessage));
 855 }
 856
 857 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 858 void CSQC_Parse_CenterPrint(string strMessage)
 859 {
 860         if(autocvar_developer_csqcentities)
 861                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 862
 863         centerprint_hud(strMessage);
 864 }
 865
 866 string notranslate_fogcmd1 = "\nfog ";
 867 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 868 void Fog_Force()
 869 {
 870         // TODO somehow thwart prvm_globalset client ...
 871
 872         if(forcefog != "")
 873                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 874 }
 875
 876 void Gamemode_Init();
 877 void Ent_ScoresInfo()
 878 {
 879         float i;
 880         self.classname = "ent_client_scores_info";
 881         gametype = ReadInt24_t();
 882         for(i = 0; i < MAX_SCORE; ++i)
 883         {
 884                 scores_label[i] = strzone(ReadString());
 885                 scores_flags[i] = ReadByte();
 886         }
 887         for(i = 0; i < MAX_TEAMSCORE; ++i)
 888         {
 889                 teamscores_label[i] = strzone(ReadString());
 890                 teamscores_flags[i] = ReadByte();
 891         }
 892         HUD_InitScores();
 893         Gamemode_Init();
 894 }
 895
 896 void Ent_Init()
 897 {
 898         self.classname = "ent_client_init";
 899
 900         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 901
 902         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 903         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 904         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 905         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 906         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 907         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 908         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 909         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 910         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 911         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 912         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 913         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 914
 915         if(forcefog)
 916                 strunzone(forcefog);
 917         forcefog = strzone(ReadString());
 918
 919         armorblockpercent = ReadByte() / 255.0;
 920
 921         g_weaponswitchdelay = ReadByte() / 255.0;
 922
 923         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 924         g_balance_grenadelauncher_bouncestop = ReadCoord();
 925         g_balance_electro_secondary_bouncefactor = ReadCoord();
 926         g_balance_electro_secondary_bouncestop = ReadCoord();
 927
 928         nex_scope = !ReadByte();
 929         rifle_scope = !ReadByte();
 930
 931         serverflags = ReadByte();
 932
 933         minelayer_maxmines = ReadByte();
 934
 935         hagar_maxrockets = ReadByte();
 936
 937         g_trueaim_minrange = ReadCoord();
 938         g_balance_porto_secondary = ReadByte();
 939
 940         if(!postinit)
 941                 PostInit();
 942 }
 943
 944 void Net_ReadRace()
 945 {
 946         float b;
 947
 948         b = ReadByte();
 949
 950         switch(b)
 951         {
 952                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 953                         race_checkpoint = ReadByte();
 954                         race_time = ReadInt24_t();
 955                         race_previousbesttime = ReadInt24_t();
 956                         if(race_previousbestname)
 957                                 strunzone(race_previousbestname);
 958                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 959
 960                         race_checkpointtime = time;
 961
 962                         if(race_checkpoint == 0 || race_checkpoint == 254)
 963                         {
 964                                 race_penaltyaccumulator = 0;
 965                                 race_laptime = time; // valid
 966                         }
 967
 968                         break;
 969
 970                 case RACE_NET_CHECKPOINT_CLEAR:
 971                         race_laptime = 0;
 972                         race_checkpointtime = 0;
 973                         break;
 974
 975                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 976                         race_laptime = ReadCoord();
 977                         race_checkpointtime = -99999;
 978                         // fall through
 979                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 980                         race_nextcheckpoint = ReadByte();
 981
 982                         race_nextbesttime = ReadInt24_t();
 983                         if(race_nextbestname)
 984                                 strunzone(race_nextbestname);
 985                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 986                         break;
 987
 988                 case RACE_NET_CHECKPOINT_HIT_RACE:
 989                         race_mycheckpoint = ReadByte();
 990                         race_mycheckpointtime = time;
 991                         race_mycheckpointdelta = ReadInt24_t();
 992                         race_mycheckpointlapsdelta = ReadByte();
 993                         if(race_mycheckpointlapsdelta >= 128)
 994                                 race_mycheckpointlapsdelta -= 256;
 995                         if(race_mycheckpointenemy)
 996                                 strunzone(race_mycheckpointenemy);
 997                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 998                         break;
 999
1000                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1001                         race_othercheckpoint = ReadByte();
1002                         race_othercheckpointtime = time;
1003                         race_othercheckpointdelta = ReadInt24_t();
1004                         race_othercheckpointlapsdelta = ReadByte();
1005                         if(race_othercheckpointlapsdelta >= 128)
1006                                 race_othercheckpointlapsdelta -= 256;
1007                         if(race_othercheckpointenemy)
1008                                 strunzone(race_othercheckpointenemy);
1009                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1010                         break;
1011
1012                 case RACE_NET_PENALTY_RACE:
1013                         race_penaltyeventtime = time;
1014                         race_penaltytime = ReadShort();
1015                         //race_penaltyaccumulator += race_penaltytime;
1016                         if(race_penaltyreason)
1017                                 strunzone(race_penaltyreason);
1018                         race_penaltyreason = strzone(ReadString());
1019                         break;
1020
1021                 case RACE_NET_PENALTY_QUALIFYING:
1022                         race_penaltyeventtime = time;
1023                         race_penaltytime = ReadShort();
1024                         race_penaltyaccumulator += race_penaltytime;
1025                         if(race_penaltyreason)
1026                                 strunzone(race_penaltyreason);
1027                         race_penaltyreason = strzone(ReadString());
1028                         break;
1029
1030                 case RACE_NET_SERVER_RECORD:
1031                         race_server_record = ReadInt24_t();
1032                         break;
1033                 case RACE_NET_SPEED_AWARD:
1034                         race_speedaward = ReadInt24_t();
1035                         if(race_speedaward_holder)
1036                                 strunzone(race_speedaward_holder);
1037                         race_speedaward_holder = strzone(ReadString());
1038                         break;
1039                 case RACE_NET_SPEED_AWARD_BEST:
1040                         race_speedaward_alltimebest = ReadInt24_t();
1041                         if(race_speedaward_alltimebest_holder)
1042                                 strunzone(race_speedaward_alltimebest_holder);
1043                         race_speedaward_alltimebest_holder = strzone(ReadString());
1044                         break;
1045                 case RACE_NET_SERVER_RANKINGS:
1046                         float pos, prevpos, del;
1047                         pos = ReadShort();
1048                         prevpos = ReadShort();
1049                         del = ReadShort();
1050
1051                         // move other rankings out of the way
1052                         float i;
1053                         if (prevpos) {
1054                                 for (i=prevpos-1;i>pos-1;--i) {
1055                                         grecordtime[i] = grecordtime[i-1];
1056                                         if(grecordholder[i])
1057                                                 strunzone(grecordholder[i]);
1058                                         grecordholder[i] = strzone(grecordholder[i-1]);
1059                                 }
1060                         } else if (del) { // a record has been deleted by the admin
1061                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1062                                         if (i == RANKINGS_CNT-1) { // clear out last record
1063                                                 grecordtime[i] = 0;
1064                                                 if (grecordholder[i])
1065                                                         strunzone(grecordholder[i]);
1066                                                 grecordholder[i] = string_null;
1067                                         }
1068                                         else {
1069                                                 grecordtime[i] = grecordtime[i+1];
1070                                                 if (grecordholder[i])
1071                                                         strunzone(grecordholder[i]);
1072                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1073                                         }
1074                                 }
1075                         } else { // player has no ranked record yet
1076                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1077                                         grecordtime[i] = grecordtime[i-1];
1078                                         if(grecordholder[i])
1079                                                 strunzone(grecordholder[i]);
1080                                         grecordholder[i] = strzone(grecordholder[i-1]);
1081                                 }
1082                         }
1083
1084                         // store new ranking
1085                         if(grecordholder[pos-1] != "")
1086                                 strunzone(grecordholder[pos-1]);
1087                         grecordholder[pos-1] = strzone(ReadString());
1088                         grecordtime[pos-1] = ReadInt24_t();
1089                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1090                                 race_myrank = pos;
1091                         break;
1092                 case RACE_NET_SERVER_STATUS:
1093                         race_status = ReadShort();
1094                         if(race_status_name)
1095                                 strunzone(race_status_name);
1096                         race_status_name = strzone(ReadString());
1097         }
1098 }
1099
1100 void Net_ReadSpawn()
1101 {
1102         zoomin_effect = 1;
1103         current_viewzoom = 0.6;
1104 }
1105
1106 void Net_TeamNagger()
1107 {
1108         teamnagger = 1;
1109 }
1110
1111 void Net_ReadPingPLReport()
1112 {
1113         float e, pi, pl, ml;
1114         e = ReadByte();
1115         pi = ReadShort();
1116         pl = ReadByte();
1117         ml = ReadByte();
1118         if not(playerslots[e])
1119                 return;
1120         playerslots[e].ping = pi;
1121         playerslots[e].ping_packetloss = pl / 255.0;
1122         playerslots[e].ping_movementloss = ml / 255.0;
1123 }
1124
1125 void Net_WeaponComplain() {
1126         complain_weapon = ReadByte();
1127
1128         if(complain_weapon_name)
1129                 strunzone(complain_weapon_name);
1130         complain_weapon_name = strzone(ReadString());
1131
1132         complain_weapon_type = ReadByte();
1133
1134         complain_weapon_time = time;
1135         weapontime = time; // ping the weapon panel
1136 }
1137
1138 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1139 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1140 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1141 float CSQC_Parse_TempEntity()
1142 {
1143         float bHandled;
1144                 bHandled  = true;
1145         // Acquire TE ID
1146         float nTEID;
1147                 nTEID = ReadByte();
1148
1149         if(autocvar_developer_csqcentities)
1150                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1151
1152                 // NOTE: Could just do return instead of break...
1153         switch(nTEID)
1154         {
1155                 case TE_CSQC_TARGET_MUSIC:
1156                         Net_TargetMusic();
1157                         bHandled = true;
1158                         break;
1159                 case TE_CSQC_PICTURE:
1160                         Net_MapVote_Picture();
1161                         bHandled = true;
1162                         break;
1163                 case TE_CSQC_RACE:
1164                         Net_ReadRace();
1165                         bHandled = true;
1166                         break;
1167                 case TE_CSQC_SPAWN:
1168                         Net_ReadSpawn();
1169                         bHandled = true;
1170                         break;
1171                 case TE_CSQC_ZCURVEPARTICLES:
1172                         Net_ReadZCurveParticles();
1173                         bHandled = true;
1174                         break;
1175                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1176                         Net_ReadNexgunBeamParticle();
1177                         bHandled = true;
1178                         break;
1179                 case TE_CSQC_TEAMNAGGER:
1180                         Net_TeamNagger();
1181                         bHandled = true;
1182                         break;
1183                 case TE_CSQC_LIGHTNINGARC:
1184                         Net_ReadLightningarc();
1185                         bHandled = true;
1186                         break;
1187                 case TE_CSQC_PINGPLREPORT:
1188                         Net_ReadPingPLReport();
1189                         bHandled = true;
1190                         break;
1191                 case TE_CSQC_ANNOUNCE:
1192                         Announcer_Play(ReadString());
1193                         bHandled = true;
1194                         break;
1195                 case TE_CSQC_KILLNOTIFY:
1196                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1197                         bHandled = true;
1198                         break;
1199                 case TE_CSQC_KILLCENTERPRINT:
1200                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1201                         bHandled = true;
1202                         break;
1203                 case TE_CSQC_CENTERPRINT_GENERIC:
1204                         float id;
1205                         string s;
1206                         id = ReadByte();
1207                         s = ReadString();
1208                         if (id != 0 && s != "")
1209                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1210                         else
1211                                 centerprint_generic(id, s, 0, 0);
1212                         bHandled = true;
1213                         break;
1214                 case TE_CSQC_WEAPONCOMPLAIN:
1215                         Net_WeaponComplain();
1216                         bHandled = true;
1217                         break;
1218                 case TE_CSQC_VEHICLESETUP:
1219                         Net_VehicleSetup();
1220                         bHandled = true;
1221                         break;
1222                 case TE_CSQC_SVNOTICE:
1223                         cl_notice_read();
1224                         bHandled = true;
1225                         break;
1226                 default:
1227                         // No special logic for this temporary entity; return 0 so the engine can handle it
1228                         bHandled = false;
1229                         break;
1230         }
1231
1232         return bHandled;
1233 }
1234
1235 string getcommandkey(string text, string command)
1236 {
1237         string keys;
1238         float n, j, k, l = 0;
1239
1240         if (!autocvar_hud_showbinds)
1241                 return text;
1242
1243         keys = db_get(binddb, command);
1244         if (keys == "")
1245         {
1246                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1247                 for(j = 0; j < n; ++j)
1248                 {
1249                         k = stof(argv(j));
1250                         if(k != -1)
1251                         {
1252                                 if ("" == keys)
1253                                         keys = keynumtostring(k);
1254                                 else
1255                                         keys = strcat(keys, ", ", keynumtostring(k));
1256
1257                                 ++l;
1258                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1259                                         break;
1260                         }
1261
1262                 }
1263                 if (keys == "")
1264                         keys = "NO_KEY";
1265                 db_put(binddb, command, keys);
1266         }
1267
1268         if (keys == "NO_KEY") {
1269                 if (autocvar_hud_showbinds > 1)
1270                         return sprintf(_("%s (not bound)"), text);
1271                 else
1272                         return text;
1273         }
1274         else if (autocvar_hud_showbinds > 1)
1275                 return sprintf(_("%s (%s)"), text, keys);
1276         else
1277                 return keys;
1278 }