Merge branch 'master' into samual/water_and_damage_blur
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / View.qc
1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
2 #define spider_rocket_targ "gfx/vehicles/target.tga"
3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
4 #define rkt_size 32
5 #define rld_size_x 256
6 #define rld_size_y 16
7
8 void CSQC_WAKIZASHI_HUD();
9
10 entity porto;
11 vector polyline[16];
12 float trace_dphitcontents;
13 float trace_networkentity;
14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
15 float DPCONTENTS_SOLID = 1; // blocks player movement
16 float DPCONTENTS_BODY = 32; // blocks player movement
17 float DPCONTENTS_CORPSE = 64; // blocks player movement
18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
19 void Porto_Draw()
20 {
21         vector p, dir, ang, q, nextdir;
22         float idx, portal_number, portal1_idx;
23
24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
25                 return;
26         if(intermission == 1)
27                 return;
28         if(intermission == 2)
29                 return;
30         if (getstati(STAT_HEALTH) <= 0)
31                 return;
32
33         dir = view_forward;
34
35         if(angles_held_status)
36         {
37                 makevectors(angles_held);
38                 dir = v_forward;
39         }
40
41         p = view_origin;
42
43         polyline[0] = p;
44         idx = 1;
45         portal_number = 0;
46         nextdir = dir;
47
48         for(;;)
49         {
50                 dir = nextdir;
51                 traceline(p, p + 65536 * dir, TRUE, porto);
52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
53                         return;
54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
55                 p = trace_endpos;
56                 polyline[idx] = p;
57                 ++idx;
58                 if(idx >= 16)
59                         return;
60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
61                         continue;
62                 ++portal_number;
63                 ang = vectoangles2(trace_plane_normal, dir);
64                 ang_x = -ang_x;
65                 makevectors(ang);
66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
67                         return;
68                 if(portal_number == 1)
69                         portal1_idx = idx;
70                 if(portal_number >= 2)
71                         break;
72         }
73
74         while(idx >= 2)
75         {
76                 p = polyline[idx-2];
77                 q = polyline[idx-1];
78                 if(idx == 2)
79                         p = p - view_up * 16;
80                 if(idx-1 >= portal1_idx)
81                 {
82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
83                 }
84                 else
85                 {
86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
87                 }
88                 --idx;
89         }
90 }
91
92 /**
93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
94  *
95  * TODO: Use a better solution where a common shared entitiy is used that contains
96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
97  * and STAT_FRAGLIMIT to be auto-sent)
98  */
99 void CheckForGamestartChange() {
100         float startTime;
101         startTime = getstatf(STAT_GAMESTARTTIME);
102         if (previous_game_starttime != startTime) {
103                 if ((time + 5.0) < startTime) {
104                         //if connecting to server while restart was active don't always play prepareforbattle
105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
106                 }
107                 if (time < startTime) {
108                         restartAnnouncer = spawn();
109                         restartAnnouncer.think = restartAnnouncer_Think;
110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
111                 }
112         }
113         previous_game_starttime = startTime;
114 }
115
116 void Porto_Init()
117 {
118         porto = spawn();
119         porto.classname = "porto";
120         porto.draw = Porto_Draw;
121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
122 }
123
124 float drawtime;
125 float avgspeed;
126 vector GetCurrentFov(float fov)
127 {
128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
129
130         zoomsensitivity = autocvar_cl_zoomsensitivity;
131         zoomfactor = autocvar_cl_zoomfactor;
132         if(zoomfactor < 1 || zoomfactor > 16)
133                 zoomfactor = 2.5;
134         zoomspeed = autocvar_cl_zoomspeed;
135         if(zoomspeed >= 0)
136                 if(zoomspeed < 0.5 || zoomspeed > 16)
137                         zoomspeed = 3.5;
138
139         zoomdir = button_zoom;
140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
141                 zoomdir += button_attack2;
142         if(spectatee_status > 0 || isdemo())
143         {
144                 if(spectatorbutton_zoom)
145                         zoomdir = 0 + !zoomdir;
146                 // do not even THINK about removing this 0
147                 // _I_ know what I am doing
148                 // fteqcc does not
149         }
150
151         if(zoomdir)
152                 zoomin_effect = 0;
153
154         if(zoomin_effect || camera_active)
155         {
156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
157         }
158         else
159         {
160                 if(zoomspeed < 0) // instant zoom
161                 {
162                         if(zoomdir)
163                                 current_viewzoom = 1 / zoomfactor;
164                         else
165                                 current_viewzoom = 1;
166                 }
167                 else
168                 {
169                         if(zoomdir)
170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
171                         else
172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
173                 }
174         }
175
176         if(almost_equals(current_viewzoom, 1))
177                 current_zoomfraction = 0;
178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
179                 current_zoomfraction = 1;
180         else
181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
182
183         if(zoomsensitivity < 1)
184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
185         else
186                 setsensitivityscale(1);
187
188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
191
192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
193
194         float frustumx, frustumy, fovx, fovy;
195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
199
200         return '1 0 0' * fovx + '0 1 0' * fovy;
201 }
202
203 // this function must match W_SetupShot!
204 float zoomscript_caught;
205
206 vector wcross_origin;
207 float wcross_scale_prev, wcross_alpha_prev;
208 vector wcross_color_prev;
209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
210 vector wcross_color_goal_prev;
211 float wcross_changedonetime;
212
213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
215 float wcross_name_changestarttime, wcross_name_changedonetime;
216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
217 entity trueaim;
218 entity trueaim_rifle;
219
220 #define SHOTTYPE_HITTEAM 1
221 #define SHOTTYPE_HITOBSTRUCTION 2
222 #define SHOTTYPE_HITWORLD 3
223 #define SHOTTYPE_HITENEMY 4
224
225 void TrueAim_Init()
226 {
227         trueaim = spawn();
228         trueaim.classname = "trueaim";
229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
230         trueaim_rifle = spawn();
231         trueaim_rifle.classname = "trueaim_rifle";
232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
233 }
234
235 float EnemyHitCheck()
236 {
237         float t;
238         wcross_origin = project_3d_to_2d(trace_endpos);
239         wcross_origin_z = 0;
240         if(trace_networkentity < 1)
241                 return SHOTTYPE_HITWORLD;
242         if(trace_networkentity > maxclients)
243                 return SHOTTYPE_HITWORLD;
244         t = GetPlayerColor(trace_networkentity - 1);
245         if(teamplay)
246                 if(t == myteam)
247                         return SHOTTYPE_HITTEAM;
248         if(t == COLOR_SPECTATOR)
249                 return SHOTTYPE_HITWORLD;
250         return SHOTTYPE_HITENEMY;
251 }
252
253 float TrueAimCheck()
254 {
255         float nudge = 1; // added to traceline target and subtracted from result
256         vector vecs, trueaimpoint, w_shotorg;
257         vector mi, ma, dv;
258         float shottype;
259         entity ta;
260         float mv;
261
262         mi = ma = '0 0 0';
263         ta = trueaim;
264         mv = MOVE_NOMONSTERS;
265
266         switch(activeweapon)
267         {
268                 case WEP_TUBA: // no aim
269                 case WEP_PORTO: // shoots from eye
270                 case WEP_HOOK: // no trueaim
271                 case WEP_GRENADE_LAUNCHER: // toss curve
272                         return SHOTTYPE_HITWORLD;
273                 case WEP_NEX:
274                 case WEP_MINSTANEX:
275                         mv = MOVE_NORMAL;
276                         break;
277                 case WEP_SNIPERRIFLE:
278                         ta = trueaim_rifle;
279                         mv = MOVE_NORMAL;
280                         if(zoomscript_caught)
281                         {
282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
283                                 return EnemyHitCheck();
284                         }
285                         break;
286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
287                         mi = '-3 -3 -3';
288                         ma = '3 3 3';
289                         break;
290                 case WEP_FIREBALL: // projectile has a size!
291                         mi = '-16 -16 -16';
292                         ma = '16 16 16';
293                         break;
294                 case WEP_SEEKER: // projectile has a size!
295                         mi = '-2 -2 -2';
296                         ma = '2 2 2';
297                         break;
298                 case WEP_ELECTRO: // projectile has a size!
299                         mi = '0 0 -3';
300                         ma = '0 0 -3';
301                         break;
302         }
303
304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
305
306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
307         trueaimpoint = trace_endpos;
308
309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
311
312         if(vecs_x > 0)
313                 vecs_y = -vecs_y;
314         else
315                 vecs = '0 0 0';
316
317         dv = view_right * vecs_y + view_up * vecs_z;
318         w_shotorg = view_origin + dv;
319
320         // now move the vecs forward as much as requested if possible
321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
322         w_shotorg = trace_endpos - view_forward * nudge;
323
324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
325         shottype = EnemyHitCheck();
326         if(shottype != SHOTTYPE_HITWORLD)
327                 return shottype;
328
329 #if 0
330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
331         // or rather, I know why, but see no fix
332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
334                 return SHOTTYPE_HITOBSTRUCTION;
335 #endif
336
337         return SHOTTYPE_HITWORLD;
338 }
339
340 void CSQC_common_hud(void);
341
342 void PostInit(void);
343 void CSQC_Demo_Camera();
344 float HUD_WouldDrawScoreboard();
345 float view_set;
346 float camera_mode;
347 float reticle_type;
348 string NextFrameCommand;
349 void CSQC_SPIDER_HUD();
350 void CSQC_RAPTOR_HUD();
351
352 vector freeze_pmove_org, freeze_input_angles;
353 entity nightvision_noise, nightvision_noise2;
354
355 float pickup_crosshair_time, pickup_crosshair_size;
356 float use_nex_chargepool;
357
358 float myhealth, myhealth_prev;
359 float myhealth_flash;
360
361 vector myhealth_gentlergb;
362
363 float contentavgalpha;
364
365 void CSQC_UpdateView(float w, float h)
366 {
367         entity e;
368         float fov;
369         float f, i, j;
370         vector v, vo;
371         vector vf_size, vf_min;
372         float a;
373
374         vf_size = R_SetView3fv(VF_SIZE);
375         vf_min = R_SetView3fv(VF_MIN);
376         vid_width = vf_size_x;
377         vid_height = vf_size_y;
378
379         vector reticle_pos, reticle_size;
380
381         WaypointSprite_Load();
382
383         if(spectatee_status)
384                 myteam = GetPlayerColor(spectatee_status - 1);
385         else
386                 myteam = GetPlayerColor(player_localentnum - 1);
387
388         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
389         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
390
391         warpzone_fixview_origin = pmove_org + vo;
392         warpzone_fixview_cl_viewangles = input_angles;
393         warpzone_fixview_angles = view_angles;
394         WarpZone_FixView();
395         pmove_org = warpzone_fixview_origin - vo;
396         input_angles = warpzone_fixview_cl_viewangles;
397         view_angles = warpzone_fixview_angles;
398
399         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
400         {
401                 pmove_org = freeze_pmove_org;
402                 input_angles = view_angles = freeze_input_angles;
403                 R_SetView(VF_ORIGIN, pmove_org + vo);
404                 R_SetView(VF_ANGLES, view_angles);
405                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
406         }
407         freeze_pmove_org = pmove_org;
408         freeze_input_angles = input_angles;
409
410         // Render the Scene
411         if(!intermission || !view_set)
412         {
413                 view_origin = pmove_org + vo;
414                 view_angles = input_angles;
415                 makevectors(view_angles);
416                 view_forward = v_forward;
417                 view_right = v_right;
418                 view_up = v_up;
419                 view_set = 1;
420         }
421
422 #ifdef BLURTEST
423         if(time > blurtest_time0 && time < blurtest_time1)
424         {
425                 float r, t;
426
427                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
428                 r = t * blurtest_radius;
429                 f = 1 / pow(t, blurtest_power) - 1;
430
431                 cvar_set("r_glsl_postprocess", "1");
432                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
433         }
434         else
435         {
436                 cvar_set("r_glsl_postprocess", "0");
437                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
438         }
439 #endif
440
441         TargetMusic_Advance();
442         Fog_Force();
443
444         drawframetime = max(0.000001, time - drawtime);
445         drawtime = time;
446
447         // watch for gametype changes here...
448         // in ParseStuffCMD the cmd isn't executed yet :/
449         // might even be better to add the gametype to TE_CSQC_INIT...?
450         if(!postinit)
451                 PostInit();
452
453         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
454                 if(calledhooks & HOOK_START)
455                 {
456                         localcmd("\ncl_hook_gameend\n");
457                         calledhooks |= HOOK_END;
458                 }
459
460         CheckForGamestartChange();
461         serverAnnouncer();
462         maptimeAnnouncer();
463         carrierAnnouncer();
464
465         fov = autocvar_fov;
466         if(button_zoom || fov <= 59.5)
467         {
468                 if(!zoomscript_caught)
469                 {
470                         localcmd("+button4\n");
471                         zoomscript_caught = 1;
472                         ignore_plus_zoom += 1;
473                 }
474         }
475         else
476         {
477                 if(zoomscript_caught)
478                 {
479                         localcmd("-button4\n");
480                         zoomscript_caught = 0;
481                         ignore_minus_zoom += 1;
482                 }
483         }
484
485         ColorTranslateMode = autocvar_cl_stripcolorcodes;
486         activeweapon = getstati(STAT_SWITCHWEAPON);
487         f = (serverflags & SERVERFLAG_TEAMPLAY);
488         if(f != teamplay)
489         {
490                 teamplay = f;
491                 HUD_InitScores();
492         }
493
494         if(last_weapon != activeweapon) {
495                 weapontime = time;
496                 last_weapon = activeweapon;
497
498                 e = get_weaponinfo(activeweapon);
499                 if(e.netname != "")
500                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
501                 else
502                         localcmd("\ncl_hook_activeweapon none\n");
503         }
504
505         // ALWAYS Clear Current Scene First
506         R_ClearScene();
507
508         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
509         R_SetView(VF_SIZE, vf_size);
510         R_SetView(VF_MIN, vf_min);
511
512         // Assign Standard Viewflags
513         // Draw the World (and sky)
514         R_SetView(VF_DRAWWORLD, 1);
515
516         // Set the console size vars
517         vid_conwidth = autocvar_vid_conwidth;
518         vid_conheight = autocvar_vid_conheight;
519         vid_pixelheight = autocvar_vid_pixelheight;
520
521         R_SetView(VF_FOV, GetCurrentFov(fov));
522
523         // Camera for demo playback
524         if(camera_active)
525         {
526                 if(autocvar_camera_enable)
527                         CSQC_Demo_Camera();
528                 else
529                 {
530                         cvar_set("chase_active", ftos(chase_active_backup));
531                         cvar_set("cl_demo_mousegrab", "0");
532                         camera_active = FALSE;
533                 }
534         }
535 #ifdef CAMERATEST
536         else if(autocvar_camera_enable)
537 #else
538         else if(autocvar_camera_enable && isdemo())
539 #endif
540         {
541                 // Enable required Darkplaces cvars
542                 chase_active_backup = autocvar_chase_active;
543                 cvar_set("chase_active", "2");
544                 cvar_set("cl_demo_mousegrab", "1");
545                 camera_active = TRUE;
546                 camera_mode = FALSE;
547         }
548
549         // Draw the Crosshair
550         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
551
552         // Draw the Engine Status Bar (the default Quake HUD)
553         R_SetView(VF_DRAWENGINEHUD, 0);
554
555         // fetch this one only once per frame
556         hud_showbinds = autocvar_hud_showbinds;
557         hud_showbinds_limit = autocvar_hud_showbinds_limit;
558
559         // Update the mouse position
560         /*
561            mousepos_x = vid_conwidth;
562            mousepos_y = vid_conheight;
563            mousepos = mousepos*0.5 + getmousepos();
564          */
565
566         e = self;
567         for(self = world; (self = nextent(self)); )
568                 if(self.draw)
569                         self.draw();
570         self = e;
571
572         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
573         R_RenderScene();
574
575         // now switch to 2D drawing mode by calling a 2D drawing function
576         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
577         // next R_RenderScene call
578         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
579
580         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
581         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
582         {
583                 // apply night vision effect
584                 vector rgb, tc_00, tc_01, tc_10, tc_11;
585
586                 if(!nightvision_noise)
587                 {
588                         nightvision_noise = spawn();
589                         nightvision_noise.classname = "nightvision_noise";
590                 }
591                 if(!nightvision_noise2)
592                 {
593                         nightvision_noise2 = spawn();
594                         nightvision_noise2.classname = "nightvision_noise2";
595                 }
596
597                 // color tint in yellow
598                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
599
600                 // draw BG
601                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
602                 rgb = '1 1 1';
603                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
604                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
605                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
606                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
607                 tc_11 = tc_01 + tc_10 - tc_00;
608                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
609                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
610                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
611                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
612                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
613                 R_EndPolygon();
614
615                 // draw FG
616                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
617                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
618                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
619                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
620                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
621                 tc_11 = tc_01 + tc_10 - tc_00;
622                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
623                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
624                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
625                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
626                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
627                 R_EndPolygon();
628         }
629
630         // Draw the aiming reticle for weapons that use it
631         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
632         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
633         // the view to go back to normal, so reticle_type would become 0 as we fade out)
634         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
635                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
636         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
637                 reticle_type = 2; // nex zoom
638         else if(button_zoom || zoomscript_caught)
639                 reticle_type = 1; // normal zoom
640         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
641                 reticle_type = 2; // nex zoom
642
643         if(autocvar_cl_reticle_stretch)
644         {
645                 reticle_size_x = vid_conwidth;
646                 reticle_size_y = vid_conheight;
647                 reticle_pos_x = 0;
648                 reticle_pos_y = 0;
649         }
650         else
651         {
652                 reticle_size_x = max(vid_conwidth, vid_conheight);
653                 reticle_size_y = max(vid_conwidth, vid_conheight);
654                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
655                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
656         }
657
658         f = current_zoomfraction;
659         if(zoomscript_caught)
660                 f = 1;
661         if(autocvar_cl_reticle_item_normal)
662         {
663                 precache_pic("gfx/reticle_normal");
664                 if(reticle_type == 1 && f)
665                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
666         }
667         if(autocvar_cl_reticle_item_nex)
668         {
669                 precache_pic("gfx/reticle_nex");
670                 if(reticle_type == 2 && f)
671                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
672         }
673
674         // improved polyblend with post processing effects
675         vector rgb;
676         vector damage_blurpostprocess;
677         vector content_blurpostprocess;
678         if(autocvar_hud_contents)
679         {
680                 float contentalpha_temp, incontent, liquidalpha;
681                 vector liquidcolor;
682                 
683                 switch(pointcontents(view_origin))
684                 {
685                         case CONTENT_WATER:
686                                 liquidalpha = autocvar_hud_contents_water_alpha;
687                                 liquidcolor = stov(autocvar_hud_contents_water_color);
688                                 incontent = 1;
689                                 break;
690                                 
691                         case CONTENT_LAVA:
692                                 liquidalpha = autocvar_hud_contents_lava_alpha;
693                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
694                                 incontent = 1;
695                                 break;  
696                                                         
697                         case CONTENT_SLIME:
698                                 liquidalpha = autocvar_hud_contents_slime_alpha;
699                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
700                                 incontent = 1;
701                                 break;
702                                 
703                         default:
704                                 liquidalpha = 0;
705                                 liquidcolor = '0 0 0';
706                                 incontent = 0;
707                                 break;
708                 }
709                 
710                 contentalpha_temp = bound(0, drawframetime / max(0.0001, autocvar_hud_contents_fadetime), 1);
711                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
712                 //contentalpha_temp = contentavgalpha;
713                 
714                 if(incontent)
715                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor, contentavgalpha * liquidalpha, DRAWFLAG_NORMAL);
716                 
717                 if(autocvar_hud_postprocessing)
718                 {
719                         if(autocvar_hud_contents_blur)
720                         {
721                                 content_blurpostprocess_x = 1;
722                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
723                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
724                         }
725                         else
726                         {
727                                 content_blurpostprocess_x = 0;
728                                 content_blurpostprocess_y = 0;
729                                 content_blurpostprocess_z = 0;
730                         }
731                 }
732         }
733         
734         if(autocvar_hud_damage)
735         {
736                 float myhealth_flash_temp;
737                 myhealth = getstati(STAT_HEALTH);
738
739                 // fade out
740                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
741                 // add new damage
742                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
743
744                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
745                 pain_threshold = autocvar_hud_damage_pain_threshold;
746                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
747                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
748
749                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
750                 {
751                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
752                 }
753
754                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
755
756                 if(myhealth_prev < 1)
757                 {
758                         if(myhealth >= 1)
759                         {
760                                 myhealth_flash = 0; // just spawned, clear the flash immediately
761                                 myhealth_flash_temp = 0;
762                         }
763                         else
764                         {
765                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
766                         }
767                 }
768
769                 if(spectatee_status == -1 || intermission)
770                 {
771                         myhealth_flash = 0; // observing, or match ended
772                         myhealth_flash_temp = 0;
773                 }
774
775                 myhealth_prev = myhealth;
776
777                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
778                 {
779                         if(autocvar_cl_gentle_damage == 2)
780                         {
781                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
782                                 {
783                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
784                                 }
785                         }
786                         else
787                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
788
789                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
790                 }
791                 else if(autocvar_hud_damage_image)
792                         drawpic(reticle_pos, "gfx/blood", reticle_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
793                         
794                 if(autocvar_hud_postprocessing)
795                 {
796                         if(autocvar_hud_damage_blur)
797                         {
798                                 damage_blurpostprocess_x = 1;
799                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
800                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
801                         }
802                         else
803                         {
804                                 damage_blurpostprocess_x = 0;
805                                 damage_blurpostprocess_y = 0;
806                                 damage_blurpostprocess_z = 0;
807                         }
808                 }
809         }
810         
811         if(autocvar_hud_postprocessing)
812         { // lets apply the postprocess effects from the previous two functions if needed
813                 if(damage_blurpostprocess_x || content_blurpostprocess_x)
814                 {
815                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
816                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
817                         cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
818                         cvar_set("r_glsl_postprocess_uservec1_enable", "1");
819                 }
820                 else
821                 {
822                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
823                         cvar_set("r_glsl_postprocess_uservec1_enable", "0");
824                 }
825         }
826         
827
828         // Draw the mouse cursor
829         // NOTE: drawpic must happen after R_RenderScene for some reason
830         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
831         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
832         //self = edict_num(player_localnum);
833         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
834         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
835         // as long as the ctf part isn't in, this is useless
836         if(menu_visible)
837                 menu_show();
838
839         /*if(gametype == GAME_CTF)
840           {
841           ctf_view();
842           } else */
843
844         // draw 2D entities
845         e = self;
846         for(self = world; (self = nextent(self)); )
847                 if(self.draw2d)
848                         self.draw2d();
849         self = e;
850
851         scoreboard_active = HUD_WouldDrawScoreboard();
852
853         float hud;
854         hud = getstati(STAT_HUD);
855         if(hud == HUD_SPIDERBOT)
856                 CSQC_SPIDER_HUD();
857         else if(hud == HUD_WAKIZASHI)
858         CSQC_WAKIZASHI_HUD();
859     else if(hud == HUD_RAPTOR)
860         CSQC_RAPTOR_HUD();
861         else
862         {
863                 if(gametype == GAME_FREEZETAG)
864                 {
865                         if(getstati(STAT_FROZEN))
866                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
867                         if(getstatf(STAT_REVIVE_PROGRESS))
868                         {
869                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
870                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
871                         }
872                 }
873
874                 if(autocvar_r_letterbox == 0)
875                         if(autocvar_viewsize < 120)
876                                 CSQC_common_hud();
877
878                 // crosshair goes VERY LAST
879                 if(!scoreboard_active && !camera_active && intermission != 2) {
880                         string wcross_style;
881                         float wcross_alpha, wcross_resolution;
882                         wcross_style = autocvar_crosshair;
883                         if (wcross_style == "0")
884                                 return;
885                         wcross_resolution = autocvar_crosshair_size;
886                         if (wcross_resolution == 0)
887                                 return;
888                         wcross_alpha = autocvar_crosshair_alpha;
889                         if (wcross_alpha == 0)
890                                 return;
891
892                         // TrueAim check
893                         float shottype;
894                         float bullets, ring_scale;
895                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
896                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
897                         wcross_origin_z = 0;
898                         if(autocvar_crosshair_hittest)
899                         {
900                                 vector wcross_oldorigin;
901                                 wcross_oldorigin = wcross_origin;
902                                 shottype = TrueAimCheck();
903                                 if(shottype == SHOTTYPE_HITWORLD)
904                                 {
905                                         v = wcross_origin - wcross_oldorigin;
906                                         v_x /= vid_conwidth;
907                                         v_y /= vid_conheight;
908                                         if(vlen(v) > 0.01)
909                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
910                                 }
911                                 if(!autocvar_crosshair_hittest_showimpact)
912                                         wcross_origin = wcross_oldorigin;
913                         }
914                         else
915                                 shottype = SHOTTYPE_HITWORLD;
916
917                         vector wcross_color, wcross_size;
918                         string wcross_wep, wcross_name;
919                         float wcross_scale, wcross_blur;
920
921                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
922                                 e = get_weaponinfo(activeweapon);
923                                 if (e && e.netname != "")
924                                 {
925                                         wcross_wep = e.netname;
926                                         if(autocvar_crosshair_per_weapon)
927                                         {
928                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
929                                                 if (wcross_resolution == 0)
930                                                         return;
931                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
932                                                 if (wcross_alpha == 0)
933                                                         return;
934
935                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
936                                                 if(wcross_style == "" || wcross_style == "0")
937                                                         wcross_style = wcross_wep;
938                                         }
939                                 }
940                         }
941                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
942                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
943                         else
944                                 wcross_color = stov(autocvar_crosshair_color);
945
946                         wcross_name = strcat("gfx/crosshair", wcross_style);
947
948                         if(autocvar_crosshair_effect_scalefade)
949                         {
950                                 wcross_scale = wcross_resolution;
951                                 wcross_resolution = 1;
952                         }
953                         else
954                         {
955                                 wcross_scale = 1;
956                         }
957
958                         if(autocvar_crosshair_pickup)
959                         {
960                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
961                                 {
962                                         pickup_crosshair_size = 1;
963                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
964                                 }
965
966                                 if(pickup_crosshair_size > 0)
967                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
968                                 else
969                                         pickup_crosshair_size = 0;
970
971                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
972                         }
973
974                         if(shottype == SHOTTYPE_HITENEMY)
975                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
976                         if(shottype == SHOTTYPE_HITTEAM)
977                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
978
979                         f = autocvar_crosshair_effect_speed;
980                         if(f < 0)
981                                 f *= -2 * g_weaponswitchdelay;
982                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
983                         {
984                                 wcross_changedonetime = time + f;
985                         }
986                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
987                         {
988                                 wcross_name_changestarttime = time;
989                                 wcross_name_changedonetime = time + f;
990                                 if(wcross_name_goal_prev_prev)
991                                         strunzone(wcross_name_goal_prev_prev);
992                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
993                                 wcross_name_goal_prev = strzone(wcross_name);
994                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
995                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
996                                 wcross_resolution_goal_prev = wcross_resolution;
997                         }
998
999                         wcross_scale_goal_prev = wcross_scale;
1000                         wcross_alpha_goal_prev = wcross_alpha;
1001                         wcross_color_goal_prev = wcross_color;
1002
1003                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1004                         {
1005                                 wcross_blur = 1;
1006                                 wcross_alpha *= 0.75;
1007                         }
1008                         else
1009                                 wcross_blur = 0;
1010                         // *_prev is at time-frametime
1011                         // * is at wcross_changedonetime+f
1012                         // what do we have at time?
1013                         if(time < wcross_changedonetime)
1014                         {
1015                                 f = frametime / (wcross_changedonetime - time + frametime);
1016                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1017                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1018                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1019                         }
1020
1021                         wcross_scale_prev = wcross_scale;
1022                         wcross_alpha_prev = wcross_alpha;
1023                         wcross_color_prev = wcross_color;
1024
1025                         wcross_scale *= 1 - autocvar__menu_alpha;
1026                         wcross_alpha *= 1 - autocvar__menu_alpha;
1027
1028                         ring_scale = autocvar_crosshair_ring_size;
1029
1030                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1031
1032                         float nex_charge, nex_chargepool;
1033                         nex_charge = getstatf(STAT_NEX_CHARGE);
1034                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1035
1036                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1037                                 nex_charge_movingavg = nex_charge;
1038
1039                         // ring around crosshair representing bullets left in camping rifle clip
1040                         if (activeweapon == WEP_SNIPERRIFLE && cr_maxbullets)
1041                         {
1042                                 bullets = getstati(STAT_BULLETS_LOADED);
1043                                 f = bound(0, bullets / cr_maxbullets, 1);
1044
1045                                 a = autocvar_crosshair_ring_sniperrifle_alpha;
1046                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1047                         }
1048                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
1049                         {
1050                                 if(nex_chargepool || use_nex_chargepool)
1051                                 {
1052                                         use_nex_chargepool = 1;
1053
1054                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1055                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1056                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", nex_chargepool, rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1057                                 }
1058                                 else
1059                                 {
1060                                         // indicate how much we're charging right now with an inner circle
1061                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1062                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1063
1064                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1065                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1066                                 }
1067
1068                                 // draw the charge
1069                                 a = autocvar_crosshair_ring_nex_outer_alpha;
1070                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1071                         }
1072
1073 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1074                         do \
1075                         { \
1076                                 if(wcross_blur > 0) \
1077                                 { \
1078                                         for(i = -2; i <= 2; ++i) \
1079                                                 for(j = -2; j <= 2; ++j) \
1080                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1081                                 } \
1082                                 else \
1083                                 { \
1084                                         M(0,0,sz,wcross_name,wcross_alpha); \
1085                                 } \
1086                         } \
1087                         while(0)
1088
1089 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1090                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1091
1092 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1093                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1094
1095                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1096                         {
1097                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1098                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1099                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1100                                 f = 1 - f;
1101                         }
1102                         else
1103                         {
1104                                 f = 1;
1105                         }
1106
1107                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1108                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1109
1110                         if(autocvar_crosshair_dot)
1111             {
1112                 vector wcross_color_old;
1113                 wcross_color_old = wcross_color;
1114                 if(autocvar_crosshair_dot_color != "0")
1115                     wcross_color = stov(autocvar_crosshair_dot_color);
1116                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1117                 wcross_color = wcross_color_old;
1118             }
1119
1120                         wcross_name_alpha_goal_prev = f;
1121                 }
1122                 else
1123                 {
1124                         wcross_scale_prev = 0;
1125                         wcross_alpha_prev = 0;
1126                         wcross_scale_goal_prev = 0;
1127                         wcross_alpha_goal_prev = 0;
1128                         wcross_changedonetime = 0;
1129                         if(wcross_name_goal_prev)
1130                                 strunzone(wcross_name_goal_prev);
1131                         wcross_name_goal_prev = string_null;
1132                         if(wcross_name_goal_prev_prev)
1133                                 strunzone(wcross_name_goal_prev_prev);
1134                         wcross_name_goal_prev_prev = string_null;
1135                         wcross_name_changestarttime = 0;
1136                         wcross_name_changedonetime = 0;
1137                         wcross_name_alpha_goal_prev = 0;
1138                         wcross_name_alpha_goal_prev_prev = 0;
1139                         wcross_resolution_goal_prev = 0;
1140                         wcross_resolution_goal_prev_prev = 0;
1141                 }
1142         }
1143
1144         if(NextFrameCommand)
1145         {
1146                 localcmd("\n", NextFrameCommand, "\n");
1147                 NextFrameCommand = string_null;
1148         }
1149
1150         // we must do this check AFTER a frame was rendered, or it won't work
1151         if(cs_project_is_b0rked == 0)
1152         {
1153                 string w0, h0;
1154                 w0 = ftos(autocvar_vid_conwidth);
1155                 h0 = ftos(autocvar_vid_conheight);
1156                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1157                 //R_SetView(VF_FOV, '90 90 0');
1158                 R_SetView(VF_ORIGIN, '0 0 0');
1159                 R_SetView(VF_ANGLES, '0 0 0');
1160                 R_SetView(VF_PERSPECTIVE, 1);
1161                 makevectors('0 0 0');
1162                 vector v1, v2;
1163                 cvar_set("vid_conwidth", "800");
1164                 cvar_set("vid_conheight", "600");
1165                 v1 = cs_project(v_forward);
1166                 cvar_set("vid_conwidth", "640");
1167                 cvar_set("vid_conheight", "480");
1168                 v2 = cs_project(v_forward);
1169                 if(v1 == v2)
1170                         cs_project_is_b0rked = 1;
1171                 else
1172                         cs_project_is_b0rked = -1;
1173                 cvar_set("vid_conwidth", w0);
1174                 cvar_set("vid_conheight", h0);
1175         }
1176
1177         if(autocvar__hud_configure)
1178                 HUD_Panel_Mouse();
1179
1180         // let's reset the view back to normal for the end
1181         R_SetView(VF_MIN, '0 0 0');
1182         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1183 }
1184
1185 #define spider_h "gfx/vehicles/hud_bg.tga"
1186 #define spider_b "gfx/vehicles/sbot.tga"
1187 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1188 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1189 #define spider_s "gfx/vehicles/shiled.tga"
1190 #define spider_a1 "gfx/hud/sb_rocket.tga"
1191 #define spider_a2 "gfx/sb_bullets.tga"
1192
1193 void CSQC_SPIDER_HUD()
1194 {
1195         float rockets, reload, heat, hp, shield;
1196         vector picsize, hudloc;
1197
1198     // Fetch health & ammo stats
1199     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1200         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1201         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1202         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1203         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1204
1205     // Draw the crosshairs
1206     picsize = drawgetimagesize(SPIDER_CROSS);
1207     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1208     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1209     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1210
1211     hudloc_y =  4;
1212     hudloc_x = 4;
1213
1214     picsize = drawgetimagesize(spider_h) * 0.5;
1215     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1216
1217     picsize = drawgetimagesize(spider_a2) * 0.5;
1218     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1219
1220     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1221     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1222     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1223
1224     picsize = drawgetimagesize(spider_a1) * 0.85;
1225     if(rockets == 9)
1226     {
1227         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1228         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1229     }
1230     else
1231     {
1232         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1233         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1234     }
1235
1236     picsize = drawgetimagesize(spider_b) * 0.5;
1237     hudloc_y = 10.5;
1238     hudloc_x = 10.5;
1239
1240     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1241     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1242     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1243     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1244
1245
1246         /*
1247         // Draw health bar
1248         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1249         p = p + '0 1 0' * vid_conheight - '0 32 0';
1250         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1251         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1252         p_y += 8;
1253         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1254         p_x += 256 * hp;
1255         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1256
1257         // Draw minigun heat indicator
1258         p = '0.5 0 0' * (vid_conwidth - 256);
1259         p = p + '0 1 0' * vid_conheight - '0 34  0';
1260         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1261         p_x += 256 * (1-heat);
1262         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1263
1264
1265         // Draw rocket icons for loaded/empty tubes.
1266         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1267         pp += '0 1 0' * vid_conheight - '0 64 0';
1268         for(i = 0; i < 8; ++i)
1269         {
1270                 p = pp + '1 0 0' * (rkt_size * i);
1271                 if(rockets == 8)
1272                 {
1273                         if(floor(reload * 8) == i)
1274                         {
1275                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1276                         }
1277                         else if(i < reload * 8)
1278                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1279                         else
1280                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1281                 }
1282                 else
1283                 {
1284                         if(i < rockets)
1285                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1286                         else
1287                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1288                 }
1289         }
1290         */
1291
1292         if (scoreboard_showscores)
1293         {
1294                 HUD_DrawScoreboard();
1295                 HUD_DrawCenterPrint();
1296         }
1297
1298 }
1299
1300 #define raptor_h "gfx/vehicles/hud_bg.tga"
1301 #define raptor_b "gfx/vehicles/raptor.tga"
1302 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1303 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1304 #define raptor_s "gfx/vehicles/shiled.tga"
1305
1306 void CSQC_RAPTOR_HUD()
1307 {
1308         float reload, hp, shield, energy;
1309         vector picsize, hudloc;
1310
1311     // Fetch health & ammo stats
1312     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1313         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1314         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1315         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1316
1317     // Draw the crosshairs
1318     picsize = drawgetimagesize(SPIDER_CROSS);
1319     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1320     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1321     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1322
1323     hudloc_y =  4;
1324     hudloc_x = 4;
1325
1326     picsize = drawgetimagesize(raptor_h) * 0.5;
1327     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1328
1329     picsize = drawgetimagesize(spider_a2) * 0.5;
1330     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1331
1332     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1333     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1334     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1335
1336
1337     picsize = drawgetimagesize(spider_a1) * 0.85;
1338     if(reload == 1)
1339     {
1340         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1341         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1342     }
1343     else
1344     {
1345         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1346         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1347     }
1348
1349     picsize = drawgetimagesize(raptor_b) * 0.5;
1350     hudloc_y = 10.5;
1351     hudloc_x = 10.5;
1352
1353     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1354     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1355     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1356     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1357
1358
1359         if (scoreboard_showscores)
1360         {
1361                 HUD_DrawScoreboard();
1362                 HUD_DrawCenterPrint();
1363         }
1364
1365 }
1366
1367 #define waki_h "gfx/vehicles/hud_bg.tga"
1368 #define waki_b "gfx/vehicles/waki.tga"
1369 #define waki_e "gfx/vehicles/waki_e.tga"
1370 #define waki_g "gfx/vehicles/waki_guns.tga"
1371 #define waki_r "gfx/vehicles/waki_rockets.tga"
1372 #define waki_s "gfx/vehicles/shiled.tga"
1373
1374 #define waki_a1 "gfx/hud/sb_rocket.tga"
1375 #define waki_a2 "gfx/sb_cells.tga"
1376
1377 void CSQC_WAKIZASHI_HUD()
1378 {
1379         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1380         float health, shield, energy, rockets;
1381         vector picsize, hudloc;
1382
1383     picsize = drawgetimagesize(SPIDER_CROSS);
1384     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1385     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1386     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1387
1388 /*
1389 const float STAT_VEHICLESTAT_HEALTH  = 60;
1390 const float STAT_VEHICLESTAT_SHIELD  = 61;
1391 const float STAT_VEHICLESTAT_ENERGY  = 62;
1392 const float STAT_VEHICLESTAT_AMMO1   = 63;
1393 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1394 const float STAT_VEHICLESTAT_AMMO2   = 65;
1395 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1396 */
1397     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1398         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1399         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1400         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1401
1402     hudloc_y =  4;
1403     hudloc_x = 4;
1404
1405     picsize = drawgetimagesize(waki_h) * 0.5;
1406     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1407
1408     picsize = drawgetimagesize(waki_a2) * 0.7;
1409     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1410
1411
1412     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1413     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1414
1415     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1416
1417     picsize = drawgetimagesize(waki_a1) * 0.75;
1418     if(rockets == 1)
1419     {
1420         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1421         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1422     }
1423     else
1424     {
1425         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1426         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1427         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1428     }
1429
1430     picsize = drawgetimagesize(waki_b) * 0.5;
1431     hudloc_y = 10.5;
1432     hudloc_x = 10.5;
1433
1434     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1435     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1436     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1437     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1438
1439
1440
1441         /*
1442         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1443         p = p + '0 1 0' * vid_conheight - '0 32 0';
1444
1445         // Draw health bar
1446         p_y += 8;
1447         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1448         p_x += 256 * health;
1449         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1450
1451         // Draw shiled bar
1452         p_x -= 256 * health;
1453         p_y += 4;
1454         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1455
1456         // Draw energy
1457         //p_x -= 256 * health;
1458         p_y -= 8;
1459         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1460
1461         // Draw rockets bar
1462         p_y += 12;
1463         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1464         */
1465
1466
1467
1468
1469         if (scoreboard_showscores)
1470         {
1471                 HUD_DrawScoreboard();
1472                 HUD_DrawCenterPrint();
1473         }
1474
1475 }
1476
1477
1478 void CSQC_common_hud(void)
1479 {
1480         // HUD_SortFrags(); done in HUD_Draw
1481         float hud;
1482         hud = getstati(STAT_HUD);
1483
1484         //hud = 10;
1485         switch(hud)
1486         {
1487                 case HUD_NORMAL:
1488                         // do some accuracy var caching
1489                         float i;
1490                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1491                         {
1492                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1493                                 {
1494                                         if(acc_color_levels)
1495                                                 strunzone(acc_color_levels);
1496                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1497                                         acc_levels = tokenize(acc_color_levels);
1498                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1499                                                 acc_levels = MAX_ACCURACY_LEVELS;
1500
1501                                         for (i = 0; i < acc_levels; ++i)
1502                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1503                                 }
1504                                 // let know that acc_col[] needs to be loaded
1505                                 acc_col_x[0] = -1;
1506                         }
1507
1508                         HUD_Main(); // always run these functions for alpha checks
1509                         HUD_DrawScoreboard();
1510
1511                         if (scoreboard_active) // scoreboard/accuracy
1512                         {       
1513                                 HUD_Reset();
1514                                 // HUD_DrawScoreboard takes care of centerprint_start
1515                         }
1516                         else if (intermission == 2) // map voting screen
1517                         {
1518                                 HUD_FinaleOverlay();
1519                                 HUD_Reset();
1520
1521                                 centerprint_start_x = 0;
1522                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1523                         }
1524                         else // hud
1525                         {
1526                                 centerprint_start_x = 0;
1527                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1528                         }
1529
1530                         HUD_DrawCenterPrint();
1531                         break;
1532
1533                 case HUD_SPIDERBOT:
1534                         CSQC_SPIDER_HUD();
1535                         break;
1536
1537                 case HUD_WAKIZASHI:
1538                         CSQC_WAKIZASHI_HUD();
1539                         break;
1540         }
1541 }
1542
1543
1544 // following vectors must be global to allow seamless switching between camera modes
1545 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1546 void CSQC_Demo_Camera()
1547 {
1548         float speed, attenuation, dimensions;
1549         vector tmp, delta;
1550
1551         if( autocvar_camera_reset || !camera_mode )
1552         {
1553                 camera_offset = '0 0 0';
1554                 current_angles = '0 0 0';
1555                 camera_direction = '0 0 0';
1556                 camera_offset_z += 30;
1557                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1558                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1559                 current_origin = view_origin;
1560                 current_camera_offset  = camera_offset;
1561                 cvar_set("camera_reset", "0");
1562                 camera_mode = CAMERA_CHASE;
1563         }
1564
1565         // Camera angles
1566         if( camera_roll )
1567                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1568
1569         if(autocvar_camera_look_player)
1570         {
1571                 local vector dir;
1572                 local float n;
1573
1574                 dir = normalize(view_origin - current_position);
1575                 n = mouse_angles_z;
1576                 mouse_angles = vectoangles(dir);
1577                 mouse_angles_x = mouse_angles_x * -1;
1578                 mouse_angles_z = n;
1579         }
1580         else
1581         {
1582                 tmp = getmousepos() * 0.1;
1583                 if(vlen(tmp)>autocvar_camera_mouse_treshold)
1584                 {
1585                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1586                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1587                 }
1588         }
1589
1590         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1591         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1592         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1593         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1594
1595         // Fix difference when angles don't have the same sign
1596         delta = '0 0 0';
1597         if(mouse_angles_y < -60 && current_angles_y > 60)
1598                 delta = '0 360 0';
1599         if(mouse_angles_y > 60 && current_angles_y < -60)
1600                 delta = '0 -360 0';
1601
1602         if(autocvar_camera_look_player)
1603                 attenuation = autocvar_camera_look_attenuation;
1604         else
1605                 attenuation = autocvar_camera_speed_attenuation;
1606
1607         attenuation = 1 / max(1, attenuation);
1608         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1609
1610         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1611         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1612         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1613         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1614
1615         // Camera position
1616         tmp = '0 0 0';
1617         dimensions = 0;
1618
1619         if( camera_direction_x )
1620         {
1621                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1622                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1623                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1624                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1625                 ++dimensions;
1626         }
1627
1628         if( camera_direction_y )
1629         {
1630                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1631                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1632                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1633                 ++dimensions;
1634         }
1635
1636         if( camera_direction_z )
1637         {
1638                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1639                 ++dimensions;
1640         }
1641
1642         if(autocvar_camera_free)
1643                 speed = autocvar_camera_speed_free;
1644         else
1645                 speed = autocvar_camera_speed_chase;
1646
1647         if(dimensions)
1648         {
1649                 speed = speed * sqrt(1 / dimensions);
1650                 camera_offset += tmp * speed;
1651         }
1652
1653         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1654
1655         // Camera modes
1656         if( autocvar_camera_free )
1657         {
1658                 if ( camera_mode == CAMERA_CHASE )
1659                 {
1660                         current_camera_offset = current_origin + current_camera_offset;
1661                         camera_offset = current_origin + camera_offset;
1662                 }
1663
1664                 camera_mode = CAMERA_FREE;
1665                 current_position = current_camera_offset;
1666         }
1667         else
1668         {
1669                 if ( camera_mode == CAMERA_FREE )
1670                 {
1671                         current_origin = view_origin;
1672                         camera_offset = camera_offset - current_origin;
1673                         current_camera_offset = current_camera_offset - current_origin;
1674                 }
1675
1676                 camera_mode = CAMERA_CHASE;
1677
1678                 if(autocvar_camera_chase_smoothly)
1679                         current_origin += (view_origin - current_origin) * attenuation;
1680                 else
1681                         current_origin = view_origin;
1682
1683                 current_position = current_origin + current_camera_offset;
1684         }
1685
1686         R_SetView(VF_ANGLES, current_angles);
1687         R_SetView(VF_ORIGIN, current_position);
1688 }