qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if (!clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 string forcefog;
  36 void WaypointSprite_Load();
  37 void ConsoleCommand_macro_init();
  38 void CSQC_Init(void)
  39 {
  40         prvm_language = cvar_string("prvm_language");
  41 #ifdef USE_FTE
  42 #pragma target ID
  43         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  44         if(!__engine_check)
  45         {
  46                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  47                 localcmd("\ndisconnect\n");
  48                 return;
  49         }
  50 #pragma target FTE
  51 #endif
  52
  53         check_unacceptable_compiler_bugs();
  54
  55 #ifdef WATERMARK
  56         printf(_("^4CSQC Build information: ^1%s\n"), WATERMARK);
  57 #endif
  58
  59         float i;
  60
  61 #ifdef COMPAT_XON050_ENGINE
  62         // old engine lacks implementation of player_localnum
  63         player_localnum = player_localentnum - 1;
  64 #endif
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69         compressShortVector_init();
  70
  71         draw_endBoldFont();
  72         menu_visible = FALSE;
  73         menu_show = menu_show_error;
  74         menu_action = func_null;
  75
  76         for(i = 0; i < 255; ++i)
  77                 if(getplayerkeyvalue(i, "viewentity") == "")
  78                         break;
  79         maxclients = i;
  80
  81         //registercommand("hud_configure");
  82         //registercommand("hud_save");
  83         //registercommand("menu_action");
  84
  85         ConsoleCommand_macro_init();
  86
  87         registercvar("hud_usecsqc", "1");
  88         registercvar("scoreboard_columns", "default");
  89
  90         registercvar("cl_nade_type", "3");
  91         registercvar("cl_pokenade_type", "zombie");
  92
  93         gametype = 0;
  94
  95         // hud_fields uses strunzone on the titles!
  96         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  97                 hud_title[i] = strzone("(null)");
  98
  99         Cmd_HUD_SetFields(0);
 100
 101         postinit = false;
 102
 103         calledhooks = 0;
 104
 105         teams = Sort_Spawn();
 106         players = Sort_Spawn();
 107
 108         GetTeam(NUM_SPECTATOR, true); // add specs first
 109
 110         // needs to be done so early because of the constants they create
 111         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 112         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 113         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 114         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 115         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 116         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 117         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 118
 119         WaypointSprite_Load();
 120
 121         // precaches
 122         precache_model("null");
 123         precache_sound("misc/hit.wav");
 124         precache_sound("misc/typehit.wav");
 125
 126         Projectile_Precache();
 127         Hook_Precache();
 128         GibSplash_Precache();
 129         Casings_Precache();
 130         DamageInfo_Precache();
 131         Vehicles_Precache();
 132         turrets_precache();
 133         Tuba_Precache();
 134         CSQCPlayer_Precache();
 135
 136         if(autocvar_cl_reticle)
 137         {
 138                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 139                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 140         }
 141
 142         get_mi_min_max_texcoords(1); // try the CLEVER way first
 143         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 144         shortmapname = mi_shortname;
 145
 146         if(precache_pic(minimapname) == "")
 147         {
 148                 // but maybe we have a non-clever minimap
 149                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 150                 if(precache_pic(minimapname) == "")
 151                         minimapname = ""; // FAIL
 152                 else
 153                         get_mi_min_max_texcoords(0); // load new texcoords
 154         }
 155
 156         mi_center = (mi_min + mi_max) * 0.5;
 157         mi_scale = mi_max - mi_min;
 158         minimapname = strzone(minimapname);
 159
 160         WarpZone_Init();
 161
 162         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 163         hud_configure_prev = -1;
 164
 165         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 166 }
 167
 168 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 169 void Shutdown(void)
 170 {
 171 #ifdef USE_FTE
 172 #pragma TARGET id
 173         if(!__engine_check)
 174                 return 0;
 175 #pragma TARGET fte
 176 #endif
 177
 178         WarpZone_Shutdown();
 179
 180         remove(teams);
 181         remove(players);
 182         db_close(binddb);
 183         db_close(tempdb);
 184         if(autocvar_cl_db_saveasdump)
 185                 db_dump(ClientProgsDB, "client.db");
 186         else
 187                 db_save(ClientProgsDB, "client.db");
 188         db_close(ClientProgsDB);
 189
 190         if(camera_active)
 191                 cvar_set("chase_active",ftos(chase_active_backup));
 192
 193         // unset the event chasecam's chase_active
 194         if(autocvar_chase_active < 0)
 195                 cvar_set("chase_active", "0");
 196
 197         if (!isdemo())
 198         {
 199                 if (!(calledhooks & HOOK_START))
 200                         localcmd("\n_cl_hook_gamestart nop\n");
 201                 if (!(calledhooks & HOOK_END))
 202                         localcmd("\ncl_hook_gameend\n");
 203         }
 204 }
 205
 206 .float has_team;
 207 float SetTeam(entity o, float Team)
 208 {
 209         entity tm;
 210         if(teamplay)
 211         {
 212                 switch(Team)
 213                 {
 214                         case -1:
 215                         case NUM_TEAM_1:
 216                         case NUM_TEAM_2:
 217                         case NUM_TEAM_3:
 218                         case NUM_TEAM_4:
 219                                 break;
 220                         default:
 221                                 if(GetTeam(Team, false) == world)
 222                                 {
 223                                         dprintf("trying to switch to unsupported team %d\n", Team);
 224                                         Team = NUM_SPECTATOR;
 225                                 }
 226                                 break;
 227                 }
 228         }
 229         else
 230         {
 231                 switch(Team)
 232                 {
 233                         case -1:
 234                         case 0:
 235                                 break;
 236                         default:
 237                                 if(GetTeam(Team, false) == world)
 238                                 {
 239                                         dprintf("trying to switch to unsupported team %d\n", Team);
 240                                         Team = NUM_SPECTATOR;
 241                                 }
 242                                 break;
 243                 }
 244         }
 245         if(Team == -1) // leave
 246         {
 247                 if(o.has_team)
 248                 {
 249                         tm = GetTeam(o.team, false);
 250                         tm.team_size -= 1;
 251                         o.has_team = 0;
 252                         return TRUE;
 253                 }
 254         }
 255         else
 256         {
 257                 if (!o.has_team)
 258                 {
 259                         o.team = Team;
 260                         tm = GetTeam(Team, true);
 261                         tm.team_size += 1;
 262                         o.has_team = 1;
 263                         return TRUE;
 264                 }
 265                 else if(Team != o.team)
 266                 {
 267                         tm = GetTeam(o.team, false);
 268                         tm.team_size -= 1;
 269                         o.team = Team;
 270                         tm = GetTeam(Team, true);
 271                         tm.team_size += 1;
 272                         return TRUE;
 273                 }
 274         }
 275         return FALSE;
 276 }
 277
 278 void Playerchecker_Think()
 279 {
 280         float i;
 281         entity e;
 282         for(i = 0; i < maxclients; ++i)
 283         {
 284                 e = playerslots[i];
 285                 if(GetPlayerName(i) == "")
 286                 {
 287                         if(e.sort_prev)
 288                         {
 289                                 // player disconnected
 290                                 SetTeam(e, -1);
 291                                 RemovePlayer(e);
 292                                 e.sort_prev = world;
 293                                 //e.gotscores = 0;
 294                         }
 295                 }
 296                 else
 297                 {
 298                         if (!e.sort_prev)
 299                         {
 300                                 // player connected
 301                                 if (!e)
 302                                         playerslots[i] = e = spawn();
 303                                 e.sv_entnum = i;
 304                                 e.ping = 0;
 305                                 e.ping_packetloss = 0;
 306                                 e.ping_movementloss = 0;
 307                                 //e.gotscores = 0; // we might already have the scores...
 308                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 309                                 RegisterPlayer(e);
 310                                 HUD_UpdatePlayerPos(e);
 311                         }
 312                 }
 313         }
 314         self.nextthink = time + 0.2;
 315 }
 316
 317 void Porto_Init();
 318 void TrueAim_Init();
 319 void PostInit(void)
 320 {
 321         entity playerchecker;
 322         playerchecker = spawn();
 323         playerchecker.think = Playerchecker_Think;
 324         playerchecker.nextthink = time + 0.2;
 325
 326         Porto_Init();
 327         TrueAim_Init();
 328
 329         postinit = true;
 330 }
 331
 332 float button_zoom;
 333
 334 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 335 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 336 // All keys are in ascii.
 337 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 338 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 339 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 340 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 341 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 342 {
 343         float bSkipKey;
 344         bSkipKey = false;
 345
 346         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 347                 return true;
 348
 349         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 350                 return true;
 351
 352         if(menu_visible && menu_action)
 353                 if(menu_action(bInputType, nPrimary, nSecondary))
 354                         return TRUE;
 355
 356         return bSkipKey;
 357 }
 358
 359 // END REQUIRED CSQC FUNCTIONS
 360 // --------------------------------------------------------------------------
 361
 362 // --------------------------------------------------------------------------
 363 // BEGIN OPTIONAL CSQC FUNCTIONS
 364 void Ent_RemoveEntCS()
 365 {
 366         entcs_receiver[self.sv_entnum] = world;
 367 }
 368 void Ent_ReadEntCS()
 369 {
 370         float sf;
 371         InterpolateOrigin_Undo();
 372
 373         self.classname = "entcs_receiver";
 374         sf = ReadByte();
 375
 376         if(sf & 1)
 377                 self.sv_entnum = ReadByte();
 378         if(sf & 2)
 379         {
 380                 self.origin_x = ReadShort();
 381                 self.origin_y = ReadShort();
 382                 self.origin_z = ReadShort();
 383                 setorigin(self, self.origin);
 384         }
 385         if(sf & 4)
 386         {
 387                 self.angles_y = ReadByte() * 360.0 / 256;
 388                 self.angles_x = self.angles_z = 0;
 389         }
 390         if(sf & 8)
 391                 self.healthvalue = ReadByte() * 10;
 392         if(sf & 16)
 393                 self.armorvalue = ReadByte() * 10;
 394
 395         entcs_receiver[self.sv_entnum] = self;
 396         self.entremove = Ent_RemoveEntCS;
 397         self.iflags |= IFLAG_ORIGIN;
 398
 399         InterpolateOrigin_Note();
 400 }
 401
 402 void Ent_Remove();
 403
 404 void Ent_RemovePlayerScore()
 405 {
 406         float i;
 407
 408         if(self.owner)
 409         {
 410                 SetTeam(self.owner, -1);
 411                 self.owner.gotscores = 0;
 412                 for(i = 0; i < MAX_SCORE; ++i)
 413                         self.owner.(scores[i]) = 0; // clear all scores
 414         }
 415 }
 416
 417 void Ent_ReadPlayerScore()
 418 {
 419         float i, n;
 420         float isNew;
 421         entity o;
 422
 423         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 424         // (no I've never heard of M-x replace-string, sed, or anything like that)
 425         isNew = !self.owner; // workaround for DP bug
 426         n = ReadByte()-1;
 427
 428 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 429         if(!isNew && n != self.sv_entnum)
 430         {
 431                 //print("A CSQC entity changed its owner!\n");
 432                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 433                 isNew = true;
 434                 Ent_Remove();
 435                 self.enttype = ENT_CLIENT_SCORES;
 436         }
 437 #endif
 438
 439         self.sv_entnum = n;
 440
 441         if (!(playerslots[self.sv_entnum]))
 442                 playerslots[self.sv_entnum] = spawn();
 443         o = self.owner = playerslots[self.sv_entnum];
 444         o.sv_entnum = self.sv_entnum;
 445         o.gotscores = 1;
 446
 447         //if (!o.sort_prev)
 448         //      RegisterPlayer(o);
 449         //playerchecker will do this for us later, if it has not already done so
 450
 451         float sf, lf;
 452 #if MAX_SCORE <= 8
 453         sf = ReadByte();
 454         lf = ReadByte();
 455 #else
 456         sf = ReadShort();
 457         lf = ReadShort();
 458 #endif
 459         float p;
 460         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 461                 if(sf & p)
 462                 {
 463                         if(lf & p)
 464                                 o.(scores[i]) = ReadInt24_t();
 465                         else
 466                                 o.(scores[i]) = ReadChar();
 467                 }
 468
 469         if(o.sort_prev)
 470                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 471
 472         self.entremove = Ent_RemovePlayerScore;
 473 }
 474
 475 void Ent_ReadTeamScore()
 476 {
 477         float i;
 478         entity o;
 479
 480         self.team = ReadByte();
 481         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 482
 483         float sf, lf;
 484 #if MAX_TEAMSCORE <= 8
 485         sf = ReadByte();
 486         lf = ReadByte();
 487 #else
 488         sf = ReadShort();
 489         lf = ReadShort();
 490 #endif
 491         float p;
 492         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 493                 if(sf & p)
 494                 {
 495                         if(lf & p)
 496                                 o.(teamscores[i]) = ReadInt24_t();
 497                         else
 498                                 o.(teamscores[i]) = ReadChar();
 499                 }
 500
 501         HUD_UpdateTeamPos(o);
 502 }
 503
 504 void Ent_ClientData()
 505 {
 506         float f;
 507         float newspectatee_status;
 508
 509         f = ReadByte();
 510
 511         scoreboard_showscores_force = (f & 1);
 512
 513         if(f & 2)
 514         {
 515                 newspectatee_status = ReadByte();
 516                 if(newspectatee_status == player_localnum + 1)
 517                         newspectatee_status = -1; // observing
 518         }
 519         else
 520                 newspectatee_status = 0;
 521
 522         spectatorbutton_zoom = (f & 4);
 523
 524         if(f & 8)
 525         {
 526                 angles_held_status = 1;
 527                 angles_held_x = ReadAngle();
 528                 angles_held_y = ReadAngle();
 529                 angles_held_z = 0;
 530         }
 531         else
 532                 angles_held_status = 0;
 533
 534         if(newspectatee_status != spectatee_status)
 535         {
 536                 // clear race stuff
 537                 race_laptime = 0;
 538                 race_checkpointtime = 0;
 539         }
 540         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 541         {
 542                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 543                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 544                 )
 545                         prev_p_health = -1;
 546                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 547                         prev_health = -1;
 548         }
 549         spectatee_status = newspectatee_status;
 550
 551         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 552 }
 553
 554 void Ent_Nagger()
 555 {
 556         float nags, i, j, b, f;
 557
 558         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 559
 560         if(!(nags & 4))
 561         {
 562                 if(vote_called_vote)
 563                         strunzone(vote_called_vote);
 564                 vote_called_vote = string_null;
 565                 vote_active = 0;
 566         }
 567         else
 568         {
 569                 vote_active = 1;
 570         }
 571
 572         if(nags & 64)
 573         {
 574                 vote_yescount = ReadByte();
 575                 vote_nocount = ReadByte();
 576                 vote_needed = ReadByte();
 577                 vote_highlighted = ReadChar();
 578         }
 579
 580         if(nags & 128)
 581         {
 582                 if(vote_called_vote)
 583                         strunzone(vote_called_vote);
 584                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 585         }
 586
 587         if(nags & 1)
 588         {
 589                 for(j = 0; j < maxclients; ++j)
 590                         if(playerslots[j])
 591                                 playerslots[j].ready = 1;
 592                 for(i = 1; i <= maxclients; i += 8)
 593                 {
 594                         f = ReadByte();
 595                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 596                                 if (!(f & b))
 597                                         if(playerslots[j])
 598                                                 playerslots[j].ready = 0;
 599                 }
 600         }
 601
 602         ready_waiting = (nags & 1);
 603         ready_waiting_for_me = (nags & 2);
 604         vote_waiting = (nags & 4);
 605         vote_waiting_for_me = (nags & 8);
 606         warmup_stage = (nags & 16);
 607 }
 608
 609 void Ent_EliminatedPlayers()
 610 {
 611         float sf, i, j, b, f;
 612
 613         sf = ReadByte();
 614         if(sf & 1)
 615         {
 616                 for(j = 0; j < maxclients; ++j)
 617                         if(playerslots[j])
 618                                 playerslots[j].eliminated = 1;
 619                 for(i = 1; i <= maxclients; i += 8)
 620                 {
 621                         f = ReadByte();
 622                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 623                                 if (!(f & b))
 624                                         if(playerslots[j])
 625                                                 playerslots[j].eliminated = 0;
 626                 }
 627         }
 628 }
 629
 630 void Ent_RandomSeed()
 631 {
 632         float s;
 633         prandom_debug();
 634         s = ReadShort();
 635         psrandom(s);
 636 }
 637
 638 void Ent_ReadAccuracy(void)
 639 {
 640         float sf, f, w, b;
 641         sf = ReadInt24_t();
 642         if(sf == 0)
 643         {
 644                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 645                         weapon_accuracy[w] = -1;
 646                 return;
 647         }
 648
 649         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 650         {
 651                 if(sf & f)
 652                 {
 653                         b = ReadByte();
 654                         if(b == 0)
 655                                 weapon_accuracy[w] = -1;
 656                         else if(b == 255)
 657                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 658                         else
 659                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 660                 }
 661                 if(f == 0x800000)
 662                         f = 1;
 663                 else
 664                         f *= 2;
 665         }
 666 }
 667
 668 void Spawn_Draw(void)
 669 {
 670         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 671 }
 672
 673 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 674 {
 675         float teamnum = (ReadByte() - 1);
 676         vector spn_origin;
 677         spn_origin_x = ReadShort();
 678         spn_origin_y = ReadShort();
 679         spn_origin_z = ReadShort();
 680
 681         if(is_new)
 682         {
 683                 self.origin = spn_origin;
 684                 setsize(self, PL_MIN, PL_MAX);
 685                 droptofloor();
 686
 687                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 688                 {
 689                         self.mdl = "models/spawnpoint.md3";
 690                         self.colormod = Team_ColorRGB(teamnum);
 691                         precache_model(self.mdl);
 692                         setmodel(self, self.mdl);
 693                         self.drawmask = MASK_NORMAL;
 694                         //self.movetype = MOVETYPE_NOCLIP;
 695                         //self.draw = Spawn_Draw;
 696                 }*/
 697                 if(autocvar_cl_spawn_point_particles)
 698                 {
 699                         if((serverflags & SERVERFLAG_TEAMPLAY))
 700                         {
 701                                 switch(teamnum)
 702                                 {
 703                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 704                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 705                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 706                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 707                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 708                                 }
 709                         }
 710                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 711
 712                         self.draw = Spawn_Draw;
 713                 }
 714         }
 715
 716         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 717 }
 718
 719 void Ent_ReadSpawnEvent(float is_new)
 720 {
 721         // If entnum is 0, ONLY do the local spawn actions
 722         // this way the server can disable the sending of
 723         // spawn origin or such to clients if wanted.
 724         float entnum = ReadByte();
 725
 726         if(entnum)
 727         {
 728                 self.origin_x = ReadShort();
 729                 self.origin_y = ReadShort();
 730                 self.origin_z = ReadShort();
 731
 732                 if(is_new)
 733                 {
 734                         float teamnum = GetPlayerColor(entnum - 1);
 735
 736                         if(autocvar_cl_spawn_event_particles)
 737                         {
 738                                 switch(teamnum)
 739                                 {
 740                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 741                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 742                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 743                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 744                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 745                                 }
 746                         }
 747                         if(autocvar_cl_spawn_event_sound)
 748                         {
 749                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 750                         }
 751                 }
 752         }
 753
 754         // local spawn actions
 755         if(is_new && (!entnum || (entnum == player_localentnum)))
 756         {
 757                 zoomin_effect = 1;
 758                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 759
 760                 if(autocvar_cl_unpress_zoom_on_spawn)
 761                 {
 762                         localcmd("-zoom\n");
 763                         button_zoom = FALSE;
 764                 }
 765         }
 766
 767         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 768 }
 769
 770 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 771 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 772 void Ent_RadarLink();
 773 void Ent_Init();
 774 void Ent_ScoresInfo();
 775 void CSQC_Ent_Update(float bIsNewEntity)
 776 {
 777         float t;
 778         float savetime;
 779         t = ReadByte();
 780
 781         if(autocvar_developer_csqcentities)
 782                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 783
 784         // set up the "time" global for received entities to be correct for interpolation purposes
 785         savetime = time;
 786         if(servertime)
 787         {
 788                 time = servertime;
 789         }
 790         else
 791         {
 792                 serverprevtime = time;
 793                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 794                 time = serverprevtime + serverdeltatime;
 795         }
 796
 797 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 798         if(self.enttype)
 799         {
 800                 if(t != self.enttype || bIsNewEntity)
 801                 {
 802                         //print("A CSQC entity changed its type!\n");
 803                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 804                         Ent_Remove();
 805                         clearentity(self);
 806                         bIsNewEntity = 1;
 807                 }
 808         }
 809         else
 810         {
 811                 if(!bIsNewEntity)
 812                 {
 813                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 814                         bIsNewEntity = 1;
 815                 }
 816         }
 817 #endif
 818         self.enttype = t;
 819         switch(t)
 820         {
 821                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 822                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 823                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 824                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 825                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 826                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 827                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 828                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 829                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 830                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 831                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 832                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 833                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 834                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 835                 case ENT_CLIENT_INIT: Ent_Init(); break;
 836                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 837                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 838                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 839                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 840                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 841                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 842                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 843                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 844                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 845                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 846                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 847                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 848                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 849                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 850                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 851                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 852                 case ENT_CLIENT_TURRET: ent_turret(); break;
 853                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 854                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 855                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 856                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 857                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 858                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 859                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 860
 861                 default:
 862                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 863                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 864                         break;
 865         }
 866
 867         time = savetime;
 868 }
 869 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 870 // used when an entity changes its type. For an entity that someone interacts
 871 // with others, make sure it can no longer do so.
 872 void Ent_Remove()
 873 {
 874         if(self.entremove)
 875                 self.entremove();
 876
 877         if(self.skeletonindex)
 878         {
 879                 skel_delete(self.skeletonindex);
 880                 self.skeletonindex = 0;
 881         }
 882
 883         if(self.snd_looping > 0)
 884         {
 885                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 886                 self.snd_looping = 0;
 887         }
 888
 889         self.enttype = 0;
 890         self.classname = "";
 891         self.draw = menu_sub_null;
 892         self.entremove = menu_sub_null;
 893         // TODO possibly set more stuff to defaults
 894 }
 895 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 896 void CSQC_Ent_Remove()
 897 {
 898         if(autocvar_developer_csqcentities)
 899                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 900
 901         if(wasfreed(self))
 902         {
 903                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 904                 return;
 905         }
 906         if(self.enttype)
 907                 Ent_Remove();
 908         remove(self);
 909 }
 910
 911 void Gamemode_Init()
 912 {
 913         if (!isdemo())
 914         {
 915                 if(!(calledhooks & HOOK_START))
 916                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 917                 calledhooks |= HOOK_START;
 918         }
 919 }
 920 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 921 void CSQC_Parse_StuffCmd(string strMessage)
 922 {
 923         if(autocvar_developer_csqcentities)
 924                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 925
 926         localcmd(strMessage);
 927 }
 928 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 929 void CSQC_Parse_Print(string strMessage)
 930 {
 931         if(autocvar_developer_csqcentities)
 932                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 933
 934         print(ColorTranslateRGB(strMessage));
 935 }
 936
 937 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 938 void CSQC_Parse_CenterPrint(string strMessage)
 939 {
 940         if(autocvar_developer_csqcentities)
 941                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 942
 943         centerprint_hud(strMessage);
 944 }
 945
 946 string notranslate_fogcmd1 = "\nfog ";
 947 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 948 void Fog_Force()
 949 {
 950         // TODO somehow thwart prvm_globalset client ...
 951
 952         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 953                 { localcmd("\nr_drawfog 0\n"); }
 954         else if(forcefog != "")
 955                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 956 }
 957
 958 void Gamemode_Init();
 959 void Ent_ScoresInfo()
 960 {
 961         float i;
 962         self.classname = "ent_client_scores_info";
 963         gametype = ReadInt24_t();
 964         HUD_ModIcons_SetFunc();
 965         for(i = 0; i < MAX_SCORE; ++i)
 966         {
 967                 if(scores_label[i])
 968                         strunzone(scores_label[i]);
 969                 scores_label[i] = strzone(ReadString());
 970                 scores_flags[i] = ReadByte();
 971         }
 972         for(i = 0; i < MAX_TEAMSCORE; ++i)
 973         {
 974                 if(teamscores_label[i])
 975                         strunzone(teamscores_label[i]);
 976                 teamscores_label[i] = strzone(ReadString());
 977                 teamscores_flags[i] = ReadByte();
 978         }
 979         HUD_InitScores();
 980         Gamemode_Init();
 981 }
 982
 983 void Ent_Init()
 984 {
 985         self.classname = "ent_client_init";
 986
 987         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 988
 989         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 990         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 991         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 992         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 993         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 994         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 995         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 996         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 997         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 998         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 999         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1000         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1001
1002         if(forcefog)
1003                 strunzone(forcefog);
1004         forcefog = strzone(ReadString());
1005
1006         armorblockpercent = ReadByte() / 255.0;
1007
1008         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1009         g_balance_grenadelauncher_bouncestop = ReadCoord();
1010         g_balance_electro_secondary_bouncefactor = ReadCoord();
1011         g_balance_electro_secondary_bouncestop = ReadCoord();
1012
1013         nex_scope = !ReadByte();
1014         rifle_scope = !ReadByte();
1015
1016         serverflags = ReadByte();
1017
1018         minelayer_maxmines = ReadByte();
1019
1020         hagar_maxrockets = ReadByte();
1021
1022         g_trueaim_minrange = ReadCoord();
1023         g_balance_porto_secondary = ReadByte();
1024
1025         if(!postinit)
1026                 PostInit();
1027 }
1028
1029 void Net_ReadRace()
1030 {
1031         float b;
1032
1033         b = ReadByte();
1034
1035         switch(b)
1036         {
1037                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1038                         race_checkpoint = ReadByte();
1039                         race_time = ReadInt24_t();
1040                         race_previousbesttime = ReadInt24_t();
1041                         if(race_previousbestname)
1042                                 strunzone(race_previousbestname);
1043                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1044
1045                         race_checkpointtime = time;
1046
1047                         if(race_checkpoint == 0 || race_checkpoint == 254)
1048                         {
1049                                 race_penaltyaccumulator = 0;
1050                                 race_laptime = time; // valid
1051                         }
1052
1053                         break;
1054
1055                 case RACE_NET_CHECKPOINT_CLEAR:
1056                         race_laptime = 0;
1057                         race_checkpointtime = 0;
1058                         break;
1059
1060                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1061                         race_laptime = ReadCoord();
1062                         race_checkpointtime = -99999;
1063                         // fall through
1064                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1065                         race_nextcheckpoint = ReadByte();
1066
1067                         race_nextbesttime = ReadInt24_t();
1068                         if(race_nextbestname)
1069                                 strunzone(race_nextbestname);
1070                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1071                         break;
1072
1073                 case RACE_NET_CHECKPOINT_HIT_RACE:
1074                         race_mycheckpoint = ReadByte();
1075                         race_mycheckpointtime = time;
1076                         race_mycheckpointdelta = ReadInt24_t();
1077                         race_mycheckpointlapsdelta = ReadByte();
1078                         if(race_mycheckpointlapsdelta >= 128)
1079                                 race_mycheckpointlapsdelta -= 256;
1080                         if(race_mycheckpointenemy)
1081                                 strunzone(race_mycheckpointenemy);
1082                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1083                         break;
1084
1085                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1086                         race_othercheckpoint = ReadByte();
1087                         race_othercheckpointtime = time;
1088                         race_othercheckpointdelta = ReadInt24_t();
1089                         race_othercheckpointlapsdelta = ReadByte();
1090                         if(race_othercheckpointlapsdelta >= 128)
1091                                 race_othercheckpointlapsdelta -= 256;
1092                         if(race_othercheckpointenemy)
1093                                 strunzone(race_othercheckpointenemy);
1094                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1095                         break;
1096
1097                 case RACE_NET_PENALTY_RACE:
1098                         race_penaltyeventtime = time;
1099                         race_penaltytime = ReadShort();
1100                         //race_penaltyaccumulator += race_penaltytime;
1101                         if(race_penaltyreason)
1102                                 strunzone(race_penaltyreason);
1103                         race_penaltyreason = strzone(ReadString());
1104                         break;
1105
1106                 case RACE_NET_PENALTY_QUALIFYING:
1107                         race_penaltyeventtime = time;
1108                         race_penaltytime = ReadShort();
1109                         race_penaltyaccumulator += race_penaltytime;
1110                         if(race_penaltyreason)
1111                                 strunzone(race_penaltyreason);
1112                         race_penaltyreason = strzone(ReadString());
1113                         break;
1114
1115                 case RACE_NET_SERVER_RECORD:
1116                         race_server_record = ReadInt24_t();
1117                         break;
1118                 case RACE_NET_SPEED_AWARD:
1119                         race_speedaward = ReadInt24_t();
1120                         if(race_speedaward_holder)
1121                                 strunzone(race_speedaward_holder);
1122                         race_speedaward_holder = strzone(ReadString());
1123                         break;
1124                 case RACE_NET_SPEED_AWARD_BEST:
1125                         race_speedaward_alltimebest = ReadInt24_t();
1126                         if(race_speedaward_alltimebest_holder)
1127                                 strunzone(race_speedaward_alltimebest_holder);
1128                         race_speedaward_alltimebest_holder = strzone(ReadString());
1129                         break;
1130                 case RACE_NET_SERVER_RANKINGS:
1131                         float pos, prevpos, del;
1132                         pos = ReadShort();
1133                         prevpos = ReadShort();
1134                         del = ReadShort();
1135
1136                         // move other rankings out of the way
1137                         float i;
1138                         if (prevpos) {
1139                                 for (i=prevpos-1;i>pos-1;--i) {
1140                                         grecordtime[i] = grecordtime[i-1];
1141                                         if(grecordholder[i])
1142                                                 strunzone(grecordholder[i]);
1143                                         grecordholder[i] = strzone(grecordholder[i-1]);
1144                                 }
1145                         } else if (del) { // a record has been deleted by the admin
1146                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1147                                         if (i == RANKINGS_CNT-1) { // clear out last record
1148                                                 grecordtime[i] = 0;
1149                                                 if (grecordholder[i])
1150                                                         strunzone(grecordholder[i]);
1151                                                 grecordholder[i] = string_null;
1152                                         }
1153                                         else {
1154                                                 grecordtime[i] = grecordtime[i+1];
1155                                                 if (grecordholder[i])
1156                                                         strunzone(grecordholder[i]);
1157                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1158                                         }
1159                                 }
1160                         } else { // player has no ranked record yet
1161                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1162                                         grecordtime[i] = grecordtime[i-1];
1163                                         if(grecordholder[i])
1164                                                 strunzone(grecordholder[i]);
1165                                         grecordholder[i] = strzone(grecordholder[i-1]);
1166                                 }
1167                         }
1168
1169                         // store new ranking
1170                         if(grecordholder[pos-1] != "")
1171                                 strunzone(grecordholder[pos-1]);
1172                         grecordholder[pos-1] = strzone(ReadString());
1173                         grecordtime[pos-1] = ReadInt24_t();
1174                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1175                                 race_myrank = pos;
1176                         break;
1177                 case RACE_NET_SERVER_STATUS:
1178                         race_status = ReadShort();
1179                         if(race_status_name)
1180                                 strunzone(race_status_name);
1181                         race_status_name = strzone(ReadString());
1182         }
1183 }
1184
1185 void Net_TeamNagger()
1186 {
1187         teamnagger = 1;
1188 }
1189
1190 void Net_ReadPingPLReport()
1191 {
1192         float e, pi, pl, ml;
1193         e = ReadByte();
1194         pi = ReadShort();
1195         pl = ReadByte();
1196         ml = ReadByte();
1197         if (!(playerslots[e]))
1198                 return;
1199         playerslots[e].ping = pi;
1200         playerslots[e].ping_packetloss = pl / 255.0;
1201         playerslots[e].ping_movementloss = ml / 255.0;
1202 }
1203
1204 void Net_WeaponComplain()
1205 {
1206         complain_weapon = ReadByte();
1207
1208         if(complain_weapon_name)
1209                 strunzone(complain_weapon_name);
1210         complain_weapon_name = strzone(ReadString());
1211
1212         complain_weapon_type = ReadByte();
1213
1214         complain_weapon_time = time;
1215         weapontime = time; // ping the weapon panel
1216
1217         switch(complain_weapon_type)
1218         {
1219                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1220                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1221                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1222         }
1223 }
1224
1225 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1226 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1227 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1228 float CSQC_Parse_TempEntity()
1229 {
1230         float bHandled;
1231                 bHandled  = true;
1232         // Acquire TE ID
1233         float nTEID;
1234                 nTEID = ReadByte();
1235
1236         if(autocvar_developer_csqcentities)
1237                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1238
1239                 // NOTE: Could just do return instead of break...
1240         switch(nTEID)
1241         {
1242                 case TE_CSQC_TARGET_MUSIC:
1243                         Net_TargetMusic();
1244                         bHandled = true;
1245                         break;
1246                 case TE_CSQC_PICTURE:
1247                         Net_MapVote_Picture();
1248                         bHandled = true;
1249                         break;
1250                 case TE_CSQC_RACE:
1251                         Net_ReadRace();
1252                         bHandled = true;
1253                         break;
1254                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1255                         Net_ReadNexgunBeamParticle();
1256                         bHandled = true;
1257                         break;
1258                 case TE_CSQC_TEAMNAGGER:
1259                         Net_TeamNagger();
1260                         bHandled = true;
1261                         break;
1262                 case TE_CSQC_LIGHTNINGARC:
1263                         Net_ReadLightningarc();
1264                         bHandled = true;
1265                         break;
1266                 case TE_CSQC_PINGPLREPORT:
1267                         Net_ReadPingPLReport();
1268                         bHandled = true;
1269                         break;
1270                 case TE_CSQC_WEAPONCOMPLAIN:
1271                         Net_WeaponComplain();
1272                         bHandled = true;
1273                         break;
1274                 case TE_CSQC_VEHICLESETUP:
1275                         Net_VehicleSetup();
1276                         bHandled = true;
1277                         break;
1278                 case TE_CSQC_SVNOTICE:
1279                         cl_notice_read();
1280                         bHandled = true;
1281                         break;
1282                 default:
1283                         // No special logic for this temporary entity; return 0 so the engine can handle it
1284                         bHandled = false;
1285                         break;
1286         }
1287
1288         return bHandled;
1289 }
1290
1291 string getcommandkey(string text, string command)
1292 {
1293         string keys;
1294         float n, j, k, l = 0;
1295
1296         if (!autocvar_hud_showbinds)
1297                 return text;
1298
1299         keys = db_get(binddb, command);
1300         if (keys == "")
1301         {
1302                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1303                 for(j = 0; j < n; ++j)
1304                 {
1305                         k = stof(argv(j));
1306                         if(k != -1)
1307                         {
1308                                 if ("" == keys)
1309                                         keys = keynumtostring(k);
1310                                 else
1311                                         keys = strcat(keys, ", ", keynumtostring(k));
1312
1313                                 ++l;
1314                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1315                                         break;
1316                         }
1317
1318                 }
1319                 if (keys == "")
1320                         keys = "NO_KEY";
1321                 db_put(binddb, command, keys);
1322         }
1323
1324         if (keys == "NO_KEY") {
1325                 if (autocvar_hud_showbinds > 1)
1326                         return sprintf(_("%s (not bound)"), text);
1327                 else
1328                         return text;
1329         }
1330         else if (autocvar_hud_showbinds > 1)
1331                 return sprintf(_("%s (%s)"), text, keys);
1332         else
1333                 return keys;
1334 }