qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: %s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+button3");
  95         registercmd("-button3");
  96         registercmd("+button4");
  97         registercmd("-button4");
  98         registercmd("+showscores");registercmd("-showscores");
  99         registercmd("+showaccuracy");registercmd("-showaccuracy");
 100
 101 #ifndef CAMERATEST
 102         if(isdemo())
 103         {
 104 #endif
 105                 registercmd("+forward");registercmd("-forward");
 106                 registercmd("+back");registercmd("-back");
 107                 registercmd("+moveup");registercmd("-moveup");
 108                 registercmd("+movedown");registercmd("-movedown");
 109                 registercmd("+moveright");registercmd("-moveright");
 110                 registercmd("+moveleft");registercmd("-moveleft");
 111                 registercmd("+roll_right");registercmd("-roll_right");
 112                 registercmd("+roll_left");registercmd("-roll_left");
 113 #ifndef CAMERATEST
 114         }
 115 #endif
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 118
 119         gametype = 0;
 120
 121         // hud_fields uses strunzone on the titles!
 122         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 123                 hud_title[i] = strzone("(null)");
 124
 125         postinit = false;
 126
 127         calledhooks = 0;
 128
 129         teams = Sort_Spawn();
 130         players = Sort_Spawn();
 131
 132         GetTeam(COLOR_SPECTATOR, true); // add specs first
 133
 134         RegisterWeapons();
 135
 136         WaypointSprite_Load();
 137
 138         // precaches
 139         precache_sound("misc/hit.wav");
 140         precache_sound("misc/typehit.wav");
 141         Projectile_Precache();
 142         Hook_Precache();
 143         GibSplash_Precache();
 144         Casings_Precache();
 145         DamageInfo_Precache();
 146         if(autocvar_cl_announcer != cl_announcer_prev) {
 147                 Announcer_Precache();
 148                 if(cl_announcer_prev)
 149                         strunzone(cl_announcer_prev);
 150                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 151         }
 152         Tuba_Precache();
 153
 154         get_mi_min_max_texcoords(1); // try the CLEVER way first
 155         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 156         shortmapname = mi_shortname;
 157
 158         if(precache_pic(minimapname) == "")
 159         {
 160                 // but maybe we have a non-clever minimap
 161                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 162                 if(precache_pic(minimapname) == "")
 163                         minimapname = ""; // FAIL
 164                 else
 165                         get_mi_min_max_texcoords(0); // load new texcoords
 166         }
 167
 168         mi_center = (mi_min + mi_max) * 0.5;
 169         mi_scale = mi_max - mi_min;
 170         minimapname = strzone(minimapname);
 171
 172         WarpZone_Init();
 173         hud_configure_prev = -1;
 174 }
 175
 176 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 177 void CSQC_Shutdown(void)
 178 {
 179 #ifdef USE_FTE
 180 #pragma TARGET id
 181         if(!__engine_check)
 182                 return 0;
 183 #pragma TARGET fte
 184 #endif
 185
 186         WarpZone_Shutdown();
 187
 188         remove(teams);
 189         remove(players);
 190         db_close(binddb);
 191         db_close(tempdb);
 192         if(autocvar_cl_db_saveasdump)
 193                 db_dump(ClientProgsDB, "client.db");
 194         else
 195                 db_save(ClientProgsDB, "client.db");
 196         db_close(ClientProgsDB);
 197
 198         cvar_clientsettemp_restore();
 199
 200         if(camera_active)
 201                 cvar_set("chase_active",ftos(chase_active_backup));
 202
 203         if not(isdemo())
 204         {
 205                 if not(calledhooks & HOOK_START)
 206                         localcmd("\n_cl_hook_gamestart nop\n");
 207                 if not(calledhooks & HOOK_END)
 208                         localcmd("\ncl_hook_gameend\n");
 209         }
 210 }
 211
 212 .float has_team;
 213 float SetTeam(entity o, float Team)
 214 {
 215         entity tm;
 216         if(teamplay)
 217         {
 218                 switch(Team)
 219                 {
 220                         case -1:
 221                         case COLOR_TEAM1:
 222                         case COLOR_TEAM2:
 223                         case COLOR_TEAM3:
 224                         case COLOR_TEAM4:
 225                                 break;
 226                         default:
 227                                 if(GetTeam(Team, false) == NULL)
 228                                 {
 229                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 230                                         Team = COLOR_SPECTATOR;
 231                                 }
 232                                 break;
 233                 }
 234         }
 235         else
 236         {
 237                 switch(Team)
 238                 {
 239                         case -1:
 240                         case 0:
 241                                 break;
 242                         default:
 243                                 if(GetTeam(Team, false) == NULL)
 244                                 {
 245                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 246                                         Team = COLOR_SPECTATOR;
 247                                 }
 248                                 break;
 249                 }
 250         }
 251         if(Team == -1) // leave
 252         {
 253                 if(o.has_team)
 254                 {
 255                         tm = GetTeam(o.team, false);
 256                         tm.team_size -= 1;
 257                         o.has_team = 0;
 258                         return TRUE;
 259                 }
 260         }
 261         else
 262         {
 263                 if not(o.has_team)
 264                 {
 265                         o.team = Team;
 266                         tm = GetTeam(Team, true);
 267                         tm.team_size += 1;
 268                         o.has_team = 1;
 269                         return TRUE;
 270                 }
 271                 else if(Team != o.team)
 272                 {
 273                         tm = GetTeam(o.team, false);
 274                         tm.team_size -= 1;
 275                         o.team = Team;
 276                         tm = GetTeam(Team, true);
 277                         tm.team_size += 1;
 278                         return TRUE;
 279                 }
 280         }
 281         return FALSE;
 282 }
 283
 284 void Playerchecker_Think()
 285 {
 286         float i;
 287         entity e;
 288         for(i = 0; i < maxclients; ++i)
 289         {
 290                 e = playerslots[i];
 291                 if(GetPlayerName(i) == "")
 292                 {
 293                         if(e.sort_prev)
 294                         {
 295                                 // player disconnected
 296                                 SetTeam(e, -1);
 297                                 RemovePlayer(e);
 298                                 e.sort_prev = world;
 299                                 //e.gotscores = 0;
 300                         }
 301                 }
 302                 else
 303                 {
 304                         if not(e.sort_prev)
 305                         {
 306                                 // player connected
 307                                 if not(e)
 308                                         playerslots[i] = e = spawn();
 309                                 e.sv_entnum = i;
 310                                 e.ping = 0;
 311                                 e.ping_packetloss = 0;
 312                                 e.ping_movementloss = 0;
 313                                 //e.gotscores = 0; // we might already have the scores...
 314                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 315                                 RegisterPlayer(e);
 316                                 HUD_UpdatePlayerPos(e);
 317                         }
 318                 }
 319         }
 320         self.nextthink = time + 0.2;
 321 }
 322
 323 void Porto_Init();
 324 void TrueAim_Init();
 325 void PostInit(void)
 326 {
 327         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 328
 329         entity playerchecker;
 330         playerchecker = spawn();
 331         playerchecker.think = Playerchecker_Think;
 332         playerchecker.nextthink = time + 0.2;
 333
 334         Porto_Init();
 335         TrueAim_Init();
 336
 337         postinit = true;
 338 }
 339
 340 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 341 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 342 float button_zoom;
 343 void Cmd_HUD_SetFields(float);
 344 void Cmd_HUD_Help(float);
 345 float CSQC_ConsoleCommand(string strMessage)
 346 {
 347         float argc;
 348         // Tokenize String
 349         //argc = tokenize(strMessage);
 350         argc = tokenize_console(strMessage);
 351
 352         // Acquire Command
 353         local string strCmd;
 354         strCmd = argv(0);
 355
 356         if(strCmd == "hud_configure") { // config hud
 357                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 358                 return true;
 359         } else if(strCmd == "hud_save") { // save hud config
 360                 if(argv(1) == "" || argv(2)) {
 361                         print(_("Usage:\n"));
 362                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 363                 }
 364                 else
 365                         HUD_Panel_ExportCfg(argv(1));
 366                 return true;
 367         } else if(strCmd == "+button4") { // zoom
 368                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 369                 if(ignore_plus_zoom)
 370                 {
 371                         --ignore_plus_zoom;
 372                         return false;
 373                 }
 374                 button_zoom = 1;
 375                 return true;
 376         } else if(strCmd == "-button4") { // zoom
 377                 if(ignore_minus_zoom)
 378                 {
 379                         --ignore_minus_zoom;
 380                         return false;
 381                 }
 382                 button_zoom = 0;
 383                 return true;
 384         } else if(strCmd == "+button3") { // secondary
 385                 button_attack2 = 1;
 386                 return false;
 387         } else if(strCmd == "-button3") { // secondary
 388                 button_attack2 = 0;
 389                 return false;
 390         } else if(strCmd == "+showscores") {
 391                 scoreboard_showscores = true;
 392                 return true;
 393         } else if(strCmd == "-showscores") {
 394                 scoreboard_showscores = false;
 395                 return true;
 396         } else if(strCmd == "+showaccuracy") {
 397                 scoreboard_showaccuracy = true;
 398                 return true;
 399         } else if(strCmd == "-showaccuracy") {
 400                 scoreboard_showaccuracy = false;
 401                 return true;
 402         }
 403
 404         if(camera_active)
 405         if(strCmd == "+forward" || strCmd == "-back") {
 406                 ++camera_direction_x;
 407                 return true;
 408         } else if(strCmd == "-forward" || strCmd == "+back") {
 409                 --camera_direction_x;
 410                 return true;
 411         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 412                 --camera_direction_y;
 413                 return true;
 414         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 415                 ++camera_direction_y;
 416                 return true;
 417         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 418                 ++camera_direction_z;
 419                 return true;
 420         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 421                 --camera_direction_z;
 422                 return true;
 423         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 424                 ++camera_roll;
 425                 return true;
 426         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 427                 --camera_roll;
 428                 return true;
 429         }
 430
 431         return false;
 432 }
 433
 434 .vector view_ofs;
 435 entity debug_shotorg;
 436 void ShotOrg_Draw()
 437 {
 438         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 439         self.angles = view_angles;
 440         self.angles_x = -self.angles_x;
 441         if not(self.cnt)
 442                 self.drawmask = MASK_NORMAL;
 443         else
 444                 self.drawmask = 0;
 445 }
 446 void ShotOrg_Draw2D()
 447 {
 448         vector coord2d_topleft, coord2d_topright, coord2d;
 449         string s;
 450         vector fs;
 451
 452         s = vtos(self.view_ofs);
 453         s = substring(s, 1, strlen(s) - 2);
 454         if(tokenize_console(s) == 3)
 455                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 456
 457         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 458         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 459
 460         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 461
 462         coord2d = coord2d_topleft;
 463         if(fs_x < 8)
 464         {
 465                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 466                 fs = '8 8 0';
 467         }
 468         coord2d_y -= fs_y;
 469         coord2d_z = 0;
 470         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 471 }
 472
 473 void ShotOrg_Spawn()
 474 {
 475         debug_shotorg = spawn();
 476         debug_shotorg.draw = ShotOrg_Draw;
 477         debug_shotorg.draw2d = ShotOrg_Draw2D;
 478         debug_shotorg.renderflags = RF_VIEWMODEL;
 479         debug_shotorg.effects = EF_FULLBRIGHT;
 480         precache_model("models/shotorg_adjuster.md3");
 481         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 482         debug_shotorg.scale = 2;
 483         debug_shotorg.view_ofs = '25 8 -8';
 484 }
 485
 486 void DrawDebugModel()
 487 {
 488         if(time - floor(time) > 0.5)
 489         {
 490                 PolyDrawModel(self);
 491                 self.drawmask = 0;
 492         }
 493         else
 494         {
 495                 self.renderflags = 0;
 496                 self.drawmask = MASK_NORMAL;
 497         }
 498 }
 499
 500 void GameCommand(string msg)
 501 {
 502         string s;
 503         float argc;
 504         entity e;
 505         argc = tokenize_console(msg);
 506
 507         if(argv(0) == "help" || argc == 0)
 508         {
 509                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 510                 print(_("  settemp cvar value\n"));
 511                 print(_("  scoreboard_columns_set ...\n"));
 512                 print(_("  scoreboard_columns_help\n"));
 513                 GameCommand_Generic("help");
 514                 return;
 515         }
 516
 517         if(GameCommand_Generic(msg))
 518                 return;
 519
 520         string cmd;
 521         cmd = argv(0);
 522         if(cmd == "mv_download") {
 523                 Cmd_MapVote_MapDownload(argc);
 524         }
 525         else if(cmd == "settemp") {
 526                 cvar_clientsettemp(argv(1), argv(2));
 527         }
 528         else if(cmd == "scoreboard_columns_set") {
 529                 Cmd_HUD_SetFields(argc);
 530         }
 531         else if(cmd == "scoreboard_columns_help") {
 532                 Cmd_HUD_Help(argc);
 533         }
 534 #ifdef BLURTEST
 535         else if(cmd == "blurtest") {
 536                 blurtest_time0 = time;
 537                 blurtest_time1 = time + stof(argv(1));
 538                 blurtest_radius = stof(argv(2));
 539                 blurtest_power = stof(argv(3));
 540         }
 541 #endif
 542         else if(cmd == "shotorg_move") {
 543                 if(!debug_shotorg)
 544                         ShotOrg_Spawn();
 545                 else
 546                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 547                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 548         }
 549         else if(cmd == "shotorg_movez") {
 550                 if(!debug_shotorg)
 551                         ShotOrg_Spawn();
 552                 else
 553                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 554                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 555         }
 556         else if(cmd == "shotorg_set") {
 557                 if(!debug_shotorg)
 558                         ShotOrg_Spawn();
 559                 else
 560                         debug_shotorg.view_ofs = stov(argv(1));
 561                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 562         }
 563         else if(cmd == "shotorg_setz") {
 564                 if(!debug_shotorg)
 565                         ShotOrg_Spawn();
 566                 else
 567                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 568                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 569         }
 570         else if(cmd == "shotorg_toggle_hide") {
 571                 if(debug_shotorg)
 572                 {
 573                         debug_shotorg.cnt = !debug_shotorg.cnt;
 574                 }
 575         }
 576         else if(cmd == "shotorg_end") {
 577                 if(debug_shotorg)
 578                 {
 579                         print(vtos(debug_shotorg.view_ofs), "\n");
 580                         remove(debug_shotorg);
 581                         debug_shotorg = world;
 582                 }
 583                 localcmd("sv_cmd debug_shotorg\n");
 584         }
 585         else if(cmd == "sendcvar") {
 586                 // W_FixWeaponOrder will trash argv, so save what we need.
 587                 string thiscvar;
 588                 thiscvar = strzone(argv(1));
 589                 s = cvar_string(thiscvar);
 590                 if(thiscvar == "cl_weaponpriority")
 591                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 592                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 593                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 594                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 595                 strunzone(thiscvar);
 596         }
 597         else if(cmd == "spawn") {
 598                 s = argv(1);
 599                 e = spawn();
 600                 precache_model(s);
 601                 setmodel(e, s);
 602                 setorigin(e, view_origin);
 603                 e.angles = view_angles;
 604                 e.draw = DrawDebugModel;
 605                 e.classname = "debugmodel";
 606         }
 607     else if(cmd == "vyes")
 608     {
 609         if(uid2name_dialog)
 610         {
 611             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 612             vote_prev = 0;
 613             cvar_set("cl_allow_uid2name", "1");
 614             vote_change = -9999;
 615         }
 616         else
 617         {
 618             localcmd("cmd vote yes\n");
 619         }
 620     }
 621     else if(cmd == "vno")
 622     {
 623         if(uid2name_dialog)
 624         {
 625             vote_active = 0;
 626             vote_prev = 0;
 627             cvar_set("cl_allow_uid2name", "0");
 628             vote_change = -9999;
 629         }
 630         else
 631         {
 632             localcmd("cmd vote no\n");
 633         }
 634     }
 635
 636         else
 637         {
 638                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 639         }
 640
 641         return;
 642 }
 643
 644 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 645 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 646 // All keys are in ascii.
 647 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 648 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 649 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 650 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 651 {
 652         local float bSkipKey;
 653         bSkipKey = false;
 654
 655         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 656                 return true;
 657
 658         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 659                 return true;
 660
 661         if(menu_visible)
 662                 if(menu_action(bInputType, nPrimary, nSecondary))
 663                         return TRUE;
 664
 665         return bSkipKey;
 666 }
 667
 668 // END REQUIRED CSQC FUNCTIONS
 669 // --------------------------------------------------------------------------
 670
 671 // --------------------------------------------------------------------------
 672 // BEGIN OPTIONAL CSQC FUNCTIONS
 673 void Ent_ReadEntCS()
 674 {
 675         InterpolateOrigin_Undo();
 676
 677         self.classname = "entcs_receiver";
 678         self.sv_entnum = ReadByte() - 1;
 679         self.origin_x = ReadShort();
 680         self.origin_y = ReadShort();
 681         self.origin_z = ReadShort();
 682         self.angles_y = ReadByte() * 360.0 / 256;
 683         self.origin_z = self.angles_x = self.angles_z = 0;
 684
 685         InterpolateOrigin_Note();
 686 }
 687
 688 void Ent_Remove();
 689
 690 void Ent_RemovePlayerScore()
 691 {
 692         float i;
 693
 694         if(self.owner)
 695         {
 696                 SetTeam(self.owner, -1);
 697                 self.owner.gotscores = 0;
 698                 for(i = 0; i < MAX_SCORE; ++i)
 699                         self.owner.(scores[i]) = 0; // clear all scores
 700         }
 701 }
 702
 703 void Ent_ReadPlayerScore()
 704 {
 705         float i, n;
 706         float isNew;
 707         entity o;
 708
 709         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 710         // (no I've never heard of M-x replace-string, sed, or anything like that)
 711         isNew = !self.owner; // workaround for DP bug
 712         n = ReadByte()-1;
 713
 714 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 715         if(!isNew && n != self.sv_entnum)
 716         {
 717                 print(_("A CSQC entity changed its owner!\n"));
 718                 isNew = true;
 719                 Ent_Remove();
 720                 self.enttype = ENT_CLIENT_SCORES;
 721         }
 722 #endif
 723
 724         self.sv_entnum = n;
 725
 726         if not(playerslots[self.sv_entnum])
 727                 playerslots[self.sv_entnum] = spawn();
 728         o = self.owner = playerslots[self.sv_entnum];
 729         o.sv_entnum = self.sv_entnum;
 730         o.gotscores = 1;
 731
 732         //if not(o.sort_prev)
 733         //      RegisterPlayer(o);
 734         //playerchecker will do this for us later, if it has not already done so
 735
 736         float sf, lf;
 737 #if MAX_SCORE <= 8
 738         sf = ReadByte();
 739         lf = ReadByte();
 740 #else
 741         sf = ReadShort();
 742         lf = ReadShort();
 743 #endif
 744         float p;
 745         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 746                 if(sf & p)
 747                 {
 748                         if(lf & p)
 749                                 o.(scores[i]) = ReadInt24_t();
 750                         else
 751                                 o.(scores[i]) = ReadChar();
 752                 }
 753
 754         if(o.sort_prev)
 755                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 756
 757         self.entremove = Ent_RemovePlayerScore;
 758 }
 759
 760 void Ent_ReadTeamScore()
 761 {
 762         float i;
 763         entity o;
 764
 765         self.team = ReadByte();
 766         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 767
 768         float sf, lf;
 769 #if MAX_TEAMSCORE <= 8
 770         sf = ReadByte();
 771         lf = ReadByte();
 772 #else
 773         sf = ReadShort();
 774         lf = ReadShort();
 775 #endif
 776         float p;
 777         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 778                 if(sf & p)
 779                 {
 780                         if(lf & p)
 781                                 o.(teamscores[i]) = ReadInt24_t();
 782                         else
 783                                 o.(teamscores[i]) = ReadChar();
 784                 }
 785
 786         HUD_UpdateTeamPos(o);
 787 }
 788
 789 void Net_Reset()
 790 {
 791 }
 792
 793 void Ent_ClientData()
 794 {
 795         float f;
 796         float newspectatee_status;
 797
 798         f = ReadByte();
 799
 800         scoreboard_showscores_force = (f & 1);
 801
 802         if(f & 2)
 803         {
 804                 newspectatee_status = ReadByte();
 805                 if(newspectatee_status == player_localentnum)
 806                         newspectatee_status = -1; // observing
 807         }
 808         else
 809                 newspectatee_status = 0;
 810
 811         spectatorbutton_zoom = (f & 4);
 812
 813         if(f & 8)
 814         {
 815                 angles_held_status = 1;
 816                 angles_held_x = ReadAngle();
 817                 angles_held_y = ReadAngle();
 818                 angles_held_z = 0;
 819         }
 820         else
 821                 angles_held_status = 0;
 822
 823         if(newspectatee_status != spectatee_status)
 824         {
 825                 float i;
 826
 827                 // clear race stuff
 828                 race_laptime = 0;
 829                 race_checkpointtime = 0;
 830         }
 831         spectatee_status = newspectatee_status;
 832 }
 833
 834 void Ent_Nagger()
 835 {
 836         float nags, i, j, b, f;
 837
 838         nags = ReadByte();
 839
 840         if(nags & 128)
 841         {
 842                 if(vote_called_vote)
 843                         strunzone(vote_called_vote);
 844                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 845         }
 846
 847         if(nags & 1)
 848         {
 849                 for(j = 0; j < maxclients; ++j)
 850                         if(playerslots[j])
 851                                 playerslots[j].ready = 1;
 852                 for(i = 1; i <= maxclients; i += 8)
 853                 {
 854                         f = ReadByte();
 855                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 856                                 if not(f & b)
 857                                         if(playerslots[j])
 858                                                 playerslots[j].ready = 0;
 859                 }
 860         }
 861
 862         ready_waiting = (nags & 1);
 863         ready_waiting_for_me = (nags & 2);
 864         vote_waiting = (nags & 4);
 865         vote_waiting_for_me = (nags & 8);
 866         warmup_stage = (nags & 16);
 867 }
 868
 869 void Ent_RandomSeed()
 870 {
 871         float s;
 872         prandom_debug();
 873         s = ReadShort();
 874         psrandom(s);
 875 }
 876
 877 void Ent_ReadAccuracy(void)
 878 {
 879         float sf, f, w, b;
 880         sf = ReadInt24_t();
 881         if(sf == 0)
 882         {
 883                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 884                         weapon_accuracy[w] = -1;
 885                 return;
 886         }
 887
 888         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 889         {
 890                 if(sf & f)
 891                 {
 892                         b = ReadByte();
 893                         if(b == 0)
 894                                 weapon_accuracy[w] = -1;
 895                         else if(b == 255)
 896                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 897                         else
 898                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 899                 }
 900         }
 901 }
 902
 903 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 904 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 905 void Ent_RadarLink();
 906 void Ent_Init();
 907 void Ent_ScoresInfo();
 908 void(float bIsNewEntity) CSQC_Ent_Update =
 909 {
 910         float t;
 911         float savetime;
 912         t = ReadByte();
 913
 914         // set up the "time" global for received entities to be correct for interpolation purposes
 915         savetime = time;
 916         if(servertime)
 917         {
 918                 time = servertime;
 919         }
 920         else
 921         {
 922                 serverprevtime = time;
 923                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 924                 time = serverprevtime + serverdeltatime;
 925         }
 926
 927 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 928         if(self.enttype)
 929                 if(t != self.enttype)
 930                 {
 931                         print(_("A CSQC entity changed its type!\n"));
 932                         Ent_Remove();
 933                         bIsNewEntity = 1;
 934                 }
 935 #endif
 936         self.enttype = t;
 937         switch(t)
 938         {
 939                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 940                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 941                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 942                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 943                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 944                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 945                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 946                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 947                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 948                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 949                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 950                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 951                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 952                 case ENT_CLIENT_INIT: Ent_Init(); break;
 953                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 954                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 955                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 956                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 957                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 958                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 959                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 960                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 961                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 962                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 963                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 964                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 965                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 966                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 967                 default:
 968                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 969                         break;
 970         }
 971
 972         time = savetime;
 973 };
 974 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 975 // used when an entity changes its type. For an entity that someone interacts
 976 // with others, make sure it can no longer do so.
 977 void Ent_Remove()
 978 {
 979         if(self.entremove)
 980                 self.entremove();
 981
 982         self.enttype = 0;
 983         self.classname = "";
 984         self.draw = menu_sub_null;
 985         self.entremove = menu_sub_null;
 986         // TODO possibly set more stuff to defaults
 987 }
 988 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 989 void CSQC_Ent_Remove()
 990 {
 991         if(self.enttype)
 992                 Ent_Remove();
 993         remove(self);
 994 }
 995
 996 void Gamemode_Init()
 997 {
 998         if(gametype == GAME_ONSLAUGHT) {
 999                 print(strcat("Using ", minimapname, " as minimap.\n"));
1000                 precache_pic("gfx/ons-cp-neutral.tga");
1001                 precache_pic("gfx/ons-cp-red.tga");
1002                 precache_pic("gfx/ons-cp-blue.tga");
1003                 precache_pic("gfx/ons-frame.tga");
1004                 precache_pic("gfx/ons-frame-team.tga");
1005         }
1006
1007         if not(isdemo())
1008         {
1009                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1010                 calledhooks |= HOOK_START;
1011         }
1012 }
1013 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1014 void CSQC_Parse_StuffCmd(string strMessage)
1015 {
1016         localcmd(strMessage);
1017 }
1018 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1019 void CSQC_Parse_Print(string strMessage)
1020 {
1021         print(ColorTranslateRGB(strMessage));
1022 }
1023
1024 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1025 void CSQC_Parse_CenterPrint(string strMessage)
1026 {
1027         centerprint(strMessage);
1028 }
1029
1030 string notranslate_fogcmd1 = "\nfog ";
1031 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1032 void Fog_Force()
1033 {
1034         // TODO somehow thwart prvm_globalset client ...
1035
1036         if(forcefog != "")
1037                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1038 }
1039
1040 void Gamemode_Init();
1041 void Ent_ScoresInfo()
1042 {
1043         float i;
1044         self.classname = "ent_client_scores_info";
1045         gametype = ReadByte();
1046         for(i = 0; i < MAX_SCORE; ++i)
1047         {
1048                 scores_label[i] = strzone(ReadString());
1049                 scores_flags[i] = ReadByte();
1050         }
1051         for(i = 0; i < MAX_TEAMSCORE; ++i)
1052         {
1053                 teamscores_label[i] = strzone(ReadString());
1054                 teamscores_flags[i] = ReadByte();
1055         }
1056         HUD_InitScores();
1057         Gamemode_Init();
1058 }
1059
1060 void Ent_Init()
1061 {
1062         self.classname = "ent_client_init";
1063
1064         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1065
1066         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1067         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1068         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1069         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1070         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1071         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1072         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1073         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1074         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1075         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1076         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1077         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1078
1079         if(forcefog)
1080                 strunzone(forcefog);
1081         forcefog = strzone(ReadString());
1082
1083         armorblockpercent = ReadByte() / 255.0;
1084
1085         g_weaponswitchdelay = ReadByte() / 255.0;
1086
1087         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1088         g_balance_grenadelauncher_bouncestop = ReadCoord();
1089         g_balance_electro_secondary_bouncefactor = ReadCoord();
1090         g_balance_electro_secondary_bouncestop = ReadCoord();
1091
1092         nex_scope = !ReadByte();
1093         sniperrifle_scope = !ReadByte();
1094
1095         serverflags = ReadByte();
1096
1097         cr_maxbullets = ReadByte();
1098
1099         g_trueaim_minrange = ReadCoord();
1100
1101         if(!postinit)
1102                 PostInit();
1103 }
1104
1105 void Net_ReadRace()
1106 {
1107         float b;
1108
1109         b = ReadByte();
1110
1111         switch(b)
1112         {
1113                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1114                         race_checkpoint = ReadByte();
1115                         race_time = ReadInt24_t();
1116                         race_previousbesttime = ReadInt24_t();
1117                         if(race_previousbestname)
1118                                 strunzone(race_previousbestname);
1119                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1120
1121                         race_checkpointtime = time;
1122
1123                         if(race_checkpoint == 0 || race_checkpoint == 254)
1124                         {
1125                                 race_penaltyaccumulator = 0;
1126                                 race_laptime = time; // valid
1127                         }
1128
1129                         break;
1130
1131                 case RACE_NET_CHECKPOINT_CLEAR:
1132                         race_laptime = 0;
1133                         race_checkpointtime = 0;
1134                         break;
1135
1136                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1137                         race_laptime = ReadCoord();
1138                         race_checkpointtime = -99999;
1139                         // fall through
1140                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1141                         race_nextcheckpoint = ReadByte();
1142
1143                         race_nextbesttime = ReadInt24_t();
1144                         if(race_nextbestname)
1145                                 strunzone(race_nextbestname);
1146                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1147                         break;
1148
1149                 case RACE_NET_CHECKPOINT_HIT_RACE:
1150                         race_mycheckpoint = ReadByte();
1151                         race_mycheckpointtime = time;
1152                         race_mycheckpointdelta = ReadInt24_t();
1153                         race_mycheckpointlapsdelta = ReadByte();
1154                         if(race_mycheckpointlapsdelta >= 128)
1155                                 race_mycheckpointlapsdelta -= 256;
1156                         if(race_mycheckpointenemy)
1157                                 strunzone(race_mycheckpointenemy);
1158                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1159                         break;
1160
1161                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1162                         race_othercheckpoint = ReadByte();
1163                         race_othercheckpointtime = time;
1164                         race_othercheckpointdelta = ReadInt24_t();
1165                         race_othercheckpointlapsdelta = ReadByte();
1166                         if(race_othercheckpointlapsdelta >= 128)
1167                                 race_othercheckpointlapsdelta -= 256;
1168                         if(race_othercheckpointenemy)
1169                                 strunzone(race_othercheckpointenemy);
1170                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1171                         break;
1172
1173                 case RACE_NET_PENALTY_RACE:
1174                         race_penaltyeventtime = time;
1175                         race_penaltytime = ReadShort();
1176                         //race_penaltyaccumulator += race_penaltytime;
1177                         if(race_penaltyreason)
1178                                 strunzone(race_penaltyreason);
1179                         race_penaltyreason = strzone(ReadString());
1180                         break;
1181
1182                 case RACE_NET_PENALTY_QUALIFYING:
1183                         race_penaltyeventtime = time;
1184                         race_penaltytime = ReadShort();
1185                         race_penaltyaccumulator += race_penaltytime;
1186                         if(race_penaltyreason)
1187                                 strunzone(race_penaltyreason);
1188                         race_penaltyreason = strzone(ReadString());
1189                         break;
1190
1191                 case RACE_NET_SERVER_RECORD:
1192                         race_server_record = ReadInt24_t();
1193                         break;
1194                 case RACE_NET_SPEED_AWARD:
1195                         race_speedaward = ReadInt24_t();
1196                         if(race_speedaward_holder)
1197                                 strunzone(race_speedaward_holder);
1198                         race_speedaward_holder = strzone(ReadString());
1199                         break;
1200                 case RACE_NET_SPEED_AWARD_BEST:
1201                         race_speedaward_alltimebest = ReadInt24_t();
1202                         if(race_speedaward_alltimebest_holder)
1203                                 strunzone(race_speedaward_alltimebest_holder);
1204                         race_speedaward_alltimebest_holder = strzone(ReadString());
1205                         break;
1206                 case RACE_NET_SERVER_RANKINGS:
1207                         float pos, prevpos, del;
1208                         pos = ReadShort();
1209                         prevpos = ReadShort();
1210                         del = ReadShort();
1211
1212                         // move other rankings out of the way
1213                         float i;
1214                         if (prevpos) {
1215                                 for (i=prevpos-1;i>pos-1;--i) {
1216                                         grecordtime[i] = grecordtime[i-1];
1217                                         if(grecordholder[i])
1218                                                 strunzone(grecordholder[i]);
1219                                         grecordholder[i] = strzone(grecordholder[i-1]);
1220                                 }
1221                         } else if (del) { // a record has been deleted by the admin
1222                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1223                                         if (i == RANKINGS_CNT-1) { // clear out last record
1224                                                 grecordtime[i] = 0;
1225                                                 if (grecordholder[i])
1226                                                         strunzone(grecordholder[i]);
1227                                                 grecordholder[i] = string_null;
1228                                         }
1229                                         else {
1230                                                 grecordtime[i] = grecordtime[i+1];
1231                                                 if (grecordholder[i])
1232                                                         strunzone(grecordholder[i]);
1233                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1234                                         }
1235                                 }
1236                         } else { // player has no ranked record yet
1237                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1238                                         grecordtime[i] = grecordtime[i-1];
1239                                         if(grecordholder[i])
1240                                                 strunzone(grecordholder[i]);
1241                                         grecordholder[i] = strzone(grecordholder[i-1]);
1242                                 }
1243                         }
1244
1245                         // store new ranking
1246                         if(grecordholder[pos-1] != "")
1247                                 strunzone(grecordholder[pos-1]);
1248                         grecordholder[pos-1] = strzone(ReadString());
1249                         grecordtime[pos-1] = ReadInt24_t();
1250                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1251                                 race_myrank = pos;
1252                         break;
1253                 case RACE_NET_SERVER_STATUS:
1254                         race_status = ReadShort();
1255                         if(race_status_name)
1256                                 strunzone(race_status_name);
1257                         race_status_name = strzone(ReadString());
1258         }
1259 }
1260
1261 void Net_ReadSpawn()
1262 {
1263         zoomin_effect = 1;
1264         current_viewzoom = 0.6;
1265 }
1266
1267 void Net_TeamNagger()
1268 {
1269         teamnagger = 1;
1270 }
1271
1272 void Net_ReadPingPLReport()
1273 {
1274         float e, pi, pl, ml;
1275         e = ReadByte();
1276         pi = ReadShort();
1277         pl = ReadByte();
1278         ml = ReadByte();
1279         if not(playerslots[e])
1280                 return;
1281         playerslots[e].ping = pi;
1282         playerslots[e].ping_packetloss = pl / 255.0;
1283         playerslots[e].ping_movementloss = ml / 255.0;
1284 }
1285
1286 void Net_VoteDialog(float highlight) {
1287         if(highlight) {
1288                 vote_highlighted = ReadByte();
1289                 return;
1290         }
1291
1292         vote_yescount = ReadByte();
1293         vote_nocount = ReadByte();
1294         vote_needed = ReadByte();
1295         vote_active = 1;
1296 }
1297
1298 void Net_VoteDialogReset() {
1299         vote_active = 0;
1300 }
1301
1302 void Net_Notify() {
1303         float type;
1304         type = ReadByte();
1305
1306         if(type == CSQC_KILLNOTIFY)
1307         {
1308                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1309         }
1310         else if(type == CSQC_CENTERPRINT)
1311         {
1312                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1313         }
1314 }
1315
1316 void Net_WeaponComplain() {
1317         complain_weapon = ReadByte();
1318
1319         if(complain_weapon_name)
1320                 strunzone(complain_weapon_name);
1321         complain_weapon_name = strzone(ReadString());
1322
1323         complain_weapon_type = ReadByte();
1324
1325         complain_weapon_time = time;
1326         weapontime = time; // ping the weapon panel
1327 }
1328
1329 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1330 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1331 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1332 float CSQC_Parse_TempEntity()
1333 {
1334         local float bHandled;
1335                 bHandled  = true;
1336         // Acquire TE ID
1337         local float nTEID;
1338                 nTEID = ReadByte();
1339
1340                 // NOTE: Could just do return instead of break...
1341         switch(nTEID)
1342         {
1343                 case TE_CSQC_TARGET_MUSIC:
1344                         Net_TargetMusic();
1345                         bHandled = true;
1346                         break;
1347                 case TE_CSQC_PICTURE:
1348                         Net_MapVote_Picture();
1349                         bHandled = true;
1350                         break;
1351                 case TE_CSQC_RACE:
1352                         Net_ReadRace();
1353                         bHandled = true;
1354                         break;
1355                 case TE_CSQC_SPAWN:
1356                         Net_ReadSpawn();
1357                         bHandled = true;
1358                         break;
1359                 case TE_CSQC_ZCURVEPARTICLES:
1360                         Net_ReadZCurveParticles();
1361                         bHandled = true;
1362                         break;
1363                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1364                         Net_ReadNexgunBeamParticle();
1365                         bHandled = true;
1366                         break;
1367                 case TE_CSQC_TEAMNAGGER:
1368                         Net_TeamNagger();
1369                         bHandled = true;
1370                         break;
1371                 case TE_CSQC_VOTE:
1372                         Net_VoteDialog(ReadByte());
1373                         bHandled = true;
1374                         break;
1375                 case TE_CSQC_VOTERESET:
1376                         Net_VoteDialogReset();
1377                         bHandled = true;
1378                         break;
1379                 case TE_CSQC_LIGHTNINGARC:
1380                         Net_ReadLightningarc();
1381                         bHandled = true;
1382                         break;
1383                 case TE_CSQC_PINGPLREPORT:
1384                         Net_ReadPingPLReport();
1385                         bHandled = true;
1386                         break;
1387                 case TE_CSQC_ANNOUNCE:
1388                         announce_snd = strzone(ReadString());
1389                         bHandled = true;
1390                         break;
1391                 case TE_CSQC_NOTIFY:
1392                         Net_Notify();
1393                         bHandled = true;
1394                         break;
1395                 case TE_CSQC_WEAPONCOMPLAIN:
1396                         Net_WeaponComplain();
1397                         bHandled = true;
1398                         break;
1399                 default:
1400                         // No special logic for this temporary entity; return 0 so the engine can handle it
1401                         bHandled = false;
1402                         break;
1403         }
1404
1405         return bHandled;
1406 }
1407
1408 string getcommandkey(string text, string command)
1409 {
1410         string keys;
1411         float n, j, k, l;
1412
1413         if (!hud_showbinds)
1414                 return text;
1415
1416         keys = db_get(binddb, command);
1417         if (!keys)
1418         {
1419                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1420                 for(j = 0; j < n; ++j)
1421                 {
1422                         k = stof(argv(j));
1423                         if(k != -1)
1424                         {
1425                                 if ("" == keys)
1426                                         keys = keynumtostring(k);
1427                                 else
1428                                         keys = strcat(keys, ", ", keynumtostring(k));
1429
1430                                 ++l;
1431                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1432                         }
1433
1434                 }
1435                 db_put(binddb, command, keys);
1436         }
1437
1438         if ("" == keys) {
1439                 if (hud_showbinds > 1)
1440                         return sprintf(_("%s (not bound)"), text);
1441                 else
1442                         return text;
1443         }
1444         else if (hud_showbinds > 1)
1445                 return sprintf(_("%s (%s)"), text, keys);
1446         else
1447                 return keys;
1448 }