qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float view_set;
 343 float camera_mode;
 344 float reticle_type;
 345 string NextFrameCommand;
 346 void CSQC_SPIDER_HUD();
 347 void CSQC_RAPTOR_HUD();
 348
 349 vector freeze_pmove_org, freeze_input_angles;
 350 entity nightvision_noise, nightvision_noise2;
 351
 352 float pickup_crosshair_time, pickup_crosshair_size;
 353 float use_nex_chargepool;
 354
 355 float myhealth, myhealth_prev;
 356 float myhealth_flash;
 357
 358 vector myhealth_gentlergb;
 359
 360 float contentavgalpha;
 361
 362 void CSQC_UpdateView(float w, float h)
 363 {
 364         entity e;
 365         float fov;
 366         float f, i, j;
 367         vector v, vo;
 368         vector vf_size, vf_min;
 369         float a;
 370
 371         vf_size = R_SetView3fv(VF_SIZE);
 372         vf_min = R_SetView3fv(VF_MIN);
 373         vid_width = vf_size_x;
 374         vid_height = vf_size_y;
 375
 376         vector reticle_pos, reticle_size;
 377
 378         WaypointSprite_Load();
 379
 380         if(spectatee_status)
 381                 myteam = GetPlayerColor(spectatee_status - 1);
 382         else
 383                 myteam = GetPlayerColor(player_localentnum - 1);
 384
 385         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 386         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 387
 388         warpzone_fixview_origin = pmove_org + vo;
 389         warpzone_fixview_cl_viewangles = input_angles;
 390         warpzone_fixview_angles = view_angles;
 391         WarpZone_FixView();
 392         pmove_org = warpzone_fixview_origin - vo;
 393         input_angles = warpzone_fixview_cl_viewangles;
 394         view_angles = warpzone_fixview_angles;
 395
 396         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 397         {
 398                 pmove_org = freeze_pmove_org;
 399                 input_angles = view_angles = freeze_input_angles;
 400                 R_SetView(VF_ORIGIN, pmove_org + vo);
 401                 R_SetView(VF_ANGLES, view_angles);
 402                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 403         }
 404         freeze_pmove_org = pmove_org;
 405         freeze_input_angles = input_angles;
 406
 407         // Render the Scene
 408         if(!intermission || !view_set)
 409         {
 410                 view_origin = pmove_org + vo;
 411                 view_angles = input_angles;
 412                 makevectors(view_angles);
 413                 view_forward = v_forward;
 414                 view_right = v_right;
 415                 view_up = v_up;
 416                 view_set = 1;
 417         }
 418
 419 #ifdef BLURTEST
 420         if(time > blurtest_time0 && time < blurtest_time1)
 421         {
 422                 float r, t;
 423
 424                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 425                 r = t * blurtest_radius;
 426                 f = 1 / pow(t, blurtest_power) - 1;
 427
 428                 cvar_set("r_glsl_postprocess", "1");
 429                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 430         }
 431         else
 432         {
 433                 cvar_set("r_glsl_postprocess", "0");
 434                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 435         }
 436 #endif
 437
 438         TargetMusic_Advance();
 439         Fog_Force();
 440
 441         drawframetime = max(0.000001, time - drawtime);
 442         drawtime = time;
 443
 444         // watch for gametype changes here...
 445         // in ParseStuffCMD the cmd isn't executed yet :/
 446         // might even be better to add the gametype to TE_CSQC_INIT...?
 447         if(!postinit)
 448                 PostInit();
 449
 450         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 451                 if(calledhooks & HOOK_START)
 452                 {
 453                         localcmd("\ncl_hook_gameend\n");
 454                         calledhooks |= HOOK_END;
 455                 }
 456
 457         CheckForGamestartChange();
 458         serverAnnouncer();
 459         maptimeAnnouncer();
 460         carrierAnnouncer();
 461
 462         fov = autocvar_fov;
 463         if(button_zoom || fov <= 59.5)
 464         {
 465                 if(!zoomscript_caught)
 466                 {
 467                         localcmd("+button4\n");
 468                         zoomscript_caught = 1;
 469                         ignore_plus_zoom += 1;
 470                 }
 471         }
 472         else
 473         {
 474                 if(zoomscript_caught)
 475                 {
 476                         localcmd("-button4\n");
 477                         zoomscript_caught = 0;
 478                         ignore_minus_zoom += 1;
 479                 }
 480         }
 481
 482         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 483         activeweapon = getstati(STAT_SWITCHWEAPON);
 484         f = (serverflags & SERVERFLAG_TEAMPLAY);
 485         if(f != teamplay)
 486         {
 487                 teamplay = f;
 488                 HUD_InitScores();
 489         }
 490
 491         if(last_weapon != activeweapon) {
 492                 weapontime = time;
 493                 last_weapon = activeweapon;
 494
 495                 e = get_weaponinfo(activeweapon);
 496                 if(e.netname != "")
 497                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 498                 else
 499                         localcmd("\ncl_hook_activeweapon none\n");
 500         }
 501
 502         // ALWAYS Clear Current Scene First
 503         R_ClearScene();
 504
 505         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 506         R_SetView(VF_SIZE, vf_size);
 507         R_SetView(VF_MIN, vf_min);
 508
 509         // Assign Standard Viewflags
 510         // Draw the World (and sky)
 511         R_SetView(VF_DRAWWORLD, 1);
 512
 513         // Set the console size vars
 514         vid_conwidth = autocvar_vid_conwidth;
 515         vid_conheight = autocvar_vid_conheight;
 516         vid_pixelheight = autocvar_vid_pixelheight;
 517
 518         R_SetView(VF_FOV, GetCurrentFov(fov));
 519
 520         // Camera for demo playback
 521         if(camera_active)
 522         {
 523                 if(autocvar_camera_enable)
 524                         CSQC_Demo_Camera();
 525                 else
 526                 {
 527                         cvar_set("chase_active", ftos(chase_active_backup));
 528                         cvar_set("cl_demo_mousegrab", "0");
 529                         camera_active = FALSE;
 530                 }
 531         }
 532 #ifdef CAMERATEST
 533         else if(autocvar_camera_enable)
 534 #else
 535         else if(autocvar_camera_enable && isdemo())
 536 #endif
 537         {
 538                 // Enable required Darkplaces cvars
 539                 chase_active_backup = autocvar_chase_active;
 540                 cvar_set("chase_active", "2");
 541                 cvar_set("cl_demo_mousegrab", "1");
 542                 camera_active = TRUE;
 543                 camera_mode = FALSE;
 544         }
 545
 546         // Draw the Crosshair
 547         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 548
 549         // Draw the Engine Status Bar (the default Quake HUD)
 550         R_SetView(VF_DRAWENGINEHUD, 0);
 551
 552         // fetch this one only once per frame
 553         hud_showbinds = autocvar_hud_showbinds;
 554         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 555
 556         // Update the mouse position
 557         /*
 558            mousepos_x = vid_conwidth;
 559            mousepos_y = vid_conheight;
 560            mousepos = mousepos*0.5 + getmousepos();
 561          */
 562
 563         e = self;
 564         for(self = world; (self = nextent(self)); )
 565                 if(self.draw)
 566                         self.draw();
 567         self = e;
 568
 569         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 570         R_RenderScene();
 571
 572         // now switch to 2D drawing mode by calling a 2D drawing function
 573         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 574         // next R_RenderScene call
 575         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 576
 577         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 578         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 579         {
 580                 // apply night vision effect
 581                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 582
 583                 if(!nightvision_noise)
 584                 {
 585                         nightvision_noise = spawn();
 586                         nightvision_noise.classname = "nightvision_noise";
 587                 }
 588                 if(!nightvision_noise2)
 589                 {
 590                         nightvision_noise2 = spawn();
 591                         nightvision_noise2.classname = "nightvision_noise2";
 592                 }
 593
 594                 // color tint in yellow
 595                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 596
 597                 // draw BG
 598                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 599                 rgb = '1 1 1';
 600                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 601                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 602                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 603                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 604                 tc_11 = tc_01 + tc_10 - tc_00;
 605                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 606                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 607                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 608                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 609                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 610                 R_EndPolygon();
 611
 612                 // draw FG
 613                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 614                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 615                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 616                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 617                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 618                 tc_11 = tc_01 + tc_10 - tc_00;
 619                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 620                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 621                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 622                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 623                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 624                 R_EndPolygon();
 625         }
 626
 627         // Draw the aiming reticle for weapons that use it
 628         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 629         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 630         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 631         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 632                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 633         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 634                 reticle_type = 2; // nex zoom
 635         else if(button_zoom || zoomscript_caught)
 636                 reticle_type = 1; // normal zoom
 637         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 638                 reticle_type = 2; // nex zoom
 639
 640         if(autocvar_cl_reticle_stretch)
 641         {
 642                 reticle_size_x = vid_conwidth;
 643                 reticle_size_y = vid_conheight;
 644                 reticle_pos_x = 0;
 645                 reticle_pos_y = 0;
 646         }
 647         else
 648         {
 649                 reticle_size_x = max(vid_conwidth, vid_conheight);
 650                 reticle_size_y = max(vid_conwidth, vid_conheight);
 651                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 652                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 653         }
 654
 655         f = current_zoomfraction;
 656         if(zoomscript_caught)
 657                 f = 1;
 658         if(autocvar_cl_reticle_item_normal)
 659         {
 660                 precache_pic("gfx/reticle_normal");
 661                 if(reticle_type == 1 && f)
 662                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 663         }
 664         if(autocvar_cl_reticle_item_nex)
 665         {
 666                 precache_pic("gfx/reticle_nex");
 667                 if(reticle_type == 2 && f)
 668                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 669         }
 670
 671         // improved polyblend with post processing effects
 672         vector rgb;
 673         vector damage_blurpostprocess;
 674         vector content_blurpostprocess;
 675         if(autocvar_hud_contents)
 676         {
 677                 float contentalpha_temp, incontent, liquidalpha;
 678                 vector liquidcolor;
 679
 680                 switch(pointcontents(view_origin))
 681                 {
 682                         case CONTENT_WATER:
 683                                 liquidalpha = autocvar_hud_contents_water_alpha;
 684                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 685                                 incontent = 1;
 686                                 break;
 687
 688                         case CONTENT_LAVA:
 689                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 690                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 691                                 incontent = 1;
 692                                 break;
 693
 694                         case CONTENT_SLIME:
 695                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 696                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 697                                 incontent = 1;
 698                                 break;
 699
 700                         default:
 701                                 liquidalpha = 0;
 702                                 liquidcolor = '0 0 0';
 703                                 incontent = 0;
 704                                 break;
 705                 }
 706
 707                 contentalpha_temp = bound(0, drawframetime / max(0.0001, autocvar_hud_contents_fadetime), 1);
 708                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 709                 //contentalpha_temp = contentavgalpha;
 710
 711                 if(incontent)
 712                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor, contentavgalpha * liquidalpha, DRAWFLAG_NORMAL);
 713
 714                 if(autocvar_hud_postprocessing)
 715                 {
 716                         if(autocvar_hud_contents_blur)
 717                         {
 718                                 content_blurpostprocess_x = 1;
 719                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 720                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 721                         }
 722                         else
 723                         {
 724                                 content_blurpostprocess_x = 0;
 725                                 content_blurpostprocess_y = 0;
 726                                 content_blurpostprocess_z = 0;
 727                         }
 728                 }
 729         }
 730
 731         if(autocvar_hud_damage)
 732         {
 733                 float myhealth_flash_temp;
 734                 myhealth = getstati(STAT_HEALTH);
 735
 736                 // fade out
 737                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 738                 // add new damage
 739                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 740
 741                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 742                 pain_threshold = autocvar_hud_damage_pain_threshold;
 743                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 744                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 745
 746                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 747                 {
 748                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 749                 }
 750
 751                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 752
 753                 if(myhealth_prev < 1)
 754                 {
 755                         if(myhealth >= 1)
 756                         {
 757                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 758                                 myhealth_flash_temp = 0;
 759                         }
 760                         else
 761                         {
 762                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 763                         }
 764                 }
 765
 766                 if(spectatee_status == -1 || intermission)
 767                 {
 768                         myhealth_flash = 0; // observing, or match ended
 769                         myhealth_flash_temp = 0;
 770                 }
 771
 772                 myhealth_prev = myhealth;
 773
 774                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 775                 {
 776                         if(autocvar_cl_gentle_damage == 2)
 777                         {
 778                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 779                                 {
 780                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 781                                 }
 782                         }
 783                         else
 784                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 785
 786                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 787                 }
 788                 else if(autocvar_hud_damage_image)
 789                         drawpic(reticle_pos, "gfx/blood", reticle_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 790
 791                 if(autocvar_hud_postprocessing)
 792                 {
 793                         if(autocvar_hud_damage_blur)
 794                         {
 795                                 damage_blurpostprocess_x = 1;
 796                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 797                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 798                         }
 799                         else
 800                         {
 801                                 damage_blurpostprocess_x = 0;
 802                                 damage_blurpostprocess_y = 0;
 803                                 damage_blurpostprocess_z = 0;
 804                         }
 805                 }
 806         }
 807
 808         if(autocvar_hud_postprocessing)
 809         { // lets apply the postprocess effects from the previous two functions if needed
 810                 if(damage_blurpostprocess_x || content_blurpostprocess_x)
 811                 {
 812                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 813                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 814                         cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 815                         cvar_set("r_glsl_postprocess_uservec1_enable", "1");
 816                 }
 817                 else
 818                 {
 819                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 820                         cvar_set("r_glsl_postprocess_uservec1_enable", "0");
 821                 }
 822         }
 823
 824
 825         // Draw the mouse cursor
 826         // NOTE: drawpic must happen after R_RenderScene for some reason
 827         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 828         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 829         //self = edict_num(player_localnum);
 830         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 831         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 832         // as long as the ctf part isn't in, this is useless
 833         if(menu_visible)
 834                 menu_show();
 835
 836         /*if(gametype == GAME_CTF)
 837           {
 838           ctf_view();
 839           } else */
 840
 841         // draw 2D entities
 842         e = self;
 843         for(self = world; (self = nextent(self)); )
 844                 if(self.draw2d)
 845                         self.draw2d();
 846         self = e;
 847
 848         scoreboard_active = HUD_WouldDrawScoreboard();
 849
 850         float hud;
 851         hud = getstati(STAT_HUD);
 852         if(hud == HUD_SPIDERBOT)
 853                 CSQC_SPIDER_HUD();
 854         else if(hud == HUD_WAKIZASHI)
 855         CSQC_WAKIZASHI_HUD();
 856     else if(hud == HUD_RAPTOR)
 857         CSQC_RAPTOR_HUD();
 858         else
 859         {
 860                 if(gametype == GAME_FREEZETAG)
 861                 {
 862                         if(getstati(STAT_FROZEN))
 863                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 864                         if(getstatf(STAT_REVIVE_PROGRESS))
 865                         {
 866                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 867                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 868                         }
 869                 }
 870
 871                 if(autocvar_r_letterbox == 0)
 872                         if(autocvar_viewsize < 120)
 873                                 CSQC_common_hud();
 874
 875                 // crosshair goes VERY LAST
 876                 if(!scoreboard_active && !camera_active && intermission != 2) {
 877                         string wcross_style;
 878                         float wcross_alpha, wcross_resolution;
 879                         wcross_style = autocvar_crosshair;
 880                         if (wcross_style == "0")
 881                                 return;
 882                         wcross_resolution = autocvar_crosshair_size;
 883                         if (wcross_resolution == 0)
 884                                 return;
 885                         wcross_alpha = autocvar_crosshair_alpha;
 886                         if (wcross_alpha == 0)
 887                                 return;
 888
 889                         // TrueAim check
 890                         float shottype;
 891                         float bullets, ring_scale;
 892                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 893                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 894                         wcross_origin_z = 0;
 895                         if(autocvar_crosshair_hittest)
 896                         {
 897                                 vector wcross_oldorigin;
 898                                 wcross_oldorigin = wcross_origin;
 899                                 shottype = TrueAimCheck();
 900                                 if(shottype == SHOTTYPE_HITWORLD)
 901                                 {
 902                                         v = wcross_origin - wcross_oldorigin;
 903                                         v_x /= vid_conwidth;
 904                                         v_y /= vid_conheight;
 905                                         if(vlen(v) > 0.01)
 906                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 907                                 }
 908                                 if(!autocvar_crosshair_hittest_showimpact)
 909                                         wcross_origin = wcross_oldorigin;
 910                         }
 911                         else
 912                                 shottype = SHOTTYPE_HITWORLD;
 913
 914                         vector wcross_color, wcross_size;
 915                         string wcross_wep, wcross_name;
 916                         float wcross_scale, wcross_blur;
 917
 918                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 919                                 e = get_weaponinfo(activeweapon);
 920                                 if (e && e.netname != "")
 921                                 {
 922                                         wcross_wep = e.netname;
 923                                         if(autocvar_crosshair_per_weapon)
 924                                         {
 925                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 926                                                 if (wcross_resolution == 0)
 927                                                         return;
 928                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 929                                                 if (wcross_alpha == 0)
 930                                                         return;
 931
 932                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 933                                                 if(wcross_style == "" || wcross_style == "0")
 934                                                         wcross_style = wcross_wep;
 935                                         }
 936                                 }
 937                         }
 938                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 939                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 940                         else
 941                                 wcross_color = stov(autocvar_crosshair_color);
 942
 943                         wcross_name = strcat("gfx/crosshair", wcross_style);
 944
 945                         if(autocvar_crosshair_effect_scalefade)
 946                         {
 947                                 wcross_scale = wcross_resolution;
 948                                 wcross_resolution = 1;
 949                         }
 950                         else
 951                         {
 952                                 wcross_scale = 1;
 953                         }
 954
 955                         if(autocvar_crosshair_pickup)
 956                         {
 957                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
 958                                 {
 959                                         pickup_crosshair_size = 1;
 960                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
 961                                 }
 962
 963                                 if(pickup_crosshair_size > 0)
 964                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 965                                 else
 966                                         pickup_crosshair_size = 0;
 967
 968                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 969                         }
 970
 971                         if(shottype == SHOTTYPE_HITENEMY)
 972                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 973                         if(shottype == SHOTTYPE_HITTEAM)
 974                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 975
 976                         f = autocvar_crosshair_effect_speed;
 977                         if(f < 0)
 978                                 f *= -2 * g_weaponswitchdelay;
 979                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 980                         {
 981                                 wcross_changedonetime = time + f;
 982                         }
 983                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 984                         {
 985                                 wcross_name_changestarttime = time;
 986                                 wcross_name_changedonetime = time + f;
 987                                 if(wcross_name_goal_prev_prev)
 988                                         strunzone(wcross_name_goal_prev_prev);
 989                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
 990                                 wcross_name_goal_prev = strzone(wcross_name);
 991                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 992                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 993                                 wcross_resolution_goal_prev = wcross_resolution;
 994                         }
 995
 996                         wcross_scale_goal_prev = wcross_scale;
 997                         wcross_alpha_goal_prev = wcross_alpha;
 998                         wcross_color_goal_prev = wcross_color;
 999
1000                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1001                         {
1002                                 wcross_blur = 1;
1003                                 wcross_alpha *= 0.75;
1004                         }
1005                         else
1006                                 wcross_blur = 0;
1007                         // *_prev is at time-frametime
1008                         // * is at wcross_changedonetime+f
1009                         // what do we have at time?
1010                         if(time < wcross_changedonetime)
1011                         {
1012                                 f = frametime / (wcross_changedonetime - time + frametime);
1013                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1014                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1015                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1016                         }
1017
1018                         wcross_scale_prev = wcross_scale;
1019                         wcross_alpha_prev = wcross_alpha;
1020                         wcross_color_prev = wcross_color;
1021
1022                         wcross_scale *= 1 - autocvar__menu_alpha;
1023                         wcross_alpha *= 1 - autocvar__menu_alpha;
1024
1025                         ring_scale = autocvar_crosshair_ring_size;
1026
1027                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1028
1029                         float nex_charge, nex_chargepool;
1030                         nex_charge = getstatf(STAT_NEX_CHARGE);
1031                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1032
1033                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1034                                 nex_charge_movingavg = nex_charge;
1035
1036                         // ring around crosshair representing bullets left in camping rifle clip
1037                         if (activeweapon == WEP_SNIPERRIFLE && cr_maxbullets)
1038                         {
1039                                 bullets = getstati(STAT_BULLETS_LOADED);
1040                                 f = bound(0, bullets / cr_maxbullets, 1);
1041
1042                                 a = autocvar_crosshair_ring_sniperrifle_alpha;
1043                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1044                         }
1045                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
1046                         {
1047                                 if(nex_chargepool || use_nex_chargepool)
1048                                 {
1049                                         use_nex_chargepool = 1;
1050
1051                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1052                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1053                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", nex_chargepool, rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1054                                 }
1055                                 else
1056                                 {
1057                                         // indicate how much we're charging right now with an inner circle
1058                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1059                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1060
1061                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1062                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1063                                 }
1064
1065                                 // draw the charge
1066                                 a = autocvar_crosshair_ring_nex_outer_alpha;
1067                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1068                         }
1069
1070 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1071                         do \
1072                         { \
1073                                 if(wcross_blur > 0) \
1074                                 { \
1075                                         for(i = -2; i <= 2; ++i) \
1076                                                 for(j = -2; j <= 2; ++j) \
1077                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1078                                 } \
1079                                 else \
1080                                 { \
1081                                         M(0,0,sz,wcross_name,wcross_alpha); \
1082                                 } \
1083                         } \
1084                         while(0)
1085
1086 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1087                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1088
1089 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1090                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1091
1092                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1093                         {
1094                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1095                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1096                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1097                                 f = 1 - f;
1098                         }
1099                         else
1100                         {
1101                                 f = 1;
1102                         }
1103
1104                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1105                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1106
1107                         if(autocvar_crosshair_dot)
1108             {
1109                 vector wcross_color_old;
1110                 wcross_color_old = wcross_color;
1111                 if(autocvar_crosshair_dot_color != "0")
1112                     wcross_color = stov(autocvar_crosshair_dot_color);
1113                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1114                 wcross_color = wcross_color_old;
1115             }
1116
1117                         wcross_name_alpha_goal_prev = f;
1118                 }
1119                 else
1120                 {
1121                         wcross_scale_prev = 0;
1122                         wcross_alpha_prev = 0;
1123                         wcross_scale_goal_prev = 0;
1124                         wcross_alpha_goal_prev = 0;
1125                         wcross_changedonetime = 0;
1126                         if(wcross_name_goal_prev)
1127                                 strunzone(wcross_name_goal_prev);
1128                         wcross_name_goal_prev = string_null;
1129                         if(wcross_name_goal_prev_prev)
1130                                 strunzone(wcross_name_goal_prev_prev);
1131                         wcross_name_goal_prev_prev = string_null;
1132                         wcross_name_changestarttime = 0;
1133                         wcross_name_changedonetime = 0;
1134                         wcross_name_alpha_goal_prev = 0;
1135                         wcross_name_alpha_goal_prev_prev = 0;
1136                         wcross_resolution_goal_prev = 0;
1137                         wcross_resolution_goal_prev_prev = 0;
1138                 }
1139         }
1140
1141         if(NextFrameCommand)
1142         {
1143                 localcmd("\n", NextFrameCommand, "\n");
1144                 NextFrameCommand = string_null;
1145         }
1146
1147         // we must do this check AFTER a frame was rendered, or it won't work
1148         if(cs_project_is_b0rked == 0)
1149         {
1150                 string w0, h0;
1151                 w0 = ftos(autocvar_vid_conwidth);
1152                 h0 = ftos(autocvar_vid_conheight);
1153                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1154                 //R_SetView(VF_FOV, '90 90 0');
1155                 R_SetView(VF_ORIGIN, '0 0 0');
1156                 R_SetView(VF_ANGLES, '0 0 0');
1157                 R_SetView(VF_PERSPECTIVE, 1);
1158                 makevectors('0 0 0');
1159                 vector v1, v2;
1160                 cvar_set("vid_conwidth", "800");
1161                 cvar_set("vid_conheight", "600");
1162                 v1 = cs_project(v_forward);
1163                 cvar_set("vid_conwidth", "640");
1164                 cvar_set("vid_conheight", "480");
1165                 v2 = cs_project(v_forward);
1166                 if(v1 == v2)
1167                         cs_project_is_b0rked = 1;
1168                 else
1169                         cs_project_is_b0rked = -1;
1170                 cvar_set("vid_conwidth", w0);
1171                 cvar_set("vid_conheight", h0);
1172         }
1173
1174         if(autocvar__hud_configure)
1175                 HUD_Panel_Mouse();
1176
1177         // let's reset the view back to normal for the end
1178         R_SetView(VF_MIN, '0 0 0');
1179         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1180 }
1181
1182 #define spider_h "gfx/vehicles/hud_bg.tga"
1183 #define spider_b "gfx/vehicles/sbot.tga"
1184 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1185 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1186 #define spider_s "gfx/vehicles/shiled.tga"
1187 #define spider_a1 "gfx/hud/sb_rocket.tga"
1188 #define spider_a2 "gfx/sb_bullets.tga"
1189
1190 void CSQC_SPIDER_HUD()
1191 {
1192         float rockets, reload, heat, hp, shield;
1193         vector picsize, hudloc;
1194
1195     // Fetch health & ammo stats
1196     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1197         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1198         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1199         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1200         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1201
1202     // Draw the crosshairs
1203     picsize = drawgetimagesize(SPIDER_CROSS);
1204     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1205     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1206     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1207
1208     hudloc_y =  4;
1209     hudloc_x = 4;
1210
1211     picsize = drawgetimagesize(spider_h) * 0.5;
1212     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1213
1214     picsize = drawgetimagesize(spider_a2) * 0.5;
1215     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1216
1217     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1218     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1219     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1220
1221     picsize = drawgetimagesize(spider_a1) * 0.85;
1222     if(rockets == 9)
1223     {
1224         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1225         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1226     }
1227     else
1228     {
1229         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1230         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1231     }
1232
1233     picsize = drawgetimagesize(spider_b) * 0.5;
1234     hudloc_y = 10.5;
1235     hudloc_x = 10.5;
1236
1237     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1238     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1239     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1240     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1241
1242
1243         /*
1244         // Draw health bar
1245         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1246         p = p + '0 1 0' * vid_conheight - '0 32 0';
1247         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1248         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1249         p_y += 8;
1250         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1251         p_x += 256 * hp;
1252         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1253
1254         // Draw minigun heat indicator
1255         p = '0.5 0 0' * (vid_conwidth - 256);
1256         p = p + '0 1 0' * vid_conheight - '0 34  0';
1257         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1258         p_x += 256 * (1-heat);
1259         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1260
1261
1262         // Draw rocket icons for loaded/empty tubes.
1263         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1264         pp += '0 1 0' * vid_conheight - '0 64 0';
1265         for(i = 0; i < 8; ++i)
1266         {
1267                 p = pp + '1 0 0' * (rkt_size * i);
1268                 if(rockets == 8)
1269                 {
1270                         if(floor(reload * 8) == i)
1271                         {
1272                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1273                         }
1274                         else if(i < reload * 8)
1275                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1276                         else
1277                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1278                 }
1279                 else
1280                 {
1281                         if(i < rockets)
1282                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1283                         else
1284                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1285                 }
1286         }
1287         */
1288
1289         if (scoreboard_showscores)
1290         {
1291                 HUD_DrawScoreboard();
1292                 HUD_DrawCenterPrint();
1293         }
1294
1295 }
1296
1297 #define raptor_h "gfx/vehicles/hud_bg.tga"
1298 #define raptor_b "gfx/vehicles/raptor.tga"
1299 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1300 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1301 #define raptor_s "gfx/vehicles/shiled.tga"
1302
1303 void CSQC_RAPTOR_HUD()
1304 {
1305         float reload, hp, shield, energy;
1306         vector picsize, hudloc;
1307
1308     // Fetch health & ammo stats
1309     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1310         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1311         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1312         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1313
1314     // Draw the crosshairs
1315     picsize = drawgetimagesize(SPIDER_CROSS);
1316     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1317     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1318     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1319
1320     hudloc_y =  4;
1321     hudloc_x = 4;
1322
1323     picsize = drawgetimagesize(raptor_h) * 0.5;
1324     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1325
1326     picsize = drawgetimagesize(spider_a2) * 0.5;
1327     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1328
1329     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1330     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1331     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1332
1333
1334     picsize = drawgetimagesize(spider_a1) * 0.85;
1335     if(reload == 1)
1336     {
1337         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1338         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1339     }
1340     else
1341     {
1342         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1343         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1344     }
1345
1346     picsize = drawgetimagesize(raptor_b) * 0.5;
1347     hudloc_y = 10.5;
1348     hudloc_x = 10.5;
1349
1350     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1351     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1352     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1353     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1354
1355
1356         if (scoreboard_showscores)
1357         {
1358                 HUD_DrawScoreboard();
1359                 HUD_DrawCenterPrint();
1360         }
1361
1362 }
1363
1364 #define waki_h "gfx/vehicles/hud_bg.tga"
1365 #define waki_b "gfx/vehicles/waki.tga"
1366 #define waki_e "gfx/vehicles/waki_e.tga"
1367 #define waki_g "gfx/vehicles/waki_guns.tga"
1368 #define waki_r "gfx/vehicles/waki_rockets.tga"
1369 #define waki_s "gfx/vehicles/shiled.tga"
1370
1371 #define waki_a1 "gfx/hud/sb_rocket.tga"
1372 #define waki_a2 "gfx/sb_cells.tga"
1373
1374 void CSQC_WAKIZASHI_HUD()
1375 {
1376         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1377         float health, shield, energy, rockets;
1378         vector picsize, hudloc;
1379
1380     picsize = drawgetimagesize(SPIDER_CROSS);
1381     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1382     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1383     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1384
1385 /*
1386 const float STAT_VEHICLESTAT_HEALTH  = 60;
1387 const float STAT_VEHICLESTAT_SHIELD  = 61;
1388 const float STAT_VEHICLESTAT_ENERGY  = 62;
1389 const float STAT_VEHICLESTAT_AMMO1   = 63;
1390 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1391 const float STAT_VEHICLESTAT_AMMO2   = 65;
1392 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1393 */
1394     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1395         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1396         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1397         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1398
1399     hudloc_y =  4;
1400     hudloc_x = 4;
1401
1402     picsize = drawgetimagesize(waki_h) * 0.5;
1403     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1404
1405     picsize = drawgetimagesize(waki_a2) * 0.7;
1406     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1407
1408
1409     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1410     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1411
1412     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1413
1414     picsize = drawgetimagesize(waki_a1) * 0.75;
1415     if(rockets == 1)
1416     {
1417         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1418         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1419     }
1420     else
1421     {
1422         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1423         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1424         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1425     }
1426
1427     picsize = drawgetimagesize(waki_b) * 0.5;
1428     hudloc_y = 10.5;
1429     hudloc_x = 10.5;
1430
1431     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1432     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1433     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1434     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1435
1436
1437
1438         /*
1439         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1440         p = p + '0 1 0' * vid_conheight - '0 32 0';
1441
1442         // Draw health bar
1443         p_y += 8;
1444         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1445         p_x += 256 * health;
1446         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1447
1448         // Draw shiled bar
1449         p_x -= 256 * health;
1450         p_y += 4;
1451         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1452
1453         // Draw energy
1454         //p_x -= 256 * health;
1455         p_y -= 8;
1456         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1457
1458         // Draw rockets bar
1459         p_y += 12;
1460         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1461         */
1462
1463
1464
1465
1466         if (scoreboard_showscores)
1467         {
1468                 HUD_DrawScoreboard();
1469                 HUD_DrawCenterPrint();
1470         }
1471
1472 }
1473
1474
1475 void CSQC_common_hud(void)
1476 {
1477         // HUD_SortFrags(); done in HUD_Draw
1478         float hud;
1479         hud = getstati(STAT_HUD);
1480
1481         //hud = 10;
1482         switch(hud)
1483         {
1484                 case HUD_NORMAL:
1485                         // do some accuracy var caching
1486                         float i;
1487                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1488                         {
1489                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1490                                 {
1491                                         if(acc_color_levels)
1492                                                 strunzone(acc_color_levels);
1493                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1494                                         acc_levels = tokenize(acc_color_levels);
1495                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1496                                                 acc_levels = MAX_ACCURACY_LEVELS;
1497
1498                                         for (i = 0; i < acc_levels; ++i)
1499                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1500                                 }
1501                                 // let know that acc_col[] needs to be loaded
1502                                 acc_col_x[0] = -1;
1503                         }
1504
1505                         HUD_Main(); // always run these functions for alpha checks
1506                         HUD_DrawScoreboard();
1507
1508                         if (scoreboard_active) // scoreboard/accuracy
1509                         {
1510                                 HUD_Reset();
1511                                 // HUD_DrawScoreboard takes care of centerprint_start
1512                         }
1513                         else if (intermission == 2) // map voting screen
1514                         {
1515                                 HUD_FinaleOverlay();
1516                                 HUD_Reset();
1517
1518                                 centerprint_start_x = 0;
1519                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1520                         }
1521                         else // hud
1522                         {
1523                                 centerprint_start_x = 0;
1524                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1525                         }
1526
1527                         HUD_DrawCenterPrint();
1528                         break;
1529
1530                 case HUD_SPIDERBOT:
1531                         CSQC_SPIDER_HUD();
1532                         break;
1533
1534                 case HUD_WAKIZASHI:
1535                         CSQC_WAKIZASHI_HUD();
1536                         break;
1537         }
1538 }
1539
1540
1541 // following vectors must be global to allow seamless switching between camera modes
1542 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1543 void CSQC_Demo_Camera()
1544 {
1545         float speed, attenuation, dimensions;
1546         vector tmp, delta;
1547
1548         if( autocvar_camera_reset || !camera_mode )
1549         {
1550                 camera_offset = '0 0 0';
1551                 current_angles = '0 0 0';
1552                 camera_direction = '0 0 0';
1553                 camera_offset_z += 30;
1554                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1555                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1556                 current_origin = view_origin;
1557                 current_camera_offset  = camera_offset;
1558                 cvar_set("camera_reset", "0");
1559                 camera_mode = CAMERA_CHASE;
1560         }
1561
1562         // Camera angles
1563         if( camera_roll )
1564                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1565
1566         if(autocvar_camera_look_player)
1567         {
1568                 local vector dir;
1569                 local float n;
1570
1571                 dir = normalize(view_origin - current_position);
1572                 n = mouse_angles_z;
1573                 mouse_angles = vectoangles(dir);
1574                 mouse_angles_x = mouse_angles_x * -1;
1575                 mouse_angles_z = n;
1576         }
1577         else
1578         {
1579                 tmp = getmousepos() * 0.1;
1580                 if(vlen(tmp)>autocvar_camera_mouse_treshold)
1581                 {
1582                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1583                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1584                 }
1585         }
1586
1587         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1588         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1589         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1590         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1591
1592         // Fix difference when angles don't have the same sign
1593         delta = '0 0 0';
1594         if(mouse_angles_y < -60 && current_angles_y > 60)
1595                 delta = '0 360 0';
1596         if(mouse_angles_y > 60 && current_angles_y < -60)
1597                 delta = '0 -360 0';
1598
1599         if(autocvar_camera_look_player)
1600                 attenuation = autocvar_camera_look_attenuation;
1601         else
1602                 attenuation = autocvar_camera_speed_attenuation;
1603
1604         attenuation = 1 / max(1, attenuation);
1605         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1606
1607         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1608         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1609         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1610         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1611
1612         // Camera position
1613         tmp = '0 0 0';
1614         dimensions = 0;
1615
1616         if( camera_direction_x )
1617         {
1618                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1619                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1620                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1621                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1622                 ++dimensions;
1623         }
1624
1625         if( camera_direction_y )
1626         {
1627                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1628                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1629                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1630                 ++dimensions;
1631         }
1632
1633         if( camera_direction_z )
1634         {
1635                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1636                 ++dimensions;
1637         }
1638
1639         if(autocvar_camera_free)
1640                 speed = autocvar_camera_speed_free;
1641         else
1642                 speed = autocvar_camera_speed_chase;
1643
1644         if(dimensions)
1645         {
1646                 speed = speed * sqrt(1 / dimensions);
1647                 camera_offset += tmp * speed;
1648         }
1649
1650         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1651
1652         // Camera modes
1653         if( autocvar_camera_free )
1654         {
1655                 if ( camera_mode == CAMERA_CHASE )
1656                 {
1657                         current_camera_offset = current_origin + current_camera_offset;
1658                         camera_offset = current_origin + camera_offset;
1659                 }
1660
1661                 camera_mode = CAMERA_FREE;
1662                 current_position = current_camera_offset;
1663         }
1664         else
1665         {
1666                 if ( camera_mode == CAMERA_FREE )
1667                 {
1668                         current_origin = view_origin;
1669                         camera_offset = camera_offset - current_origin;
1670                         current_camera_offset = current_camera_offset - current_origin;
1671                 }
1672
1673                 camera_mode = CAMERA_CHASE;
1674
1675                 if(autocvar_camera_chase_smoothly)
1676                         current_origin += (view_origin - current_origin) * attenuation;
1677                 else
1678                         current_origin = view_origin;
1679
1680                 current_position = current_origin + current_camera_offset;
1681         }
1682
1683         R_SetView(VF_ANGLES, current_angles);
1684         R_SetView(VF_ORIGIN, current_position);
1685 }