qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon)
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_GRENADE_LAUNCHER: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_NEX:
 291                 case WEP_MINSTANEX:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string NextFrameCommand;
 369 void CSQC_SPIDER_HUD();
 370 void CSQC_RAPTOR_HUD();
 371
 372 vector freeze_org, freeze_ang;
 373 entity nightvision_noise, nightvision_noise2;
 374
 375 #define MAX_TIME_DIFF 5
 376 float pickup_crosshair_time, pickup_crosshair_size;
 377 float hit_time, typehit_time;
 378 float nextsound_hit_time, nextsound_typehit_time;
 379 float hitindication_crosshair_time, hitindication_crosshair_size;
 380 float use_nex_chargepool;
 381
 382 float myhealth, myhealth_prev;
 383 float myhealth_flash;
 384
 385 float old_blurradius, old_bluralpha;
 386 float old_sharpen_intensity;
 387
 388 vector myhealth_gentlergb;
 389
 390 float contentavgalpha, liquidalpha_prev;
 391 vector liquidcolor_prev;
 392
 393 float eventchase_current_distance;
 394
 395 vector damage_blurpostprocess, content_blurpostprocess;
 396
 397 float checkfail[16];
 398
 399 float rainbow_last_flicker;
 400 vector rainbow_prev_color;
 401
 402 #define BUTTON_3 4
 403 #define BUTTON_4 8
 404 float cl_notice_run();
 405 float prev_myteam;
 406 void CSQC_UpdateView(float w, float h)
 407 {
 408         entity e;
 409         float fov;
 410         float f, i, j;
 411         vector v;
 412         vector vf_size, vf_min;
 413         float a;
 414
 415         execute_next_frame();
 416
 417         ++framecount;
 418
 419         hud = getstati(STAT_HUD);
 420
 421         if(autocvar__hud_showbinds_reload) // menu can set this one
 422         {
 423                 db_close(binddb);
 424                 binddb = db_create();
 425                 cvar_set("_hud_showbinds_reload", "0");
 426         }
 427
 428         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 429                 view_quality = getproperty(VF_MINFPS_QUALITY);
 430         else
 431                 view_quality = 1;
 432
 433         button_attack2 = (input_buttons & BUTTON_3);
 434         button_zoom = (input_buttons & BUTTON_4);
 435
 436 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 437         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 438         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 439         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 440         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 441         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 442         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 443         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 444
 445         vf_size = getpropertyvec(VF_SIZE);
 446         vf_min = getpropertyvec(VF_MIN);
 447         vid_width = vf_size_x;
 448         vid_height = vf_size_y;
 449
 450         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 451         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 452
 453         WaypointSprite_Load();
 454
 455         CSQCPlayer_SetCamera();
 456
 457 #ifdef COMPAT_XON050_ENGINE
 458         if(spectatee_status)
 459                 myteam = GetPlayerColor(spectatee_status - 1);
 460         else
 461 #endif
 462                 myteam = GetPlayerColor(player_localentnum - 1);
 463
 464         if(myteam != prev_myteam)
 465         {
 466                 myteamcolors = colormapPaletteColor(myteam, 1);
 467                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 468                         hud_panel[i].update_time = time;
 469                 prev_myteam = myteam;
 470         }
 471
 472         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 473
 474         float is_dead = (getstati(STAT_HEALTH) <= 0);
 475
 476         // FIXME do we need this hack?
 477         if(isdemo())
 478         {
 479                 // in demos, input_buttons do not work
 480                 button_zoom = (autocvar__togglezoom == "-");
 481         }
 482         else if(button_zoom
 483                 && autocvar_cl_unpress_zoom_on_death
 484                 && (spectatee_status >= 0)
 485                 && (is_dead || intermission))
 486         {
 487                 // no zoom while dead or in intermission please
 488                 localcmd("-zoom\n");
 489                 button_zoom = FALSE;
 490         }
 491
 492         // event chase camera
 493         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 494         {
 495                 if(((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission) && !autocvar_cl_orthoview)
 496                 {
 497                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 498                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 499
 500                         // detect maximum viewoffset and use it
 501                         if(autocvar_cl_eventchase_viewoffset)
 502                         {
 503                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 504                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 505                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 506                         }
 507
 508                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 509                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 510                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 511                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 512
 513                         // make the camera smooth back
 514                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 515                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 516                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 517                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 518
 519                         makevectors(view_angles);
 520
 521                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 522                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 523
 524                         // If the boxtrace fails, revert back to line tracing.
 525                         if(trace_startsolid)
 526                         {
 527                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 528                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 529                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 530                         }
 531                         else { setproperty(VF_ORIGIN, trace_endpos); }
 532
 533                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 534                 }
 535                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 536                 {
 537                         cvar_set("chase_active", "0");
 538                         eventchase_current_distance = 0; // start from 0 next time
 539                 }
 540         }
 541         // workaround for camera stuck between player's legs when using chase_active 1
 542         // because the engine stops updating the chase_active camera when the game ends
 543         else if(intermission)
 544         {
 545                 cvar_settemp("chase_active", "-1");
 546                 eventchase_current_distance = 0;
 547         }
 548
 549         // do lockview after event chase camera so that it still applies whenever necessary.
 550         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 551         {
 552                 setproperty(VF_ORIGIN, freeze_org);
 553                 setproperty(VF_ANGLES, freeze_ang);
 554         }
 555         else
 556         {
 557                 freeze_org = getpropertyvec(VF_ORIGIN);
 558                 freeze_ang = getpropertyvec(VF_ANGLES);
 559         }
 560
 561         WarpZone_FixView();
 562         //WarpZone_FixPMove();
 563
 564         vector ov_org = '0 0 0';
 565         vector ov_mid = '0 0 0';
 566         vector ov_worldmin = '0 0 0';
 567         vector ov_worldmax = '0 0 0';
 568         if(autocvar_cl_orthoview)
 569         {
 570                 ov_worldmin = mi_picmin;
 571                 ov_worldmax = mi_picmax;
 572
 573                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
 574                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
 575                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
 576
 577                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
 578                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
 579
 580                 float ov_nearest = vlen(ov_org - vec3(
 581                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
 582                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
 583                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
 584                 ));
 585
 586                 float ov_furthest = 0;
 587                 float dist = 0;
 588
 589                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 590                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 591                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 592                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 593                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 594                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 595                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 596                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 597
 598                 cvar_settemp("r_nearclip", ftos(ov_nearest));
 599                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
 600                 cvar_settemp("r_farclip_world", "0");
 601                 cvar_settemp("r_novis", "1");
 602                 cvar_settemp("r_useportalculling", "0");
 603                 cvar_settemp("r_useinfinitefarclip", "0");
 604
 605                 setproperty(VF_ORIGIN, ov_org);
 606                 setproperty(VF_ANGLES, '90 0 0');
 607
 608                 #if 0
 609                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
 610                         vtos(ov_org),
 611                         vtos(getpropertyvec(VF_ANGLES)),
 612                         ov_distance,
 613                         ov_nearest,
 614                         ov_furthest);
 615                 #endif
 616         }
 617
 618         // Render the Scene
 619         view_origin = getpropertyvec(VF_ORIGIN);
 620         view_angles = getpropertyvec(VF_ANGLES);
 621         makevectors(view_angles);
 622         view_forward = v_forward;
 623         view_right = v_right;
 624         view_up = v_up;
 625
 626 #ifdef BLURTEST
 627         if(time > blurtest_time0 && time < blurtest_time1)
 628         {
 629                 float r, t;
 630
 631                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 632                 r = t * blurtest_radius;
 633                 f = 1 / pow(t, blurtest_power) - 1;
 634
 635                 cvar_set("r_glsl_postprocess", "1");
 636                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 637         }
 638         else
 639         {
 640                 cvar_set("r_glsl_postprocess", "0");
 641                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 642         }
 643 #endif
 644
 645         TargetMusic_Advance();
 646         Fog_Force();
 647
 648         if(drawtime == 0)
 649                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 650         else
 651                 drawframetime = bound(0.000001, time - drawtime, 1);
 652         drawtime = time;
 653
 654         // watch for gametype changes here...
 655         // in ParseStuffCMD the cmd isn't executed yet :/
 656         // might even be better to add the gametype to TE_CSQC_INIT...?
 657         if(!postinit)
 658                 PostInit();
 659
 660         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 661         {
 662                 if(calledhooks & HOOK_START)
 663                 {
 664                         localcmd("\ncl_hook_gameend\n");
 665                         calledhooks |= HOOK_END;
 666                 }
 667         }
 668
 669         Announcer();
 670
 671         fov = autocvar_fov;
 672         if(fov <= 59.5)
 673         {
 674                 if(!zoomscript_caught)
 675                 {
 676                         localcmd("+button9\n");
 677                         zoomscript_caught = 1;
 678                 }
 679         }
 680         else
 681         {
 682                 if(zoomscript_caught)
 683                 {
 684                         localcmd("-button9\n");
 685                         zoomscript_caught = 0;
 686                 }
 687         }
 688
 689         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 690
 691         // next WANTED weapon (for HUD)
 692         switchweapon = getstati(STAT_SWITCHWEAPON);
 693
 694         // currently switching-to weapon (for crosshair)
 695         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 696
 697         // actually active weapon (for zoom)
 698         activeweapon = getstati(STAT_ACTIVEWEAPON);
 699
 700         f = (serverflags & SERVERFLAG_TEAMPLAY);
 701         if(f != teamplay)
 702         {
 703                 teamplay = f;
 704                 HUD_InitScores();
 705         }
 706
 707         if(last_switchweapon != switchweapon)
 708         {
 709                 weapontime = time;
 710                 last_switchweapon = switchweapon;
 711                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 712                 {
 713                         localcmd("-zoom\n");
 714                         button_zoom = FALSE;
 715                 }
 716                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 717                 {
 718                         localcmd("-fire\n");
 719                         localcmd("-fire2\n");
 720                         button_attack2 = FALSE;
 721                 }
 722         }
 723         if(last_activeweapon != activeweapon)
 724         {
 725                 last_activeweapon = activeweapon;
 726
 727                 e = get_weaponinfo(activeweapon);
 728                 if(e.netname != "")
 729                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 730                 else
 731                         localcmd("\ncl_hook_activeweapon none\n");
 732         }
 733
 734         // ALWAYS Clear Current Scene First
 735         clearscene();
 736 #ifdef WORKAROUND_XON010
 737         if(checkextension("DP_CSQC_ROTATEMOVES"))
 738         {
 739 #endif
 740         setproperty(VF_ORIGIN, view_origin);
 741         setproperty(VF_ANGLES, view_angles);
 742 #ifdef WORKAROUND_XON010
 743         }
 744 #endif
 745
 746         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 747         setproperty(VF_SIZE, vf_size);
 748         setproperty(VF_MIN, vf_min);
 749
 750         // Assign Standard Viewflags
 751         // Draw the World (and sky)
 752         setproperty(VF_DRAWWORLD, 1);
 753
 754         // Set the console size vars
 755         vid_conwidth = autocvar_vid_conwidth;
 756         vid_conheight = autocvar_vid_conheight;
 757         vid_pixelheight = autocvar_vid_pixelheight;
 758
 759         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
 760         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 761
 762         // Camera for demo playback
 763         if(camera_active)
 764         {
 765                 if(autocvar_camera_enable)
 766                         CSQC_Demo_Camera();
 767                 else
 768                 {
 769                         cvar_set("chase_active", ftos(chase_active_backup));
 770                         cvar_set("cl_demo_mousegrab", "0");
 771                         camera_active = FALSE;
 772                 }
 773         }
 774 #ifdef CAMERATEST
 775         else if(autocvar_camera_enable)
 776 #else
 777         else if(autocvar_camera_enable && isdemo())
 778 #endif
 779         {
 780                 // Enable required Darkplaces cvars
 781                 chase_active_backup = autocvar_chase_active;
 782                 cvar_set("chase_active", "2");
 783                 cvar_set("cl_demo_mousegrab", "1");
 784                 camera_active = TRUE;
 785                 camera_mode = FALSE;
 786         }
 787
 788         // Draw the Crosshair
 789         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 790
 791         // Draw the Engine Status Bar (the default Quake HUD)
 792         setproperty(VF_DRAWENGINESBAR, 0);
 793
 794         // Update the mouse position
 795         /*
 796            mousepos_x = vid_conwidth;
 797            mousepos_y = vid_conheight;
 798            mousepos = mousepos*0.5 + getmousepos();
 799          */
 800
 801         e = self;
 802         for(self = world; (self = nextent(self)); )
 803                 if(self.draw)
 804                         self.draw();
 805         self = e;
 806
 807         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 808         renderscene();
 809
 810         // now switch to 2D drawing mode by calling a 2D drawing function
 811         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 812         // next R_RenderScene call
 813         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 814
 815         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 816         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 817         {
 818                 // apply night vision effect
 819                 vector tc_00, tc_01, tc_10, tc_11;
 820                 vector rgb;
 821                 rgb_x = 0; // fteqcc sucks
 822                 rgb_y = 0; // fteqcc sucks
 823                 rgb_z = 0; // fteqcc sucks
 824
 825                 if(!nightvision_noise)
 826                 {
 827                         nightvision_noise = spawn();
 828                         nightvision_noise.classname = "nightvision_noise";
 829                 }
 830                 if(!nightvision_noise2)
 831                 {
 832                         nightvision_noise2 = spawn();
 833                         nightvision_noise2.classname = "nightvision_noise2";
 834                 }
 835
 836                 // color tint in yellow
 837                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 838
 839                 // draw BG
 840                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 841                 rgb = '1 1 1';
 842                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 843                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 844                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 845                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 846                 tc_11 = tc_01 + tc_10 - tc_00;
 847                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 848                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 849                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 850                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 851                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 852                 R_EndPolygon();
 853
 854                 // draw FG
 855                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 856                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 857                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 858                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 859                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 860                 tc_11 = tc_01 + tc_10 - tc_00;
 861                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 862                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 863                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 864                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 865                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 866                 R_EndPolygon();
 867         }
 868
 869         // Draw the aiming reticle for weapons that use it
 870         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 871         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 872         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 873         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 874                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 875         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
 876                 reticle_type = 2; // nex zoom
 877         else if(button_zoom || zoomscript_caught)
 878                 reticle_type = 1; // normal zoom
 879         else if((activeweapon == WEP_NEX) && button_attack2)
 880                 reticle_type = 2; // nex zoom
 881
 882         if(reticle_type && autocvar_cl_reticle)
 883         {
 884                 if(autocvar_cl_reticle_stretch)
 885                 {
 886                         reticle_size_x = vid_conwidth;
 887                         reticle_size_y = vid_conheight;
 888                         reticle_pos_x = 0;
 889                         reticle_pos_y = 0;
 890                 }
 891                 else
 892                 {
 893                         reticle_size_x = max(vid_conwidth, vid_conheight);
 894                         reticle_size_y = max(vid_conwidth, vid_conheight);
 895                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 896                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 897                 }
 898
 899                 f = current_zoomfraction;
 900                 if(zoomscript_caught)
 901                         f = 1;
 902                 if(autocvar_cl_reticle_item_normal)
 903                 {
 904                         if(reticle_type == 1 && f)
 905                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 906                 }
 907                 if(autocvar_cl_reticle_item_nex)
 908                 {
 909                         if(reticle_type == 2 && f)
 910                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 911                 }
 912         }
 913
 914
 915         // improved polyblend
 916         if(autocvar_hud_contents)
 917         {
 918                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 919                 vector liquidcolor;
 920
 921                 switch(pointcontents(view_origin))
 922                 {
 923                         case CONTENT_WATER:
 924                                 liquidalpha = autocvar_hud_contents_water_alpha;
 925                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 926                                 incontent = 1;
 927                                 break;
 928
 929                         case CONTENT_LAVA:
 930                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 931                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 932                                 incontent = 1;
 933                                 break;
 934
 935                         case CONTENT_SLIME:
 936                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 937                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 938                                 incontent = 1;
 939                                 break;
 940
 941                         default:
 942                                 liquidalpha = 0;
 943                                 liquidcolor = '0 0 0';
 944                                 incontent = 0;
 945                                 break;
 946                 }
 947
 948                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 949                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 950                         contentfadetime = autocvar_hud_contents_fadeintime;
 951                         liquidalpha_prev = liquidalpha;
 952                         liquidcolor_prev = liquidcolor;
 953                 }
 954                 else
 955                         contentfadetime = autocvar_hud_contents_fadeouttime;
 956
 957                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 958                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 959
 960                 if(contentavgalpha)
 961                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 962
 963                 if(autocvar_hud_postprocessing)
 964                 {
 965                         if(autocvar_hud_contents_blur && contentavgalpha)
 966                         {
 967                                 content_blurpostprocess_x = 1;
 968                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 969                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 970                         }
 971                         else
 972                         {
 973                                 content_blurpostprocess_x = 0;
 974                                 content_blurpostprocess_y = 0;
 975                                 content_blurpostprocess_z = 0;
 976                         }
 977                 }
 978         }
 979
 980         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 981         {
 982                 splash_size_x = max(vid_conwidth, vid_conheight);
 983                 splash_size_y = max(vid_conwidth, vid_conheight);
 984                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 985                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 986
 987                 float myhealth_flash_temp;
 988                 myhealth = getstati(STAT_HEALTH);
 989
 990                 // fade out
 991                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 992                 // add new damage
 993                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 994
 995                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 996                 pain_threshold = autocvar_hud_damage_pain_threshold;
 997                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 998                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 999
1000                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1001                 {
1002                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1003                 }
1004
1005                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1006
1007                 if(myhealth_prev < 1)
1008                 {
1009                         if(myhealth >= 1)
1010                         {
1011                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1012                                 myhealth_flash_temp = 0;
1013                         }
1014                         else
1015                         {
1016                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1017                         }
1018                 }
1019
1020                 if(spectatee_status == -1 || intermission)
1021                 {
1022                         myhealth_flash = 0; // observing, or match ended
1023                         myhealth_flash_temp = 0;
1024                 }
1025
1026                 myhealth_prev = myhealth;
1027
1028                 // IDEA: change damage color/picture based on player model for robot/alien species?
1029                 // pro: matches model better
1030                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1031                 // maybe different reddish pics?
1032                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1033                 {
1034                         if(autocvar_cl_gentle_damage == 2)
1035                         {
1036                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1037                                 {
1038                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1039                                 }
1040                         }
1041                         else
1042                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1043
1044                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1045                 }
1046                 else
1047                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1048
1049                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1050                 {
1051                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1052                         {
1053                                 damage_blurpostprocess_x = 1;
1054                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1055                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1056                         }
1057                         else
1058                         {
1059                                 damage_blurpostprocess_x = 0;
1060                                 damage_blurpostprocess_y = 0;
1061                                 damage_blurpostprocess_z = 0;
1062                         }
1063                 }
1064         }
1065
1066         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1067         float e2 = (autocvar_hud_powerup != 0);
1068         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1069         {
1070                 // enable or disable rendering types if they are used or not
1071                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1072                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1073
1074                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1075                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1076                 {
1077                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1078                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1079                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1080                         {
1081                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1082                                 old_blurradius = blurradius;
1083                                 old_bluralpha = bluralpha;
1084                         }
1085                 }
1086                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1087                 {
1088                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1089                         old_blurradius = 0;
1090                         old_bluralpha = 0;
1091                 }
1092
1093                 // edge detection postprocess handling done second (used by hud_powerup)
1094                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1095                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1096                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1097
1098                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1099
1100                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1101                 {
1102                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1103                         {
1104                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1105                                 old_sharpen_intensity = sharpen_intensity;
1106                         }
1107                 }
1108                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1109                 {
1110                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1111                         old_sharpen_intensity = 0;
1112                 }
1113
1114                 if(cvar("r_glsl_postprocess") == 0)
1115                         cvar_set("r_glsl_postprocess", "2");
1116         }
1117         else if(cvar("r_glsl_postprocess") == 2)
1118                 cvar_set("r_glsl_postprocess", "0");
1119
1120         if(menu_visible)
1121                 menu_show();
1122
1123         /*if(gametype == MAPINFO_TYPE_CTF)
1124           {
1125           ctf_view();
1126           } else */
1127
1128         // draw 2D entities
1129         e = self;
1130         for(self = world; (self = nextent(self)); )
1131                 if(self.draw2d)
1132                         self.draw2d();
1133         self = e;
1134         Draw_ShowNames_All();
1135
1136         scoreboard_active = HUD_WouldDrawScoreboard();
1137
1138         hit_time = getstatf(STAT_HIT_TIME);
1139         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1140         {
1141                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1142                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1143
1144                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1145         }
1146         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1147         if(typehit_time > nextsound_typehit_time)
1148         {
1149                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1150                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1151
1152                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1153         }
1154
1155         //else
1156         {
1157                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1158                 {
1159                         if(getstati(STAT_FROZEN))
1160                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1161                         if(getstatf(STAT_REVIVE_PROGRESS))
1162                         {
1163                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1164                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1165                         }
1166                 }
1167
1168                 if(autocvar_r_letterbox == 0)
1169                         if(autocvar_viewsize < 120)
1170                                 CSQC_common_hud();
1171
1172                 // crosshair goes VERY LAST
1173                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1174                 {
1175                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1176                                 return;
1177
1178                         string wcross_style;
1179                         float wcross_alpha, wcross_resolution;
1180                         wcross_style = autocvar_crosshair;
1181                         if (wcross_style == "0")
1182                                 return;
1183                         wcross_resolution = autocvar_crosshair_size;
1184                         if (wcross_resolution == 0)
1185                                 return;
1186                         wcross_alpha = autocvar_crosshair_alpha;
1187                         if (wcross_alpha == 0)
1188                                 return;
1189
1190                         // TrueAim check
1191                         float shottype;
1192
1193                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1194                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1195                         wcross_origin_z = 0;
1196                         if(autocvar_crosshair_hittest)
1197                         {
1198                                 vector wcross_oldorigin;
1199                                 wcross_oldorigin = wcross_origin;
1200                                 shottype = TrueAimCheck();
1201                                 if(shottype == SHOTTYPE_HITWORLD)
1202                                 {
1203                                         v = wcross_origin - wcross_oldorigin;
1204                                         v_x /= vid_conwidth;
1205                                         v_y /= vid_conheight;
1206                                         if(vlen(v) > 0.01)
1207                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1208                                 }
1209                                 if(!autocvar_crosshair_hittest_showimpact)
1210                                         wcross_origin = wcross_oldorigin;
1211                         }
1212                         else
1213                                 shottype = SHOTTYPE_HITWORLD;
1214
1215                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1216                         string wcross_wep = "", wcross_name;
1217                         float wcross_scale, wcross_blur;
1218
1219                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1220                         {
1221                                 e = get_weaponinfo(switchingweapon);
1222                                 if (e && e.netname != "")
1223                                 {
1224                                         wcross_wep = e.netname;
1225                                         if(autocvar_crosshair_per_weapon)
1226                                         {
1227                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1228                                                 if (wcross_resolution == 0)
1229                                                         return;
1230                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1231                                                 if (wcross_alpha == 0)
1232                                                         return;
1233
1234                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1235                                                 if(wcross_style == "" || wcross_style == "0")
1236                                                         wcross_style = wcross_wep;
1237                                         }
1238                                 }
1239                         }
1240
1241                         //printf("crosshair style: %s\n", wcross_style);
1242                         wcross_name = strcat("gfx/crosshair", wcross_style);
1243
1244                         // MAIN CROSSHAIR COLOR DECISION
1245                         switch(autocvar_crosshair_color_special)
1246                         {
1247                                 case 1: // crosshair_color_per_weapon
1248                                 {
1249                                         if(wcross_wep != "")
1250                                         {
1251                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1252                                                 break;
1253                                         }
1254                                         else { goto normalcolor; }
1255                                 }
1256
1257                                 case 2: // crosshair_color_by_health
1258                                 {
1259                                         float x = getstati(STAT_HEALTH);
1260
1261                                         //x = red
1262                                         //y = green
1263                                         //z = blue
1264
1265                                         wcross_color_z = 0;
1266
1267                                         if(x > 200)
1268                                         {
1269                                                 wcross_color_x = 0;
1270                                                 wcross_color_y = 1;
1271                                         }
1272                                         else if(x > 150)
1273                                         {
1274                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1275                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1276                                         }
1277                                         else if(x > 100)
1278                                         {
1279                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1280                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1281                                                 wcross_color_z = 1 - (x-100)*0.02;
1282                                         }
1283                                         else if(x > 50)
1284                                         {
1285                                                 wcross_color_x = 1;
1286                                                 wcross_color_y = 1;
1287                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1288                                         }
1289                                         else if(x > 20)
1290                                         {
1291                                                 wcross_color_x = 1;
1292                                                 wcross_color_y = (x-20)*90/27/100;
1293                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1294                                         }
1295                                         else
1296                                         {
1297                                                 wcross_color_x = 1;
1298                                                 wcross_color_y = 0;
1299                                         }
1300                                         break;
1301                                 }
1302
1303                                 case 3: // crosshair_color_rainbow
1304                                 {
1305                                         if(time >= rainbow_last_flicker)
1306                                         {
1307                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1308                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1309                                         }
1310                                         wcross_color = rainbow_prev_color;
1311                                         break;
1312                                 }
1313                                 :normalcolor
1314                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1315                         }
1316
1317                         if(autocvar_crosshair_effect_scalefade)
1318                         {
1319                                 wcross_scale = wcross_resolution;
1320                                 wcross_resolution = 1;
1321                         }
1322                         else
1323                         {
1324                                 wcross_scale = 1;
1325                         }
1326
1327                         if(autocvar_crosshair_pickup)
1328                         {
1329                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1330
1331                                 if(pickup_crosshair_time < stat_pickup_time)
1332                                 {
1333                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1334                                                 pickup_crosshair_size = 1;
1335
1336                                         pickup_crosshair_time = stat_pickup_time;
1337                                 }
1338
1339                                 if(pickup_crosshair_size > 0)
1340                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1341                                 else
1342                                         pickup_crosshair_size = 0;
1343
1344                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1345                         }
1346
1347                         if(autocvar_crosshair_hitindication)
1348                         {
1349                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1350
1351                                 if(hitindication_crosshair_time < hit_time)
1352                                 {
1353                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1354                                                 hitindication_crosshair_size = 1;
1355
1356                                         hitindication_crosshair_time = hit_time;
1357                                 }
1358
1359                                 if(hitindication_crosshair_size > 0)
1360                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1361                                 else
1362                                         hitindication_crosshair_size = 0;
1363
1364                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1365                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1366                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1367                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1368                         }
1369
1370                         if(shottype == SHOTTYPE_HITENEMY)
1371                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1372                         if(shottype == SHOTTYPE_HITTEAM)
1373                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1374
1375                         f = fabs(autocvar_crosshair_effect_time);
1376                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1377                         {
1378                                 wcross_changedonetime = time + f;
1379                         }
1380                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1381                         {
1382                                 wcross_name_changestarttime = time;
1383                                 wcross_name_changedonetime = time + f;
1384                                 if(wcross_name_goal_prev_prev)
1385                                         strunzone(wcross_name_goal_prev_prev);
1386                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1387                                 wcross_name_goal_prev = strzone(wcross_name);
1388                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1389                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1390                                 wcross_resolution_goal_prev = wcross_resolution;
1391                         }
1392
1393                         wcross_scale_goal_prev = wcross_scale;
1394                         wcross_alpha_goal_prev = wcross_alpha;
1395                         wcross_color_goal_prev = wcross_color;
1396
1397                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1398                         {
1399                                 wcross_blur = 1;
1400                                 wcross_alpha *= 0.75;
1401                         }
1402                         else
1403                                 wcross_blur = 0;
1404                         // *_prev is at time-frametime
1405                         // * is at wcross_changedonetime+f
1406                         // what do we have at time?
1407                         if(time < wcross_changedonetime)
1408                         {
1409                                 f = frametime / (wcross_changedonetime - time + frametime);
1410                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1411                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1412                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1413                         }
1414
1415                         wcross_scale_prev = wcross_scale;
1416                         wcross_alpha_prev = wcross_alpha;
1417                         wcross_color_prev = wcross_color;
1418
1419                         wcross_scale *= 1 - autocvar__menu_alpha;
1420                         wcross_alpha *= 1 - autocvar__menu_alpha;
1421                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1422
1423                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1424                         {
1425                                 // crosshair rings for weapon stats
1426                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1427                                 {
1428                                         // declarations and stats
1429                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1430                                         string ring_image = string_null, ring_inner_image = string_null;
1431                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1432
1433                                         ring_scale = autocvar_crosshair_ring_size;
1434
1435                                         float weapon_clipload, weapon_clipsize;
1436                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1437                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1438
1439                                         float nex_charge, nex_chargepool;
1440                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1441                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1442
1443                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1444                                                 nex_charge_movingavg = nex_charge;
1445
1446
1447                                         // handle the values
1448                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1449                                         {
1450                                                 if (nex_chargepool || use_nex_chargepool) {
1451                                                         use_nex_chargepool = 1;
1452                                                         ring_inner_value = nex_chargepool;
1453                                                 } else {
1454                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1455                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1456                                                 }
1457
1458                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1459                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1460                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1461
1462                                                 // draw the outer ring to show the current charge of the weapon
1463                                                 ring_value = nex_charge;
1464                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1465                                                 ring_rgb = wcross_color;
1466                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1467                                         }
1468                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1469                                         {
1470                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1471                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1472                                                 ring_rgb = wcross_color;
1473                                                 ring_image = "gfx/crosshair_ring.tga";
1474                                         }
1475                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1476                                         {
1477                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1478                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1479                                                 ring_rgb = wcross_color;
1480                                                 ring_image = "gfx/crosshair_ring.tga";
1481                                         }
1482
1483                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1484                                         {
1485                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1486                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1487                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1488                                                 ring_rgb = wcross_color;
1489
1490                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1491                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1492                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1493                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1494                                                 else
1495                                                         ring_image = "gfx/crosshair_ring.tga";
1496                                         }
1497
1498                                         // if in weapon switch animation, fade ring out/in
1499                                         if(autocvar_crosshair_effect_time > 0)
1500                                         {
1501                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1502                                                 if (!(f < 1))
1503                                                 {
1504                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1505                                                 }
1506
1507                                                 if(wcross_ring_prev)
1508                                                 {
1509                                                         if(f < 1)
1510                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1511                                                 }
1512                                                 else
1513                                                 {
1514                                                         if(f < 1)
1515                                                                 ring_alpha *= bound(0, f, 1);
1516                                                 }
1517                                         }
1518
1519                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1520                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1521
1522                                         if (ring_value)
1523                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1524                                 }
1525
1526 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1527                                 do \
1528                                 { \
1529                                         if(wcross_blur > 0) \
1530                                         { \
1531                                                 for(i = -2; i <= 2; ++i) \
1532                                                 for(j = -2; j <= 2; ++j) \
1533                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1534                                         } \
1535                                         else \
1536                                         { \
1537                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1538                                         } \
1539                                 } \
1540                                 while(0)
1541
1542 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1543                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1544
1545 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1546                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1547
1548                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1549                                 {
1550                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1551                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1552                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1553                                         f = 1 - f;
1554                                 }
1555                                 else
1556                                 {
1557                                         f = 1;
1558                                 }
1559                                 wcross_name_alpha_goal_prev = f;
1560
1561                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1562                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1563
1564                                 if(autocvar_crosshair_dot)
1565                                 {
1566                                         vector wcross_color_old;
1567                                         wcross_color_old = wcross_color;
1568
1569                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1570                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1571
1572                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1573                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1574                                         wcross_color = wcross_color_old;
1575                                 }
1576                         }
1577                 }
1578                 else
1579                 {
1580                         wcross_scale_prev = 0;
1581                         wcross_alpha_prev = 0;
1582                         wcross_scale_goal_prev = 0;
1583                         wcross_alpha_goal_prev = 0;
1584                         wcross_changedonetime = 0;
1585                         if(wcross_name_goal_prev)
1586                                 strunzone(wcross_name_goal_prev);
1587                         wcross_name_goal_prev = string_null;
1588                         if(wcross_name_goal_prev_prev)
1589                                 strunzone(wcross_name_goal_prev_prev);
1590                         wcross_name_goal_prev_prev = string_null;
1591                         wcross_name_changestarttime = 0;
1592                         wcross_name_changedonetime = 0;
1593                         wcross_name_alpha_goal_prev = 0;
1594                         wcross_name_alpha_goal_prev_prev = 0;
1595                         wcross_resolution_goal_prev = 0;
1596                         wcross_resolution_goal_prev_prev = 0;
1597                 }
1598         }
1599
1600         if(NextFrameCommand)
1601         {
1602                 localcmd("\n", NextFrameCommand, "\n");
1603                 NextFrameCommand = string_null;
1604         }
1605
1606         // we must do this check AFTER a frame was rendered, or it won't work
1607         if(cs_project_is_b0rked == 0)
1608         {
1609                 string w0, h0;
1610                 w0 = ftos(autocvar_vid_conwidth);
1611                 h0 = ftos(autocvar_vid_conheight);
1612                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1613                 //setproperty(VF_FOV, '90 90 0');
1614                 setproperty(VF_ORIGIN, '0 0 0');
1615                 setproperty(VF_ANGLES, '0 0 0');
1616                 setproperty(VF_PERSPECTIVE, 1);
1617                 makevectors('0 0 0');
1618                 vector v1, v2;
1619                 cvar_set("vid_conwidth", "800");
1620                 cvar_set("vid_conheight", "600");
1621                 v1 = cs_project(v_forward);
1622                 cvar_set("vid_conwidth", "640");
1623                 cvar_set("vid_conheight", "480");
1624                 v2 = cs_project(v_forward);
1625                 if(v1 == v2)
1626                         cs_project_is_b0rked = 1;
1627                 else
1628                         cs_project_is_b0rked = -1;
1629                 cvar_set("vid_conwidth", w0);
1630                 cvar_set("vid_conheight", h0);
1631         }
1632
1633         if(autocvar__hud_configure)
1634                 HUD_Panel_Mouse();
1635
1636     if(hud && !intermission)
1637     {
1638         if(hud == HUD_SPIDERBOT)
1639             CSQC_SPIDER_HUD();
1640         else if(hud == HUD_WAKIZASHI)
1641             CSQC_WAKIZASHI_HUD();
1642         else if(hud == HUD_RAPTOR)
1643             CSQC_RAPTOR_HUD();
1644         else if(hud == HUD_BUMBLEBEE)
1645             CSQC_BUMBLE_HUD();
1646         else if(hud == HUD_BUMBLEBEE_GUN)
1647             CSQC_BUMBLE_GUN_HUD();
1648     }
1649
1650         cl_notice_run();
1651
1652         // let's reset the view back to normal for the end
1653         setproperty(VF_MIN, '0 0 0');
1654         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1655 }
1656
1657
1658 void CSQC_common_hud(void)
1659 {
1660         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1661                 Accuracy_LoadLevels();
1662
1663         HUD_Main(); // always run these functions for alpha checks
1664         HUD_DrawScoreboard();
1665
1666         if (scoreboard_active) // scoreboard/accuracy
1667                 HUD_Reset();
1668         else if (intermission == 2) // map voting screen
1669         {
1670                 MapVote_Draw();
1671                 HUD_Reset();
1672         }
1673 }
1674
1675
1676 // following vectors must be global to allow seamless switching between camera modes
1677 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1678 void CSQC_Demo_Camera()
1679 {
1680         float speed, attenuation, dimensions;
1681         vector tmp, delta;
1682
1683         if( autocvar_camera_reset || !camera_mode )
1684         {
1685                 camera_offset = '0 0 0';
1686                 current_angles = '0 0 0';
1687                 camera_direction = '0 0 0';
1688                 camera_offset_z += 30;
1689                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1690                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1691                 current_origin = view_origin;
1692                 current_camera_offset  = camera_offset;
1693                 cvar_set("camera_reset", "0");
1694                 camera_mode = CAMERA_CHASE;
1695         }
1696
1697         // Camera angles
1698         if( camera_roll )
1699                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1700
1701         if(autocvar_camera_look_player)
1702         {
1703                 vector dir;
1704                 float n;
1705
1706                 dir = normalize(view_origin - current_position);
1707                 n = mouse_angles_z;
1708                 mouse_angles = vectoangles(dir);
1709                 mouse_angles_x = mouse_angles_x * -1;
1710                 mouse_angles_z = n;
1711         }
1712         else
1713         {
1714                 tmp = getmousepos() * 0.1;
1715                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1716                 {
1717                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1718                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1719                 }
1720         }
1721
1722         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1723         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1724         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1725         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1726
1727         // Fix difference when angles don't have the same sign
1728         delta = '0 0 0';
1729         if(mouse_angles_y < -60 && current_angles_y > 60)
1730                 delta = '0 360 0';
1731         if(mouse_angles_y > 60 && current_angles_y < -60)
1732                 delta = '0 -360 0';
1733
1734         if(autocvar_camera_look_player)
1735                 attenuation = autocvar_camera_look_attenuation;
1736         else
1737                 attenuation = autocvar_camera_speed_attenuation;
1738
1739         attenuation = 1 / max(1, attenuation);
1740         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1741
1742         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1743         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1744         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1745         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1746
1747         // Camera position
1748         tmp = '0 0 0';
1749         dimensions = 0;
1750
1751         if( camera_direction_x )
1752         {
1753                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1754                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1755                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1756                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1757                 ++dimensions;
1758         }
1759
1760         if( camera_direction_y )
1761         {
1762                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1763                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1764                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1765                 ++dimensions;
1766         }
1767
1768         if( camera_direction_z )
1769         {
1770                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1771                 ++dimensions;
1772         }
1773
1774         if(autocvar_camera_free)
1775                 speed = autocvar_camera_speed_free;
1776         else
1777                 speed = autocvar_camera_speed_chase;
1778
1779         if(dimensions)
1780         {
1781                 speed = speed * sqrt(1 / dimensions);
1782                 camera_offset += tmp * speed;
1783         }
1784
1785         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1786
1787         // Camera modes
1788         if( autocvar_camera_free )
1789         {
1790                 if ( camera_mode == CAMERA_CHASE )
1791                 {
1792                         current_camera_offset = current_origin + current_camera_offset;
1793                         camera_offset = current_origin + camera_offset;
1794                 }
1795
1796                 camera_mode = CAMERA_FREE;
1797                 current_position = current_camera_offset;
1798         }
1799         else
1800         {
1801                 if ( camera_mode == CAMERA_FREE )
1802                 {
1803                         current_origin = view_origin;
1804                         camera_offset = camera_offset - current_origin;
1805                         current_camera_offset = current_camera_offset - current_origin;
1806                 }
1807
1808                 camera_mode = CAMERA_CHASE;
1809
1810                 if(autocvar_camera_chase_smoothly)
1811                         current_origin += (view_origin - current_origin) * attenuation;
1812                 else
1813                         current_origin = view_origin;
1814
1815                 current_position = current_origin + current_camera_offset;
1816         }
1817
1818         setproperty(VF_ANGLES, current_angles);
1819         setproperty(VF_ORIGIN, current_position);
1820 }