minelayer model with placeholder texture
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / View.qc
1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
2 #define spider_rocket_targ "gfx/vehicles/target.tga"
3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
4 #define rkt_size 32
5 #define rld_size_x 256
6 #define rld_size_y 16
7
8 void CSQC_WAKIZASHI_HUD();
9
10 entity porto;
11 vector polyline[16];
12 float trace_dphitcontents;
13 float trace_networkentity;
14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
15 float DPCONTENTS_SOLID = 1; // blocks player movement
16 float DPCONTENTS_BODY = 32; // blocks player movement
17 float DPCONTENTS_CORPSE = 64; // blocks player movement
18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
19 void Porto_Draw()
20 {
21         vector p, dir, ang, q, nextdir;
22         float idx, portal_number, portal1_idx;
23
24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
25                 return;
26         if(intermission == 1)
27                 return;
28         if(intermission == 2)
29                 return;
30         if (getstati(STAT_HEALTH) <= 0)
31                 return;
32
33         dir = view_forward;
34
35         if(angles_held_status)
36         {
37                 makevectors(angles_held);
38                 dir = v_forward;
39         }
40
41         p = view_origin;
42
43         polyline[0] = p;
44         idx = 1;
45         portal_number = 0;
46         nextdir = dir;
47
48         for(;;)
49         {
50                 dir = nextdir;
51                 traceline(p, p + 65536 * dir, TRUE, porto);
52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
53                         return;
54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
55                 p = trace_endpos;
56                 polyline[idx] = p;
57                 ++idx;
58                 if(idx >= 16)
59                         return;
60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
61                         continue;
62                 ++portal_number;
63                 ang = vectoangles2(trace_plane_normal, dir);
64                 ang_x = -ang_x;
65                 makevectors(ang);
66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
67                         return;
68                 if(portal_number == 1)
69                         portal1_idx = idx;
70                 if(portal_number >= 2)
71                         break;
72         }
73
74         while(idx >= 2)
75         {
76                 p = polyline[idx-2];
77                 q = polyline[idx-1];
78                 if(idx == 2)
79                         p = p - view_up * 16;
80                 if(idx-1 >= portal1_idx)
81                 {
82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
83                 }
84                 else
85                 {
86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
87                 }
88                 --idx;
89         }
90 }
91
92 /**
93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
94  *
95  * TODO: Use a better solution where a common shared entitiy is used that contains
96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
97  * and STAT_FRAGLIMIT to be auto-sent)
98  */
99 void CheckForGamestartChange() {
100         float startTime;
101         startTime = getstatf(STAT_GAMESTARTTIME);
102         if (previous_game_starttime != startTime) {
103                 if ((time + 5.0) < startTime) {
104                         //if connecting to server while restart was active don't always play prepareforbattle
105                         sound(world, CHAN_AUTO, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
106                 }
107                 if (time < startTime) {
108                         restartAnnouncer = spawn();
109                         restartAnnouncer.think = restartAnnouncer_Think;
110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
111                 }
112         }
113         previous_game_starttime = startTime;
114 }
115
116 void Porto_Init()
117 {
118         porto = spawn();
119         porto.classname = "porto";
120         porto.draw = Porto_Draw;
121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
122 }
123
124 float drawtime;
125 float avgspeed;
126 vector GetCurrentFov(float fov)
127 {
128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
129
130         zoomsensitivity = cvar("cl_zoomsensitivity");
131         zoomfactor = cvar("cl_zoomfactor");
132         if(zoomfactor < 1 || zoomfactor > 16)
133                 zoomfactor = 2.5;
134         zoomspeed = cvar("cl_zoomspeed");
135         if(zoomspeed >= 0)
136                 if(zoomspeed < 0.5 || zoomspeed > 16)
137                         zoomspeed = 3.5;
138
139         zoomdir = button_zoom;
140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
141                 zoomdir += button_attack2;
142         if(spectatee_status > 0 || isdemo())
143         {
144                 if(spectatorbutton_zoom)
145                         zoomdir = 0 + !zoomdir;
146                 // do not even THINK about removing this 0
147                 // _I_ know what I am doing
148                 // fteqcc does not
149         }
150
151         if(zoomdir)
152                 zoomin_effect = 0;
153
154         if(zoomin_effect || camera_active)
155         {
156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
157         }
158         else
159         {
160                 if(zoomspeed < 0) // instant zoom
161                 {
162                         if(zoomdir)
163                                 current_viewzoom = 1 / zoomfactor;
164                         else
165                                 current_viewzoom = 1;
166                 }
167                 else
168                 {
169                         if(zoomdir)
170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
171                         else
172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
173                 }
174         }
175
176         if(almost_equals(current_viewzoom, 1))
177                 current_zoomfraction = 0;
178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
179                 current_zoomfraction = 1;
180         else
181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
182
183         if(zoomsensitivity < 1)
184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
185         else
186                 setsensitivityscale(1);
187
188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
191
192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
193
194         float frustumx, frustumy, fovx, fovy;
195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
199
200         return '1 0 0' * fovx + '0 1 0' * fovy;
201 }
202
203 // this function must match W_SetupShot!
204 float zoomscript_caught;
205
206 vector wcross_origin;
207 float wcross_scale_prev, wcross_alpha_prev;
208 vector wcross_color_prev;
209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
210 vector wcross_color_goal_prev;
211 float wcross_changedonetime;
212
213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
215 float wcross_name_changestarttime, wcross_name_changedonetime;
216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
217 entity trueaim;
218 entity trueaim_rifle;
219
220 #define SHOTTYPE_HITTEAM 1
221 #define SHOTTYPE_HITOBSTRUCTION 2
222 #define SHOTTYPE_HITWORLD 3
223 #define SHOTTYPE_HITENEMY 4
224
225 void TrueAim_Init()
226 {
227         trueaim = spawn();
228         trueaim.classname = "trueaim";
229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
230         trueaim_rifle = spawn();
231         trueaim_rifle.classname = "trueaim_rifle";
232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
233 }
234
235 float EnemyHitCheck()
236 {
237         float t;
238         wcross_origin = project_3d_to_2d(trace_endpos);
239         wcross_origin_z = 0;
240         if(trace_networkentity < 1)
241                 return SHOTTYPE_HITWORLD;
242         if(trace_networkentity > maxclients)
243                 return SHOTTYPE_HITWORLD;
244         t = GetPlayerColor(trace_networkentity - 1);
245         if(teamplay)
246                 if(t == myteam)
247                         return SHOTTYPE_HITTEAM;
248         if(t == COLOR_SPECTATOR)
249                 return SHOTTYPE_HITWORLD;
250         return SHOTTYPE_HITENEMY;
251 }
252
253 float TrueAimCheck()
254 {
255         float nudge = 1; // added to traceline target and subtracted from result
256         vector vecs, trueaimpoint, w_shotorg;
257         vector mi, ma, dv;
258         float shottype;
259         entity ta;
260         float mv;
261
262         mi = ma = '0 0 0';
263         ta = trueaim;
264         mv = MOVE_NOMONSTERS;
265
266         switch(activeweapon)
267         {
268                 case WEP_TUBA: // no aim
269                 case WEP_PORTO: // shoots from eye
270                 case WEP_HOOK: // no trueaim
271                 case WEP_GRENADE_LAUNCHER: // toss curve
272                         return SHOTTYPE_HITWORLD;
273                 case WEP_NEX:
274                 case WEP_MINSTANEX:
275                         mv = MOVE_NORMAL;
276                         break;
277                 case WEP_CAMPINGRIFLE:
278                         ta = trueaim_rifle;
279                         mv = MOVE_NORMAL;
280                         if(zoomscript_caught)
281                         {
282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
283                                 return EnemyHitCheck();
284                         }
285                         break;
286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
287                         mi = '-3 -3 -3';
288                         ma = '3 3 3';
289                         break;
290                 case WEP_FIREBALL: // projectile has a size!
291                         mi = '-16 -16 -16';
292                         ma = '16 16 16';
293                         break;
294                 case WEP_SEEKER: // projectile has a size!
295                         mi = '-2 -2 -2';
296                         ma = '2 2 2';
297                         break;
298                 case WEP_ELECTRO: // projectile has a size!
299                         mi = '0 0 -3';
300                         ma = '0 0 -3';
301                         break;
302         }
303
304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
305
306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
307         trueaimpoint = trace_endpos;
308
309         if(vecs_x > 0)
310                 vecs_y = -vecs_y;
311         else
312                 vecs = '0 0 0';
313
314         dv = view_right * vecs_y + view_up * vecs_z;
315         w_shotorg = view_origin + dv;
316
317         // now move the vecs forward as much as requested if possible
318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
319         w_shotorg = trace_endpos - view_forward * nudge;
320
321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
322         shottype = EnemyHitCheck();
323         if(shottype != SHOTTYPE_HITWORLD)
324                 return shottype;
325
326 #if 0
327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
328         // or rather, I know why, but see no fix
329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
331                 return SHOTTYPE_HITOBSTRUCTION;
332 #endif
333
334         return SHOTTYPE_HITWORLD;
335 }
336
337 void CSQC_common_hud(void);
338
339 void PostInit(void);
340 void CSQC_Demo_Camera();
341 float HUD_WouldDrawScoreboard();
342 float view_set;
343 float camera_mode;
344 float reticle_type;
345 string NextFrameCommand;
346 void CSQC_SPIDER_HUD();
347 void CSQC_RAPTOR_HUD();
348
349 vector freeze_pmove_org, freeze_input_angles;
350 entity nightvision_noise, nightvision_noise2;
351
352 float pickup_crosshair_time, pickup_crosshair_size;
353 float use_nex_charge_pool;
354
355 float myhealth, myhealth_prev;
356 float myhealth_flash;
357
358 vector myhealth_gentlergb;
359
360 void CSQC_UpdateView(float w, float h)
361 {
362         entity e;
363         float fov;
364         float f, i, j;
365         vector v, vo;
366         vector vf_size, vf_min;
367         float a;
368
369         vf_size = R_SetView3fv(VF_SIZE);
370         vf_min = R_SetView3fv(VF_MIN);
371         vid_width = vf_size_x;
372         vid_height = vf_size_y;
373
374         vector reticle_pos, reticle_size;
375
376         WaypointSprite_Load();
377
378         if(spectatee_status)
379                 myteam = GetPlayerColor(spectatee_status - 1);
380         else
381                 myteam = GetPlayerColor(player_localentnum - 1);
382
383         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
384         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
385
386         warpzone_fixview_origin = pmove_org + vo;
387         warpzone_fixview_cl_viewangles = input_angles;
388         warpzone_fixview_angles = view_angles;
389         WarpZone_FixView();
390         pmove_org = warpzone_fixview_origin - vo;
391         input_angles = warpzone_fixview_cl_viewangles;
392         view_angles = warpzone_fixview_angles;
393
394         if(cvar("cl_lockview") || (autocvar__hud_configure && spectatee_status <= 0))
395         {
396                 pmove_org = freeze_pmove_org;
397                 input_angles = view_angles = freeze_input_angles;
398                 R_SetView(VF_ORIGIN, pmove_org + vo);
399                 R_SetView(VF_ANGLES, view_angles);
400                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
401         }
402         freeze_pmove_org = pmove_org;
403         freeze_input_angles = input_angles;
404
405         // Render the Scene
406         if(!intermission || !view_set)
407         {
408                 view_origin = pmove_org + vo;
409                 view_angles = input_angles;
410                 makevectors(view_angles);
411                 view_forward = v_forward;
412                 view_right = v_right;
413                 view_up = v_up;
414                 view_set = 1;
415         }
416
417 #ifdef BLURTEST
418         if(time > blurtest_time0 && time < blurtest_time1)
419         {
420                 float r, t;
421
422                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
423                 r = t * blurtest_radius;
424                 f = 1 / pow(t, blurtest_power) - 1;
425
426                 cvar_set("r_glsl_postprocess", "1");
427                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
428         }
429         else
430         {
431                 cvar_set("r_glsl_postprocess", "0");
432                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
433         }
434 #endif
435
436         TargetMusic_Advance();
437         Fog_Force();
438
439         drawframetime = max(0.000001, time - drawtime);
440         drawtime = time;
441
442         // watch for gametype changes here...
443         // in ParseStuffCMD the cmd isn't executed yet :/
444         // might even be better to add the gametype to TE_CSQC_INIT...?
445         if(!postinit)
446                 PostInit();
447
448         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
449                 if(calledhooks & HOOK_START)
450                 {
451                         localcmd("\ncl_hook_gameend\n");
452                         calledhooks |= HOOK_END;
453                 }
454
455         CheckForGamestartChange();
456         serverAnnouncer();
457         maptimeAnnouncer();
458         carrierAnnouncer();
459
460         fov = cvar("fov");
461         if(button_zoom || fov <= 59.5)
462         {
463                 if(!zoomscript_caught)
464                 {
465                         localcmd("+button4\n");
466                         zoomscript_caught = 1;
467                         ignore_plus_zoom += 1;
468                 }
469         }
470         else
471         {
472                 if(zoomscript_caught)
473                 {
474                         localcmd("-button4\n");
475                         zoomscript_caught = 0;
476                         ignore_minus_zoom += 1;
477                 }
478         }
479
480         ColorTranslateMode = cvar("cl_stripcolorcodes");
481         activeweapon = getstati(STAT_SWITCHWEAPON);
482         f = cvar("teamplay");
483         if(f != teamplay)
484         {
485                 teamplay = f;
486                 HUD_InitScores();
487         }
488
489         if(last_weapon != activeweapon) {
490                 weapontime = time;
491                 last_weapon = activeweapon;
492
493                 e = get_weaponinfo(activeweapon);
494                 if(e.netname != "")
495                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
496                 else
497                         localcmd("\ncl_hook_activeweapon none\n");
498         }
499
500         // ALWAYS Clear Current Scene First
501         R_ClearScene();
502
503         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
504         R_SetView(VF_SIZE, vf_size);
505         R_SetView(VF_MIN, vf_min);
506
507         // Assign Standard Viewflags
508         // Draw the World (and sky)
509         R_SetView(VF_DRAWWORLD, 1);
510
511         // Set the console size vars
512         vid_conwidth = cvar("vid_conwidth");
513         vid_conheight = cvar("vid_conheight");
514         vid_pixelheight = cvar("vid_pixelheight");
515
516         R_SetView(VF_FOV, GetCurrentFov(fov));
517
518         // Camera for demo playback
519         if(camera_active)
520         {
521                 if(cvar("camera_enable"))
522                         CSQC_Demo_Camera();
523                 else
524                 {
525                         cvar_set("chase_active", ftos(chase_active_backup));
526                         cvar_set("cl_demo_mousegrab", "0");
527                         camera_active = FALSE;
528                 }
529         }
530 #ifdef CAMERATEST
531         else if(cvar("camera_enable"))
532 #else
533         else if(cvar("camera_enable") && isdemo())
534 #endif
535         {
536                 // Enable required Darkplaces cvars
537                 chase_active_backup = cvar("chase_active");
538                 cvar_set("chase_active", "2");
539                 cvar_set("cl_demo_mousegrab", "1");
540                 camera_active = TRUE;
541                 camera_mode = FALSE;
542         }
543
544         // Draw the Crosshair
545         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
546
547         // Draw the Engine Status Bar (the default Quake HUD)
548         R_SetView(VF_DRAWENGINEHUD, 0);
549
550         // fetch this one only once per frame
551         hud_showbinds = cvar("hud_showbinds");
552         hud_showbinds_limit = cvar("hud_showbinds_limit");
553
554         // Update the mouse position
555         /*
556            mousepos_x = vid_conwidth;
557            mousepos_y = vid_conheight;
558            mousepos = mousepos*0.5 + getmousepos();
559          */
560
561         e = self;
562         for(self = world; (self = nextent(self)); )
563                 if(self.draw)
564                         self.draw();
565         self = e;
566
567         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
568         R_RenderScene();
569
570         // now switch to 2D drawing mode by calling a 2D drawing function
571         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
572         // next R_RenderScene call
573         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
574
575         if(cvar("r_fakelight") >= 2 || cvar("r_fullbright") >= 1)
576         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
577         {
578                 // apply night vision effect
579                 vector rgb, tc_00, tc_01, tc_10, tc_11;
580
581                 if(!nightvision_noise)
582                 {
583                         nightvision_noise = spawn();
584                         nightvision_noise.classname = "nightvision_noise";
585                 }
586                 if(!nightvision_noise2)
587                 {
588                         nightvision_noise2 = spawn();
589                         nightvision_noise2.classname = "nightvision_noise2";
590                 }
591
592                 // color tint in yellow
593                 drawfill('0 0 0', cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
594
595                 // draw BG
596                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
597                 rgb = '1 1 1';
598                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
599                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
600                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
601                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
602                 tc_11 = tc_01 + tc_10 - tc_00;
603                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
604                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
605                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
606                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
607                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
608                 R_EndPolygon();
609
610                 // draw FG
611                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
612                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
613                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
614                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
615                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
616                 tc_11 = tc_01 + tc_10 - tc_00;
617                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
618                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
619                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
620                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
621                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
622                 R_EndPolygon();
623         }
624
625         // Draw the aiming reticle for weapons that use it
626         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
627         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
628         // the view to go back to normal, so reticle_type would become 0 as we fade out)
629         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
630                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
631         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_CAMPINGRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
632                 reticle_type = 2; // nex zoom
633         else if(button_zoom || zoomscript_caught)
634                 reticle_type = 1; // normal zoom
635         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
636                 reticle_type = 2; // nex zoom
637
638         if(cvar("cl_reticle_stretch"))
639         {
640                 reticle_size_x = vid_conwidth;
641                 reticle_size_y = vid_conheight;
642                 reticle_pos_x = 0;
643                 reticle_pos_y = 0;
644         }
645         else
646         {
647                 reticle_size_x = max(vid_conwidth, vid_conheight);
648                 reticle_size_y = max(vid_conwidth, vid_conheight);
649                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
650                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
651         }
652
653         f = current_zoomfraction;
654         if(zoomscript_caught)
655                 f = 1;
656         if(cvar("cl_reticle_item_normal"))
657         {
658                 precache_pic("gfx/reticle_normal");
659                 if(reticle_type == 1 && f)
660                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
661         }
662         if(cvar("cl_reticle_item_nex"))
663         {
664                 precache_pic("gfx/reticle_nex");
665                 if(reticle_type == 2 && f)
666                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
667         }
668
669         // improved polyblend
670         vector rgb;
671         if(cvar("hud_damage"))
672         {
673                 float myhealth_flash_temp;
674                 myhealth = getstati(STAT_HEALTH);
675
676                 // fade out
677                 myhealth_flash = max(0, myhealth_flash - cvar("hud_damage_fade_rate") * frametime);
678                 // add new damage
679                 myhealth_flash = bound(0, myhealth_flash + max(0, myhealth_prev - myhealth) * cvar("hud_damage_factor"), cvar("hud_damage_maxalpha"));
680
681                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
682                 pain_threshold = cvar("hud_damage_pain_threshold");
683                 pain_threshold_lower = cvar("hud_damage_pain_threshold_lower");
684                 pain_threshold_lower_health = cvar("hud_damage_pain_threshold_lower_health");
685
686                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
687                 {
688                         pain_threshold = pain_threshold - max(cvar("hud_damage_pain_threshold_pulsating_min"), fabs(sin(M_PI * time / cvar("hud_damage_pain_threshold_pulsating_period")))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
689                 }
690
691                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
692
693                 if(myhealth_prev < 1)
694                 {
695                         if(myhealth >= 1)
696                         {
697                                 myhealth_flash = 0; // just spawned, clear the flash immediately
698                                 myhealth_flash_temp = 0;
699                         }
700                         else
701                         {
702                                 myhealth_flash += cvar("hud_damage_fade_rate") * frametime; // dead
703                         }
704                 }
705
706                 if(spectatee_status == -1 || intermission)
707                 {
708                         myhealth_flash = 0; // observing, or match ended
709                         myhealth_flash_temp = 0;
710                 }
711
712                 myhealth_prev = myhealth;
713
714                 if(autocvar_cl_gentle_damage || cvar("cl_gentle"))
715                 {
716                         if(autocvar_cl_gentle_damage == 2)
717                         {
718                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
719                                 {
720                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
721                                 }
722                         }
723                         else
724                                 myhealth_gentlergb = stov(cvar_string("hud_damage_gentle_color"));
725
726                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, cvar("hud_damage_gentle_alpha_multiplier") * bound(0, myhealth_flash_temp, 1), DRAWFLAG_NORMAL);
727                 }
728                 else
729                         drawpic(reticle_pos, "gfx/blood", reticle_size, stov(cvar_string("hud_damage_color")), bound(0, myhealth_flash_temp, 1), DRAWFLAG_NORMAL);
730         }
731
732         // Draw the mouse cursor
733         // NOTE: drawpic must happen after R_RenderScene for some reason
734         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
735         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
736         //self = edict_num(player_localnum);
737         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
738         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
739         // as long as the ctf part isn't in, this is useless
740         if(menu_visible)
741                 menu_show();
742
743         /*if(gametype == GAME_CTF)
744           {
745           ctf_view();
746           } else */
747
748         // draw 2D entities
749         e = self;
750         for(self = world; (self = nextent(self)); )
751                 if(self.draw2d)
752                         self.draw2d();
753         self = e;
754
755         scoreboard_active = HUD_WouldDrawScoreboard();
756
757         float hud;
758         hud = getstati(STAT_HUD);
759         if(hud == HUD_SPIDERBOT)
760                 CSQC_SPIDER_HUD();
761         else if(hud == HUD_WAKIZASHI)
762         CSQC_WAKIZASHI_HUD();
763     else if(hud == HUD_RAPTOR)
764         CSQC_RAPTOR_HUD();
765         else
766         {
767                 if(cvar("r_letterbox") == 0)
768                         if(cvar("viewsize") < 120)
769                                 CSQC_common_hud();
770
771                 // crosshair goes VERY LAST
772                 if(!scoreboard_active && !camera_active && intermission != 2) {
773                         string wcross_style;
774                         float wcross_alpha, wcross_resolution;
775                         wcross_style = cvar_string("crosshair");
776                         if (wcross_style == "0")
777                                 return;
778                         wcross_resolution = cvar("crosshair_size");
779                         if (wcross_resolution == 0)
780                                 return;
781                         wcross_alpha = cvar("crosshair_alpha");
782                         if (wcross_alpha == 0)
783                                 return;
784
785                         // TrueAim check
786                         float shottype;
787                         float bullets, ring_scale;
788                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
789                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
790                         wcross_origin_z = 0;
791                         if(cvar("crosshair_hittest"))
792                         {
793                                 vector wcross_oldorigin;
794                                 wcross_oldorigin = wcross_origin;
795                                 shottype = TrueAimCheck();
796                                 if(shottype == SHOTTYPE_HITWORLD)
797                                 {
798                                         v = wcross_origin - wcross_oldorigin;
799                                         v_x /= vid_conwidth;
800                                         v_y /= vid_conheight;
801                                         if(vlen(v) > 0.01)
802                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
803                                 }
804                                 if(!cvar("crosshair_hittest_showimpact"))
805                                         wcross_origin = wcross_oldorigin;
806                         }
807                         else
808                                 shottype = SHOTTYPE_HITWORLD;
809
810                         vector wcross_color, wcross_size;
811                         string wcross_wep, wcross_name;
812                         float wcross_scale, wcross_blur;
813
814                         if (cvar("crosshair_per_weapon") || cvar("crosshair_color_per_weapon")) {
815                                 e = get_weaponinfo(activeweapon);
816                                 if (e && e.netname != "")
817                                 {
818                                         wcross_wep = e.netname;
819                                         if(cvar("crosshair_per_weapon"))
820                                         {
821                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
822                                                 if (wcross_resolution == 0)
823                                                         return;
824                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
825                                                 if (wcross_alpha == 0)
826                                                         return;
827
828                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
829                                                 if(wcross_style == "" || wcross_style == "0")
830                                                         wcross_style = wcross_wep;
831                                         }
832                                 }
833                         }
834                         if(wcross_wep != "" && cvar("crosshair_color_per_weapon"))
835                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
836                         else
837                                 wcross_color = stov(cvar_string("crosshair_color"));
838
839                         wcross_name = strcat("gfx/crosshair", wcross_style);
840
841                         if(cvar("crosshair_effect_scalefade"))
842                         {
843                                 wcross_scale = wcross_resolution;
844                                 wcross_resolution = 1;
845                         }
846                         else
847                         {
848                                 wcross_scale = 1;
849                         }
850
851                         if(cvar("crosshair_pickup"))
852                         {
853                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
854                                 {
855                                         pickup_crosshair_size = 1;
856                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
857                                 }
858
859                                 if(pickup_crosshair_size > 0)
860                                         pickup_crosshair_size -= cvar("crosshair_pickup_speed") * frametime;
861                                 else
862                                         pickup_crosshair_size = 0;
863
864                                 wcross_scale += sin(pickup_crosshair_size) * cvar("crosshair_pickup");
865                         }
866
867                         if(shottype == SHOTTYPE_HITENEMY)
868                                 wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
869                         if(shottype == SHOTTYPE_HITTEAM)
870                                 wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
871
872                         f = cvar("crosshair_effect_speed");
873                         if(f < 0)
874                                 f *= -2 * g_weaponswitchdelay;
875                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
876                         {
877                                 wcross_changedonetime = time + f;
878                         }
879                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
880                         {
881                                 wcross_name_changestarttime = time;
882                                 wcross_name_changedonetime = time + f;
883                                 if(wcross_name_goal_prev_prev)
884                                         strunzone(wcross_name_goal_prev_prev);
885                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
886                                 wcross_name_goal_prev = strzone(wcross_name);
887                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
888                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
889                                 wcross_resolution_goal_prev = wcross_resolution;
890                         }
891
892                         wcross_scale_goal_prev = wcross_scale;
893                         wcross_alpha_goal_prev = wcross_alpha;
894                         wcross_color_goal_prev = wcross_color;
895
896                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
897                         {
898                                 wcross_blur = 1;
899                                 wcross_alpha *= 0.75;
900                         }
901                         else
902                                 wcross_blur = 0;
903                         // *_prev is at time-frametime
904                         // * is at wcross_changedonetime+f
905                         // what do we have at time?
906                         if(time < wcross_changedonetime)
907                         {
908                                 f = frametime / (wcross_changedonetime - time + frametime);
909                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
910                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
911                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
912                         }
913
914                         wcross_scale_prev = wcross_scale;
915                         wcross_alpha_prev = wcross_alpha;
916                         wcross_color_prev = wcross_color;
917
918                         wcross_scale *= 1 - cvar("_menu_alpha");
919                         wcross_alpha *= 1 - cvar("_menu_alpha");
920
921                         ring_scale = cvar("crosshair_ring_size");
922
923                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
924
925                         float nex_charge, nex_charge_pool;
926                         nex_charge = getstatf(STAT_NEX_CHARGE);
927                         nex_charge_pool = getstatf(STAT_NEX_CHARGEPOOL);
928
929                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
930                                 nex_charge_movingavg = nex_charge;
931
932                         // ring around crosshair representing bullets left in camping rifle clip
933                         if (activeweapon == WEP_CAMPINGRIFLE && cr_maxbullets)
934                         {
935                                 bullets = getstati(STAT_BULLETS_LOADED);
936                                 f = bound(0, bullets / cr_maxbullets, 1);
937
938                                 a = cvar("crosshair_ring_campingrifle_alpha");
939                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
940                         }
941                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
942                         {
943                                 if(nex_charge_pool || use_nex_charge_pool)
944                                 {
945                                         use_nex_charge_pool = 1;
946
947                                         a = cvar("crosshair_ring_nex_inner_alpha");
948                                         rgb = eX * cvar("crosshair_ring_nex_inner_color_red") + eY * cvar("crosshair_ring_nex_inner_color_green") + eZ * cvar("crosshair_ring_nex_inner_color_blue");
949                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", nex_charge_pool, rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
950                                 }
951                                 else
952                                 {
953                                         // indicate how much we're charging right now with an inner circle
954                                         a = cvar("crosshair_ring_nex_inner_alpha");
955                                         nex_charge_movingavg = (1 - cvar("crosshair_ring_nex_currentcharge_movingavg_rate")) * nex_charge_movingavg + cvar("crosshair_ring_nex_currentcharge_movingavg_rate") * nex_charge;
956
957                                         rgb = eX * cvar("crosshair_ring_nex_inner_color_red") + eY * cvar("crosshair_ring_nex_inner_color_green") + eZ * cvar("crosshair_ring_nex_inner_color_blue");
958                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, cvar("crosshair_ring_nex_currentcharge_scale") * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
959                                 }
960
961                                 // draw the charge
962                                 a = cvar("crosshair_ring_nex_outer_alpha");
963                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
964                         }
965
966 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
967                         do \
968                         { \
969                                 if(wcross_blur > 0) \
970                                 { \
971                                         for(i = -2; i <= 2; ++i) \
972                                                 for(j = -2; j <= 2; ++j) \
973                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
974                                 } \
975                                 else \
976                                 { \
977                                         M(0,0,sz,wcross_name,wcross_alpha); \
978                                 } \
979                         } \
980                         while(0)
981
982 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
983                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
984
985 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
986                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
987
988                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
989                         {
990                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
991                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
992                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
993                                 f = 1 - f;
994                         }
995                         else
996                         {
997                                 f = 1;
998                         }
999
1000                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1001                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1002
1003                         if(cvar("crosshair_dot"))
1004                                 CROSSHAIR_DRAW(wcross_resolution * cvar("crosshair_dot_size"), "gfx/crosshairdot.tga", wcross_alpha * f * cvar("crosshair_dot_alpha"));
1005
1006                         wcross_name_alpha_goal_prev = f;
1007                 }
1008                 else
1009                 {
1010                         wcross_scale_prev = 0;
1011                         wcross_alpha_prev = 0;
1012                         wcross_scale_goal_prev = 0;
1013                         wcross_alpha_goal_prev = 0;
1014                         wcross_changedonetime = 0;
1015                         if(wcross_name_goal_prev)
1016                                 strunzone(wcross_name_goal_prev);
1017                         wcross_name_goal_prev = string_null;
1018                         if(wcross_name_goal_prev_prev)
1019                                 strunzone(wcross_name_goal_prev_prev);
1020                         wcross_name_goal_prev_prev = string_null;
1021                         wcross_name_changestarttime = 0;
1022                         wcross_name_changedonetime = 0;
1023                         wcross_name_alpha_goal_prev = 0;
1024                         wcross_name_alpha_goal_prev_prev = 0;
1025                         wcross_resolution_goal_prev = 0;
1026                         wcross_resolution_goal_prev_prev = 0;
1027                 }
1028         }
1029
1030         if(NextFrameCommand)
1031         {
1032                 localcmd("\n", NextFrameCommand, "\n");
1033                 NextFrameCommand = string_null;
1034         }
1035
1036         // we must do this check AFTER a frame was rendered, or it won't work
1037         if(cs_project_is_b0rked == 0)
1038         {
1039                 string w0, h0;
1040                 w0 = cvar_string("vid_conwidth");
1041                 h0 = cvar_string("vid_conheight");
1042                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1043                 //R_SetView(VF_FOV, '90 90 0');
1044                 R_SetView(VF_ORIGIN, '0 0 0');
1045                 R_SetView(VF_ANGLES, '0 0 0');
1046                 R_SetView(VF_PERSPECTIVE, 1);
1047                 makevectors('0 0 0');
1048                 vector v1, v2;
1049                 cvar_set("vid_conwidth", "800");
1050                 cvar_set("vid_conheight", "600");
1051                 v1 = cs_project(v_forward);
1052                 cvar_set("vid_conwidth", "640");
1053                 cvar_set("vid_conheight", "480");
1054                 v2 = cs_project(v_forward);
1055                 if(v1 == v2)
1056                         cs_project_is_b0rked = 1;
1057                 else
1058                         cs_project_is_b0rked = -1;
1059                 cvar_set("vid_conwidth", w0);
1060                 cvar_set("vid_conheight", h0);
1061         }
1062
1063         if(autocvar__hud_configure)
1064                 HUD_Panel_Mouse();
1065
1066         // let's reset the view back to normal for the end
1067         R_SetView(VF_MIN, '0 0 0');
1068         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1069 }
1070
1071 #define spider_h "gfx/vehicles/hud_bg.tga"
1072 #define spider_b "gfx/vehicles/sbot.tga"
1073 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1074 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1075 #define spider_s "gfx/vehicles/shiled.tga"
1076 #define spider_a1 "gfx/hud/sb_rocket.tga"
1077 #define spider_a2 "gfx/sb_bullets.tga"
1078
1079 void CSQC_SPIDER_HUD()
1080 {
1081         float rockets, reload, heat, hp, shield;
1082         vector picsize, hudloc;
1083
1084     // Fetch health & ammo stats
1085     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1086         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1087         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1088         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1089         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1090
1091     // Draw the crosshairs
1092     picsize = drawgetimagesize(SPIDER_CROSS);
1093     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1094     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1095     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1096
1097     hudloc_y =  4;
1098     hudloc_x = 4;
1099
1100     picsize = drawgetimagesize(spider_h) * 0.5;
1101     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1102
1103     picsize = drawgetimagesize(spider_a2) * 0.5;
1104     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1105
1106     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1107     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1108     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1109
1110     picsize = drawgetimagesize(spider_a1) * 0.85;
1111     if(rockets == 9)
1112     {
1113         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1114         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1115     }
1116     else
1117     {
1118         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1119         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1120     }
1121
1122     picsize = drawgetimagesize(spider_b) * 0.5;
1123     hudloc_y = 10.5;
1124     hudloc_x = 10.5;
1125
1126     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1127     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1128     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1129     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1130
1131
1132         /*
1133         // Draw health bar
1134         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1135         p = p + '0 1 0' * vid_conheight - '0 32 0';
1136         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1137         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1138         p_y += 8;
1139         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1140         p_x += 256 * hp;
1141         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1142
1143         // Draw minigun heat indicator
1144         p = '0.5 0 0' * (vid_conwidth - 256);
1145         p = p + '0 1 0' * vid_conheight - '0 34  0';
1146         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1147         p_x += 256 * (1-heat);
1148         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1149
1150
1151         // Draw rocket icons for loaded/empty tubes.
1152         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1153         pp += '0 1 0' * vid_conheight - '0 64 0';
1154         for(i = 0; i < 8; ++i)
1155         {
1156                 p = pp + '1 0 0' * (rkt_size * i);
1157                 if(rockets == 8)
1158                 {
1159                         if(floor(reload * 8) == i)
1160                         {
1161                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1162                         }
1163                         else if(i < reload * 8)
1164                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1165                         else
1166                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1167                 }
1168                 else
1169                 {
1170                         if(i < rockets)
1171                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1172                         else
1173                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1174                 }
1175         }
1176         */
1177
1178         if (scoreboard_showscores)
1179         {
1180                 HUD_DrawScoreboard();
1181                 HUD_DrawCenterPrint();
1182         }
1183
1184 }
1185
1186 #define raptor_h "gfx/vehicles/hud_bg.tga"
1187 #define raptor_b "gfx/vehicles/raptor.tga"
1188 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1189 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1190 #define raptor_s "gfx/vehicles/shiled.tga"
1191
1192 void CSQC_RAPTOR_HUD()
1193 {
1194         float reload, hp, shield, energy;
1195         vector picsize, hudloc;
1196
1197     // Fetch health & ammo stats
1198     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1199         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1200         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1201         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1202
1203     // Draw the crosshairs
1204     picsize = drawgetimagesize(SPIDER_CROSS);
1205     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1206     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1207     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1208
1209     hudloc_y =  4;
1210     hudloc_x = 4;
1211
1212     picsize = drawgetimagesize(raptor_h) * 0.5;
1213     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1214
1215     picsize = drawgetimagesize(spider_a2) * 0.5;
1216     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1217
1218     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1219     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1220     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1221
1222
1223     picsize = drawgetimagesize(spider_a1) * 0.85;
1224     if(reload == 1)
1225     {
1226         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1227         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1228     }
1229     else
1230     {
1231         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1232         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1233     }
1234
1235     picsize = drawgetimagesize(raptor_b) * 0.5;
1236     hudloc_y = 10.5;
1237     hudloc_x = 10.5;
1238
1239     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1240     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1241     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1242     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1243
1244
1245         if (scoreboard_showscores)
1246         {
1247                 HUD_DrawScoreboard();
1248                 HUD_DrawCenterPrint();
1249         }
1250
1251 }
1252
1253 #define waki_h "gfx/vehicles/hud_bg.tga"
1254 #define waki_b "gfx/vehicles/waki.tga"
1255 #define waki_e "gfx/vehicles/waki_e.tga"
1256 #define waki_g "gfx/vehicles/waki_guns.tga"
1257 #define waki_r "gfx/vehicles/waki_rockets.tga"
1258 #define waki_s "gfx/vehicles/shiled.tga"
1259
1260 #define waki_a1 "gfx/hud/sb_rocket.tga"
1261 #define waki_a2 "gfx/sb_cells.tga"
1262
1263 void CSQC_WAKIZASHI_HUD()
1264 {
1265         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1266         float health, shield, energy, rockets;
1267         vector picsize, hudloc;
1268
1269     picsize = drawgetimagesize(SPIDER_CROSS);
1270     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1271     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1272     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1273
1274 /*
1275 const float STAT_VEHICLESTAT_HEALTH  = 60;
1276 const float STAT_VEHICLESTAT_SHIELD  = 61;
1277 const float STAT_VEHICLESTAT_ENERGY  = 62;
1278 const float STAT_VEHICLESTAT_AMMO1   = 63;
1279 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1280 const float STAT_VEHICLESTAT_AMMO2   = 65;
1281 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1282 */
1283     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1284         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1285         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1286         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1287
1288     hudloc_y =  4;
1289     hudloc_x = 4;
1290
1291     picsize = drawgetimagesize(waki_h) * 0.5;
1292     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1293
1294     picsize = drawgetimagesize(waki_a2) * 0.7;
1295     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1296
1297
1298     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1299     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1300
1301     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1302
1303     picsize = drawgetimagesize(waki_a1) * 0.75;
1304     if(rockets == 1)
1305     {
1306         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1307         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1308     }
1309     else
1310     {
1311         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1312         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1313         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1314     }
1315
1316     picsize = drawgetimagesize(waki_b) * 0.5;
1317     hudloc_y = 10.5;
1318     hudloc_x = 10.5;
1319
1320     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1321     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1322     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1323     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1324
1325
1326
1327         /*
1328         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1329         p = p + '0 1 0' * vid_conheight - '0 32 0';
1330
1331         // Draw health bar
1332         p_y += 8;
1333         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1334         p_x += 256 * health;
1335         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1336
1337         // Draw shiled bar
1338         p_x -= 256 * health;
1339         p_y += 4;
1340         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1341
1342         // Draw energy
1343         //p_x -= 256 * health;
1344         p_y -= 8;
1345         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1346
1347         // Draw rockets bar
1348         p_y += 12;
1349         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1350         */
1351
1352
1353
1354
1355         if (scoreboard_showscores)
1356         {
1357                 HUD_DrawScoreboard();
1358                 HUD_DrawCenterPrint();
1359         }
1360
1361 }
1362
1363
1364 void CSQC_common_hud(void)
1365 {
1366         // HUD_SortFrags(); done in HUD_Draw
1367         float hud;
1368         hud = getstati(STAT_HUD);
1369
1370         //hud = 10;
1371         switch(hud)
1372         {
1373                 case HUD_NORMAL:
1374                         // do some accuracy var caching
1375                         float i;
1376                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1377                         {
1378                                 if(cvar_string("accuracy_color_levels") != acc_color_levels)
1379                                 {
1380                                         if(acc_color_levels)
1381                                                 strunzone(acc_color_levels);
1382                                         acc_color_levels = strzone(cvar_string("accuracy_color_levels"));
1383                                         acc_levels = tokenize(acc_color_levels);
1384                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1385                                                 acc_levels = MAX_ACCURACY_LEVELS;
1386
1387                                         for (i = 0; i < acc_levels; ++i)
1388                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1389                                 }
1390                                 // let know that acc_col[] needs to be loaded
1391                                 acc_col_x[0] = -1;
1392                         }
1393
1394                         HUD_Main(); // always run these functions for alpha checks
1395                         HUD_DrawScoreboard();
1396
1397                         if (scoreboard_active) // scoreboard/accuracy
1398                         {       
1399                                 HUD_Reset();
1400                                 // HUD_DrawScoreboard takes care of centerprint_start
1401                         }
1402                         else if (intermission == 2) // map voting screen
1403                         {
1404                                 HUD_FinaleOverlay();
1405                                 HUD_Reset();
1406
1407                                 centerprint_start_x = 0;
1408                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1409                         }
1410                         else // hud
1411                         {
1412                                 centerprint_start_x = 0;
1413                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1414                         }
1415
1416                         HUD_DrawCenterPrint();
1417                         break;
1418
1419                 case HUD_SPIDERBOT:
1420                         CSQC_SPIDER_HUD();
1421                         break;
1422
1423                 case HUD_WAKIZASHI:
1424                         CSQC_WAKIZASHI_HUD();
1425                         break;
1426         }
1427 }
1428
1429
1430 // following vectors must be global to allow seamless switching between camera modes
1431 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1432 void CSQC_Demo_Camera()
1433 {
1434         float speed, attenuation, dimensions;
1435         vector tmp, delta;
1436
1437         if( cvar("camera_reset") || !camera_mode )
1438         {
1439                 camera_offset = '0 0 0';
1440                 current_angles = '0 0 0';
1441                 camera_direction = '0 0 0';
1442                 camera_offset_z += 30;
1443                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1444                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1445                 current_origin = view_origin;
1446                 current_camera_offset  = camera_offset;
1447                 cvar_set("camera_reset", "0");
1448                 camera_mode = CAMERA_CHASE;
1449         }
1450
1451         // Camera angles
1452         if( camera_roll )
1453                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1454
1455         if(cvar("camera_look_player"))
1456         {
1457                 local vector dir;
1458                 local float n;
1459
1460                 dir = normalize(view_origin - current_position);
1461                 n = mouse_angles_z;
1462                 mouse_angles = vectoangles(dir);
1463                 mouse_angles_x = mouse_angles_x * -1;
1464                 mouse_angles_z = n;
1465         }
1466         else
1467         {
1468                 tmp = getmousepos() * 0.1;
1469                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1470                 {
1471                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1472                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1473                 }
1474         }
1475
1476         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1477         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1478         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1479         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1480
1481         // Fix difference when angles don't have the same sign
1482         delta = '0 0 0';
1483         if(mouse_angles_y < -60 && current_angles_y > 60)
1484                 delta = '0 360 0';
1485         if(mouse_angles_y > 60 && current_angles_y < -60)
1486                 delta = '0 -360 0';
1487
1488         if(cvar("camera_look_player"))
1489                 attenuation = cvar("camera_look_attenuation");
1490         else
1491                 attenuation = cvar("camera_speed_attenuation");
1492
1493         attenuation = 1 / max(1, attenuation);
1494         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1495
1496         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1497         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1498         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1499         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1500
1501         // Camera position
1502         tmp = '0 0 0';
1503         dimensions = 0;
1504
1505         if( camera_direction_x )
1506         {
1507                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1508                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1509                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1510                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1511                 ++dimensions;
1512         }
1513
1514         if( camera_direction_y )
1515         {
1516                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1517                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1518                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1519                 ++dimensions;
1520         }
1521
1522         if( camera_direction_z )
1523         {
1524                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1525                 ++dimensions;
1526         }
1527
1528         if(cvar("camera_free"))
1529                 speed = cvar("camera_speed_free");
1530         else
1531                 speed = cvar("camera_speed_chase");
1532
1533         if(dimensions)
1534         {
1535                 speed = speed * sqrt(1 / dimensions);
1536                 camera_offset += tmp * speed;
1537         }
1538
1539         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1540
1541         // Camera modes
1542         if( cvar("camera_free") )
1543         {
1544                 if ( camera_mode == CAMERA_CHASE )
1545                 {
1546                         current_camera_offset = current_origin + current_camera_offset;
1547                         camera_offset = current_origin + camera_offset;
1548                 }
1549
1550                 camera_mode = CAMERA_FREE;
1551                 current_position = current_camera_offset;
1552         }
1553         else
1554         {
1555                 if ( camera_mode == CAMERA_FREE )
1556                 {
1557                         current_origin = view_origin;
1558                         camera_offset = camera_offset - current_origin;
1559                         current_camera_offset = current_camera_offset - current_origin;
1560                 }
1561
1562                 camera_mode = CAMERA_CHASE;
1563
1564                 if(cvar("camera_chase_smoothly"))
1565                         current_origin += (view_origin - current_origin) * attenuation;
1566                 else
1567                         current_origin = view_origin;
1568
1569                 current_position = current_origin + current_camera_offset;
1570         }
1571
1572         R_SetView(VF_ANGLES, current_angles);
1573         R_SetView(VF_ORIGIN, current_position);
1574 }