Merge branch 'terencehill/crosshair_colors' into fruitiex/panelhud
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / View.qc
1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
2 #define spider_rocket_targ "gfx/vehicles/target.tga"
3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
4 #define rkt_size 32
5 #define rld_size_x 256
6 #define rld_size_y 16
7
8 void CSQC_WAKIZASHI_HUD();
9
10 entity porto;
11 vector polyline[16];
12 float trace_dphitcontents;
13 float trace_networkentity;
14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
15 float DPCONTENTS_SOLID = 1; // blocks player movement
16 float DPCONTENTS_BODY = 32; // blocks player movement
17 float DPCONTENTS_CORPSE = 64; // blocks player movement
18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
19 void Porto_Draw()
20 {
21         vector p, dir, ang, q, nextdir;
22         float idx, portal_number, portal1_idx;
23
24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
25                 return;
26         if(intermission == 1)
27                 return;
28         if(intermission == 2)
29                 return;
30         if (getstati(STAT_HEALTH) <= 0)
31                 return;
32
33         dir = view_forward;
34
35         if(angles_held_status)
36         {
37                 makevectors(angles_held);
38                 dir = v_forward;
39         }
40
41         p = view_origin;
42
43         polyline[0] = p;
44         idx = 1;
45         portal_number = 0;
46         nextdir = dir;
47
48         for(;;)
49         {
50                 dir = nextdir;
51                 traceline(p, p + 65536 * dir, TRUE, porto);
52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
53                         return;
54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
55                 p = trace_endpos;
56                 polyline[idx] = p;
57                 ++idx;
58                 if(idx >= 16)
59                         return;
60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
61                         continue;
62                 ++portal_number;
63                 ang = vectoangles2(trace_plane_normal, dir);
64                 ang_x = -ang_x;
65                 makevectors(ang);
66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
67                         return;
68                 if(portal_number == 1)
69                         portal1_idx = idx;
70                 if(portal_number >= 2)
71                         break;
72         }
73
74         while(idx >= 2)
75         {
76                 p = polyline[idx-2];
77                 q = polyline[idx-1];
78                 if(idx == 2)
79                         p = p - view_up * 16;
80                 if(idx-1 >= portal1_idx)
81                 {
82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
83                 }
84                 else
85                 {
86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
87                 }
88                 --idx;
89         }
90 }
91
92 /**
93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
94  *
95  * TODO: Use a better solution where a common shared entitiy is used that contains
96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
97  * and STAT_FRAGLIMIT to be auto-sent)
98  */
99 void CheckForGamestartChange() {
100         float startTime;
101         startTime = getstatf(STAT_GAMESTARTTIME);
102         if (previous_game_starttime != startTime) {
103                 if ((time + 5.0) < startTime) {
104                         //if connecting to server while restart was active don't always play prepareforbattle
105                         sound(world, CHAN_AUTO, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
106                 }
107                 if (time < startTime) {
108                         restartAnnouncer = spawn();
109                         restartAnnouncer.think = restartAnnouncer_Think;
110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
111                 }
112         }
113         previous_game_starttime = startTime;
114 }
115
116 void Porto_Init()
117 {
118         porto = spawn();
119         porto.classname = "porto";
120         porto.draw = Porto_Draw;
121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
122 }
123
124 float drawtime;
125 float avgspeed;
126 vector GetCurrentFov(float fov)
127 {
128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
129
130         zoomsensitivity = cvar("cl_zoomsensitivity");
131         zoomfactor = cvar("cl_zoomfactor");
132         if(zoomfactor < 1 || zoomfactor > 16)
133                 zoomfactor = 2.5;
134         zoomspeed = cvar("cl_zoomspeed");
135         if(zoomspeed >= 0)
136                 if(zoomspeed < 0.5 || zoomspeed > 16)
137                         zoomspeed = 3.5;
138
139         zoomdir = button_zoom;
140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
141                 zoomdir += button_attack2;
142         if(spectatee_status > 0 || isdemo())
143         {
144                 if(spectatorbutton_zoom)
145                         zoomdir = 0 + !zoomdir;
146                 // do not even THINK about removing this 0
147                 // _I_ know what I am doing
148                 // fteqcc does not
149         }
150
151         if(zoomdir)
152                 zoomin_effect = 0;
153
154         if(zoomin_effect || camera_active)
155         {
156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
157         }
158         else
159         {
160                 if(zoomspeed < 0) // instant zoom
161                 {
162                         if(zoomdir)
163                                 current_viewzoom = 1 / zoomfactor;
164                         else
165                                 current_viewzoom = 1;
166                 }
167                 else
168                 {
169                         if(zoomdir)
170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
171                         else
172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
173                 }
174         }
175
176         if(almost_equals(current_viewzoom, 1))
177                 current_zoomfraction = 0;
178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
179                 current_zoomfraction = 1;
180         else
181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
182
183         if(zoomsensitivity < 1)
184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
185         else
186                 setsensitivityscale(1);
187
188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
191
192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
193
194         float frustumx, frustumy, fovx, fovy;
195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
199
200         return '1 0 0' * fovx + '0 1 0' * fovy;
201 }
202
203 // this function must match W_SetupShot!
204 float zoomscript_caught;
205
206 vector wcross_origin;
207 float wcross_scale_prev, wcross_alpha_prev;
208 vector wcross_color_prev;
209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
210 vector wcross_color_goal_prev;
211 float wcross_changedonetime;
212
213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
215 float wcross_name_changestarttime, wcross_name_changedonetime;
216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
217 entity trueaim;
218 entity trueaim_rifle;
219
220 #define SHOTTYPE_HITTEAM 1
221 #define SHOTTYPE_HITOBSTRUCTION 2
222 #define SHOTTYPE_HITWORLD 3
223 #define SHOTTYPE_HITENEMY 4
224
225 void TrueAim_Init()
226 {
227         trueaim = spawn();
228         trueaim.classname = "trueaim";
229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
230         trueaim_rifle = spawn();
231         trueaim_rifle.classname = "trueaim_rifle";
232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
233 }
234
235 float EnemyHitCheck()
236 {
237         float t;
238         wcross_origin = project_3d_to_2d(trace_endpos);
239         wcross_origin_z = 0;
240         if(trace_networkentity < 1)
241                 return SHOTTYPE_HITWORLD;
242         if(trace_networkentity > maxclients)
243                 return SHOTTYPE_HITWORLD;
244         t = GetPlayerColor(trace_networkentity - 1);
245         if(teamplay)
246                 if(t == myteam)
247                         return SHOTTYPE_HITTEAM;
248         if(t == COLOR_SPECTATOR)
249                 return SHOTTYPE_HITWORLD;
250         return SHOTTYPE_HITENEMY;
251 }
252
253 float TrueAimCheck()
254 {
255         float nudge = 1; // added to traceline target and subtracted from result
256         vector vecs, trueaimpoint, w_shotorg;
257         vector mi, ma, dv;
258         float shottype;
259         entity ta;
260         float mv;
261
262         mi = ma = '0 0 0';
263         ta = trueaim;
264         mv = MOVE_NOMONSTERS;
265
266         switch(activeweapon)
267         {
268                 case WEP_TUBA: // no aim
269                 case WEP_PORTO: // shoots from eye
270                 case WEP_HOOK: // no trueaim
271                 case WEP_GRENADE_LAUNCHER: // toss curve
272                         return SHOTTYPE_HITWORLD;
273                 case WEP_NEX:
274                 case WEP_MINSTANEX:
275                         mv = MOVE_NORMAL;
276                         break;
277                 case WEP_CAMPINGRIFLE:
278                         ta = trueaim_rifle;
279                         mv = MOVE_NORMAL;
280                         if(zoomscript_caught)
281                         {
282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
283                                 return EnemyHitCheck();
284                         }
285                         break;
286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
287                         mi = '-3 -3 -3';
288                         ma = '3 3 3';
289                         break;
290                 case WEP_FIREBALL: // projectile has a size!
291                         mi = '-16 -16 -16';
292                         ma = '16 16 16';
293                         break;
294                 case WEP_SEEKER: // projectile has a size!
295                         mi = '-2 -2 -2';
296                         ma = '2 2 2';
297                         break;
298                 case WEP_ELECTRO: // projectile has a size!
299                         mi = '0 0 -3';
300                         ma = '0 0 -3';
301                         break;
302         }
303
304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
305
306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
307         trueaimpoint = trace_endpos;
308
309         if(vecs_x > 0)
310                 vecs_y = -vecs_y;
311         else
312                 vecs = '0 0 0';
313
314         dv = view_right * vecs_y + view_up * vecs_z;
315         w_shotorg = view_origin + dv;
316
317         // now move the vecs forward as much as requested if possible
318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
319         w_shotorg = trace_endpos - view_forward * nudge;
320
321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
322         shottype = EnemyHitCheck();
323         if(shottype != SHOTTYPE_HITWORLD)
324                 return shottype;
325
326 #if 0
327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
328         // or rather, I know why, but see no fix
329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
331                 return SHOTTYPE_HITOBSTRUCTION;
332 #endif
333
334         return SHOTTYPE_HITWORLD;
335 }
336
337 void CSQC_common_hud(void);
338
339 void PostInit(void);
340 void CSQC_Demo_Camera();
341 float HUD_WouldDrawScoreboard();
342 float view_set;
343 float camera_mode;
344 float reticle_type;
345 string NextFrameCommand;
346 void CSQC_SPIDER_HUD();
347 void CSQC_RAPTOR_HUD();
348
349 vector freeze_pmove_org, freeze_input_angles;
350 entity nightvision_noise, nightvision_noise2;
351
352 float pickup_crosshair_time, pickup_crosshair_size;
353
354 void CSQC_UpdateView(float w, float h)
355 {
356         entity e;
357         float fov;
358         float f, i, j;
359         vector v, vo;
360         vector vf_size, vf_min;
361         float a;
362
363         vf_size = R_SetView3fv(VF_SIZE);
364         vf_min = R_SetView3fv(VF_MIN);
365         vid_width = vf_size_x;
366         vid_height = vf_size_y;
367
368         vector reticle_pos, reticle_size;
369
370         WaypointSprite_Load();
371
372         if(spectatee_status)
373                 myteam = GetPlayerColor(spectatee_status - 1);
374         else
375                 myteam = GetPlayerColor(player_localentnum - 1);
376
377         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
378         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
379
380         warpzone_fixview_origin = pmove_org + vo;
381         warpzone_fixview_cl_viewangles = input_angles;
382         warpzone_fixview_angles = view_angles;
383         WarpZone_FixView();
384         pmove_org = warpzone_fixview_origin - vo;
385         input_angles = warpzone_fixview_cl_viewangles;
386         view_angles = warpzone_fixview_angles;
387
388         if(cvar("cl_lockview") || (autocvar__hud_configure && spectatee_status <= 0))
389         {
390                 pmove_org = freeze_pmove_org;
391                 input_angles = view_angles = freeze_input_angles;
392                 R_SetView(VF_ORIGIN, pmove_org + vo);
393                 R_SetView(VF_ANGLES, view_angles);
394                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
395         }
396         freeze_pmove_org = pmove_org;
397         freeze_input_angles = input_angles;
398
399         // Render the Scene
400         if(!intermission || !view_set)
401         {
402                 view_origin = pmove_org + vo;
403                 view_angles = input_angles;
404                 makevectors(view_angles);
405                 view_forward = v_forward;
406                 view_right = v_right;
407                 view_up = v_up;
408                 view_set = 1;
409         }
410
411 #ifdef BLURTEST
412         if(time > blurtest_time0 && time < blurtest_time1)
413         {
414                 float r, t;
415
416                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
417                 r = t * blurtest_radius;
418                 f = 1 / pow(t, blurtest_power) - 1;
419
420                 cvar_set("r_glsl_postprocess", "1");
421                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
422         }
423         else
424         {
425                 cvar_set("r_glsl_postprocess", "0");
426                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
427         }
428 #endif
429
430         TargetMusic_Advance();
431         Fog_Force();
432
433         drawframetime = max(0.000001, time - drawtime);
434         drawtime = time;
435
436         // watch for gametype changes here...
437         // in ParseStuffCMD the cmd isn't executed yet :/
438         // might even be better to add the gametype to TE_CSQC_INIT...?
439         if(!postinit)
440                 PostInit();
441
442         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
443                 if(calledhooks & HOOK_START)
444                 {
445                         localcmd("\ncl_hook_gameend\n");
446                         calledhooks |= HOOK_END;
447                 }
448
449         CheckForGamestartChange();
450         serverAnnouncer();
451         maptimeAnnouncer();
452         carrierAnnouncer();
453
454         fov = cvar("fov");
455         if(button_zoom || fov <= 59.5)
456         {
457                 if(!zoomscript_caught)
458                 {
459                         localcmd("+button4\n");
460                         zoomscript_caught = 1;
461                         ignore_plus_zoom += 1;
462                 }
463         }
464         else
465         {
466                 if(zoomscript_caught)
467                 {
468                         localcmd("-button4\n");
469                         zoomscript_caught = 0;
470                         ignore_minus_zoom += 1;
471                 }
472         }
473
474         ColorTranslateMode = cvar("cl_stripcolorcodes");
475         activeweapon = getstati(STAT_SWITCHWEAPON);
476         f = cvar("teamplay");
477         if(f != teamplay)
478         {
479                 teamplay = f;
480                 HUD_InitScores();
481         }
482
483         if(last_weapon != activeweapon) {
484                 weapontime = time;
485                 last_weapon = activeweapon;
486
487                 e = get_weaponinfo(activeweapon);
488                 if(e.netname != "")
489                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
490                 else
491                         localcmd("\ncl_hook_activeweapon none\n");
492         }
493
494         // ALWAYS Clear Current Scene First
495         R_ClearScene();
496
497         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
498         R_SetView(VF_SIZE, vf_size);
499         R_SetView(VF_MIN, vf_min);
500
501         // Assign Standard Viewflags
502         // Draw the World (and sky)
503         R_SetView(VF_DRAWWORLD, 1);
504
505         // Set the console size vars
506         vid_conwidth = cvar("vid_conwidth");
507         vid_conheight = cvar("vid_conheight");
508         vid_pixelheight = cvar("vid_pixelheight");
509
510         R_SetView(VF_FOV, GetCurrentFov(fov));
511
512         // Camera for demo playback
513         if(camera_active)
514         {
515                 if(cvar("camera_enable"))
516                         CSQC_Demo_Camera();
517                 else
518                 {
519                         cvar_set("chase_active", ftos(chase_active_backup));
520                         cvar_set("cl_demo_mousegrab", "0");
521                         camera_active = FALSE;
522                 }
523         }
524 #ifdef CAMERATEST
525         else if(cvar("camera_enable"))
526 #else
527         else if(cvar("camera_enable") && isdemo())
528 #endif
529         {
530                 // Enable required Darkplaces cvars
531                 chase_active_backup = cvar("chase_active");
532                 cvar_set("chase_active", "2");
533                 cvar_set("cl_demo_mousegrab", "1");
534                 camera_active = TRUE;
535                 camera_mode = FALSE;
536         }
537
538         // Draw the Crosshair
539         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
540
541         // Draw the Engine Status Bar (the default Quake HUD)
542         R_SetView(VF_DRAWENGINEHUD, 0);
543
544         // fetch this one only once per frame
545         hud_showbinds = cvar("hud_showbinds");
546         hud_showbinds_limit = cvar("hud_showbinds_limit");
547
548         // Update the mouse position
549         /*
550            mousepos_x = vid_conwidth;
551            mousepos_y = vid_conheight;
552            mousepos = mousepos*0.5 + getmousepos();
553          */
554
555         e = self;
556         for(self = world; (self = nextent(self)); )
557                 if(self.draw)
558                         self.draw();
559         self = e;
560
561         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
562         R_RenderScene();
563
564         // now switch to 2D drawing mode by calling a 2D drawing function
565         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
566         // next R_RenderScene call
567         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
568
569         if(cvar("r_fakelight") >= 2 || cvar("r_fullbright") >= 1)
570         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
571         {
572                 // apply night vision effect
573                 vector rgb, tc_00, tc_01, tc_10, tc_11;
574
575                 if(!nightvision_noise)
576                 {
577                         nightvision_noise = spawn();
578                         nightvision_noise.classname = "nightvision_noise";
579                 }
580                 if(!nightvision_noise2)
581                 {
582                         nightvision_noise2 = spawn();
583                         nightvision_noise2.classname = "nightvision_noise2";
584                 }
585
586                 // color tint in yellow
587                 drawfill('0 0 0', cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
588
589                 // draw BG
590                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
591                 rgb = '1 1 1';
592                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
593                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
594                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
595                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
596                 tc_11 = tc_01 + tc_10 - tc_00;
597                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
598                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
599                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
600                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
601                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
602                 R_EndPolygon();
603
604                 // draw FG
605                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
606                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
607                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
608                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
609                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
610                 tc_11 = tc_01 + tc_10 - tc_00;
611                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
612                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
613                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
614                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
615                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
616                 R_EndPolygon();
617         }
618
619         // Draw the aiming reticle for weapons that use it
620         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
621         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
622         // the view to go back to normal, so reticle_type would become 0 as we fade out)
623         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
624                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
625         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_CAMPINGRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
626                 reticle_type = 2; // nex zoom
627         else if(button_zoom || zoomscript_caught)
628                 reticle_type = 1; // normal zoom
629         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
630                 reticle_type = 2; // nex zoom
631
632         if(cvar("cl_reticle_stretch"))
633         {
634                 reticle_size_x = vid_conwidth;
635                 reticle_size_y = vid_conheight;
636                 reticle_pos_x = 0;
637                 reticle_pos_y = 0;
638         }
639         else
640         {
641                 reticle_size_x = max(vid_conwidth, vid_conheight);
642                 reticle_size_y = max(vid_conwidth, vid_conheight);
643                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
644                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
645         }
646
647         f = current_zoomfraction;
648         if(zoomscript_caught)
649                 f = 1;
650         if(cvar("cl_reticle_item_normal"))
651         {
652                 precache_pic("gfx/reticle_normal");
653                 if(reticle_type == 1 && f)
654                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
655         }
656         if(cvar("cl_reticle_item_nex"))
657         {
658                 precache_pic("gfx/reticle_nex");
659                 if(reticle_type == 2 && f)
660                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
661         }
662
663         // Draw the mouse cursor
664         // NOTE: drawpic must happen after R_RenderScene for some reason
665         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
666         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
667         //self = edict_num(player_localnum);
668         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
669         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
670         // as long as the ctf part isn't in, this is useless
671         if(menu_visible)
672                 menu_show();
673
674         /*if(gametype == GAME_CTF)
675           {
676           ctf_view();
677           } else */
678
679         // draw 2D entities
680         e = self;
681         for(self = world; (self = nextent(self)); )
682                 if(self.draw2d)
683                         self.draw2d();
684         self = e;
685
686         scoreboard_active = HUD_WouldDrawScoreboard();
687
688         float hud;
689         hud = getstati(STAT_HUD);
690         if(hud == HUD_SPIDERBOT)
691                 CSQC_SPIDER_HUD();
692         else if(hud == HUD_WAKIZASHI)
693         CSQC_WAKIZASHI_HUD();
694     else if(hud == HUD_RAPTOR)
695         CSQC_RAPTOR_HUD();
696         else
697         {
698                 if(cvar("r_letterbox") == 0)
699                         if(cvar("viewsize") < 120)
700                                 CSQC_common_hud();
701
702                 // crosshair goes VERY LAST
703                 if(!scoreboard_active && !camera_active && intermission != 2) {
704                         string wcross_style;
705                         float wcross_alpha, wcross_resolution;
706                         wcross_style = cvar_string("crosshair");
707                         if (wcross_style == "0")
708                                 return;
709                         wcross_resolution = cvar("crosshair_size");
710                         if (wcross_resolution == 0)
711                                 return;
712                         wcross_alpha = cvar("crosshair_alpha");
713                         if (wcross_alpha == 0)
714                                 return;
715
716                         // TrueAim check
717                         float shottype;
718                         float bullets, ring_scale;
719                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
720                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
721                         wcross_origin_z = 0;
722                         if(cvar("crosshair_hittest"))
723                         {
724                                 vector wcross_oldorigin;
725                                 wcross_oldorigin = wcross_origin;
726                                 shottype = TrueAimCheck();
727                                 if(shottype == SHOTTYPE_HITWORLD)
728                                 {
729                                         v = wcross_origin - wcross_oldorigin;
730                                         v_x /= vid_conwidth;
731                                         v_y /= vid_conheight;
732                                         if(vlen(v) > 0.01)
733                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
734                                 }
735                                 if(!cvar("crosshair_hittest_showimpact"))
736                                         wcross_origin = wcross_oldorigin;
737                         }
738                         else
739                                 shottype = SHOTTYPE_HITWORLD;
740
741                         vector wcross_color, wcross_size;
742                         string wcross_wep, wcross_name;
743                         float wcross_scale, wcross_blur;
744
745                         if (cvar("crosshair_per_weapon") || cvar("crosshair_color_per_weapon")) {
746                                 e = get_weaponinfo(activeweapon);
747                                 if (e && e.netname != "")
748                                 {
749                                         wcross_wep = e.netname;
750                                         if(cvar("crosshair_per_weapon"))
751                                         {
752                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
753                                                 if (wcross_resolution == 0)
754                                                         return;
755                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
756                                                 if (wcross_alpha == 0)
757                                                         return;
758
759                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
760                                                 if(wcross_style == "" || wcross_style == "0")
761                                                         wcross_style = wcross_wep;
762                                         }
763                                 }
764                         }
765                         if(wcross_wep != "" && cvar("crosshair_color_per_weapon"))
766                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
767                         else
768                                 wcross_color = stov(cvar_string("crosshair_color"));
769
770                         wcross_name = strcat("gfx/crosshair", wcross_style);
771
772                         if(cvar("crosshair_effect_scalefade"))
773                         {
774                                 wcross_scale = wcross_resolution;
775                                 wcross_resolution = 1;
776                         }
777                         else
778                         {
779                                 wcross_scale = 1;
780                         }
781
782                         if(cvar("crosshair_pickup"))
783                         {
784                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
785                                 {
786                                         pickup_crosshair_size = 1;
787                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
788                                 }
789
790                                 if(pickup_crosshair_size > 0)
791                                         pickup_crosshair_size -= cvar("crosshair_pickup_speed") * frametime;
792                                 else
793                                         pickup_crosshair_size = 0;
794
795                                 wcross_scale += sin(pickup_crosshair_size) * cvar("crosshair_pickup");
796                         }
797
798                         if(shottype == SHOTTYPE_HITENEMY)
799                                 wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
800                         if(shottype == SHOTTYPE_HITTEAM)
801                                 wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
802
803                         f = cvar("crosshair_effect_speed");
804                         if(f < 0)
805                                 f *= -2 * g_weaponswitchdelay;
806                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
807                         {
808                                 wcross_changedonetime = time + f;
809                         }
810                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
811                         {
812                                 wcross_name_changestarttime = time;
813                                 wcross_name_changedonetime = time + f;
814                                 if(wcross_name_goal_prev_prev)
815                                         strunzone(wcross_name_goal_prev_prev);
816                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
817                                 wcross_name_goal_prev = strzone(wcross_name);
818                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
819                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
820                                 wcross_resolution_goal_prev = wcross_resolution;
821                         }
822
823                         wcross_scale_goal_prev = wcross_scale;
824                         wcross_alpha_goal_prev = wcross_alpha;
825                         wcross_color_goal_prev = wcross_color;
826
827                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
828                         {
829                                 wcross_blur = 1;
830                                 wcross_alpha *= 0.75;
831                         }
832                         else
833                                 wcross_blur = 0;
834                         // *_prev is at time-frametime
835                         // * is at wcross_changedonetime+f
836                         // what do we have at time?
837                         if(time < wcross_changedonetime)
838                         {
839                                 f = frametime / (wcross_changedonetime - time + frametime);
840                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
841                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
842                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
843                         }
844
845                         wcross_scale_prev = wcross_scale;
846                         wcross_alpha_prev = wcross_alpha;
847                         wcross_color_prev = wcross_color;
848
849                         wcross_scale *= 1 - cvar("_menu_alpha");
850                         wcross_alpha *= 1 - cvar("_menu_alpha");
851
852                         ring_scale = cvar("crosshair_ring_size");
853
854                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
855
856                         float nex_charge;
857                         nex_charge = getstatf(STAT_NEX_CHARGE);
858
859                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
860                                 nex_charge_movingavg = nex_charge;
861
862                         // ring around crosshair representing bullets left in camping rifle clip
863                         if (activeweapon == WEP_CAMPINGRIFLE && cr_maxbullets)
864                         {
865                                 bullets = getstati(STAT_BULLETS_LOADED);
866                                 f = bound(0, bullets / cr_maxbullets, 1);
867
868                                 a = cvar("crosshair_campingrifle_bulletcounter_alpha");
869                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
870                         }
871                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
872                         {
873                                 vector rgb;
874                                 // indicate how much we're charging right now with an inner circle
875                                 a = cvar("crosshair_nexvelocity_currentcharge_alpha");
876                                 nex_charge_movingavg = (1 - cvar("crosshair_nexvelocity_currentcharge_movingavg_rate")) * nex_charge_movingavg + cvar("crosshair_nexvelocity_currentcharge_movingavg_rate") * nex_charge;
877
878                                 rgb = eX * cvar("crosshair_nexvelocity_currentcharge_color_red") + eY * cvar("crosshair_nexvelocity_currentcharge_color_green") + eZ * cvar("crosshair_nexvelocity_currentcharge_color_blue");
879                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, cvar("crosshair_nexvelocity_currentcharge_scale") * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
880
881                                 // draw the charge
882                                 a = cvar("crosshair_nexvelocity_alpha");
883                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
884                         }
885
886 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
887                         do \
888                         { \
889                                 if(wcross_blur > 0) \
890                                 { \
891                                         for(i = -2; i <= 2; ++i) \
892                                                 for(j = -2; j <= 2; ++j) \
893                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
894                                 } \
895                                 else \
896                                 { \
897                                         M(0,0,sz,wcross_name,wcross_alpha); \
898                                 } \
899                         } \
900                         while(0)
901
902 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
903                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
904
905 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
906                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
907
908                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
909                         {
910                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
911                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
912                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
913                                 f = 1 - f;
914                         }
915                         else
916                         {
917                                 f = 1;
918                         }
919
920                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
921                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
922
923                         if(cvar("crosshair_dot"))
924                                 CROSSHAIR_DRAW(wcross_resolution * cvar("crosshair_dot_size"), "gfx/crosshairdot.tga", wcross_alpha * f * cvar("crosshair_dot_alpha"));
925
926                         wcross_name_alpha_goal_prev = f;
927                 }
928                 else
929                 {
930                         wcross_scale_prev = 0;
931                         wcross_alpha_prev = 0;
932                         wcross_scale_goal_prev = 0;
933                         wcross_alpha_goal_prev = 0;
934                         wcross_changedonetime = 0;
935                         if(wcross_name_goal_prev)
936                                 strunzone(wcross_name_goal_prev);
937                         wcross_name_goal_prev = string_null;
938                         if(wcross_name_goal_prev_prev)
939                                 strunzone(wcross_name_goal_prev_prev);
940                         wcross_name_goal_prev_prev = string_null;
941                         wcross_name_changestarttime = 0;
942                         wcross_name_changedonetime = 0;
943                         wcross_name_alpha_goal_prev = 0;
944                         wcross_name_alpha_goal_prev_prev = 0;
945                         wcross_resolution_goal_prev = 0;
946                         wcross_resolution_goal_prev_prev = 0;
947                 }
948         }
949
950         if(NextFrameCommand)
951         {
952                 localcmd("\n", NextFrameCommand, "\n");
953                 NextFrameCommand = string_null;
954         }
955
956         // we must do this check AFTER a frame was rendered, or it won't work
957         if(cs_project_is_b0rked == 0)
958         {
959                 string w0, h0;
960                 w0 = cvar_string("vid_conwidth");
961                 h0 = cvar_string("vid_conheight");
962                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
963                 //R_SetView(VF_FOV, '90 90 0');
964                 R_SetView(VF_ORIGIN, '0 0 0');
965                 R_SetView(VF_ANGLES, '0 0 0');
966                 R_SetView(VF_PERSPECTIVE, 1);
967                 makevectors('0 0 0');
968                 vector v1, v2;
969                 cvar_set("vid_conwidth", "800");
970                 cvar_set("vid_conheight", "600");
971                 v1 = cs_project(v_forward);
972                 cvar_set("vid_conwidth", "640");
973                 cvar_set("vid_conheight", "480");
974                 v2 = cs_project(v_forward);
975                 if(v1 == v2)
976                         cs_project_is_b0rked = 1;
977                 else
978                         cs_project_is_b0rked = -1;
979                 cvar_set("vid_conwidth", w0);
980                 cvar_set("vid_conheight", h0);
981         }
982
983         if(autocvar__hud_configure)
984                 HUD_Panel_Mouse();
985
986         // let's reset the view back to normal for the end
987         R_SetView(VF_MIN, '0 0 0');
988         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
989 }
990
991 #define spider_h "gfx/vehicles/hud_bg.tga"
992 #define spider_b "gfx/vehicles/sbot.tga"
993 #define spider_r "gfx/vehicles/sbot_rpods.tga"
994 #define spider_g "gfx/vehicles/sbot_mguns.tga"
995 #define spider_s "gfx/vehicles/shiled.tga"
996 #define spider_a1 "gfx/hud/sb_rocket.tga"
997 #define spider_a2 "gfx/sb_bullets.tga"
998
999 void CSQC_SPIDER_HUD()
1000 {
1001         float rockets, reload, heat, hp, shield;
1002         vector picsize, hudloc;
1003
1004     // Fetch health & ammo stats
1005     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1006         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1007         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1008         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1009         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1010
1011     // Draw the crosshairs
1012     picsize = drawgetimagesize(SPIDER_CROSS);
1013     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1014     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1015     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1016
1017     hudloc_y =  4;
1018     hudloc_x = 4;
1019
1020     picsize = drawgetimagesize(spider_h) * 0.5;
1021     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1022
1023     picsize = drawgetimagesize(spider_a2) * 0.5;
1024     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1025
1026     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1027     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1028     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1029
1030     picsize = drawgetimagesize(spider_a1) * 0.85;
1031     if(rockets == 9)
1032     {
1033         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1034         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1035     }
1036     else
1037     {
1038         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1039         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1040     }
1041
1042     picsize = drawgetimagesize(spider_b) * 0.5;
1043     hudloc_y = 10.5;
1044     hudloc_x = 10.5;
1045
1046     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1047     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1048     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1049     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1050
1051
1052         /*
1053         // Draw health bar
1054         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1055         p = p + '0 1 0' * vid_conheight - '0 32 0';
1056         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1057         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1058         p_y += 8;
1059         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1060         p_x += 256 * hp;
1061         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1062
1063         // Draw minigun heat indicator
1064         p = '0.5 0 0' * (vid_conwidth - 256);
1065         p = p + '0 1 0' * vid_conheight - '0 34  0';
1066         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1067         p_x += 256 * (1-heat);
1068         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1069
1070
1071         // Draw rocket icons for loaded/empty tubes.
1072         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1073         pp += '0 1 0' * vid_conheight - '0 64 0';
1074         for(i = 0; i < 8; ++i)
1075         {
1076                 p = pp + '1 0 0' * (rkt_size * i);
1077                 if(rockets == 8)
1078                 {
1079                         if(floor(reload * 8) == i)
1080                         {
1081                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1082                         }
1083                         else if(i < reload * 8)
1084                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1085                         else
1086                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1087                 }
1088                 else
1089                 {
1090                         if(i < rockets)
1091                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1092                         else
1093                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1094                 }
1095         }
1096         */
1097
1098         if (scoreboard_showscores)
1099         {
1100                 HUD_DrawScoreboard();
1101                 HUD_DrawCenterPrint();
1102         }
1103
1104 }
1105
1106 #define raptor_h "gfx/vehicles/hud_bg.tga"
1107 #define raptor_b "gfx/vehicles/raptor.tga"
1108 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1109 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1110 #define raptor_s "gfx/vehicles/shiled.tga"
1111
1112 void CSQC_RAPTOR_HUD()
1113 {
1114         float reload, hp, shield, energy;
1115         vector picsize, hudloc;
1116
1117     // Fetch health & ammo stats
1118     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1119         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1120         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1121         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1122
1123     // Draw the crosshairs
1124     picsize = drawgetimagesize(SPIDER_CROSS);
1125     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1126     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1127     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1128
1129     hudloc_y =  4;
1130     hudloc_x = 4;
1131
1132     picsize = drawgetimagesize(raptor_h) * 0.5;
1133     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1134
1135     picsize = drawgetimagesize(spider_a2) * 0.5;
1136     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1137
1138     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1139     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1140     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1141
1142
1143     picsize = drawgetimagesize(spider_a1) * 0.85;
1144     if(reload == 1)
1145     {
1146         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1147         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1148     }
1149     else
1150     {
1151         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1152         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1153     }
1154
1155     picsize = drawgetimagesize(raptor_b) * 0.5;
1156     hudloc_y = 10.5;
1157     hudloc_x = 10.5;
1158
1159     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1160     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1161     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1162     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1163
1164
1165         if (scoreboard_showscores)
1166         {
1167                 HUD_DrawScoreboard();
1168                 HUD_DrawCenterPrint();
1169         }
1170
1171 }
1172
1173 #define waki_h "gfx/vehicles/hud_bg.tga"
1174 #define waki_b "gfx/vehicles/waki.tga"
1175 #define waki_e "gfx/vehicles/waki_e.tga"
1176 #define waki_g "gfx/vehicles/waki_guns.tga"
1177 #define waki_r "gfx/vehicles/waki_rockets.tga"
1178 #define waki_s "gfx/vehicles/shiled.tga"
1179
1180 #define waki_a1 "gfx/hud/sb_rocket.tga"
1181 #define waki_a2 "gfx/sb_cells.tga"
1182
1183 void CSQC_WAKIZASHI_HUD()
1184 {
1185         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1186         float health, shield, energy, rockets;
1187         vector picsize, hudloc;
1188
1189     picsize = drawgetimagesize(SPIDER_CROSS);
1190     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1191     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1192     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1193
1194 /*
1195 const float STAT_VEHICLESTAT_HEALTH  = 60;
1196 const float STAT_VEHICLESTAT_SHIELD  = 61;
1197 const float STAT_VEHICLESTAT_ENERGY  = 62;
1198 const float STAT_VEHICLESTAT_AMMO1   = 63;
1199 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1200 const float STAT_VEHICLESTAT_AMMO2   = 65;
1201 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1202 */
1203     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1204         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1205         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1206         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1207
1208     hudloc_y =  4;
1209     hudloc_x = 4;
1210
1211     picsize = drawgetimagesize(waki_h) * 0.5;
1212     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1213
1214     picsize = drawgetimagesize(waki_a2) * 0.7;
1215     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1216
1217
1218     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1219     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1220
1221     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1222
1223     picsize = drawgetimagesize(waki_a1) * 0.75;
1224     if(rockets == 1)
1225     {
1226         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1227         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1228     }
1229     else
1230     {
1231         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1232         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1233         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1234     }
1235
1236     picsize = drawgetimagesize(waki_b) * 0.5;
1237     hudloc_y = 10.5;
1238     hudloc_x = 10.5;
1239
1240     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1241     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1242     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1243     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1244
1245
1246
1247         /*
1248         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1249         p = p + '0 1 0' * vid_conheight - '0 32 0';
1250
1251         // Draw health bar
1252         p_y += 8;
1253         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1254         p_x += 256 * health;
1255         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1256
1257         // Draw shiled bar
1258         p_x -= 256 * health;
1259         p_y += 4;
1260         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1261
1262         // Draw energy
1263         //p_x -= 256 * health;
1264         p_y -= 8;
1265         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1266
1267         // Draw rockets bar
1268         p_y += 12;
1269         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1270         */
1271
1272
1273
1274
1275         if (scoreboard_showscores)
1276         {
1277                 HUD_DrawScoreboard();
1278                 HUD_DrawCenterPrint();
1279         }
1280
1281 }
1282
1283
1284 void CSQC_common_hud(void)
1285 {
1286         // HUD_SortFrags(); done in HUD_Draw
1287         float hud;
1288         hud = getstati(STAT_HUD);
1289
1290         //hud = 10;
1291         switch(hud)
1292         {
1293                 case HUD_NORMAL:
1294                         // do some accuracy var caching
1295                         float i;
1296                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1297                         {
1298                                 if(cvar_string("accuracy_color_levels") != acc_color_levels)
1299                                 {
1300                                         if(acc_color_levels)
1301                                                 strunzone(acc_color_levels);
1302                                         acc_color_levels = strzone(cvar_string("accuracy_color_levels"));
1303                                         acc_levels = tokenize(acc_color_levels);
1304                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1305                                                 acc_levels = MAX_ACCURACY_LEVELS;
1306
1307                                         for (i = 0; i < acc_levels; ++i)
1308                                                 acc_lev[i] = stof(argv(i));
1309                                 }
1310                                 // let know that acc_col[] needs to be loaded
1311                                 acc_col_x[0] = -1;
1312                         }
1313
1314                         HUD_Main(); // always run these functions for alpha checks
1315                         HUD_DrawScoreboard();
1316
1317                         if (scoreboard_active) // scoreboard/accuracy
1318                         {       
1319                                 HUD_Reset();
1320                                 // HUD_DrawScoreboard takes care of centerprint_start
1321                         }
1322                         else if (intermission == 2) // map voting screen
1323                         {
1324                                 HUD_FinaleOverlay();
1325                                 HUD_Reset();
1326
1327                                 centerprint_start_x = 0;
1328                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1329                         }
1330                         else // hud
1331                         {
1332                                 centerprint_start_x = 0;
1333                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1334                         }
1335
1336                         HUD_DrawCenterPrint();
1337                         break;
1338
1339                 case HUD_SPIDERBOT:
1340                         CSQC_SPIDER_HUD();
1341                         break;
1342
1343                 case HUD_WAKIZASHI:
1344                         CSQC_WAKIZASHI_HUD();
1345                         break;
1346         }
1347 }
1348
1349
1350 // following vectors must be global to allow seamless switching between camera modes
1351 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1352 void CSQC_Demo_Camera()
1353 {
1354         float speed, attenuation, dimensions;
1355         vector tmp, delta;
1356
1357         if( cvar("camera_reset") || !camera_mode )
1358         {
1359                 camera_offset = '0 0 0';
1360                 current_angles = '0 0 0';
1361                 camera_direction = '0 0 0';
1362                 camera_offset_z += 30;
1363                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1364                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1365                 current_origin = view_origin;
1366                 current_camera_offset  = camera_offset;
1367                 cvar_set("camera_reset", "0");
1368                 camera_mode = CAMERA_CHASE;
1369         }
1370
1371         // Camera angles
1372         if( camera_roll )
1373                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1374
1375         if(cvar("camera_look_player"))
1376         {
1377                 local vector dir;
1378                 local float n;
1379
1380                 dir = normalize(view_origin - current_position);
1381                 n = mouse_angles_z;
1382                 mouse_angles = vectoangles(dir);
1383                 mouse_angles_x = mouse_angles_x * -1;
1384                 mouse_angles_z = n;
1385         }
1386         else
1387         {
1388                 tmp = getmousepos() * 0.1;
1389                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1390                 {
1391                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1392                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1393                 }
1394         }
1395
1396         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1397         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1398         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1399         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1400
1401         // Fix difference when angles don't have the same sign
1402         delta = '0 0 0';
1403         if(mouse_angles_y < -60 && current_angles_y > 60)
1404                 delta = '0 360 0';
1405         if(mouse_angles_y > 60 && current_angles_y < -60)
1406                 delta = '0 -360 0';
1407
1408         if(cvar("camera_look_player"))
1409                 attenuation = cvar("camera_look_attenuation");
1410         else
1411                 attenuation = cvar("camera_speed_attenuation");
1412
1413         attenuation = 1 / max(1, attenuation);
1414         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1415
1416         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1417         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1418         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1419         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1420
1421         // Camera position
1422         tmp = '0 0 0';
1423         dimensions = 0;
1424
1425         if( camera_direction_x )
1426         {
1427                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1428                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1429                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1430                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1431                 ++dimensions;
1432         }
1433
1434         if( camera_direction_y )
1435         {
1436                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1437                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1438                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1439                 ++dimensions;
1440         }
1441
1442         if( camera_direction_z )
1443         {
1444                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1445                 ++dimensions;
1446         }
1447
1448         if(cvar("camera_free"))
1449                 speed = cvar("camera_speed_free");
1450         else
1451                 speed = cvar("camera_speed_chase");
1452
1453         if(dimensions)
1454         {
1455                 speed = speed * sqrt(1 / dimensions);
1456                 camera_offset += tmp * speed;
1457         }
1458
1459         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1460
1461         // Camera modes
1462         if( cvar("camera_free") )
1463         {
1464                 if ( camera_mode == CAMERA_CHASE )
1465                 {
1466                         current_camera_offset = current_origin + current_camera_offset;
1467                         camera_offset = current_origin + camera_offset;
1468                 }
1469
1470                 camera_mode = CAMERA_FREE;
1471                 current_position = current_camera_offset;
1472         }
1473         else
1474         {
1475                 if ( camera_mode == CAMERA_FREE )
1476                 {
1477                         current_origin = view_origin;
1478                         camera_offset = camera_offset - current_origin;
1479                         current_camera_offset = current_camera_offset - current_origin;
1480                 }
1481
1482                 camera_mode = CAMERA_CHASE;
1483
1484                 if(cvar("camera_chase_smoothly"))
1485                         current_origin += (view_origin - current_origin) * attenuation;
1486                 else
1487                         current_origin = view_origin;
1488
1489                 current_position = current_origin + current_camera_offset;
1490         }
1491
1492         R_SetView(VF_ANGLES, current_angles);
1493         R_SetView(VF_ORIGIN, current_position);
1494 }