add a master switch cvar and a custom color cvar
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / View.qc
1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
2 #define spider_rocket_targ "gfx/vehicles/target.tga"
3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
4 #define rkt_size 32
5 #define rld_size_x 256
6 #define rld_size_y 16
7
8 void CSQC_WAKIZASHI_HUD();
9
10 entity porto;
11 vector polyline[16];
12 float trace_dphitcontents;
13 float trace_networkentity;
14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
15 float DPCONTENTS_SOLID = 1; // blocks player movement
16 float DPCONTENTS_BODY = 32; // blocks player movement
17 float DPCONTENTS_CORPSE = 64; // blocks player movement
18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
19 void Porto_Draw()
20 {
21         vector p, dir, ang, q, nextdir;
22         float idx, portal_number, portal1_idx;
23
24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
25                 return;
26         if(intermission == 1)
27                 return;
28         if(intermission == 2)
29                 return;
30         if (getstati(STAT_HEALTH) <= 0)
31                 return;
32
33         dir = view_forward;
34
35         if(angles_held_status)
36         {
37                 makevectors(angles_held);
38                 dir = v_forward;
39         }
40
41         p = view_origin;
42
43         polyline[0] = p;
44         idx = 1;
45         portal_number = 0;
46         nextdir = dir;
47
48         for(;;)
49         {
50                 dir = nextdir;
51                 traceline(p, p + 65536 * dir, TRUE, porto);
52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
53                         return;
54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
55                 p = trace_endpos;
56                 polyline[idx] = p;
57                 ++idx;
58                 if(idx >= 16)
59                         return;
60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
61                         continue;
62                 ++portal_number;
63                 ang = vectoangles2(trace_plane_normal, dir);
64                 ang_x = -ang_x;
65                 makevectors(ang);
66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
67                         return;
68                 if(portal_number == 1)
69                         portal1_idx = idx;
70                 if(portal_number >= 2)
71                         break;
72         }
73
74         while(idx >= 2)
75         {
76                 p = polyline[idx-2];
77                 q = polyline[idx-1];
78                 if(idx == 2)
79                         p = p - view_up * 16;
80                 if(idx-1 >= portal1_idx)
81                 {
82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
83                 }
84                 else
85                 {
86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
87                 }
88                 --idx;
89         }
90 }
91
92 /**
93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
94  *
95  * TODO: Use a better solution where a common shared entitiy is used that contains
96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
97  * and STAT_FRAGLIMIT to be auto-sent)
98  */
99 void CheckForGamestartChange() {
100         float startTime;
101         startTime = getstatf(STAT_GAMESTARTTIME);
102         if (previous_game_starttime != startTime) {
103                 if ((time + 5.0) < startTime) {
104                         //if connecting to server while restart was active don't always play prepareforbattle
105                         sound(world, CHAN_AUTO, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
106                 }
107                 if (time < startTime) {
108                         restartAnnouncer = spawn();
109                         restartAnnouncer.think = restartAnnouncer_Think;
110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
111                 }
112         }
113         previous_game_starttime = startTime;
114 }
115
116 void Porto_Init()
117 {
118         porto = spawn();
119         porto.classname = "porto";
120         porto.draw = Porto_Draw;
121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
122 }
123
124 float drawtime;
125 float avgspeed;
126 vector GetCurrentFov(float fov)
127 {
128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
129
130         zoomsensitivity = cvar("cl_zoomsensitivity");
131         zoomfactor = cvar("cl_zoomfactor");
132         if(zoomfactor < 1 || zoomfactor > 16)
133                 zoomfactor = 2.5;
134         zoomspeed = cvar("cl_zoomspeed");
135         if(zoomspeed >= 0)
136                 if(zoomspeed < 0.5 || zoomspeed > 16)
137                         zoomspeed = 3.5;
138
139         zoomdir = button_zoom;
140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
141                 zoomdir += button_attack2;
142         if(spectatee_status > 0 || isdemo())
143         {
144                 if(spectatorbutton_zoom)
145                         zoomdir = 0 + !zoomdir;
146                 // do not even THINK about removing this 0
147                 // _I_ know what I am doing
148                 // fteqcc does not
149         }
150
151         if(zoomdir)
152                 zoomin_effect = 0;
153
154         if(zoomin_effect || camera_active)
155         {
156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
157         }
158         else
159         {
160                 if(zoomspeed < 0) // instant zoom
161                 {
162                         if(zoomdir)
163                                 current_viewzoom = 1 / zoomfactor;
164                         else
165                                 current_viewzoom = 1;
166                 }
167                 else
168                 {
169                         if(zoomdir)
170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
171                         else
172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
173                 }
174         }
175
176         if(almost_equals(current_viewzoom, 1))
177                 current_zoomfraction = 0;
178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
179                 current_zoomfraction = 1;
180         else
181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
182
183         if(zoomsensitivity < 1)
184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
185         else
186                 setsensitivityscale(1);
187
188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
191
192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
193
194         float frustumx, frustumy, fovx, fovy;
195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
199
200         return '1 0 0' * fovx + '0 1 0' * fovy;
201 }
202
203 // this function must match W_SetupShot!
204 float zoomscript_caught;
205
206 vector wcross_origin;
207 float wcross_scale_prev, wcross_alpha_prev;
208 vector wcross_color_prev;
209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
210 vector wcross_color_goal_prev;
211 float wcross_changedonetime;
212
213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
215 float wcross_name_changestarttime, wcross_name_changedonetime;
216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
217 entity trueaim;
218 entity trueaim_rifle;
219
220 #define SHOTTYPE_HITTEAM 1
221 #define SHOTTYPE_HITOBSTRUCTION 2
222 #define SHOTTYPE_HITWORLD 3
223 #define SHOTTYPE_HITENEMY 4
224
225 void TrueAim_Init()
226 {
227         trueaim = spawn();
228         trueaim.classname = "trueaim";
229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
230         trueaim_rifle = spawn();
231         trueaim_rifle.classname = "trueaim_rifle";
232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
233 }
234
235 float EnemyHitCheck()
236 {
237         float t;
238         wcross_origin = project_3d_to_2d(trace_endpos);
239         wcross_origin_z = 0;
240         if(trace_networkentity < 1)
241                 return SHOTTYPE_HITWORLD;
242         if(trace_networkentity > maxclients)
243                 return SHOTTYPE_HITWORLD;
244         t = GetPlayerColor(trace_networkentity - 1);
245         if(teamplay)
246                 if(t == myteam)
247                         return SHOTTYPE_HITTEAM;
248         if(t == COLOR_SPECTATOR)
249                 return SHOTTYPE_HITWORLD;
250         return SHOTTYPE_HITENEMY;
251 }
252
253 float TrueAimCheck()
254 {
255         float nudge = 1; // added to traceline target and subtracted from result
256         vector vecs, trueaimpoint, w_shotorg;
257         vector mi, ma, dv;
258         float shottype;
259         entity ta;
260         float mv;
261
262         mi = ma = '0 0 0';
263         ta = trueaim;
264         mv = MOVE_NOMONSTERS;
265
266         switch(activeweapon)
267         {
268                 case WEP_TUBA: // no aim
269                 case WEP_PORTO: // shoots from eye
270                 case WEP_HOOK: // no trueaim
271                 case WEP_GRENADE_LAUNCHER: // toss curve
272                         return SHOTTYPE_HITWORLD;
273                 case WEP_NEX:
274                 case WEP_MINSTANEX:
275                         mv = MOVE_NORMAL;
276                         break;
277                 case WEP_CAMPINGRIFLE:
278                         ta = trueaim_rifle;
279                         mv = MOVE_NORMAL;
280                         if(zoomscript_caught)
281                         {
282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
283                                 return EnemyHitCheck();
284                         }
285                         break;
286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
287                         mi = '-3 -3 -3';
288                         ma = '3 3 3';
289                         break;
290                 case WEP_FIREBALL: // projectile has a size!
291                         mi = '-16 -16 -16';
292                         ma = '16 16 16';
293                         break;
294                 case WEP_SEEKER: // projectile has a size!
295                         mi = '-2 -2 -2';
296                         ma = '2 2 2';
297                         break;
298                 case WEP_ELECTRO: // projectile has a size!
299                         mi = '0 0 -3';
300                         ma = '0 0 -3';
301                         break;
302         }
303
304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
305
306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
307         trueaimpoint = trace_endpos;
308
309         if(vecs_x > 0)
310                 vecs_y = -vecs_y;
311         else
312                 vecs = '0 0 0';
313
314         dv = view_right * vecs_y + view_up * vecs_z;
315         w_shotorg = view_origin + dv;
316
317         // now move the vecs forward as much as requested if possible
318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
319         w_shotorg = trace_endpos - view_forward * nudge;
320
321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
322         shottype = EnemyHitCheck();
323         if(shottype != SHOTTYPE_HITWORLD)
324                 return shottype;
325
326 #if 0
327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
328         // or rather, I know why, but see no fix
329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
331                 return SHOTTYPE_HITOBSTRUCTION;
332 #endif
333
334         return SHOTTYPE_HITWORLD;
335 }
336
337 void CSQC_common_hud(void);
338
339 void PostInit(void);
340 void CSQC_Demo_Camera();
341 float HUD_WouldDrawScoreboard();
342 float view_set;
343 float camera_mode;
344 float reticle_type;
345 string NextFrameCommand;
346 void CSQC_SPIDER_HUD();
347 void CSQC_RAPTOR_HUD();
348
349 vector freeze_pmove_org, freeze_input_angles;
350 entity nightvision_noise, nightvision_noise2;
351
352 float pickup_crosshair_time, pickup_crosshair_size;
353
354 float myhealth, myhealth_prev;
355 float myhealth_flash;
356
357 void CSQC_UpdateView(float w, float h)
358 {
359         entity e;
360         float fov;
361         float f, i, j;
362         vector v, vo;
363         vector vf_size, vf_min;
364         float a;
365
366         vf_size = R_SetView3fv(VF_SIZE);
367         vf_min = R_SetView3fv(VF_MIN);
368         vid_width = vf_size_x;
369         vid_height = vf_size_y;
370
371         vector reticle_pos, reticle_size;
372
373         WaypointSprite_Load();
374
375         if(spectatee_status)
376                 myteam = GetPlayerColor(spectatee_status - 1);
377         else
378                 myteam = GetPlayerColor(player_localentnum - 1);
379
380         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
381         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
382
383         warpzone_fixview_origin = pmove_org + vo;
384         warpzone_fixview_cl_viewangles = input_angles;
385         warpzone_fixview_angles = view_angles;
386         WarpZone_FixView();
387         pmove_org = warpzone_fixview_origin - vo;
388         input_angles = warpzone_fixview_cl_viewangles;
389         view_angles = warpzone_fixview_angles;
390
391         if(cvar("cl_lockview") || (autocvar__hud_configure && spectatee_status <= 0))
392         {
393                 pmove_org = freeze_pmove_org;
394                 input_angles = view_angles = freeze_input_angles;
395                 R_SetView(VF_ORIGIN, pmove_org + vo);
396                 R_SetView(VF_ANGLES, view_angles);
397                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
398         }
399         freeze_pmove_org = pmove_org;
400         freeze_input_angles = input_angles;
401
402         // Render the Scene
403         if(!intermission || !view_set)
404         {
405                 view_origin = pmove_org + vo;
406                 view_angles = input_angles;
407                 makevectors(view_angles);
408                 view_forward = v_forward;
409                 view_right = v_right;
410                 view_up = v_up;
411                 view_set = 1;
412         }
413
414 #ifdef BLURTEST
415         if(time > blurtest_time0 && time < blurtest_time1)
416         {
417                 float r, t;
418
419                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
420                 r = t * blurtest_radius;
421                 f = 1 / pow(t, blurtest_power) - 1;
422
423                 cvar_set("r_glsl_postprocess", "1");
424                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
425         }
426         else
427         {
428                 cvar_set("r_glsl_postprocess", "0");
429                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
430         }
431 #endif
432
433         TargetMusic_Advance();
434         Fog_Force();
435
436         drawframetime = max(0.000001, time - drawtime);
437         drawtime = time;
438
439         // watch for gametype changes here...
440         // in ParseStuffCMD the cmd isn't executed yet :/
441         // might even be better to add the gametype to TE_CSQC_INIT...?
442         if(!postinit)
443                 PostInit();
444
445         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
446                 if(calledhooks & HOOK_START)
447                 {
448                         localcmd("\ncl_hook_gameend\n");
449                         calledhooks |= HOOK_END;
450                 }
451
452         CheckForGamestartChange();
453         serverAnnouncer();
454         maptimeAnnouncer();
455         carrierAnnouncer();
456
457         fov = cvar("fov");
458         if(button_zoom || fov <= 59.5)
459         {
460                 if(!zoomscript_caught)
461                 {
462                         localcmd("+button4\n");
463                         zoomscript_caught = 1;
464                         ignore_plus_zoom += 1;
465                 }
466         }
467         else
468         {
469                 if(zoomscript_caught)
470                 {
471                         localcmd("-button4\n");
472                         zoomscript_caught = 0;
473                         ignore_minus_zoom += 1;
474                 }
475         }
476
477         ColorTranslateMode = cvar("cl_stripcolorcodes");
478         activeweapon = getstati(STAT_SWITCHWEAPON);
479         f = cvar("teamplay");
480         if(f != teamplay)
481         {
482                 teamplay = f;
483                 HUD_InitScores();
484         }
485
486         if(last_weapon != activeweapon) {
487                 weapontime = time;
488                 last_weapon = activeweapon;
489
490                 e = get_weaponinfo(activeweapon);
491                 if(e.netname != "")
492                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
493                 else
494                         localcmd("\ncl_hook_activeweapon none\n");
495         }
496
497         // ALWAYS Clear Current Scene First
498         R_ClearScene();
499
500         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
501         R_SetView(VF_SIZE, vf_size);
502         R_SetView(VF_MIN, vf_min);
503
504         // Assign Standard Viewflags
505         // Draw the World (and sky)
506         R_SetView(VF_DRAWWORLD, 1);
507
508         // Set the console size vars
509         vid_conwidth = cvar("vid_conwidth");
510         vid_conheight = cvar("vid_conheight");
511         vid_pixelheight = cvar("vid_pixelheight");
512
513         R_SetView(VF_FOV, GetCurrentFov(fov));
514
515         // Camera for demo playback
516         if(camera_active)
517         {
518                 if(cvar("camera_enable"))
519                         CSQC_Demo_Camera();
520                 else
521                 {
522                         cvar_set("chase_active", ftos(chase_active_backup));
523                         cvar_set("cl_demo_mousegrab", "0");
524                         camera_active = FALSE;
525                 }
526         }
527 #ifdef CAMERATEST
528         else if(cvar("camera_enable"))
529 #else
530         else if(cvar("camera_enable") && isdemo())
531 #endif
532         {
533                 // Enable required Darkplaces cvars
534                 chase_active_backup = cvar("chase_active");
535                 cvar_set("chase_active", "2");
536                 cvar_set("cl_demo_mousegrab", "1");
537                 camera_active = TRUE;
538                 camera_mode = FALSE;
539         }
540
541         // Draw the Crosshair
542         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
543
544         // Draw the Engine Status Bar (the default Quake HUD)
545         R_SetView(VF_DRAWENGINEHUD, 0);
546
547         // fetch this one only once per frame
548         hud_showbinds = cvar("hud_showbinds");
549         hud_showbinds_limit = cvar("hud_showbinds_limit");
550
551         // Update the mouse position
552         /*
553            mousepos_x = vid_conwidth;
554            mousepos_y = vid_conheight;
555            mousepos = mousepos*0.5 + getmousepos();
556          */
557
558         e = self;
559         for(self = world; (self = nextent(self)); )
560                 if(self.draw)
561                         self.draw();
562         self = e;
563
564         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
565         R_RenderScene();
566
567         // now switch to 2D drawing mode by calling a 2D drawing function
568         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
569         // next R_RenderScene call
570         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
571
572         if(cvar("r_fakelight") >= 2 || cvar("r_fullbright") >= 1)
573         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
574         {
575                 // apply night vision effect
576                 vector rgb, tc_00, tc_01, tc_10, tc_11;
577
578                 if(!nightvision_noise)
579                 {
580                         nightvision_noise = spawn();
581                         nightvision_noise.classname = "nightvision_noise";
582                 }
583                 if(!nightvision_noise2)
584                 {
585                         nightvision_noise2 = spawn();
586                         nightvision_noise2.classname = "nightvision_noise2";
587                 }
588
589                 // color tint in yellow
590                 drawfill('0 0 0', cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
591
592                 // draw BG
593                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
594                 rgb = '1 1 1';
595                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
596                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
597                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
598                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
599                 tc_11 = tc_01 + tc_10 - tc_00;
600                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
601                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
602                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
603                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
604                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
605                 R_EndPolygon();
606
607                 // draw FG
608                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
609                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
610                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
611                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
612                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
613                 tc_11 = tc_01 + tc_10 - tc_00;
614                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
615                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
616                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
617                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
618                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
619                 R_EndPolygon();
620         }
621
622         // Draw the aiming reticle for weapons that use it
623         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
624         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
625         // the view to go back to normal, so reticle_type would become 0 as we fade out)
626         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
627                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
628         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_CAMPINGRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
629                 reticle_type = 2; // nex zoom
630         else if(button_zoom || zoomscript_caught)
631                 reticle_type = 1; // normal zoom
632         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
633                 reticle_type = 2; // nex zoom
634
635         if(cvar("cl_reticle_stretch"))
636         {
637                 reticle_size_x = vid_conwidth;
638                 reticle_size_y = vid_conheight;
639                 reticle_pos_x = 0;
640                 reticle_pos_y = 0;
641         }
642         else
643         {
644                 reticle_size_x = max(vid_conwidth, vid_conheight);
645                 reticle_size_y = max(vid_conwidth, vid_conheight);
646                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
647                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
648         }
649
650         f = current_zoomfraction;
651         if(zoomscript_caught)
652                 f = 1;
653         if(cvar("cl_reticle_item_normal"))
654         {
655                 precache_pic("gfx/reticle_normal");
656                 if(reticle_type == 1 && f)
657                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
658         }
659         if(cvar("cl_reticle_item_nex"))
660         {
661                 precache_pic("gfx/reticle_nex");
662                 if(reticle_type == 2 && f)
663                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
664         }
665
666         // improved polyblend
667         if(cvar("hud_damage"))
668         {
669                 float myhealth_flash_temp;
670                 myhealth = getstati(STAT_HEALTH);
671
672                 // fade out
673                 myhealth_flash = max(0, myhealth_flash - cvar("hud_damage_fade_rate") * frametime);
674                 // add new damage
675                 myhealth_flash = bound(0, myhealth_flash + max(0, myhealth_prev - myhealth) * cvar("hud_damage_factor"), cvar("hud_damage_maxalpha"));
676
677                 float pain_treshold, pain_treshold_lower, pain_treshold_lower_health;
678                 pain_treshold = cvar("hud_damage_pain_treshold");
679                 pain_treshold_lower = cvar("hud_damage_pain_treshold_lower");
680                 pain_treshold_lower_health = cvar("hud_damage_pain_treshold_lower_health");
681
682                 if(pain_treshold_lower && myhealth < pain_treshold_lower_health)
683                 {
684                         pain_treshold = pain_treshold - max(cvar("hud_damage_pain_treshold_pulsating_min"), fabs(sin(M_PI * time / cvar("hud_damage_pain_treshold_pulsating_period")))) * pain_treshold_lower * (1 - max(0, myhealth)/pain_treshold_lower_health);
685                 }
686
687                 myhealth_flash_temp = bound(0, myhealth_flash - pain_treshold, 1);
688
689                 if(myhealth_prev < 1)
690                 {
691                         if(myhealth >= 1)
692                         {
693                                 myhealth_flash = 0; // just spawned, clear the flash immediately
694                                 myhealth_flash_temp = 0;
695                         }
696                         else
697                         {
698                                 myhealth_flash += cvar("hud_damage_fade_rate") * frametime; // dead
699                         }
700                 }
701
702                 if(spectatee_status == -1 || intermission)
703                 {
704                         myhealth_flash = 0; // observing, or match ended
705                         myhealth_flash_temp = 0;
706                 }
707
708                 myhealth_prev = myhealth;
709
710                 drawpic(reticle_pos, "gfx/blood", reticle_size, stov(cvar_string("hud_damage_color")), bound(0, myhealth_flash_temp, 1), DRAWFLAG_NORMAL);
711         }
712
713         // Draw the mouse cursor
714         // NOTE: drawpic must happen after R_RenderScene for some reason
715         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
716         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
717         //self = edict_num(player_localnum);
718         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
719         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
720         // as long as the ctf part isn't in, this is useless
721         if(menu_visible)
722                 menu_show();
723
724         /*if(gametype == GAME_CTF)
725           {
726           ctf_view();
727           } else */
728
729         // draw 2D entities
730         e = self;
731         for(self = world; (self = nextent(self)); )
732                 if(self.draw2d)
733                         self.draw2d();
734         self = e;
735
736         scoreboard_active = HUD_WouldDrawScoreboard();
737
738         float hud;
739         hud = getstati(STAT_HUD);
740         if(hud == HUD_SPIDERBOT)
741                 CSQC_SPIDER_HUD();
742         else if(hud == HUD_WAKIZASHI)
743         CSQC_WAKIZASHI_HUD();
744     else if(hud == HUD_RAPTOR)
745         CSQC_RAPTOR_HUD();
746         else
747         {
748                 if(cvar("r_letterbox") == 0)
749                         if(cvar("viewsize") < 120)
750                                 CSQC_common_hud();
751
752                 // crosshair goes VERY LAST
753                 if(!scoreboard_active && !camera_active && intermission != 2) {
754                         string wcross_style;
755                         float wcross_alpha, wcross_resolution;
756                         wcross_style = cvar_string("crosshair");
757                         if (wcross_style == "0")
758                                 return;
759                         wcross_resolution = cvar("crosshair_size");
760                         if (wcross_resolution == 0)
761                                 return;
762                         wcross_alpha = cvar("crosshair_alpha");
763                         if (wcross_alpha == 0)
764                                 return;
765
766                         // TrueAim check
767                         float shottype;
768                         float bullets, ring_scale;
769                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
770                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
771                         wcross_origin_z = 0;
772                         if(cvar("crosshair_hittest"))
773                         {
774                                 vector wcross_oldorigin;
775                                 wcross_oldorigin = wcross_origin;
776                                 shottype = TrueAimCheck();
777                                 if(shottype == SHOTTYPE_HITWORLD)
778                                 {
779                                         v = wcross_origin - wcross_oldorigin;
780                                         v_x /= vid_conwidth;
781                                         v_y /= vid_conheight;
782                                         if(vlen(v) > 0.01)
783                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
784                                 }
785                                 if(!cvar("crosshair_hittest_showimpact"))
786                                         wcross_origin = wcross_oldorigin;
787                         }
788                         else
789                                 shottype = SHOTTYPE_HITWORLD;
790
791                         vector wcross_color, wcross_size;
792                         string wcross_wep, wcross_name;
793                         float wcross_scale, wcross_blur;
794
795                         if (cvar("crosshair_per_weapon") || cvar("crosshair_color_per_weapon")) {
796                                 e = get_weaponinfo(activeweapon);
797                                 if (e && e.netname != "")
798                                 {
799                                         wcross_wep = e.netname;
800                                         if(cvar("crosshair_per_weapon"))
801                                         {
802                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
803                                                 if (wcross_resolution == 0)
804                                                         return;
805                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
806                                                 if (wcross_alpha == 0)
807                                                         return;
808
809                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
810                                                 if(wcross_style == "" || wcross_style == "0")
811                                                         wcross_style = wcross_wep;
812                                         }
813                                 }
814                         }
815                         if(wcross_wep != "" && cvar("crosshair_color_per_weapon"))
816                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
817                         else
818                                 wcross_color = stov(cvar_string("crosshair_color"));
819
820                         wcross_name = strcat("gfx/crosshair", wcross_style);
821
822                         if(cvar("crosshair_effect_scalefade"))
823                         {
824                                 wcross_scale = wcross_resolution;
825                                 wcross_resolution = 1;
826                         }
827                         else
828                         {
829                                 wcross_scale = 1;
830                         }
831
832                         if(cvar("crosshair_pickup"))
833                         {
834                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
835                                 {
836                                         pickup_crosshair_size = 1;
837                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
838                                 }
839
840                                 if(pickup_crosshair_size > 0)
841                                         pickup_crosshair_size -= cvar("crosshair_pickup_speed") * frametime;
842                                 else
843                                         pickup_crosshair_size = 0;
844
845                                 wcross_scale += sin(pickup_crosshair_size) * cvar("crosshair_pickup");
846                         }
847
848                         if(shottype == SHOTTYPE_HITENEMY)
849                                 wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
850                         if(shottype == SHOTTYPE_HITTEAM)
851                                 wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
852
853                         f = cvar("crosshair_effect_speed");
854                         if(f < 0)
855                                 f *= -2 * g_weaponswitchdelay;
856                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
857                         {
858                                 wcross_changedonetime = time + f;
859                         }
860                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
861                         {
862                                 wcross_name_changestarttime = time;
863                                 wcross_name_changedonetime = time + f;
864                                 if(wcross_name_goal_prev_prev)
865                                         strunzone(wcross_name_goal_prev_prev);
866                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
867                                 wcross_name_goal_prev = strzone(wcross_name);
868                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
869                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
870                                 wcross_resolution_goal_prev = wcross_resolution;
871                         }
872
873                         wcross_scale_goal_prev = wcross_scale;
874                         wcross_alpha_goal_prev = wcross_alpha;
875                         wcross_color_goal_prev = wcross_color;
876
877                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
878                         {
879                                 wcross_blur = 1;
880                                 wcross_alpha *= 0.75;
881                         }
882                         else
883                                 wcross_blur = 0;
884                         // *_prev is at time-frametime
885                         // * is at wcross_changedonetime+f
886                         // what do we have at time?
887                         if(time < wcross_changedonetime)
888                         {
889                                 f = frametime / (wcross_changedonetime - time + frametime);
890                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
891                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
892                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
893                         }
894
895                         wcross_scale_prev = wcross_scale;
896                         wcross_alpha_prev = wcross_alpha;
897                         wcross_color_prev = wcross_color;
898
899                         wcross_scale *= 1 - cvar("_menu_alpha");
900                         wcross_alpha *= 1 - cvar("_menu_alpha");
901
902                         ring_scale = cvar("crosshair_ring_size");
903
904                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
905
906                         float nex_charge;
907                         nex_charge = getstatf(STAT_NEX_CHARGE);
908
909                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
910                                 nex_charge_movingavg = nex_charge;
911
912                         // ring around crosshair representing bullets left in camping rifle clip
913                         if (activeweapon == WEP_CAMPINGRIFLE && cr_maxbullets)
914                         {
915                                 bullets = getstati(STAT_BULLETS_LOADED);
916                                 f = bound(0, bullets / cr_maxbullets, 1);
917
918                                 a = cvar("crosshair_campingrifle_bulletcounter_alpha");
919                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
920                         }
921                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
922                         {
923                                 vector rgb;
924                                 // indicate how much we're charging right now with an inner circle
925                                 a = cvar("crosshair_nexvelocity_currentcharge_alpha");
926                                 nex_charge_movingavg = (1 - cvar("crosshair_nexvelocity_currentcharge_movingavg_rate")) * nex_charge_movingavg + cvar("crosshair_nexvelocity_currentcharge_movingavg_rate") * nex_charge;
927
928                                 rgb = eX * cvar("crosshair_nexvelocity_currentcharge_color_red") + eY * cvar("crosshair_nexvelocity_currentcharge_color_green") + eZ * cvar("crosshair_nexvelocity_currentcharge_color_blue");
929                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, cvar("crosshair_nexvelocity_currentcharge_scale") * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
930
931                                 // draw the charge
932                                 a = cvar("crosshair_nexvelocity_alpha");
933                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
934                         }
935
936 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
937                         do \
938                         { \
939                                 if(wcross_blur > 0) \
940                                 { \
941                                         for(i = -2; i <= 2; ++i) \
942                                                 for(j = -2; j <= 2; ++j) \
943                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
944                                 } \
945                                 else \
946                                 { \
947                                         M(0,0,sz,wcross_name,wcross_alpha); \
948                                 } \
949                         } \
950                         while(0)
951
952 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
953                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
954
955 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
956                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
957
958                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
959                         {
960                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
961                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
962                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
963                                 f = 1 - f;
964                         }
965                         else
966                         {
967                                 f = 1;
968                         }
969
970                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
971                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
972
973                         if(cvar("crosshair_dot"))
974                                 CROSSHAIR_DRAW(wcross_resolution * cvar("crosshair_dot_size"), "gfx/crosshairdot.tga", wcross_alpha * f * cvar("crosshair_dot_alpha"));
975
976                         wcross_name_alpha_goal_prev = f;
977                 }
978                 else
979                 {
980                         wcross_scale_prev = 0;
981                         wcross_alpha_prev = 0;
982                         wcross_scale_goal_prev = 0;
983                         wcross_alpha_goal_prev = 0;
984                         wcross_changedonetime = 0;
985                         if(wcross_name_goal_prev)
986                                 strunzone(wcross_name_goal_prev);
987                         wcross_name_goal_prev = string_null;
988                         if(wcross_name_goal_prev_prev)
989                                 strunzone(wcross_name_goal_prev_prev);
990                         wcross_name_goal_prev_prev = string_null;
991                         wcross_name_changestarttime = 0;
992                         wcross_name_changedonetime = 0;
993                         wcross_name_alpha_goal_prev = 0;
994                         wcross_name_alpha_goal_prev_prev = 0;
995                         wcross_resolution_goal_prev = 0;
996                         wcross_resolution_goal_prev_prev = 0;
997                 }
998         }
999
1000         if(NextFrameCommand)
1001         {
1002                 localcmd("\n", NextFrameCommand, "\n");
1003                 NextFrameCommand = string_null;
1004         }
1005
1006         // we must do this check AFTER a frame was rendered, or it won't work
1007         if(cs_project_is_b0rked == 0)
1008         {
1009                 string w0, h0;
1010                 w0 = cvar_string("vid_conwidth");
1011                 h0 = cvar_string("vid_conheight");
1012                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1013                 //R_SetView(VF_FOV, '90 90 0');
1014                 R_SetView(VF_ORIGIN, '0 0 0');
1015                 R_SetView(VF_ANGLES, '0 0 0');
1016                 R_SetView(VF_PERSPECTIVE, 1);
1017                 makevectors('0 0 0');
1018                 vector v1, v2;
1019                 cvar_set("vid_conwidth", "800");
1020                 cvar_set("vid_conheight", "600");
1021                 v1 = cs_project(v_forward);
1022                 cvar_set("vid_conwidth", "640");
1023                 cvar_set("vid_conheight", "480");
1024                 v2 = cs_project(v_forward);
1025                 if(v1 == v2)
1026                         cs_project_is_b0rked = 1;
1027                 else
1028                         cs_project_is_b0rked = -1;
1029                 cvar_set("vid_conwidth", w0);
1030                 cvar_set("vid_conheight", h0);
1031         }
1032
1033         if(autocvar__hud_configure)
1034                 HUD_Panel_Mouse();
1035
1036         // let's reset the view back to normal for the end
1037         R_SetView(VF_MIN, '0 0 0');
1038         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1039 }
1040
1041 #define spider_h "gfx/vehicles/hud_bg.tga"
1042 #define spider_b "gfx/vehicles/sbot.tga"
1043 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1044 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1045 #define spider_s "gfx/vehicles/shiled.tga"
1046 #define spider_a1 "gfx/hud/sb_rocket.tga"
1047 #define spider_a2 "gfx/sb_bullets.tga"
1048
1049 void CSQC_SPIDER_HUD()
1050 {
1051         float rockets, reload, heat, hp, shield;
1052         vector picsize, hudloc;
1053
1054     // Fetch health & ammo stats
1055     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1056         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1057         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1058         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1059         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1060
1061     // Draw the crosshairs
1062     picsize = drawgetimagesize(SPIDER_CROSS);
1063     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1064     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1065     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1066
1067     hudloc_y =  4;
1068     hudloc_x = 4;
1069
1070     picsize = drawgetimagesize(spider_h) * 0.5;
1071     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1072
1073     picsize = drawgetimagesize(spider_a2) * 0.5;
1074     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1075
1076     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1077     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1078     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1079
1080     picsize = drawgetimagesize(spider_a1) * 0.85;
1081     if(rockets == 9)
1082     {
1083         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1084         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1085     }
1086     else
1087     {
1088         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1089         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1090     }
1091
1092     picsize = drawgetimagesize(spider_b) * 0.5;
1093     hudloc_y = 10.5;
1094     hudloc_x = 10.5;
1095
1096     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1097     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1098     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1099     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1100
1101
1102         /*
1103         // Draw health bar
1104         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1105         p = p + '0 1 0' * vid_conheight - '0 32 0';
1106         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1107         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1108         p_y += 8;
1109         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1110         p_x += 256 * hp;
1111         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1112
1113         // Draw minigun heat indicator
1114         p = '0.5 0 0' * (vid_conwidth - 256);
1115         p = p + '0 1 0' * vid_conheight - '0 34  0';
1116         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1117         p_x += 256 * (1-heat);
1118         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1119
1120
1121         // Draw rocket icons for loaded/empty tubes.
1122         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1123         pp += '0 1 0' * vid_conheight - '0 64 0';
1124         for(i = 0; i < 8; ++i)
1125         {
1126                 p = pp + '1 0 0' * (rkt_size * i);
1127                 if(rockets == 8)
1128                 {
1129                         if(floor(reload * 8) == i)
1130                         {
1131                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1132                         }
1133                         else if(i < reload * 8)
1134                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1135                         else
1136                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1137                 }
1138                 else
1139                 {
1140                         if(i < rockets)
1141                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1142                         else
1143                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1144                 }
1145         }
1146         */
1147
1148         if (scoreboard_showscores)
1149         {
1150                 HUD_DrawScoreboard();
1151                 HUD_DrawCenterPrint();
1152         }
1153
1154 }
1155
1156 #define raptor_h "gfx/vehicles/hud_bg.tga"
1157 #define raptor_b "gfx/vehicles/raptor.tga"
1158 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1159 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1160 #define raptor_s "gfx/vehicles/shiled.tga"
1161
1162 void CSQC_RAPTOR_HUD()
1163 {
1164         float reload, hp, shield, energy;
1165         vector picsize, hudloc;
1166
1167     // Fetch health & ammo stats
1168     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1169         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1170         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1171         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1172
1173     // Draw the crosshairs
1174     picsize = drawgetimagesize(SPIDER_CROSS);
1175     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1176     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1177     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1178
1179     hudloc_y =  4;
1180     hudloc_x = 4;
1181
1182     picsize = drawgetimagesize(raptor_h) * 0.5;
1183     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1184
1185     picsize = drawgetimagesize(spider_a2) * 0.5;
1186     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1187
1188     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1189     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1190     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1191
1192
1193     picsize = drawgetimagesize(spider_a1) * 0.85;
1194     if(reload == 1)
1195     {
1196         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1197         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1198     }
1199     else
1200     {
1201         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1202         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1203     }
1204
1205     picsize = drawgetimagesize(raptor_b) * 0.5;
1206     hudloc_y = 10.5;
1207     hudloc_x = 10.5;
1208
1209     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1210     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1211     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1212     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1213
1214
1215         if (scoreboard_showscores)
1216         {
1217                 HUD_DrawScoreboard();
1218                 HUD_DrawCenterPrint();
1219         }
1220
1221 }
1222
1223 #define waki_h "gfx/vehicles/hud_bg.tga"
1224 #define waki_b "gfx/vehicles/waki.tga"
1225 #define waki_e "gfx/vehicles/waki_e.tga"
1226 #define waki_g "gfx/vehicles/waki_guns.tga"
1227 #define waki_r "gfx/vehicles/waki_rockets.tga"
1228 #define waki_s "gfx/vehicles/shiled.tga"
1229
1230 #define waki_a1 "gfx/hud/sb_rocket.tga"
1231 #define waki_a2 "gfx/sb_cells.tga"
1232
1233 void CSQC_WAKIZASHI_HUD()
1234 {
1235         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1236         float health, shield, energy, rockets;
1237         vector picsize, hudloc;
1238
1239     picsize = drawgetimagesize(SPIDER_CROSS);
1240     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1241     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1242     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1243
1244 /*
1245 const float STAT_VEHICLESTAT_HEALTH  = 60;
1246 const float STAT_VEHICLESTAT_SHIELD  = 61;
1247 const float STAT_VEHICLESTAT_ENERGY  = 62;
1248 const float STAT_VEHICLESTAT_AMMO1   = 63;
1249 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1250 const float STAT_VEHICLESTAT_AMMO2   = 65;
1251 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1252 */
1253     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1254         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1255         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1256         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1257
1258     hudloc_y =  4;
1259     hudloc_x = 4;
1260
1261     picsize = drawgetimagesize(waki_h) * 0.5;
1262     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1263
1264     picsize = drawgetimagesize(waki_a2) * 0.7;
1265     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1266
1267
1268     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1269     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1270
1271     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1272
1273     picsize = drawgetimagesize(waki_a1) * 0.75;
1274     if(rockets == 1)
1275     {
1276         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1277         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1278     }
1279     else
1280     {
1281         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1282         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1283         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1284     }
1285
1286     picsize = drawgetimagesize(waki_b) * 0.5;
1287     hudloc_y = 10.5;
1288     hudloc_x = 10.5;
1289
1290     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1291     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1292     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1293     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1294
1295
1296
1297         /*
1298         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1299         p = p + '0 1 0' * vid_conheight - '0 32 0';
1300
1301         // Draw health bar
1302         p_y += 8;
1303         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1304         p_x += 256 * health;
1305         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1306
1307         // Draw shiled bar
1308         p_x -= 256 * health;
1309         p_y += 4;
1310         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1311
1312         // Draw energy
1313         //p_x -= 256 * health;
1314         p_y -= 8;
1315         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1316
1317         // Draw rockets bar
1318         p_y += 12;
1319         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1320         */
1321
1322
1323
1324
1325         if (scoreboard_showscores)
1326         {
1327                 HUD_DrawScoreboard();
1328                 HUD_DrawCenterPrint();
1329         }
1330
1331 }
1332
1333
1334 void CSQC_common_hud(void)
1335 {
1336         // HUD_SortFrags(); done in HUD_Draw
1337         float hud;
1338         hud = getstati(STAT_HUD);
1339
1340         //hud = 10;
1341         switch(hud)
1342         {
1343                 case HUD_NORMAL:
1344                         // do some accuracy var caching
1345                         float i;
1346                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1347                         {
1348                                 if(cvar_string("accuracy_color_levels") != acc_color_levels)
1349                                 {
1350                                         if(acc_color_levels)
1351                                                 strunzone(acc_color_levels);
1352                                         acc_color_levels = strzone(cvar_string("accuracy_color_levels"));
1353                                         acc_levels = tokenize(acc_color_levels);
1354                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1355                                                 acc_levels = MAX_ACCURACY_LEVELS;
1356
1357                                         for (i = 0; i < acc_levels; ++i)
1358                                                 acc_lev[i] = stof(argv(i));
1359                                 }
1360                                 // let know that acc_col[] needs to be loaded
1361                                 acc_col_x[0] = -1;
1362                         }
1363
1364                         HUD_Main(); // always run these functions for alpha checks
1365                         HUD_DrawScoreboard();
1366
1367                         if (scoreboard_active) // scoreboard/accuracy
1368                         {       
1369                                 HUD_Reset();
1370                                 // HUD_DrawScoreboard takes care of centerprint_start
1371                         }
1372                         else if (intermission == 2) // map voting screen
1373                         {
1374                                 HUD_FinaleOverlay();
1375                                 HUD_Reset();
1376
1377                                 centerprint_start_x = 0;
1378                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1379                         }
1380                         else // hud
1381                         {
1382                                 centerprint_start_x = 0;
1383                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1384                         }
1385
1386                         HUD_DrawCenterPrint();
1387                         break;
1388
1389                 case HUD_SPIDERBOT:
1390                         CSQC_SPIDER_HUD();
1391                         break;
1392
1393                 case HUD_WAKIZASHI:
1394                         CSQC_WAKIZASHI_HUD();
1395                         break;
1396         }
1397 }
1398
1399
1400 // following vectors must be global to allow seamless switching between camera modes
1401 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1402 void CSQC_Demo_Camera()
1403 {
1404         float speed, attenuation, dimensions;
1405         vector tmp, delta;
1406
1407         if( cvar("camera_reset") || !camera_mode )
1408         {
1409                 camera_offset = '0 0 0';
1410                 current_angles = '0 0 0';
1411                 camera_direction = '0 0 0';
1412                 camera_offset_z += 30;
1413                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1414                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1415                 current_origin = view_origin;
1416                 current_camera_offset  = camera_offset;
1417                 cvar_set("camera_reset", "0");
1418                 camera_mode = CAMERA_CHASE;
1419         }
1420
1421         // Camera angles
1422         if( camera_roll )
1423                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1424
1425         if(cvar("camera_look_player"))
1426         {
1427                 local vector dir;
1428                 local float n;
1429
1430                 dir = normalize(view_origin - current_position);
1431                 n = mouse_angles_z;
1432                 mouse_angles = vectoangles(dir);
1433                 mouse_angles_x = mouse_angles_x * -1;
1434                 mouse_angles_z = n;
1435         }
1436         else
1437         {
1438                 tmp = getmousepos() * 0.1;
1439                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1440                 {
1441                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1442                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1443                 }
1444         }
1445
1446         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1447         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1448         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1449         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1450
1451         // Fix difference when angles don't have the same sign
1452         delta = '0 0 0';
1453         if(mouse_angles_y < -60 && current_angles_y > 60)
1454                 delta = '0 360 0';
1455         if(mouse_angles_y > 60 && current_angles_y < -60)
1456                 delta = '0 -360 0';
1457
1458         if(cvar("camera_look_player"))
1459                 attenuation = cvar("camera_look_attenuation");
1460         else
1461                 attenuation = cvar("camera_speed_attenuation");
1462
1463         attenuation = 1 / max(1, attenuation);
1464         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1465
1466         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1467         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1468         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1469         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1470
1471         // Camera position
1472         tmp = '0 0 0';
1473         dimensions = 0;
1474
1475         if( camera_direction_x )
1476         {
1477                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1478                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1479                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1480                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1481                 ++dimensions;
1482         }
1483
1484         if( camera_direction_y )
1485         {
1486                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1487                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1488                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1489                 ++dimensions;
1490         }
1491
1492         if( camera_direction_z )
1493         {
1494                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1495                 ++dimensions;
1496         }
1497
1498         if(cvar("camera_free"))
1499                 speed = cvar("camera_speed_free");
1500         else
1501                 speed = cvar("camera_speed_chase");
1502
1503         if(dimensions)
1504         {
1505                 speed = speed * sqrt(1 / dimensions);
1506                 camera_offset += tmp * speed;
1507         }
1508
1509         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1510
1511         // Camera modes
1512         if( cvar("camera_free") )
1513         {
1514                 if ( camera_mode == CAMERA_CHASE )
1515                 {
1516                         current_camera_offset = current_origin + current_camera_offset;
1517                         camera_offset = current_origin + camera_offset;
1518                 }
1519
1520                 camera_mode = CAMERA_FREE;
1521                 current_position = current_camera_offset;
1522         }
1523         else
1524         {
1525                 if ( camera_mode == CAMERA_FREE )
1526                 {
1527                         current_origin = view_origin;
1528                         camera_offset = camera_offset - current_origin;
1529                         current_camera_offset = current_camera_offset - current_origin;
1530                 }
1531
1532                 camera_mode = CAMERA_CHASE;
1533
1534                 if(cvar("camera_chase_smoothly"))
1535                         current_origin += (view_origin - current_origin) * attenuation;
1536                 else
1537                         current_origin = view_origin;
1538
1539                 current_position = current_origin + current_camera_offset;
1540         }
1541
1542         R_SetView(VF_ANGLES, current_angles);
1543         R_SetView(VF_ORIGIN, current_position);
1544 }