qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63 #ifdef WATERMARK
  64         print("^4CSQC Build information: ", WATERMARK(), "\n");
  65 #endif
  66
  67         float i;
  68
  69         binddb = db_create();
  70         tempdb = db_create();
  71         ClientProgsDB = db_load("client.db");
  72         compressShortVector_init();
  73
  74         drawfont = FONT_USER+1;
  75         menu_visible = FALSE;
  76         menu_show = menu_show_error;
  77         menu_action = menu_sub_null;
  78
  79         for(i = 0; i < 255; ++i)
  80                 if(getplayerkey(i, "viewentity") == "")
  81                         break;
  82         maxclients = i;
  83
  84         //ctf_temp_1 = "";
  85         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  86         //registercmd("ctf_menu");
  87         registercmd("ons_map");
  88         registercmd("hud_configure");
  89         registercmd("hud_save");
  90         //registercmd("menu_action");
  91
  92         registercmd("+button3");
  93         registercmd("-button3");
  94         registercmd("+button4");
  95         registercmd("-button4");
  96         registercmd("+showscores");registercmd("-showscores");
  97         registercmd("+showaccuracy");registercmd("-showaccuracy");
  98
  99 #ifndef CAMERATEST
 100         if(isdemo())
 101         {
 102 #endif
 103                 registercmd("+forward");registercmd("-forward");
 104                 registercmd("+back");registercmd("-back");
 105                 registercmd("+moveup");registercmd("-moveup");
 106                 registercmd("+movedown");registercmd("-movedown");
 107                 registercmd("+moveright");registercmd("-moveright");
 108                 registercmd("+moveleft");registercmd("-moveleft");
 109                 registercmd("+roll_right");registercmd("-roll_right");
 110                 registercmd("+roll_left");registercmd("-roll_left");
 111 #ifndef CAMERATEST
 112         }
 113 #endif
 114         registercvar("hud_usecsqc", "1");
 115         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 116
 117         gametype = 0;
 118
 119         // hud_fields uses strunzone on the titles!
 120         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 121                 hud_title[i] = strzone("(null)");
 122
 123         postinit = false;
 124
 125         calledhooks = 0;
 126
 127         teams = Sort_Spawn();
 128         players = Sort_Spawn();
 129
 130         GetTeam(COLOR_SPECTATOR, true); // add specs first
 131
 132         RegisterWeapons();
 133
 134         WaypointSprite_Load();
 135
 136         // precaches
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         if(autocvar_cl_announcer != cl_announcer_prev) {
 143                 Announcer_Precache();
 144                 if(cl_announcer_prev)
 145                         strunzone(cl_announcer_prev);
 146                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 147         }
 148         Tuba_Precache();
 149
 150         get_mi_min_max_texcoords(1); // try the CLEVER way first
 151         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 152         shortmapname = mi_shortname;
 153
 154         if(precache_pic(minimapname) == "")
 155         {
 156                 // but maybe we have a non-clever minimap
 157                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 158                 if(precache_pic(minimapname) == "")
 159                         minimapname = ""; // FAIL
 160                 else
 161                         get_mi_min_max_texcoords(0); // load new texcoords
 162         }
 163
 164         mi_center = (mi_min + mi_max) * 0.5;
 165         mi_scale = mi_max - mi_min;
 166         minimapname = strzone(minimapname);
 167
 168         WarpZone_Init();
 169         hud_configure_prev = -1;
 170 }
 171
 172 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 173 void CSQC_Shutdown(void)
 174 {
 175 #ifdef USE_FTE
 176 #pragma TARGET id
 177         if(!__engine_check)
 178                 return 0;
 179 #pragma TARGET fte
 180 #endif
 181
 182         WarpZone_Shutdown();
 183
 184         remove(teams);
 185         remove(players);
 186         db_close(binddb);
 187         db_close(tempdb);
 188         if(autocvar_cl_db_saveasdump)
 189                 db_dump(ClientProgsDB, "client.db");
 190         else
 191                 db_save(ClientProgsDB, "client.db");
 192         db_close(ClientProgsDB);
 193
 194         cvar_clientsettemp_restore();
 195
 196         if(camera_active)
 197                 cvar_set("chase_active",ftos(chase_active_backup));
 198
 199         if not(isdemo())
 200         {
 201                 if not(calledhooks & HOOK_START)
 202                         localcmd("\n_cl_hook_gamestart nop\n");
 203                 if not(calledhooks & HOOK_END)
 204                         localcmd("\ncl_hook_gameend\n");
 205         }
 206 }
 207
 208 .float has_team;
 209 float SetTeam(entity o, float Team)
 210 {
 211         entity tm;
 212         if(teamplay)
 213         {
 214                 switch(Team)
 215                 {
 216                         case -1:
 217                         case COLOR_TEAM1:
 218                         case COLOR_TEAM2:
 219                         case COLOR_TEAM3:
 220                         case COLOR_TEAM4:
 221                                 break;
 222                         default:
 223                                 if(GetTeam(Team, false) == NULL)
 224                                 {
 225                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 226                                         Team = COLOR_SPECTATOR;
 227                                 }
 228                                 break;
 229                 }
 230         }
 231         else
 232         {
 233                 switch(Team)
 234                 {
 235                         case -1:
 236                         case 0:
 237                                 break;
 238                         default:
 239                                 if(GetTeam(Team, false) == NULL)
 240                                 {
 241                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 242                                         Team = COLOR_SPECTATOR;
 243                                 }
 244                                 break;
 245                 }
 246         }
 247         if(Team == -1) // leave
 248         {
 249                 if(o.has_team)
 250                 {
 251                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 252                         tm = GetTeam(o.team, false);
 253                         tm.team_size -= 1;
 254                         o.has_team = 0;
 255                         return TRUE;
 256                 }
 257         }
 258         else
 259         {
 260                 if not(o.has_team)
 261                 {
 262                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 263                         o.team = Team;
 264                         tm = GetTeam(Team, true);
 265                         tm.team_size += 1;
 266                         o.has_team = 1;
 267                         return TRUE;
 268                 }
 269                 else if(Team != o.team)
 270                 {
 271                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 272                         tm = GetTeam(o.team, false);
 273                         tm.team_size -= 1;
 274                         o.team = Team;
 275                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 276                         tm = GetTeam(Team, true);
 277                         tm.team_size += 1;
 278                         return TRUE;
 279                 }
 280         }
 281         return FALSE;
 282 }
 283
 284 void Playerchecker_Think()
 285 {
 286         float i;
 287         entity e;
 288         for(i = 0; i < maxclients; ++i)
 289         {
 290                 e = playerslots[i];
 291                 if(GetPlayerName(i) == "")
 292                 {
 293                         if(e.sort_prev)
 294                         {
 295                                 //print("playerchecker: KILL KILL KILL\n");
 296                                 // player disconnected
 297                                 SetTeam(e, -1);
 298                                 RemovePlayer(e);
 299                                 e.sort_prev = world;
 300                                 //e.gotscores = 0;
 301                         }
 302                 }
 303                 else
 304                 {
 305                         if not(e.sort_prev)
 306                         {
 307                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 308                                 // player connected
 309                                 if not(e)
 310                                         playerslots[i] = e = spawn();
 311                                 e.sv_entnum = i;
 312                                 e.ping = 0;
 313                                 e.ping_packetloss = 0;
 314                                 e.ping_movementloss = 0;
 315                                 //e.gotscores = 0; // we might already have the scores...
 316                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 317                                 RegisterPlayer(e);
 318                                 HUD_UpdatePlayerPos(e);
 319                         }
 320                 }
 321         }
 322         self.nextthink = time + 0.2;
 323 }
 324
 325 void Porto_Init();
 326 void TrueAim_Init();
 327 void PostInit(void)
 328 {
 329         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 330         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 331
 332         entity playerchecker;
 333         playerchecker = spawn();
 334         playerchecker.think = Playerchecker_Think;
 335         playerchecker.nextthink = time + 0.2;
 336
 337         Porto_Init();
 338         TrueAim_Init();
 339
 340         postinit = true;
 341 }
 342
 343 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 344 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 345 float button_zoom;
 346 void Cmd_HUD_SetFields(float);
 347 void Cmd_HUD_Help(float);
 348 float CSQC_ConsoleCommand(string strMessage)
 349 {
 350         float argc;
 351         // Tokenize String
 352         //argc = tokenize(strMessage);
 353         argc = tokenize_console(strMessage);
 354
 355         // Acquire Command
 356         local string strCmd;
 357         strCmd = argv(0);
 358
 359         if(strCmd == "hud_configure") { // config hud
 360                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 361                 return true;
 362         } else if(strCmd == "hud_save") { // save hud config
 363                 if(argv(1) == "" || argv(2)) {
 364                         print("Usage:\n");
 365                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
 366                 }
 367                 else
 368                         HUD_Panel_ExportCfg(argv(1));
 369                 return true;
 370         } else if(strCmd == "+button4") { // zoom
 371                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 372                 if(ignore_plus_zoom)
 373                 {
 374                         --ignore_plus_zoom;
 375                         return false;
 376                 }
 377                 button_zoom = 1;
 378                 return true;
 379         } else if(strCmd == "-button4") { // zoom
 380                 if(ignore_minus_zoom)
 381                 {
 382                         --ignore_minus_zoom;
 383                         return false;
 384                 }
 385                 button_zoom = 0;
 386                 return true;
 387         } else if(strCmd == "+button3") { // secondary
 388                 button_attack2 = 1;
 389                 return false;
 390         } else if(strCmd == "-button3") { // secondary
 391                 button_attack2 = 0;
 392                 return false;
 393         } else if(strCmd == "+showscores") {
 394                 scoreboard_showscores = true;
 395                 return true;
 396         } else if(strCmd == "-showscores") {
 397                 scoreboard_showscores = false;
 398                 return true;
 399         } else if(strCmd == "+showaccuracy") {
 400                 scoreboard_showaccuracy = true;
 401                 return true;
 402         } else if(strCmd == "-showaccuracy") {
 403                 scoreboard_showaccuracy = false;
 404                 return true;
 405         }
 406
 407         if(camera_active)
 408         if(strCmd == "+forward" || strCmd == "-back") {
 409                 ++camera_direction_x;
 410                 return true;
 411         } else if(strCmd == "-forward" || strCmd == "+back") {
 412                 --camera_direction_x;
 413                 return true;
 414         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 415                 --camera_direction_y;
 416                 return true;
 417         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 418                 ++camera_direction_y;
 419                 return true;
 420         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 421                 ++camera_direction_z;
 422                 return true;
 423         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 424                 --camera_direction_z;
 425                 return true;
 426         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 427                 ++camera_roll;
 428                 return true;
 429         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 430                 --camera_roll;
 431                 return true;
 432         }
 433
 434         return false;
 435 }
 436
 437 .vector view_ofs;
 438 entity debug_shotorg;
 439 void ShotOrg_Draw()
 440 {
 441         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 442         self.angles = view_angles;
 443         self.angles_x = -self.angles_x;
 444         if not(self.cnt)
 445                 self.drawmask = MASK_NORMAL;
 446         else
 447                 self.drawmask = 0;
 448 }
 449 void ShotOrg_Draw2D()
 450 {
 451         vector coord2d_topleft, coord2d_topright, coord2d;
 452         string s;
 453         vector fs;
 454
 455         s = vtos(self.view_ofs);
 456         s = substring(s, 1, strlen(s) - 2);
 457         if(tokenize_console(s) == 3)
 458                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 459
 460         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 461         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 462
 463         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 464
 465         coord2d = coord2d_topleft;
 466         if(fs_x < 8)
 467         {
 468                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 469                 fs = '8 8 0';
 470         }
 471         coord2d_y -= fs_y;
 472         coord2d_z = 0;
 473         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 474 }
 475
 476 void ShotOrg_Spawn()
 477 {
 478         debug_shotorg = spawn();
 479         debug_shotorg.draw = ShotOrg_Draw;
 480         debug_shotorg.draw2d = ShotOrg_Draw2D;
 481         debug_shotorg.renderflags = RF_VIEWMODEL;
 482         debug_shotorg.effects = EF_FULLBRIGHT;
 483         precache_model("models/shotorg_adjuster.md3");
 484         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 485         debug_shotorg.scale = 2;
 486         debug_shotorg.view_ofs = '25 8 -8';
 487 }
 488
 489 void DrawDebugModel()
 490 {
 491         if(time - floor(time) > 0.5)
 492         {
 493                 PolyDrawModel(self);
 494                 self.drawmask = 0;
 495         }
 496         else
 497         {
 498                 self.renderflags = 0;
 499                 self.drawmask = MASK_NORMAL;
 500         }
 501 }
 502
 503 void GameCommand(string msg)
 504 {
 505         string s;
 506         float argc;
 507         entity e;
 508         argc = tokenize_console(msg);
 509
 510         if(argv(0) == "help" || argc == 0)
 511         {
 512                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 513                 print("  settemp cvar value\n");
 514                 print("  scoreboard_columns_set ...\n");
 515                 print("  scoreboard_columns_help\n");
 516                 GameCommand_Generic("help");
 517                 return;
 518         }
 519
 520         if(GameCommand_Generic(msg))
 521                 return;
 522
 523         string cmd;
 524         cmd = argv(0);
 525         if(cmd == "mv_download") {
 526                 Cmd_MapVote_MapDownload(argc);
 527         }
 528         else if(cmd == "settemp") {
 529                 cvar_clientsettemp(argv(1), argv(2));
 530         }
 531         else if(cmd == "scoreboard_columns_set") {
 532                 Cmd_HUD_SetFields(argc);
 533         }
 534         else if(cmd == "scoreboard_columns_help") {
 535                 Cmd_HUD_Help(argc);
 536         }
 537 #ifdef BLURTEST
 538         else if(cmd == "blurtest") {
 539                 blurtest_time0 = time;
 540                 blurtest_time1 = time + stof(argv(1));
 541                 blurtest_radius = stof(argv(2));
 542                 blurtest_power = stof(argv(3));
 543         }
 544 #endif
 545         else if(cmd == "shotorg_move") {
 546                 if(!debug_shotorg)
 547                         ShotOrg_Spawn();
 548                 else
 549                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 550                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 551         }
 552         else if(cmd == "shotorg_movez") {
 553                 if(!debug_shotorg)
 554                         ShotOrg_Spawn();
 555                 else
 556                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 557                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 558         }
 559         else if(cmd == "shotorg_set") {
 560                 if(!debug_shotorg)
 561                         ShotOrg_Spawn();
 562                 else
 563                         debug_shotorg.view_ofs = stov(argv(1));
 564                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 565         }
 566         else if(cmd == "shotorg_setz") {
 567                 if(!debug_shotorg)
 568                         ShotOrg_Spawn();
 569                 else
 570                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 571                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 572         }
 573         else if(cmd == "shotorg_toggle_hide") {
 574                 if(debug_shotorg)
 575                 {
 576                         debug_shotorg.cnt = !debug_shotorg.cnt;
 577                 }
 578         }
 579         else if(cmd == "shotorg_end") {
 580                 if(debug_shotorg)
 581                 {
 582                         print(vtos(debug_shotorg.view_ofs), "\n");
 583                         remove(debug_shotorg);
 584                         debug_shotorg = world;
 585                 }
 586                 localcmd("sv_cmd debug_shotorg\n");
 587         }
 588         else if(cmd == "sendcvar") {
 589                 // W_FixWeaponOrder will trash argv, so save what we need.
 590                 string thiscvar;
 591                 thiscvar = strzone(argv(1));
 592                 s = cvar_string(thiscvar);
 593                 if(thiscvar == "cl_weaponpriority")
 594                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 595                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 596                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 597                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 598                 strunzone(thiscvar);
 599         }
 600         else if(cmd == "spawn") {
 601                 s = argv(1);
 602                 e = spawn();
 603                 precache_model(s);
 604                 setmodel(e, s);
 605                 setorigin(e, view_origin);
 606                 e.angles = view_angles;
 607                 e.draw = DrawDebugModel;
 608                 e.classname = "debugmodel";
 609         }
 610     else if(cmd == "vyes")
 611     {
 612         if(uid2name_dialog)
 613         {
 614             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 615             vote_prev = 0;
 616             cvar_set("cl_allow_uid2name", "1");
 617             vote_change = -9999;
 618         }
 619         else
 620         {
 621             localcmd("cmd vote yes\n");
 622         }
 623     }
 624     else if(cmd == "vno")
 625     {
 626         if(uid2name_dialog)
 627         {
 628             vote_active = 0;
 629             vote_prev = 0;
 630             cvar_set("cl_allow_uid2name", "0");
 631             vote_change = -9999;
 632         }
 633         else
 634         {
 635             localcmd("cmd vote no\n");
 636         }
 637     }
 638
 639         else
 640         {
 641                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 642         }
 643
 644         return;
 645 }
 646
 647 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 648 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 649 // All keys are in ascii.
 650 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 651 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 652 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 653 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 654 {
 655         local float bSkipKey;
 656         bSkipKey = false;
 657
 658         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 659                 return true;
 660
 661         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 662                 return true;
 663
 664         if(menu_visible)
 665                 if(menu_action(bInputType, nPrimary, nSecondary))
 666                         return TRUE;
 667
 668         return bSkipKey;
 669 }
 670
 671 // END REQUIRED CSQC FUNCTIONS
 672 // --------------------------------------------------------------------------
 673
 674 // --------------------------------------------------------------------------
 675 // BEGIN OPTIONAL CSQC FUNCTIONS
 676 void Ent_ReadEntCS()
 677 {
 678         InterpolateOrigin_Undo();
 679
 680         self.classname = "entcs_receiver";
 681         self.sv_entnum = ReadByte() - 1;
 682         self.origin_x = ReadShort();
 683         self.origin_y = ReadShort();
 684         self.origin_z = ReadShort();
 685         self.angles_y = ReadByte() * 360.0 / 256;
 686         self.origin_z = self.angles_x = self.angles_z = 0;
 687
 688         InterpolateOrigin_Note();
 689 }
 690
 691 void Ent_Remove();
 692
 693 void Ent_RemovePlayerScore()
 694 {
 695         float i;
 696
 697         if(self.owner)
 698         {
 699                 SetTeam(self.owner, -1);
 700                 self.owner.gotscores = 0;
 701                 for(i = 0; i < MAX_SCORE; ++i)
 702                         self.owner.(scores[i]) = 0; // clear all scores
 703         }
 704 }
 705
 706 void Ent_ReadPlayerScore()
 707 {
 708         float i, n;
 709         float isNew;
 710         entity o;
 711
 712         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 713         // (no I've never heard of M-x replace-string, sed, or anything like that)
 714         isNew = !self.owner; // workaround for DP bug
 715         n = ReadByte()-1;
 716
 717 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 718         if(!isNew && n != self.sv_entnum)
 719         {
 720                 print("A CSQC entity changed its owner!\n");
 721                 isNew = true;
 722                 Ent_Remove();
 723                 self.enttype = ENT_CLIENT_SCORES;
 724         }
 725 #endif
 726
 727         self.sv_entnum = n;
 728
 729         if not(playerslots[self.sv_entnum])
 730                 playerslots[self.sv_entnum] = spawn();
 731         o = self.owner = playerslots[self.sv_entnum];
 732         o.sv_entnum = self.sv_entnum;
 733         o.gotscores = 1;
 734
 735         //if not(o.sort_prev)
 736         //      RegisterPlayer(o);
 737         //playerchecker will do this for us later, if it has not already done so
 738
 739         float sf, lf;
 740 #if MAX_SCORE <= 8
 741         sf = ReadByte();
 742         lf = ReadByte();
 743 #else
 744         sf = ReadShort();
 745         lf = ReadShort();
 746 #endif
 747         float p;
 748         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 749                 if(sf & p)
 750                 {
 751                         if(lf & p)
 752                                 o.(scores[i]) = ReadInt24_t();
 753                         else
 754                                 o.(scores[i]) = ReadChar();
 755                 }
 756
 757         if(o.sort_prev)
 758                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 759
 760         self.entremove = Ent_RemovePlayerScore;
 761 }
 762
 763 void Ent_ReadTeamScore()
 764 {
 765         float i;
 766         entity o;
 767
 768         self.team = ReadByte();
 769         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 770
 771         float sf, lf;
 772 #if MAX_TEAMSCORE <= 8
 773         sf = ReadByte();
 774         lf = ReadByte();
 775 #else
 776         sf = ReadShort();
 777         lf = ReadShort();
 778 #endif
 779         float p;
 780         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 781                 if(sf & p)
 782                 {
 783                         if(lf & p)
 784                                 o.(teamscores[i]) = ReadInt24_t();
 785                         else
 786                                 o.(teamscores[i]) = ReadChar();
 787                 }
 788
 789         HUD_UpdateTeamPos(o);
 790 }
 791
 792 void Net_Reset()
 793 {
 794 }
 795
 796 void Ent_ClientData()
 797 {
 798         float f;
 799         float newspectatee_status;
 800
 801         f = ReadByte();
 802
 803         scoreboard_showscores_force = (f & 1);
 804
 805         if(f & 2)
 806         {
 807                 newspectatee_status = ReadByte();
 808                 if(newspectatee_status == player_localentnum)
 809                         newspectatee_status = -1; // observing
 810         }
 811         else
 812                 newspectatee_status = 0;
 813
 814         spectatorbutton_zoom = (f & 4);
 815
 816         if(f & 8)
 817         {
 818                 angles_held_status = 1;
 819                 angles_held_x = ReadAngle();
 820                 angles_held_y = ReadAngle();
 821                 angles_held_z = 0;
 822         }
 823         else
 824                 angles_held_status = 0;
 825
 826         if(newspectatee_status != spectatee_status)
 827         {
 828                 float i;
 829
 830                 // clear race stuff
 831                 race_laptime = 0;
 832                 race_checkpointtime = 0;
 833         }
 834         spectatee_status = newspectatee_status;
 835 }
 836
 837 void Ent_Nagger()
 838 {
 839         float nags, i, j, b, f;
 840
 841         nags = ReadByte();
 842
 843         if(nags & 128)
 844         {
 845                 if(vote_called_vote)
 846                         strunzone(vote_called_vote);
 847                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 848         }
 849
 850         if(nags & 1)
 851         {
 852                 for(j = 0; j < maxclients; ++j)
 853                         if(playerslots[j])
 854                                 playerslots[j].ready = 1;
 855                 for(i = 1; i <= maxclients; i += 8)
 856                 {
 857                         f = ReadByte();
 858                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 859                                 if not(f & b)
 860                                         if(playerslots[j])
 861                                                 playerslots[j].ready = 0;
 862                 }
 863         }
 864
 865         ready_waiting = (nags & 1);
 866         ready_waiting_for_me = (nags & 2);
 867         vote_waiting = (nags & 4);
 868         vote_waiting_for_me = (nags & 8);
 869         warmup_stage = (nags & 16);
 870 }
 871
 872 void Ent_RandomSeed()
 873 {
 874         float s;
 875         prandom_debug();
 876         s = ReadShort();
 877         psrandom(s);
 878 }
 879
 880 void Ent_ReadAccuracy(void)
 881 {
 882         float sf, f, w, b;
 883         sf = ReadInt24_t();
 884         if(sf == 0)
 885         {
 886                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 887                         weapon_accuracy[w] = -1;
 888                 return;
 889         }
 890
 891         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 892         {
 893                 if(sf & f)
 894                 {
 895                         b = ReadByte();
 896                         if(b == 0)
 897                                 weapon_accuracy[w] = -1;
 898                         else if(b == 255)
 899                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 900                         else
 901                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 902                 }
 903         }
 904 }
 905
 906 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 907 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 908 void Ent_RadarLink();
 909 void Ent_Init();
 910 void Ent_ScoresInfo();
 911 void(float bIsNewEntity) CSQC_Ent_Update =
 912 {
 913         float t;
 914         float savetime;
 915         t = ReadByte();
 916
 917         // set up the "time" global for received entities to be correct for interpolation purposes
 918         savetime = time;
 919         if(servertime)
 920         {
 921                 time = servertime;
 922         }
 923         else
 924         {
 925                 serverprevtime = time;
 926                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 927                 time = serverprevtime + serverdeltatime;
 928         }
 929
 930 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 931         if(self.enttype)
 932                 if(t != self.enttype)
 933                 {
 934                         print("A CSQC entity changed its type!\n");
 935                         Ent_Remove();
 936                         bIsNewEntity = 1;
 937                 }
 938 #endif
 939         self.enttype = t;
 940         switch(t)
 941         {
 942                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 943                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 944                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 945                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 946                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 947                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 948                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 949                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 950                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 951                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 952                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 953                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 954                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 955                 case ENT_CLIENT_INIT: Ent_Init(); break;
 956                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 957                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 958                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 959                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 960                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 961                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 962                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 963                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 964                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 965                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 966                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 967                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 968                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 969                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 970                 default:
 971                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 972                         break;
 973         }
 974
 975         time = savetime;
 976 };
 977 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 978 // used when an entity changes its type. For an entity that someone interacts
 979 // with others, make sure it can no longer do so.
 980 void Ent_Remove()
 981 {
 982         if(self.entremove)
 983                 self.entremove();
 984
 985         self.enttype = 0;
 986         self.classname = "";
 987         self.draw = menu_sub_null;
 988         self.entremove = menu_sub_null;
 989         // TODO possibly set more stuff to defaults
 990 }
 991 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 992 void CSQC_Ent_Remove()
 993 {
 994         if(self.enttype)
 995                 Ent_Remove();
 996         remove(self);
 997 }
 998
 999 void Gamemode_Init()
1000 {
1001         if(gametype == GAME_ONSLAUGHT) {
1002                 print(strcat("Using ", minimapname, " as minimap.\n"));
1003                 precache_pic("gfx/ons-cp-neutral.tga");
1004                 precache_pic("gfx/ons-cp-red.tga");
1005                 precache_pic("gfx/ons-cp-blue.tga");
1006                 precache_pic("gfx/ons-frame.tga");
1007                 precache_pic("gfx/ons-frame-team.tga");
1008         }
1009
1010         if not(isdemo())
1011         {
1012                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1013                 calledhooks |= HOOK_START;
1014         }
1015 }
1016 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1017 void CSQC_Parse_StuffCmd(string strMessage)
1018 {
1019         localcmd(strMessage);
1020 }
1021 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1022 void CSQC_Parse_Print(string strMessage)
1023 {
1024         print(ColorTranslateRGB(strMessage));
1025 }
1026
1027 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1028 void CSQC_Parse_CenterPrint(string strMessage)
1029 {
1030         centerprint(strMessage);
1031 }
1032
1033 string notranslate_fogcmd1 = "\nfog ";
1034 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1035 void Fog_Force()
1036 {
1037         // TODO somehow thwart prvm_globalset client ...
1038
1039         if(forcefog != "")
1040                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1041 }
1042
1043 void Gamemode_Init();
1044 void Ent_ScoresInfo()
1045 {
1046         float i;
1047         self.classname = "ent_client_scores_info";
1048         gametype = ReadByte();
1049         for(i = 0; i < MAX_SCORE; ++i)
1050         {
1051                 scores_label[i] = strzone(ReadString());
1052                 scores_flags[i] = ReadByte();
1053         }
1054         for(i = 0; i < MAX_TEAMSCORE; ++i)
1055         {
1056                 teamscores_label[i] = strzone(ReadString());
1057                 teamscores_flags[i] = ReadByte();
1058         }
1059         HUD_InitScores();
1060         Gamemode_Init();
1061 }
1062
1063 void Ent_Init()
1064 {
1065         self.classname = "ent_client_init";
1066
1067         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1068
1069         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1070         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1071         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1072         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1073         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1074         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1075         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1076         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1077         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1078         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1079         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1080         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1081
1082         if(forcefog)
1083                 strunzone(forcefog);
1084         forcefog = strzone(ReadString());
1085
1086         armorblockpercent = ReadByte() / 255.0;
1087
1088         g_weaponswitchdelay = ReadByte() / 255.0;
1089
1090         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1091         g_balance_grenadelauncher_bouncestop = ReadCoord();
1092         g_balance_electro_secondary_bouncefactor = ReadCoord();
1093         g_balance_electro_secondary_bouncestop = ReadCoord();
1094
1095         nex_scope = !ReadByte();
1096         sniperrifle_scope = !ReadByte();
1097
1098         serverflags = ReadByte();
1099
1100         cr_maxbullets = ReadByte();
1101
1102         g_trueaim_minrange = ReadCoord();
1103
1104         if(!postinit)
1105                 PostInit();
1106 }
1107
1108 void Net_ReadRace()
1109 {
1110         float b;
1111
1112         b = ReadByte();
1113
1114         switch(b)
1115         {
1116                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1117                         race_checkpoint = ReadByte();
1118                         race_time = ReadInt24_t();
1119                         race_previousbesttime = ReadInt24_t();
1120                         if(race_previousbestname)
1121                                 strunzone(race_previousbestname);
1122                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1123
1124                         race_checkpointtime = time;
1125
1126                         if(race_checkpoint == 0 || race_checkpoint == 254)
1127                         {
1128                                 race_penaltyaccumulator = 0;
1129                                 race_laptime = time; // valid
1130                         }
1131
1132                         break;
1133
1134                 case RACE_NET_CHECKPOINT_CLEAR:
1135                         race_laptime = 0;
1136                         race_checkpointtime = 0;
1137                         break;
1138
1139                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1140                         race_laptime = ReadCoord();
1141                         race_checkpointtime = -99999;
1142                         // fall through
1143                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1144                         race_nextcheckpoint = ReadByte();
1145
1146                         race_nextbesttime = ReadInt24_t();
1147                         if(race_nextbestname)
1148                                 strunzone(race_nextbestname);
1149                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1150                         break;
1151
1152                 case RACE_NET_CHECKPOINT_HIT_RACE:
1153                         race_mycheckpoint = ReadByte();
1154                         race_mycheckpointtime = time;
1155                         race_mycheckpointdelta = ReadInt24_t();
1156                         race_mycheckpointlapsdelta = ReadByte();
1157                         if(race_mycheckpointlapsdelta >= 128)
1158                                 race_mycheckpointlapsdelta -= 256;
1159                         if(race_mycheckpointenemy)
1160                                 strunzone(race_mycheckpointenemy);
1161                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1162                         break;
1163
1164                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1165                         race_othercheckpoint = ReadByte();
1166                         race_othercheckpointtime = time;
1167                         race_othercheckpointdelta = ReadInt24_t();
1168                         race_othercheckpointlapsdelta = ReadByte();
1169                         if(race_othercheckpointlapsdelta >= 128)
1170                                 race_othercheckpointlapsdelta -= 256;
1171                         if(race_othercheckpointenemy)
1172                                 strunzone(race_othercheckpointenemy);
1173                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1174                         break;
1175
1176                 case RACE_NET_PENALTY_RACE:
1177                         race_penaltyeventtime = time;
1178                         race_penaltytime = ReadShort();
1179                         //race_penaltyaccumulator += race_penaltytime;
1180                         if(race_penaltyreason)
1181                                 strunzone(race_penaltyreason);
1182                         race_penaltyreason = strzone(ReadString());
1183                         break;
1184
1185                 case RACE_NET_PENALTY_QUALIFYING:
1186                         race_penaltyeventtime = time;
1187                         race_penaltytime = ReadShort();
1188                         race_penaltyaccumulator += race_penaltytime;
1189                         if(race_penaltyreason)
1190                                 strunzone(race_penaltyreason);
1191                         race_penaltyreason = strzone(ReadString());
1192                         break;
1193
1194                 case RACE_NET_SERVER_RECORD:
1195                         race_server_record = ReadInt24_t();
1196                         break;
1197                 case RACE_NET_SPEED_AWARD:
1198                         race_speedaward = ReadInt24_t();
1199                         if(race_speedaward_holder)
1200                                 strunzone(race_speedaward_holder);
1201                         race_speedaward_holder = strzone(ReadString());
1202                         break;
1203                 case RACE_NET_SPEED_AWARD_BEST:
1204                         race_speedaward_alltimebest = ReadInt24_t();
1205                         if(race_speedaward_alltimebest_holder)
1206                                 strunzone(race_speedaward_alltimebest_holder);
1207                         race_speedaward_alltimebest_holder = strzone(ReadString());
1208                         break;
1209                 case RACE_NET_SERVER_RANKINGS:
1210                         float pos, prevpos, del;
1211                         pos = ReadShort();
1212                         prevpos = ReadShort();
1213                         del = ReadShort();
1214
1215                         // move other rankings out of the way
1216                         float i;
1217                         if (prevpos) {
1218                                 for (i=prevpos-1;i>pos-1;--i) {
1219                                         grecordtime[i] = grecordtime[i-1];
1220                                         if(grecordholder[i])
1221                                                 strunzone(grecordholder[i]);
1222                                         grecordholder[i] = strzone(grecordholder[i-1]);
1223                                 }
1224                         } else if (del) { // a record has been deleted by the admin
1225                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1226                                         if (i == RANKINGS_CNT-1) { // clear out last record
1227                                                 grecordtime[i] = 0;
1228                                                 if (grecordholder[i])
1229                                                         strunzone(grecordholder[i]);
1230                                                 grecordholder[i] = string_null;
1231                                         }
1232                                         else {
1233                                                 grecordtime[i] = grecordtime[i+1];
1234                                                 if (grecordholder[i])
1235                                                         strunzone(grecordholder[i]);
1236                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1237                                         }
1238                                 }
1239                         } else { // player has no ranked record yet
1240                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1241                                         grecordtime[i] = grecordtime[i-1];
1242                                         if(grecordholder[i])
1243                                                 strunzone(grecordholder[i]);
1244                                         grecordholder[i] = strzone(grecordholder[i-1]);
1245                                 }
1246                         }
1247
1248                         // store new ranking
1249                         if(grecordholder[pos-1] != "")
1250                                 strunzone(grecordholder[pos-1]);
1251                         grecordholder[pos-1] = strzone(ReadString());
1252                         grecordtime[pos-1] = ReadInt24_t();
1253                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1254                                 race_myrank = pos;
1255                         break;
1256                 case RACE_NET_SERVER_STATUS:
1257                         race_status = ReadShort();
1258                         if(race_status_name)
1259                                 strunzone(race_status_name);
1260                         race_status_name = strzone(ReadString());
1261         }
1262 }
1263
1264 void Net_ReadSpawn()
1265 {
1266         zoomin_effect = 1;
1267         current_viewzoom = 0.6;
1268 }
1269
1270 void Net_TeamNagger()
1271 {
1272         teamnagger = 1;
1273 }
1274
1275 void Net_ReadPingPLReport()
1276 {
1277         float e, pi, pl, ml;
1278         e = ReadByte();
1279         pi = ReadShort();
1280         pl = ReadByte();
1281         ml = ReadByte();
1282         if not(playerslots[e])
1283                 return;
1284         playerslots[e].ping = pi;
1285         playerslots[e].ping_packetloss = pl / 255.0;
1286         playerslots[e].ping_movementloss = ml / 255.0;
1287 }
1288
1289 void Net_VoteDialog(float highlight) {
1290         if(highlight) {
1291                 vote_highlighted = ReadByte();
1292                 return;
1293         }
1294
1295         vote_yescount = ReadByte();
1296         vote_nocount = ReadByte();
1297         vote_needed = ReadByte();
1298         vote_active = 1;
1299 }
1300
1301 void Net_VoteDialogReset() {
1302         vote_active = 0;
1303 }
1304
1305 void Net_Notify() {
1306         float type;
1307         type = ReadByte();
1308
1309         if(type == CSQC_KILLNOTIFY)
1310         {
1311                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1312         }
1313         else if(type == CSQC_CENTERPRINT)
1314         {
1315                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1316         }
1317 }
1318
1319 void Net_WeaponComplain() {
1320         complain_weapon = ReadByte();
1321
1322         if(complain_weapon_name)
1323                 strunzone(complain_weapon_name);
1324         complain_weapon_name = strzone(ReadString());
1325
1326         complain_weapon_type = ReadByte();
1327
1328         complain_weapon_time = time;
1329         weapontime = time; // ping the weapon panel
1330 }
1331
1332 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1333 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1334 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1335 float CSQC_Parse_TempEntity()
1336 {
1337         local float bHandled;
1338                 bHandled  = true;
1339         // Acquire TE ID
1340         local float nTEID;
1341                 nTEID = ReadByte();
1342
1343                 // NOTE: Could just do return instead of break...
1344         switch(nTEID)
1345         {
1346                 case TE_CSQC_TARGET_MUSIC:
1347                         Net_TargetMusic();
1348                         bHandled = true;
1349                         break;
1350                 case TE_CSQC_PICTURE:
1351                         Net_MapVote_Picture();
1352                         bHandled = true;
1353                         break;
1354                 case TE_CSQC_RACE:
1355                         Net_ReadRace();
1356                         bHandled = true;
1357                         break;
1358                 case TE_CSQC_SPAWN:
1359                         Net_ReadSpawn();
1360                         bHandled = true;
1361                         break;
1362                 case TE_CSQC_ZCURVEPARTICLES:
1363                         Net_ReadZCurveParticles();
1364                         bHandled = true;
1365                         break;
1366                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1367                         Net_ReadNexgunBeamParticle();
1368                         bHandled = true;
1369                         break;
1370                 case TE_CSQC_TEAMNAGGER:
1371                         Net_TeamNagger();
1372                         bHandled = true;
1373                         break;
1374                 case TE_CSQC_VOTE:
1375                         Net_VoteDialog(ReadByte());
1376                         bHandled = true;
1377                         break;
1378                 case TE_CSQC_VOTERESET:
1379                         Net_VoteDialogReset();
1380                         bHandled = true;
1381                         break;
1382                 case TE_CSQC_LIGHTNINGARC:
1383                         Net_ReadLightningarc();
1384                         bHandled = true;
1385                         break;
1386                 case TE_CSQC_PINGPLREPORT:
1387                         Net_ReadPingPLReport();
1388                         bHandled = true;
1389                         break;
1390                 case TE_CSQC_ANNOUNCE:
1391                         announce_snd = strzone(ReadString());
1392                         bHandled = true;
1393                         break;
1394                 case TE_CSQC_NOTIFY:
1395                         Net_Notify();
1396                         bHandled = true;
1397                         break;
1398                 case TE_CSQC_WEAPONCOMPLAIN:
1399                         Net_WeaponComplain();
1400                         bHandled = true;
1401                         break;
1402                 default:
1403                         // No special logic for this temporary entity; return 0 so the engine can handle it
1404                         bHandled = false;
1405                         break;
1406         }
1407
1408         return bHandled;
1409 }
1410
1411 string getcommandkey(string text, string command)
1412 {
1413         string keys;
1414         float n, j, k, l;
1415
1416         if (!hud_showbinds)
1417                 return text;
1418
1419         keys = db_get(binddb, command);
1420         if (!keys)
1421         {
1422                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1423                 for(j = 0; j < n; ++j)
1424                 {
1425                         k = stof(argv(j));
1426                         if(k != -1)
1427                         {
1428                                 if ("" == keys)
1429                                         keys = keynumtostring(k);
1430                                 else
1431                                         keys = strcat(keys, ", ", keynumtostring(k));
1432
1433                                 ++l;
1434                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1435                         }
1436
1437                 }
1438                 db_put(binddb, command, keys);
1439         }
1440
1441         if ("" == keys) {
1442                 if (hud_showbinds > 1)
1443                         return strcat(text, " (not bound)");
1444                 else
1445                         return text;
1446         }
1447         else if (hud_showbinds > 1)
1448                 return strcat(text, " (", keys, ")");
1449         else
1450                 return keys;
1451 }