qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void menu_show_error()
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 }
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void menu_sub_null()
  37 {
  38 }
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+showscores");registercmd("-showscores");
  95         registercmd("+showaccuracy");registercmd("-showaccuracy");
  96
  97 #ifndef CAMERATEST
  98         if(isdemo())
  99         {
 100 #endif
 101                 registercmd("+forward");registercmd("-forward");
 102                 registercmd("+back");registercmd("-back");
 103                 registercmd("+moveup");registercmd("-moveup");
 104                 registercmd("+movedown");registercmd("-movedown");
 105                 registercmd("+moveright");registercmd("-moveright");
 106                 registercmd("+moveleft");registercmd("-moveleft");
 107                 registercmd("+roll_right");registercmd("-roll_right");
 108                 registercmd("+roll_left");registercmd("-roll_left");
 109 #ifndef CAMERATEST
 110         }
 111 #endif
 112         registercvar("hud_usecsqc", "1");
 113         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 114
 115         gametype = 0;
 116
 117         // hud_fields uses strunzone on the titles!
 118         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 119                 hud_title[i] = strzone("(null)");
 120
 121         postinit = false;
 122
 123         calledhooks = 0;
 124
 125         teams = Sort_Spawn();
 126         players = Sort_Spawn();
 127
 128         GetTeam(COLOR_SPECTATOR, true); // add specs first
 129
 130         RegisterWeapons();
 131
 132         WaypointSprite_Load();
 133
 134         // precaches
 135         precache_sound("misc/hit.wav");
 136         precache_sound("misc/typehit.wav");
 137         Projectile_Precache();
 138         Hook_Precache();
 139         GibSplash_Precache();
 140         Casings_Precache();
 141         DamageInfo_Precache();
 142         Vehicles_Precache();
 143         turrets_precache();
 144
 145         if(autocvar_cl_announcer != cl_announcer_prev) {
 146                 Announcer_Precache();
 147                 if(cl_announcer_prev)
 148                         strunzone(cl_announcer_prev);
 149                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 150         }
 151         Tuba_Precache();
 152
 153         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 154         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 155
 156         get_mi_min_max_texcoords(1); // try the CLEVER way first
 157         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 158         shortmapname = mi_shortname;
 159
 160         if(precache_pic(minimapname) == "")
 161         {
 162                 // but maybe we have a non-clever minimap
 163                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 164                 if(precache_pic(minimapname) == "")
 165                         minimapname = ""; // FAIL
 166                 else
 167                         get_mi_min_max_texcoords(0); // load new texcoords
 168         }
 169
 170         mi_center = (mi_min + mi_max) * 0.5;
 171         mi_scale = mi_max - mi_min;
 172         minimapname = strzone(minimapname);
 173
 174         WarpZone_Init();
 175
 176         hud_configure_prev = -1;
 177         tab_panel = -1;
 178 }
 179
 180 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 181 void CSQC_Shutdown(void)
 182 {
 183 #ifdef USE_FTE
 184 #pragma TARGET id
 185         if(!__engine_check)
 186                 return 0;
 187 #pragma TARGET fte
 188 #endif
 189
 190         WarpZone_Shutdown();
 191
 192         remove(teams);
 193         remove(players);
 194         db_close(binddb);
 195         db_close(tempdb);
 196         if(autocvar_cl_db_saveasdump)
 197                 db_dump(ClientProgsDB, "client.db");
 198         else
 199                 db_save(ClientProgsDB, "client.db");
 200         db_close(ClientProgsDB);
 201
 202         cvar_clientsettemp_restore();
 203
 204         if(camera_active)
 205                 cvar_set("chase_active",ftos(chase_active_backup));
 206
 207         // unset the event chasecam's chase_active
 208         if(autocvar_chase_active < 0)
 209                 cvar_set("chase_active", "0");
 210
 211         if not(isdemo())
 212         {
 213                 if not(calledhooks & HOOK_START)
 214                         localcmd("\n_cl_hook_gamestart nop\n");
 215                 if not(calledhooks & HOOK_END)
 216                         localcmd("\ncl_hook_gameend\n");
 217         }
 218 }
 219
 220 .float has_team;
 221 float SetTeam(entity o, float Team)
 222 {
 223         entity tm;
 224         if(teamplay)
 225         {
 226                 switch(Team)
 227                 {
 228                         case -1:
 229                         case COLOR_TEAM1:
 230                         case COLOR_TEAM2:
 231                         case COLOR_TEAM3:
 232                         case COLOR_TEAM4:
 233                                 break;
 234                         default:
 235                                 if(GetTeam(Team, false) == NULL)
 236                                 {
 237                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 238                                         Team = COLOR_SPECTATOR;
 239                                 }
 240                                 break;
 241                 }
 242         }
 243         else
 244         {
 245                 switch(Team)
 246                 {
 247                         case -1:
 248                         case 0:
 249                                 break;
 250                         default:
 251                                 if(GetTeam(Team, false) == NULL)
 252                                 {
 253                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 254                                         Team = COLOR_SPECTATOR;
 255                                 }
 256                                 break;
 257                 }
 258         }
 259         if(Team == -1) // leave
 260         {
 261                 if(o.has_team)
 262                 {
 263                         tm = GetTeam(o.team, false);
 264                         tm.team_size -= 1;
 265                         o.has_team = 0;
 266                         return TRUE;
 267                 }
 268         }
 269         else
 270         {
 271                 if not(o.has_team)
 272                 {
 273                         o.team = Team;
 274                         tm = GetTeam(Team, true);
 275                         tm.team_size += 1;
 276                         o.has_team = 1;
 277                         return TRUE;
 278                 }
 279                 else if(Team != o.team)
 280                 {
 281                         tm = GetTeam(o.team, false);
 282                         tm.team_size -= 1;
 283                         o.team = Team;
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         return TRUE;
 287                 }
 288         }
 289         return FALSE;
 290 }
 291
 292 void Playerchecker_Think()
 293 {
 294         float i;
 295         entity e;
 296         for(i = 0; i < maxclients; ++i)
 297         {
 298                 e = playerslots[i];
 299                 if(GetPlayerName(i) == "")
 300                 {
 301                         if(e.sort_prev)
 302                         {
 303                                 // player disconnected
 304                                 SetTeam(e, -1);
 305                                 RemovePlayer(e);
 306                                 e.sort_prev = world;
 307                                 //e.gotscores = 0;
 308                         }
 309                 }
 310                 else
 311                 {
 312                         if not(e.sort_prev)
 313                         {
 314                                 // player connected
 315                                 if not(e)
 316                                         playerslots[i] = e = spawn();
 317                                 e.sv_entnum = i;
 318                                 e.ping = 0;
 319                                 e.ping_packetloss = 0;
 320                                 e.ping_movementloss = 0;
 321                                 //e.gotscores = 0; // we might already have the scores...
 322                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 323                                 RegisterPlayer(e);
 324                                 HUD_UpdatePlayerPos(e);
 325                         }
 326                 }
 327         }
 328         self.nextthink = time + 0.2;
 329 }
 330
 331 void Porto_Init();
 332 void TrueAim_Init();
 333 void PostInit(void)
 334 {
 335         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 336
 337         entity playerchecker;
 338         playerchecker = spawn();
 339         playerchecker.think = Playerchecker_Think;
 340         playerchecker.nextthink = time + 0.2;
 341
 342         Porto_Init();
 343         TrueAim_Init();
 344
 345         postinit = true;
 346 }
 347
 348 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 349 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 350 float button_zoom;
 351 void Cmd_HUD_SetFields(float);
 352 void Cmd_HUD_Help(float);
 353 float CSQC_ConsoleCommand(string strMessage)
 354 {
 355         float argc;
 356         // Tokenize String
 357         argc = tokenize_console(strMessage);
 358
 359         // Acquire Command
 360         string strCmd;
 361         strCmd = argv(0);
 362
 363         if(strCmd == "hud_configure") { // config hud
 364                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 365                 return true;
 366         } else if(strCmd == "hud_save") { // save hud config
 367                 if(argv(1) == "" || argv(2)) {
 368                         print(_("Usage:\n"));
 369                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 370                 }
 371                 else
 372                         HUD_Panel_ExportCfg(argv(1));
 373                 return true;
 374         } else if(strCmd == "+showscores") {
 375                 scoreboard_showscores = true;
 376                 return true;
 377         } else if(strCmd == "-showscores") {
 378                 scoreboard_showscores = false;
 379                 return true;
 380         } else if(strCmd == "+showaccuracy") {
 381                 scoreboard_showaccuracy = true;
 382                 return true;
 383         } else if(strCmd == "-showaccuracy") {
 384                 scoreboard_showaccuracy = false;
 385                 return true;
 386         }
 387
 388         if(camera_active)
 389         if(strCmd == "+forward" || strCmd == "-back") {
 390                 ++camera_direction_x;
 391                 return true;
 392         } else if(strCmd == "-forward" || strCmd == "+back") {
 393                 --camera_direction_x;
 394                 return true;
 395         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 396                 --camera_direction_y;
 397                 return true;
 398         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 399                 ++camera_direction_y;
 400                 return true;
 401         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 402                 ++camera_direction_z;
 403                 return true;
 404         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 405                 --camera_direction_z;
 406                 return true;
 407         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 408                 ++camera_roll;
 409                 return true;
 410         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 411                 --camera_roll;
 412                 return true;
 413         }
 414
 415         return false;
 416 }
 417
 418 .vector view_ofs;
 419 entity debug_shotorg;
 420 void ShotOrg_Draw()
 421 {
 422         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 423         self.angles = view_angles;
 424         self.angles_x = -self.angles_x;
 425         if not(self.cnt)
 426                 self.drawmask = MASK_NORMAL;
 427         else
 428                 self.drawmask = 0;
 429 }
 430 void ShotOrg_Draw2D()
 431 {
 432         vector coord2d_topleft, coord2d_topright, coord2d;
 433         string s;
 434         vector fs;
 435
 436         s = vtos(self.view_ofs);
 437         s = substring(s, 1, strlen(s) - 2);
 438         if(tokenize_console(s) == 3)
 439                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 440
 441         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 442         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 443
 444         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 445
 446         coord2d = coord2d_topleft;
 447         if(fs_x < 8)
 448         {
 449                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 450                 fs = '8 8 0';
 451         }
 452         coord2d_y -= fs_y;
 453         coord2d_z = 0;
 454         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 455 }
 456
 457 void ShotOrg_Spawn()
 458 {
 459         debug_shotorg = spawn();
 460         debug_shotorg.draw = ShotOrg_Draw;
 461         debug_shotorg.draw2d = ShotOrg_Draw2D;
 462         debug_shotorg.renderflags = RF_VIEWMODEL;
 463         debug_shotorg.effects = EF_FULLBRIGHT;
 464         precache_model("models/shotorg_adjuster.md3");
 465         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 466         debug_shotorg.scale = 2;
 467         debug_shotorg.view_ofs = '25 8 -8';
 468 }
 469
 470 void DrawDebugModel()
 471 {
 472         if(time - floor(time) > 0.5)
 473         {
 474                 PolyDrawModel(self);
 475                 self.drawmask = 0;
 476         }
 477         else
 478         {
 479                 self.renderflags = 0;
 480                 self.drawmask = MASK_NORMAL;
 481         }
 482 }
 483
 484 void GameCommand(string msg)
 485 {
 486         string s;
 487         float argc;
 488         entity e;
 489         argc = tokenize_console(msg);
 490
 491         if(argv(0) == "help" || argc == 0)
 492         {
 493                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 494                 print(_("  settemp cvar value\n"));
 495                 print(_("  scoreboard_columns_set ...\n"));
 496                 print(_("  scoreboard_columns_help\n"));
 497                 GameCommand_Generic("help");
 498                 return;
 499         }
 500
 501         if(GameCommand_Generic(msg))
 502                 return;
 503
 504         string cmd;
 505         cmd = argv(0);
 506         if(cmd == "mv_download") {
 507                 Cmd_MapVote_MapDownload(argc);
 508         }
 509         else if(cmd == "hud_panel_radar_maximized")
 510         {
 511                 if(argc == 1)
 512                         hud_panel_radar_maximized = !hud_panel_radar_maximized;
 513                 else
 514                         hud_panel_radar_maximized = (stof(argv(1)) != 0);
 515         }
 516         else if(cmd == "settemp") {
 517                 cvar_clientsettemp(argv(1), argv(2));
 518         }
 519         else if(cmd == "scoreboard_columns_set") {
 520                 Cmd_HUD_SetFields(argc);
 521         }
 522         else if(cmd == "scoreboard_columns_help") {
 523                 Cmd_HUD_Help(argc);
 524         }
 525 #ifdef BLURTEST
 526         else if(cmd == "blurtest") {
 527                 blurtest_time0 = time;
 528                 blurtest_time1 = time + stof(argv(1));
 529                 blurtest_radius = stof(argv(2));
 530                 blurtest_power = stof(argv(3));
 531         }
 532 #endif
 533         else if(cmd == "shotorg_move") {
 534                 if(!debug_shotorg)
 535                         ShotOrg_Spawn();
 536                 else
 537                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 538                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 539         }
 540         else if(cmd == "shotorg_movez") {
 541                 if(!debug_shotorg)
 542                         ShotOrg_Spawn();
 543                 else
 544                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 545                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 546         }
 547         else if(cmd == "shotorg_set") {
 548                 if(!debug_shotorg)
 549                         ShotOrg_Spawn();
 550                 else
 551                         debug_shotorg.view_ofs = stov(argv(1));
 552                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 553         }
 554         else if(cmd == "shotorg_setz") {
 555                 if(!debug_shotorg)
 556                         ShotOrg_Spawn();
 557                 else
 558                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 559                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 560         }
 561         else if(cmd == "shotorg_toggle_hide") {
 562                 if(debug_shotorg)
 563                 {
 564                         debug_shotorg.cnt = !debug_shotorg.cnt;
 565                 }
 566         }
 567         else if(cmd == "shotorg_end") {
 568                 if(debug_shotorg)
 569                 {
 570                         print(vtos(debug_shotorg.view_ofs), "\n");
 571                         remove(debug_shotorg);
 572                         debug_shotorg = world;
 573                 }
 574                 localcmd("sv_cmd debug_shotorg\n");
 575         }
 576         else if(cmd == "sendcvar") {
 577                 // W_FixWeaponOrder will trash argv, so save what we need.
 578                 string thiscvar;
 579                 thiscvar = strzone(argv(1));
 580                 s = cvar_string(thiscvar);
 581                 if(thiscvar == "cl_weaponpriority")
 582                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 583                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 584                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 585                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 586                 strunzone(thiscvar);
 587         }
 588         else if(cmd == "spawn") {
 589                 s = argv(1);
 590                 e = spawn();
 591                 precache_model(s);
 592                 setmodel(e, s);
 593                 setorigin(e, view_origin);
 594                 e.angles = view_angles;
 595                 e.draw = DrawDebugModel;
 596                 e.classname = "debugmodel";
 597         }
 598     else if(cmd == "vyes")
 599     {
 600         if(uid2name_dialog)
 601         {
 602             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 603             vote_prev = 0;
 604             localcmd("setreport cl_allow_uid2name 1\n");
 605             vote_change = -9999;
 606                         uid2name_dialog = 0;
 607         }
 608         else
 609         {
 610             localcmd("cmd vote yes\n");
 611         }
 612     }
 613     else if(cmd == "vno")
 614     {
 615         if(uid2name_dialog)
 616         {
 617             vote_active = 0;
 618             vote_prev = 0;
 619             localcmd("setreport cl_allow_uid2name 0\n");
 620             vote_change = -9999;
 621                         uid2name_dialog = 0;
 622         }
 623         else
 624         {
 625             localcmd("cmd vote no\n");
 626         }
 627     }
 628
 629         else
 630         {
 631                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 632         }
 633
 634         return;
 635 }
 636
 637 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 638 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 639 // All keys are in ascii.
 640 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 641 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 642 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 643 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 644 {
 645         float bSkipKey;
 646         bSkipKey = false;
 647
 648         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 649                 return true;
 650
 651         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 652                 return true;
 653
 654         if(menu_visible)
 655                 if(menu_action(bInputType, nPrimary, nSecondary))
 656                         return TRUE;
 657
 658         return bSkipKey;
 659 }
 660
 661 // END REQUIRED CSQC FUNCTIONS
 662 // --------------------------------------------------------------------------
 663
 664 // --------------------------------------------------------------------------
 665 // BEGIN OPTIONAL CSQC FUNCTIONS
 666 void Ent_RemoveEntCS()
 667 {
 668         entcs_receiver[self.sv_entnum] = world;
 669 }
 670 void Ent_ReadEntCS()
 671 {
 672         float sf;
 673         InterpolateOrigin_Undo();
 674
 675         self.classname = "entcs_receiver";
 676         sf = ReadByte();
 677
 678         if(sf & 1)
 679                 self.sv_entnum = ReadByte();
 680         if(sf & 2)
 681         {
 682                 self.origin_x = ReadShort();
 683                 self.origin_y = ReadShort();
 684                 self.origin_z = ReadShort();
 685         }
 686         if(sf & 4)
 687         {
 688                 self.angles_y = ReadByte() * 360.0 / 256;
 689                 self.angles_x = self.angles_z = 0;
 690         }
 691         if(sf & 8)
 692                 self.healthvalue = ReadByte() * 10;
 693         if(sf & 16)
 694                 self.armorvalue = ReadByte() * 10;
 695
 696         entcs_receiver[self.sv_entnum] = self;
 697         self.entremove = Ent_RemoveEntCS;
 698
 699         InterpolateOrigin_Note();
 700 }
 701
 702 void Ent_Remove();
 703
 704 void Ent_RemovePlayerScore()
 705 {
 706         float i;
 707
 708         if(self.owner)
 709         {
 710                 SetTeam(self.owner, -1);
 711                 self.owner.gotscores = 0;
 712                 for(i = 0; i < MAX_SCORE; ++i)
 713                         self.owner.(scores[i]) = 0; // clear all scores
 714         }
 715 }
 716
 717 void Ent_ReadPlayerScore()
 718 {
 719         float i, n;
 720         float isNew;
 721         entity o;
 722
 723         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 724         // (no I've never heard of M-x replace-string, sed, or anything like that)
 725         isNew = !self.owner; // workaround for DP bug
 726         n = ReadByte()-1;
 727
 728 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 729         if(!isNew && n != self.sv_entnum)
 730         {
 731                 //print(_("A CSQC entity changed its owner!\n"));
 732                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 733                 isNew = true;
 734                 Ent_Remove();
 735                 self.enttype = ENT_CLIENT_SCORES;
 736         }
 737 #endif
 738
 739         self.sv_entnum = n;
 740
 741         if not(playerslots[self.sv_entnum])
 742                 playerslots[self.sv_entnum] = spawn();
 743         o = self.owner = playerslots[self.sv_entnum];
 744         o.sv_entnum = self.sv_entnum;
 745         o.gotscores = 1;
 746
 747         //if not(o.sort_prev)
 748         //      RegisterPlayer(o);
 749         //playerchecker will do this for us later, if it has not already done so
 750
 751         float sf, lf;
 752 #if MAX_SCORE <= 8
 753         sf = ReadByte();
 754         lf = ReadByte();
 755 #else
 756         sf = ReadShort();
 757         lf = ReadShort();
 758 #endif
 759         float p;
 760         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 761                 if(sf & p)
 762                 {
 763                         if(lf & p)
 764                                 o.(scores[i]) = ReadInt24_t();
 765                         else
 766                                 o.(scores[i]) = ReadChar();
 767                 }
 768
 769         if(o.sort_prev)
 770                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 771
 772         self.entremove = Ent_RemovePlayerScore;
 773 }
 774
 775 void Ent_ReadTeamScore()
 776 {
 777         float i;
 778         entity o;
 779
 780         self.team = ReadByte();
 781         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 782
 783         float sf, lf;
 784 #if MAX_TEAMSCORE <= 8
 785         sf = ReadByte();
 786         lf = ReadByte();
 787 #else
 788         sf = ReadShort();
 789         lf = ReadShort();
 790 #endif
 791         float p;
 792         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 793                 if(sf & p)
 794                 {
 795                         if(lf & p)
 796                                 o.(teamscores[i]) = ReadInt24_t();
 797                         else
 798                                 o.(teamscores[i]) = ReadChar();
 799                 }
 800
 801         HUD_UpdateTeamPos(o);
 802 }
 803
 804 void Ent_ClientData()
 805 {
 806         float f;
 807         float newspectatee_status;
 808
 809         f = ReadByte();
 810
 811         scoreboard_showscores_force = (f & 1);
 812
 813         if(f & 2)
 814         {
 815                 newspectatee_status = ReadByte();
 816                 if(newspectatee_status == player_localentnum)
 817                         newspectatee_status = -1; // observing
 818         }
 819         else
 820                 newspectatee_status = 0;
 821
 822         spectatorbutton_zoom = (f & 4);
 823
 824         if(f & 8)
 825         {
 826                 angles_held_status = 1;
 827                 angles_held_x = ReadAngle();
 828                 angles_held_y = ReadAngle();
 829                 angles_held_z = 0;
 830         }
 831         else
 832                 angles_held_status = 0;
 833
 834         if(newspectatee_status != spectatee_status)
 835         {
 836                 // clear race stuff
 837                 race_laptime = 0;
 838                 race_checkpointtime = 0;
 839         }
 840         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 841         {
 842                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 843                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 844                 )
 845                         prev_p_health = -1;
 846                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 847                         prev_health = -1;
 848         }
 849         spectatee_status = newspectatee_status;
 850 }
 851
 852 void Ent_Nagger()
 853 {
 854         float nags, i, j, b, f;
 855
 856         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 857
 858         if(!(nags & 4))
 859         {
 860                 if(vote_called_vote)
 861                         strunzone(vote_called_vote);
 862                 vote_called_vote = string_null;
 863                 vote_active = 0;
 864         }
 865         else
 866         {
 867                 vote_active = 1;
 868         }
 869
 870         if(nags & 64)
 871         {
 872                 vote_yescount = ReadByte();
 873                 vote_nocount = ReadByte();
 874                 vote_needed = ReadByte();
 875                 vote_highlighted = ReadChar();
 876         }
 877
 878         if(nags & 128)
 879         {
 880                 if(vote_called_vote)
 881                         strunzone(vote_called_vote);
 882                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 883         }
 884
 885         if(nags & 1)
 886         {
 887                 for(j = 0; j < maxclients; ++j)
 888                         if(playerslots[j])
 889                                 playerslots[j].ready = 1;
 890                 for(i = 1; i <= maxclients; i += 8)
 891                 {
 892                         f = ReadByte();
 893                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 894                                 if not(f & b)
 895                                         if(playerslots[j])
 896                                                 playerslots[j].ready = 0;
 897                 }
 898         }
 899
 900         ready_waiting = (nags & 1);
 901         ready_waiting_for_me = (nags & 2);
 902         vote_waiting = (nags & 4);
 903         vote_waiting_for_me = (nags & 8);
 904         warmup_stage = (nags & 16);
 905 }
 906
 907 void Ent_RandomSeed()
 908 {
 909         float s;
 910         prandom_debug();
 911         s = ReadShort();
 912         psrandom(s);
 913 }
 914
 915 void Ent_ReadAccuracy(void)
 916 {
 917         float sf, f, w, b;
 918         sf = ReadInt24_t();
 919         if(sf == 0)
 920         {
 921                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 922                         weapon_accuracy[w] = -1;
 923                 return;
 924         }
 925
 926         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 927         {
 928                 if(sf & f)
 929                 {
 930                         b = ReadByte();
 931                         if(b == 0)
 932                                 weapon_accuracy[w] = -1;
 933                         else if(b == 255)
 934                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 935                         else
 936                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 937                 }
 938         }
 939 }
 940
 941 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 942 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 943 void Ent_RadarLink();
 944 void Ent_Init();
 945 void Ent_ScoresInfo();
 946 void CSQC_Ent_Update(float bIsNewEntity)
 947 {
 948         float t;
 949         float savetime;
 950         t = ReadByte();
 951
 952         // set up the "time" global for received entities to be correct for interpolation purposes
 953         savetime = time;
 954         if(servertime)
 955         {
 956                 time = servertime;
 957         }
 958         else
 959         {
 960                 serverprevtime = time;
 961                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 962                 time = serverprevtime + serverdeltatime;
 963         }
 964
 965 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 966         if(self.enttype)
 967         {
 968                 if(t != self.enttype || bIsNewEntity)
 969                 {
 970                         //print(_("A CSQC entity changed its type!\n"));
 971                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 972                         Ent_Remove();
 973                         bIsNewEntity = 1;
 974                 }
 975         }
 976         else
 977         {
 978                 if(!bIsNewEntity)
 979                 {
 980                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 981                         bIsNewEntity = 1;
 982                 }
 983         }
 984 #endif
 985         self.enttype = t;
 986         switch(t)
 987         {
 988                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 989                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 990                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 991                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 992                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 993                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 994                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 995                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 996                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 997                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 998                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 999                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
1000                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
1001                 case ENT_CLIENT_INIT: Ent_Init(); break;
1002                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
1003                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
1004                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
1005                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
1006                 case ENT_CLIENT_WALL: Ent_Wall(); break;
1007                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
1008                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
1009                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
1010                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
1011                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
1012                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
1013                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
1014                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
1015                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
1016                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
1017                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
1018                 case ENT_CLIENT_TURRET: ent_turret(); break;
1019                 default:
1020                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
1021                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
1022                         break;
1023         }
1024
1025         time = savetime;
1026 }
1027 // Destructor, but does NOT deallocate the entity by calling remove(). Also
1028 // used when an entity changes its type. For an entity that someone interacts
1029 // with others, make sure it can no longer do so.
1030 void Ent_Remove()
1031 {
1032         if(self.entremove)
1033                 self.entremove();
1034
1035         self.enttype = 0;
1036         self.classname = "";
1037         self.draw = menu_sub_null;
1038         self.entremove = menu_sub_null;
1039         // TODO possibly set more stuff to defaults
1040 }
1041 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
1042 void CSQC_Ent_Remove()
1043 {
1044         if(self.enttype)
1045                 Ent_Remove();
1046         remove(self);
1047 }
1048
1049 void Gamemode_Init()
1050 {
1051         if not(isdemo())
1052         {
1053                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1054                 calledhooks |= HOOK_START;
1055         }
1056 }
1057 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1058 void CSQC_Parse_StuffCmd(string strMessage)
1059 {
1060         localcmd(strMessage);
1061 }
1062 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1063 void CSQC_Parse_Print(string strMessage)
1064 {
1065         print(ColorTranslateRGB(strMessage));
1066 }
1067
1068 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1069 void CSQC_Parse_CenterPrint(string strMessage)
1070 {
1071         centerprint(strMessage);
1072 }
1073
1074 string notranslate_fogcmd1 = "\nfog ";
1075 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1076 void Fog_Force()
1077 {
1078         // TODO somehow thwart prvm_globalset client ...
1079
1080         if(forcefog != "")
1081                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1082 }
1083
1084 void Gamemode_Init();
1085 void Ent_ScoresInfo()
1086 {
1087         float i;
1088         self.classname = "ent_client_scores_info";
1089         gametype = ReadByte();
1090         for(i = 0; i < MAX_SCORE; ++i)
1091         {
1092                 scores_label[i] = strzone(ReadString());
1093                 scores_flags[i] = ReadByte();
1094         }
1095         for(i = 0; i < MAX_TEAMSCORE; ++i)
1096         {
1097                 teamscores_label[i] = strzone(ReadString());
1098                 teamscores_flags[i] = ReadByte();
1099         }
1100         HUD_InitScores();
1101         Gamemode_Init();
1102 }
1103
1104 void Ent_Init()
1105 {
1106         self.classname = "ent_client_init";
1107
1108         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1109
1110         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1111         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1112         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1113         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1114         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1115         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1116         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1117         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1118         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1119         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1120         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1121         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1122
1123         if(forcefog)
1124                 strunzone(forcefog);
1125         forcefog = strzone(ReadString());
1126
1127         armorblockpercent = ReadByte() / 255.0;
1128
1129         g_weaponswitchdelay = ReadByte() / 255.0;
1130
1131         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1132         g_balance_grenadelauncher_bouncestop = ReadCoord();
1133         g_balance_electro_secondary_bouncefactor = ReadCoord();
1134         g_balance_electro_secondary_bouncestop = ReadCoord();
1135
1136         nex_scope = !ReadByte();
1137         rifle_scope = !ReadByte();
1138
1139         serverflags = ReadByte();
1140
1141         minelayer_maxmines = ReadByte();
1142
1143         hagar_maxrockets = ReadByte();
1144
1145         g_trueaim_minrange = ReadCoord();
1146
1147         if(!postinit)
1148                 PostInit();
1149 }
1150
1151 void Net_ReadRace()
1152 {
1153         float b;
1154
1155         b = ReadByte();
1156
1157         switch(b)
1158         {
1159                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1160                         race_checkpoint = ReadByte();
1161                         race_time = ReadInt24_t();
1162                         race_previousbesttime = ReadInt24_t();
1163                         if(race_previousbestname)
1164                                 strunzone(race_previousbestname);
1165                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1166
1167                         race_checkpointtime = time;
1168
1169                         if(race_checkpoint == 0 || race_checkpoint == 254)
1170                         {
1171                                 race_penaltyaccumulator = 0;
1172                                 race_laptime = time; // valid
1173                         }
1174
1175                         break;
1176
1177                 case RACE_NET_CHECKPOINT_CLEAR:
1178                         race_laptime = 0;
1179                         race_checkpointtime = 0;
1180                         break;
1181
1182                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1183                         race_laptime = ReadCoord();
1184                         race_checkpointtime = -99999;
1185                         // fall through
1186                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1187                         race_nextcheckpoint = ReadByte();
1188
1189                         race_nextbesttime = ReadInt24_t();
1190                         if(race_nextbestname)
1191                                 strunzone(race_nextbestname);
1192                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1193                         break;
1194
1195                 case RACE_NET_CHECKPOINT_HIT_RACE:
1196                         race_mycheckpoint = ReadByte();
1197                         race_mycheckpointtime = time;
1198                         race_mycheckpointdelta = ReadInt24_t();
1199                         race_mycheckpointlapsdelta = ReadByte();
1200                         if(race_mycheckpointlapsdelta >= 128)
1201                                 race_mycheckpointlapsdelta -= 256;
1202                         if(race_mycheckpointenemy)
1203                                 strunzone(race_mycheckpointenemy);
1204                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1205                         break;
1206
1207                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1208                         race_othercheckpoint = ReadByte();
1209                         race_othercheckpointtime = time;
1210                         race_othercheckpointdelta = ReadInt24_t();
1211                         race_othercheckpointlapsdelta = ReadByte();
1212                         if(race_othercheckpointlapsdelta >= 128)
1213                                 race_othercheckpointlapsdelta -= 256;
1214                         if(race_othercheckpointenemy)
1215                                 strunzone(race_othercheckpointenemy);
1216                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1217                         break;
1218
1219                 case RACE_NET_PENALTY_RACE:
1220                         race_penaltyeventtime = time;
1221                         race_penaltytime = ReadShort();
1222                         //race_penaltyaccumulator += race_penaltytime;
1223                         if(race_penaltyreason)
1224                                 strunzone(race_penaltyreason);
1225                         race_penaltyreason = strzone(ReadString());
1226                         break;
1227
1228                 case RACE_NET_PENALTY_QUALIFYING:
1229                         race_penaltyeventtime = time;
1230                         race_penaltytime = ReadShort();
1231                         race_penaltyaccumulator += race_penaltytime;
1232                         if(race_penaltyreason)
1233                                 strunzone(race_penaltyreason);
1234                         race_penaltyreason = strzone(ReadString());
1235                         break;
1236
1237                 case RACE_NET_SERVER_RECORD:
1238                         race_server_record = ReadInt24_t();
1239                         break;
1240                 case RACE_NET_SPEED_AWARD:
1241                         race_speedaward = ReadInt24_t();
1242                         if(race_speedaward_holder)
1243                                 strunzone(race_speedaward_holder);
1244                         race_speedaward_holder = strzone(ReadString());
1245                         break;
1246                 case RACE_NET_SPEED_AWARD_BEST:
1247                         race_speedaward_alltimebest = ReadInt24_t();
1248                         if(race_speedaward_alltimebest_holder)
1249                                 strunzone(race_speedaward_alltimebest_holder);
1250                         race_speedaward_alltimebest_holder = strzone(ReadString());
1251                         break;
1252                 case RACE_NET_SERVER_RANKINGS:
1253                         float pos, prevpos, del;
1254                         pos = ReadShort();
1255                         prevpos = ReadShort();
1256                         del = ReadShort();
1257
1258                         // move other rankings out of the way
1259                         float i;
1260                         if (prevpos) {
1261                                 for (i=prevpos-1;i>pos-1;--i) {
1262                                         grecordtime[i] = grecordtime[i-1];
1263                                         if(grecordholder[i])
1264                                                 strunzone(grecordholder[i]);
1265                                         grecordholder[i] = strzone(grecordholder[i-1]);
1266                                 }
1267                         } else if (del) { // a record has been deleted by the admin
1268                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1269                                         if (i == RANKINGS_CNT-1) { // clear out last record
1270                                                 grecordtime[i] = 0;
1271                                                 if (grecordholder[i])
1272                                                         strunzone(grecordholder[i]);
1273                                                 grecordholder[i] = string_null;
1274                                         }
1275                                         else {
1276                                                 grecordtime[i] = grecordtime[i+1];
1277                                                 if (grecordholder[i])
1278                                                         strunzone(grecordholder[i]);
1279                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1280                                         }
1281                                 }
1282                         } else { // player has no ranked record yet
1283                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1284                                         grecordtime[i] = grecordtime[i-1];
1285                                         if(grecordholder[i])
1286                                                 strunzone(grecordholder[i]);
1287                                         grecordholder[i] = strzone(grecordholder[i-1]);
1288                                 }
1289                         }
1290
1291                         // store new ranking
1292                         if(grecordholder[pos-1] != "")
1293                                 strunzone(grecordholder[pos-1]);
1294                         grecordholder[pos-1] = strzone(ReadString());
1295                         grecordtime[pos-1] = ReadInt24_t();
1296                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1297                                 race_myrank = pos;
1298                         break;
1299                 case RACE_NET_SERVER_STATUS:
1300                         race_status = ReadShort();
1301                         if(race_status_name)
1302                                 strunzone(race_status_name);
1303                         race_status_name = strzone(ReadString());
1304         }
1305 }
1306
1307 void Net_ReadSpawn()
1308 {
1309         zoomin_effect = 1;
1310         current_viewzoom = 0.6;
1311 }
1312
1313 void Net_TeamNagger()
1314 {
1315         teamnagger = 1;
1316 }
1317
1318 void Net_ReadPingPLReport()
1319 {
1320         float e, pi, pl, ml;
1321         e = ReadByte();
1322         pi = ReadShort();
1323         pl = ReadByte();
1324         ml = ReadByte();
1325         if not(playerslots[e])
1326                 return;
1327         playerslots[e].ping = pi;
1328         playerslots[e].ping_packetloss = pl / 255.0;
1329         playerslots[e].ping_movementloss = ml / 255.0;
1330 }
1331
1332 void Net_WeaponComplain() {
1333         complain_weapon = ReadByte();
1334
1335         if(complain_weapon_name)
1336                 strunzone(complain_weapon_name);
1337         complain_weapon_name = strzone(ReadString());
1338
1339         complain_weapon_type = ReadByte();
1340
1341         complain_weapon_time = time;
1342         weapontime = time; // ping the weapon panel
1343 }
1344
1345 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1346 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1347 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1348 float CSQC_Parse_TempEntity()
1349 {
1350         float bHandled;
1351                 bHandled  = true;
1352         // Acquire TE ID
1353         float nTEID;
1354                 nTEID = ReadByte();
1355
1356                 // NOTE: Could just do return instead of break...
1357         switch(nTEID)
1358         {
1359                 case TE_CSQC_TARGET_MUSIC:
1360                         Net_TargetMusic();
1361                         bHandled = true;
1362                         break;
1363                 case TE_CSQC_PICTURE:
1364                         Net_MapVote_Picture();
1365                         bHandled = true;
1366                         break;
1367                 case TE_CSQC_RACE:
1368                         Net_ReadRace();
1369                         bHandled = true;
1370                         break;
1371                 case TE_CSQC_SPAWN:
1372                         Net_ReadSpawn();
1373                         bHandled = true;
1374                         break;
1375                 case TE_CSQC_ZCURVEPARTICLES:
1376                         Net_ReadZCurveParticles();
1377                         bHandled = true;
1378                         break;
1379                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1380                         Net_ReadNexgunBeamParticle();
1381                         bHandled = true;
1382                         break;
1383                 case TE_CSQC_TEAMNAGGER:
1384                         Net_TeamNagger();
1385                         bHandled = true;
1386                         break;
1387                 case TE_CSQC_LIGHTNINGARC:
1388                         Net_ReadLightningarc();
1389                         bHandled = true;
1390                         break;
1391                 case TE_CSQC_PINGPLREPORT:
1392                         Net_ReadPingPLReport();
1393                         bHandled = true;
1394                         break;
1395                 case TE_CSQC_ANNOUNCE:
1396                         announce_snd = strzone(ReadString());
1397                         bHandled = true;
1398                         break;
1399                 case TE_CSQC_KILLNOTIFY:
1400                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1401                         bHandled = true;
1402                         break;
1403                 case TE_CSQC_KILLCENTERPRINT:
1404                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1405                         bHandled = true;
1406                         break;
1407                 case TE_CSQC_CENTERPRINT_GENERIC:
1408                         float id;
1409                         string s;
1410                         id = ReadByte();
1411                         s = ReadString();
1412                         if (id != 0 && s != "")
1413                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1414                         else
1415                                 centerprint_generic(id, s, 0, 0);
1416                         bHandled = true;
1417                         break;
1418                 case TE_CSQC_WEAPONCOMPLAIN:
1419                         Net_WeaponComplain();
1420                         bHandled = true;
1421                         break;
1422         case TE_CSQC_VEHICLESETUP:
1423             Net_VehicleSetup();
1424             bHandled = true;
1425             break;
1426                 default:
1427                         // No special logic for this temporary entity; return 0 so the engine can handle it
1428                         bHandled = false;
1429                         break;
1430         }
1431
1432         return bHandled;
1433 }
1434
1435 string getcommandkey(string text, string command)
1436 {
1437         string keys;
1438         float n, j, k, l;
1439
1440         if (!autocvar_hud_showbinds)
1441                 return text;
1442
1443         keys = db_get(binddb, command);
1444         if (!keys)
1445         {
1446                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1447                 for(j = 0; j < n; ++j)
1448                 {
1449                         k = stof(argv(j));
1450                         if(k != -1)
1451                         {
1452                                 if ("" == keys)
1453                                         keys = keynumtostring(k);
1454                                 else
1455                                         keys = strcat(keys, ", ", keynumtostring(k));
1456
1457                                 ++l;
1458                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1459                         }
1460
1461                 }
1462                 db_put(binddb, command, keys);
1463         }
1464
1465         if ("" == keys) {
1466                 if (autocvar_hud_showbinds > 1)
1467                         return sprintf(_("%s (not bound)"), text);
1468                 else
1469                         return text;
1470         }
1471         else if (autocvar_hud_showbinds > 1)
1472                 return sprintf(_("%s (%s)"), text, keys);
1473         else
1474                 return keys;
1475 }