qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 /**
  82  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  83  *
  84  * TODO: Use a better solution where a common shared entitiy is used that contains
  85  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  86  * and STAT_FRAGLIMIT to be auto-sent)
  87  */
  88 void CheckForGamestartChange() {
  89         float startTime;
  90         startTime = getstatf(STAT_GAMESTARTTIME);
  91         if (previous_game_starttime != startTime) {
  92                 if ((time + 5.0) < startTime) {
  93                         //if connecting to server while restart was active don't always play prepareforbattle
  94                         sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  95                 }
  96                 if (time < startTime) {
  97                         restartAnnouncer = spawn();
  98                         restartAnnouncer.think = restartAnnouncer_Think;
  99                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 100                 }
 101         }
 102         previous_game_starttime = startTime;
 103 }
 104
 105 void Porto_Init()
 106 {
 107         porto = spawn();
 108         porto.classname = "porto";
 109         porto.draw = Porto_Draw;
 110         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 111 }
 112
 113 float drawtime;
 114 float avgspeed;
 115 vector GetCurrentFov(float fov)
 116 {
 117         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 118         float velocityzoom, curspeed;
 119
 120         zoomsensitivity = autocvar_cl_zoomsensitivity;
 121         zoomfactor = autocvar_cl_zoomfactor;
 122         if(zoomfactor < 1 || zoomfactor > 16)
 123                 zoomfactor = 2.5;
 124         zoomspeed = autocvar_cl_zoomspeed;
 125         if(zoomspeed >= 0)
 126                 if(zoomspeed < 0.5 || zoomspeed > 16)
 127                         zoomspeed = 3.5;
 128
 129         zoomdir = button_zoom;
 130         if(hud == HUD_NORMAL)
 131         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 132                 zoomdir += button_attack2;
 133         if(spectatee_status > 0 || isdemo())
 134         {
 135                 if(spectatorbutton_zoom)
 136                 {
 137                         if(zoomdir)
 138                                 zoomdir = 0;
 139                         else
 140                                 zoomdir = 1;
 141                 }
 142                 // fteqcc failed twice here already, don't optimize this
 143         }
 144
 145         if(zoomdir)
 146                 zoomin_effect = 0;
 147
 148         if(zoomin_effect || camera_active)
 149         {
 150                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 151         }
 152         else
 153         {
 154                 if(zoomspeed < 0) // instant zoom
 155                 {
 156                         if(zoomdir)
 157                                 current_viewzoom = 1 / zoomfactor;
 158                         else
 159                                 current_viewzoom = 1;
 160                 }
 161                 else
 162                 {
 163                         if(zoomdir)
 164                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 165                         else
 166                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 167                 }
 168         }
 169
 170         if(almost_equals(current_viewzoom, 1))
 171                 current_zoomfraction = 0;
 172         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 173                 current_zoomfraction = 1;
 174         else
 175                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 176
 177         if(zoomsensitivity < 1)
 178                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 179         else
 180                 setsensitivityscale(1);
 181
 182         makevectors(view_angles);
 183
 184         if(autocvar_cl_velocityzoom)
 185         {
 186                 switch(autocvar_cl_velocityzoom_type)
 187                 {
 188                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 189                         case 2: curspeed = (v_forward * pmove_vel); break;
 190                         case 1: default: curspeed = vlen(pmove_vel); break;
 191                 }
 192
 193                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 194                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 195                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 196
 197                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 198         }
 199         else
 200                 velocityzoom = 1;
 201
 202         float frustumx, frustumy, fovx, fovy;
 203         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 204         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 205         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 206         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 207
 208         return '1 0 0' * fovx + '0 1 0' * fovy;
 209 }
 210
 211 // this function must match W_SetupShot!
 212 float zoomscript_caught;
 213
 214 vector wcross_origin;
 215 float wcross_scale_prev, wcross_alpha_prev;
 216 vector wcross_color_prev;
 217 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 218 vector wcross_color_goal_prev;
 219 float wcross_changedonetime;
 220
 221 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 222 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 223 float wcross_name_changestarttime, wcross_name_changedonetime;
 224 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 225 entity trueaim;
 226 entity trueaim_rifle;
 227
 228 #define SHOTTYPE_HITTEAM 1
 229 #define SHOTTYPE_HITOBSTRUCTION 2
 230 #define SHOTTYPE_HITWORLD 3
 231 #define SHOTTYPE_HITENEMY 4
 232
 233 void TrueAim_Init()
 234 {
 235         trueaim = spawn();
 236         trueaim.classname = "trueaim";
 237         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 238         trueaim_rifle = spawn();
 239         trueaim_rifle.classname = "trueaim_rifle";
 240         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 241 }
 242
 243 float EnemyHitCheck()
 244 {
 245         float t;
 246         wcross_origin = project_3d_to_2d(trace_endpos);
 247         wcross_origin_z = 0;
 248         if(trace_networkentity < 1)
 249                 return SHOTTYPE_HITWORLD;
 250         if(trace_networkentity > maxclients)
 251                 return SHOTTYPE_HITWORLD;
 252         t = GetPlayerColor(trace_networkentity - 1);
 253         if(teamplay)
 254                 if(t == myteam)
 255                         return SHOTTYPE_HITTEAM;
 256         if(t == COLOR_SPECTATOR)
 257                 return SHOTTYPE_HITWORLD;
 258         return SHOTTYPE_HITENEMY;
 259 }
 260
 261 float TrueAimCheck()
 262 {
 263         float nudge = 1; // added to traceline target and subtracted from result
 264         vector vecs, trueaimpoint, w_shotorg;
 265         vector mi, ma, dv;
 266         float shottype;
 267         entity ta;
 268         float mv;
 269
 270         mi = ma = '0 0 0';
 271         ta = trueaim;
 272         mv = MOVE_NOMONSTERS;
 273
 274         switch(activeweapon)
 275         {
 276                 case WEP_TUBA: // no aim
 277                 case WEP_PORTO: // shoots from eye
 278                 case WEP_HOOK: // no trueaim
 279                 case WEP_GRENADE_LAUNCHER: // toss curve
 280                         return SHOTTYPE_HITWORLD;
 281                 case WEP_NEX:
 282                 case WEP_MINSTANEX:
 283                         mv = MOVE_NORMAL;
 284                         break;
 285                 case WEP_RIFLE:
 286                         ta = trueaim_rifle;
 287                         mv = MOVE_NORMAL;
 288                         if(zoomscript_caught)
 289                         {
 290                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 291                                 return EnemyHitCheck();
 292                         }
 293                         break;
 294                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 295                         mi = '-3 -3 -3';
 296                         ma = '3 3 3';
 297                         break;
 298                 case WEP_FIREBALL: // projectile has a size!
 299                         mi = '-16 -16 -16';
 300                         ma = '16 16 16';
 301                         break;
 302                 case WEP_SEEKER: // projectile has a size!
 303                         mi = '-2 -2 -2';
 304                         ma = '2 2 2';
 305                         break;
 306                 case WEP_ELECTRO: // projectile has a size!
 307                         mi = '0 0 -3';
 308                         ma = '0 0 -3';
 309                         break;
 310         }
 311
 312         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 313
 314         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 315         trueaimpoint = trace_endpos;
 316
 317         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 318                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 319
 320         if(vecs_x > 0)
 321                 vecs_y = -vecs_y;
 322         else
 323                 vecs = '0 0 0';
 324
 325         dv = view_right * vecs_y + view_up * vecs_z;
 326         w_shotorg = view_origin + dv;
 327
 328         // now move the vecs forward as much as requested if possible
 329         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 330         w_shotorg = trace_endpos - view_forward * nudge;
 331
 332         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 333         shottype = EnemyHitCheck();
 334         if(shottype != SHOTTYPE_HITWORLD)
 335                 return shottype;
 336
 337 #if 0
 338         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 339         // or rather, I know why, but see no fix
 340         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 341                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 342                 return SHOTTYPE_HITOBSTRUCTION;
 343 #endif
 344
 345         return SHOTTYPE_HITWORLD;
 346 }
 347
 348 void CSQC_common_hud(void);
 349
 350 void PostInit(void);
 351 void CSQC_Demo_Camera();
 352 float HUD_WouldDrawScoreboard();
 353 float camera_mode;
 354 float reticle_type;
 355 string NextFrameCommand;
 356 void CSQC_SPIDER_HUD();
 357 void CSQC_RAPTOR_HUD();
 358
 359 vector freeze_org, freeze_ang;
 360 entity nightvision_noise, nightvision_noise2;
 361
 362 #define MAX_TIME_DIFF 5
 363 float pickup_crosshair_time, pickup_crosshair_size;
 364 float hit_time, typehit_time;
 365 float nextsound_hit_time, nextsound_typehit_time;
 366 float hitindication_crosshair_time, hitindication_crosshair_size;
 367 float use_nex_chargepool;
 368
 369 float myhealth, myhealth_prev;
 370 float myhealth_flash;
 371
 372 float old_blurradius, old_bluralpha;
 373 float old_sharpen_intensity;
 374
 375 vector myhealth_gentlergb;
 376
 377 float contentavgalpha, liquidalpha_prev;
 378 vector liquidcolor_prev;
 379
 380 float eventchase_current_distance;
 381
 382 vector damage_blurpostprocess, content_blurpostprocess;
 383
 384 float checkfail[16];
 385
 386 void CSQC_UpdateView(float w, float h)
 387 {
 388         entity e;
 389         float fov;
 390         float f, i, j;
 391         vector v;
 392         vector vf_size, vf_min;
 393         float a;
 394         hud = getstati(STAT_HUD);
 395
 396         button_attack2 = (input_buttons & BUTTON_3);
 397         button_zoom = (input_buttons & BUTTON_4);
 398
 399         // FIXME do we need this hack?
 400         if(isdemo())
 401         {
 402                 // in demos, input_buttons do not work
 403                 button_zoom = (autocvar__togglezoom == "-");
 404         }
 405
 406 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 407         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 408         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 409         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 410         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 411         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 412         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 413
 414         vf_size = R_SetView3fv(VF_SIZE);
 415         vf_min = R_SetView3fv(VF_MIN);
 416         vid_width = vf_size_x;
 417         vid_height = vf_size_y;
 418
 419         vector reticle_pos, reticle_size;
 420         vector splash_pos, splash_size;
 421
 422         WaypointSprite_Load();
 423
 424         if(spectatee_status)
 425                 myteam = GetPlayerColor(spectatee_status - 1);
 426         else
 427                 myteam = GetPlayerColor(player_localentnum - 1);
 428
 429         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 430
 431         // event chase camera
 432         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 433         {
 434                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 435                 {
 436                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 437                         vector current_view_origin = R_SetView3fv(VF_ORIGIN);
 438
 439                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 440                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 441                         if(!autocvar_chase_active)
 442                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 443
 444                         // make the camera smooth back
 445                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 446                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 447                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 448                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 449
 450                         vector eventchase_target_origin;
 451                         makevectors(view_angles);
 452                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 453                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 454                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 455                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 456                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 457                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 458                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 459
 460                         R_SetView(VF_ORIGIN, trace_endpos);
 461                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 462                 }
 463                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 464                 {
 465                         cvar_set("chase_active", "0");
 466                         eventchase_current_distance = 0; // start from 0 next time
 467                 }
 468         }
 469
 470         // do lockview after event chase camera so that it still applies whenever necessary.
 471         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 472         {
 473                 R_SetView(VF_ORIGIN, freeze_org);
 474                 R_SetView(VF_ANGLES, freeze_ang);
 475         }
 476         else
 477         {
 478                 freeze_org = R_SetView3fv(VF_ORIGIN);
 479                 freeze_ang = R_SetView3fv(VF_ANGLES);
 480         }
 481
 482         WarpZone_FixView();
 483         //WarpZone_FixPMove();
 484
 485         // Render the Scene
 486         view_origin = R_SetView3fv(VF_ORIGIN);
 487         view_angles = R_SetView3fv(VF_ANGLES);
 488         makevectors(view_angles);
 489         view_forward = v_forward;
 490         view_right = v_right;
 491         view_up = v_up;
 492
 493 #ifdef BLURTEST
 494         if(time > blurtest_time0 && time < blurtest_time1)
 495         {
 496                 float r, t;
 497
 498                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 499                 r = t * blurtest_radius;
 500                 f = 1 / pow(t, blurtest_power) - 1;
 501
 502                 cvar_set("r_glsl_postprocess", "1");
 503                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 504         }
 505         else
 506         {
 507                 cvar_set("r_glsl_postprocess", "0");
 508                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 509         }
 510 #endif
 511
 512         TargetMusic_Advance();
 513         Fog_Force();
 514
 515         if(drawtime == 0)
 516                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 517         else
 518                 drawframetime = bound(0.000001, time - drawtime, 1);
 519         drawtime = time;
 520
 521         // watch for gametype changes here...
 522         // in ParseStuffCMD the cmd isn't executed yet :/
 523         // might even be better to add the gametype to TE_CSQC_INIT...?
 524         if(!postinit)
 525                 PostInit();
 526
 527         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 528                 if(calledhooks & HOOK_START)
 529                 {
 530                         localcmd("\ncl_hook_gameend\n");
 531                         calledhooks |= HOOK_END;
 532                 }
 533
 534         CheckForGamestartChange();
 535         serverAnnouncer();
 536         maptimeAnnouncer();
 537         carrierAnnouncer();
 538
 539         fov = autocvar_fov;
 540         if(fov <= 59.5)
 541         {
 542                 if(!zoomscript_caught)
 543                 {
 544                         localcmd("+button9\n");
 545                         zoomscript_caught = 1;
 546                 }
 547         }
 548         else
 549         {
 550                 if(zoomscript_caught)
 551                 {
 552                         localcmd("-button9\n");
 553                         zoomscript_caught = 0;
 554                 }
 555         }
 556
 557         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 558
 559         // next WANTED weapon (for HUD)
 560         switchweapon = getstati(STAT_SWITCHWEAPON);
 561
 562         // currently switching-to weapon (for crosshair)
 563         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 564
 565         // actually active weapon (for zoom)
 566         activeweapon = getstati(STAT_ACTIVEWEAPON);
 567
 568         f = (serverflags & SERVERFLAG_TEAMPLAY);
 569         if(f != teamplay)
 570         {
 571                 teamplay = f;
 572                 HUD_InitScores();
 573         }
 574
 575         if(last_switchweapon != switchweapon) {
 576                 weapontime = time;
 577                 last_switchweapon = switchweapon;
 578         }
 579         if(last_activeweapon != activeweapon) {
 580                 last_activeweapon = activeweapon;
 581
 582                 e = get_weaponinfo(activeweapon);
 583                 if(e.netname != "")
 584                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 585                 else
 586                         localcmd("\ncl_hook_activeweapon none\n");
 587         }
 588
 589         // ALWAYS Clear Current Scene First
 590         R_ClearScene();
 591 #ifdef WORKAROUND_XON010
 592         if(checkextension("DP_CSQC_ROTATEMOVES"))
 593         {
 594 #endif
 595         R_SetView(VF_ORIGIN, view_origin);
 596         R_SetView(VF_ANGLES, view_angles);
 597 #ifdef WORKAROUND_XON010
 598         }
 599 #endif
 600
 601         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 602         R_SetView(VF_SIZE, vf_size);
 603         R_SetView(VF_MIN, vf_min);
 604
 605         // Assign Standard Viewflags
 606         // Draw the World (and sky)
 607         R_SetView(VF_DRAWWORLD, 1);
 608
 609         // Set the console size vars
 610         vid_conwidth = autocvar_vid_conwidth;
 611         vid_conheight = autocvar_vid_conheight;
 612         vid_pixelheight = autocvar_vid_pixelheight;
 613
 614         R_SetView(VF_FOV, GetCurrentFov(fov));
 615
 616         // Camera for demo playback
 617         if(camera_active)
 618         {
 619                 if(autocvar_camera_enable)
 620                         CSQC_Demo_Camera();
 621                 else
 622                 {
 623                         cvar_set("chase_active", ftos(chase_active_backup));
 624                         cvar_set("cl_demo_mousegrab", "0");
 625                         camera_active = FALSE;
 626                 }
 627         }
 628 #ifdef CAMERATEST
 629         else if(autocvar_camera_enable)
 630 #else
 631         else if(autocvar_camera_enable && isdemo())
 632 #endif
 633         {
 634                 // Enable required Darkplaces cvars
 635                 chase_active_backup = autocvar_chase_active;
 636                 cvar_set("chase_active", "2");
 637                 cvar_set("cl_demo_mousegrab", "1");
 638                 camera_active = TRUE;
 639                 camera_mode = FALSE;
 640         }
 641
 642         // Draw the Crosshair
 643         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 644
 645         // Draw the Engine Status Bar (the default Quake HUD)
 646         R_SetView(VF_DRAWENGINEHUD, 0);
 647
 648         // Update the mouse position
 649         /*
 650            mousepos_x = vid_conwidth;
 651            mousepos_y = vid_conheight;
 652            mousepos = mousepos*0.5 + getmousepos();
 653          */
 654
 655         e = self;
 656         for(self = world; (self = nextent(self)); )
 657                 if(self.draw)
 658                         self.draw();
 659         self = e;
 660
 661         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 662         R_RenderScene();
 663
 664         // now switch to 2D drawing mode by calling a 2D drawing function
 665         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 666         // next R_RenderScene call
 667         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 668
 669         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 670         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 671         {
 672                 // apply night vision effect
 673                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 674
 675                 if(!nightvision_noise)
 676                 {
 677                         nightvision_noise = spawn();
 678                         nightvision_noise.classname = "nightvision_noise";
 679                 }
 680                 if(!nightvision_noise2)
 681                 {
 682                         nightvision_noise2 = spawn();
 683                         nightvision_noise2.classname = "nightvision_noise2";
 684                 }
 685
 686                 // color tint in yellow
 687                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 688
 689                 // draw BG
 690                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 691                 rgb = '1 1 1';
 692                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 693                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 694                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 695                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 696                 tc_11 = tc_01 + tc_10 - tc_00;
 697                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 698                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 699                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 700                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 701                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 702                 R_EndPolygon();
 703
 704                 // draw FG
 705                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 706                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 707                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 708                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 709                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 710                 tc_11 = tc_01 + tc_10 - tc_00;
 711                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 712                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 713                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 714                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 715                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 716                 R_EndPolygon();
 717         }
 718
 719         // Draw the aiming reticle for weapons that use it
 720         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 721         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 722         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 723         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 724                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 725         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 726                 reticle_type = 2; // nex zoom
 727         else if(button_zoom || zoomscript_caught)
 728                 reticle_type = 1; // normal zoom
 729         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 730                 reticle_type = 2; // nex zoom
 731
 732         if(reticle_type && autocvar_cl_reticle)
 733         {
 734                 if(autocvar_cl_reticle_stretch)
 735                 {
 736                         reticle_size_x = vid_conwidth;
 737                         reticle_size_y = vid_conheight;
 738                         reticle_pos_x = 0;
 739                         reticle_pos_y = 0;
 740                 }
 741                 else
 742                 {
 743                         reticle_size_x = max(vid_conwidth, vid_conheight);
 744                         reticle_size_y = max(vid_conwidth, vid_conheight);
 745                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 746                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 747                 }
 748
 749                 f = current_zoomfraction;
 750                 if(zoomscript_caught)
 751                         f = 1;
 752                 if(autocvar_cl_reticle_item_normal)
 753                 {
 754                         if(reticle_type == 1 && f)
 755                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 756                 }
 757                 if(autocvar_cl_reticle_item_nex)
 758                 {
 759                         if(reticle_type == 2 && f)
 760                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 761                 }
 762         }
 763
 764
 765         // improved polyblend
 766         vector rgb;
 767         if(autocvar_hud_contents)
 768         {
 769                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 770                 vector liquidcolor;
 771
 772                 switch(pointcontents(view_origin))
 773                 {
 774                         case CONTENT_WATER:
 775                                 liquidalpha = autocvar_hud_contents_water_alpha;
 776                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 777                                 incontent = 1;
 778                                 break;
 779
 780                         case CONTENT_LAVA:
 781                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 782                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 783                                 incontent = 1;
 784                                 break;
 785
 786                         case CONTENT_SLIME:
 787                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 788                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 789                                 incontent = 1;
 790                                 break;
 791
 792                         default:
 793                                 liquidalpha = 0;
 794                                 liquidcolor = '0 0 0';
 795                                 incontent = 0;
 796                                 break;
 797                 }
 798
 799                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 800                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 801                         contentfadetime = autocvar_hud_contents_fadeintime;
 802                         liquidalpha_prev = liquidalpha;
 803                         liquidcolor_prev = liquidcolor;
 804                 }
 805                 else
 806                         contentfadetime = autocvar_hud_contents_fadeouttime;
 807
 808                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 809                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 810
 811                 if(contentavgalpha)
 812                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 813
 814                 if(autocvar_hud_postprocessing)
 815                 {
 816                         if(autocvar_hud_contents_blur && contentavgalpha)
 817                         {
 818                                 content_blurpostprocess_x = 1;
 819                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 820                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 821                         }
 822                         else
 823                         {
 824                                 content_blurpostprocess_x = 0;
 825                                 content_blurpostprocess_y = 0;
 826                                 content_blurpostprocess_z = 0;
 827                         }
 828                 }
 829         }
 830
 831         if(autocvar_hud_damage)
 832         {
 833                 splash_size_x = max(vid_conwidth, vid_conheight);
 834                 splash_size_y = max(vid_conwidth, vid_conheight);
 835                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 836                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 837
 838                 float myhealth_flash_temp;
 839                 myhealth = getstati(STAT_HEALTH);
 840
 841                 // fade out
 842                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 843                 // add new damage
 844                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 845
 846                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 847                 pain_threshold = autocvar_hud_damage_pain_threshold;
 848                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 849                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 850
 851                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 852                 {
 853                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 854                 }
 855
 856                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 857
 858                 if(myhealth_prev < 1)
 859                 {
 860                         if(myhealth >= 1)
 861                         {
 862                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 863                                 myhealth_flash_temp = 0;
 864                         }
 865                         else
 866                         {
 867                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 868                         }
 869                 }
 870
 871                 if(spectatee_status == -1 || intermission)
 872                 {
 873                         myhealth_flash = 0; // observing, or match ended
 874                         myhealth_flash_temp = 0;
 875                 }
 876
 877                 myhealth_prev = myhealth;
 878
 879                 // IDEA: change damage color/picture based on player model for robot/alien species?
 880                 // pro: matches model better
 881                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 882                 // maybe different reddish pics?
 883                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 884                 {
 885                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 886                         {
 887                                 if(autocvar_cl_gentle_damage == 2)
 888                                 {
 889                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 890                                         {
 891                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 892                                         }
 893                                 }
 894                                 else
 895                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 896
 897                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 898                         }
 899                         else
 900                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 901                 }
 902
 903                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 904                 {
 905                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 906                         {
 907                                 damage_blurpostprocess_x = 1;
 908                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 909                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 910                         }
 911                         else
 912                         {
 913                                 damage_blurpostprocess_x = 0;
 914                                 damage_blurpostprocess_y = 0;
 915                                 damage_blurpostprocess_z = 0;
 916                         }
 917                 }
 918         }
 919
 920         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 921         {
 922                 // enable or disable rendering types if they are used or not
 923                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 924                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 925
 926                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 927                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 928                 {
 929                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 930                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 931                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 932                         {
 933                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 934                                 old_blurradius = blurradius;
 935                                 old_bluralpha = bluralpha;
 936                         }
 937                 }
 938                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 939                 {
 940                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 941                         old_blurradius = 0;
 942                         old_bluralpha = 0;
 943                 }
 944
 945                 // edge detection postprocess handling done second (used by hud_powerup)
 946                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 947                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 948                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 949
 950                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 951
 952                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 953                 {
 954                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 955                         {
 956                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 957                                 old_sharpen_intensity = sharpen_intensity;
 958                         }
 959                 }
 960                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 961                 {
 962                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 963                         old_sharpen_intensity = 0;
 964                 }
 965         }
 966
 967         if(menu_visible)
 968                 menu_show();
 969
 970         /*if(gametype == GAME_CTF)
 971           {
 972           ctf_view();
 973           } else */
 974
 975         // draw 2D entities
 976         e = self;
 977         for(self = world; (self = nextent(self)); )
 978                 if(self.draw2d)
 979                         self.draw2d();
 980         self = e;
 981         Draw_ShowNames_All();
 982
 983         scoreboard_active = HUD_WouldDrawScoreboard();
 984
 985         hit_time = getstatf(STAT_HIT_TIME);
 986         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 987         {
 988                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 989                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 990
 991                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 992         }
 993         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 994         if(typehit_time > nextsound_typehit_time)
 995         {
 996                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 997                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 998
 999                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1000         }
1001
1002         //else
1003         {
1004                 if(gametype == GAME_FREEZETAG)
1005                 {
1006                         if(getstati(STAT_FROZEN))
1007                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1008                         if(getstatf(STAT_REVIVE_PROGRESS))
1009                         {
1010                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1011                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1012                         }
1013                 }
1014
1015                 if(autocvar_r_letterbox == 0)
1016                         if(autocvar_viewsize < 120)
1017                                 CSQC_common_hud();
1018
1019                 // crosshair goes VERY LAST
1020                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
1021                         string wcross_style;
1022                         float wcross_alpha, wcross_resolution;
1023                         wcross_style = autocvar_crosshair;
1024                         if (wcross_style == "0")
1025                                 return;
1026                         wcross_resolution = autocvar_crosshair_size;
1027                         if (wcross_resolution == 0)
1028                                 return;
1029                         wcross_alpha = autocvar_crosshair_alpha;
1030                         if (wcross_alpha == 0)
1031                                 return;
1032
1033                         // TrueAim check
1034                         float shottype;
1035
1036                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1037                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1038                         wcross_origin_z = 0;
1039                         if(autocvar_crosshair_hittest)
1040                         {
1041                                 vector wcross_oldorigin;
1042                                 wcross_oldorigin = wcross_origin;
1043                                 shottype = TrueAimCheck();
1044                                 if(shottype == SHOTTYPE_HITWORLD)
1045                                 {
1046                                         v = wcross_origin - wcross_oldorigin;
1047                                         v_x /= vid_conwidth;
1048                                         v_y /= vid_conheight;
1049                                         if(vlen(v) > 0.01)
1050                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1051                                 }
1052                                 if(!autocvar_crosshair_hittest_showimpact)
1053                                         wcross_origin = wcross_oldorigin;
1054                         }
1055                         else
1056                                 shottype = SHOTTYPE_HITWORLD;
1057
1058                         vector wcross_color, wcross_size;
1059                         string wcross_wep, wcross_name;
1060                         float wcross_scale, wcross_blur;
1061
1062                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1063                                 e = get_weaponinfo(switchingweapon);
1064                                 if (e && e.netname != "")
1065                                 {
1066                                         wcross_wep = e.netname;
1067                                         if(autocvar_crosshair_per_weapon)
1068                                         {
1069                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1070                                                 if (wcross_resolution == 0)
1071                                                         return;
1072                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1073                                                 if (wcross_alpha == 0)
1074                                                         return;
1075
1076                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1077                                                 if(wcross_style == "" || wcross_style == "0")
1078                                                         wcross_style = wcross_wep;
1079                                         }
1080                                 }
1081                         }
1082                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1083                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1084                         else if(autocvar_crosshair_color_by_health)
1085                         {
1086                                 float x = getstati(STAT_HEALTH);
1087
1088                                 //x = red
1089                                 //y = green
1090                                 //z = blue
1091
1092                                 wcross_color_z = 0;
1093
1094                                 if(x > 200)
1095                                 {
1096                                         wcross_color_x = 0;
1097                                         wcross_color_y = 1;
1098                                 }
1099                                 else if(x > 150)
1100                                 {
1101                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1102                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1103                                 }
1104                                 else if(x > 100)
1105                                 {
1106                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1107                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1108                                         wcross_color_z = 1 - (x-100)*0.02;
1109                                 }
1110                                 else if(x > 50)
1111                                 {
1112                                         wcross_color_x = 1;
1113                                         wcross_color_y = 1;
1114                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1115                                 }
1116                                 else if(x > 20)
1117                                 {
1118                                         wcross_color_x = 1;
1119                                         wcross_color_y = (x-20)*90/27/100;
1120                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1121                                 }
1122                                 else
1123                                 {
1124                                         wcross_color_x = 1;
1125                                         wcross_color_y = 0;
1126                                 }
1127                         }
1128                         else
1129                                 wcross_color = stov(autocvar_crosshair_color);
1130
1131                         wcross_name = strcat("gfx/crosshair", wcross_style);
1132
1133                         if(autocvar_crosshair_effect_scalefade)
1134                         {
1135                                 wcross_scale = wcross_resolution;
1136                                 wcross_resolution = 1;
1137                         }
1138                         else
1139                         {
1140                                 wcross_scale = 1;
1141                         }
1142
1143                         if(autocvar_crosshair_pickup)
1144                         {
1145                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1146
1147                                 if(pickup_crosshair_time < stat_pickup_time)
1148                                 {
1149                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1150                                                 pickup_crosshair_size = 1;
1151
1152                                         pickup_crosshair_time = stat_pickup_time;
1153                                 }
1154
1155                                 if(pickup_crosshair_size > 0)
1156                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1157                                 else
1158                                         pickup_crosshair_size = 0;
1159
1160                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1161                         }
1162
1163                         if(autocvar_crosshair_hitindication)
1164                         {
1165                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1166                                 if(hitindication_crosshair_time < hit_time)
1167                                 {
1168                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1169                                                 hitindication_crosshair_size = 1;
1170
1171                                         hitindication_crosshair_time = hit_time;
1172                                 }
1173
1174                                 if(hitindication_crosshair_size > 0)
1175                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1176                                 else
1177                                         hitindication_crosshair_size = 0;
1178
1179                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1180                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1181                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1182                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1183                         }
1184
1185                         if(shottype == SHOTTYPE_HITENEMY)
1186                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1187                         if(shottype == SHOTTYPE_HITTEAM)
1188                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1189
1190                         f = autocvar_crosshair_effect_speed;
1191                         if(f < 0)
1192                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1193                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1194                         {
1195                                 wcross_changedonetime = time + f;
1196                         }
1197                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1198                         {
1199                                 wcross_name_changestarttime = time;
1200                                 wcross_name_changedonetime = time + f;
1201                                 if(wcross_name_goal_prev_prev)
1202                                         strunzone(wcross_name_goal_prev_prev);
1203                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1204                                 wcross_name_goal_prev = strzone(wcross_name);
1205                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1206                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1207                                 wcross_resolution_goal_prev = wcross_resolution;
1208                         }
1209
1210                         wcross_scale_goal_prev = wcross_scale;
1211                         wcross_alpha_goal_prev = wcross_alpha;
1212                         wcross_color_goal_prev = wcross_color;
1213
1214                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1215                         {
1216                                 wcross_blur = 1;
1217                                 wcross_alpha *= 0.75;
1218                         }
1219                         else
1220                                 wcross_blur = 0;
1221                         // *_prev is at time-frametime
1222                         // * is at wcross_changedonetime+f
1223                         // what do we have at time?
1224                         if(time < wcross_changedonetime)
1225                         {
1226                                 f = frametime / (wcross_changedonetime - time + frametime);
1227                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1228                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1229                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1230                         }
1231
1232                         wcross_scale_prev = wcross_scale;
1233                         wcross_alpha_prev = wcross_alpha;
1234                         wcross_color_prev = wcross_color;
1235
1236                         wcross_scale *= 1 - autocvar__menu_alpha;
1237                         wcross_alpha *= 1 - autocvar__menu_alpha;
1238                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1239
1240                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1241                         {
1242                                 // crosshair rings for weapon stats
1243                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1244                                 {
1245                                         // declarations and stats
1246                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1247                                         string ring_image, ring_inner_image;
1248                                         vector ring_rgb, ring_inner_rgb;
1249
1250                                         ring_scale = autocvar_crosshair_ring_size;
1251
1252                                         float weapon_clipload, weapon_clipsize;
1253                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1254                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1255
1256                                         float nex_charge, nex_chargepool;
1257                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1258                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1259
1260                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1261                                                 nex_charge_movingavg = nex_charge;
1262
1263
1264                                         // handle the values
1265                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1266                                         {
1267                                                 if (nex_chargepool || use_nex_chargepool) {
1268                                                         use_nex_chargepool = 1;
1269                                                         ring_inner_value = nex_chargepool;
1270                                                 } else {
1271                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1272                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1273                                                 }
1274
1275                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1276                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1277                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1278
1279                                                 // draw the outer ring to show the current charge of the weapon
1280                                                 ring_value = nex_charge;
1281                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1282                                                 ring_rgb = wcross_color;
1283                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1284                                         }
1285                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1286                                         {
1287                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1288                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1289                                                 ring_rgb = wcross_color;
1290                                                 ring_image = "gfx/crosshair_ring.tga";
1291                                         }
1292                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1293                                         {
1294                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1295                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1296                                                 ring_rgb = wcross_color;
1297                                                 ring_image = "gfx/crosshair_ring.tga";
1298                                         }
1299
1300                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1301                                         {
1302                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1303                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1304                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1305                                                 ring_rgb = wcross_color;
1306
1307                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1308                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1309                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1310                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1311                                                 else
1312                                                         ring_image = "gfx/crosshair_ring.tga";
1313                                         }
1314
1315                                         // if in weapon switch animation, fade ring out/in
1316                                         if(g_weaponswitchdelay > 0)
1317                                         {
1318                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1319                                                 if(f > 0 && f < 2)
1320                                                         ring_alpha *= fabs(1 - f);
1321                                         }
1322
1323                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1324                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1325
1326                                         if (ring_value)
1327                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1328                                 }
1329
1330 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1331                                 do \
1332                                 { \
1333                                         if(wcross_blur > 0) \
1334                                         { \
1335                                                 for(i = -2; i <= 2; ++i) \
1336                                                 for(j = -2; j <= 2; ++j) \
1337                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1338                                         } \
1339                                         else \
1340                                         { \
1341                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1342                                         } \
1343                                 } \
1344                                 while(0)
1345
1346 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1347                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1348
1349 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1350                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1351
1352                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1353                                 {
1354                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1355                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1356                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1357                                         f = 1 - f;
1358                                 }
1359                                 else
1360                                 {
1361                                         f = 1;
1362                                 }
1363                                 wcross_name_alpha_goal_prev = f;
1364
1365                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1366                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1367
1368                                 if(autocvar_crosshair_dot)
1369                                 {
1370                                         vector wcross_color_old;
1371                                         wcross_color_old = wcross_color;
1372                                         if(autocvar_crosshair_dot_color != "0")
1373                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1374                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1375                                         // FIXME why don't we use wcross_alpha here?
1376                                         wcross_color = wcross_color_old;
1377                                 }
1378                         }
1379                 }
1380                 else
1381                 {
1382                         wcross_scale_prev = 0;
1383                         wcross_alpha_prev = 0;
1384                         wcross_scale_goal_prev = 0;
1385                         wcross_alpha_goal_prev = 0;
1386                         wcross_changedonetime = 0;
1387                         if(wcross_name_goal_prev)
1388                                 strunzone(wcross_name_goal_prev);
1389                         wcross_name_goal_prev = string_null;
1390                         if(wcross_name_goal_prev_prev)
1391                                 strunzone(wcross_name_goal_prev_prev);
1392                         wcross_name_goal_prev_prev = string_null;
1393                         wcross_name_changestarttime = 0;
1394                         wcross_name_changedonetime = 0;
1395                         wcross_name_alpha_goal_prev = 0;
1396                         wcross_name_alpha_goal_prev_prev = 0;
1397                         wcross_resolution_goal_prev = 0;
1398                         wcross_resolution_goal_prev_prev = 0;
1399                 }
1400         }
1401
1402         if(NextFrameCommand)
1403         {
1404                 localcmd("\n", NextFrameCommand, "\n");
1405                 NextFrameCommand = string_null;
1406         }
1407
1408         // we must do this check AFTER a frame was rendered, or it won't work
1409         if(cs_project_is_b0rked == 0)
1410         {
1411                 string w0, h0;
1412                 w0 = ftos(autocvar_vid_conwidth);
1413                 h0 = ftos(autocvar_vid_conheight);
1414                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1415                 //R_SetView(VF_FOV, '90 90 0');
1416                 R_SetView(VF_ORIGIN, '0 0 0');
1417                 R_SetView(VF_ANGLES, '0 0 0');
1418                 R_SetView(VF_PERSPECTIVE, 1);
1419                 makevectors('0 0 0');
1420                 vector v1, v2;
1421                 cvar_set("vid_conwidth", "800");
1422                 cvar_set("vid_conheight", "600");
1423                 v1 = cs_project(v_forward);
1424                 cvar_set("vid_conwidth", "640");
1425                 cvar_set("vid_conheight", "480");
1426                 v2 = cs_project(v_forward);
1427                 if(v1 == v2)
1428                         cs_project_is_b0rked = 1;
1429                 else
1430                         cs_project_is_b0rked = -1;
1431                 cvar_set("vid_conwidth", w0);
1432                 cvar_set("vid_conheight", h0);
1433         }
1434
1435         if(autocvar__hud_configure)
1436                 HUD_Panel_Mouse();
1437
1438     if(hud && !intermission)
1439     {
1440         if(hud == HUD_SPIDERBOT)
1441             CSQC_SPIDER_HUD();
1442         else if(hud == HUD_WAKIZASHI)
1443             CSQC_WAKIZASHI_HUD();
1444         else if(hud == HUD_RAPTOR)
1445             CSQC_RAPTOR_HUD();
1446         else if(hud == HUD_BUMBLEBEE)
1447             CSQC_BUMBLE_HUD();
1448     }
1449         // let's reset the view back to normal for the end
1450         R_SetView(VF_MIN, '0 0 0');
1451         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1452 }
1453
1454
1455 void CSQC_common_hud(void)
1456 {
1457     // do some accuracy var caching
1458     float i;
1459     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1460     {
1461         if(autocvar_accuracy_color_levels != acc_color_levels)
1462         {
1463             if(acc_color_levels)
1464                 strunzone(acc_color_levels);
1465             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1466             acc_levels = tokenize_console(acc_color_levels);
1467             if (acc_levels > MAX_ACCURACY_LEVELS)
1468                 acc_levels = MAX_ACCURACY_LEVELS;
1469
1470             for (i = 0; i < acc_levels; ++i)
1471                 acc_lev[i] = stof(argv(i)) / 100.0;
1472         }
1473         // let know that acc_col[] needs to be loaded
1474         acc_col_x[0] = -1;
1475     }
1476
1477     HUD_Main(); // always run these functions for alpha checks
1478     HUD_DrawScoreboard();
1479
1480     if (scoreboard_active) // scoreboard/accuracy
1481         HUD_Reset();
1482     else if (intermission == 2) // map voting screen
1483     {
1484         HUD_FinaleOverlay();
1485         HUD_Reset();
1486     }
1487         /*
1488         switch(hud)
1489         {
1490                 case HUD_SPIDERBOT:
1491                         CSQC_SPIDER_HUD();
1492                         break;
1493
1494                 case HUD_WAKIZASHI:
1495                         CSQC_WAKIZASHI_HUD();
1496                         break;
1497
1498         case HUD_BUMBLEBEE:
1499             CSQC_BUMBLE_HUD();
1500             break;
1501         }
1502         */
1503 }
1504
1505
1506 // following vectors must be global to allow seamless switching between camera modes
1507 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1508 void CSQC_Demo_Camera()
1509 {
1510         float speed, attenuation, dimensions;
1511         vector tmp, delta;
1512
1513         if( autocvar_camera_reset || !camera_mode )
1514         {
1515                 camera_offset = '0 0 0';
1516                 current_angles = '0 0 0';
1517                 camera_direction = '0 0 0';
1518                 camera_offset_z += 30;
1519                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1520                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1521                 current_origin = view_origin;
1522                 current_camera_offset  = camera_offset;
1523                 cvar_set("camera_reset", "0");
1524                 camera_mode = CAMERA_CHASE;
1525         }
1526
1527         // Camera angles
1528         if( camera_roll )
1529                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1530
1531         if(autocvar_camera_look_player)
1532         {
1533                 vector dir;
1534                 float n;
1535
1536                 dir = normalize(view_origin - current_position);
1537                 n = mouse_angles_z;
1538                 mouse_angles = vectoangles(dir);
1539                 mouse_angles_x = mouse_angles_x * -1;
1540                 mouse_angles_z = n;
1541         }
1542         else
1543         {
1544                 tmp = getmousepos() * 0.1;
1545                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1546                 {
1547                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1548                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1549                 }
1550         }
1551
1552         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1553         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1554         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1555         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1556
1557         // Fix difference when angles don't have the same sign
1558         delta = '0 0 0';
1559         if(mouse_angles_y < -60 && current_angles_y > 60)
1560                 delta = '0 360 0';
1561         if(mouse_angles_y > 60 && current_angles_y < -60)
1562                 delta = '0 -360 0';
1563
1564         if(autocvar_camera_look_player)
1565                 attenuation = autocvar_camera_look_attenuation;
1566         else
1567                 attenuation = autocvar_camera_speed_attenuation;
1568
1569         attenuation = 1 / max(1, attenuation);
1570         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1571
1572         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1573         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1574         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1575         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1576
1577         // Camera position
1578         tmp = '0 0 0';
1579         dimensions = 0;
1580
1581         if( camera_direction_x )
1582         {
1583                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1584                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1585                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1586                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1587                 ++dimensions;
1588         }
1589
1590         if( camera_direction_y )
1591         {
1592                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1593                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1594                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1595                 ++dimensions;
1596         }
1597
1598         if( camera_direction_z )
1599         {
1600                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1601                 ++dimensions;
1602         }
1603
1604         if(autocvar_camera_free)
1605                 speed = autocvar_camera_speed_free;
1606         else
1607                 speed = autocvar_camera_speed_chase;
1608
1609         if(dimensions)
1610         {
1611                 speed = speed * sqrt(1 / dimensions);
1612                 camera_offset += tmp * speed;
1613         }
1614
1615         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1616
1617         // Camera modes
1618         if( autocvar_camera_free )
1619         {
1620                 if ( camera_mode == CAMERA_CHASE )
1621                 {
1622                         current_camera_offset = current_origin + current_camera_offset;
1623                         camera_offset = current_origin + camera_offset;
1624                 }
1625
1626                 camera_mode = CAMERA_FREE;
1627                 current_position = current_camera_offset;
1628         }
1629         else
1630         {
1631                 if ( camera_mode == CAMERA_FREE )
1632                 {
1633                         current_origin = view_origin;
1634                         camera_offset = camera_offset - current_origin;
1635                         current_camera_offset = current_camera_offset - current_origin;
1636                 }
1637
1638                 camera_mode = CAMERA_CHASE;
1639
1640                 if(autocvar_camera_chase_smoothly)
1641                         current_origin += (view_origin - current_origin) * attenuation;
1642                 else
1643                         current_origin = view_origin;
1644
1645                 current_position = current_origin + current_camera_offset;
1646         }
1647
1648         R_SetView(VF_ANGLES, current_angles);
1649         R_SetView(VF_ORIGIN, current_position);
1650 }