qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63         float i;
  64         CSQC_CheckEngine();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         drawfont = 0;
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = menu_sub_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkey(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //ctf_temp_1 = "";
  82         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  83         //registercmd("ctf_menu");
  84         registercmd("ons_map");
  85         //registercmd("menu_action");
  86
  87         registercmd("+button3");
  88         registercmd("-button3");
  89         registercmd("+button4");
  90         registercmd("-button4");
  91         registercmd("+showaccuracy");registercmd("-showaccuracy");
  92
  93 #ifndef CAMERATEST
  94         if(isdemo())
  95         {
  96 #endif
  97                 registercmd("+forward");registercmd("-forward");
  98                 registercmd("+back");registercmd("-back");
  99                 registercmd("+moveup");registercmd("-moveup");
 100                 registercmd("+movedown");registercmd("-movedown");
 101                 registercmd("+moveright");registercmd("-moveright");
 102                 registercmd("+moveleft");registercmd("-moveleft");
 103                 registercmd("+roll_right");registercmd("-roll_right");
 104                 registercmd("+roll_left");registercmd("-roll_left");
 105 #ifndef CAMERATEST
 106         }
 107 #endif
 108         registercvar("sbar_usecsqc", "1");
 109         registercvar("sbar_columns", "default", CVAR_SAVE);
 110
 111         gametype = 0;
 112
 113         // sbar_fields uses strunzone on the titles!
 114         for(i = 0; i < MAX_SBAR_FIELDS; ++i)
 115                 sbar_title[i] = strzone("(null)");
 116
 117         postinit = false;
 118
 119         calledhooks = 0;
 120
 121         teams = Sort_Spawn();
 122         players = Sort_Spawn();
 123
 124         GetTeam(COLOR_SPECTATOR, true); // add specs first
 125
 126         cvar_clientsettemp("_supports_weaponpriority", "1");
 127
 128         RegisterWeapons();
 129
 130         WaypointSprite_Load();
 131
 132         // precaches
 133         Projectile_Precache();
 134         GibSplash_Precache();
 135         Casings_Precache();
 136         DamageInfo_Precache();
 137         if(cvar_string("cl_announcer") != cl_announcer_prev) {
 138                 Announcer_Precache();
 139                 if(cl_announcer_prev)
 140                         strunzone(cl_announcer_prev);
 141                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
 142         }
 143         Tuba_Precache();
 144
 145 #ifdef UID
 146         {
 147                 // find the user ID
 148                 string uid;
 149                 registercvar("_cl_userid", "", CVAR_SAVE);
 150                 uid = cvar_string("_cl_userid");
 151                 if(strlen(uid) < 16)
 152                 {
 153                         uid = "";
 154                         for(i = 0; i < 4; ++i)
 155                                 uid = strcat(uid, substring(ftos(floor(10000 + random() * 10000)), 1, -1));
 156                 }
 157                 cvar_set("_cl_userid", uid);
 158                 localcmd(strcat("\ncmd uid ", uid, "\n"));
 159         }
 160 #endif
 161
 162         get_mi_min_max_texcoords(1); // try the CLEVER way first
 163         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 164         shortmapname = mi_shortname;
 165
 166         if(precache_pic(minimapname) == "")
 167         {
 168                 // but maybe we have a non-clever minimap
 169                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 170                 if(precache_pic(minimapname) == "")
 171                         minimapname = ""; // FAIL
 172                 else
 173                         get_mi_min_max_texcoords(0); // load new texcoords
 174         }
 175
 176         mi_center = (mi_min + mi_max) * 0.5;
 177         mi_scale = mi_max - mi_min;
 178         minimapname = strzone(minimapname);
 179
 180         WarpZone_Init();
 181 }
 182
 183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 184 void CSQC_Shutdown(void)
 185 {
 186 #ifdef USE_FTE
 187 #pragma TARGET id
 188         if(!__engine_check)
 189                 return 0;
 190 #pragma TARGET fte
 191 #endif
 192
 193         WarpZone_Shutdown();
 194
 195         remove(teams);
 196         remove(players);
 197         db_close(binddb);
 198         db_close(tempdb);
 199         db_save(ClientProgsDB, "client.db");
 200         db_close(ClientProgsDB);
 201
 202         cvar_clientsettemp_restore();
 203
 204         if(camera_active)
 205                 cvar_set("chase_active",ftos(chase_active_backup));
 206
 207         if not(isdemo())
 208         {
 209                 if not(calledhooks & HOOK_START)
 210                         localcmd("\n_cl_hook_gamestart nop;");
 211                 if not(calledhooks & HOOK_END)
 212                         localcmd("\ncl_hook_gameend;");
 213         }
 214 }
 215
 216 .float has_team;
 217 float SetTeam(entity o, float Team)
 218 {
 219         entity tm;
 220         if(teamplay)
 221         {
 222                 switch(Team)
 223                 {
 224                         case -1:
 225                         case COLOR_TEAM1:
 226                         case COLOR_TEAM2:
 227                         case COLOR_TEAM3:
 228                         case COLOR_TEAM4:
 229                                 break;
 230                         default:
 231                                 if(GetTeam(Team, false) == NULL)
 232                                 {
 233                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 234                                         Team = COLOR_SPECTATOR;
 235                                 }
 236                                 break;
 237                 }
 238         }
 239         else
 240         {
 241                 switch(Team)
 242                 {
 243                         case -1:
 244                         case 0:
 245                                 break;
 246                         default:
 247                                 if(GetTeam(Team, false) == NULL)
 248                                 {
 249                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 250                                         Team = COLOR_SPECTATOR;
 251                                 }
 252                                 break;
 253                 }
 254         }
 255         if(Team == -1) // leave
 256         {
 257                 if(o.has_team)
 258                 {
 259                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 260                         tm = GetTeam(o.team, false);
 261                         tm.team_size -= 1;
 262                         o.has_team = 0;
 263                         return TRUE;
 264                 }
 265         }
 266         else
 267         {
 268                 if not(o.has_team)
 269                 {
 270                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 271                         o.team = Team;
 272                         tm = GetTeam(Team, true);
 273                         tm.team_size += 1;
 274                         o.has_team = 1;
 275                         return TRUE;
 276                 }
 277                 else if(Team != o.team)
 278                 {
 279                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 280                         tm = GetTeam(o.team, false);
 281                         tm.team_size -= 1;
 282                         o.team = Team;
 283                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         return TRUE;
 287                 }
 288         }
 289         return FALSE;
 290 }
 291
 292 void Playerchecker_Think()
 293 {
 294         float i;
 295         entity e;
 296         for(i = 0; i < maxclients; ++i)
 297         {
 298                 e = playerslots[i];
 299                 if(GetPlayerName(i) == "")
 300                 {
 301                         if(e.sort_prev)
 302                         {
 303                                 //print("playerchecker: KILL KILL KILL\n");
 304                                 // player disconnected
 305                                 SetTeam(e, -1);
 306                                 RemovePlayer(e);
 307                                 e.sort_prev = world;
 308                                 //e.gotscores = 0;
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if not(e.sort_prev)
 314                         {
 315                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 316                                 // player connected
 317                                 if not(e)
 318                                         playerslots[i] = e = spawn();
 319                                 e.sv_entnum = i;
 320                                 e.ping = 0;
 321                                 e.ping_packetloss = 0;
 322                                 e.ping_movementloss = 0;
 323                                 //e.gotscores = 0; // we might already have the scores...
 324                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams
 325                                 RegisterPlayer(e);
 326                                 Sbar_UpdatePlayerPos(e);
 327                         }
 328                 }
 329         }
 330         self.nextthink = time + 0.2;
 331 }
 332
 333 void Porto_Init();
 334 void TrueAim_Init();
 335 void PostInit(void)
 336 {
 337         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 338         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));
 339
 340         entity playerchecker;
 341         playerchecker = spawn();
 342         playerchecker.think = Playerchecker_Think;
 343         playerchecker.nextthink = time + 0.2;
 344
 345         Porto_Init();
 346         TrueAim_Init();
 347
 348         postinit = true;
 349 }
 350
 351 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 352 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 353 float button_zoom;
 354 void Cmd_Sbar_SetFields(float);
 355 void Cmd_Sbar_Help(float);
 356 float CSQC_ConsoleCommand(string strMessage)
 357 {
 358         float argc;
 359         // Tokenize String
 360         //argc = tokenize(strMessage);
 361         argc = tokenize_console(strMessage);
 362
 363         // Acquire Command
 364         local string strCmd;
 365         strCmd = argv(0);
 366
 367         if(strCmd == "+button4") { // zoom
 368                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 369                 if(ignore_plus_zoom)
 370                 {
 371                         --ignore_plus_zoom;
 372                         return false;
 373                 }
 374                 button_zoom = 1;
 375                 return true;
 376         } else if(strCmd == "-button4") { // zoom
 377                 if(ignore_minus_zoom)
 378                 {
 379                         --ignore_minus_zoom;
 380                         return false;
 381                 }
 382                 button_zoom = 0;
 383                 return true;
 384         } else if(strCmd == "+button3") { // secondary
 385                 button_attack2 = 1;
 386                 return false;
 387         } else if(strCmd == "-button3") { // secondary
 388                 button_attack2 = 0;
 389                 return false;
 390         } else if(strCmd == "+showscores") {
 391                 sb_showscores = true;
 392                 return true;
 393         } else if(strCmd == "-showscores") {
 394                 sb_showscores = false;
 395                 return true;
 396         } else if(strCmd == "+showaccuracy") {
 397                 sb_showaccuracy = true;
 398                 return true;
 399         } else if(strCmd == "-showaccuracy") {
 400                 sb_showaccuracy = false;
 401                 return true;
 402         }
 403
 404         if(camera_active)
 405         if(strCmd == "+forward" || strCmd == "-back") {
 406                 ++camera_direction_x;
 407                 return true;
 408         } else if(strCmd == "-forward" || strCmd == "+back") {
 409                 --camera_direction_x;
 410                 return true;
 411         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 412                 --camera_direction_y;
 413                 return true;
 414         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 415                 ++camera_direction_y;
 416                 return true;
 417         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 418                 ++camera_direction_z;
 419                 return true;
 420         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 421                 --camera_direction_z;
 422                 return true;
 423         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 424                 ++camera_roll;
 425                 return true;
 426         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 427                 --camera_roll;
 428                 return true;
 429         }
 430
 431         return false;
 432 }
 433
 434 .vector view_ofs;
 435 entity debug_shotorg;
 436 void ShotOrg_Draw()
 437 {
 438         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 439         self.angles = view_angles;
 440         self.angles_x = -self.angles_x;
 441         if not(self.cnt)
 442                 R_AddEntity(self);
 443 }
 444 void ShotOrg_Draw2D()
 445 {
 446         vector coord2d_topleft, coord2d_topright, coord2d;
 447         string s;
 448         vector fs;
 449
 450         s = vtos(self.view_ofs);
 451         s = substring(s, 1, strlen(s) - 2);
 452         if(tokenize_console(s) == 3)
 453                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 454
 455         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 456         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 457
 458         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 459
 460         coord2d = coord2d_topleft;
 461         if(fs_x < 8)
 462         {
 463                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 464                 fs = '8 8 0';
 465         }
 466         coord2d_y -= fs_y;
 467         coord2d_z = 0;
 468         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 469 }
 470
 471 void ShotOrg_Spawn()
 472 {
 473         debug_shotorg = spawn();
 474         debug_shotorg.draw = ShotOrg_Draw;
 475         debug_shotorg.draw2d = ShotOrg_Draw2D;
 476         debug_shotorg.renderflags = RF_VIEWMODEL;
 477         debug_shotorg.effects = EF_FULLBRIGHT;
 478         precache_model("models/shotorg_adjuster.md3");
 479         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 480         debug_shotorg.scale = 2;
 481         debug_shotorg.view_ofs = '25 8 -8';
 482 }
 483
 484 void DrawDebugModel()
 485 {
 486         if(time - floor(time) > 0.5)
 487         {
 488                 PolyDrawModel(self);
 489         }
 490         else
 491         {
 492                 self.renderflags = 0;
 493                 R_AddEntity(self);
 494         }
 495 }
 496
 497 void GameCommand(string msg)
 498 {
 499         string s;
 500         float argc;
 501         entity e;
 502         argc = tokenize_console(msg);
 503
 504         if(argv(0) == "help" || argc == 0)
 505         {
 506                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 507                 print("  settemp cvar value\n");
 508                 print("  radar\n");
 509                 print("  sbar_columns_set ...\n");
 510                 print("  sbar_columns_help\n");
 511                 GameCommand_Generic("help");
 512                 return;
 513         }
 514
 515         if(GameCommand_Generic(msg))
 516                 return;
 517
 518         string cmd;
 519         cmd = argv(0);
 520         if(cmd == "mv_download") {
 521                 Cmd_MapVote_MapDownload(argc);
 522         }
 523         else if(cmd == "settemp") {
 524                 cvar_clientsettemp(argv(1), argv(2));
 525         }
 526         else if(cmd == "radar") {
 527                 ons_showmap = !ons_showmap;
 528         }
 529         else if(cmd == "sbar_columns_set") {
 530                 Cmd_Sbar_SetFields(argc);
 531         }
 532         else if(cmd == "sbar_columns_help") {
 533                 Cmd_Sbar_Help(argc);
 534         }
 535 #ifdef BLURTEST
 536         else if(cmd == "blurtest") {
 537                 blurtest_time0 = time;
 538                 blurtest_time1 = time + stof(argv(1));
 539                 blurtest_radius = stof(argv(2));
 540                 blurtest_power = stof(argv(3));
 541         }
 542 #endif
 543         else if(cmd == "shotorg_move") {
 544                 if(!debug_shotorg)
 545                         ShotOrg_Spawn();
 546                 else
 547                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 548                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 549         }
 550         else if(cmd == "shotorg_movez") {
 551                 if(!debug_shotorg)
 552                         ShotOrg_Spawn();
 553                 else
 554                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 555                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 556         }
 557         else if(cmd == "shotorg_set") {
 558                 if(!debug_shotorg)
 559                         ShotOrg_Spawn();
 560                 else
 561                         debug_shotorg.view_ofs = stov(argv(1));
 562                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 563         }
 564         else if(cmd == "shotorg_setz") {
 565                 if(!debug_shotorg)
 566                         ShotOrg_Spawn();
 567                 else
 568                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 569                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 570         }
 571         else if(cmd == "shotorg_toggle_hide") {
 572                 if(debug_shotorg)
 573                 {
 574                         debug_shotorg.cnt = !debug_shotorg.cnt;
 575                 }
 576         }
 577         else if(cmd == "shotorg_end") {
 578                 if(debug_shotorg)
 579                 {
 580                         print(vtos(debug_shotorg.view_ofs), "\n");
 581                         remove(debug_shotorg);
 582                         debug_shotorg = world;
 583                 }
 584                 localcmd("sv_cmd debug_shotorg\n");
 585         }
 586         else if(cmd == "sendcvar") {
 587                 // W_FixWeaponOrder will trash argv, so save what we need.
 588                 string cvar;
 589                 cvar = strzone(argv(1));
 590                 s = cvar_string(cvar);
 591                 if(cvar == "cl_weaponpriority")
 592                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 593                 else if(substring(cvar, 0, 17) == "cl_weaponpriority" && strlen(cvar) == 18)
 594                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 595                 localcmd("cmd sentcvar ", cvar, " \"", s, "\"\n");
 596                 strunzone(cvar);
 597         }
 598         else if(cmd == "spawn") {
 599                 s = argv(1);
 600                 e = spawn();
 601                 precache_model(s);
 602                 setmodel(e, s);
 603                 setorigin(e, view_origin);
 604                 e.angles = view_angles;
 605                 e.draw = DrawDebugModel;
 606                 e.classname = "debugmodel";
 607         }
 608         else
 609         {
 610                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 611         }
 612
 613         return;
 614 }
 615
 616 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 617 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 618 // All keys are in ascii.
 619 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 620 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 621 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 622 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 623 {
 624         local float bSkipKey;
 625         bSkipKey = false;
 626
 627         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 628                 return true;
 629
 630         if(menu_visible)
 631                 if(menu_action(bInputType, nPrimary, nSecondary))
 632                         return TRUE;
 633         return bSkipKey;
 634 }
 635
 636 // END REQUIRED CSQC FUNCTIONS
 637 // --------------------------------------------------------------------------
 638
 639 // --------------------------------------------------------------------------
 640 // BEGIN OPTIONAL CSQC FUNCTIONS
 641 void Ent_ReadEntCS()
 642 {
 643         InterpolateOrigin_Undo();
 644
 645         self.classname = "entcs_receiver";
 646         self.sv_entnum = ReadByte() - 1;
 647         self.origin_x = ReadShort();
 648         self.origin_y = ReadShort();
 649         self.origin_z = ReadShort();
 650         self.angles_y = ReadByte() * 360.0 / 256;
 651         self.origin_z = self.angles_x = self.angles_z = 0;
 652
 653         InterpolateOrigin_Note();
 654 }
 655
 656 void Ent_Remove();
 657
 658 void Ent_RemovePlayerScore()
 659 {
 660         float i;
 661
 662         if(self.owner)
 663         {
 664                 SetTeam(self.owner, -1);
 665                 self.owner.gotscores = 0;
 666                 for(i = 0; i < MAX_SCORE; ++i)
 667                         self.owner.(scores[i]) = 0; // clear all scores
 668         }
 669 }
 670
 671 void Ent_ReadPlayerScore()
 672 {
 673         float i, n;
 674         float isNew;
 675         entity o;
 676
 677         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN
 678         // (no I've never heard of M-x replace-string, sed, or anything like that)
 679         isNew = !self.owner; // workaround for DP bug
 680         n = ReadByte()-1;
 681
 682 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 683         if(!isNew && n != self.sv_entnum)
 684         {
 685                 print("A CSQC entity changed its owner!\n");
 686                 isNew = true;
 687                 Ent_Remove();
 688                 self.enttype = ENT_CLIENT_SCORES;
 689         }
 690 #endif
 691
 692         self.sv_entnum = n;
 693
 694         if not(playerslots[self.sv_entnum])
 695                 playerslots[self.sv_entnum] = spawn();
 696         o = self.owner = playerslots[self.sv_entnum];
 697         o.sv_entnum = self.sv_entnum;
 698         o.gotscores = 1;
 699
 700         //if not(o.sort_prev)
 701         //      RegisterPlayer(o);
 702         //playerchecker will do this for us later, if it has not already done so
 703
 704         float sf, lf;
 705 #if MAX_SCORE <= 8
 706         sf = ReadByte();
 707         lf = ReadByte();
 708 #else
 709         sf = ReadShort();
 710         lf = ReadShort();
 711 #endif
 712         float p;
 713         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 714                 if(sf & p)
 715                 {
 716                         if(lf & p)
 717                                 o.(scores[i]) = ReadInt24_t();
 718                         else
 719                                 o.(scores[i]) = ReadChar();
 720                 }
 721
 722         if(o.sort_prev)
 723                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 724
 725         self.entremove = Ent_RemovePlayerScore;
 726 }
 727
 728 void Ent_ReadTeamScore()
 729 {
 730         float i;
 731         entity o;
 732
 733         self.team = ReadByte();
 734         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 735
 736         float sf, lf;
 737 #if MAX_TEAMSCORE <= 8
 738         sf = ReadByte();
 739         lf = ReadByte();
 740 #else
 741         sf = ReadShort();
 742         lf = ReadShort();
 743 #endif
 744         float p;
 745         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 746                 if(sf & p)
 747                 {
 748                         if(lf & p)
 749                                 o.(teamscores[i]) = ReadInt24_t();
 750                         else
 751                                 o.(teamscores[i]) = ReadChar();
 752                 }
 753
 754         Sbar_UpdateTeamPos(o);
 755 }
 756
 757 void Net_Reset()
 758 {
 759 }
 760
 761 void Ent_ClientData()
 762 {
 763         float f;
 764         float newspectatee_status;
 765
 766         f = ReadByte();
 767
 768         sb_showscores_force = (f & 1);
 769
 770         if(f & 2)
 771         {
 772                 newspectatee_status = ReadByte();
 773                 if(newspectatee_status == player_localentnum)
 774                         newspectatee_status = -1; // observing
 775         }
 776         else
 777                 newspectatee_status = 0;
 778
 779         spectatorbutton_zoom = (f & 4);
 780
 781         if(f & 8)
 782         {
 783                 angles_held_status = 1;
 784                 angles_held_x = ReadAngle();
 785                 angles_held_y = ReadAngle();
 786                 angles_held_z = 0;
 787         }
 788         else
 789                 angles_held_status = 0;
 790
 791         if(newspectatee_status != spectatee_status)
 792         {
 793                 float i;
 794                 // clear the weapon accuracy stats
 795                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
 796                         weapon_hits[i] = 0;
 797                         weapon_fired[i] = 0;
 798                 }
 799
 800                 // clear race stuff
 801                 race_laptime = 0;
 802                 race_checkpointtime = 0;
 803         }
 804         spectatee_status = newspectatee_status;
 805 }
 806
 807 void Ent_Nagger()
 808 {
 809         float nags, i, j, b, f;
 810
 811         nags = ReadByte();
 812
 813         if(nags & 128)
 814         {
 815                 if(vote_called_vote)
 816                         strunzone(vote_called_vote);
 817                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 818         }
 819
 820         if(nags & 1)
 821         {
 822                 for(j = 0; j < maxclients; ++j)
 823                         if(playerslots[j])
 824                                 playerslots[j].ready = 1;
 825                 for(i = 1; i <= maxclients; i += 8)
 826                 {
 827                         f = ReadByte();
 828                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 829                                 if not(f & b)
 830                                         if(playerslots[j])
 831                                                 playerslots[j].ready = 0;
 832                 }
 833         }
 834
 835         ready_waiting = (nags & 1);
 836         ready_waiting_for_me = (nags & 2);
 837         vote_waiting = (nags & 4);
 838         vote_waiting_for_me = (nags & 8);
 839         warmup_stage = (nags & 16);
 840 }
 841
 842 void Ent_RandomSeed()
 843 {
 844         float s;
 845         prandom_debug();
 846         s = ReadShort();
 847         psrandom(s);
 848 }
 849
 850 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 851 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 852 void Ent_RadarLink();
 853 void Ent_Init();
 854 void Ent_ScoresInfo();
 855 void(float bIsNewEntity) CSQC_Ent_Update =
 856 {
 857         float t;
 858         float savetime;
 859         t = ReadByte();
 860
 861         // set up the "time" global for received entities to be correct for interpolation purposes
 862         savetime = time;
 863         if(servertime)
 864         {
 865                 time = servertime;
 866         }
 867         else
 868         {
 869                 serverprevtime = time;
 870                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 871                 time = serverprevtime + serverdeltatime;
 872         }
 873
 874 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 875         if(self.enttype)
 876                 if(t != self.enttype)
 877                 {
 878                         print("A CSQC entity changed its type!\n");
 879                         Ent_Remove();
 880                         bIsNewEntity = 1;
 881                 }
 882 #endif
 883         self.enttype = t;
 884         switch(t)
 885         {
 886                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 887                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 888                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 889                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 890                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 891                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 892                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 893                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 894                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 895                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 896                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 897                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 898                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 899                 case ENT_CLIENT_INIT: Ent_Init(); break;
 900                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 901                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 902                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 903                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 904                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 905                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 906                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 907                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 908                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 909                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 910                 default:
 911                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 912                         break;
 913         }
 914
 915         time = savetime;
 916 };
 917 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 918 // used when an entity changes its type. For an entity that someone interacts
 919 // with others, make sure it can no longer do so.
 920 void Ent_Remove()
 921 {
 922         if(self.entremove)
 923                 self.entremove();
 924
 925         self.enttype = 0;
 926         self.classname = "";
 927         self.draw = menu_sub_null;
 928         self.entremove = menu_sub_null;
 929         // TODO possibly set more stuff to defaults
 930 }
 931 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 932 void CSQC_Ent_Remove()
 933 {
 934         if(self.enttype)
 935                 Ent_Remove();
 936         remove(self);
 937 }
 938
 939 void Gamemode_Init()
 940 {
 941         if(gametype == GAME_ONSLAUGHT) {
 942                 print(strcat("Using ", minimapname, " as minimap.\n"));
 943                 precache_pic("gfx/ons-cp-neutral.tga");
 944                 precache_pic("gfx/ons-cp-red.tga");
 945                 precache_pic("gfx/ons-cp-blue.tga");
 946                 precache_pic("gfx/ons-frame.tga");
 947                 precache_pic("gfx/ons-frame-team.tga");
 948         } else if(gametype == GAME_KEYHUNT) {
 949                 precache_pic("gfx/sb_key_carrying");
 950                 precache_pic("gfx/sb_key_carrying_outline");
 951         }
 952
 953         if not(isdemo())
 954         {
 955                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), ";");
 956                 calledhooks |= HOOK_START;
 957         }
 958 }
 959 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 960 void CSQC_Parse_StuffCmd(string strMessage)
 961 {
 962         localcmd(strMessage);
 963 }
 964 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 965 void CSQC_Parse_Print(string strMessage)
 966 {
 967         print(ColorTranslateRGB(strMessage));
 968 }
 969
 970 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
 971 void CSQC_Parse_CenterPrint(string strMessage)
 972 {
 973         centerprint(strMessage);
 974 }
 975
 976 string notranslate_fogcmd1 = "\nfog ";
 977 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 978 void Fog_Force()
 979 {
 980         // TODO somehow thwart prvm_globalset client ...
 981
 982         if(forcefog != "")
 983                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 984 }
 985
 986 void Gamemode_Init();
 987 void Ent_ScoresInfo()
 988 {
 989         float i;
 990         self.classname = "ent_client_scores_info";
 991         gametype = ReadByte();
 992         for(i = 0; i < MAX_SCORE; ++i)
 993         {
 994                 scores_label[i] = strzone(ReadString());
 995                 scores_flags[i] = ReadByte();
 996         }
 997         for(i = 0; i < MAX_TEAMSCORE; ++i)
 998         {
 999                 teamscores_label[i] = strzone(ReadString());
1000                 teamscores_flags[i] = ReadByte();
1001         }
1002         Sbar_InitScores();
1003         Gamemode_Init();
1004 }
1005
1006 void Ent_Init()
1007 {
1008         self.classname = "ent_client_init";
1009
1010         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1011
1012         hook_shotorigin_x = ReadCoord();
1013         hook_shotorigin_y = ReadCoord();
1014         hook_shotorigin_z = ReadCoord();
1015
1016         if(forcefog)
1017                 strunzone(forcefog);
1018         forcefog = strzone(ReadString());
1019
1020         armorblockpercent = ReadByte() / 255.0;
1021
1022         g_weaponswitchdelay = ReadByte() / 255.0;
1023
1024         g_balance_grenadelauncher_secondary_bouncefactor = ReadCoord();
1025         g_balance_grenadelauncher_secondary_bouncestop = ReadCoord();
1026
1027         if(!postinit)
1028                 PostInit();
1029 }
1030
1031 void Net_ReadRace()
1032 {
1033         float b;
1034
1035         b = ReadByte();
1036
1037         switch(b)
1038         {
1039                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1040                         race_checkpoint = ReadByte();
1041                         race_time = ReadInt24_t();
1042                         race_previousbesttime = ReadInt24_t();
1043                         if(race_previousbestname)
1044                                 strunzone(race_previousbestname);
1045                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1046
1047                         race_checkpointtime = time;
1048
1049                         if(race_checkpoint == 0 || race_checkpoint == 254)
1050                         {
1051                                 race_penaltyaccumulator = 0;
1052                                 race_laptime = time; // valid
1053                         }
1054
1055                         break;
1056
1057                 case RACE_NET_CHECKPOINT_CLEAR:
1058                         race_laptime = 0;
1059                         race_checkpointtime = 0;
1060                         break;
1061
1062                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1063                         race_laptime = ReadCoord();
1064                         race_checkpointtime = -99999;
1065                         // fall through
1066                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1067                         race_nextcheckpoint = ReadByte();
1068
1069                         race_nextbesttime = ReadInt24_t();
1070                         if(race_nextbestname)
1071                                 strunzone(race_nextbestname);
1072                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1073                         break;
1074
1075                 case RACE_NET_CHECKPOINT_HIT_RACE:
1076                         race_mycheckpoint = ReadByte();
1077                         race_mycheckpointtime = time;
1078                         race_mycheckpointdelta = ReadInt24_t();
1079                         race_mycheckpointlapsdelta = ReadByte();
1080                         if(race_mycheckpointlapsdelta >= 128)
1081                                 race_mycheckpointlapsdelta -= 256;
1082                         if(race_mycheckpointenemy)
1083                                 strunzone(race_mycheckpointenemy);
1084                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1085                         break;
1086
1087                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1088                         race_othercheckpoint = ReadByte();
1089                         race_othercheckpointtime = time;
1090                         race_othercheckpointdelta = ReadInt24_t();
1091                         race_othercheckpointlapsdelta = ReadByte();
1092                         if(race_othercheckpointlapsdelta >= 128)
1093                                 race_othercheckpointlapsdelta -= 256;
1094                         if(race_othercheckpointenemy)
1095                                 strunzone(race_othercheckpointenemy);
1096                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1097                         break;
1098
1099                 case RACE_NET_PENALTY_RACE:
1100                         race_penaltyeventtime = time;
1101                         race_penaltytime = ReadShort();
1102                         //race_penaltyaccumulator += race_penaltytime;
1103                         if(race_penaltyreason)
1104                                 strunzone(race_penaltyreason);
1105                         race_penaltyreason = strzone(ReadString());
1106                         break;
1107
1108                 case RACE_NET_PENALTY_QUALIFYING:
1109                         race_penaltyeventtime = time;
1110                         race_penaltytime = ReadShort();
1111                         race_penaltyaccumulator += race_penaltytime;
1112                         if(race_penaltyreason)
1113                                 strunzone(race_penaltyreason);
1114                         race_penaltyreason = strzone(ReadString());
1115                         break;
1116
1117                 case RACE_NET_SERVER_RECORD:
1118                         race_server_record = ReadInt24_t();
1119                         break;
1120                 case RACE_NET_SPEED_AWARD:
1121                         race_speedaward = ReadInt24_t();
1122                         if(race_speedaward_holder)
1123                                 strunzone(race_speedaward_holder);
1124                         race_speedaward_holder = strzone(ReadString());
1125                         break;
1126                 case RACE_NET_SPEED_AWARD_BEST:
1127                         race_speedaward_alltimebest = ReadInt24_t();
1128                         if(race_speedaward_alltimebest_holder)
1129                                 strunzone(race_speedaward_alltimebest_holder);
1130                         race_speedaward_alltimebest_holder = strzone(ReadString());
1131                         break;
1132                 case RACE_NET_SERVER_RANKINGS:
1133                         float pos, prevpos, del;
1134                         pos = ReadShort();
1135                         prevpos = ReadShort();
1136                         del = ReadShort();
1137
1138                         // move other rankings out of the way
1139                         float i;
1140                         if (prevpos) {
1141                                 for (i=prevpos-1;i>pos-1;--i) {
1142                                         grecordtime[i] = grecordtime[i-1];
1143                                         if(grecordholder[i])
1144                                                 strunzone(grecordholder[i]);
1145                                         grecordholder[i] = strzone(grecordholder[i-1]);
1146                                 }
1147                         } else if (del) { // a record has been deleted by the admin
1148                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1149                                         if (i == RANKINGS_CNT-1) { // clear out last record
1150                                                 grecordtime[i] = 0;
1151                                                 if (grecordholder[i])
1152                                                         strunzone(grecordholder[i]);
1153                                                 grecordholder[i] = string_null;
1154                                         }
1155                                         else {
1156                                                 grecordtime[i] = grecordtime[i+1];
1157                                                 if (grecordholder[i])
1158                                                         strunzone(grecordholder[i]);
1159                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1160                                         }
1161                                 }
1162                         } else { // player has no ranked record yet
1163                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1164                                         grecordtime[i] = grecordtime[i-1];
1165                                         if(grecordholder[i])
1166                                                 strunzone(grecordholder[i]);
1167                                         grecordholder[i] = strzone(grecordholder[i-1]);
1168                                 }
1169                         }
1170
1171                         // store new ranking
1172                         if(grecordholder[pos-1] != "")
1173                                 strunzone(grecordholder[pos-1]);
1174                         grecordholder[pos-1] = strzone(ReadString());
1175                         grecordtime[pos-1] = ReadInt24_t();
1176                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1177                                 race_myrank = pos;
1178                         break;
1179                 case RACE_NET_SERVER_STATUS:
1180                         race_status = ReadShort();
1181                         if(race_status_name)
1182                                 strunzone(race_status_name);
1183                         race_status_name = strzone(ReadString());
1184         }
1185 }
1186
1187 void Net_ReadSpawn()
1188 {
1189         zoomin_effect = 1;
1190         current_viewzoom = 0.6;
1191 }
1192
1193 void Net_TeamNagger()
1194 {
1195         teamnagger = 1;
1196 }
1197
1198 void Net_ReadPingPLReport()
1199 {
1200         float e, pi, pl, ml;
1201         e = ReadByte();
1202         pi = ReadShort();
1203         pl = ReadByte();
1204         ml = ReadByte();
1205         if not(playerslots[e])
1206                 return;
1207         playerslots[e].ping = pi;
1208         playerslots[e].ping_packetloss = pl / 255.0;
1209         playerslots[e].ping_movementloss = ml / 255.0;
1210 }
1211
1212 void Net_VoteDialog(float highlight) {
1213         if(highlight) {
1214                 vote_highlighted = ReadShort();
1215                 return;
1216         }
1217
1218         vote_yescount = ReadShort();
1219         vote_nocount = ReadShort();
1220         vote_needed = ReadShort();
1221         vote_active = 1;
1222 }
1223
1224 void Net_VoteDialogReset() {
1225         vote_active = 0;
1226 }
1227
1228 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1229 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1230 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1231 float CSQC_Parse_TempEntity()
1232 {
1233         local float bHandled;
1234                 bHandled  = true;
1235         // Acquire TE ID
1236         local float nTEID;
1237                 nTEID = ReadByte();
1238
1239                 // NOTE: Could just do return instead of break...
1240         switch(nTEID)
1241         {
1242                 case TE_CSQC_TARGET_MUSIC:
1243                         Net_TargetMusic();
1244                         bHandled = true;
1245                         break;
1246                 case TE_CSQC_PICTURE:
1247                         Net_MapVote_Picture();
1248                         bHandled = true;
1249                         break;
1250                 case TE_CSQC_RACE:
1251                         Net_ReadRace();
1252                         bHandled = true;
1253                         break;
1254                 case 13: // TE_BEAM
1255                         Net_GrapplingHook();
1256                         bHandled = true;
1257                         break;
1258                 case TE_CSQC_SPAWN:
1259                         Net_ReadSpawn();
1260                         bHandled = true;
1261                         break;
1262                 case TE_CSQC_ZCURVEPARTICLES:
1263                         Net_ReadZCurveParticles();
1264                         bHandled = true;
1265                         break;
1266                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1267                         Net_ReadNexgunBeamParticle();
1268                         bHandled = true;
1269                         break;
1270                 case TE_CSQC_TEAMNAGGER:
1271                         Net_TeamNagger();
1272                         bHandled = true;
1273                         break;
1274                 case TE_CSQC_VOTE:
1275                         Net_VoteDialog(ReadByte());
1276                         bHandled = true;
1277                         break;
1278                 case TE_CSQC_VOTERESET:
1279                         Net_VoteDialogReset();
1280                         bHandled = true;
1281                         break;
1282                 case TE_CSQC_LIGHTNINGARC:
1283                         Net_ReadLightningarc();
1284                         bHandled = true;
1285                         break;
1286                 case TE_CSQC_PINGPLREPORT:
1287                         Net_ReadPingPLReport();
1288                         bHandled = true;
1289                         break;
1290                 case TE_CSQC_ANNOUNCE:
1291                         announce_snd = strzone(ReadString());
1292                         bHandled = true;
1293                         break;
1294                 default:
1295                         // No special logic for this temporary entity; return 0 so the engine can handle it
1296                         bHandled = false;
1297                         break;
1298         }
1299
1300         return bHandled;
1301 }
1302
1303 string getcommandkey(string text, string command)
1304 {
1305         string keys;
1306         float n, j, k, l;
1307
1308         if (!sbar_showbinds)
1309                 return text;
1310
1311         keys = db_get(binddb, command);
1312         if (!keys)
1313         {
1314                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1315                 for(j = 0; j < n; ++j)
1316                 {
1317                         k = stof(argv(j));
1318                         if(k != -1)
1319                         {
1320                                 if ("" == keys)
1321                                         keys = keynumtostring(k);
1322                                 else
1323                                         keys = strcat(keys, ", ", keynumtostring(k));
1324
1325                                 ++l;
1326                                 if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;
1327                         }
1328
1329                 }
1330                 db_put(binddb, command, keys);
1331         }
1332
1333         if ("" == keys) {
1334                 if (sbar_showbinds > 1)
1335                         return strcat(text, " (not bound)");
1336                 else
1337                         return text;
1338         }
1339         else if (sbar_showbinds > 1)
1340                 return strcat(text, " (", keys, ")");
1341         else
1342                 return keys;
1343 }