Merge branch 'master' into samual/combined_updates
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / View.qc
1 entity porto;
2 vector polyline[16];
3 void Porto_Draw()
4 {
5         vector p, dir, ang, q, nextdir;
6         float idx, portal_number, portal1_idx;
7
8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
9                 return;
10         if(g_balance_porto_secondary)
11                 return;
12         if(intermission == 1)
13                 return;
14         if(intermission == 2)
15                 return;
16         if (getstati(STAT_HEALTH) <= 0)
17                 return;
18
19         dir = view_forward;
20
21         if(angles_held_status)
22         {
23                 makevectors(angles_held);
24                 dir = v_forward;
25         }
26
27         p = view_origin;
28
29         polyline[0] = p;
30         idx = 1;
31         portal_number = 0;
32         nextdir = dir;
33
34         for(;;)
35         {
36                 dir = nextdir;
37                 traceline(p, p + 65536 * dir, TRUE, porto);
38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
39                         return;
40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
41                 p = trace_endpos;
42                 polyline[idx] = p;
43                 ++idx;
44                 if(idx >= 16)
45                         return;
46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
47                         continue;
48                 ++portal_number;
49                 ang = vectoangles2(trace_plane_normal, dir);
50                 ang_x = -ang_x;
51                 makevectors(ang);
52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
53                         return;
54                 if(portal_number == 1)
55                 {
56                         portal1_idx = idx;
57                         if(portal_number >= 2)
58                                 break;
59                 }
60         }
61
62         while(idx >= 2)
63         {
64                 p = polyline[idx-2];
65                 q = polyline[idx-1];
66                 if(idx == 2)
67                         p = p - view_up * 16;
68                 if(idx-1 >= portal1_idx)
69                 {
70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
71                 }
72                 else
73                 {
74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
75                 }
76                 --idx;
77         }
78 }
79
80 void Porto_Init()
81 {
82         porto = spawn();
83         porto.classname = "porto";
84         porto.draw = Porto_Draw;
85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
86 }
87
88 float drawtime;
89 float avgspeed;
90 vector GetCurrentFov(float fov)
91 {
92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
93         float velocityzoom, curspeed;
94         vector v;
95
96         zoomsensitivity = autocvar_cl_zoomsensitivity;
97         zoomfactor = autocvar_cl_zoomfactor;
98         if(zoomfactor < 1 || zoomfactor > 16)
99                 zoomfactor = 2.5;
100         zoomspeed = autocvar_cl_zoomspeed;
101         if(zoomspeed >= 0)
102         if(zoomspeed < 0.5 || zoomspeed > 16)
103                         zoomspeed = 3.5;
104
105         zoomdir = button_zoom;
106         if(hud == HUD_NORMAL)
107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
108                 zoomdir += button_attack2;
109         if(spectatee_status > 0 || isdemo())
110         {
111                 if(spectatorbutton_zoom)
112                 {
113                         if(zoomdir)
114                                 zoomdir = 0;
115                         else
116                                 zoomdir = 1;
117                 }
118                 // fteqcc failed twice here already, don't optimize this
119         }
120
121         if(zoomdir) { zoomin_effect = 0; }
122
123         if(camera_active)
124         {
125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
126         }
127         else if(autocvar_cl_spawnzoom && zoomin_effect)
128         {
129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
130
131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
134         }
135         else
136         {
137                 if(zoomspeed < 0) // instant zoom
138                 {
139                         if(zoomdir)
140                                 current_viewzoom = 1 / zoomfactor;
141                         else
142                                 current_viewzoom = 1;
143                 }
144                 else
145                 {
146                         if(zoomdir)
147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
148                         else
149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
150                 }
151         }
152
153         if(almost_equals(current_viewzoom, 1))
154                 current_zoomfraction = 0;
155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
156                 current_zoomfraction = 1;
157         else
158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
159
160         if(zoomsensitivity < 1)
161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
162         else
163                 setsensitivityscale(1);
164
165         makevectors(view_angles);
166
167         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type && autocvar_cl_velocityzoom_factor) // _type = 0 disables velocity zoom too
168         {
169                 if(intermission) { curspeed = 0; }
170                 else
171                 {
172                         v = pmove_vel;
173                         if(csqcplayer)
174                                 v = csqcplayer.velocity;
175
176                         switch(autocvar_cl_velocityzoom_type)
177                         {
178                                 case 3: curspeed = max(0, v_forward * v); break;
179                                 case 2: curspeed = (v_forward * v); break;
180                                 case 1: default: curspeed = vlen(v); break;
181                         }
182                 }
183
184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
187
188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
189         }
190         else
191                 velocityzoom = 1;
192
193         float frustumx, frustumy, fovx, fovy;
194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
198
199         return '1 0 0' * fovx + '0 1 0' * fovy;
200 }
201
202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
203 {
204         float fovx, fovy;
205         float width = (ov_worldmax_x - ov_worldmin_x);
206         float height = (ov_worldmax_y - ov_worldmin_y);
207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
210         return '1 0 0' * fovx + '0 1 0' * fovy;
211 }
212
213 // this function must match W_SetupShot!
214 float zoomscript_caught;
215
216 vector wcross_origin;
217 float wcross_scale_prev, wcross_alpha_prev;
218 vector wcross_color_prev;
219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
220 vector wcross_color_goal_prev;
221 float wcross_changedonetime;
222
223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
225 float wcross_name_changestarttime, wcross_name_changedonetime;
226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
227
228 float wcross_ring_prev;
229
230 entity trueaim;
231 entity trueaim_rifle;
232
233 #define SHOTTYPE_HITTEAM 1
234 #define SHOTTYPE_HITOBSTRUCTION 2
235 #define SHOTTYPE_HITWORLD 3
236 #define SHOTTYPE_HITENEMY 4
237
238 void TrueAim_Init()
239 {
240         trueaim = spawn();
241         trueaim.classname = "trueaim";
242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
243         trueaim_rifle = spawn();
244         trueaim_rifle.classname = "trueaim_rifle";
245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
246 }
247
248 float EnemyHitCheck()
249 {
250         float t, n;
251         wcross_origin = project_3d_to_2d(trace_endpos);
252         wcross_origin_z = 0;
253         if(trace_ent)
254                 n = trace_ent.entnum;
255         else
256                 n = trace_networkentity;
257         if(n < 1)
258                 return SHOTTYPE_HITWORLD;
259         if(n > maxclients)
260                 return SHOTTYPE_HITWORLD;
261         t = GetPlayerColor(n - 1);
262         if(teamplay)
263                 if(t == myteam)
264                         return SHOTTYPE_HITTEAM;
265         if(t == NUM_SPECTATOR)
266                 return SHOTTYPE_HITWORLD;
267         return SHOTTYPE_HITENEMY;
268 }
269
270 float TrueAimCheck()
271 {
272         float nudge = 1; // added to traceline target and subtracted from result
273         vector vecs, trueaimpoint, w_shotorg;
274         vector mi, ma, dv;
275         float shottype;
276         entity ta;
277         float mv;
278
279         mi = ma = '0 0 0';
280         ta = trueaim;
281         mv = MOVE_NOMONSTERS;
282
283         switch(activeweapon)
284         {
285                 case WEP_TUBA: // no aim
286                 case WEP_PORTO: // shoots from eye
287                 case WEP_HOOK: // no trueaim
288                 case WEP_GRENADE_LAUNCHER: // toss curve
289                         return SHOTTYPE_HITWORLD;
290                 case WEP_NEX:
291                 case WEP_MINSTANEX:
292                         mv = MOVE_NORMAL;
293                         break;
294                 case WEP_RIFLE:
295                         ta = trueaim_rifle;
296                         mv = MOVE_NORMAL;
297                         if(zoomscript_caught)
298                         {
299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
300                                 return EnemyHitCheck();
301                         }
302                         break;
303                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
304                         mi = '-3 -3 -3';
305                         ma = '3 3 3';
306                         break;
307                 case WEP_FIREBALL: // projectile has a size!
308                         mi = '-16 -16 -16';
309                         ma = '16 16 16';
310                         break;
311                 case WEP_SEEKER: // projectile has a size!
312                         mi = '-2 -2 -2';
313                         ma = '2 2 2';
314                         break;
315                 case WEP_ELECTRO: // projectile has a size!
316                         mi = '0 0 -3';
317                         ma = '0 0 -3';
318                         break;
319         }
320
321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
322
323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
324
325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
326         trueaimpoint = trace_endpos;
327
328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
330
331         if(vecs_x > 0)
332                 vecs_y = -vecs_y;
333         else
334                 vecs = '0 0 0';
335
336         dv = view_right * vecs_y + view_up * vecs_z;
337         w_shotorg = traceorigin + dv;
338
339         // now move the vecs forward as much as requested if possible
340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
341         w_shotorg = trace_endpos - view_forward * nudge;
342
343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
344         shottype = EnemyHitCheck();
345         if(shottype != SHOTTYPE_HITWORLD)
346                 return shottype;
347
348 #if 0
349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
350         // or rather, I know why, but see no fix
351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
353                 return SHOTTYPE_HITOBSTRUCTION;
354 #endif
355
356         return SHOTTYPE_HITWORLD;
357 }
358
359 void CSQC_common_hud(void);
360
361 void PostInit(void);
362 void CSQC_Demo_Camera();
363 float HUD_WouldDrawScoreboard();
364 float camera_mode;
365 const float CAMERA_FREE = 1;
366 const float CAMERA_CHASE = 2;
367 float reticle_type;
368 string NextFrameCommand;
369 void CSQC_SPIDER_HUD();
370 void CSQC_RAPTOR_HUD();
371
372 vector freeze_org, freeze_ang;
373 entity nightvision_noise, nightvision_noise2;
374
375 #define MAX_TIME_DIFF 5
376 float pickup_crosshair_time, pickup_crosshair_size;
377 float hit_time, typehit_time;
378 float nextsound_hit_time, nextsound_typehit_time;
379 float hitindication_crosshair_time, hitindication_crosshair_size;
380 float use_nex_chargepool;
381
382 float myhealth, myhealth_prev;
383 float myhealth_flash;
384
385 float old_blurradius, old_bluralpha;
386 float old_sharpen_intensity;
387
388 vector myhealth_gentlergb;
389
390 float contentavgalpha, liquidalpha_prev;
391 vector liquidcolor_prev;
392
393 float eventchase_current_distance;
394
395 vector damage_blurpostprocess, content_blurpostprocess;
396
397 float checkfail[16];
398
399 float rainbow_last_flicker;
400 vector rainbow_prev_color;
401
402 #define BUTTON_3 4
403 #define BUTTON_4 8
404 float cl_notice_run();
405 float prev_myteam;
406 void CSQC_UpdateView(float w, float h)
407 {
408         entity e;
409         float fov;
410         float f, i, j;
411         vector v;
412         vector vf_size, vf_min;
413         float a;
414
415         execute_next_frame();
416
417         ++framecount;
418
419         hud = getstati(STAT_HUD);
420
421         if(autocvar__hud_showbinds_reload) // menu can set this one
422         {
423                 db_close(binddb);
424                 binddb = db_create();
425                 cvar_set("_hud_showbinds_reload", "0");
426         }
427
428         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
429                 view_quality = getproperty(VF_MINFPS_QUALITY);
430         else
431                 view_quality = 1;
432
433         button_attack2 = (input_buttons & BUTTON_3);
434         button_zoom = (input_buttons & BUTTON_4);
435
436 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
437         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
438         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
439         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
440         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
441         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
442         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
443         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
444
445         vf_size = getpropertyvec(VF_SIZE);
446         vf_min = getpropertyvec(VF_MIN);
447         vid_width = vf_size_x;
448         vid_height = vf_size_y;
449
450         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
451         vector splash_pos = '0 0 0', splash_size = '0 0 0';
452
453         WaypointSprite_Load();
454
455         CSQCPlayer_SetCamera();
456
457 #ifdef COMPAT_XON050_ENGINE
458         if(spectatee_status)
459                 myteam = GetPlayerColor(spectatee_status - 1);
460         else
461 #endif
462                 myteam = GetPlayerColor(player_localentnum - 1);
463
464         if(myteam != prev_myteam)
465         {
466                 myteamcolors = colormapPaletteColor(myteam, 1);
467                 for(i = 0; i < HUD_PANEL_NUM; ++i)
468                         hud_panel[i].update_time = time;
469                 prev_myteam = myteam;
470         }
471
472         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
473
474         float is_dead = (getstati(STAT_HEALTH) <= 0);
475
476         // FIXME do we need this hack?
477         if(isdemo())
478         {
479                 // in demos, input_buttons do not work
480                 button_zoom = (autocvar__togglezoom == "-");
481         }
482         else if(button_zoom
483                 && autocvar_cl_unpress_zoom_on_death
484                 && (spectatee_status >= 0)
485                 && (is_dead || intermission))
486         {
487                 // no zoom while dead or in intermission please
488                 localcmd("-zoom\n");
489                 button_zoom = FALSE;
490         }
491
492         // event chase camera
493         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
494         {
495                 WepSet weapons_stat = WepSet_GetFromStat();
496                 if(((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission) && !autocvar_cl_orthoview || (autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(weapons_stat & WepSet_FromWeapon(WEP_PORTO))))
497                 {
498                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
499                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
500
501                         // detect maximum viewoffset and use it
502                         if(autocvar_cl_eventchase_viewoffset)
503                         {
504                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
505                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
506                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
507                         }
508
509                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
510                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
511                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
512                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
513
514                         // make the camera smooth back
515                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
516                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
517                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
518                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
519
520                         makevectors(view_angles);
521
522                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
523                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
524
525                         // If the boxtrace fails, revert back to line tracing.
526                         if(trace_startsolid)
527                         {
528                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
529                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
530                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
531                         }
532                         else { setproperty(VF_ORIGIN, trace_endpos); }
533
534                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
535                 }
536                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
537                 {
538                         cvar_set("chase_active", "0");
539                         eventchase_current_distance = 0; // start from 0 next time
540                 }
541         }
542         // workaround for camera stuck between player's legs when using chase_active 1
543         // because the engine stops updating the chase_active camera when the game ends
544         else if(intermission)
545         {
546                 cvar_settemp("chase_active", "-1");
547                 eventchase_current_distance = 0;
548         }
549
550         // do lockview after event chase camera so that it still applies whenever necessary.
551         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
552         {
553                 setproperty(VF_ORIGIN, freeze_org);
554                 setproperty(VF_ANGLES, freeze_ang);
555         }
556         else
557         {
558                 freeze_org = getpropertyvec(VF_ORIGIN);
559                 freeze_ang = getpropertyvec(VF_ANGLES);
560         }
561
562         WarpZone_FixView();
563         //WarpZone_FixPMove();
564
565         vector ov_org = '0 0 0';
566         vector ov_mid = '0 0 0';
567         vector ov_worldmin = '0 0 0';
568         vector ov_worldmax = '0 0 0';
569         if(autocvar_cl_orthoview)
570         {
571                 ov_worldmin = mi_picmin;
572                 ov_worldmax = mi_picmax;
573
574                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
575                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
576                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
577
578                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
579                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
580
581                 float ov_nearest = vlen(ov_org - vec3(
582                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
583                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
584                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
585                 ));
586
587                 float ov_furthest = 0;
588                 float dist = 0;
589
590                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
591                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
592                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
593                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
594                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
595                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
596                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
597                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
598
599                 cvar_settemp("r_nearclip", ftos(ov_nearest));
600                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
601                 cvar_settemp("r_farclip_world", "0");
602                 cvar_settemp("r_novis", "1");
603                 cvar_settemp("r_useportalculling", "0");
604                 cvar_settemp("r_useinfinitefarclip", "0");
605
606                 setproperty(VF_ORIGIN, ov_org);
607                 setproperty(VF_ANGLES, '90 0 0');
608
609                 #if 0
610                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
611                         vtos(ov_org),
612                         vtos(getpropertyvec(VF_ANGLES)),
613                         ov_distance,
614                         ov_nearest,
615                         ov_furthest);
616                 #endif
617         }
618
619         // Render the Scene
620         view_origin = getpropertyvec(VF_ORIGIN);
621         view_angles = getpropertyvec(VF_ANGLES);
622         makevectors(view_angles);
623         view_forward = v_forward;
624         view_right = v_right;
625         view_up = v_up;
626
627 #ifdef BLURTEST
628         if(time > blurtest_time0 && time < blurtest_time1)
629         {
630                 float r, t;
631
632                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
633                 r = t * blurtest_radius;
634                 f = 1 / pow(t, blurtest_power) - 1;
635
636                 cvar_set("r_glsl_postprocess", "1");
637                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
638         }
639         else
640         {
641                 cvar_set("r_glsl_postprocess", "0");
642                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
643         }
644 #endif
645
646         TargetMusic_Advance();
647         Fog_Force();
648
649         if(drawtime == 0)
650                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
651         else
652                 drawframetime = bound(0.000001, time - drawtime, 1);
653         drawtime = time;
654
655         // watch for gametype changes here...
656         // in ParseStuffCMD the cmd isn't executed yet :/
657         // might even be better to add the gametype to TE_CSQC_INIT...?
658         if(!postinit)
659                 PostInit();
660
661         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
662         {
663                 if(calledhooks & HOOK_START)
664                 {
665                         localcmd("\ncl_hook_gameend\n");
666                         calledhooks |= HOOK_END;
667                 }
668         }
669
670         Announcer();
671
672         fov = autocvar_fov;
673         if(fov <= 59.5)
674         {
675                 if(!zoomscript_caught)
676                 {
677                         localcmd("+button9\n");
678                         zoomscript_caught = 1;
679                 }
680         }
681         else
682         {
683                 if(zoomscript_caught)
684                 {
685                         localcmd("-button9\n");
686                         zoomscript_caught = 0;
687                 }
688         }
689
690         ColorTranslateMode = autocvar_cl_stripcolorcodes;
691
692         // next WANTED weapon (for HUD)
693         switchweapon = getstati(STAT_SWITCHWEAPON);
694
695         // currently switching-to weapon (for crosshair)
696         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
697
698         // actually active weapon (for zoom)
699         activeweapon = getstati(STAT_ACTIVEWEAPON);
700
701         f = (serverflags & SERVERFLAG_TEAMPLAY);
702         if(f != teamplay)
703         {
704                 teamplay = f;
705                 HUD_InitScores();
706         }
707
708         if(last_switchweapon != switchweapon)
709         {
710                 weapontime = time;
711                 last_switchweapon = switchweapon;
712                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
713                 {
714                         localcmd("-zoom\n");
715                         button_zoom = FALSE;
716                 }
717                 if(autocvar_cl_unpress_attack_on_weapon_switch)
718                 {
719                         localcmd("-fire\n");
720                         localcmd("-fire2\n");
721                         button_attack2 = FALSE;
722                 }
723         }
724         if(last_activeweapon != activeweapon)
725         {
726                 last_activeweapon = activeweapon;
727
728                 e = get_weaponinfo(activeweapon);
729                 if(e.netname != "")
730                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
731                 else
732                         localcmd("\ncl_hook_activeweapon none\n");
733         }
734
735         // ALWAYS Clear Current Scene First
736         clearscene();
737 #ifdef WORKAROUND_XON010
738         if(checkextension("DP_CSQC_ROTATEMOVES"))
739         {
740 #endif
741         setproperty(VF_ORIGIN, view_origin);
742         setproperty(VF_ANGLES, view_angles);
743 #ifdef WORKAROUND_XON010
744         }
745 #endif
746
747         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
748         setproperty(VF_SIZE, vf_size);
749         setproperty(VF_MIN, vf_min);
750
751         // Assign Standard Viewflags
752         // Draw the World (and sky)
753         setproperty(VF_DRAWWORLD, 1);
754
755         // Set the console size vars
756         vid_conwidth = autocvar_vid_conwidth;
757         vid_conheight = autocvar_vid_conheight;
758         vid_pixelheight = autocvar_vid_pixelheight;
759
760         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
761         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
762
763         // Camera for demo playback
764         if(camera_active)
765         {
766                 if(autocvar_camera_enable)
767                         CSQC_Demo_Camera();
768                 else
769                 {
770                         cvar_set("chase_active", ftos(chase_active_backup));
771                         cvar_set("cl_demo_mousegrab", "0");
772                         camera_active = FALSE;
773                 }
774         }
775 #ifdef CAMERATEST
776         else if(autocvar_camera_enable)
777 #else
778         else if(autocvar_camera_enable && isdemo())
779 #endif
780         {
781                 // Enable required Darkplaces cvars
782                 chase_active_backup = autocvar_chase_active;
783                 cvar_set("chase_active", "2");
784                 cvar_set("cl_demo_mousegrab", "1");
785                 camera_active = TRUE;
786                 camera_mode = FALSE;
787         }
788
789         // Draw the Crosshair
790         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
791
792         // Draw the Engine Status Bar (the default Quake HUD)
793         setproperty(VF_DRAWENGINESBAR, 0);
794
795         // Update the mouse position
796         /*
797            mousepos_x = vid_conwidth;
798            mousepos_y = vid_conheight;
799            mousepos = mousepos*0.5 + getmousepos();
800          */
801
802         e = self;
803         for(self = world; (self = nextent(self)); )
804                 if(self.draw)
805                         self.draw();
806         self = e;
807
808         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
809         renderscene();
810
811         // now switch to 2D drawing mode by calling a 2D drawing function
812         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
813         // next R_RenderScene call
814         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
815
816         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
817         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
818         {
819                 // apply night vision effect
820                 vector tc_00, tc_01, tc_10, tc_11;
821                 vector rgb;
822                 rgb_x = 0; // fteqcc sucks
823                 rgb_y = 0; // fteqcc sucks
824                 rgb_z = 0; // fteqcc sucks
825
826                 if(!nightvision_noise)
827                 {
828                         nightvision_noise = spawn();
829                         nightvision_noise.classname = "nightvision_noise";
830                 }
831                 if(!nightvision_noise2)
832                 {
833                         nightvision_noise2 = spawn();
834                         nightvision_noise2.classname = "nightvision_noise2";
835                 }
836
837                 // color tint in yellow
838                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
839
840                 // draw BG
841                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
842                 rgb = '1 1 1';
843                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
844                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
845                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
846                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
847                 tc_11 = tc_01 + tc_10 - tc_00;
848                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
849                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
850                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
851                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
852                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
853                 R_EndPolygon();
854
855                 // draw FG
856                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
857                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
858                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
859                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
860                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
861                 tc_11 = tc_01 + tc_10 - tc_00;
862                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
863                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
864                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
865                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
866                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
867                 R_EndPolygon();
868         }
869
870         // Draw the aiming reticle for weapons that use it
871         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
872         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
873         // the view to go back to normal, so reticle_type would become 0 as we fade out)
874         if(spectatee_status || is_dead || hud != HUD_NORMAL)
875                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
876         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
877                 reticle_type = 2; // nex zoom
878         else if(button_zoom || zoomscript_caught)
879                 reticle_type = 1; // normal zoom
880         else if((activeweapon == WEP_NEX) && button_attack2)
881                 reticle_type = 2; // nex zoom
882
883         if(reticle_type && autocvar_cl_reticle)
884         {
885                 if(autocvar_cl_reticle_stretch)
886                 {
887                         reticle_size_x = vid_conwidth;
888                         reticle_size_y = vid_conheight;
889                         reticle_pos_x = 0;
890                         reticle_pos_y = 0;
891                 }
892                 else
893                 {
894                         reticle_size_x = max(vid_conwidth, vid_conheight);
895                         reticle_size_y = max(vid_conwidth, vid_conheight);
896                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
897                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
898                 }
899
900                 f = current_zoomfraction;
901                 if(zoomscript_caught)
902                         f = 1;
903                 if(autocvar_cl_reticle_item_normal)
904                 {
905                         if(reticle_type == 1 && f)
906                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
907                 }
908                 if(autocvar_cl_reticle_item_nex)
909                 {
910                         if(reticle_type == 2 && f)
911                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
912                 }
913         }
914
915
916         // improved polyblend
917         if(autocvar_hud_contents)
918         {
919                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
920                 vector liquidcolor;
921
922                 switch(pointcontents(view_origin))
923                 {
924                         case CONTENT_WATER:
925                                 liquidalpha = autocvar_hud_contents_water_alpha;
926                                 liquidcolor = stov(autocvar_hud_contents_water_color);
927                                 incontent = 1;
928                                 break;
929
930                         case CONTENT_LAVA:
931                                 liquidalpha = autocvar_hud_contents_lava_alpha;
932                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
933                                 incontent = 1;
934                                 break;
935
936                         case CONTENT_SLIME:
937                                 liquidalpha = autocvar_hud_contents_slime_alpha;
938                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
939                                 incontent = 1;
940                                 break;
941
942                         default:
943                                 liquidalpha = 0;
944                                 liquidcolor = '0 0 0';
945                                 incontent = 0;
946                                 break;
947                 }
948
949                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
950                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
951                         contentfadetime = autocvar_hud_contents_fadeintime;
952                         liquidalpha_prev = liquidalpha;
953                         liquidcolor_prev = liquidcolor;
954                 }
955                 else
956                         contentfadetime = autocvar_hud_contents_fadeouttime;
957
958                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
959                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
960
961                 if(contentavgalpha)
962                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
963
964                 if(autocvar_hud_postprocessing)
965                 {
966                         if(autocvar_hud_contents_blur && contentavgalpha)
967                         {
968                                 content_blurpostprocess_x = 1;
969                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
970                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
971                         }
972                         else
973                         {
974                                 content_blurpostprocess_x = 0;
975                                 content_blurpostprocess_y = 0;
976                                 content_blurpostprocess_z = 0;
977                         }
978                 }
979         }
980
981         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
982         {
983                 splash_size_x = max(vid_conwidth, vid_conheight);
984                 splash_size_y = max(vid_conwidth, vid_conheight);
985                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
986                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
987
988                 float myhealth_flash_temp;
989                 myhealth = getstati(STAT_HEALTH);
990
991                 // fade out
992                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
993                 // add new damage
994                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
995
996                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
997                 pain_threshold = autocvar_hud_damage_pain_threshold;
998                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
999                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1000
1001                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1002                 {
1003                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1004                 }
1005
1006                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1007
1008                 if(myhealth_prev < 1)
1009                 {
1010                         if(myhealth >= 1)
1011                         {
1012                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1013                                 myhealth_flash_temp = 0;
1014                         }
1015                         else
1016                         {
1017                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1018                         }
1019                 }
1020
1021                 if(spectatee_status == -1 || intermission)
1022                 {
1023                         myhealth_flash = 0; // observing, or match ended
1024                         myhealth_flash_temp = 0;
1025                 }
1026
1027                 myhealth_prev = myhealth;
1028
1029                 // IDEA: change damage color/picture based on player model for robot/alien species?
1030                 // pro: matches model better
1031                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1032                 // maybe different reddish pics?
1033                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1034                 {
1035                         if(autocvar_cl_gentle_damage == 2)
1036                         {
1037                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1038                                 {
1039                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1040                                 }
1041                         }
1042                         else
1043                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1044
1045                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1046                 }
1047                 else
1048                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1049
1050                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1051                 {
1052                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1053                         {
1054                                 damage_blurpostprocess_x = 1;
1055                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1056                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1057                         }
1058                         else
1059                         {
1060                                 damage_blurpostprocess_x = 0;
1061                                 damage_blurpostprocess_y = 0;
1062                                 damage_blurpostprocess_z = 0;
1063                         }
1064                 }
1065         }
1066
1067         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1068         float e2 = (autocvar_hud_powerup != 0);
1069         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1070         {
1071                 // enable or disable rendering types if they are used or not
1072                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1073                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1074
1075                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1076                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1077                 {
1078                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1079                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1080                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1081                         {
1082                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1083                                 old_blurradius = blurradius;
1084                                 old_bluralpha = bluralpha;
1085                         }
1086                 }
1087                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1088                 {
1089                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1090                         old_blurradius = 0;
1091                         old_bluralpha = 0;
1092                 }
1093
1094                 // edge detection postprocess handling done second (used by hud_powerup)
1095                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1096                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1097                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1098
1099                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1100
1101                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1102                 {
1103                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1104                         {
1105                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1106                                 old_sharpen_intensity = sharpen_intensity;
1107                         }
1108                 }
1109                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1110                 {
1111                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1112                         old_sharpen_intensity = 0;
1113                 }
1114
1115                 if(cvar("r_glsl_postprocess") == 0)
1116                         cvar_set("r_glsl_postprocess", "2");
1117         }
1118         else if(cvar("r_glsl_postprocess") == 2)
1119                 cvar_set("r_glsl_postprocess", "0");
1120
1121         if(menu_visible)
1122                 menu_show();
1123
1124         /*if(gametype == MAPINFO_TYPE_CTF)
1125           {
1126           ctf_view();
1127           } else */
1128
1129         // draw 2D entities
1130         e = self;
1131         for(self = world; (self = nextent(self)); )
1132                 if(self.draw2d)
1133                         self.draw2d();
1134         self = e;
1135         Draw_ShowNames_All();
1136
1137         scoreboard_active = HUD_WouldDrawScoreboard();
1138
1139         hit_time = getstatf(STAT_HIT_TIME);
1140         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1141         {
1142                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1143                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1144
1145                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1146         }
1147         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1148         if(typehit_time > nextsound_typehit_time)
1149         {
1150                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1151                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1152
1153                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1154         }
1155
1156         //else
1157         {
1158                 if(getstati(STAT_FROZEN))
1159                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1160                 else if (getstatf(STAT_HEALING_ORB)>time)
1161                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1162                 if(!intermission)
1163                 if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1164                 {
1165                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1166                         drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1167                 }
1168                 else if(getstatf(STAT_REVIVE_PROGRESS))
1169                 {
1170                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1171                         drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1172                 }
1173
1174                 if(autocvar_r_letterbox == 0)
1175                         if(autocvar_viewsize < 120)
1176                                 CSQC_common_hud();
1177
1178                 // crosshair goes VERY LAST
1179                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1180                 {
1181                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1182                                 return;
1183
1184                         string wcross_style;
1185                         float wcross_alpha, wcross_resolution;
1186                         wcross_style = autocvar_crosshair;
1187                         if (wcross_style == "0")
1188                                 return;
1189                         wcross_resolution = autocvar_crosshair_size;
1190                         if (wcross_resolution == 0)
1191                                 return;
1192                         wcross_alpha = autocvar_crosshair_alpha;
1193                         if (wcross_alpha == 0)
1194                                 return;
1195
1196                         // TrueAim check
1197                         float shottype;
1198
1199                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1200                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1201                         wcross_origin_z = 0;
1202                         
1203                         if(
1204                                 autocvar_crosshair_hittest
1205                                 &&
1206                                 (
1207                                         autocvar_crosshair_hittest_blur
1208                                         ||
1209                                         autocvar_crosshair_hittest_scale
1210                                         ||
1211                                         autocvar_crosshair_hittest_showimpact
1212                                 )
1213                         )
1214                         {
1215                                 vector wcross_oldorigin;
1216                                 wcross_oldorigin = wcross_origin;
1217                                 shottype = TrueAimCheck();
1218                                 if(shottype == SHOTTYPE_HITWORLD)
1219                                 {
1220                                         v = wcross_origin - wcross_oldorigin;
1221                                         v_x /= vid_conwidth;
1222                                         v_y /= vid_conheight;
1223                                         if(vlen(v) > 0.01)
1224                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1225                                 }
1226                                 if(!autocvar_crosshair_hittest_showimpact)
1227                                         wcross_origin = wcross_oldorigin;
1228                         }
1229                         else { shottype = SHOTTYPE_HITWORLD; }
1230
1231                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1232                         string wcross_wep = "", wcross_name;
1233                         float wcross_scale, wcross_blur;
1234
1235                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1236                         {
1237                                 e = get_weaponinfo(switchingweapon);
1238                                 if (e && e.netname != "")
1239                                 {
1240                                         wcross_wep = e.netname;
1241                                         if(autocvar_crosshair_per_weapon)
1242                                         {
1243                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1244                                                 if (wcross_resolution == 0)
1245                                                         return;
1246                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1247                                                 if (wcross_alpha == 0)
1248                                                         return;
1249
1250                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1251                                                 if(wcross_style == "" || wcross_style == "0")
1252                                                         wcross_style = wcross_wep;
1253                                         }
1254                                 }
1255                         }
1256
1257                         //printf("crosshair style: %s\n", wcross_style);
1258                         wcross_name = strcat("gfx/crosshair", wcross_style);
1259
1260                         // MAIN CROSSHAIR COLOR DECISION
1261                         switch(autocvar_crosshair_color_special)
1262                         {
1263                                 case 1: // crosshair_color_per_weapon
1264                                 {
1265                                         if(wcross_wep != "")
1266                                         {
1267                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1268                                                 break;
1269                                         }
1270                                         else { goto normalcolor; }
1271                                 }
1272
1273                                 case 2: // crosshair_color_by_health
1274                                 {
1275                                         float x = getstati(STAT_HEALTH);
1276
1277                                         //x = red
1278                                         //y = green
1279                                         //z = blue
1280
1281                                         wcross_color_z = 0;
1282
1283                                         if(x > 200)
1284                                         {
1285                                                 wcross_color_x = 0;
1286                                                 wcross_color_y = 1;
1287                                         }
1288                                         else if(x > 150)
1289                                         {
1290                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1291                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1292                                         }
1293                                         else if(x > 100)
1294                                         {
1295                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1296                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1297                                                 wcross_color_z = 1 - (x-100)*0.02;
1298                                         }
1299                                         else if(x > 50)
1300                                         {
1301                                                 wcross_color_x = 1;
1302                                                 wcross_color_y = 1;
1303                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1304                                         }
1305                                         else if(x > 20)
1306                                         {
1307                                                 wcross_color_x = 1;
1308                                                 wcross_color_y = (x-20)*90/27/100;
1309                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1310                                         }
1311                                         else
1312                                         {
1313                                                 wcross_color_x = 1;
1314                                                 wcross_color_y = 0;
1315                                         }
1316                                         break;
1317                                 }
1318
1319                                 case 3: // crosshair_color_rainbow
1320                                 {
1321                                         if(time >= rainbow_last_flicker)
1322                                         {
1323                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1324                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1325                                         }
1326                                         wcross_color = rainbow_prev_color;
1327                                         break;
1328                                 }
1329                                 :normalcolor
1330                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1331                         }
1332
1333                         if(autocvar_crosshair_effect_scalefade)
1334                         {
1335                                 wcross_scale = wcross_resolution;
1336                                 wcross_resolution = 1;
1337                         }
1338                         else
1339                         {
1340                                 wcross_scale = 1;
1341                         }
1342
1343                         if(autocvar_crosshair_pickup)
1344                         {
1345                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1346
1347                                 if(pickup_crosshair_time < stat_pickup_time)
1348                                 {
1349                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1350                                                 pickup_crosshair_size = 1;
1351
1352                                         pickup_crosshair_time = stat_pickup_time;
1353                                 }
1354
1355                                 if(pickup_crosshair_size > 0)
1356                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1357                                 else
1358                                         pickup_crosshair_size = 0;
1359
1360                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1361                         }
1362
1363                         if(autocvar_crosshair_hitindication)
1364                         {
1365                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1366
1367                                 if(hitindication_crosshair_time < hit_time)
1368                                 {
1369                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1370                                                 hitindication_crosshair_size = 1;
1371
1372                                         hitindication_crosshair_time = hit_time;
1373                                 }
1374
1375                                 if(hitindication_crosshair_size > 0)
1376                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1377                                 else
1378                                         hitindication_crosshair_size = 0;
1379
1380                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1381                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1382                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1383                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1384                         }
1385
1386                         if(shottype == SHOTTYPE_HITENEMY)
1387                                 wcross_scale *= autocvar_crosshair_hittest_scale; // is not queried if hittest is 0
1388                         if(shottype == SHOTTYPE_HITTEAM)
1389                                 wcross_scale /= autocvar_crosshair_hittest_scale; // is not queried if hittest is 0
1390
1391                         f = fabs(autocvar_crosshair_effect_time);
1392                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1393                         {
1394                                 wcross_changedonetime = time + f;
1395                         }
1396                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1397                         {
1398                                 wcross_name_changestarttime = time;
1399                                 wcross_name_changedonetime = time + f;
1400                                 if(wcross_name_goal_prev_prev)
1401                                         strunzone(wcross_name_goal_prev_prev);
1402                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1403                                 wcross_name_goal_prev = strzone(wcross_name);
1404                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1405                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1406                                 wcross_resolution_goal_prev = wcross_resolution;
1407                         }
1408
1409                         wcross_scale_goal_prev = wcross_scale;
1410                         wcross_alpha_goal_prev = wcross_alpha;
1411                         wcross_color_goal_prev = wcross_color;
1412
1413                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1414                         {
1415                                 wcross_blur = 1;
1416                                 wcross_alpha *= 0.75;
1417                         }
1418                         else
1419                                 wcross_blur = 0;
1420                         // *_prev is at time-frametime
1421                         // * is at wcross_changedonetime+f
1422                         // what do we have at time?
1423                         if(time < wcross_changedonetime)
1424                         {
1425                                 f = frametime / (wcross_changedonetime - time + frametime);
1426                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1427                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1428                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1429                         }
1430
1431                         wcross_scale_prev = wcross_scale;
1432                         wcross_alpha_prev = wcross_alpha;
1433                         wcross_color_prev = wcross_color;
1434
1435                         wcross_scale *= 1 - autocvar__menu_alpha;
1436                         wcross_alpha *= 1 - autocvar__menu_alpha;
1437                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1438
1439                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1440                         {
1441                                 // crosshair rings for weapon stats
1442                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1443                                 {
1444                                         // declarations and stats
1445                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1446                                         string ring_image = string_null, ring_inner_image = string_null;
1447                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1448
1449                                         ring_scale = autocvar_crosshair_ring_size;
1450
1451                                         float weapon_clipload, weapon_clipsize;
1452                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1453                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1454
1455                                         float nex_charge, nex_chargepool;
1456                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1457                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1458
1459                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1460                                                 nex_charge_movingavg = nex_charge;
1461
1462
1463                                         // handle the values
1464                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1465                                         {
1466                                                 if (nex_chargepool || use_nex_chargepool) {
1467                                                         use_nex_chargepool = 1;
1468                                                         ring_inner_value = nex_chargepool;
1469                                                 } else {
1470                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1471                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1472                                                 }
1473
1474                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1475                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1476                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1477
1478                                                 // draw the outer ring to show the current charge of the weapon
1479                                                 ring_value = nex_charge;
1480                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1481                                                 ring_rgb = wcross_color;
1482                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1483                                         }
1484                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1485                                         {
1486                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1487                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1488                                                 ring_rgb = wcross_color;
1489                                                 ring_image = "gfx/crosshair_ring.tga";
1490                                         }
1491                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1492                                         {
1493                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1494                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1495                                                 ring_rgb = wcross_color;
1496                                                 ring_image = "gfx/crosshair_ring.tga";
1497                                         }
1498
1499                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1500                                         {
1501                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1502                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1503                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1504                                                 ring_rgb = wcross_color;
1505
1506                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1507                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1508                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1509                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1510                                                 else
1511                                                         ring_image = "gfx/crosshair_ring.tga";
1512                                         }
1513
1514                                         // if in weapon switch animation, fade ring out/in
1515                                         if(autocvar_crosshair_effect_time > 0)
1516                                         {
1517                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1518                                                 if (!(f < 1))
1519                                                 {
1520                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1521                                                 }
1522
1523                                                 if(wcross_ring_prev)
1524                                                 {
1525                                                         if(f < 1)
1526                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1527                                                 }
1528                                                 else
1529                                                 {
1530                                                         if(f < 1)
1531                                                                 ring_alpha *= bound(0, f, 1);
1532                                                 }
1533                                         }
1534
1535                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1536                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1537
1538                                         if (ring_value)
1539                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1540                                 }
1541
1542 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1543                                 do \
1544                                 { \
1545                                         if(wcross_blur > 0) \
1546                                         { \
1547                                                 for(i = -2; i <= 2; ++i) \
1548                                                 for(j = -2; j <= 2; ++j) \
1549                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1550                                         } \
1551                                         else \
1552                                         { \
1553                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1554                                         } \
1555                                 } \
1556                                 while(0)
1557
1558 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1559                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1560
1561 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1562                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1563
1564                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1565                                 {
1566                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1567                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1568                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1569                                         f = 1 - f;
1570                                 }
1571                                 else
1572                                 {
1573                                         f = 1;
1574                                 }
1575                                 wcross_name_alpha_goal_prev = f;
1576
1577                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1578                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1579
1580                                 if(autocvar_crosshair_dot)
1581                                 {
1582                                         vector wcross_color_old;
1583                                         wcross_color_old = wcross_color;
1584
1585                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1586                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1587
1588                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1589                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1590                                         wcross_color = wcross_color_old;
1591                                 }
1592                         }
1593                 }
1594                 else
1595                 {
1596                         wcross_scale_prev = 0;
1597                         wcross_alpha_prev = 0;
1598                         wcross_scale_goal_prev = 0;
1599                         wcross_alpha_goal_prev = 0;
1600                         wcross_changedonetime = 0;
1601                         if(wcross_name_goal_prev)
1602                                 strunzone(wcross_name_goal_prev);
1603                         wcross_name_goal_prev = string_null;
1604                         if(wcross_name_goal_prev_prev)
1605                                 strunzone(wcross_name_goal_prev_prev);
1606                         wcross_name_goal_prev_prev = string_null;
1607                         wcross_name_changestarttime = 0;
1608                         wcross_name_changedonetime = 0;
1609                         wcross_name_alpha_goal_prev = 0;
1610                         wcross_name_alpha_goal_prev_prev = 0;
1611                         wcross_resolution_goal_prev = 0;
1612                         wcross_resolution_goal_prev_prev = 0;
1613                 }
1614         }
1615
1616         if(NextFrameCommand)
1617         {
1618                 localcmd("\n", NextFrameCommand, "\n");
1619                 NextFrameCommand = string_null;
1620         }
1621
1622         // we must do this check AFTER a frame was rendered, or it won't work
1623         if(cs_project_is_b0rked == 0)
1624         {
1625                 string w0, h0;
1626                 w0 = ftos(autocvar_vid_conwidth);
1627                 h0 = ftos(autocvar_vid_conheight);
1628                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1629                 //setproperty(VF_FOV, '90 90 0');
1630                 setproperty(VF_ORIGIN, '0 0 0');
1631                 setproperty(VF_ANGLES, '0 0 0');
1632                 setproperty(VF_PERSPECTIVE, 1);
1633                 makevectors('0 0 0');
1634                 vector v1, v2;
1635                 cvar_set("vid_conwidth", "800");
1636                 cvar_set("vid_conheight", "600");
1637                 v1 = cs_project(v_forward);
1638                 cvar_set("vid_conwidth", "640");
1639                 cvar_set("vid_conheight", "480");
1640                 v2 = cs_project(v_forward);
1641                 if(v1 == v2)
1642                         cs_project_is_b0rked = 1;
1643                 else
1644                         cs_project_is_b0rked = -1;
1645                 cvar_set("vid_conwidth", w0);
1646                 cvar_set("vid_conheight", h0);
1647         }
1648
1649         if(autocvar__hud_configure)
1650                 HUD_Panel_Mouse();
1651
1652     if(hud && !intermission)
1653     {
1654         if(hud == HUD_SPIDERBOT)
1655             CSQC_SPIDER_HUD();
1656         else if(hud == HUD_WAKIZASHI)
1657             CSQC_WAKIZASHI_HUD();
1658         else if(hud == HUD_RAPTOR)
1659             CSQC_RAPTOR_HUD();
1660         else if(hud == HUD_BUMBLEBEE)
1661             CSQC_BUMBLE_HUD();
1662         else if(hud == HUD_BUMBLEBEE_GUN)
1663             CSQC_BUMBLE_GUN_HUD();
1664     }
1665
1666         cl_notice_run();
1667
1668         // let's reset the view back to normal for the end
1669         setproperty(VF_MIN, '0 0 0');
1670         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1671 }
1672
1673
1674 void CSQC_common_hud(void)
1675 {
1676         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1677                 Accuracy_LoadLevels();
1678
1679         HUD_Main(); // always run these functions for alpha checks
1680         HUD_DrawScoreboard();
1681
1682         if (scoreboard_active) // scoreboard/accuracy
1683                 HUD_Reset();
1684         else if (intermission == 2) // map voting screen
1685         {
1686                 MapVote_Draw();
1687                 HUD_Reset();
1688         }
1689 }
1690
1691
1692 // following vectors must be global to allow seamless switching between camera modes
1693 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1694 void CSQC_Demo_Camera()
1695 {
1696         float speed, attenuation, dimensions;
1697         vector tmp, delta;
1698
1699         if( autocvar_camera_reset || !camera_mode )
1700         {
1701                 camera_offset = '0 0 0';
1702                 current_angles = '0 0 0';
1703                 camera_direction = '0 0 0';
1704                 camera_offset_z += 30;
1705                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1706                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1707                 current_origin = view_origin;
1708                 current_camera_offset  = camera_offset;
1709                 cvar_set("camera_reset", "0");
1710                 camera_mode = CAMERA_CHASE;
1711         }
1712
1713         // Camera angles
1714         if( camera_roll )
1715                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1716
1717         if(autocvar_camera_look_player)
1718         {
1719                 vector dir;
1720                 float n;
1721
1722                 dir = normalize(view_origin - current_position);
1723                 n = mouse_angles_z;
1724                 mouse_angles = vectoangles(dir);
1725                 mouse_angles_x = mouse_angles_x * -1;
1726                 mouse_angles_z = n;
1727         }
1728         else
1729         {
1730                 tmp = getmousepos() * 0.1;
1731                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1732                 {
1733                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1734                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1735                 }
1736         }
1737
1738         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1739         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1740         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1741         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1742
1743         // Fix difference when angles don't have the same sign
1744         delta = '0 0 0';
1745         if(mouse_angles_y < -60 && current_angles_y > 60)
1746                 delta = '0 360 0';
1747         if(mouse_angles_y > 60 && current_angles_y < -60)
1748                 delta = '0 -360 0';
1749
1750         if(autocvar_camera_look_player)
1751                 attenuation = autocvar_camera_look_attenuation;
1752         else
1753                 attenuation = autocvar_camera_speed_attenuation;
1754
1755         attenuation = 1 / max(1, attenuation);
1756         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1757
1758         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1759         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1760         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1761         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1762
1763         // Camera position
1764         tmp = '0 0 0';
1765         dimensions = 0;
1766
1767         if( camera_direction_x )
1768         {
1769                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1770                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1771                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1772                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1773                 ++dimensions;
1774         }
1775
1776         if( camera_direction_y )
1777         {
1778                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1779                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1780                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1781                 ++dimensions;
1782         }
1783
1784         if( camera_direction_z )
1785         {
1786                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1787                 ++dimensions;
1788         }
1789
1790         if(autocvar_camera_free)
1791                 speed = autocvar_camera_speed_free;
1792         else
1793                 speed = autocvar_camera_speed_chase;
1794
1795         if(dimensions)
1796         {
1797                 speed = speed * sqrt(1 / dimensions);
1798                 camera_offset += tmp * speed;
1799         }
1800
1801         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1802
1803         // Camera modes
1804         if( autocvar_camera_free )
1805         {
1806                 if ( camera_mode == CAMERA_CHASE )
1807                 {
1808                         current_camera_offset = current_origin + current_camera_offset;
1809                         camera_offset = current_origin + camera_offset;
1810                 }
1811
1812                 camera_mode = CAMERA_FREE;
1813                 current_position = current_camera_offset;
1814         }
1815         else
1816         {
1817                 if ( camera_mode == CAMERA_FREE )
1818                 {
1819                         current_origin = view_origin;
1820                         camera_offset = camera_offset - current_origin;
1821                         current_camera_offset = current_camera_offset - current_origin;
1822                 }
1823
1824                 camera_mode = CAMERA_CHASE;
1825
1826                 if(autocvar_camera_chase_smoothly)
1827                         current_origin += (view_origin - current_origin) * attenuation;
1828                 else
1829                         current_origin = view_origin;
1830
1831                 current_position = current_origin + current_camera_offset;
1832         }
1833
1834         setproperty(VF_ANGLES, current_angles);
1835         setproperty(VF_ORIGIN, current_position);
1836 }