qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 166         {
 167                 if(intermission) { curspeed = 0; }
 168                 else
 169                 {
 170
 171                         makevectors(view_angles);
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon) // WEAPONTODO
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_MORTAR: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_VORTEX:
 291                 case WEP_VAPORIZER:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_DEVASTATOR: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string reticle_image;
 369 string NextFrameCommand;
 370 void CSQC_SPIDER_HUD();
 371 void CSQC_RAPTOR_HUD();
 372
 373 vector freeze_org, freeze_ang;
 374 entity nightvision_noise, nightvision_noise2;
 375
 376 #define MAX_TIME_DIFF 5
 377 float pickup_crosshair_time, pickup_crosshair_size;
 378 float hitsound_time_prev;
 379 float spectatee_status_prev; // for preventing hitsound when switching spectatee
 380 float damage_dealt_total, damage_dealt_total_prev;
 381 float typehit_time, typehit_time_prev;
 382 float hitindication_crosshair_size;
 383 float use_vortex_chargepool;
 384
 385 float myhealth, myhealth_prev;
 386 float myhealth_flash;
 387
 388 float old_blurradius, old_bluralpha;
 389 float old_sharpen_intensity;
 390
 391 vector myhealth_gentlergb;
 392
 393 float contentavgalpha, liquidalpha_prev;
 394 vector liquidcolor_prev;
 395
 396 float eventchase_current_distance;
 397
 398 vector damage_blurpostprocess, content_blurpostprocess;
 399
 400 float checkfail[16];
 401
 402 float rainbow_last_flicker;
 403 vector rainbow_prev_color;
 404
 405 #define BUTTON_3 4
 406 #define BUTTON_4 8
 407 float cl_notice_run();
 408 float prev_myteam;
 409 void CSQC_UpdateView(float w, float h)
 410 {
 411         entity e;
 412         float fov;
 413         float f, i, j;
 414         vector v;
 415         vector vf_size, vf_min;
 416         float a;
 417
 418         execute_next_frame();
 419
 420         ++framecount;
 421
 422         hud = getstati(STAT_HUD);
 423
 424         if(autocvar__hud_showbinds_reload) // menu can set this one
 425         {
 426                 db_close(binddb);
 427                 binddb = db_create();
 428                 cvar_set("_hud_showbinds_reload", "0");
 429         }
 430
 431         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 432                 view_quality = getproperty(VF_MINFPS_QUALITY);
 433         else
 434                 view_quality = 1;
 435
 436         button_attack2 = (input_buttons & BUTTON_3);
 437         button_zoom = (input_buttons & BUTTON_4);
 438
 439 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 440         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 441         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 442         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 443         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 444         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 445         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 446         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 447
 448         vf_size = getpropertyvec(VF_SIZE);
 449         vf_min = getpropertyvec(VF_MIN);
 450         vid_width = vf_size_x;
 451         vid_height = vf_size_y;
 452
 453         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 454         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 455
 456         WaypointSprite_Load();
 457
 458         CSQCPlayer_SetCamera();
 459
 460 #ifdef COMPAT_XON050_ENGINE
 461         if(spectatee_status)
 462                 myteam = GetPlayerColor(spectatee_status - 1);
 463         else
 464 #endif
 465                 myteam = GetPlayerColor(player_localentnum - 1);
 466
 467         if(myteam != prev_myteam)
 468         {
 469                 myteamcolors = colormapPaletteColor(myteam, 1);
 470                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 471                         hud_panel[i].update_time = time;
 472                 prev_myteam = myteam;
 473         }
 474
 475         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 476
 477         float is_dead = (getstati(STAT_HEALTH) <= 0);
 478
 479         // FIXME do we need this hack?
 480         if(isdemo())
 481         {
 482                 // in demos, input_buttons do not work
 483                 button_zoom = (autocvar__togglezoom == "-");
 484         }
 485         else if(button_zoom
 486                 && autocvar_cl_unpress_zoom_on_death
 487                 && (spectatee_status >= 0)
 488                 && (is_dead || intermission))
 489         {
 490                 // no zoom while dead or in intermission please
 491                 localcmd("-zoom\n");
 492                 button_zoom = FALSE;
 493         }
 494
 495         // event chase camera
 496         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 497         {
 498                 WepSet weapons_stat = WepSet_GetFromStat();
 499                 if(((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission) && !autocvar_cl_orthoview || (autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(weapons_stat & WepSet_FromWeapon(WEP_PORTO))))
 500                 {
 501                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 502                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 503
 504                         // detect maximum viewoffset and use it
 505                         if(autocvar_cl_eventchase_viewoffset)
 506                         {
 507                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 508                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 509                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 510                         }
 511
 512                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 513                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 514                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 515                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 516
 517                         // make the camera smooth back
 518                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 519                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 520                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 521                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 522
 523                         makevectors(view_angles);
 524
 525                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 526                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 527
 528                         // If the boxtrace fails, revert back to line tracing.
 529                         if(trace_startsolid)
 530                         {
 531                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 532                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 533                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 534                         }
 535                         else { setproperty(VF_ORIGIN, trace_endpos); }
 536
 537                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 538                 }
 539                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 540                 {
 541                         cvar_set("chase_active", "0");
 542                         eventchase_current_distance = 0; // start from 0 next time
 543                 }
 544         }
 545         // workaround for camera stuck between player's legs when using chase_active 1
 546         // because the engine stops updating the chase_active camera when the game ends
 547         else if(intermission)
 548         {
 549                 cvar_settemp("chase_active", "-1");
 550                 eventchase_current_distance = 0;
 551         }
 552
 553         // do lockview after event chase camera so that it still applies whenever necessary.
 554         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 555         {
 556                 setproperty(VF_ORIGIN, freeze_org);
 557                 setproperty(VF_ANGLES, freeze_ang);
 558         }
 559         else
 560         {
 561                 freeze_org = getpropertyvec(VF_ORIGIN);
 562                 freeze_ang = getpropertyvec(VF_ANGLES);
 563         }
 564
 565         WarpZone_FixView();
 566         //WarpZone_FixPMove();
 567
 568         vector ov_org = '0 0 0';
 569         vector ov_mid = '0 0 0';
 570         vector ov_worldmin = '0 0 0';
 571         vector ov_worldmax = '0 0 0';
 572         if(autocvar_cl_orthoview)
 573         {
 574                 ov_worldmin = mi_picmin;
 575                 ov_worldmax = mi_picmax;
 576
 577                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
 578                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
 579                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
 580
 581                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
 582                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
 583
 584                 float ov_nearest = vlen(ov_org - vec3(
 585                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
 586                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
 587                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
 588                 ));
 589
 590                 float ov_furthest = 0;
 591                 float dist = 0;
 592
 593                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 594                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 595                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 596                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 597                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 598                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 599                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 600                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 601
 602                 cvar_settemp("r_nearclip", ftos(ov_nearest));
 603                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
 604                 cvar_settemp("r_farclip_world", "0");
 605                 cvar_settemp("r_novis", "1");
 606                 cvar_settemp("r_useportalculling", "0");
 607                 cvar_settemp("r_useinfinitefarclip", "0");
 608
 609                 setproperty(VF_ORIGIN, ov_org);
 610                 setproperty(VF_ANGLES, '90 0 0');
 611
 612                 #if 0
 613                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
 614                         vtos(ov_org),
 615                         vtos(getpropertyvec(VF_ANGLES)),
 616                         ov_distance,
 617                         ov_nearest,
 618                         ov_furthest);
 619                 #endif
 620         }
 621
 622         // Render the Scene
 623         view_origin = getpropertyvec(VF_ORIGIN);
 624         view_angles = getpropertyvec(VF_ANGLES);
 625         makevectors(view_angles);
 626         view_forward = v_forward;
 627         view_right = v_right;
 628         view_up = v_up;
 629
 630 #ifdef BLURTEST
 631         if(time > blurtest_time0 && time < blurtest_time1)
 632         {
 633                 float r, t;
 634
 635                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 636                 r = t * blurtest_radius;
 637                 f = 1 / pow(t, blurtest_power) - 1;
 638
 639                 cvar_set("r_glsl_postprocess", "1");
 640                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 641         }
 642         else
 643         {
 644                 cvar_set("r_glsl_postprocess", "0");
 645                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 646         }
 647 #endif
 648
 649         TargetMusic_Advance();
 650         Fog_Force();
 651
 652         if(drawtime == 0)
 653                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 654         else
 655                 drawframetime = bound(0.000001, time - drawtime, 1);
 656         drawtime = time;
 657
 658         // watch for gametype changes here...
 659         // in ParseStuffCMD the cmd isn't executed yet :/
 660         // might even be better to add the gametype to TE_CSQC_INIT...?
 661         if(!postinit)
 662                 PostInit();
 663
 664         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 665         {
 666                 if(calledhooks & HOOK_START)
 667                 {
 668                         localcmd("\ncl_hook_gameend\n");
 669                         calledhooks |= HOOK_END;
 670                 }
 671         }
 672
 673         Announcer();
 674
 675         fov = autocvar_fov;
 676         if(fov <= 59.5)
 677         {
 678                 if(!zoomscript_caught)
 679                 {
 680                         localcmd("+button9\n");
 681                         zoomscript_caught = 1;
 682                 }
 683         }
 684         else
 685         {
 686                 if(zoomscript_caught)
 687                 {
 688                         localcmd("-button9\n");
 689                         zoomscript_caught = 0;
 690                 }
 691         }
 692
 693         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 694
 695         // next WANTED weapon (for HUD)
 696         switchweapon = getstati(STAT_SWITCHWEAPON);
 697
 698         // currently switching-to weapon (for crosshair)
 699         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 700
 701         // actually active weapon (for zoom)
 702         activeweapon = getstati(STAT_ACTIVEWEAPON);
 703
 704         f = (serverflags & SERVERFLAG_TEAMPLAY);
 705         if(f != teamplay)
 706         {
 707                 teamplay = f;
 708                 HUD_InitScores();
 709         }
 710
 711         if(last_switchweapon != switchweapon)
 712         {
 713                 weapontime = time;
 714                 last_switchweapon = switchweapon;
 715                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 716                 {
 717                         localcmd("-zoom\n");
 718                         button_zoom = FALSE;
 719                 }
 720                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 721                 {
 722                         localcmd("-fire\n");
 723                         localcmd("-fire2\n");
 724                         button_attack2 = FALSE;
 725                 }
 726         }
 727         if(last_activeweapon != activeweapon)
 728         {
 729                 last_activeweapon = activeweapon;
 730
 731                 e = get_weaponinfo(activeweapon);
 732                 if(e.netname != "")
 733                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 734                 else
 735                         localcmd("\ncl_hook_activeweapon none\n");
 736         }
 737
 738         // ALWAYS Clear Current Scene First
 739         clearscene();
 740 #ifdef WORKAROUND_XON010
 741         if(checkextension("DP_CSQC_ROTATEMOVES"))
 742         {
 743 #endif
 744         setproperty(VF_ORIGIN, view_origin);
 745         setproperty(VF_ANGLES, view_angles);
 746 #ifdef WORKAROUND_XON010
 747         }
 748 #endif
 749
 750         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 751         setproperty(VF_SIZE, vf_size);
 752         setproperty(VF_MIN, vf_min);
 753
 754         // Assign Standard Viewflags
 755         // Draw the World (and sky)
 756         setproperty(VF_DRAWWORLD, 1);
 757
 758         // Set the console size vars
 759         vid_conwidth = autocvar_vid_conwidth;
 760         vid_conheight = autocvar_vid_conheight;
 761         vid_pixelheight = autocvar_vid_pixelheight;
 762
 763         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
 764         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 765
 766         // Camera for demo playback
 767         if(camera_active)
 768         {
 769                 if(autocvar_camera_enable)
 770                         CSQC_Demo_Camera();
 771                 else
 772                 {
 773                         cvar_set("chase_active", ftos(chase_active_backup));
 774                         cvar_set("cl_demo_mousegrab", "0");
 775                         camera_active = FALSE;
 776                 }
 777         }
 778 #ifdef CAMERATEST
 779         else if(autocvar_camera_enable)
 780 #else
 781         else if(autocvar_camera_enable && isdemo())
 782 #endif
 783         {
 784                 // Enable required Darkplaces cvars
 785                 chase_active_backup = autocvar_chase_active;
 786                 cvar_set("chase_active", "2");
 787                 cvar_set("cl_demo_mousegrab", "1");
 788                 camera_active = TRUE;
 789                 camera_mode = FALSE;
 790         }
 791
 792         // Draw the Crosshair
 793         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 794
 795         // Draw the Engine Status Bar (the default Quake HUD)
 796         setproperty(VF_DRAWENGINESBAR, 0);
 797
 798         // Update the mouse position
 799         /*
 800            mousepos_x = vid_conwidth;
 801            mousepos_y = vid_conheight;
 802            mousepos = mousepos*0.5 + getmousepos();
 803          */
 804
 805         e = self;
 806         for(self = world; (self = nextent(self)); )
 807                 if(self.draw)
 808                         self.draw();
 809         self = e;
 810
 811         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 812         renderscene();
 813
 814         // now switch to 2D drawing mode by calling a 2D drawing function
 815         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 816         // next R_RenderScene call
 817         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 818
 819         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 820         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 821         {
 822                 // apply night vision effect
 823                 vector tc_00, tc_01, tc_10, tc_11;
 824                 vector rgb = '0 0 0';
 825
 826                 if(!nightvision_noise)
 827                 {
 828                         nightvision_noise = spawn();
 829                         nightvision_noise.classname = "nightvision_noise";
 830                 }
 831                 if(!nightvision_noise2)
 832                 {
 833                         nightvision_noise2 = spawn();
 834                         nightvision_noise2.classname = "nightvision_noise2";
 835                 }
 836
 837                 // color tint in yellow
 838                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 839
 840                 // draw BG
 841                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 842                 rgb = '1 1 1';
 843                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 844                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 845                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 846                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 847                 tc_11 = tc_01 + tc_10 - tc_00;
 848                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 849                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 850                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 851                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 852                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 853                 R_EndPolygon();
 854
 855                 // draw FG
 856                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 857                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 858                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 859                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 860                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 861                 tc_11 = tc_01 + tc_10 - tc_00;
 862                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 863                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 864                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 865                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 866                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 867                 R_EndPolygon();
 868         }
 869
 870         if(autocvar_cl_reticle)
 871         {
 872                 // Draw the aiming reticle for weapons that use it
 873                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 874                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 875                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
 876                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
 877                 {
 878                         // no zoom reticle while dead
 879                         reticle_type = 0;
 880                 }
 881                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
 882                 {
 883                         if(reticle_image != "") { reticle_type = 2; }
 884                         else { reticle_type = 0; }
 885                 }
 886                 else if(button_zoom || zoomscript_caught)
 887                 {
 888                         // normal zoom
 889                         reticle_type = 1;
 890                 }
 891
 892                 if(reticle_type)
 893                 {
 894                         if(autocvar_cl_reticle_stretch)
 895                         {
 896                                 reticle_size_x = vid_conwidth;
 897                                 reticle_size_y = vid_conheight;
 898                                 reticle_pos_x = 0;
 899                                 reticle_pos_y = 0;
 900                         }
 901                         else
 902                         {
 903                                 reticle_size_x = max(vid_conwidth, vid_conheight);
 904                                 reticle_size_y = max(vid_conwidth, vid_conheight);
 905                                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 906                                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 907                         }
 908
 909                         if(zoomscript_caught)
 910                                 f = 1;
 911                         else
 912                                 f = current_zoomfraction;
 913
 914                         if(f)
 915                         {
 916                                 switch(reticle_type)
 917                                 {
 918                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
 919                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
 920                                 }
 921                         }
 922                 }
 923         }
 924         else
 925         {
 926                 if(reticle_type != 0) { reticle_type = 0; }
 927         }
 928
 929
 930         // improved polyblend
 931         if(autocvar_hud_contents)
 932         {
 933                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 934                 vector liquidcolor;
 935
 936                 switch(pointcontents(view_origin))
 937                 {
 938                         case CONTENT_WATER:
 939                                 liquidalpha = autocvar_hud_contents_water_alpha;
 940                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 941                                 incontent = 1;
 942                                 break;
 943
 944                         case CONTENT_LAVA:
 945                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 946                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 947                                 incontent = 1;
 948                                 break;
 949
 950                         case CONTENT_SLIME:
 951                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 952                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 953                                 incontent = 1;
 954                                 break;
 955
 956                         default:
 957                                 liquidalpha = 0;
 958                                 liquidcolor = '0 0 0';
 959                                 incontent = 0;
 960                                 break;
 961                 }
 962
 963                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 964                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 965                         contentfadetime = autocvar_hud_contents_fadeintime;
 966                         liquidalpha_prev = liquidalpha;
 967                         liquidcolor_prev = liquidcolor;
 968                 }
 969                 else
 970                         contentfadetime = autocvar_hud_contents_fadeouttime;
 971
 972                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 973                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 974
 975                 if(contentavgalpha)
 976                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 977
 978                 if(autocvar_hud_postprocessing)
 979                 {
 980                         if(autocvar_hud_contents_blur && contentavgalpha)
 981                         {
 982                                 content_blurpostprocess_x = 1;
 983                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 984                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 985                         }
 986                         else
 987                         {
 988                                 content_blurpostprocess_x = 0;
 989                                 content_blurpostprocess_y = 0;
 990                                 content_blurpostprocess_z = 0;
 991                         }
 992                 }
 993         }
 994
 995         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 996         {
 997                 splash_size_x = max(vid_conwidth, vid_conheight);
 998                 splash_size_y = max(vid_conwidth, vid_conheight);
 999                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
1000                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
1001
1002                 float myhealth_flash_temp;
1003                 myhealth = getstati(STAT_HEALTH);
1004
1005                 // fade out
1006                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1007                 // add new damage
1008                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1009
1010                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1011                 pain_threshold = autocvar_hud_damage_pain_threshold;
1012                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1013                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1014
1015                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1016                 {
1017                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1018                 }
1019
1020                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1021
1022                 if(myhealth_prev < 1)
1023                 {
1024                         if(myhealth >= 1)
1025                         {
1026                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1027                                 myhealth_flash_temp = 0;
1028                         }
1029                         else
1030                         {
1031                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1032                         }
1033                 }
1034
1035                 if(spectatee_status == -1 || intermission)
1036                 {
1037                         myhealth_flash = 0; // observing, or match ended
1038                         myhealth_flash_temp = 0;
1039                 }
1040
1041                 myhealth_prev = myhealth;
1042
1043                 // IDEA: change damage color/picture based on player model for robot/alien species?
1044                 // pro: matches model better
1045                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1046                 // maybe different reddish pics?
1047                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1048                 {
1049                         if(autocvar_cl_gentle_damage == 2)
1050                         {
1051                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1052                                 {
1053                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1054                                 }
1055                         }
1056                         else
1057                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1058
1059                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1060                 }
1061                 else
1062                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1063
1064                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1065                 {
1066                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1067                         {
1068                                 damage_blurpostprocess_x = 1;
1069                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1070                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1071                         }
1072                         else
1073                         {
1074                                 damage_blurpostprocess_x = 0;
1075                                 damage_blurpostprocess_y = 0;
1076                                 damage_blurpostprocess_z = 0;
1077                         }
1078                 }
1079         }
1080
1081         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1082         float e2 = (autocvar_hud_powerup != 0);
1083         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1084         {
1085                 // enable or disable rendering types if they are used or not
1086                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1087                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1088
1089                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1090                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1091                 {
1092                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1093                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1094                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1095                         {
1096                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1097                                 old_blurradius = blurradius;
1098                                 old_bluralpha = bluralpha;
1099                         }
1100                 }
1101                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1102                 {
1103                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1104                         old_blurradius = 0;
1105                         old_bluralpha = 0;
1106                 }
1107
1108                 // edge detection postprocess handling done second (used by hud_powerup)
1109                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1110                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1111                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1112
1113                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1114
1115                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1116                 {
1117                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1118                         {
1119                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1120                                 old_sharpen_intensity = sharpen_intensity;
1121                         }
1122                 }
1123                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1124                 {
1125                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1126                         old_sharpen_intensity = 0;
1127                 }
1128
1129                 if(cvar("r_glsl_postprocess") == 0)
1130                         cvar_set("r_glsl_postprocess", "2");
1131         }
1132         else if(cvar("r_glsl_postprocess") == 2)
1133                 cvar_set("r_glsl_postprocess", "0");
1134
1135         if(menu_visible)
1136                 menu_show();
1137
1138         /*if(gametype == MAPINFO_TYPE_CTF)
1139           {
1140           ctf_view();
1141           } else */
1142
1143         // draw 2D entities
1144         e = self;
1145         for(self = world; (self = nextent(self)); )
1146                 if(self.draw2d)
1147                         self.draw2d();
1148         self = e;
1149         Draw_ShowNames_All();
1150
1151         scoreboard_active = HUD_WouldDrawScoreboard();
1152
1153         // varying sound pitch
1154         damage_dealt_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
1155
1156         // detect overflow on server side
1157         if (damage_dealt_total < damage_dealt_total_prev)
1158         {
1159                 dprint("resetting dmg total: ", ftos(damage_dealt_total), " prev: ", ftos(damage_dealt_total_prev), "\n");
1160                 damage_dealt_total_prev = 0;
1161         }
1162
1163         // prevent hitsound when switching spectatee
1164         if (spectatee_status != spectatee_status_prev)
1165         {
1166                 damage_dealt_total_prev = damage_dealt_total;
1167         }
1168         spectatee_status_prev = spectatee_status;
1169
1170         // amount of damage since last hit sound
1171         float unaccounted_damage = damage_dealt_total - damage_dealt_total_prev;
1172
1173
1174         if (autocvar_cl_hitsound == 1)
1175         {
1176                 if ( time - hitsound_time_prev > autocvar_cl_hitsound_antispam_time )
1177                 if ( damage_dealt_total > 0 )
1178                 {
1179                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1180                         hitsound_time_prev = time;
1181                 }
1182         }
1183         else if (unaccounted_damage > 0 && autocvar_cl_hitsound > 0 && time - hitsound_time_prev > autocvar_cl_hitsound_antispam_time)
1184         {
1185                 // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
1186                 float a, b, c, x;
1187                 a = autocvar_cl_hitsound_max_pitch;
1188                 b = autocvar_cl_hitsound_min_pitch;
1189                 c = autocvar_cl_hitsound_nom_damage;
1190                 x = unaccounted_damage;
1191                 float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
1192
1193                 // if sound variation is disabled, set pitch_shift to 1
1194                 if (autocvar_cl_hitsound == 1)
1195                 {
1196                         pitch_shift = 1;
1197                 }
1198
1199                 // if pitch shift is reversed, mirror in (max-min)/2 + min
1200                 if (autocvar_cl_hitsound == 3)
1201                 {
1202                         float mirror_value = (a-b)/2 + b;
1203                         pitch_shift = mirror_value + (mirror_value - pitch_shift);
1204                 }
1205
1206                 dprint("dmg total (dmg): ", ftos(damage_dealt_total), " (+", ftos(unaccounted_damage), "), pitch shift: ", ftos(pitch_shift), "\n");
1207
1208                 // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
1209                 // todo: normalize sound pressure levels? seems unnecessary
1210
1211                 // scale to fit function interface
1212                 float param_pitch_shift = pitch_shift * 100;
1213
1214                 // play sound
1215                 sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, param_pitch_shift, 0);
1216
1217                 // track damage accounted for
1218                 damage_dealt_total_prev = damage_dealt_total;
1219
1220                 // remember when this sound was played to prevent sound spam
1221                 hitsound_time_prev = time;
1222         }
1223         else if (autocvar_cl_hitsound == 0)
1224         {
1225                 // forget the damage to prevent hitsound when enabling it
1226                 damage_dealt_total_prev = damage_dealt_total;
1227         }
1228
1229         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1230         if(typehit_time - typehit_time_prev > autocvar_cl_hitsound_antispam_time)
1231         {
1232                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1233                 typehit_time_prev = typehit_time;
1234         }
1235
1236         //else
1237         {
1238                 if(getstati(STAT_FROZEN))
1239                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1240                 else if (getstatf(STAT_HEALING_ORB)>time)
1241                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1242                 if(!intermission)
1243                 if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1244                 {
1245                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1246                         drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1247                 }
1248                 else if(getstatf(STAT_REVIVE_PROGRESS))
1249                 {
1250                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1251                         drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1252                 }
1253
1254                 if(autocvar_r_letterbox == 0)
1255                         if(autocvar_viewsize < 120)
1256                                 CSQC_common_hud();
1257
1258                 // crosshair goes VERY LAST
1259                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1260                 {
1261                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1262                                 return;
1263
1264                         string wcross_style;
1265                         float wcross_alpha, wcross_resolution;
1266                         wcross_style = autocvar_crosshair;
1267                         if (wcross_style == "0")
1268                                 return;
1269                         wcross_resolution = autocvar_crosshair_size;
1270                         if (wcross_resolution == 0)
1271                                 return;
1272                         wcross_alpha = autocvar_crosshair_alpha;
1273                         if (wcross_alpha == 0)
1274                                 return;
1275
1276                         // TrueAim check
1277                         float shottype;
1278
1279                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1280                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1281                         wcross_origin_z = 0;
1282                         if(autocvar_crosshair_hittest)
1283                         {
1284                                 vector wcross_oldorigin;
1285                                 wcross_oldorigin = wcross_origin;
1286                                 shottype = TrueAimCheck();
1287                                 if(shottype == SHOTTYPE_HITWORLD)
1288                                 {
1289                                         v = wcross_origin - wcross_oldorigin;
1290                                         v_x /= vid_conwidth;
1291                                         v_y /= vid_conheight;
1292                                         if(vlen(v) > 0.01)
1293                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1294                                 }
1295                                 if(!autocvar_crosshair_hittest_showimpact)
1296                                         wcross_origin = wcross_oldorigin;
1297                         }
1298                         else
1299                                 shottype = SHOTTYPE_HITWORLD;
1300
1301                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1302                         string wcross_name = "";
1303                         float wcross_scale, wcross_blur;
1304
1305                         if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1306                         {
1307                                 e = get_weaponinfo(switchingweapon);
1308                                 if(e)
1309                                 {
1310                                         if(autocvar_crosshair_per_weapon)
1311                                         {
1312                                                 // WEAPONTODO: access these through some general settings (with non-balance config settings)
1313                                                 //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1314                                                 //if (wcross_resolution == 0)
1315                                                         //return;
1316
1317                                                 //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1318                                                 wcross_resolution *= e.w_crosshair_size;
1319                                                 wcross_name = e.w_crosshair;
1320                                         }
1321                                 }
1322                         }
1323
1324                         if(wcross_name == "")
1325                                 wcross_name = strcat("gfx/crosshair", wcross_style);
1326
1327                         // MAIN CROSSHAIR COLOR DECISION
1328                         switch(autocvar_crosshair_color_special)
1329                         {
1330                                 case 1: // crosshair_color_per_weapon
1331                                 {
1332                                         if(e)
1333                                         {
1334                                                 wcross_color = e.wpcolor;
1335                                                 break;
1336                                         }
1337                                         else { goto normalcolor; }
1338                                 }
1339
1340                                 case 2: // crosshair_color_by_health
1341                                 {
1342                                         float x = getstati(STAT_HEALTH);
1343
1344                                         //x = red
1345                                         //y = green
1346                                         //z = blue
1347
1348                                         wcross_color_z = 0;
1349
1350                                         if(x > 200)
1351                                         {
1352                                                 wcross_color_x = 0;
1353                                                 wcross_color_y = 1;
1354                                         }
1355                                         else if(x > 150)
1356                                         {
1357                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1358                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1359                                         }
1360                                         else if(x > 100)
1361                                         {
1362                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1363                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1364                                                 wcross_color_z = 1 - (x-100)*0.02;
1365                                         }
1366                                         else if(x > 50)
1367                                         {
1368                                                 wcross_color_x = 1;
1369                                                 wcross_color_y = 1;
1370                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1371                                         }
1372                                         else if(x > 20)
1373                                         {
1374                                                 wcross_color_x = 1;
1375                                                 wcross_color_y = (x-20)*90/27/100;
1376                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1377                                         }
1378                                         else
1379                                         {
1380                                                 wcross_color_x = 1;
1381                                                 wcross_color_y = 0;
1382                                         }
1383                                         break;
1384                                 }
1385
1386                                 case 3: // crosshair_color_rainbow
1387                                 {
1388                                         if(time >= rainbow_last_flicker)
1389                                         {
1390                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1391                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1392                                         }
1393                                         wcross_color = rainbow_prev_color;
1394                                         break;
1395                                 }
1396                                 :normalcolor
1397                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1398                         }
1399
1400                         if(autocvar_crosshair_effect_scalefade)
1401                         {
1402                                 wcross_scale = wcross_resolution;
1403                                 wcross_resolution = 1;
1404                         }
1405                         else
1406                         {
1407                                 wcross_scale = 1;
1408                         }
1409
1410                         if(autocvar_crosshair_pickup)
1411                         {
1412                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1413
1414                                 if(pickup_crosshair_time < stat_pickup_time)
1415                                 {
1416                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1417                                                 pickup_crosshair_size = 1;
1418
1419                                         pickup_crosshair_time = stat_pickup_time;
1420                                 }
1421
1422                                 if(pickup_crosshair_size > 0)
1423                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1424                                 else
1425                                         pickup_crosshair_size = 0;
1426
1427                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1428                         }
1429
1430                         // todo: make crosshair hit indication dependent on damage dealt
1431                         if(autocvar_crosshair_hitindication)
1432                         {
1433                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1434
1435                                 if(unaccounted_damage)
1436                                 {
1437                                         hitindication_crosshair_size = 1;
1438                                 }
1439
1440                                 if(hitindication_crosshair_size > 0)
1441                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1442                                 else
1443                                         hitindication_crosshair_size = 0;
1444
1445                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1446                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1447                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1448                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1449                         }
1450
1451                         if(shottype == SHOTTYPE_HITENEMY)
1452                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1453                         if(shottype == SHOTTYPE_HITTEAM)
1454                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1455
1456                         f = fabs(autocvar_crosshair_effect_time);
1457                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1458                         {
1459                                 wcross_changedonetime = time + f;
1460                         }
1461                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1462                         {
1463                                 wcross_name_changestarttime = time;
1464                                 wcross_name_changedonetime = time + f;
1465                                 if(wcross_name_goal_prev_prev)
1466                                         strunzone(wcross_name_goal_prev_prev);
1467                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1468                                 wcross_name_goal_prev = strzone(wcross_name);
1469                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1470                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1471                                 wcross_resolution_goal_prev = wcross_resolution;
1472                         }
1473
1474                         wcross_scale_goal_prev = wcross_scale;
1475                         wcross_alpha_goal_prev = wcross_alpha;
1476                         wcross_color_goal_prev = wcross_color;
1477
1478                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1479                         {
1480                                 wcross_blur = 1;
1481                                 wcross_alpha *= 0.75;
1482                         }
1483                         else
1484                                 wcross_blur = 0;
1485                         // *_prev is at time-frametime
1486                         // * is at wcross_changedonetime+f
1487                         // what do we have at time?
1488                         if(time < wcross_changedonetime)
1489                         {
1490                                 f = frametime / (wcross_changedonetime - time + frametime);
1491                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1492                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1493                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1494                         }
1495
1496                         wcross_scale_prev = wcross_scale;
1497                         wcross_alpha_prev = wcross_alpha;
1498                         wcross_color_prev = wcross_color;
1499
1500                         wcross_scale *= 1 - autocvar__menu_alpha;
1501                         wcross_alpha *= 1 - autocvar__menu_alpha;
1502                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1503
1504                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1505                         {
1506                                 // crosshair rings for weapon stats
1507                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1508                                 {
1509                                         // declarations and stats
1510                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1511                                         string ring_image = string_null, ring_inner_image = string_null;
1512                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1513
1514                                         ring_scale = autocvar_crosshair_ring_size;
1515
1516                                         float weapon_clipload, weapon_clipsize;
1517                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1518                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1519
1520                                         float vortex_charge, vortex_chargepool;
1521                                         vortex_charge = getstatf(STAT_VORTEX_CHARGE);
1522                                         vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
1523
1524                                         float arc_heat = getstatf(STAT_ARC_HEAT);
1525
1526                                         if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1527                                                 vortex_charge_movingavg = vortex_charge;
1528
1529
1530                                         // handle the values
1531                                         if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1532                                         {
1533                                                 if (vortex_chargepool || use_vortex_chargepool) {
1534                                                         use_vortex_chargepool = 1;
1535                                                         ring_inner_value = vortex_chargepool;
1536                                                 } else {
1537                                                         vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1538                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1539                                                 }
1540
1541                                                 ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1542                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1543                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1544
1545                                                 // draw the outer ring to show the current charge of the weapon
1546                                                 ring_value = vortex_charge;
1547                                                 ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1548                                                 ring_rgb = wcross_color;
1549                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1550                                         }
1551                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1552                                         {
1553                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1554                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1555                                                 ring_rgb = wcross_color;
1556                                                 ring_image = "gfx/crosshair_ring.tga";
1557                                         }
1558                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1559                                         {
1560                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1561                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1562                                                 ring_rgb = wcross_color;
1563                                                 ring_image = "gfx/crosshair_ring.tga";
1564                                         }
1565
1566                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1567                                         {
1568                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1569                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1570                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1571                                                 ring_rgb = wcross_color;
1572
1573                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1574                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1575                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1576                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1577                                                 else
1578                                                         ring_image = "gfx/crosshair_ring.tga";
1579                                         }
1580                                         else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1581                                         {
1582                                                 ring_value = arc_heat;
1583                                                 ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1584                                                         arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1585                                                 ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1586                                                 ring_image = "gfx/crosshair_ring.tga";
1587                                         }
1588
1589                                         // if in weapon switch animation, fade ring out/in
1590                                         if(autocvar_crosshair_effect_time > 0)
1591                                         {
1592                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1593                                                 if (!(f < 1))
1594                                                 {
1595                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1596                                                 }
1597
1598                                                 if(wcross_ring_prev)
1599                                                 {
1600                                                         if(f < 1)
1601                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1602                                                 }
1603                                                 else
1604                                                 {
1605                                                         if(f < 1)
1606                                                                 ring_alpha *= bound(0, f, 1);
1607                                                 }
1608                                         }
1609
1610                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1611                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1612
1613                                         if (ring_value)
1614                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1615                                 }
1616
1617 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1618                                 do \
1619                                 { \
1620                                         if(wcross_blur > 0) \
1621                                         { \
1622                                                 for(i = -2; i <= 2; ++i) \
1623                                                 for(j = -2; j <= 2; ++j) \
1624                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1625                                         } \
1626                                         else \
1627                                         { \
1628                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1629                                         } \
1630                                 } \
1631                                 while(0)
1632
1633 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1634                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1635
1636 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1637                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1638
1639                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1640                                 {
1641                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1642                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1643                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1644                                         f = 1 - f;
1645                                 }
1646                                 else
1647                                 {
1648                                         f = 1;
1649                                 }
1650                                 wcross_name_alpha_goal_prev = f;
1651
1652                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1653                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1654
1655                                 if(autocvar_crosshair_dot)
1656                                 {
1657                                         vector wcross_color_old;
1658                                         wcross_color_old = wcross_color;
1659
1660                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1661                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1662
1663                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1664                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1665                                         wcross_color = wcross_color_old;
1666                                 }
1667                         }
1668                 }
1669                 else
1670                 {
1671                         wcross_scale_prev = 0;
1672                         wcross_alpha_prev = 0;
1673                         wcross_scale_goal_prev = 0;
1674                         wcross_alpha_goal_prev = 0;
1675                         wcross_changedonetime = 0;
1676                         if(wcross_name_goal_prev)
1677                                 strunzone(wcross_name_goal_prev);
1678                         wcross_name_goal_prev = string_null;
1679                         if(wcross_name_goal_prev_prev)
1680                                 strunzone(wcross_name_goal_prev_prev);
1681                         wcross_name_goal_prev_prev = string_null;
1682                         wcross_name_changestarttime = 0;
1683                         wcross_name_changedonetime = 0;
1684                         wcross_name_alpha_goal_prev = 0;
1685                         wcross_name_alpha_goal_prev_prev = 0;
1686                         wcross_resolution_goal_prev = 0;
1687                         wcross_resolution_goal_prev_prev = 0;
1688                 }
1689         }
1690
1691         if(NextFrameCommand)
1692         {
1693                 localcmd("\n", NextFrameCommand, "\n");
1694                 NextFrameCommand = string_null;
1695         }
1696
1697         // we must do this check AFTER a frame was rendered, or it won't work
1698         if(cs_project_is_b0rked == 0)
1699         {
1700                 string w0, h0;
1701                 w0 = ftos(autocvar_vid_conwidth);
1702                 h0 = ftos(autocvar_vid_conheight);
1703                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1704                 //setproperty(VF_FOV, '90 90 0');
1705                 setproperty(VF_ORIGIN, '0 0 0');
1706                 setproperty(VF_ANGLES, '0 0 0');
1707                 setproperty(VF_PERSPECTIVE, 1);
1708                 makevectors('0 0 0');
1709                 vector v1, v2;
1710                 cvar_set("vid_conwidth", "800");
1711                 cvar_set("vid_conheight", "600");
1712                 v1 = cs_project(v_forward);
1713                 cvar_set("vid_conwidth", "640");
1714                 cvar_set("vid_conheight", "480");
1715                 v2 = cs_project(v_forward);
1716                 if(v1 == v2)
1717                         cs_project_is_b0rked = 1;
1718                 else
1719                         cs_project_is_b0rked = -1;
1720                 cvar_set("vid_conwidth", w0);
1721                 cvar_set("vid_conheight", h0);
1722         }
1723
1724         if(autocvar__hud_configure)
1725                 HUD_Panel_Mouse();
1726
1727     if(hud && !intermission)
1728     {
1729         if(hud == HUD_SPIDERBOT)
1730             CSQC_SPIDER_HUD();
1731         else if(hud == HUD_WAKIZASHI)
1732             CSQC_WAKIZASHI_HUD();
1733         else if(hud == HUD_RAPTOR)
1734             CSQC_RAPTOR_HUD();
1735         else if(hud == HUD_BUMBLEBEE)
1736             CSQC_BUMBLE_HUD();
1737         else if(hud == HUD_BUMBLEBEE_GUN)
1738             CSQC_BUMBLE_GUN_HUD();
1739     }
1740
1741         cl_notice_run();
1742
1743         // let's reset the view back to normal for the end
1744         setproperty(VF_MIN, '0 0 0');
1745         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1746 }
1747
1748
1749 void CSQC_common_hud(void)
1750 {
1751         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1752                 Accuracy_LoadLevels();
1753
1754         HUD_Main(); // always run these functions for alpha checks
1755         HUD_DrawScoreboard();
1756
1757         if (scoreboard_active) // scoreboard/accuracy
1758                 HUD_Reset();
1759         else if (intermission == 2) // map voting screen
1760         {
1761                 MapVote_Draw();
1762                 HUD_Reset();
1763         }
1764 }
1765
1766
1767 // following vectors must be global to allow seamless switching between camera modes
1768 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1769 void CSQC_Demo_Camera()
1770 {
1771         float speed, attenuation, dimensions;
1772         vector tmp, delta;
1773
1774         if( autocvar_camera_reset || !camera_mode )
1775         {
1776                 camera_offset = '0 0 0';
1777                 current_angles = '0 0 0';
1778                 camera_direction = '0 0 0';
1779                 camera_offset_z += 30;
1780                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1781                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1782                 current_origin = view_origin;
1783                 current_camera_offset  = camera_offset;
1784                 cvar_set("camera_reset", "0");
1785                 camera_mode = CAMERA_CHASE;
1786         }
1787
1788         // Camera angles
1789         if( camera_roll )
1790                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1791
1792         if(autocvar_camera_look_player)
1793         {
1794                 vector dir;
1795                 float n;
1796
1797                 dir = normalize(view_origin - current_position);
1798                 n = mouse_angles_z;
1799                 mouse_angles = vectoangles(dir);
1800                 mouse_angles_x = mouse_angles_x * -1;
1801                 mouse_angles_z = n;
1802         }
1803         else
1804         {
1805                 tmp = getmousepos() * 0.1;
1806                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1807                 {
1808                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1809                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1810                 }
1811         }
1812
1813         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1814         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1815         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1816         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1817
1818         // Fix difference when angles don't have the same sign
1819         delta = '0 0 0';
1820         if(mouse_angles_y < -60 && current_angles_y > 60)
1821                 delta = '0 360 0';
1822         if(mouse_angles_y > 60 && current_angles_y < -60)
1823                 delta = '0 -360 0';
1824
1825         if(autocvar_camera_look_player)
1826                 attenuation = autocvar_camera_look_attenuation;
1827         else
1828                 attenuation = autocvar_camera_speed_attenuation;
1829
1830         attenuation = 1 / max(1, attenuation);
1831         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1832
1833         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1834         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1835         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1836         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1837
1838         // Camera position
1839         tmp = '0 0 0';
1840         dimensions = 0;
1841
1842         if( camera_direction_x )
1843         {
1844                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1845                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1846                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1847                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1848                 ++dimensions;
1849         }
1850
1851         if( camera_direction_y )
1852         {
1853                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1854                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1855                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1856                 ++dimensions;
1857         }
1858
1859         if( camera_direction_z )
1860         {
1861                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1862                 ++dimensions;
1863         }
1864
1865         if(autocvar_camera_free)
1866                 speed = autocvar_camera_speed_free;
1867         else
1868                 speed = autocvar_camera_speed_chase;
1869
1870         if(dimensions)
1871         {
1872                 speed = speed * sqrt(1 / dimensions);
1873                 camera_offset += tmp * speed;
1874         }
1875
1876         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1877
1878         // Camera modes
1879         if( autocvar_camera_free )
1880         {
1881                 if ( camera_mode == CAMERA_CHASE )
1882                 {
1883                         current_camera_offset = current_origin + current_camera_offset;
1884                         camera_offset = current_origin + camera_offset;
1885                 }
1886
1887                 camera_mode = CAMERA_FREE;
1888                 current_position = current_camera_offset;
1889         }
1890         else
1891         {
1892                 if ( camera_mode == CAMERA_FREE )
1893                 {
1894                         current_origin = view_origin;
1895                         camera_offset = camera_offset - current_origin;
1896                         current_camera_offset = current_camera_offset - current_origin;
1897                 }
1898
1899                 camera_mode = CAMERA_CHASE;
1900
1901                 if(autocvar_camera_chase_smoothly)
1902                         current_origin += (view_origin - current_origin) * attenuation;
1903                 else
1904                         current_origin = view_origin;
1905
1906                 current_position = current_origin + current_camera_offset;
1907         }
1908
1909         setproperty(VF_ANGLES, current_angles);
1910         setproperty(VF_ORIGIN, current_position);
1911 }