qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon)
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_GRENADE_LAUNCHER: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_NEX:
 291                 case WEP_MINSTANEX:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string NextFrameCommand;
 369
 370 vector freeze_org, freeze_ang;
 371 entity nightvision_noise, nightvision_noise2;
 372
 373 #define MAX_TIME_DIFF 5
 374 float pickup_crosshair_time, pickup_crosshair_size;
 375 float hit_time, typehit_time;
 376 float nextsound_hit_time, nextsound_typehit_time;
 377 float hitindication_crosshair_time, hitindication_crosshair_size;
 378 float use_nex_chargepool;
 379
 380 float myhealth, myhealth_prev;
 381 float myhealth_flash;
 382
 383 float old_blurradius, old_bluralpha;
 384 float old_sharpen_intensity;
 385
 386 vector myhealth_gentlergb;
 387
 388 float contentavgalpha, liquidalpha_prev;
 389 vector liquidcolor_prev;
 390
 391 float eventchase_current_distance;
 392
 393 vector damage_blurpostprocess, content_blurpostprocess;
 394
 395 float checkfail[16];
 396
 397 float rainbow_last_flicker;
 398 vector rainbow_prev_color;
 399
 400 #define BUTTON_3 4
 401 #define BUTTON_4 8
 402 float cl_notice_run();
 403 float prev_myteam;
 404 void CSQC_UpdateView(float w, float h)
 405 {
 406         entity e;
 407         float fov;
 408         float f, i, j;
 409         vector v;
 410         vector vf_size, vf_min;
 411         float a;
 412
 413         execute_next_frame();
 414
 415         ++framecount;
 416
 417         hud = getstati(STAT_HUD);
 418
 419         if(autocvar__hud_showbinds_reload) // menu can set this one
 420         {
 421                 db_close(binddb);
 422                 binddb = db_create();
 423                 cvar_set("_hud_showbinds_reload", "0");
 424         }
 425
 426         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 427                 view_quality = getproperty(VF_MINFPS_QUALITY);
 428         else
 429                 view_quality = 1;
 430
 431         button_attack2 = (input_buttons & BUTTON_3);
 432         button_zoom = (input_buttons & BUTTON_4);
 433
 434 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 435         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 436         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 437         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 438         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 439         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 440         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 441         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 442
 443         vf_size = getpropertyvec(VF_SIZE);
 444         vf_min = getpropertyvec(VF_MIN);
 445         vid_width = vf_size_x;
 446         vid_height = vf_size_y;
 447
 448         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 449         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 450
 451         WaypointSprite_Load();
 452
 453         CSQCPlayer_SetCamera();
 454
 455 #ifdef COMPAT_XON050_ENGINE
 456         if(spectatee_status)
 457                 myteam = GetPlayerColor(spectatee_status - 1);
 458         else
 459 #endif
 460                 myteam = GetPlayerColor(player_localentnum - 1);
 461
 462         if(myteam != prev_myteam)
 463         {
 464                 myteamcolors = colormapPaletteColor(myteam, 1);
 465                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 466                         hud_panel[i].update_time = time;
 467                 prev_myteam = myteam;
 468         }
 469
 470         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 471
 472         float is_dead = (getstati(STAT_HEALTH) <= 0);
 473
 474         // FIXME do we need this hack?
 475         if(isdemo())
 476         {
 477                 // in demos, input_buttons do not work
 478                 button_zoom = (autocvar__togglezoom == "-");
 479         }
 480         else if(button_zoom
 481                 && autocvar_cl_unpress_zoom_on_death
 482                 && (spectatee_status >= 0)
 483                 && (is_dead || intermission))
 484         {
 485                 // no zoom while dead or in intermission please
 486                 localcmd("-zoom\n");
 487                 button_zoom = FALSE;
 488         }
 489
 490         // event chase camera
 491         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 492         {
 493                 if(((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission) && !autocvar_cl_orthoview)
 494                 {
 495                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 496                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 497
 498                         // detect maximum viewoffset and use it
 499                         if(autocvar_cl_eventchase_viewoffset)
 500                         {
 501                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 502                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 503                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 504                         }
 505
 506                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 507                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 508                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 509                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 510
 511                         // make the camera smooth back
 512                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 513                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 514                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 515                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 516
 517                         makevectors(view_angles);
 518
 519                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 520                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 521
 522                         // If the boxtrace fails, revert back to line tracing.
 523                         if(trace_startsolid)
 524                         {
 525                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 526                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 527                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 528                         }
 529                         else { setproperty(VF_ORIGIN, trace_endpos); }
 530
 531                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 532                 }
 533                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 534                 {
 535                         cvar_set("chase_active", "0");
 536                         eventchase_current_distance = 0; // start from 0 next time
 537                 }
 538         }
 539         // workaround for camera stuck between player's legs when using chase_active 1
 540         // because the engine stops updating the chase_active camera when the game ends
 541         else if(intermission)
 542         {
 543                 cvar_settemp("chase_active", "-1");
 544                 eventchase_current_distance = 0;
 545         }
 546
 547         // do lockview after event chase camera so that it still applies whenever necessary.
 548         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 549         {
 550                 setproperty(VF_ORIGIN, freeze_org);
 551                 setproperty(VF_ANGLES, freeze_ang);
 552         }
 553         else
 554         {
 555                 freeze_org = getpropertyvec(VF_ORIGIN);
 556                 freeze_ang = getpropertyvec(VF_ANGLES);
 557         }
 558
 559         WarpZone_FixView();
 560         //WarpZone_FixPMove();
 561
 562         vector ov_org = '0 0 0';
 563         vector ov_mid = '0 0 0';
 564         vector ov_worldmin = '0 0 0';
 565         vector ov_worldmax = '0 0 0';
 566         if(autocvar_cl_orthoview)
 567         {
 568                 ov_worldmin = mi_picmin;
 569                 ov_worldmax = mi_picmax;
 570
 571                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
 572                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
 573                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
 574
 575                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
 576                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
 577
 578                 float ov_nearest = vlen(ov_org - vec3(
 579                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
 580                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
 581                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
 582                 ));
 583
 584                 float ov_furthest = 0;
 585                 float dist = 0;
 586
 587                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 588                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 589                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 590                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 591                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 592                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 593                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 594                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 595
 596                 cvar_settemp("r_nearclip", ftos(ov_nearest));
 597                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
 598                 cvar_settemp("r_farclip_world", "0");
 599                 cvar_settemp("r_novis", "1");
 600                 cvar_settemp("r_useportalculling", "0");
 601                 cvar_settemp("r_useinfinitefarclip", "0");
 602
 603                 setproperty(VF_ORIGIN, ov_org);
 604                 setproperty(VF_ANGLES, '90 0 0');
 605
 606                 #if 0
 607                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
 608                         vtos(ov_org),
 609                         vtos(getpropertyvec(VF_ANGLES)),
 610                         ov_distance,
 611                         ov_nearest,
 612                         ov_furthest);
 613                 #endif
 614         }
 615
 616         // Render the Scene
 617         view_origin = getpropertyvec(VF_ORIGIN);
 618         view_angles = getpropertyvec(VF_ANGLES);
 619         makevectors(view_angles);
 620         view_forward = v_forward;
 621         view_right = v_right;
 622         view_up = v_up;
 623
 624 #ifdef BLURTEST
 625         if(time > blurtest_time0 && time < blurtest_time1)
 626         {
 627                 float r, t;
 628
 629                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 630                 r = t * blurtest_radius;
 631                 f = 1 / pow(t, blurtest_power) - 1;
 632
 633                 cvar_set("r_glsl_postprocess", "1");
 634                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 635         }
 636         else
 637         {
 638                 cvar_set("r_glsl_postprocess", "0");
 639                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 640         }
 641 #endif
 642
 643         TargetMusic_Advance();
 644         Fog_Force();
 645
 646         if(drawtime == 0)
 647                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 648         else
 649                 drawframetime = bound(0.000001, time - drawtime, 1);
 650         drawtime = time;
 651
 652         // watch for gametype changes here...
 653         // in ParseStuffCMD the cmd isn't executed yet :/
 654         // might even be better to add the gametype to TE_CSQC_INIT...?
 655         if(!postinit)
 656                 PostInit();
 657
 658         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 659         {
 660                 if(calledhooks & HOOK_START)
 661                 {
 662                         localcmd("\ncl_hook_gameend\n");
 663                         calledhooks |= HOOK_END;
 664                 }
 665         }
 666
 667         Announcer();
 668
 669         fov = autocvar_fov;
 670         if(fov <= 59.5)
 671         {
 672                 if(!zoomscript_caught)
 673                 {
 674                         localcmd("+button9\n");
 675                         zoomscript_caught = 1;
 676                 }
 677         }
 678         else
 679         {
 680                 if(zoomscript_caught)
 681                 {
 682                         localcmd("-button9\n");
 683                         zoomscript_caught = 0;
 684                 }
 685         }
 686
 687         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 688
 689         // next WANTED weapon (for HUD)
 690         switchweapon = getstati(STAT_SWITCHWEAPON);
 691
 692         // currently switching-to weapon (for crosshair)
 693         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 694
 695         // actually active weapon (for zoom)
 696         activeweapon = getstati(STAT_ACTIVEWEAPON);
 697
 698         f = (serverflags & SERVERFLAG_TEAMPLAY);
 699         if(f != teamplay)
 700         {
 701                 teamplay = f;
 702                 HUD_InitScores();
 703         }
 704
 705         if(last_switchweapon != switchweapon)
 706         {
 707                 weapontime = time;
 708                 last_switchweapon = switchweapon;
 709                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 710                 {
 711                         localcmd("-zoom\n");
 712                         button_zoom = FALSE;
 713                 }
 714                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 715                 {
 716                         localcmd("-fire\n");
 717                         localcmd("-fire2\n");
 718                         button_attack2 = FALSE;
 719                 }
 720         }
 721         if(last_activeweapon != activeweapon)
 722         {
 723                 last_activeweapon = activeweapon;
 724
 725                 e = get_weaponinfo(activeweapon);
 726                 if(e.netname != "")
 727                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 728                 else
 729                         localcmd("\ncl_hook_activeweapon none\n");
 730         }
 731
 732         // ALWAYS Clear Current Scene First
 733         clearscene();
 734 #ifdef WORKAROUND_XON010
 735         if(checkextension("DP_CSQC_ROTATEMOVES"))
 736         {
 737 #endif
 738         setproperty(VF_ORIGIN, view_origin);
 739         setproperty(VF_ANGLES, view_angles);
 740 #ifdef WORKAROUND_XON010
 741         }
 742 #endif
 743
 744         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 745         setproperty(VF_SIZE, vf_size);
 746         setproperty(VF_MIN, vf_min);
 747
 748         // Assign Standard Viewflags
 749         // Draw the World (and sky)
 750         setproperty(VF_DRAWWORLD, 1);
 751
 752         // Set the console size vars
 753         vid_conwidth = autocvar_vid_conwidth;
 754         vid_conheight = autocvar_vid_conheight;
 755         vid_pixelheight = autocvar_vid_pixelheight;
 756
 757         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
 758         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 759
 760         // Camera for demo playback
 761         if(camera_active)
 762         {
 763                 if(autocvar_camera_enable)
 764                         CSQC_Demo_Camera();
 765                 else
 766                 {
 767                         cvar_set("chase_active", ftos(chase_active_backup));
 768                         cvar_set("cl_demo_mousegrab", "0");
 769                         camera_active = FALSE;
 770                 }
 771         }
 772 #ifdef CAMERATEST
 773         else if(autocvar_camera_enable)
 774 #else
 775         else if(autocvar_camera_enable && isdemo())
 776 #endif
 777         {
 778                 // Enable required Darkplaces cvars
 779                 chase_active_backup = autocvar_chase_active;
 780                 cvar_set("chase_active", "2");
 781                 cvar_set("cl_demo_mousegrab", "1");
 782                 camera_active = TRUE;
 783                 camera_mode = FALSE;
 784         }
 785
 786         // Draw the Crosshair
 787         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 788
 789         // Draw the Engine Status Bar (the default Quake HUD)
 790         setproperty(VF_DRAWENGINESBAR, 0);
 791
 792         // Update the mouse position
 793         /*
 794            mousepos_x = vid_conwidth;
 795            mousepos_y = vid_conheight;
 796            mousepos = mousepos*0.5 + getmousepos();
 797          */
 798
 799         e = self;
 800         for(self = world; (self = nextent(self)); )
 801                 if(self.draw)
 802                         self.draw();
 803         self = e;
 804
 805         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 806         renderscene();
 807
 808         // now switch to 2D drawing mode by calling a 2D drawing function
 809         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 810         // next R_RenderScene call
 811         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 812
 813         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 814         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 815         {
 816                 // apply night vision effect
 817                 vector tc_00, tc_01, tc_10, tc_11;
 818                 vector rgb;
 819                 rgb_x = 0; // fteqcc sucks
 820                 rgb_y = 0; // fteqcc sucks
 821                 rgb_z = 0; // fteqcc sucks
 822
 823                 if(!nightvision_noise)
 824                 {
 825                         nightvision_noise = spawn();
 826                         nightvision_noise.classname = "nightvision_noise";
 827                 }
 828                 if(!nightvision_noise2)
 829                 {
 830                         nightvision_noise2 = spawn();
 831                         nightvision_noise2.classname = "nightvision_noise2";
 832                 }
 833
 834                 // color tint in yellow
 835                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 836
 837                 // draw BG
 838                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 839                 rgb = '1 1 1';
 840                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 841                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 842                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 843                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 844                 tc_11 = tc_01 + tc_10 - tc_00;
 845                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 846                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 847                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 848                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 849                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 850                 R_EndPolygon();
 851
 852                 // draw FG
 853                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 854                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 855                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 856                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 857                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 858                 tc_11 = tc_01 + tc_10 - tc_00;
 859                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 860                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 861                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 862                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 863                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 864                 R_EndPolygon();
 865         }
 866
 867         // Draw the aiming reticle for weapons that use it
 868         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 869         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 870         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 871         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 872                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 873         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
 874                 reticle_type = 2; // nex zoom
 875         else if(button_zoom || zoomscript_caught)
 876                 reticle_type = 1; // normal zoom
 877         else if((activeweapon == WEP_NEX) && button_attack2)
 878                 reticle_type = 2; // nex zoom
 879
 880         if(reticle_type && autocvar_cl_reticle)
 881         {
 882                 if(autocvar_cl_reticle_stretch)
 883                 {
 884                         reticle_size_x = vid_conwidth;
 885                         reticle_size_y = vid_conheight;
 886                         reticle_pos_x = 0;
 887                         reticle_pos_y = 0;
 888                 }
 889                 else
 890                 {
 891                         reticle_size_x = max(vid_conwidth, vid_conheight);
 892                         reticle_size_y = max(vid_conwidth, vid_conheight);
 893                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 894                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 895                 }
 896
 897                 f = current_zoomfraction;
 898                 if(zoomscript_caught)
 899                         f = 1;
 900                 if(autocvar_cl_reticle_item_normal)
 901                 {
 902                         if(reticle_type == 1 && f)
 903                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 904                 }
 905                 if(autocvar_cl_reticle_item_nex)
 906                 {
 907                         if(reticle_type == 2 && f)
 908                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 909                 }
 910         }
 911
 912
 913         // improved polyblend
 914         if(autocvar_hud_contents)
 915         {
 916                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 917                 vector liquidcolor;
 918
 919                 switch(pointcontents(view_origin))
 920                 {
 921                         case CONTENT_WATER:
 922                                 liquidalpha = autocvar_hud_contents_water_alpha;
 923                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 924                                 incontent = 1;
 925                                 break;
 926
 927                         case CONTENT_LAVA:
 928                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 929                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 930                                 incontent = 1;
 931                                 break;
 932
 933                         case CONTENT_SLIME:
 934                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 935                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 936                                 incontent = 1;
 937                                 break;
 938
 939                         default:
 940                                 liquidalpha = 0;
 941                                 liquidcolor = '0 0 0';
 942                                 incontent = 0;
 943                                 break;
 944                 }
 945
 946                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 947                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 948                         contentfadetime = autocvar_hud_contents_fadeintime;
 949                         liquidalpha_prev = liquidalpha;
 950                         liquidcolor_prev = liquidcolor;
 951                 }
 952                 else
 953                         contentfadetime = autocvar_hud_contents_fadeouttime;
 954
 955                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 956                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 957
 958                 if(contentavgalpha)
 959                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 960
 961                 if(autocvar_hud_postprocessing)
 962                 {
 963                         if(autocvar_hud_contents_blur && contentavgalpha)
 964                         {
 965                                 content_blurpostprocess_x = 1;
 966                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 967                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 968                         }
 969                         else
 970                         {
 971                                 content_blurpostprocess_x = 0;
 972                                 content_blurpostprocess_y = 0;
 973                                 content_blurpostprocess_z = 0;
 974                         }
 975                 }
 976         }
 977
 978         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 979         {
 980                 splash_size_x = max(vid_conwidth, vid_conheight);
 981                 splash_size_y = max(vid_conwidth, vid_conheight);
 982                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 983                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 984
 985                 float myhealth_flash_temp;
 986                 myhealth = getstati(STAT_HEALTH);
 987
 988                 // fade out
 989                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 990                 // add new damage
 991                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 992
 993                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 994                 pain_threshold = autocvar_hud_damage_pain_threshold;
 995                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 996                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 997
 998                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 999                 {
1000                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1001                 }
1002
1003                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1004
1005                 if(myhealth_prev < 1)
1006                 {
1007                         if(myhealth >= 1)
1008                         {
1009                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1010                                 myhealth_flash_temp = 0;
1011                         }
1012                         else
1013                         {
1014                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1015                         }
1016                 }
1017
1018                 if(spectatee_status == -1 || intermission)
1019                 {
1020                         myhealth_flash = 0; // observing, or match ended
1021                         myhealth_flash_temp = 0;
1022                 }
1023
1024                 myhealth_prev = myhealth;
1025
1026                 // IDEA: change damage color/picture based on player model for robot/alien species?
1027                 // pro: matches model better
1028                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1029                 // maybe different reddish pics?
1030                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1031                 {
1032                         if(autocvar_cl_gentle_damage == 2)
1033                         {
1034                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1035                                 {
1036                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1037                                 }
1038                         }
1039                         else
1040                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1041
1042                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1043                 }
1044                 else
1045                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1046
1047                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1048                 {
1049                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1050                         {
1051                                 damage_blurpostprocess_x = 1;
1052                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1053                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1054                         }
1055                         else
1056                         {
1057                                 damage_blurpostprocess_x = 0;
1058                                 damage_blurpostprocess_y = 0;
1059                                 damage_blurpostprocess_z = 0;
1060                         }
1061                 }
1062         }
1063
1064         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1065         float e2 = (autocvar_hud_powerup != 0);
1066         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1067         {
1068                 // enable or disable rendering types if they are used or not
1069                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1070                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1071
1072                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1073                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1074                 {
1075                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1076                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1077                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1078                         {
1079                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1080                                 old_blurradius = blurradius;
1081                                 old_bluralpha = bluralpha;
1082                         }
1083                 }
1084                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1085                 {
1086                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1087                         old_blurradius = 0;
1088                         old_bluralpha = 0;
1089                 }
1090
1091                 // edge detection postprocess handling done second (used by hud_powerup)
1092                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1093                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1094                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1095
1096                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1097
1098                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1099                 {
1100                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1101                         {
1102                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1103                                 old_sharpen_intensity = sharpen_intensity;
1104                         }
1105                 }
1106                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1107                 {
1108                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1109                         old_sharpen_intensity = 0;
1110                 }
1111
1112                 if(cvar("r_glsl_postprocess") == 0)
1113                         cvar_set("r_glsl_postprocess", "2");
1114         }
1115         else if(cvar("r_glsl_postprocess") == 2)
1116                 cvar_set("r_glsl_postprocess", "0");
1117
1118         if(menu_visible)
1119                 menu_show();
1120
1121         /*if(gametype == MAPINFO_TYPE_CTF)
1122           {
1123           ctf_view();
1124           } else */
1125
1126         // draw 2D entities
1127         e = self;
1128         for(self = world; (self = nextent(self)); )
1129                 if(self.draw2d)
1130                         self.draw2d();
1131         self = e;
1132         Draw_ShowNames_All();
1133
1134         scoreboard_active = HUD_WouldDrawScoreboard();
1135
1136         hit_time = getstatf(STAT_HIT_TIME);
1137         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1138         {
1139                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1140                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1141
1142                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1143         }
1144         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1145         if(typehit_time > nextsound_typehit_time)
1146         {
1147                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1148                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1149
1150                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1151         }
1152
1153         //else
1154         {
1155                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1156                 {
1157                         if(getstati(STAT_FROZEN))
1158                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1159                         if(getstatf(STAT_REVIVE_PROGRESS))
1160                         {
1161                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1162                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1163                         }
1164                 }
1165
1166                 if(autocvar_r_letterbox == 0)
1167                         if(autocvar_viewsize < 120)
1168                                 CSQC_common_hud();
1169
1170                 // crosshair goes VERY LAST
1171                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1172                 {
1173                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1174                                 return;
1175
1176                         string wcross_style;
1177                         float wcross_alpha, wcross_resolution;
1178                         wcross_style = autocvar_crosshair;
1179                         if (wcross_style == "0")
1180                                 return;
1181                         wcross_resolution = autocvar_crosshair_size;
1182                         if (wcross_resolution == 0)
1183                                 return;
1184                         wcross_alpha = autocvar_crosshair_alpha;
1185                         if (wcross_alpha == 0)
1186                                 return;
1187
1188                         // TrueAim check
1189                         float shottype;
1190
1191                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1192                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1193                         wcross_origin_z = 0;
1194                         if(autocvar_crosshair_hittest)
1195                         {
1196                                 vector wcross_oldorigin;
1197                                 wcross_oldorigin = wcross_origin;
1198                                 shottype = TrueAimCheck();
1199                                 if(shottype == SHOTTYPE_HITWORLD)
1200                                 {
1201                                         v = wcross_origin - wcross_oldorigin;
1202                                         v_x /= vid_conwidth;
1203                                         v_y /= vid_conheight;
1204                                         if(vlen(v) > 0.01)
1205                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1206                                 }
1207                                 if(!autocvar_crosshair_hittest_showimpact)
1208                                         wcross_origin = wcross_oldorigin;
1209                         }
1210                         else
1211                                 shottype = SHOTTYPE_HITWORLD;
1212
1213                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1214                         string wcross_wep = "", wcross_name;
1215                         float wcross_scale, wcross_blur;
1216
1217                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1218                         {
1219                                 e = get_weaponinfo(switchingweapon);
1220                                 if (e && e.netname != "")
1221                                 {
1222                                         wcross_wep = e.netname;
1223                                         if(autocvar_crosshair_per_weapon)
1224                                         {
1225                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1226                                                 if (wcross_resolution == 0)
1227                                                         return;
1228                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1229                                                 if (wcross_alpha == 0)
1230                                                         return;
1231
1232                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1233                                                 if(wcross_style == "" || wcross_style == "0")
1234                                                         wcross_style = wcross_wep;
1235                                         }
1236                                 }
1237                         }
1238
1239                         //printf("crosshair style: %s\n", wcross_style);
1240                         wcross_name = strcat("gfx/crosshair", wcross_style);
1241
1242                         // MAIN CROSSHAIR COLOR DECISION
1243                         switch(autocvar_crosshair_color_special)
1244                         {
1245                                 case 1: // crosshair_color_per_weapon
1246                                 {
1247                                         if(wcross_wep != "")
1248                                         {
1249                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1250                                                 break;
1251                                         }
1252                                         else { goto normalcolor; }
1253                                 }
1254
1255                                 case 2: // crosshair_color_by_health
1256                                 {
1257                                         float x = getstati(STAT_HEALTH);
1258
1259                                         //x = red
1260                                         //y = green
1261                                         //z = blue
1262
1263                                         wcross_color_z = 0;
1264
1265                                         if(x > 200)
1266                                         {
1267                                                 wcross_color_x = 0;
1268                                                 wcross_color_y = 1;
1269                                         }
1270                                         else if(x > 150)
1271                                         {
1272                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1273                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1274                                         }
1275                                         else if(x > 100)
1276                                         {
1277                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1278                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1279                                                 wcross_color_z = 1 - (x-100)*0.02;
1280                                         }
1281                                         else if(x > 50)
1282                                         {
1283                                                 wcross_color_x = 1;
1284                                                 wcross_color_y = 1;
1285                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1286                                         }
1287                                         else if(x > 20)
1288                                         {
1289                                                 wcross_color_x = 1;
1290                                                 wcross_color_y = (x-20)*90/27/100;
1291                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1292                                         }
1293                                         else
1294                                         {
1295                                                 wcross_color_x = 1;
1296                                                 wcross_color_y = 0;
1297                                         }
1298                                         break;
1299                                 }
1300
1301                                 case 3: // crosshair_color_rainbow
1302                                 {
1303                                         if(time >= rainbow_last_flicker)
1304                                         {
1305                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1306                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1307                                         }
1308                                         wcross_color = rainbow_prev_color;
1309                                         break;
1310                                 }
1311                                 :normalcolor
1312                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1313                         }
1314
1315                         if(autocvar_crosshair_effect_scalefade)
1316                         {
1317                                 wcross_scale = wcross_resolution;
1318                                 wcross_resolution = 1;
1319                         }
1320                         else
1321                         {
1322                                 wcross_scale = 1;
1323                         }
1324
1325                         if(autocvar_crosshair_pickup)
1326                         {
1327                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1328
1329                                 if(pickup_crosshair_time < stat_pickup_time)
1330                                 {
1331                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1332                                                 pickup_crosshair_size = 1;
1333
1334                                         pickup_crosshair_time = stat_pickup_time;
1335                                 }
1336
1337                                 if(pickup_crosshair_size > 0)
1338                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1339                                 else
1340                                         pickup_crosshair_size = 0;
1341
1342                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1343                         }
1344
1345                         if(autocvar_crosshair_hitindication)
1346                         {
1347                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1348
1349                                 if(hitindication_crosshair_time < hit_time)
1350                                 {
1351                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1352                                                 hitindication_crosshair_size = 1;
1353
1354                                         hitindication_crosshair_time = hit_time;
1355                                 }
1356
1357                                 if(hitindication_crosshair_size > 0)
1358                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1359                                 else
1360                                         hitindication_crosshair_size = 0;
1361
1362                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1363                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1364                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1365                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1366                         }
1367
1368                         if(shottype == SHOTTYPE_HITENEMY)
1369                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1370                         if(shottype == SHOTTYPE_HITTEAM)
1371                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1372
1373                         f = fabs(autocvar_crosshair_effect_time);
1374                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1375                         {
1376                                 wcross_changedonetime = time + f;
1377                         }
1378                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1379                         {
1380                                 wcross_name_changestarttime = time;
1381                                 wcross_name_changedonetime = time + f;
1382                                 if(wcross_name_goal_prev_prev)
1383                                         strunzone(wcross_name_goal_prev_prev);
1384                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1385                                 wcross_name_goal_prev = strzone(wcross_name);
1386                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1387                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1388                                 wcross_resolution_goal_prev = wcross_resolution;
1389                         }
1390
1391                         wcross_scale_goal_prev = wcross_scale;
1392                         wcross_alpha_goal_prev = wcross_alpha;
1393                         wcross_color_goal_prev = wcross_color;
1394
1395                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1396                         {
1397                                 wcross_blur = 1;
1398                                 wcross_alpha *= 0.75;
1399                         }
1400                         else
1401                                 wcross_blur = 0;
1402                         // *_prev is at time-frametime
1403                         // * is at wcross_changedonetime+f
1404                         // what do we have at time?
1405                         if(time < wcross_changedonetime)
1406                         {
1407                                 f = frametime / (wcross_changedonetime - time + frametime);
1408                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1409                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1410                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1411                         }
1412
1413                         wcross_scale_prev = wcross_scale;
1414                         wcross_alpha_prev = wcross_alpha;
1415                         wcross_color_prev = wcross_color;
1416
1417                         wcross_scale *= 1 - autocvar__menu_alpha;
1418                         wcross_alpha *= 1 - autocvar__menu_alpha;
1419                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1420
1421                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1422                         {
1423                                 // crosshair rings for weapon stats
1424                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1425                                 {
1426                                         // declarations and stats
1427                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1428                                         string ring_image = string_null, ring_inner_image = string_null;
1429                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1430
1431                                         ring_scale = autocvar_crosshair_ring_size;
1432
1433                                         float weapon_clipload, weapon_clipsize;
1434                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1435                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1436
1437                                         float nex_charge, nex_chargepool;
1438                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1439                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1440
1441                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1442                                                 nex_charge_movingavg = nex_charge;
1443
1444
1445                                         // handle the values
1446                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1447                                         {
1448                                                 if (nex_chargepool || use_nex_chargepool) {
1449                                                         use_nex_chargepool = 1;
1450                                                         ring_inner_value = nex_chargepool;
1451                                                 } else {
1452                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1453                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1454                                                 }
1455
1456                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1457                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1458                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1459
1460                                                 // draw the outer ring to show the current charge of the weapon
1461                                                 ring_value = nex_charge;
1462                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1463                                                 ring_rgb = wcross_color;
1464                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1465                                         }
1466                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1467                                         {
1468                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1469                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1470                                                 ring_rgb = wcross_color;
1471                                                 ring_image = "gfx/crosshair_ring.tga";
1472                                         }
1473                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1474                                         {
1475                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1476                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1477                                                 ring_rgb = wcross_color;
1478                                                 ring_image = "gfx/crosshair_ring.tga";
1479                                         }
1480
1481                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1482                                         {
1483                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1484                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1485                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1486                                                 ring_rgb = wcross_color;
1487
1488                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1489                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1490                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1491                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1492                                                 else
1493                                                         ring_image = "gfx/crosshair_ring.tga";
1494                                         }
1495
1496                                         // if in weapon switch animation, fade ring out/in
1497                                         if(autocvar_crosshair_effect_time > 0)
1498                                         {
1499                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1500                                                 if (!(f < 1))
1501                                                 {
1502                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1503                                                 }
1504
1505                                                 if(wcross_ring_prev)
1506                                                 {
1507                                                         if(f < 1)
1508                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1509                                                 }
1510                                                 else
1511                                                 {
1512                                                         if(f < 1)
1513                                                                 ring_alpha *= bound(0, f, 1);
1514                                                 }
1515                                         }
1516
1517                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1518                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1519
1520                                         if (ring_value)
1521                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1522                                 }
1523
1524 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1525                                 do \
1526                                 { \
1527                                         if(wcross_blur > 0) \
1528                                         { \
1529                                                 for(i = -2; i <= 2; ++i) \
1530                                                 for(j = -2; j <= 2; ++j) \
1531                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1532                                         } \
1533                                         else \
1534                                         { \
1535                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1536                                         } \
1537                                 } \
1538                                 while(0)
1539
1540 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1541                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1542
1543 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1544                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1545
1546                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1547                                 {
1548                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1549                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1550                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1551                                         f = 1 - f;
1552                                 }
1553                                 else
1554                                 {
1555                                         f = 1;
1556                                 }
1557                                 wcross_name_alpha_goal_prev = f;
1558
1559                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1560                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1561
1562                                 if(autocvar_crosshair_dot)
1563                                 {
1564                                         vector wcross_color_old;
1565                                         wcross_color_old = wcross_color;
1566
1567                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1568                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1569
1570                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1571                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1572                                         wcross_color = wcross_color_old;
1573                                 }
1574                         }
1575                 }
1576                 else
1577                 {
1578                         wcross_scale_prev = 0;
1579                         wcross_alpha_prev = 0;
1580                         wcross_scale_goal_prev = 0;
1581                         wcross_alpha_goal_prev = 0;
1582                         wcross_changedonetime = 0;
1583                         if(wcross_name_goal_prev)
1584                                 strunzone(wcross_name_goal_prev);
1585                         wcross_name_goal_prev = string_null;
1586                         if(wcross_name_goal_prev_prev)
1587                                 strunzone(wcross_name_goal_prev_prev);
1588                         wcross_name_goal_prev_prev = string_null;
1589                         wcross_name_changestarttime = 0;
1590                         wcross_name_changedonetime = 0;
1591                         wcross_name_alpha_goal_prev = 0;
1592                         wcross_name_alpha_goal_prev_prev = 0;
1593                         wcross_resolution_goal_prev = 0;
1594                         wcross_resolution_goal_prev_prev = 0;
1595                 }
1596         }
1597
1598         if(NextFrameCommand)
1599         {
1600                 localcmd("\n", NextFrameCommand, "\n");
1601                 NextFrameCommand = string_null;
1602         }
1603
1604         // we must do this check AFTER a frame was rendered, or it won't work
1605         if(cs_project_is_b0rked == 0)
1606         {
1607                 string w0, h0;
1608                 w0 = ftos(autocvar_vid_conwidth);
1609                 h0 = ftos(autocvar_vid_conheight);
1610                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1611                 //setproperty(VF_FOV, '90 90 0');
1612                 setproperty(VF_ORIGIN, '0 0 0');
1613                 setproperty(VF_ANGLES, '0 0 0');
1614                 setproperty(VF_PERSPECTIVE, 1);
1615                 makevectors('0 0 0');
1616                 vector v1, v2;
1617                 cvar_set("vid_conwidth", "800");
1618                 cvar_set("vid_conheight", "600");
1619                 v1 = cs_project(v_forward);
1620                 cvar_set("vid_conwidth", "640");
1621                 cvar_set("vid_conheight", "480");
1622                 v2 = cs_project(v_forward);
1623                 if(v1 == v2)
1624                         cs_project_is_b0rked = 1;
1625                 else
1626                         cs_project_is_b0rked = -1;
1627                 cvar_set("vid_conwidth", w0);
1628                 cvar_set("vid_conheight", h0);
1629         }
1630
1631         if(autocvar__hud_configure)
1632                 HUD_Panel_Mouse();
1633
1634     if(hud && !intermission)
1635                 VEH_ACTION(hud, VR_HUD);
1636
1637         cl_notice_run();
1638
1639         // let's reset the view back to normal for the end
1640         setproperty(VF_MIN, '0 0 0');
1641         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1642 }
1643
1644
1645 void CSQC_common_hud(void)
1646 {
1647         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1648                 Accuracy_LoadLevels();
1649
1650         HUD_Main(); // always run these functions for alpha checks
1651         HUD_DrawScoreboard();
1652
1653         if (scoreboard_active) // scoreboard/accuracy
1654                 HUD_Reset();
1655         else if (intermission == 2) // map voting screen
1656         {
1657                 MapVote_Draw();
1658                 HUD_Reset();
1659         }
1660 }
1661
1662
1663 // following vectors must be global to allow seamless switching between camera modes
1664 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1665 void CSQC_Demo_Camera()
1666 {
1667         float speed, attenuation, dimensions;
1668         vector tmp, delta;
1669
1670         if( autocvar_camera_reset || !camera_mode )
1671         {
1672                 camera_offset = '0 0 0';
1673                 current_angles = '0 0 0';
1674                 camera_direction = '0 0 0';
1675                 camera_offset_z += 30;
1676                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1677                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1678                 current_origin = view_origin;
1679                 current_camera_offset  = camera_offset;
1680                 cvar_set("camera_reset", "0");
1681                 camera_mode = CAMERA_CHASE;
1682         }
1683
1684         // Camera angles
1685         if( camera_roll )
1686                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1687
1688         if(autocvar_camera_look_player)
1689         {
1690                 vector dir;
1691                 float n;
1692
1693                 dir = normalize(view_origin - current_position);
1694                 n = mouse_angles_z;
1695                 mouse_angles = vectoangles(dir);
1696                 mouse_angles_x = mouse_angles_x * -1;
1697                 mouse_angles_z = n;
1698         }
1699         else
1700         {
1701                 tmp = getmousepos() * 0.1;
1702                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1703                 {
1704                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1705                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1706                 }
1707         }
1708
1709         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1710         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1711         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1712         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1713
1714         // Fix difference when angles don't have the same sign
1715         delta = '0 0 0';
1716         if(mouse_angles_y < -60 && current_angles_y > 60)
1717                 delta = '0 360 0';
1718         if(mouse_angles_y > 60 && current_angles_y < -60)
1719                 delta = '0 -360 0';
1720
1721         if(autocvar_camera_look_player)
1722                 attenuation = autocvar_camera_look_attenuation;
1723         else
1724                 attenuation = autocvar_camera_speed_attenuation;
1725
1726         attenuation = 1 / max(1, attenuation);
1727         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1728
1729         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1730         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1731         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1732         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1733
1734         // Camera position
1735         tmp = '0 0 0';
1736         dimensions = 0;
1737
1738         if( camera_direction_x )
1739         {
1740                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1741                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1742                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1743                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1744                 ++dimensions;
1745         }
1746
1747         if( camera_direction_y )
1748         {
1749                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1750                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1751                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1752                 ++dimensions;
1753         }
1754
1755         if( camera_direction_z )
1756         {
1757                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1758                 ++dimensions;
1759         }
1760
1761         if(autocvar_camera_free)
1762                 speed = autocvar_camera_speed_free;
1763         else
1764                 speed = autocvar_camera_speed_chase;
1765
1766         if(dimensions)
1767         {
1768                 speed = speed * sqrt(1 / dimensions);
1769                 camera_offset += tmp * speed;
1770         }
1771
1772         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1773
1774         // Camera modes
1775         if( autocvar_camera_free )
1776         {
1777                 if ( camera_mode == CAMERA_CHASE )
1778                 {
1779                         current_camera_offset = current_origin + current_camera_offset;
1780                         camera_offset = current_origin + camera_offset;
1781                 }
1782
1783                 camera_mode = CAMERA_FREE;
1784                 current_position = current_camera_offset;
1785         }
1786         else
1787         {
1788                 if ( camera_mode == CAMERA_FREE )
1789                 {
1790                         current_origin = view_origin;
1791                         camera_offset = camera_offset - current_origin;
1792                         current_camera_offset = current_camera_offset - current_origin;
1793                 }
1794
1795                 camera_mode = CAMERA_CHASE;
1796
1797                 if(autocvar_camera_chase_smoothly)
1798                         current_origin += (view_origin - current_origin) * attenuation;
1799                 else
1800                         current_origin = view_origin;
1801
1802                 current_position = current_origin + current_camera_offset;
1803         }
1804
1805         setproperty(VF_ANGLES, current_angles);
1806         setproperty(VF_ORIGIN, current_position);
1807 }