fix warnings
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / View.qc
1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
2 #define spider_rocket_targ "gfx/vehicles/target.tga"
3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
4 #define rkt_size 32
5 #define rld_size_x 256
6 #define rld_size_y 16
7
8 void CSQC_WAKIZASHI_HUD();
9
10 entity porto;
11 vector polyline[16];
12 float trace_dphitcontents;
13 float trace_networkentity;
14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
15 float DPCONTENTS_SOLID = 1; // blocks player movement
16 float DPCONTENTS_BODY = 32; // blocks player movement
17 float DPCONTENTS_CORPSE = 64; // blocks player movement
18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
19 void Porto_Draw()
20 {
21         vector p, dir, ang, q, nextdir;
22         float idx, portal_number, portal1_idx;
23
24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
25                 return;
26         if(intermission == 1)
27                 return;
28         if(intermission == 2)
29                 return;
30         if (getstati(STAT_HEALTH) <= 0)
31                 return;
32
33         dir = view_forward;
34
35         if(angles_held_status)
36         {
37                 makevectors(angles_held);
38                 dir = v_forward;
39         }
40
41         p = view_origin;
42
43         polyline[0] = p;
44         idx = 1;
45         portal_number = 0;
46         nextdir = dir;
47
48         for(;;)
49         {
50                 dir = nextdir;
51                 traceline(p, p + 65536 * dir, TRUE, porto);
52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
53                         return;
54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
55                 p = trace_endpos;
56                 polyline[idx] = p;
57                 ++idx;
58                 if(idx >= 16)
59                         return;
60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
61                         continue;
62                 ++portal_number;
63                 ang = vectoangles2(trace_plane_normal, dir);
64                 ang_x = -ang_x;
65                 makevectors(ang);
66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
67                         return;
68                 if(portal_number == 1)
69                         portal1_idx = idx;
70                 if(portal_number >= 2)
71                         break;
72         }
73
74         while(idx >= 2)
75         {
76                 p = polyline[idx-2];
77                 q = polyline[idx-1];
78                 if(idx == 2)
79                         p = p - view_up * 16;
80                 if(idx-1 >= portal1_idx)
81                 {
82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
83                 }
84                 else
85                 {
86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
87                 }
88                 --idx;
89         }
90 }
91
92 /**
93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
94  *
95  * TODO: Use a better solution where a common shared entitiy is used that contains
96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
97  * and STAT_FRAGLIMIT to be auto-sent)
98  */
99 void CheckForGamestartChange() {
100         float startTime;
101         startTime = getstatf(STAT_GAMESTARTTIME);
102         if (previous_game_starttime != startTime) {
103                 if ((time + 5.0) < startTime) {
104                         //if connecting to server while restart was active don't always play prepareforbattle
105                         sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
106                 }
107                 if (time < startTime) {
108                         restartAnnouncer = spawn();
109                         restartAnnouncer.think = restartAnnouncer_Think;
110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
111                 }
112         }
113         previous_game_starttime = startTime;
114 }
115
116 void Porto_Init()
117 {
118         porto = spawn();
119         porto.classname = "porto";
120         porto.draw = Porto_Draw;
121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
122 }
123
124 float drawtime;
125 float avgspeed;
126 vector GetCurrentFov(float fov)
127 {
128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
129
130         zoomsensitivity = cvar("cl_zoomsensitivity");
131         zoomfactor = cvar("cl_zoomfactor");
132         if(zoomfactor < 1 || zoomfactor > 16)
133                 zoomfactor = 2.5;
134         zoomspeed = cvar("cl_zoomspeed");
135         if(zoomspeed >= 0)
136                 if(zoomspeed < 0.5 || zoomspeed > 16)
137                         zoomspeed = 3.5;
138
139         zoomdir = button_zoom;
140         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
141                 zoomdir += button_attack2;
142         if(spectatee_status > 0 || isdemo())
143         {
144                 if(spectatorbutton_zoom)
145                         zoomdir = 0 + !zoomdir;
146                 // do not even THINK about removing this 0
147                 // _I_ know what I am doing
148                 // fteqcc does not
149         }
150
151         if(zoomdir)
152                 zoomin_effect = 0;
153
154         if(zoomin_effect || camera_active)
155         {
156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
157         }
158         else
159         {
160                 if(zoomspeed < 0) // instant zoom
161                 {
162                         if(zoomdir)
163                                 current_viewzoom = 1 / zoomfactor;
164                         else
165                                 current_viewzoom = 1;
166                 }
167                 else
168                 {
169                         if(zoomdir)
170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
171                         else
172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
173                 }
174         }
175
176         if(almost_equals(current_viewzoom, 1))
177                 current_zoomfraction = 0;
178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
179                 current_zoomfraction = 1;
180         else
181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
182
183         if(zoomsensitivity < 1)
184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
185         else
186                 setsensitivityscale(1);
187
188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
191
192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
193
194         float frustumx, frustumy, fovx, fovy;
195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
199
200         return '1 0 0' * fovx + '0 1 0' * fovy;
201 }
202
203 // this function must match W_SetupShot!
204 float zoomscript_caught;
205
206 vector wcross_origin;
207 float wcross_scale_prev, wcross_alpha_prev;
208 vector wcross_color_prev;
209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
210 vector wcross_color_goal_prev;
211 float wcross_changedonetime;
212
213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
215 float wcross_name_changestarttime, wcross_name_changedonetime;
216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
217 entity trueaim;
218 entity trueaim_rifle;
219
220 #define SHOTTYPE_HITTEAM 1
221 #define SHOTTYPE_HITOBSTRUCTION 2
222 #define SHOTTYPE_HITWORLD 3
223 #define SHOTTYPE_HITENEMY 4
224
225 void TrueAim_Init()
226 {
227         trueaim = spawn();
228         trueaim.classname = "trueaim";
229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
230         trueaim_rifle = spawn();
231         trueaim_rifle.classname = "trueaim_rifle";
232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
233 }
234
235 float EnemyHitCheck()
236 {
237         float t;
238         wcross_origin = project_3d_to_2d(trace_endpos);
239         wcross_origin_z = 0;
240         if(trace_networkentity < 1)
241                 return SHOTTYPE_HITWORLD;
242         if(trace_networkentity > maxclients)
243                 return SHOTTYPE_HITWORLD;
244         t = GetPlayerColor(trace_networkentity - 1);
245         if(teamplay)
246                 if(t == myteam)
247                         return SHOTTYPE_HITTEAM;
248         if(t == COLOR_SPECTATOR)
249                 return SHOTTYPE_HITWORLD;
250         return SHOTTYPE_HITENEMY;
251 }
252
253 float TrueAimCheck()
254 {
255         float nudge = 1; // added to traceline target and subtracted from result
256         vector vecs, trueaimpoint, w_shotorg;
257         vector mi, ma, dv;
258         float shottype;
259         entity ta;
260         float mv;
261
262         mi = ma = '0 0 0';
263         ta = trueaim;
264         mv = MOVE_NOMONSTERS;
265
266         switch(activeweapon)
267         {
268                 case WEP_TUBA: // no aim
269                 case WEP_PORTO: // shoots from eye
270                 case WEP_HOOK: // no trueaim
271                 case WEP_GRENADE_LAUNCHER: // toss curve
272                         return SHOTTYPE_HITWORLD;
273                 case WEP_NEX:
274                 case WEP_MINSTANEX:
275                         mv = MOVE_NORMAL;
276                         break;
277                 case WEP_CAMPINGRIFLE:
278                         ta = trueaim_rifle;
279                         mv = MOVE_NORMAL;
280                         if(zoomscript_caught)
281                         {
282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
283                                 return EnemyHitCheck();
284                         }
285                         break;
286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
287                         mi = '-3 -3 -3';
288                         ma = '3 3 3';
289                         break;
290                 case WEP_FIREBALL: // projectile has a size!
291                         mi = '-16 -16 -16';
292                         ma = '16 16 16';
293                         break;
294                 case WEP_SEEKER: // projectile has a size!
295                         mi = '-2 -2 -2';
296                         ma = '2 2 2';
297                         break;
298                 case WEP_ELECTRO: // projectile has a size!
299                         mi = '0 0 -3';
300                         ma = '0 0 -3';
301                         break;
302         }
303
304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
305
306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
307         trueaimpoint = trace_endpos;
308
309         if(vecs_x > 0)
310                 vecs_y = -vecs_y;
311         else
312                 vecs = '0 0 0';
313
314         dv = view_right * vecs_y + view_up * vecs_z;
315         w_shotorg = view_origin + dv;
316
317         // now move the vecs forward as much as requested if possible
318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
319         w_shotorg = trace_endpos - view_forward * nudge;
320
321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
322         shottype = EnemyHitCheck();
323         if(shottype != SHOTTYPE_HITWORLD)
324                 return shottype;
325
326 #if 0
327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
328         // or rather, I know why, but see no fix
329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
331                 return SHOTTYPE_HITOBSTRUCTION;
332 #endif
333
334         return SHOTTYPE_HITWORLD;
335 }
336
337 void CSQC_common_hud(void);
338
339 void PostInit(void);
340 void CSQC_Demo_Camera();
341 float HUD_WouldDrawScoreboard ();
342 float view_set;
343 float camera_mode;
344 string NextFrameCommand;
345 void CSQC_SPIDER_HUD();
346 void CSQC_RAPTOR_HUD();
347
348 vector freeze_pmove_org, freeze_input_angles;
349
350 void CSQC_UpdateView(float w, float h)
351 {
352         entity e;
353         float fov;
354         float f, i, j;
355         vector v, vo;
356
357         WaypointSprite_Load();
358
359         if(spectatee_status)
360                 myteam = GetPlayerColor(spectatee_status - 1);
361         else
362                 myteam = GetPlayerColor(player_localentnum - 1);
363
364         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
365         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
366
367         warpzone_fixview_origin = pmove_org + vo;
368         warpzone_fixview_cl_viewangles = input_angles;
369         warpzone_fixview_angles = view_angles;
370         WarpZone_FixView();
371         pmove_org = warpzone_fixview_origin - vo;
372         input_angles = warpzone_fixview_cl_viewangles;
373         view_angles = warpzone_fixview_angles;
374
375         if(cvar("cl_lockview"))
376         {
377                 pmove_org = freeze_pmove_org;
378                 input_angles = view_angles = freeze_input_angles;
379                 R_SetView(VF_ORIGIN, pmove_org + vo);
380                 R_SetView(VF_ANGLES, view_angles);
381                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
382         }
383         freeze_pmove_org = pmove_org;
384         freeze_input_angles = input_angles;
385
386         // Render the Scene
387         if(!intermission || !view_set)
388         {
389                 view_origin = pmove_org + vo;
390                 view_angles = input_angles;
391                 makevectors(view_angles);
392                 view_forward = v_forward;
393                 view_right = v_right;
394                 view_up = v_up;
395                 view_set = 1;
396         }
397
398         hudconf_active = cvar("_hud_configure");
399         if(hudconf_active)
400                 R_SetView(VF_ANGLES, self.angles); // TODO: this should freeze the view as it is, not change it to '0 0 0' or whatever it currently does...
401
402         vid_width = w;
403         vid_height = h;
404
405 #ifdef BLURTEST
406         if(time > blurtest_time0 && time < blurtest_time1)
407         {
408                 float r, t;
409
410                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
411                 r = t * blurtest_radius;
412                 f = 1 / pow(t, blurtest_power) - 1;
413
414                 cvar_set("r_glsl_postprocess", "1");
415                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
416         }
417         else
418         {
419                 cvar_set("r_glsl_postprocess", "0");
420                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
421         }
422 #endif
423
424         TargetMusic_Advance();
425         Fog_Force();
426
427         drawframetime = max(0.000001, time - drawtime);
428         drawtime = time;
429
430         // watch for gametype changes here...
431         // in ParseStuffCMD the cmd isn't executed yet :/
432         // might even be better to add the gametype to TE_CSQC_INIT...?
433         if(!postinit)
434                 PostInit();
435
436         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
437                 if(calledhooks & HOOK_START)
438                 {
439                         localcmd("\ncl_hook_gameend;");
440                         calledhooks |= HOOK_END;
441                 }
442
443         CheckForGamestartChange();
444         serverAnnouncer();
445         maptimeAnnouncer();
446         carrierAnnouncer();
447
448         fov = cvar("fov");
449         if(button_zoom || fov <= 59.5)
450         {
451                 if(!zoomscript_caught)
452                 {
453                         localcmd("+button4\n");
454                         zoomscript_caught = 1;
455                         ignore_plus_zoom += 1;
456                 }
457         }
458         else
459         {
460                 if(zoomscript_caught)
461                 {
462                         localcmd("-button4\n");
463                         zoomscript_caught = 0;
464                         ignore_minus_zoom += 1;
465                 }
466         }
467
468         hud_alpha_fg = cvar_or("hud_fg_alpha", 1) * (1 - cvar("_menu_alpha"));
469         hud_accuracy_hud = cvar_or("hud_accuracy_hud", 1);
470         ColorTranslateMode = cvar("cl_stripcolorcodes");
471         activeweapon = getstati(STAT_SWITCHWEAPON);
472         f = cvar("teamplay");
473         if(f != teamplay)
474         {
475                 teamplay = f;
476                 HUD_InitScores();
477         }
478
479         if(last_weapon != activeweapon) {
480                 weapontime = time;
481                 last_weapon = activeweapon;
482         }
483
484         // ALWAYS Clear Current Scene First
485         R_ClearScene();
486
487         // Assign Standard Viewflags
488         // Draw the World (and sky)
489         R_SetView(VF_DRAWWORLD, 1);
490
491         // Set the console size vars
492         vid_conwidth = cvar("vid_conwidth");
493         vid_conheight = cvar("vid_conheight");
494         vid_pixelheight = cvar("vid_pixelheight");
495
496         R_SetView(VF_FOV, GetCurrentFov(fov));
497
498         // Camera for demo playback
499         if(camera_active)
500         {
501                 if(cvar("camera_enable"))
502                         CSQC_Demo_Camera();
503                 else
504                 {
505                         cvar_set("chase_active", ftos(chase_active_backup));
506                         cvar_set("cl_demo_mousegrab", "0");
507                         camera_active = FALSE;
508                 }
509         }
510 #ifdef CAMERATEST
511         else if(cvar("camera_enable"))
512 #else
513         else if(cvar("camera_enable") && isdemo())
514 #endif
515         {
516                 // Enable required Darkplaces cvars
517                 chase_active_backup = cvar("chase_active");
518                 cvar_set("chase_active", "2");
519                 cvar_set("cl_demo_mousegrab", "1");
520                 camera_active = TRUE;
521                 camera_mode = FALSE;
522         }
523
524         // Draw the Crosshair
525         float scoreboard_active;
526         scoreboard_active = HUD_WouldDrawScoreboard();
527         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
528
529         // Draw the Engine Status Bar (the default Quake HUD)
530         R_SetView(VF_DRAWENGINEHUD, 0);
531
532         // fetch this one only once per frame
533         hud_showbinds = cvar("hud_showbinds");
534         hud_showbinds_limit = cvar("hud_showbinds_limit");
535
536         // Update the mouse position
537         /*
538            mousepos_x = vid_conwidth;
539            mousepos_y = vid_conheight;
540            mousepos = mousepos*0.5 + getmousepos();
541          */
542
543         e = self;
544         for(self = world; (self = nextent(self)); )
545                 if(self.draw)
546                         self.draw();
547         self = e;
548
549         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
550         R_RenderScene();
551
552         // now switch to 2D drawing mode by calling a 2D drawing function
553         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
554         // next R_RenderScene call
555         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
556
557         // Draw the mouse cursor
558         // NOTE: drawpic must happen after R_RenderScene for some reason
559         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
560         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
561         //self = edict_num(player_localnum);
562         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
563         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
564         // as long as the ctf part isn't in, this is useless
565         if(menu_visible)
566                 menu_show();
567
568         /*if(gametype == GAME_CTF)
569           {
570           ctf_view();
571           } else */
572
573         // draw 2D entities
574         e = self;
575         for(self = world; (self = nextent(self)); )
576                 if(self.draw2d)
577                         self.draw2d();
578         self = e;
579
580         // draw hud
581         if(cvar("r_letterbox") == 0) {
582                 HUD_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
583         }
584
585         float hud;
586         hud = getstati(STAT_HUD);
587         if(hud == HUD_SPIDERBOT)
588         {
589                 CSQC_SPIDER_HUD();
590         }
591         else if(hud == HUD_WAKIZASHI)
592         CSQC_WAKIZASHI_HUD();
593     else if(hud == HUD_RAPTOR)
594         CSQC_RAPTOR_HUD();
595         else
596         {
597                 if(cvar("r_letterbox") == 0)
598                         if(cvar("viewsize") < 120)
599                                 CSQC_common_hud();
600
601                 // crosshair goes VERY LAST
602                 if(!scoreboard_active && !camera_active && !hudconf_active) {
603                         // TrueAim check
604                         float shottype;
605                         float bullets, ring_scale;
606                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
607                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
608                         wcross_origin_z = 0;
609                         if(cvar("crosshair_hittest"))
610                         {
611                                 vector wcross_oldorigin;
612                                 wcross_oldorigin = wcross_origin;
613                                 shottype = TrueAimCheck();
614                                 if(shottype == SHOTTYPE_HITWORLD)
615                                 {
616                                         v = wcross_origin - wcross_oldorigin;
617                                         v_x /= vid_conwidth;
618                                         v_y /= vid_conheight;
619                                         if(vlen(v) > 0.01)
620                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
621                                 }
622                                 if(!cvar("crosshair_hittest_showimpact"))
623                                         wcross_origin = wcross_oldorigin;
624                         }
625                         else
626                                 shottype = SHOTTYPE_HITWORLD;
627
628                         string wcross_style;
629                         wcross_style = cvar_string("crosshair");
630
631                         if (wcross_style != "0") {
632                                 vector wcross_color, wcross_size;
633                                 string wcross_wep, wcross_name;
634                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
635
636                                 wcross_color_x = cvar("crosshair_color_red");
637                                 wcross_color_y = cvar("crosshair_color_green");
638                                 wcross_color_z = cvar("crosshair_color_blue");
639                                 wcross_alpha = cvar("crosshair_color_alpha");
640                                 wcross_resolution = cvar("crosshair_size");
641                                 if (cvar("crosshair_per_weapon")) {
642                                         e = get_weaponinfo(activeweapon);
643                                         if (e && e.netname != "")
644                                         {
645                                                 wcross_wep = e.netname;
646                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
647                                                 if(wcross_style == "")
648                                                         wcross_style = e.netname;
649
650                                                 if(!cvar("crosshair_color_override"))
651                                                 {
652                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
653                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
654                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
655                                                 }
656
657                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
658                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
659                                         }
660                                 }
661
662                                 wcross_name = strcat("gfx/crosshair", wcross_style);
663
664                                 if(cvar("crosshair_effect_scalefade"))
665                                 {
666                                         wcross_scale = wcross_resolution;
667                                         wcross_resolution = 1;
668                                 }
669                                 else
670                                 {
671                                         wcross_scale = 1;
672                                 }
673
674                                 if(shottype == SHOTTYPE_HITENEMY)
675                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
676                                 if(shottype == SHOTTYPE_HITTEAM)
677                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
678
679                                 f = cvar("crosshair_effect_speed");
680                                 if(f < 0)
681                                         f *= -2 * g_weaponswitchdelay;
682                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
683                                 {
684                                         wcross_changedonetime = time + f;
685                                 }
686                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
687                                 {
688                                         wcross_name_changestarttime = time;
689                                         wcross_name_changedonetime = time + f;
690                                         if(wcross_name_goal_prev_prev)
691                                                 strunzone(wcross_name_goal_prev_prev);
692                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
693                                         wcross_name_goal_prev = strzone(wcross_name);
694                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
695                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
696                                         wcross_resolution_goal_prev = wcross_resolution;
697                                 }
698
699                                 wcross_scale_goal_prev = wcross_scale;
700                                 wcross_alpha_goal_prev = wcross_alpha;
701                                 wcross_color_goal_prev = wcross_color;
702
703                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
704                                 {
705                                         wcross_blur = 1;
706                                         wcross_alpha *= 0.75;
707                                 }
708                                 else
709                                         wcross_blur = 0;
710                                 // *_prev is at time-frametime
711                                 // * is at wcross_changedonetime+f
712                                 // what do we have at time?
713                                 if(time < wcross_changedonetime)
714                                 {
715                                         f = frametime / (wcross_changedonetime - time + frametime);
716                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
717                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
718                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
719                                 }
720
721                                 wcross_scale_prev = wcross_scale;
722                                 wcross_alpha_prev = wcross_alpha;
723                                 wcross_color_prev = wcross_color;
724
725                                 wcross_scale *= 1 - cvar("_menu_alpha");
726                                 wcross_alpha *= 1 - cvar("_menu_alpha");
727
728                                 // ring around crosshair representing bullets left in camping rifle clip
729                                 if (activeweapon == WEP_CAMPINGRIFLE)
730                                 {
731                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
732                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
733                                 }
734                                 else
735                                         bullets = 0;
736
737 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
738                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/hud/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
739
740 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
741                                 do \
742                                 { \
743                                         if(wcross_blur > 0) \
744                                         { \
745                                                 for(i = -2; i <= 2; ++i) \
746                                                         for(j = -2; j <= 2; ++j) \
747                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
748                                         } \
749                                         else \
750                                         { \
751                                                 M(0,0,sz,wcross_name,wcross_alpha); \
752                                         } \
753                                 } \
754                                 while(0)
755
756 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
757                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
758
759 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
760                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
761
762                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
763                                 {
764                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
765                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
766                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
767                                         f = 1 - f;
768                                 }
769                                 else
770                                 {
771                                         f = 1;
772                                 }
773
774                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
775                                 if(bullets)
776                                 {
777                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
778                                 }
779                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
780                                 wcross_name_alpha_goal_prev = f;
781                         }
782                 }
783                 else
784                 {
785                         wcross_scale_prev = 0;
786                         wcross_alpha_prev = 0;
787                         wcross_scale_goal_prev = 0;
788                         wcross_alpha_goal_prev = 0;
789                         wcross_changedonetime = 0;
790                         if(wcross_name_goal_prev)
791                                 strunzone(wcross_name_goal_prev);
792                         wcross_name_goal_prev = string_null;
793                         if(wcross_name_goal_prev_prev)
794                                 strunzone(wcross_name_goal_prev_prev);
795                         wcross_name_goal_prev_prev = string_null;
796                         wcross_name_changestarttime = 0;
797                         wcross_name_changedonetime = 0;
798                         wcross_name_alpha_goal_prev = 0;
799                         wcross_name_alpha_goal_prev_prev = 0;
800                         wcross_resolution_goal_prev = 0;
801                         wcross_resolution_goal_prev_prev = 0;
802                 }
803         }
804
805         if(NextFrameCommand)
806         {
807                 localcmd("\n", NextFrameCommand, "\n");
808                 NextFrameCommand = string_null;
809         }
810
811         // we must do this check AFTER a frame was rendered, or it won't work
812         if(cs_project_is_b0rked == 0)
813         {
814                 string w0, h0;
815                 w0 = cvar_string("vid_conwidth");
816                 h0 = cvar_string("vid_conheight");
817                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
818                 //R_SetView(VF_FOV, '90 90 0');
819                 R_SetView(VF_ORIGIN, '0 0 0');
820                 R_SetView(VF_ANGLES, '0 0 0');
821                 R_SetView(VF_PERSPECTIVE, 1);
822                 makevectors('0 0 0');
823                 vector v1, v2;
824                 cvar_set("vid_conwidth", "800");
825                 cvar_set("vid_conheight", "600");
826                 v1 = cs_project(v_forward);
827                 cvar_set("vid_conwidth", "640");
828                 cvar_set("vid_conheight", "480");
829                 v2 = cs_project(v_forward);
830                 if(v1 == v2)
831                         cs_project_is_b0rked = 1;
832                 else
833                         cs_project_is_b0rked = -1;
834                 cvar_set("vid_conwidth", w0);
835                 cvar_set("vid_conheight", h0);
836         }
837
838         if(hudconf_active)
839                 HUD_Panel_Mouse();
840         // be safe against triggerbots until everyone has the fixed engine
841         // this call is meant to overwrite the trace globals by something
842         // unsuspicious
843         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
844 }
845
846 #define spider_h "gfx/vehicles/hud_bg.tga"
847 #define spider_b "gfx/vehicles/sbot.tga"
848 #define spider_r "gfx/vehicles/sbot_rpods.tga"
849 #define spider_g "gfx/vehicles/sbot_mguns.tga"
850 #define spider_s "gfx/vehicles/shiled.tga"
851 #define spider_a1 "gfx/hud/sb_rocket.tga"
852 #define spider_a2 "gfx/sb_bullets.tga"
853
854 void CSQC_SPIDER_HUD()
855 {
856         float rockets, reload, heat, hp, shield;
857         vector picsize, hudloc;
858
859     // Fetch health & ammo stats
860     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
861         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
862         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
863         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
864         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
865
866     // Draw the crosshairs
867     picsize = drawgetimagesize(SPIDER_CROSS);
868     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
869     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
870     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
871
872     hudloc_y =  4;
873     hudloc_x = 4;
874
875     picsize = drawgetimagesize(spider_h) * 0.5;
876     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
877
878     picsize = drawgetimagesize(spider_a2) * 0.5;
879     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
880
881     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
882     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
883     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
884
885     picsize = drawgetimagesize(spider_a1) * 0.85;
886     if(rockets == 9)
887     {
888         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
889         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
890     }
891     else
892     {
893         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
894         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
895     }
896
897     picsize = drawgetimagesize(spider_b) * 0.5;
898     hudloc_y = 10.5;
899     hudloc_x = 10.5;
900
901     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
902     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
903     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
904     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
905
906
907         /*
908         // Draw health bar
909         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
910         p = p + '0 1 0' * vid_conheight - '0 32 0';
911         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
912         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
913         p_y += 8;
914         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
915         p_x += 256 * hp;
916         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
917
918         // Draw minigun heat indicator
919         p = '0.5 0 0' * (vid_conwidth - 256);
920         p = p + '0 1 0' * vid_conheight - '0 34  0';
921         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
922         p_x += 256 * (1-heat);
923         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
924
925
926         // Draw rocket icons for loaded/empty tubes.
927         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
928         pp += '0 1 0' * vid_conheight - '0 64 0';
929         for(i = 0; i < 8; ++i)
930         {
931                 p = pp + '1 0 0' * (rkt_size * i);
932                 if(rockets == 8)
933                 {
934                         if(floor(reload * 8) == i)
935                         {
936                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
937                         }
938                         else if(i < reload * 8)
939                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
940                         else
941                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
942                 }
943                 else
944                 {
945                         if(i < rockets)
946                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
947                         else
948                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
949                 }
950         }
951         */
952
953         if (scoreboard_showscores)
954         {
955                 HUD_DrawScoreboard();
956                 HUD_DrawCenterPrint();
957         }
958
959 }
960
961 #define raptor_h "gfx/vehicles/hud_bg.tga"
962 #define raptor_b "gfx/vehicles/raptor.tga"
963 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
964 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
965 #define raptor_s "gfx/vehicles/shiled.tga"
966
967 void CSQC_RAPTOR_HUD()
968 {
969         float rockets, reload, heat, hp, shield, energy;
970         vector picsize, hudloc;
971
972     // Fetch health & ammo stats
973     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
974         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
975         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
976         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
977
978     // Draw the crosshairs
979     picsize = drawgetimagesize(SPIDER_CROSS);
980     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
981     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
982     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
983
984     hudloc_y =  4;
985     hudloc_x = 4;
986
987     picsize = drawgetimagesize(raptor_h) * 0.5;
988     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
989
990     picsize = drawgetimagesize(spider_a2) * 0.5;
991     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
992
993     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
994     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
995     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
996
997
998     picsize = drawgetimagesize(spider_a1) * 0.85;
999     if(reload == 1)
1000     {
1001         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1002         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1003     }
1004     else
1005     {
1006         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1007         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1008     }
1009
1010     picsize = drawgetimagesize(raptor_b) * 0.5;
1011     hudloc_y = 10.5;
1012     hudloc_x = 10.5;
1013
1014     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1015     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1016     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1017     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1018
1019
1020         if (scoreboard_showscores)
1021         {
1022                 HUD_DrawScoreboard();
1023                 HUD_DrawCenterPrint();
1024         }
1025
1026 }
1027
1028 #define waki_h "gfx/vehicles/hud_bg.tga"
1029 #define waki_b "gfx/vehicles/waki.tga"
1030 #define waki_e "gfx/vehicles/waki_e.tga"
1031 #define waki_g "gfx/vehicles/waki_guns.tga"
1032 #define waki_r "gfx/vehicles/waki_rockets.tga"
1033 #define waki_s "gfx/vehicles/shiled.tga"
1034
1035 #define waki_a1 "gfx/hud/sb_rocket.tga"
1036 #define waki_a2 "gfx/sb_cells.tga"
1037
1038 void CSQC_WAKIZASHI_HUD()
1039 {
1040         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1041         float health, shield, energy, rockets;
1042         vector picsize, hudloc;
1043
1044     picsize = drawgetimagesize(SPIDER_CROSS);
1045     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1046     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1047     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1048
1049 /*
1050 const float STAT_VEHICLESTAT_HEALTH  = 60;
1051 const float STAT_VEHICLESTAT_SHIELD  = 61;
1052 const float STAT_VEHICLESTAT_ENERGY  = 62;
1053 const float STAT_VEHICLESTAT_AMMO1   = 63;
1054 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1055 const float STAT_VEHICLESTAT_AMMO2   = 65;
1056 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1057 */
1058     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1059         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1060         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1061         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1062
1063     hudloc_y =  4;
1064     hudloc_x = 4;
1065
1066     picsize = drawgetimagesize(waki_h) * 0.5;
1067     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1068
1069     picsize = drawgetimagesize(waki_a2) * 0.7;
1070     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1071
1072
1073     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1074     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1075
1076     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1077
1078     picsize = drawgetimagesize(waki_a1) * 0.75;
1079     if(rockets == 1)
1080     {
1081         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1082         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1083     }
1084     else
1085     {
1086         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1087         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1088         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1089     }
1090
1091     picsize = drawgetimagesize(waki_b) * 0.5;
1092     hudloc_y = 10.5;
1093     hudloc_x = 10.5;
1094
1095     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1096     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1097     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1098     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1099
1100
1101
1102         /*
1103         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1104         p = p + '0 1 0' * vid_conheight - '0 32 0';
1105
1106         // Draw health bar
1107         p_y += 8;
1108         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1109         p_x += 256 * health;
1110         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1111
1112         // Draw shiled bar
1113         p_x -= 256 * health;
1114         p_y += 4;
1115         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1116
1117         // Draw energy
1118         //p_x -= 256 * health;
1119         p_y -= 8;
1120         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1121
1122         // Draw rockets bar
1123         p_y += 12;
1124         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1125         */
1126
1127
1128
1129
1130         if (scoreboard_showscores)
1131         {
1132                 HUD_DrawScoreboard();
1133                 HUD_DrawCenterPrint();
1134         }
1135
1136 }
1137
1138
1139 void CSQC_common_hud(void)
1140 {
1141         // HUD_SortFrags(); done in HUD_Draw
1142         float hud;
1143         hud = getstati(STAT_HUD);
1144
1145         //hud = 10;
1146         switch(hud)
1147         {
1148                 case HUD_NORMAL:
1149                         // hud first
1150                         HUD_Main();
1151
1152                         // scoreboard/accuracy
1153                         if (intermission == 2 && !scoreboard_showaccuracy && !scoreboard_showscores) // map voting screen
1154                         {
1155                                 HUD_FinaleOverlay();
1156                                 HUD_Reset();
1157                         }
1158                         else if(scoreboard_showaccuracy && spectatee_status != -1)
1159                                 HUD_DrawAccuracyStats();
1160                         else
1161                                 HUD_DrawScoreboard();
1162
1163                         if (scoreboard_showscores || scoreboard_showaccuracy || scoreboard_showscores_force || getstati(STAT_HEALTH) <= 0 || intermission == 1)
1164                                 HUD_Reset();
1165
1166                         break;
1167
1168                 case HUD_SPIDERBOT:
1169                         CSQC_SPIDER_HUD();
1170                         break;
1171
1172                 case HUD_WAKIZASHI:
1173                         CSQC_WAKIZASHI_HUD();
1174                         break;
1175         }
1176 }
1177
1178
1179 // following vectors must be global to allow seamless switching between camera modes
1180 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1181 void CSQC_Demo_Camera()
1182 {
1183         float speed, attenuation, dimensions;
1184         vector tmp, delta;
1185
1186         if( cvar("camera_reset") || !camera_mode )
1187         {
1188                 camera_offset = '0 0 0';
1189                 current_angles = '0 0 0';
1190                 camera_direction = '0 0 0';
1191                 camera_offset_z += 30;
1192                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1193                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1194                 current_origin = view_origin;
1195                 current_camera_offset  = camera_offset;
1196                 cvar_set("camera_reset", "0");
1197                 camera_mode = CAMERA_CHASE;
1198         }
1199
1200         // Camera angles
1201         if( camera_roll )
1202                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1203
1204         if(cvar("camera_look_player"))
1205         {
1206                 local vector dir;
1207                 local float n;
1208
1209                 dir = normalize(view_origin - current_position);
1210                 n = mouse_angles_z;
1211                 mouse_angles = vectoangles(dir);
1212                 mouse_angles_x = mouse_angles_x * -1;
1213                 mouse_angles_z = n;
1214         }
1215         else
1216         {
1217                 tmp = getmousepos() * 0.1;
1218                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1219                 {
1220                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1221                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1222                 }
1223         }
1224
1225         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1226         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1227         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1228         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1229
1230         // Fix difference when angles don't have the same sign
1231         delta = '0 0 0';
1232         if(mouse_angles_y < -60 && current_angles_y > 60)
1233                 delta = '0 360 0';
1234         if(mouse_angles_y > 60 && current_angles_y < -60)
1235                 delta = '0 -360 0';
1236
1237         if(cvar("camera_look_player"))
1238                 attenuation = cvar("camera_look_attenuation");
1239         else
1240                 attenuation = cvar("camera_speed_attenuation");
1241
1242         attenuation = 1 / max(1, attenuation);
1243         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1244
1245         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1246         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1247         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1248         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1249
1250         // Camera position
1251         tmp = '0 0 0';
1252         dimensions = 0;
1253
1254         if( camera_direction_x )
1255         {
1256                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1257                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1258                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1259                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1260                 ++dimensions;
1261         }
1262
1263         if( camera_direction_y )
1264         {
1265                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1266                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1267                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1268                 ++dimensions;
1269         }
1270
1271         if( camera_direction_z )
1272         {
1273                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1274                 ++dimensions;
1275         }
1276
1277         if(cvar("camera_free"))
1278                 speed = cvar("camera_speed_free");
1279         else
1280                 speed = cvar("camera_speed_chase");
1281
1282         if(dimensions)
1283         {
1284                 speed = speed * sqrt(1 / dimensions);
1285                 camera_offset += tmp * speed;
1286         }
1287
1288         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1289
1290         // Camera modes
1291         if( cvar("camera_free") )
1292         {
1293                 if ( camera_mode == CAMERA_CHASE )
1294                 {
1295                         current_camera_offset = current_origin + current_camera_offset;
1296                         camera_offset = current_origin + camera_offset;
1297                 }
1298
1299                 camera_mode = CAMERA_FREE;
1300                 current_position = current_camera_offset;
1301         }
1302         else
1303         {
1304                 if ( camera_mode == CAMERA_FREE )
1305                 {
1306                         current_origin = view_origin;
1307                         camera_offset = camera_offset - current_origin;
1308                         current_camera_offset = current_camera_offset - current_origin;
1309                 }
1310
1311                 camera_mode = CAMERA_CHASE;
1312
1313                 if(cvar("camera_chase_smoothly"))
1314                         current_origin += (view_origin - current_origin) * attenuation;
1315                 else
1316                         current_origin = view_origin;
1317
1318                 current_position = current_origin + current_camera_offset;
1319         }
1320
1321         R_SetView(VF_ANGLES, current_angles);
1322         R_SetView(VF_ORIGIN, current_position);
1323 }