qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float use_nex_chargepool;
 357
 358 float myhealth, myhealth_prev;
 359 float myhealth_flash;
 360
 361 vector myhealth_gentlergb;
 362
 363 float contentavgalpha, liquidalpha_prev;
 364 vector liquidcolor_prev;
 365
 366 void CSQC_UpdateView(float w, float h)
 367 {
 368         entity e;
 369         float fov;
 370         float f, i, j;
 371         vector v, vo;
 372         vector vf_size, vf_min;
 373         float a;
 374
 375         vf_size = R_SetView3fv(VF_SIZE);
 376         vf_min = R_SetView3fv(VF_MIN);
 377         vid_width = vf_size_x;
 378         vid_height = vf_size_y;
 379
 380         vector reticle_pos, reticle_size;
 381
 382         WaypointSprite_Load();
 383
 384         if(spectatee_status)
 385                 myteam = GetPlayerColor(spectatee_status - 1);
 386         else
 387                 myteam = GetPlayerColor(player_localentnum - 1);
 388
 389         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 390         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 391
 392         warpzone_fixview_origin = pmove_org + vo;
 393         warpzone_fixview_cl_viewangles = input_angles;
 394         warpzone_fixview_angles = view_angles;
 395         WarpZone_FixView();
 396         pmove_org = warpzone_fixview_origin - vo;
 397         input_angles = warpzone_fixview_cl_viewangles;
 398         view_angles = warpzone_fixview_angles;
 399
 400         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 401         {
 402                 pmove_org = freeze_pmove_org;
 403                 input_angles = view_angles = freeze_input_angles;
 404                 R_SetView(VF_ORIGIN, pmove_org + vo);
 405                 R_SetView(VF_ANGLES, view_angles);
 406                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 407         }
 408         freeze_pmove_org = pmove_org;
 409         freeze_input_angles = input_angles;
 410
 411         // Render the Scene
 412         if(!intermission || !view_set)
 413         {
 414                 view_origin = pmove_org + vo;
 415                 view_angles = input_angles;
 416                 makevectors(view_angles);
 417                 view_forward = v_forward;
 418                 view_right = v_right;
 419                 view_up = v_up;
 420                 view_set = 1;
 421         }
 422
 423 #ifdef BLURTEST
 424         if(time > blurtest_time0 && time < blurtest_time1)
 425         {
 426                 float r, t;
 427
 428                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 429                 r = t * blurtest_radius;
 430                 f = 1 / pow(t, blurtest_power) - 1;
 431
 432                 cvar_set("r_glsl_postprocess", "1");
 433                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 434         }
 435         else
 436         {
 437                 cvar_set("r_glsl_postprocess", "0");
 438                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 439         }
 440 #endif
 441
 442         TargetMusic_Advance();
 443         Fog_Force();
 444
 445         drawframetime = max(0.000001, time - drawtime);
 446         drawtime = time;
 447
 448         // watch for gametype changes here...
 449         // in ParseStuffCMD the cmd isn't executed yet :/
 450         // might even be better to add the gametype to TE_CSQC_INIT...?
 451         if(!postinit)
 452                 PostInit();
 453
 454         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 455                 if(calledhooks & HOOK_START)
 456                 {
 457                         localcmd("\ncl_hook_gameend\n");
 458                         calledhooks |= HOOK_END;
 459                 }
 460
 461         CheckForGamestartChange();
 462         serverAnnouncer();
 463         maptimeAnnouncer();
 464         carrierAnnouncer();
 465
 466         fov = autocvar_fov;
 467         if(button_zoom || fov <= 59.5)
 468         {
 469                 if(!zoomscript_caught)
 470                 {
 471                         localcmd("+button4\n");
 472                         zoomscript_caught = 1;
 473                         ignore_plus_zoom += 1;
 474                 }
 475         }
 476         else
 477         {
 478                 if(zoomscript_caught)
 479                 {
 480                         localcmd("-button4\n");
 481                         zoomscript_caught = 0;
 482                         ignore_minus_zoom += 1;
 483                 }
 484         }
 485
 486         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 487         activeweapon = getstati(STAT_SWITCHWEAPON);
 488         f = (serverflags & SERVERFLAG_TEAMPLAY);
 489         if(f != teamplay)
 490         {
 491                 teamplay = f;
 492                 HUD_InitScores();
 493         }
 494
 495         if(last_weapon != activeweapon) {
 496                 weapontime = time;
 497                 last_weapon = activeweapon;
 498
 499                 e = get_weaponinfo(activeweapon);
 500                 if(e.netname != "")
 501                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 502                 else
 503                         localcmd("\ncl_hook_activeweapon none\n");
 504         }
 505
 506         // ALWAYS Clear Current Scene First
 507         R_ClearScene();
 508
 509         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 510         R_SetView(VF_SIZE, vf_size);
 511         R_SetView(VF_MIN, vf_min);
 512
 513         // Assign Standard Viewflags
 514         // Draw the World (and sky)
 515         R_SetView(VF_DRAWWORLD, 1);
 516
 517         // Set the console size vars
 518         vid_conwidth = autocvar_vid_conwidth;
 519         vid_conheight = autocvar_vid_conheight;
 520         vid_pixelheight = autocvar_vid_pixelheight;
 521
 522         R_SetView(VF_FOV, GetCurrentFov(fov));
 523
 524         // Camera for demo playback
 525         if(camera_active)
 526         {
 527                 if(autocvar_camera_enable)
 528                         CSQC_Demo_Camera();
 529                 else
 530                 {
 531                         cvar_set("chase_active", ftos(chase_active_backup));
 532                         cvar_set("cl_demo_mousegrab", "0");
 533                         camera_active = FALSE;
 534                 }
 535         }
 536 #ifdef CAMERATEST
 537         else if(autocvar_camera_enable)
 538 #else
 539         else if(autocvar_camera_enable && isdemo())
 540 #endif
 541         {
 542                 // Enable required Darkplaces cvars
 543                 chase_active_backup = autocvar_chase_active;
 544                 cvar_set("chase_active", "2");
 545                 cvar_set("cl_demo_mousegrab", "1");
 546                 camera_active = TRUE;
 547                 camera_mode = FALSE;
 548         }
 549
 550         // Draw the Crosshair
 551         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 552
 553         // Draw the Engine Status Bar (the default Quake HUD)
 554         R_SetView(VF_DRAWENGINEHUD, 0);
 555
 556         // fetch this one only once per frame
 557         hud_showbinds = autocvar_hud_showbinds;
 558         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 559
 560         // Update the mouse position
 561         /*
 562            mousepos_x = vid_conwidth;
 563            mousepos_y = vid_conheight;
 564            mousepos = mousepos*0.5 + getmousepos();
 565          */
 566
 567         e = self;
 568         for(self = world; (self = nextent(self)); )
 569                 if(self.draw)
 570                         self.draw();
 571         self = e;
 572
 573         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 574         R_RenderScene();
 575
 576         // now switch to 2D drawing mode by calling a 2D drawing function
 577         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 578         // next R_RenderScene call
 579         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 580
 581         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 582         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 583         {
 584                 // apply night vision effect
 585                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 586
 587                 if(!nightvision_noise)
 588                 {
 589                         nightvision_noise = spawn();
 590                         nightvision_noise.classname = "nightvision_noise";
 591                 }
 592                 if(!nightvision_noise2)
 593                 {
 594                         nightvision_noise2 = spawn();
 595                         nightvision_noise2.classname = "nightvision_noise2";
 596                 }
 597
 598                 // color tint in yellow
 599                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 600
 601                 // draw BG
 602                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 603                 rgb = '1 1 1';
 604                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 605                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 606                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 607                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 608                 tc_11 = tc_01 + tc_10 - tc_00;
 609                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 610                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 611                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 612                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 613                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 614                 R_EndPolygon();
 615
 616                 // draw FG
 617                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 618                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 619                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 620                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 621                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 622                 tc_11 = tc_01 + tc_10 - tc_00;
 623                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 624                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 625                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 626                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 627                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 628                 R_EndPolygon();
 629         }
 630
 631         // Draw the aiming reticle for weapons that use it
 632         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 633         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 634         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 635         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 636                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 637         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 638                 reticle_type = 2; // nex zoom
 639         else if(button_zoom || zoomscript_caught)
 640                 reticle_type = 1; // normal zoom
 641         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 642                 reticle_type = 2; // nex zoom
 643
 644         if(autocvar_cl_reticle_stretch)
 645         {
 646                 reticle_size_x = vid_conwidth;
 647                 reticle_size_y = vid_conheight;
 648                 reticle_pos_x = 0;
 649                 reticle_pos_y = 0;
 650         }
 651         else
 652         {
 653                 reticle_size_x = max(vid_conwidth, vid_conheight);
 654                 reticle_size_y = max(vid_conwidth, vid_conheight);
 655                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 656                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 657         }
 658
 659         f = current_zoomfraction;
 660         if(zoomscript_caught)
 661                 f = 1;
 662         if(autocvar_cl_reticle_item_normal)
 663         {
 664                 precache_pic("gfx/reticle_normal");
 665                 if(reticle_type == 1 && f)
 666                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 667         }
 668         if(autocvar_cl_reticle_item_nex)
 669         {
 670                 precache_pic("gfx/reticle_nex");
 671                 if(reticle_type == 2 && f)
 672                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 673         }
 674
 675
 676         // improved polyblend
 677         vector rgb;
 678         if(autocvar_hud_contents)
 679         {
 680                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 681                 vector liquidcolor;
 682
 683                 switch(pointcontents(view_origin))
 684                 {
 685                         case CONTENT_WATER:
 686                                 liquidalpha = autocvar_hud_contents_water_alpha;
 687                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 688                                 incontent = 1;
 689                                 break;
 690
 691                         case CONTENT_LAVA:
 692                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 693                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 694                                 incontent = 1;
 695                                 break;
 696
 697                         case CONTENT_SLIME:
 698                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 699                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 700                                 incontent = 1;
 701                                 break;
 702
 703                         default:
 704                                 liquidalpha = 0;
 705                                 liquidcolor = '0 0 0';
 706                                 incontent = 0;
 707                                 break;
 708                 }
 709
 710                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 711                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 712                         contentfadetime = autocvar_hud_contents_fadeintime;
 713                         liquidalpha_prev = liquidalpha;
 714                         liquidcolor_prev = liquidcolor;
 715                 }
 716                 else
 717                         contentfadetime = autocvar_hud_contents_fadeouttime;
 718
 719                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 720                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 721
 722                 if(contentavgalpha)
 723                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 724         }
 725
 726         if(autocvar_hud_damage)
 727         {
 728                 float myhealth_flash_temp;
 729                 myhealth = getstati(STAT_HEALTH);
 730
 731                 // fade out
 732                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 733                 // add new damage
 734                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 735
 736                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 737                 pain_threshold = autocvar_hud_damage_pain_threshold;
 738                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 739                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 740
 741                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 742                 {
 743                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 744                 }
 745
 746                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 747
 748                 if(myhealth_prev < 1)
 749                 {
 750                         if(myhealth >= 1)
 751                         {
 752                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 753                                 myhealth_flash_temp = 0;
 754                         }
 755                         else
 756                         {
 757                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 758                         }
 759                 }
 760
 761                 if(spectatee_status == -1 || intermission)
 762                 {
 763                         myhealth_flash = 0; // observing, or match ended
 764                         myhealth_flash_temp = 0;
 765                 }
 766
 767                 myhealth_prev = myhealth;
 768
 769                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 770                 {
 771                         if(autocvar_cl_gentle_damage == 2)
 772                         {
 773                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 774                                 {
 775                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 776                                 }
 777                         }
 778                         else
 779                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 780
 781                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 782                 }
 783                 else
 784                         drawpic(reticle_pos, "gfx/blood", reticle_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 785         }
 786
 787         // Draw the mouse cursor
 788         // NOTE: drawpic must happen after R_RenderScene for some reason
 789         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 790         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 791         //self = edict_num(player_localnum);
 792         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 793         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 794         // as long as the ctf part isn't in, this is useless
 795         if(menu_visible)
 796                 menu_show();
 797
 798         /*if(gametype == GAME_CTF)
 799           {
 800           ctf_view();
 801           } else */
 802
 803         // draw 2D entities
 804         e = self;
 805         for(self = world; (self = nextent(self)); )
 806                 if(self.draw2d)
 807                         self.draw2d();
 808         self = e;
 809
 810         scoreboard_active = HUD_WouldDrawScoreboard();
 811
 812         float hud;
 813         hud = getstati(STAT_HUD);
 814         if(hud == HUD_SPIDERBOT)
 815                 CSQC_SPIDER_HUD();
 816         else if(hud == HUD_WAKIZASHI)
 817         CSQC_WAKIZASHI_HUD();
 818     else if(hud == HUD_RAPTOR)
 819         CSQC_RAPTOR_HUD();
 820         else
 821         {
 822                 if(gametype == GAME_FREEZETAG)
 823                 {
 824                         if(getstati(STAT_FROZEN))
 825                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 826                         if(getstatf(STAT_REVIVE_PROGRESS))
 827                         {
 828                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 829                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 830                         }
 831                 }
 832
 833                 if(autocvar_r_letterbox == 0)
 834                         if(autocvar_viewsize < 120)
 835                                 CSQC_common_hud();
 836
 837                 // crosshair goes VERY LAST
 838                 if(!scoreboard_active && !camera_active && intermission != 2) {
 839                         string wcross_style;
 840                         float wcross_alpha, wcross_resolution;
 841                         wcross_style = autocvar_crosshair;
 842                         if (wcross_style == "0")
 843                                 return;
 844                         wcross_resolution = autocvar_crosshair_size;
 845                         if (wcross_resolution == 0)
 846                                 return;
 847                         wcross_alpha = autocvar_crosshair_alpha;
 848                         if (wcross_alpha == 0)
 849                                 return;
 850
 851                         // TrueAim check
 852                         float shottype;
 853                         float bullets, ring_scale;
 854                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 855                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 856                         wcross_origin_z = 0;
 857                         if(autocvar_crosshair_hittest)
 858                         {
 859                                 vector wcross_oldorigin;
 860                                 wcross_oldorigin = wcross_origin;
 861                                 shottype = TrueAimCheck();
 862                                 if(shottype == SHOTTYPE_HITWORLD)
 863                                 {
 864                                         v = wcross_origin - wcross_oldorigin;
 865                                         v_x /= vid_conwidth;
 866                                         v_y /= vid_conheight;
 867                                         if(vlen(v) > 0.01)
 868                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 869                                 }
 870                                 if(!autocvar_crosshair_hittest_showimpact)
 871                                         wcross_origin = wcross_oldorigin;
 872                         }
 873                         else
 874                                 shottype = SHOTTYPE_HITWORLD;
 875
 876                         vector wcross_color, wcross_size;
 877                         string wcross_wep, wcross_name;
 878                         float wcross_scale, wcross_blur;
 879
 880                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 881                                 e = get_weaponinfo(activeweapon);
 882                                 if (e && e.netname != "")
 883                                 {
 884                                         wcross_wep = e.netname;
 885                                         if(autocvar_crosshair_per_weapon)
 886                                         {
 887                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 888                                                 if (wcross_resolution == 0)
 889                                                         return;
 890                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 891                                                 if (wcross_alpha == 0)
 892                                                         return;
 893
 894                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 895                                                 if(wcross_style == "" || wcross_style == "0")
 896                                                         wcross_style = wcross_wep;
 897                                         }
 898                                 }
 899                         }
 900                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 901                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 902                         else if(autocvar_crosshair_color_by_health)
 903                         {
 904                                 local float x = getstati(STAT_HEALTH);
 905
 906                                 //x = red
 907                                 //y = green
 908                                 //z = blue
 909
 910                                 wcross_color_z = 0;
 911
 912                                 if(x > 200)
 913                                 {
 914                                         wcross_color_x = 0;
 915                                         wcross_color_y = 1;
 916                                 }
 917                                 else if(x > 150)
 918                                 {
 919                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 920                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 921                                 }
 922                                 else if(x > 100)
 923                                 {
 924                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 925                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 926                                         wcross_color_z = 1 - (x-100)*0.02;
 927                                 }
 928                                 else if(x > 50)
 929                                 {
 930                                         wcross_color_x = 1;
 931                                         wcross_color_y = 1;
 932                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 933                                 }
 934                                 else if(x > 20)
 935                                 {
 936                                         wcross_color_x = 1;
 937                                         wcross_color_y = (x-20)*90/27/100;
 938                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 939                                 }
 940                                 else
 941                                 {
 942                                         wcross_color_x = 1;
 943                                         wcross_color_y = 0;
 944                                 }
 945                         }
 946                         else
 947                                 wcross_color = stov(autocvar_crosshair_color);
 948
 949                         wcross_name = strcat("gfx/crosshair", wcross_style);
 950
 951                         if(autocvar_crosshair_effect_scalefade)
 952                         {
 953                                 wcross_scale = wcross_resolution;
 954                                 wcross_resolution = 1;
 955                         }
 956                         else
 957                         {
 958                                 wcross_scale = 1;
 959                         }
 960
 961                         if(autocvar_crosshair_pickup)
 962                         {
 963                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
 964                                 {
 965                                         pickup_crosshair_size = 1;
 966                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
 967                                 }
 968
 969                                 if(pickup_crosshair_size > 0)
 970                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 971                                 else
 972                                         pickup_crosshair_size = 0;
 973
 974                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 975                         }
 976
 977                         if(shottype == SHOTTYPE_HITENEMY)
 978                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 979                         if(shottype == SHOTTYPE_HITTEAM)
 980                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 981
 982                         f = autocvar_crosshair_effect_speed;
 983                         if(f < 0)
 984                                 f *= -2 * g_weaponswitchdelay;
 985                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 986                         {
 987                                 wcross_changedonetime = time + f;
 988                         }
 989                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 990                         {
 991                                 wcross_name_changestarttime = time;
 992                                 wcross_name_changedonetime = time + f;
 993                                 if(wcross_name_goal_prev_prev)
 994                                         strunzone(wcross_name_goal_prev_prev);
 995                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
 996                                 wcross_name_goal_prev = strzone(wcross_name);
 997                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 998                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 999                                 wcross_resolution_goal_prev = wcross_resolution;
1000                         }
1001
1002                         wcross_scale_goal_prev = wcross_scale;
1003                         wcross_alpha_goal_prev = wcross_alpha;
1004                         wcross_color_goal_prev = wcross_color;
1005
1006                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1007                         {
1008                                 wcross_blur = 1;
1009                                 wcross_alpha *= 0.75;
1010                         }
1011                         else
1012                                 wcross_blur = 0;
1013                         // *_prev is at time-frametime
1014                         // * is at wcross_changedonetime+f
1015                         // what do we have at time?
1016                         if(time < wcross_changedonetime)
1017                         {
1018                                 f = frametime / (wcross_changedonetime - time + frametime);
1019                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1020                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1021                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1022                         }
1023
1024                         wcross_scale_prev = wcross_scale;
1025                         wcross_alpha_prev = wcross_alpha;
1026                         wcross_color_prev = wcross_color;
1027
1028                         wcross_scale *= 1 - autocvar__menu_alpha;
1029                         wcross_alpha *= 1 - autocvar__menu_alpha;
1030
1031                         ring_scale = autocvar_crosshair_ring_size;
1032
1033                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1034
1035                         float nex_charge, nex_chargepool;
1036                         nex_charge = getstatf(STAT_NEX_CHARGE);
1037                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1038
1039                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1040                                 nex_charge_movingavg = nex_charge;
1041
1042                         // ring around crosshair representing bullets left in camping rifle clip
1043                         if (activeweapon == WEP_SNIPERRIFLE && cr_maxbullets)
1044                         {
1045                                 bullets = getstati(STAT_BULLETS_LOADED);
1046                                 f = bound(0, bullets / cr_maxbullets, 1);
1047
1048                                 a = autocvar_crosshair_ring_sniperrifle_alpha;
1049                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1050                         }
1051                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
1052                         {
1053                                 if(nex_chargepool || use_nex_chargepool)
1054                                 {
1055                                         use_nex_chargepool = 1;
1056
1057                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1058                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1059                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", nex_chargepool, rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1060                                 }
1061                                 else
1062                                 {
1063                                         // indicate how much we're charging right now with an inner circle
1064                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1065                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1066
1067                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1068                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1069                                 }
1070
1071                                 // draw the charge
1072                                 a = autocvar_crosshair_ring_nex_outer_alpha;
1073                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1074                         }
1075
1076 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1077                         do \
1078                         { \
1079                                 if(wcross_blur > 0) \
1080                                 { \
1081                                         for(i = -2; i <= 2; ++i) \
1082                                                 for(j = -2; j <= 2; ++j) \
1083                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1084                                 } \
1085                                 else \
1086                                 { \
1087                                         M(0,0,sz,wcross_name,wcross_alpha); \
1088                                 } \
1089                         } \
1090                         while(0)
1091
1092 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1093                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1094
1095 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1096                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1097
1098                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1099                         {
1100                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1101                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1102                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1103                                 f = 1 - f;
1104                         }
1105                         else
1106                         {
1107                                 f = 1;
1108                         }
1109
1110                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1111                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1112
1113                         if(autocvar_crosshair_dot)
1114             {
1115                 vector wcross_color_old;
1116                 wcross_color_old = wcross_color;
1117                 if(autocvar_crosshair_dot_color != "0")
1118                     wcross_color = stov(autocvar_crosshair_dot_color);
1119                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1120                 wcross_color = wcross_color_old;
1121             }
1122
1123                         wcross_name_alpha_goal_prev = f;
1124                 }
1125                 else
1126                 {
1127                         wcross_scale_prev = 0;
1128                         wcross_alpha_prev = 0;
1129                         wcross_scale_goal_prev = 0;
1130                         wcross_alpha_goal_prev = 0;
1131                         wcross_changedonetime = 0;
1132                         if(wcross_name_goal_prev)
1133                                 strunzone(wcross_name_goal_prev);
1134                         wcross_name_goal_prev = string_null;
1135                         if(wcross_name_goal_prev_prev)
1136                                 strunzone(wcross_name_goal_prev_prev);
1137                         wcross_name_goal_prev_prev = string_null;
1138                         wcross_name_changestarttime = 0;
1139                         wcross_name_changedonetime = 0;
1140                         wcross_name_alpha_goal_prev = 0;
1141                         wcross_name_alpha_goal_prev_prev = 0;
1142                         wcross_resolution_goal_prev = 0;
1143                         wcross_resolution_goal_prev_prev = 0;
1144                 }
1145         }
1146
1147         if(NextFrameCommand)
1148         {
1149                 localcmd("\n", NextFrameCommand, "\n");
1150                 NextFrameCommand = string_null;
1151         }
1152
1153         // we must do this check AFTER a frame was rendered, or it won't work
1154         if(cs_project_is_b0rked == 0)
1155         {
1156                 string w0, h0;
1157                 w0 = ftos(autocvar_vid_conwidth);
1158                 h0 = ftos(autocvar_vid_conheight);
1159                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1160                 //R_SetView(VF_FOV, '90 90 0');
1161                 R_SetView(VF_ORIGIN, '0 0 0');
1162                 R_SetView(VF_ANGLES, '0 0 0');
1163                 R_SetView(VF_PERSPECTIVE, 1);
1164                 makevectors('0 0 0');
1165                 vector v1, v2;
1166                 cvar_set("vid_conwidth", "800");
1167                 cvar_set("vid_conheight", "600");
1168                 v1 = cs_project(v_forward);
1169                 cvar_set("vid_conwidth", "640");
1170                 cvar_set("vid_conheight", "480");
1171                 v2 = cs_project(v_forward);
1172                 if(v1 == v2)
1173                         cs_project_is_b0rked = 1;
1174                 else
1175                         cs_project_is_b0rked = -1;
1176                 cvar_set("vid_conwidth", w0);
1177                 cvar_set("vid_conheight", h0);
1178         }
1179
1180         if(autocvar__hud_configure)
1181                 HUD_Panel_Mouse();
1182
1183         // let's reset the view back to normal for the end
1184         R_SetView(VF_MIN, '0 0 0');
1185         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1186 }
1187
1188 #define spider_h "gfx/vehicles/hud_bg.tga"
1189 #define spider_b "gfx/vehicles/sbot.tga"
1190 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1191 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1192 #define spider_s "gfx/vehicles/shiled.tga"
1193 #define spider_a1 "gfx/hud/sb_rocket.tga"
1194 #define spider_a2 "gfx/sb_bullets.tga"
1195
1196 void CSQC_SPIDER_HUD()
1197 {
1198         float rockets, reload, heat, hp, shield;
1199         vector picsize, hudloc;
1200
1201     // Fetch health & ammo stats
1202     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1203         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1204         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1205         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1206         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1207
1208     // Draw the crosshairs
1209     picsize = drawgetimagesize(SPIDER_CROSS);
1210     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1211     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1212     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1213
1214     hudloc_y =  4;
1215     hudloc_x = 4;
1216
1217     picsize = drawgetimagesize(spider_h) * 0.5;
1218     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1219
1220     picsize = drawgetimagesize(spider_a2) * 0.5;
1221     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1222
1223     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1224     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1225     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1226
1227     picsize = drawgetimagesize(spider_a1) * 0.85;
1228     if(rockets == 9)
1229     {
1230         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1231         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1232     }
1233     else
1234     {
1235         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1236         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1237     }
1238
1239     picsize = drawgetimagesize(spider_b) * 0.5;
1240     hudloc_y = 10.5;
1241     hudloc_x = 10.5;
1242
1243     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1244     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1245     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1246     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1247
1248
1249         /*
1250         // Draw health bar
1251         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1252         p = p + '0 1 0' * vid_conheight - '0 32 0';
1253         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1254         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1255         p_y += 8;
1256         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1257         p_x += 256 * hp;
1258         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1259
1260         // Draw minigun heat indicator
1261         p = '0.5 0 0' * (vid_conwidth - 256);
1262         p = p + '0 1 0' * vid_conheight - '0 34  0';
1263         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1264         p_x += 256 * (1-heat);
1265         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1266
1267
1268         // Draw rocket icons for loaded/empty tubes.
1269         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1270         pp += '0 1 0' * vid_conheight - '0 64 0';
1271         for(i = 0; i < 8; ++i)
1272         {
1273                 p = pp + '1 0 0' * (rkt_size * i);
1274                 if(rockets == 8)
1275                 {
1276                         if(floor(reload * 8) == i)
1277                         {
1278                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1279                         }
1280                         else if(i < reload * 8)
1281                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1282                         else
1283                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1284                 }
1285                 else
1286                 {
1287                         if(i < rockets)
1288                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1289                         else
1290                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1291                 }
1292         }
1293         */
1294
1295         if (scoreboard_showscores)
1296         {
1297                 HUD_DrawScoreboard();
1298                 HUD_DrawCenterPrint();
1299         }
1300
1301 }
1302
1303 #define raptor_h "gfx/vehicles/hud_bg.tga"
1304 #define raptor_b "gfx/vehicles/raptor.tga"
1305 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1306 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1307 #define raptor_s "gfx/vehicles/shiled.tga"
1308
1309 void CSQC_RAPTOR_HUD()
1310 {
1311         float reload, hp, shield, energy;
1312         vector picsize, hudloc;
1313
1314     // Fetch health & ammo stats
1315     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1316         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1317         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1318         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1319
1320     // Draw the crosshairs
1321     picsize = drawgetimagesize(SPIDER_CROSS);
1322     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1323     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1324     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1325
1326     hudloc_y =  4;
1327     hudloc_x = 4;
1328
1329     picsize = drawgetimagesize(raptor_h) * 0.5;
1330     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1331
1332     picsize = drawgetimagesize(spider_a2) * 0.5;
1333     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1334
1335     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1336     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1337     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1338
1339
1340     picsize = drawgetimagesize(spider_a1) * 0.85;
1341     if(reload == 1)
1342     {
1343         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1344         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1345     }
1346     else
1347     {
1348         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1349         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1350     }
1351
1352     picsize = drawgetimagesize(raptor_b) * 0.5;
1353     hudloc_y = 10.5;
1354     hudloc_x = 10.5;
1355
1356     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1357     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1358     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1359     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1360
1361
1362         if (scoreboard_showscores)
1363         {
1364                 HUD_DrawScoreboard();
1365                 HUD_DrawCenterPrint();
1366         }
1367
1368 }
1369
1370 #define waki_h "gfx/vehicles/hud_bg.tga"
1371 #define waki_b "gfx/vehicles/waki.tga"
1372 #define waki_e "gfx/vehicles/waki_e.tga"
1373 #define waki_g "gfx/vehicles/waki_guns.tga"
1374 #define waki_r "gfx/vehicles/waki_rockets.tga"
1375 #define waki_s "gfx/vehicles/shiled.tga"
1376
1377 #define waki_a1 "gfx/hud/sb_rocket.tga"
1378 #define waki_a2 "gfx/sb_cells.tga"
1379
1380 void CSQC_WAKIZASHI_HUD()
1381 {
1382         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1383         float health, shield, energy, rockets;
1384         vector picsize, hudloc;
1385
1386     picsize = drawgetimagesize(SPIDER_CROSS);
1387     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1388     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1389     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1390
1391 /*
1392 const float STAT_VEHICLESTAT_HEALTH  = 60;
1393 const float STAT_VEHICLESTAT_SHIELD  = 61;
1394 const float STAT_VEHICLESTAT_ENERGY  = 62;
1395 const float STAT_VEHICLESTAT_AMMO1   = 63;
1396 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1397 const float STAT_VEHICLESTAT_AMMO2   = 65;
1398 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1399 */
1400     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1401         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1402         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1403         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1404
1405     hudloc_y =  4;
1406     hudloc_x = 4;
1407
1408     picsize = drawgetimagesize(waki_h) * 0.5;
1409     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1410
1411     picsize = drawgetimagesize(waki_a2) * 0.7;
1412     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1413
1414
1415     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1416     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1417
1418     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1419
1420     picsize = drawgetimagesize(waki_a1) * 0.75;
1421     if(rockets == 1)
1422     {
1423         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1424         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1425     }
1426     else
1427     {
1428         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1429         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1430         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1431     }
1432
1433     picsize = drawgetimagesize(waki_b) * 0.5;
1434     hudloc_y = 10.5;
1435     hudloc_x = 10.5;
1436
1437     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1438     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1439     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1440     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1441
1442
1443
1444         /*
1445         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1446         p = p + '0 1 0' * vid_conheight - '0 32 0';
1447
1448         // Draw health bar
1449         p_y += 8;
1450         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1451         p_x += 256 * health;
1452         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1453
1454         // Draw shiled bar
1455         p_x -= 256 * health;
1456         p_y += 4;
1457         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1458
1459         // Draw energy
1460         //p_x -= 256 * health;
1461         p_y -= 8;
1462         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1463
1464         // Draw rockets bar
1465         p_y += 12;
1466         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1467         */
1468
1469
1470
1471
1472         if (scoreboard_showscores)
1473         {
1474                 HUD_DrawScoreboard();
1475                 HUD_DrawCenterPrint();
1476         }
1477
1478 }
1479
1480
1481 void CSQC_common_hud(void)
1482 {
1483         // HUD_SortFrags(); done in HUD_Draw
1484         float hud;
1485         hud = getstati(STAT_HUD);
1486
1487         //hud = 10;
1488         switch(hud)
1489         {
1490                 case HUD_NORMAL:
1491                         // do some accuracy var caching
1492                         float i;
1493                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1494                         {
1495                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1496                                 {
1497                                         if(acc_color_levels)
1498                                                 strunzone(acc_color_levels);
1499                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1500                                         acc_levels = tokenize(acc_color_levels);
1501                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1502                                                 acc_levels = MAX_ACCURACY_LEVELS;
1503
1504                                         for (i = 0; i < acc_levels; ++i)
1505                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1506                                 }
1507                                 // let know that acc_col[] needs to be loaded
1508                                 acc_col_x[0] = -1;
1509                         }
1510
1511                         HUD_Main(); // always run these functions for alpha checks
1512                         HUD_DrawScoreboard();
1513
1514                         if (scoreboard_active) // scoreboard/accuracy
1515                         {
1516                                 HUD_Reset();
1517                                 // HUD_DrawScoreboard takes care of centerprint_start
1518                         }
1519                         else if (intermission == 2) // map voting screen
1520                         {
1521                                 HUD_FinaleOverlay();
1522                                 HUD_Reset();
1523
1524                                 centerprint_start_x = 0;
1525                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1526                         }
1527                         else // hud
1528                         {
1529                                 centerprint_start_x = 0;
1530                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1531                         }
1532
1533                         HUD_DrawCenterPrint();
1534                         break;
1535
1536                 case HUD_SPIDERBOT:
1537                         CSQC_SPIDER_HUD();
1538                         break;
1539
1540                 case HUD_WAKIZASHI:
1541                         CSQC_WAKIZASHI_HUD();
1542                         break;
1543         }
1544 }
1545
1546
1547 // following vectors must be global to allow seamless switching between camera modes
1548 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1549 void CSQC_Demo_Camera()
1550 {
1551         float speed, attenuation, dimensions;
1552         vector tmp, delta;
1553
1554         if( autocvar_camera_reset || !camera_mode )
1555         {
1556                 camera_offset = '0 0 0';
1557                 current_angles = '0 0 0';
1558                 camera_direction = '0 0 0';
1559                 camera_offset_z += 30;
1560                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1561                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1562                 current_origin = view_origin;
1563                 current_camera_offset  = camera_offset;
1564                 cvar_set("camera_reset", "0");
1565                 camera_mode = CAMERA_CHASE;
1566         }
1567
1568         // Camera angles
1569         if( camera_roll )
1570                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1571
1572         if(autocvar_camera_look_player)
1573         {
1574                 local vector dir;
1575                 local float n;
1576
1577                 dir = normalize(view_origin - current_position);
1578                 n = mouse_angles_z;
1579                 mouse_angles = vectoangles(dir);
1580                 mouse_angles_x = mouse_angles_x * -1;
1581                 mouse_angles_z = n;
1582         }
1583         else
1584         {
1585                 tmp = getmousepos() * 0.1;
1586                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1587                 {
1588                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1589                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1590                 }
1591         }
1592
1593         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1594         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1595         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1596         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1597
1598         // Fix difference when angles don't have the same sign
1599         delta = '0 0 0';
1600         if(mouse_angles_y < -60 && current_angles_y > 60)
1601                 delta = '0 360 0';
1602         if(mouse_angles_y > 60 && current_angles_y < -60)
1603                 delta = '0 -360 0';
1604
1605         if(autocvar_camera_look_player)
1606                 attenuation = autocvar_camera_look_attenuation;
1607         else
1608                 attenuation = autocvar_camera_speed_attenuation;
1609
1610         attenuation = 1 / max(1, attenuation);
1611         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1612
1613         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1614         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1615         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1616         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1617
1618         // Camera position
1619         tmp = '0 0 0';
1620         dimensions = 0;
1621
1622         if( camera_direction_x )
1623         {
1624                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1625                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1626                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1627                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1628                 ++dimensions;
1629         }
1630
1631         if( camera_direction_y )
1632         {
1633                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1634                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1635                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1636                 ++dimensions;
1637         }
1638
1639         if( camera_direction_z )
1640         {
1641                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1642                 ++dimensions;
1643         }
1644
1645         if(autocvar_camera_free)
1646                 speed = autocvar_camera_speed_free;
1647         else
1648                 speed = autocvar_camera_speed_chase;
1649
1650         if(dimensions)
1651         {
1652                 speed = speed * sqrt(1 / dimensions);
1653                 camera_offset += tmp * speed;
1654         }
1655
1656         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1657
1658         // Camera modes
1659         if( autocvar_camera_free )
1660         {
1661                 if ( camera_mode == CAMERA_CHASE )
1662                 {
1663                         current_camera_offset = current_origin + current_camera_offset;
1664                         camera_offset = current_origin + camera_offset;
1665                 }
1666
1667                 camera_mode = CAMERA_FREE;
1668                 current_position = current_camera_offset;
1669         }
1670         else
1671         {
1672                 if ( camera_mode == CAMERA_FREE )
1673                 {
1674                         current_origin = view_origin;
1675                         camera_offset = camera_offset - current_origin;
1676                         current_camera_offset = current_camera_offset - current_origin;
1677                 }
1678
1679                 camera_mode = CAMERA_CHASE;
1680
1681                 if(autocvar_camera_chase_smoothly)
1682                         current_origin += (view_origin - current_origin) * attenuation;
1683                 else
1684                         current_origin = view_origin;
1685
1686                 current_position = current_origin + current_camera_offset;
1687         }
1688
1689         R_SetView(VF_ANGLES, current_angles);
1690         R_SetView(VF_ORIGIN, current_position);
1691 }