qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void menu_show_error()
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 }
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void menu_sub_null()
  37 {
  38 }
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 void WaypointSprite_Load();
  46 void CSQC_Init(void)
  47 {
  48         prvm_language = cvar_string("prvm_language");
  49
  50 #ifdef USE_FTE
  51 #pragma target ID
  52         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  53         if(!__engine_check)
  54         {
  55                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  56                 localcmd("\ndisconnect\n");
  57                 return;
  58         }
  59 #pragma target FTE
  60 #endif
  61
  62         check_unacceptable_compiler_bugs();
  63
  64 #ifdef WATERMARK
  65         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  66 #endif
  67
  68         float i;
  69
  70         binddb = db_create();
  71         tempdb = db_create();
  72         ClientProgsDB = db_load("client.db");
  73         compressShortVector_init();
  74
  75         drawfont = FONT_USER+1;
  76         menu_visible = FALSE;
  77         menu_show = menu_show_error;
  78         menu_action = menu_sub_null;
  79
  80         for(i = 0; i < 255; ++i)
  81                 if(getplayerkey(i, "viewentity") == "")
  82                         break;
  83         maxclients = i;
  84
  85         registercmd("hud_configure");
  86         registercmd("hud_save");
  87         //registercmd("menu_action");
  88
  89         registercmd("+showscores");registercmd("-showscores");
  90         registercmd("+showaccuracy");registercmd("-showaccuracy");
  91
  92 #ifndef CAMERATEST
  93         if(isdemo())
  94         {
  95 #endif
  96                 registercmd("+forward");registercmd("-forward");
  97                 registercmd("+back");registercmd("-back");
  98                 registercmd("+moveup");registercmd("-moveup");
  99                 registercmd("+movedown");registercmd("-movedown");
 100                 registercmd("+moveright");registercmd("-moveright");
 101                 registercmd("+moveleft");registercmd("-moveleft");
 102                 registercmd("+roll_right");registercmd("-roll_right");
 103                 registercmd("+roll_left");registercmd("-roll_left");
 104 #ifndef CAMERATEST
 105         }
 106 #endif
 107         registercvar("hud_usecsqc", "1");
 108         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 109
 110         gametype = 0;
 111
 112         // hud_fields uses strunzone on the titles!
 113         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 114                 hud_title[i] = strzone("(null)");
 115
 116         postinit = false;
 117
 118         calledhooks = 0;
 119
 120         teams = Sort_Spawn();
 121         players = Sort_Spawn();
 122
 123         GetTeam(COLOR_SPECTATOR, true); // add specs first
 124
 125         RegisterWeapons();
 126
 127         WaypointSprite_Load();
 128
 129         // precaches
 130         precache_sound("misc/hit.wav");
 131         precache_sound("misc/typehit.wav");
 132         Projectile_Precache();
 133         Hook_Precache();
 134         GibSplash_Precache();
 135         Casings_Precache();
 136         DamageInfo_Precache();
 137         Vehicles_Precache();
 138         turrets_precache();
 139   Announcer_Precache();
 140         Tuba_Precache();
 141
 142         if(autocvar_cl_reticle)
 143         {
 144                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 145                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 146         }
 147
 148         get_mi_min_max_texcoords(1); // try the CLEVER way first
 149         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 150         shortmapname = mi_shortname;
 151
 152         if(precache_pic(minimapname) == "")
 153         {
 154                 // but maybe we have a non-clever minimap
 155                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 156                 if(precache_pic(minimapname) == "")
 157                         minimapname = ""; // FAIL
 158                 else
 159                         get_mi_min_max_texcoords(0); // load new texcoords
 160         }
 161
 162         mi_center = (mi_min + mi_max) * 0.5;
 163         mi_scale = mi_max - mi_min;
 164         minimapname = strzone(minimapname);
 165
 166         WarpZone_Init();
 167
 168         hud_configure_prev = -1;
 169         tab_panel = -1;
 170 }
 171
 172 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 173 void CSQC_Shutdown(void)
 174 {
 175 #ifdef USE_FTE
 176 #pragma TARGET id
 177         if(!__engine_check)
 178                 return 0;
 179 #pragma TARGET fte
 180 #endif
 181
 182         WarpZone_Shutdown();
 183
 184         remove(teams);
 185         remove(players);
 186         db_close(binddb);
 187         db_close(tempdb);
 188         if(autocvar_cl_db_saveasdump)
 189                 db_dump(ClientProgsDB, "client.db");
 190         else
 191                 db_save(ClientProgsDB, "client.db");
 192         db_close(ClientProgsDB);
 193
 194         cvar_clientsettemp_restore();
 195
 196         if(camera_active)
 197                 cvar_set("chase_active",ftos(chase_active_backup));
 198
 199         // unset the event chasecam's chase_active
 200         if(autocvar_chase_active < 0)
 201                 cvar_set("chase_active", "0");
 202
 203         if not(isdemo())
 204         {
 205                 if not(calledhooks & HOOK_START)
 206                         localcmd("\n_cl_hook_gamestart nop\n");
 207                 if not(calledhooks & HOOK_END)
 208                         localcmd("\ncl_hook_gameend\n");
 209         }
 210 }
 211
 212 .float has_team;
 213 float SetTeam(entity o, float Team)
 214 {
 215         entity tm;
 216         if(teamplay)
 217         {
 218                 switch(Team)
 219                 {
 220                         case -1:
 221                         case COLOR_TEAM1:
 222                         case COLOR_TEAM2:
 223                         case COLOR_TEAM3:
 224                         case COLOR_TEAM4:
 225                                 break;
 226                         default:
 227                                 if(GetTeam(Team, false) == NULL)
 228                                 {
 229                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 230                                         Team = COLOR_SPECTATOR;
 231                                 }
 232                                 break;
 233                 }
 234         }
 235         else
 236         {
 237                 switch(Team)
 238                 {
 239                         case -1:
 240                         case 0:
 241                                 break;
 242                         default:
 243                                 if(GetTeam(Team, false) == NULL)
 244                                 {
 245                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 246                                         Team = COLOR_SPECTATOR;
 247                                 }
 248                                 break;
 249                 }
 250         }
 251         if(Team == -1) // leave
 252         {
 253                 if(o.has_team)
 254                 {
 255                         tm = GetTeam(o.team, false);
 256                         tm.team_size -= 1;
 257                         o.has_team = 0;
 258                         return TRUE;
 259                 }
 260         }
 261         else
 262         {
 263                 if not(o.has_team)
 264                 {
 265                         o.team = Team;
 266                         tm = GetTeam(Team, true);
 267                         tm.team_size += 1;
 268                         o.has_team = 1;
 269                         return TRUE;
 270                 }
 271                 else if(Team != o.team)
 272                 {
 273                         tm = GetTeam(o.team, false);
 274                         tm.team_size -= 1;
 275                         o.team = Team;
 276                         tm = GetTeam(Team, true);
 277                         tm.team_size += 1;
 278                         return TRUE;
 279                 }
 280         }
 281         return FALSE;
 282 }
 283
 284 void Playerchecker_Think()
 285 {
 286         float i;
 287         entity e;
 288         for(i = 0; i < maxclients; ++i)
 289         {
 290                 e = playerslots[i];
 291                 if(GetPlayerName(i) == "")
 292                 {
 293                         if(e.sort_prev)
 294                         {
 295                                 // player disconnected
 296                                 SetTeam(e, -1);
 297                                 RemovePlayer(e);
 298                                 e.sort_prev = world;
 299                                 //e.gotscores = 0;
 300                         }
 301                 }
 302                 else
 303                 {
 304                         if not(e.sort_prev)
 305                         {
 306                                 // player connected
 307                                 if not(e)
 308                                         playerslots[i] = e = spawn();
 309                                 e.sv_entnum = i;
 310                                 e.ping = 0;
 311                                 e.ping_packetloss = 0;
 312                                 e.ping_movementloss = 0;
 313                                 //e.gotscores = 0; // we might already have the scores...
 314                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 315                                 RegisterPlayer(e);
 316                                 HUD_UpdatePlayerPos(e);
 317                         }
 318                 }
 319         }
 320         self.nextthink = time + 0.2;
 321 }
 322
 323 void Porto_Init();
 324 void TrueAim_Init();
 325 void PostInit(void)
 326 {
 327         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 328
 329         entity playerchecker;
 330         playerchecker = spawn();
 331         playerchecker.think = Playerchecker_Think;
 332         playerchecker.nextthink = time + 0.2;
 333
 334         Porto_Init();
 335         TrueAim_Init();
 336
 337         postinit = true;
 338 }
 339
 340 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 341 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 342 float button_zoom;
 343 void Cmd_HUD_SetFields(float);
 344 void Cmd_HUD_Help(float);
 345 float CSQC_ConsoleCommand(string strMessage)
 346 {
 347         float argc;
 348         // Tokenize String
 349         argc = tokenize_console(strMessage);
 350
 351         // Acquire Command
 352         string strCmd;
 353         strCmd = argv(0);
 354
 355         if(strCmd == "hud_configure") { // config hud
 356                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 357                 return true;
 358         } else if(strCmd == "hud_save") { // save hud config
 359                 if(argv(1) == "" || argv(2)) {
 360                         print(_("Usage:\n"));
 361                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 362                 }
 363                 else
 364                         HUD_Panel_ExportCfg(argv(1));
 365                 return true;
 366         } else if(strCmd == "+showscores") {
 367                 scoreboard_showscores = true;
 368                 return true;
 369         } else if(strCmd == "-showscores") {
 370                 scoreboard_showscores = false;
 371                 return true;
 372         } else if(strCmd == "+showaccuracy") {
 373                 scoreboard_showaccuracy = true;
 374                 return true;
 375         } else if(strCmd == "-showaccuracy") {
 376                 scoreboard_showaccuracy = false;
 377                 return true;
 378         }
 379
 380         if(camera_active)
 381         if(strCmd == "+forward" || strCmd == "-back") {
 382                 ++camera_direction_x;
 383                 return true;
 384         } else if(strCmd == "-forward" || strCmd == "+back") {
 385                 --camera_direction_x;
 386                 return true;
 387         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 388                 --camera_direction_y;
 389                 return true;
 390         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 391                 ++camera_direction_y;
 392                 return true;
 393         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 394                 ++camera_direction_z;
 395                 return true;
 396         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 397                 --camera_direction_z;
 398                 return true;
 399         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 400                 ++camera_roll;
 401                 return true;
 402         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 403                 --camera_roll;
 404                 return true;
 405         }
 406
 407         return false;
 408 }
 409
 410 .vector view_ofs;
 411 entity debug_shotorg;
 412 void ShotOrg_Draw()
 413 {
 414         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 415         self.angles = view_angles;
 416         self.angles_x = -self.angles_x;
 417         if not(self.cnt)
 418                 self.drawmask = MASK_NORMAL;
 419         else
 420                 self.drawmask = 0;
 421 }
 422 void ShotOrg_Draw2D()
 423 {
 424         vector coord2d_topleft, coord2d_topright, coord2d;
 425         string s;
 426         vector fs;
 427
 428         s = vtos(self.view_ofs);
 429         s = substring(s, 1, strlen(s) - 2);
 430         if(tokenize_console(s) == 3)
 431                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 432
 433         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 434         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 435
 436         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 437
 438         coord2d = coord2d_topleft;
 439         if(fs_x < 8)
 440         {
 441                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 442                 fs = '8 8 0';
 443         }
 444         coord2d_y -= fs_y;
 445         coord2d_z = 0;
 446         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 447 }
 448
 449 void ShotOrg_Spawn()
 450 {
 451         debug_shotorg = spawn();
 452         debug_shotorg.draw = ShotOrg_Draw;
 453         debug_shotorg.draw2d = ShotOrg_Draw2D;
 454         debug_shotorg.renderflags = RF_VIEWMODEL;
 455         debug_shotorg.effects = EF_FULLBRIGHT;
 456         precache_model("models/shotorg_adjuster.md3");
 457         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 458         debug_shotorg.scale = 2;
 459         debug_shotorg.view_ofs = '25 8 -8';
 460 }
 461
 462 void DrawDebugModel()
 463 {
 464         if(time - floor(time) > 0.5)
 465         {
 466                 PolyDrawModel(self);
 467                 self.drawmask = 0;
 468         }
 469         else
 470         {
 471                 self.renderflags = 0;
 472                 self.drawmask = MASK_NORMAL;
 473         }
 474 }
 475
 476 void GameCommand(string msg)
 477 {
 478         string s;
 479         float argc;
 480         entity e;
 481         argc = tokenize_console(msg);
 482
 483         if(argv(0) == "help" || argc == 0)
 484         {
 485                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 486                 print(_("  settemp cvar value\n"));
 487                 print(_("  scoreboard_columns_set ...\n"));
 488                 print(_("  scoreboard_columns_help\n"));
 489                 GameCommand_Generic("help");
 490                 return;
 491         }
 492
 493         if(GameCommand_Generic(msg))
 494                 return;
 495
 496         string cmd;
 497         cmd = argv(0);
 498         if(cmd == "mv_download") {
 499                 Cmd_MapVote_MapDownload(argc);
 500         }
 501         else if(cmd == "hud_panel_radar_maximized")
 502         {
 503                 if(argc == 1)
 504                         hud_panel_radar_maximized = !hud_panel_radar_maximized;
 505                 else
 506                         hud_panel_radar_maximized = (stof(argv(1)) != 0);
 507         }
 508         else if(cmd == "settemp") {
 509                 cvar_clientsettemp(argv(1), argv(2));
 510         }
 511         else if(cmd == "scoreboard_columns_set") {
 512                 Cmd_HUD_SetFields(argc);
 513         }
 514         else if(cmd == "scoreboard_columns_help") {
 515                 Cmd_HUD_Help(argc);
 516         }
 517 #ifdef BLURTEST
 518         else if(cmd == "blurtest") {
 519                 blurtest_time0 = time;
 520                 blurtest_time1 = time + stof(argv(1));
 521                 blurtest_radius = stof(argv(2));
 522                 blurtest_power = stof(argv(3));
 523         }
 524 #endif
 525         else if(cmd == "shotorg_move") {
 526                 if(!debug_shotorg)
 527                         ShotOrg_Spawn();
 528                 else
 529                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 530                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 531         }
 532         else if(cmd == "shotorg_movez") {
 533                 if(!debug_shotorg)
 534                         ShotOrg_Spawn();
 535                 else
 536                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 537                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 538         }
 539         else if(cmd == "shotorg_set") {
 540                 if(!debug_shotorg)
 541                         ShotOrg_Spawn();
 542                 else
 543                         debug_shotorg.view_ofs = stov(argv(1));
 544                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 545         }
 546         else if(cmd == "shotorg_setz") {
 547                 if(!debug_shotorg)
 548                         ShotOrg_Spawn();
 549                 else
 550                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 551                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 552         }
 553         else if(cmd == "shotorg_toggle_hide") {
 554                 if(debug_shotorg)
 555                 {
 556                         debug_shotorg.cnt = !debug_shotorg.cnt;
 557                 }
 558         }
 559         else if(cmd == "shotorg_end") {
 560                 if(debug_shotorg)
 561                 {
 562                         print(vtos(debug_shotorg.view_ofs), "\n");
 563                         remove(debug_shotorg);
 564                         debug_shotorg = world;
 565                 }
 566                 localcmd("sv_cmd debug_shotorg\n");
 567         }
 568         else if(cmd == "sendcvar") {
 569                 // W_FixWeaponOrder will trash argv, so save what we need.
 570                 string thiscvar;
 571                 thiscvar = strzone(argv(1));
 572                 s = cvar_string(thiscvar);
 573                 if(thiscvar == "cl_weaponpriority")
 574                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 575                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 576                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 577                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 578                 strunzone(thiscvar);
 579         }
 580         else if(cmd == "spawn") {
 581                 s = argv(1);
 582                 e = spawn();
 583                 precache_model(s);
 584                 setmodel(e, s);
 585                 setorigin(e, view_origin);
 586                 e.angles = view_angles;
 587                 e.draw = DrawDebugModel;
 588                 e.classname = "debugmodel";
 589         }
 590     else if(cmd == "vyes")
 591     {
 592         if(uid2name_dialog)
 593         {
 594             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 595             vote_prev = 0;
 596             localcmd("setreport cl_allow_uid2name 1\n");
 597             vote_change = -9999;
 598                         uid2name_dialog = 0;
 599         }
 600         else
 601         {
 602             localcmd("cmd vote yes\n");
 603         }
 604     }
 605     else if(cmd == "vno")
 606     {
 607         if(uid2name_dialog)
 608         {
 609             vote_active = 0;
 610             vote_prev = 0;
 611             localcmd("setreport cl_allow_uid2name 0\n");
 612             vote_change = -9999;
 613                         uid2name_dialog = 0;
 614         }
 615         else
 616         {
 617             localcmd("cmd vote no\n");
 618         }
 619     }
 620
 621         else
 622         {
 623                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 624         }
 625
 626         return;
 627 }
 628
 629 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 630 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 631 // All keys are in ascii.
 632 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 633 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 634 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 635 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 636 {
 637         float bSkipKey;
 638         bSkipKey = false;
 639
 640         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 641                 return true;
 642
 643         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 644                 return true;
 645
 646         if(menu_visible)
 647                 if(menu_action(bInputType, nPrimary, nSecondary))
 648                         return TRUE;
 649
 650         return bSkipKey;
 651 }
 652
 653 // END REQUIRED CSQC FUNCTIONS
 654 // --------------------------------------------------------------------------
 655
 656 // --------------------------------------------------------------------------
 657 // BEGIN OPTIONAL CSQC FUNCTIONS
 658 void Ent_RemoveEntCS()
 659 {
 660         entcs_receiver[self.sv_entnum] = world;
 661 }
 662 void Ent_ReadEntCS()
 663 {
 664         float sf;
 665         InterpolateOrigin_Undo();
 666
 667         self.classname = "entcs_receiver";
 668         sf = ReadByte();
 669
 670         if(sf & 1)
 671                 self.sv_entnum = ReadByte();
 672         if(sf & 2)
 673         {
 674                 self.origin_x = ReadShort();
 675                 self.origin_y = ReadShort();
 676                 self.origin_z = ReadShort();
 677         }
 678         if(sf & 4)
 679         {
 680                 self.angles_y = ReadByte() * 360.0 / 256;
 681                 self.angles_x = self.angles_z = 0;
 682         }
 683         if(sf & 8)
 684                 self.healthvalue = ReadByte() * 10;
 685         if(sf & 16)
 686                 self.armorvalue = ReadByte() * 10;
 687
 688         entcs_receiver[self.sv_entnum] = self;
 689         self.entremove = Ent_RemoveEntCS;
 690
 691         InterpolateOrigin_Note();
 692 }
 693
 694 void Ent_Remove();
 695
 696 void Ent_RemovePlayerScore()
 697 {
 698         float i;
 699
 700         if(self.owner)
 701         {
 702                 SetTeam(self.owner, -1);
 703                 self.owner.gotscores = 0;
 704                 for(i = 0; i < MAX_SCORE; ++i)
 705                         self.owner.(scores[i]) = 0; // clear all scores
 706         }
 707 }
 708
 709 void Ent_ReadPlayerScore()
 710 {
 711         float i, n;
 712         float isNew;
 713         entity o;
 714
 715         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 716         // (no I've never heard of M-x replace-string, sed, or anything like that)
 717         isNew = !self.owner; // workaround for DP bug
 718         n = ReadByte()-1;
 719
 720 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 721         if(!isNew && n != self.sv_entnum)
 722         {
 723                 //print(_("A CSQC entity changed its owner!\n"));
 724                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 725                 isNew = true;
 726                 Ent_Remove();
 727                 self.enttype = ENT_CLIENT_SCORES;
 728         }
 729 #endif
 730
 731         self.sv_entnum = n;
 732
 733         if not(playerslots[self.sv_entnum])
 734                 playerslots[self.sv_entnum] = spawn();
 735         o = self.owner = playerslots[self.sv_entnum];
 736         o.sv_entnum = self.sv_entnum;
 737         o.gotscores = 1;
 738
 739         //if not(o.sort_prev)
 740         //      RegisterPlayer(o);
 741         //playerchecker will do this for us later, if it has not already done so
 742
 743         float sf, lf;
 744 #if MAX_SCORE <= 8
 745         sf = ReadByte();
 746         lf = ReadByte();
 747 #else
 748         sf = ReadShort();
 749         lf = ReadShort();
 750 #endif
 751         float p;
 752         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 753                 if(sf & p)
 754                 {
 755                         if(lf & p)
 756                                 o.(scores[i]) = ReadInt24_t();
 757                         else
 758                                 o.(scores[i]) = ReadChar();
 759                 }
 760
 761         if(o.sort_prev)
 762                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 763
 764         self.entremove = Ent_RemovePlayerScore;
 765 }
 766
 767 void Ent_ReadTeamScore()
 768 {
 769         float i;
 770         entity o;
 771
 772         self.team = ReadByte();
 773         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 774
 775         float sf, lf;
 776 #if MAX_TEAMSCORE <= 8
 777         sf = ReadByte();
 778         lf = ReadByte();
 779 #else
 780         sf = ReadShort();
 781         lf = ReadShort();
 782 #endif
 783         float p;
 784         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 785                 if(sf & p)
 786                 {
 787                         if(lf & p)
 788                                 o.(teamscores[i]) = ReadInt24_t();
 789                         else
 790                                 o.(teamscores[i]) = ReadChar();
 791                 }
 792
 793         HUD_UpdateTeamPos(o);
 794 }
 795
 796 void Ent_ClientData()
 797 {
 798         float f;
 799         float newspectatee_status;
 800
 801         f = ReadByte();
 802
 803         scoreboard_showscores_force = (f & 1);
 804
 805         if(f & 2)
 806         {
 807                 newspectatee_status = ReadByte();
 808                 if(newspectatee_status == player_localentnum)
 809                         newspectatee_status = -1; // observing
 810         }
 811         else
 812                 newspectatee_status = 0;
 813
 814         spectatorbutton_zoom = (f & 4);
 815
 816         if(f & 8)
 817         {
 818                 angles_held_status = 1;
 819                 angles_held_x = ReadAngle();
 820                 angles_held_y = ReadAngle();
 821                 angles_held_z = 0;
 822         }
 823         else
 824                 angles_held_status = 0;
 825
 826         if(newspectatee_status != spectatee_status)
 827         {
 828                 // clear race stuff
 829                 race_laptime = 0;
 830                 race_checkpointtime = 0;
 831         }
 832         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 833         {
 834                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 835                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 836                 )
 837                         prev_p_health = -1;
 838                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 839                         prev_health = -1;
 840         }
 841         spectatee_status = newspectatee_status;
 842 }
 843
 844 void Ent_Nagger()
 845 {
 846         float nags, i, j, b, f;
 847
 848         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 849
 850         if(!(nags & 4))
 851         {
 852                 if(vote_called_vote)
 853                         strunzone(vote_called_vote);
 854                 vote_called_vote = string_null;
 855                 vote_active = 0;
 856         }
 857         else
 858         {
 859                 vote_active = 1;
 860         }
 861
 862         if(nags & 64)
 863         {
 864                 vote_yescount = ReadByte();
 865                 vote_nocount = ReadByte();
 866                 vote_needed = ReadByte();
 867                 vote_highlighted = ReadChar();
 868         }
 869
 870         if(nags & 128)
 871         {
 872                 if(vote_called_vote)
 873                         strunzone(vote_called_vote);
 874                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 875         }
 876
 877         if(nags & 1)
 878         {
 879                 for(j = 0; j < maxclients; ++j)
 880                         if(playerslots[j])
 881                                 playerslots[j].ready = 1;
 882                 for(i = 1; i <= maxclients; i += 8)
 883                 {
 884                         f = ReadByte();
 885                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 886                                 if not(f & b)
 887                                         if(playerslots[j])
 888                                                 playerslots[j].ready = 0;
 889                 }
 890         }
 891
 892         ready_waiting = (nags & 1);
 893         ready_waiting_for_me = (nags & 2);
 894         vote_waiting = (nags & 4);
 895         vote_waiting_for_me = (nags & 8);
 896         warmup_stage = (nags & 16);
 897 }
 898
 899 void Ent_RandomSeed()
 900 {
 901         float s;
 902         prandom_debug();
 903         s = ReadShort();
 904         psrandom(s);
 905 }
 906
 907 void Ent_ReadAccuracy(void)
 908 {
 909         float sf, f, w, b;
 910         sf = ReadInt24_t();
 911         if(sf == 0)
 912         {
 913                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 914                         weapon_accuracy[w] = -1;
 915                 return;
 916         }
 917
 918         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 919         {
 920                 if(sf & f)
 921                 {
 922                         b = ReadByte();
 923                         if(b == 0)
 924                                 weapon_accuracy[w] = -1;
 925                         else if(b == 255)
 926                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 927                         else
 928                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 929                 }
 930         }
 931 }
 932
 933 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 934 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 935 void Ent_RadarLink();
 936 void Ent_Init();
 937 void Ent_ScoresInfo();
 938 void CSQC_Ent_Update(float bIsNewEntity)
 939 {
 940         float t;
 941         float savetime;
 942         t = ReadByte();
 943
 944         // set up the "time" global for received entities to be correct for interpolation purposes
 945         savetime = time;
 946         if(servertime)
 947         {
 948                 time = servertime;
 949         }
 950         else
 951         {
 952                 serverprevtime = time;
 953                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 954                 time = serverprevtime + serverdeltatime;
 955         }
 956
 957 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 958         if(self.enttype)
 959         {
 960                 if(t != self.enttype || bIsNewEntity)
 961                 {
 962                         //print(_("A CSQC entity changed its type!\n"));
 963                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 964                         Ent_Remove();
 965                         bIsNewEntity = 1;
 966                 }
 967         }
 968         else
 969         {
 970                 if(!bIsNewEntity)
 971                 {
 972                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 973                         bIsNewEntity = 1;
 974                 }
 975         }
 976 #endif
 977         self.enttype = t;
 978         switch(t)
 979         {
 980                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 981                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 982                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 983                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 984                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 985                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 986                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 987                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 988                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 989                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 990                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 991                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 992                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 993                 case ENT_CLIENT_INIT: Ent_Init(); break;
 994                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 995                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 996                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 997                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 998                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 999                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
1000                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
1001                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
1002                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
1003                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
1004                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
1005                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
1006                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
1007                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
1008                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
1009                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
1010                 case ENT_CLIENT_TURRET: ent_turret(); break;
1011                 default:
1012                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
1013                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
1014                         break;
1015         }
1016
1017         time = savetime;
1018 }
1019 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1020 // used when an entity changes its type. For an entity that someone interacts
1021 // with others, make sure it can no longer do so.
1022 void Ent_Remove()
1023 {
1024         if(self.entremove)
1025                 self.entremove();
1026
1027         self.enttype = 0;
1028         self.classname = "";
1029         self.draw = menu_sub_null;
1030         self.entremove = menu_sub_null;
1031         // TODO possibly set more stuff to defaults
1032 }
1033 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1034 void CSQC_Ent_Remove()
1035 {
1036         if(self.enttype)
1037                 Ent_Remove();
1038         remove(self);
1039 }
1040
1041 void Gamemode_Init()
1042 {
1043         if not(isdemo())
1044         {
1045                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1046                 calledhooks |= HOOK_START;
1047         }
1048 }
1049 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1050 void CSQC_Parse_StuffCmd(string strMessage)
1051 {
1052         localcmd(strMessage);
1053 }
1054 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1055 void CSQC_Parse_Print(string strMessage)
1056 {
1057         print(ColorTranslateRGB(strMessage));
1058 }
1059
1060 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1061 void CSQC_Parse_CenterPrint(string strMessage)
1062 {
1063         centerprint(strMessage);
1064 }
1065
1066 string notranslate_fogcmd1 = "\nfog ";
1067 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1068 void Fog_Force()
1069 {
1070         // TODO somehow thwart prvm_globalset client ...
1071
1072         if(forcefog != "")
1073                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1074 }
1075
1076 void Gamemode_Init();
1077 void Ent_ScoresInfo()
1078 {
1079         float i;
1080         self.classname = "ent_client_scores_info";
1081         gametype = ReadByte();
1082         for(i = 0; i < MAX_SCORE; ++i)
1083         {
1084                 scores_label[i] = strzone(ReadString());
1085                 scores_flags[i] = ReadByte();
1086         }
1087         for(i = 0; i < MAX_TEAMSCORE; ++i)
1088         {
1089                 teamscores_label[i] = strzone(ReadString());
1090                 teamscores_flags[i] = ReadByte();
1091         }
1092         HUD_InitScores();
1093         Gamemode_Init();
1094 }
1095
1096 void Ent_Init()
1097 {
1098         self.classname = "ent_client_init";
1099
1100         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1101
1102         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1103         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1104         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1105         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1106         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1107         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1108         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1109         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1110         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1111         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1112         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1113         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1114
1115         if(forcefog)
1116                 strunzone(forcefog);
1117         forcefog = strzone(ReadString());
1118
1119         armorblockpercent = ReadByte() / 255.0;
1120
1121         g_weaponswitchdelay = ReadByte() / 255.0;
1122
1123         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1124         g_balance_grenadelauncher_bouncestop = ReadCoord();
1125         g_balance_electro_secondary_bouncefactor = ReadCoord();
1126         g_balance_electro_secondary_bouncestop = ReadCoord();
1127
1128         nex_scope = !ReadByte();
1129         rifle_scope = !ReadByte();
1130
1131         serverflags = ReadByte();
1132
1133         minelayer_maxmines = ReadByte();
1134
1135         hagar_maxrockets = ReadByte();
1136
1137         g_trueaim_minrange = ReadCoord();
1138
1139         if(!postinit)
1140                 PostInit();
1141 }
1142
1143 void Net_ReadRace()
1144 {
1145         float b;
1146
1147         b = ReadByte();
1148
1149         switch(b)
1150         {
1151                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1152                         race_checkpoint = ReadByte();
1153                         race_time = ReadInt24_t();
1154                         race_previousbesttime = ReadInt24_t();
1155                         if(race_previousbestname)
1156                                 strunzone(race_previousbestname);
1157                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1158
1159                         race_checkpointtime = time;
1160
1161                         if(race_checkpoint == 0 || race_checkpoint == 254)
1162                         {
1163                                 race_penaltyaccumulator = 0;
1164                                 race_laptime = time; // valid
1165                         }
1166
1167                         break;
1168
1169                 case RACE_NET_CHECKPOINT_CLEAR:
1170                         race_laptime = 0;
1171                         race_checkpointtime = 0;
1172                         break;
1173
1174                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1175                         race_laptime = ReadCoord();
1176                         race_checkpointtime = -99999;
1177                         // fall through
1178                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1179                         race_nextcheckpoint = ReadByte();
1180
1181                         race_nextbesttime = ReadInt24_t();
1182                         if(race_nextbestname)
1183                                 strunzone(race_nextbestname);
1184                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1185                         break;
1186
1187                 case RACE_NET_CHECKPOINT_HIT_RACE:
1188                         race_mycheckpoint = ReadByte();
1189                         race_mycheckpointtime = time;
1190                         race_mycheckpointdelta = ReadInt24_t();
1191                         race_mycheckpointlapsdelta = ReadByte();
1192                         if(race_mycheckpointlapsdelta >= 128)
1193                                 race_mycheckpointlapsdelta -= 256;
1194                         if(race_mycheckpointenemy)
1195                                 strunzone(race_mycheckpointenemy);
1196                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1197                         break;
1198
1199                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1200                         race_othercheckpoint = ReadByte();
1201                         race_othercheckpointtime = time;
1202                         race_othercheckpointdelta = ReadInt24_t();
1203                         race_othercheckpointlapsdelta = ReadByte();
1204                         if(race_othercheckpointlapsdelta >= 128)
1205                                 race_othercheckpointlapsdelta -= 256;
1206                         if(race_othercheckpointenemy)
1207                                 strunzone(race_othercheckpointenemy);
1208                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1209                         break;
1210
1211                 case RACE_NET_PENALTY_RACE:
1212                         race_penaltyeventtime = time;
1213                         race_penaltytime = ReadShort();
1214                         //race_penaltyaccumulator += race_penaltytime;
1215                         if(race_penaltyreason)
1216                                 strunzone(race_penaltyreason);
1217                         race_penaltyreason = strzone(ReadString());
1218                         break;
1219
1220                 case RACE_NET_PENALTY_QUALIFYING:
1221                         race_penaltyeventtime = time;
1222                         race_penaltytime = ReadShort();
1223                         race_penaltyaccumulator += race_penaltytime;
1224                         if(race_penaltyreason)
1225                                 strunzone(race_penaltyreason);
1226                         race_penaltyreason = strzone(ReadString());
1227                         break;
1228
1229                 case RACE_NET_SERVER_RECORD:
1230                         race_server_record = ReadInt24_t();
1231                         break;
1232                 case RACE_NET_SPEED_AWARD:
1233                         race_speedaward = ReadInt24_t();
1234                         if(race_speedaward_holder)
1235                                 strunzone(race_speedaward_holder);
1236                         race_speedaward_holder = strzone(ReadString());
1237                         break;
1238                 case RACE_NET_SPEED_AWARD_BEST:
1239                         race_speedaward_alltimebest = ReadInt24_t();
1240                         if(race_speedaward_alltimebest_holder)
1241                                 strunzone(race_speedaward_alltimebest_holder);
1242                         race_speedaward_alltimebest_holder = strzone(ReadString());
1243                         break;
1244                 case RACE_NET_SERVER_RANKINGS:
1245                         float pos, prevpos, del;
1246                         pos = ReadShort();
1247                         prevpos = ReadShort();
1248                         del = ReadShort();
1249
1250                         // move other rankings out of the way
1251                         float i;
1252                         if (prevpos) {
1253                                 for (i=prevpos-1;i>pos-1;--i) {
1254                                         grecordtime[i] = grecordtime[i-1];
1255                                         if(grecordholder[i])
1256                                                 strunzone(grecordholder[i]);
1257                                         grecordholder[i] = strzone(grecordholder[i-1]);
1258                                 }
1259                         } else if (del) { // a record has been deleted by the admin
1260                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1261                                         if (i == RANKINGS_CNT-1) { // clear out last record
1262                                                 grecordtime[i] = 0;
1263                                                 if (grecordholder[i])
1264                                                         strunzone(grecordholder[i]);
1265                                                 grecordholder[i] = string_null;
1266                                         }
1267                                         else {
1268                                                 grecordtime[i] = grecordtime[i+1];
1269                                                 if (grecordholder[i])
1270                                                         strunzone(grecordholder[i]);
1271                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1272                                         }
1273                                 }
1274                         } else { // player has no ranked record yet
1275                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1276                                         grecordtime[i] = grecordtime[i-1];
1277                                         if(grecordholder[i])
1278                                                 strunzone(grecordholder[i]);
1279                                         grecordholder[i] = strzone(grecordholder[i-1]);
1280                                 }
1281                         }
1282
1283                         // store new ranking
1284                         if(grecordholder[pos-1] != "")
1285                                 strunzone(grecordholder[pos-1]);
1286                         grecordholder[pos-1] = strzone(ReadString());
1287                         grecordtime[pos-1] = ReadInt24_t();
1288                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1289                                 race_myrank = pos;
1290                         break;
1291                 case RACE_NET_SERVER_STATUS:
1292                         race_status = ReadShort();
1293                         if(race_status_name)
1294                                 strunzone(race_status_name);
1295                         race_status_name = strzone(ReadString());
1296         }
1297 }
1298
1299 void Net_ReadSpawn()
1300 {
1301         zoomin_effect = 1;
1302         current_viewzoom = 0.6;
1303 }
1304
1305 void Net_TeamNagger()
1306 {
1307         teamnagger = 1;
1308 }
1309
1310 void Net_ReadPingPLReport()
1311 {
1312         float e, pi, pl, ml;
1313         e = ReadByte();
1314         pi = ReadShort();
1315         pl = ReadByte();
1316         ml = ReadByte();
1317         if not(playerslots[e])
1318                 return;
1319         playerslots[e].ping = pi;
1320         playerslots[e].ping_packetloss = pl / 255.0;
1321         playerslots[e].ping_movementloss = ml / 255.0;
1322 }
1323
1324 void Net_WeaponComplain() {
1325         complain_weapon = ReadByte();
1326
1327         if(complain_weapon_name)
1328                 strunzone(complain_weapon_name);
1329         complain_weapon_name = strzone(ReadString());
1330
1331         complain_weapon_type = ReadByte();
1332
1333         complain_weapon_time = time;
1334         weapontime = time; // ping the weapon panel
1335 }
1336
1337 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1338 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1339 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1340 float CSQC_Parse_TempEntity()
1341 {
1342         float bHandled;
1343                 bHandled  = true;
1344         // Acquire TE ID
1345         float nTEID;
1346                 nTEID = ReadByte();
1347
1348                 // NOTE: Could just do return instead of break...
1349         switch(nTEID)
1350         {
1351                 case TE_CSQC_TARGET_MUSIC:
1352                         Net_TargetMusic();
1353                         bHandled = true;
1354                         break;
1355                 case TE_CSQC_PICTURE:
1356                         Net_MapVote_Picture();
1357                         bHandled = true;
1358                         break;
1359                 case TE_CSQC_RACE:
1360                         Net_ReadRace();
1361                         bHandled = true;
1362                         break;
1363                 case TE_CSQC_SPAWN:
1364                         Net_ReadSpawn();
1365                         bHandled = true;
1366                         break;
1367                 case TE_CSQC_ZCURVEPARTICLES:
1368                         Net_ReadZCurveParticles();
1369                         bHandled = true;
1370                         break;
1371                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1372                         Net_ReadNexgunBeamParticle();
1373                         bHandled = true;
1374                         break;
1375                 case TE_CSQC_TEAMNAGGER:
1376                         Net_TeamNagger();
1377                         bHandled = true;
1378                         break;
1379                 case TE_CSQC_LIGHTNINGARC:
1380                         Net_ReadLightningarc();
1381                         bHandled = true;
1382                         break;
1383                 case TE_CSQC_PINGPLREPORT:
1384                         Net_ReadPingPLReport();
1385                         bHandled = true;
1386                         break;
1387                 case TE_CSQC_ANNOUNCE:
1388                         Announcer_Play(ReadString());
1389                         bHandled = true;
1390                         break;
1391                 case TE_CSQC_KILLNOTIFY:
1392                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1393                         bHandled = true;
1394                         break;
1395                 case TE_CSQC_KILLCENTERPRINT:
1396                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1397                         bHandled = true;
1398                         break;
1399                 case TE_CSQC_CENTERPRINT_GENERIC:
1400                         float id;
1401                         string s;
1402                         id = ReadByte();
1403                         s = ReadString();
1404                         if (id != 0 && s != "")
1405                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1406                         else
1407                                 centerprint_generic(id, s, 0, 0);
1408                         bHandled = true;
1409                         break;
1410                 case TE_CSQC_WEAPONCOMPLAIN:
1411                         Net_WeaponComplain();
1412                         bHandled = true;
1413                         break;
1414                 case TE_CSQC_VEHICLESETUP:
1415                         Net_VehicleSetup();
1416                         bHandled = true;
1417                         break;
1418                 default:
1419                         // No special logic for this temporary entity; return 0 so the engine can handle it
1420                         bHandled = false;
1421                         break;
1422         }
1423
1424         return bHandled;
1425 }
1426
1427 string getcommandkey(string text, string command)
1428 {
1429         string keys;
1430         float n, j, k, l;
1431
1432         if (!autocvar_hud_showbinds)
1433                 return text;
1434
1435         keys = db_get(binddb, command);
1436         if (!keys)
1437         {
1438                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1439                 for(j = 0; j < n; ++j)
1440                 {
1441                         k = stof(argv(j));
1442                         if(k != -1)
1443                         {
1444                                 if ("" == keys)
1445                                         keys = keynumtostring(k);
1446                                 else
1447                                         keys = strcat(keys, ", ", keynumtostring(k));
1448
1449                                 ++l;
1450                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1451                         }
1452
1453                 }
1454                 db_put(binddb, command, keys);
1455         }
1456
1457         if ("" == keys) {
1458                 if (autocvar_hud_showbinds > 1)
1459                         return sprintf(_("%s (not bound)"), text);
1460                 else
1461                         return text;
1462         }
1463         else if (autocvar_hud_showbinds > 1)
1464                 return sprintf(_("%s (%s)"), text, keys);
1465         else
1466                 return keys;
1467 }