qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float use_nex_chargepool;
 357
 358 float myhealth, myhealth_prev;
 359 float myhealth_flash;
 360
 361 vector myhealth_gentlergb;
 362
 363 float contentavgalpha, liquidalpha_prev;
 364 vector liquidcolor_prev;
 365
 366 void CSQC_UpdateView(float w, float h)
 367 {
 368         entity e;
 369         float fov;
 370         float f, i, j;
 371         vector v, vo;
 372         vector vf_size, vf_min;
 373         float a;
 374
 375         vf_size = R_SetView3fv(VF_SIZE);
 376         vf_min = R_SetView3fv(VF_MIN);
 377         vid_width = vf_size_x;
 378         vid_height = vf_size_y;
 379
 380         vector reticle_pos, reticle_size;
 381
 382         WaypointSprite_Load();
 383
 384         if(spectatee_status)
 385                 myteam = GetPlayerColor(spectatee_status - 1);
 386         else
 387                 myteam = GetPlayerColor(player_localentnum - 1);
 388
 389         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 390         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 391
 392         warpzone_fixview_origin = pmove_org + vo;
 393         warpzone_fixview_cl_viewangles = input_angles;
 394         warpzone_fixview_angles = view_angles;
 395         WarpZone_FixView();
 396         pmove_org = warpzone_fixview_origin - vo;
 397         input_angles = warpzone_fixview_cl_viewangles;
 398         view_angles = warpzone_fixview_angles;
 399
 400         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 401         {
 402                 pmove_org = freeze_pmove_org;
 403                 input_angles = view_angles = freeze_input_angles;
 404                 R_SetView(VF_ORIGIN, pmove_org + vo);
 405                 R_SetView(VF_ANGLES, view_angles);
 406                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 407         }
 408         freeze_pmove_org = pmove_org;
 409         freeze_input_angles = input_angles;
 410
 411         // Render the Scene
 412         if(!intermission || !view_set)
 413         {
 414                 view_origin = pmove_org + vo;
 415                 view_angles = input_angles;
 416                 makevectors(view_angles);
 417                 view_forward = v_forward;
 418                 view_right = v_right;
 419                 view_up = v_up;
 420                 view_set = 1;
 421         }
 422
 423 #ifdef BLURTEST
 424         if(time > blurtest_time0 && time < blurtest_time1)
 425         {
 426                 float r, t;
 427
 428                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 429                 r = t * blurtest_radius;
 430                 f = 1 / pow(t, blurtest_power) - 1;
 431
 432                 cvar_set("r_glsl_postprocess", "1");
 433                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 434         }
 435         else
 436         {
 437                 cvar_set("r_glsl_postprocess", "0");
 438                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 439         }
 440 #endif
 441
 442         TargetMusic_Advance();
 443         Fog_Force();
 444
 445         drawframetime = max(0.000001, time - drawtime);
 446         drawtime = time;
 447
 448         // watch for gametype changes here...
 449         // in ParseStuffCMD the cmd isn't executed yet :/
 450         // might even be better to add the gametype to TE_CSQC_INIT...?
 451         if(!postinit)
 452                 PostInit();
 453
 454         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 455                 if(calledhooks & HOOK_START)
 456                 {
 457                         localcmd("\ncl_hook_gameend\n");
 458                         calledhooks |= HOOK_END;
 459                 }
 460
 461         CheckForGamestartChange();
 462         serverAnnouncer();
 463         maptimeAnnouncer();
 464         carrierAnnouncer();
 465
 466         fov = autocvar_fov;
 467         if(button_zoom || fov <= 59.5)
 468         {
 469                 if(!zoomscript_caught)
 470                 {
 471                         localcmd("+button4\n");
 472                         zoomscript_caught = 1;
 473                         ignore_plus_zoom += 1;
 474                 }
 475         }
 476         else
 477         {
 478                 if(zoomscript_caught)
 479                 {
 480                         localcmd("-button4\n");
 481                         zoomscript_caught = 0;
 482                         ignore_minus_zoom += 1;
 483                 }
 484         }
 485
 486         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 487         activeweapon = getstati(STAT_SWITCHWEAPON);
 488         f = (serverflags & SERVERFLAG_TEAMPLAY);
 489         if(f != teamplay)
 490         {
 491                 teamplay = f;
 492                 HUD_InitScores();
 493         }
 494
 495         if(last_weapon != activeweapon) {
 496                 weapontime = time;
 497                 last_weapon = activeweapon;
 498
 499                 e = get_weaponinfo(activeweapon);
 500                 if(e.netname != "")
 501                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 502                 else
 503                         localcmd("\ncl_hook_activeweapon none\n");
 504         }
 505
 506         // ALWAYS Clear Current Scene First
 507         R_ClearScene();
 508
 509         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 510         R_SetView(VF_SIZE, vf_size);
 511         R_SetView(VF_MIN, vf_min);
 512
 513         // Assign Standard Viewflags
 514         // Draw the World (and sky)
 515         R_SetView(VF_DRAWWORLD, 1);
 516
 517         // Set the console size vars
 518         vid_conwidth = autocvar_vid_conwidth;
 519         vid_conheight = autocvar_vid_conheight;
 520         vid_pixelheight = autocvar_vid_pixelheight;
 521
 522         R_SetView(VF_FOV, GetCurrentFov(fov));
 523
 524         // Camera for demo playback
 525         if(camera_active)
 526         {
 527                 if(autocvar_camera_enable)
 528                         CSQC_Demo_Camera();
 529                 else
 530                 {
 531                         cvar_set("chase_active", ftos(chase_active_backup));
 532                         cvar_set("cl_demo_mousegrab", "0");
 533                         camera_active = FALSE;
 534                 }
 535         }
 536 #ifdef CAMERATEST
 537         else if(autocvar_camera_enable)
 538 #else
 539         else if(autocvar_camera_enable && isdemo())
 540 #endif
 541         {
 542                 // Enable required Darkplaces cvars
 543                 chase_active_backup = autocvar_chase_active;
 544                 cvar_set("chase_active", "2");
 545                 cvar_set("cl_demo_mousegrab", "1");
 546                 camera_active = TRUE;
 547                 camera_mode = FALSE;
 548         }
 549
 550         // Draw the Crosshair
 551         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 552
 553         // Draw the Engine Status Bar (the default Quake HUD)
 554         R_SetView(VF_DRAWENGINEHUD, 0);
 555
 556         // fetch this one only once per frame
 557         hud_showbinds = autocvar_hud_showbinds;
 558         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 559
 560         // Update the mouse position
 561         /*
 562            mousepos_x = vid_conwidth;
 563            mousepos_y = vid_conheight;
 564            mousepos = mousepos*0.5 + getmousepos();
 565          */
 566
 567         e = self;
 568         for(self = world; (self = nextent(self)); )
 569                 if(self.draw)
 570                         self.draw();
 571         self = e;
 572
 573         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 574         R_RenderScene();
 575
 576         // now switch to 2D drawing mode by calling a 2D drawing function
 577         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 578         // next R_RenderScene call
 579         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 580
 581         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 582         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 583         {
 584                 // apply night vision effect
 585                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 586
 587                 if(!nightvision_noise)
 588                 {
 589                         nightvision_noise = spawn();
 590                         nightvision_noise.classname = "nightvision_noise";
 591                 }
 592                 if(!nightvision_noise2)
 593                 {
 594                         nightvision_noise2 = spawn();
 595                         nightvision_noise2.classname = "nightvision_noise2";
 596                 }
 597
 598                 // color tint in yellow
 599                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 600
 601                 // draw BG
 602                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 603                 rgb = '1 1 1';
 604                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 605                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 606                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 607                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 608                 tc_11 = tc_01 + tc_10 - tc_00;
 609                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 610                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 611                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 612                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 613                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 614                 R_EndPolygon();
 615
 616                 // draw FG
 617                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 618                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 619                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 620                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 621                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 622                 tc_11 = tc_01 + tc_10 - tc_00;
 623                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 624                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 625                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 626                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 627                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 628                 R_EndPolygon();
 629         }
 630
 631         // Draw the aiming reticle for weapons that use it
 632         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 633         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 634         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 635         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 636                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 637         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 638                 reticle_type = 2; // nex zoom
 639         else if(button_zoom || zoomscript_caught)
 640                 reticle_type = 1; // normal zoom
 641         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 642                 reticle_type = 2; // nex zoom
 643
 644         if(autocvar_cl_reticle_stretch)
 645         {
 646                 reticle_size_x = vid_conwidth;
 647                 reticle_size_y = vid_conheight;
 648                 reticle_pos_x = 0;
 649                 reticle_pos_y = 0;
 650         }
 651         else
 652         {
 653                 reticle_size_x = max(vid_conwidth, vid_conheight);
 654                 reticle_size_y = max(vid_conwidth, vid_conheight);
 655                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 656                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 657         }
 658
 659         f = current_zoomfraction;
 660         if(zoomscript_caught)
 661                 f = 1;
 662         if(autocvar_cl_reticle_item_normal)
 663         {
 664                 precache_pic("gfx/reticle_normal");
 665                 if(reticle_type == 1 && f)
 666                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 667         }
 668         if(autocvar_cl_reticle_item_nex)
 669         {
 670                 precache_pic("gfx/reticle_nex");
 671                 if(reticle_type == 2 && f)
 672                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 673         }
 674
 675
 676         // improved polyblend
 677         vector rgb;
 678         if(autocvar_hud_contents)
 679         {
 680                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 681                 vector liquidcolor;
 682
 683                 switch(pointcontents(view_origin))
 684                 {
 685                         case CONTENT_WATER:
 686                                 liquidalpha = autocvar_hud_contents_water_alpha;
 687                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 688                                 incontent = 1;
 689                                 break;
 690
 691                         case CONTENT_LAVA:
 692                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 693                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 694                                 incontent = 1;
 695                                 break;
 696
 697                         case CONTENT_SLIME:
 698                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 699                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 700                                 incontent = 1;
 701                                 break;
 702
 703                         default:
 704                                 liquidalpha = 0;
 705                                 liquidcolor = '0 0 0';
 706                                 incontent = 0;
 707                                 break;
 708                 }
 709
 710                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 711                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 712                         contentfadetime = autocvar_hud_contents_fadeintime;
 713                         liquidalpha_prev = liquidalpha;
 714                         liquidcolor_prev = liquidcolor;
 715                 }
 716                 else
 717                         contentfadetime = autocvar_hud_contents_fadeouttime;
 718
 719                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 720                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 721
 722                 if(contentavgalpha)
 723                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 724         }
 725
 726         if(autocvar_hud_damage)
 727         {
 728                 float myhealth_flash_temp;
 729                 myhealth = getstati(STAT_HEALTH);
 730
 731                 // fade out
 732                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 733                 // add new damage
 734                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 735
 736                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 737                 pain_threshold = autocvar_hud_damage_pain_threshold;
 738                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 739                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 740
 741                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 742                 {
 743                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 744                 }
 745
 746                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 747
 748                 if(myhealth_prev < 1)
 749                 {
 750                         if(myhealth >= 1)
 751                         {
 752                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 753                                 myhealth_flash_temp = 0;
 754                         }
 755                         else
 756                         {
 757                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 758                         }
 759                 }
 760
 761                 if(spectatee_status == -1 || intermission)
 762                 {
 763                         myhealth_flash = 0; // observing, or match ended
 764                         myhealth_flash_temp = 0;
 765                 }
 766
 767                 myhealth_prev = myhealth;
 768
 769                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 770                 {
 771                         if(autocvar_cl_gentle_damage == 2)
 772                         {
 773                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 774                                 {
 775                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 776                                 }
 777                         }
 778                         else
 779                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 780
 781                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 782                 }
 783                 else
 784                         drawpic(reticle_pos, "gfx/blood", reticle_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 785         }
 786
 787         // Draw the mouse cursor
 788         // NOTE: drawpic must happen after R_RenderScene for some reason
 789         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 790         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 791         //self = edict_num(player_localnum);
 792         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 793         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 794         // as long as the ctf part isn't in, this is useless
 795         if(menu_visible)
 796                 menu_show();
 797
 798         /*if(gametype == GAME_CTF)
 799           {
 800           ctf_view();
 801           } else */
 802
 803         // draw 2D entities
 804         e = self;
 805         for(self = world; (self = nextent(self)); )
 806                 if(self.draw2d)
 807                         self.draw2d();
 808         self = e;
 809
 810         scoreboard_active = HUD_WouldDrawScoreboard();
 811
 812         float hud;
 813         hud = getstati(STAT_HUD);
 814         if(hud == HUD_SPIDERBOT)
 815                 CSQC_SPIDER_HUD();
 816         else if(hud == HUD_WAKIZASHI)
 817         CSQC_WAKIZASHI_HUD();
 818     else if(hud == HUD_RAPTOR)
 819         CSQC_RAPTOR_HUD();
 820         else
 821         {
 822                 if(gametype == GAME_FREEZETAG)
 823                 {
 824                         if(getstati(STAT_FROZEN))
 825                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 826                         if(getstatf(STAT_REVIVE_PROGRESS))
 827                         {
 828                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 829                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 830                         }
 831                 }
 832
 833                 if(autocvar_r_letterbox == 0)
 834                         if(autocvar_viewsize < 120)
 835                                 CSQC_common_hud();
 836
 837                 // crosshair goes VERY LAST
 838                 if(!scoreboard_active && !camera_active && intermission != 2) {
 839                         string wcross_style;
 840                         float wcross_alpha, wcross_resolution;
 841                         wcross_style = autocvar_crosshair;
 842                         if (wcross_style == "0")
 843                                 return;
 844                         wcross_resolution = autocvar_crosshair_size;
 845                         if (wcross_resolution == 0)
 846                                 return;
 847                         wcross_alpha = autocvar_crosshair_alpha;
 848                         if (wcross_alpha == 0)
 849                                 return;
 850
 851                         // TrueAim check
 852                         float shottype;
 853                         float bullets, ring_scale;
 854                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 855                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 856                         wcross_origin_z = 0;
 857                         if(autocvar_crosshair_hittest)
 858                         {
 859                                 vector wcross_oldorigin;
 860                                 wcross_oldorigin = wcross_origin;
 861                                 shottype = TrueAimCheck();
 862                                 if(shottype == SHOTTYPE_HITWORLD)
 863                                 {
 864                                         v = wcross_origin - wcross_oldorigin;
 865                                         v_x /= vid_conwidth;
 866                                         v_y /= vid_conheight;
 867                                         if(vlen(v) > 0.01)
 868                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 869                                 }
 870                                 if(!autocvar_crosshair_hittest_showimpact)
 871                                         wcross_origin = wcross_oldorigin;
 872                         }
 873                         else
 874                                 shottype = SHOTTYPE_HITWORLD;
 875
 876                         vector wcross_color, wcross_size;
 877                         string wcross_wep, wcross_name;
 878                         float wcross_scale, wcross_blur;
 879
 880                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 881                                 e = get_weaponinfo(activeweapon);
 882                                 if (e && e.netname != "")
 883                                 {
 884                                         wcross_wep = e.netname;
 885                                         if(autocvar_crosshair_per_weapon)
 886                                         {
 887                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 888                                                 if (wcross_resolution == 0)
 889                                                         return;
 890                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 891                                                 if (wcross_alpha == 0)
 892                                                         return;
 893
 894                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 895                                                 if(wcross_style == "" || wcross_style == "0")
 896                                                         wcross_style = wcross_wep;
 897                                         }
 898                                 }
 899                         }
 900                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 901                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 902                         else
 903                                 wcross_color = stov(autocvar_crosshair_color);
 904
 905                         wcross_name = strcat("gfx/crosshair", wcross_style);
 906
 907                         if(autocvar_crosshair_effect_scalefade)
 908                         {
 909                                 wcross_scale = wcross_resolution;
 910                                 wcross_resolution = 1;
 911                         }
 912                         else
 913                         {
 914                                 wcross_scale = 1;
 915                         }
 916
 917                         if(autocvar_crosshair_pickup)
 918                         {
 919                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
 920                                 {
 921                                         pickup_crosshair_size = 1;
 922                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
 923                                 }
 924
 925                                 if(pickup_crosshair_size > 0)
 926                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 927                                 else
 928                                         pickup_crosshair_size = 0;
 929
 930                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 931                         }
 932
 933                         if(shottype == SHOTTYPE_HITENEMY)
 934                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 935                         if(shottype == SHOTTYPE_HITTEAM)
 936                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 937
 938                         f = autocvar_crosshair_effect_speed;
 939                         if(f < 0)
 940                                 f *= -2 * g_weaponswitchdelay;
 941                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 942                         {
 943                                 wcross_changedonetime = time + f;
 944                         }
 945                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 946                         {
 947                                 wcross_name_changestarttime = time;
 948                                 wcross_name_changedonetime = time + f;
 949                                 if(wcross_name_goal_prev_prev)
 950                                         strunzone(wcross_name_goal_prev_prev);
 951                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
 952                                 wcross_name_goal_prev = strzone(wcross_name);
 953                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 954                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 955                                 wcross_resolution_goal_prev = wcross_resolution;
 956                         }
 957
 958                         wcross_scale_goal_prev = wcross_scale;
 959                         wcross_alpha_goal_prev = wcross_alpha;
 960                         wcross_color_goal_prev = wcross_color;
 961
 962                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 963                         {
 964                                 wcross_blur = 1;
 965                                 wcross_alpha *= 0.75;
 966                         }
 967                         else
 968                                 wcross_blur = 0;
 969                         // *_prev is at time-frametime
 970                         // * is at wcross_changedonetime+f
 971                         // what do we have at time?
 972                         if(time < wcross_changedonetime)
 973                         {
 974                                 f = frametime / (wcross_changedonetime - time + frametime);
 975                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 976                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 977                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 978                         }
 979
 980                         wcross_scale_prev = wcross_scale;
 981                         wcross_alpha_prev = wcross_alpha;
 982                         wcross_color_prev = wcross_color;
 983
 984                         wcross_scale *= 1 - autocvar__menu_alpha;
 985                         wcross_alpha *= 1 - autocvar__menu_alpha;
 986
 987                         ring_scale = autocvar_crosshair_ring_size;
 988
 989                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 990
 991                         float nex_charge, nex_chargepool;
 992                         nex_charge = getstatf(STAT_NEX_CHARGE);
 993                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
 994
 995                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 996                                 nex_charge_movingavg = nex_charge;
 997
 998                         // ring around crosshair representing bullets left in camping rifle clip
 999                         if (activeweapon == WEP_SNIPERRIFLE && cr_maxbullets)
1000                         {
1001                                 bullets = getstati(STAT_BULLETS_LOADED);
1002                                 f = bound(0, bullets / cr_maxbullets, 1);
1003
1004                                 a = autocvar_crosshair_ring_sniperrifle_alpha;
1005                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1006                         }
1007                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
1008                         {
1009                                 if(nex_chargepool || use_nex_chargepool)
1010                                 {
1011                                         use_nex_chargepool = 1;
1012
1013                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1014                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1015                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", nex_chargepool, rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1016                                 }
1017                                 else
1018                                 {
1019                                         // indicate how much we're charging right now with an inner circle
1020                                         a = autocvar_crosshair_ring_nex_inner_alpha;
1021                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1022
1023                                         rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1024                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1025                                 }
1026
1027                                 // draw the charge
1028                                 a = autocvar_crosshair_ring_nex_outer_alpha;
1029                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
1030                         }
1031
1032 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1033                         do \
1034                         { \
1035                                 if(wcross_blur > 0) \
1036                                 { \
1037                                         for(i = -2; i <= 2; ++i) \
1038                                                 for(j = -2; j <= 2; ++j) \
1039                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1040                                 } \
1041                                 else \
1042                                 { \
1043                                         M(0,0,sz,wcross_name,wcross_alpha); \
1044                                 } \
1045                         } \
1046                         while(0)
1047
1048 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1049                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1050
1051 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1052                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1053
1054                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1055                         {
1056                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1057                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1058                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1059                                 f = 1 - f;
1060                         }
1061                         else
1062                         {
1063                                 f = 1;
1064                         }
1065
1066                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1067                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1068
1069                         if(autocvar_crosshair_dot)
1070             {
1071                 vector wcross_color_old;
1072                 wcross_color_old = wcross_color;
1073                 if(autocvar_crosshair_dot_color != "0")
1074                     wcross_color = stov(autocvar_crosshair_dot_color);
1075                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1076                 wcross_color = wcross_color_old;
1077             }
1078
1079                         wcross_name_alpha_goal_prev = f;
1080                 }
1081                 else
1082                 {
1083                         wcross_scale_prev = 0;
1084                         wcross_alpha_prev = 0;
1085                         wcross_scale_goal_prev = 0;
1086                         wcross_alpha_goal_prev = 0;
1087                         wcross_changedonetime = 0;
1088                         if(wcross_name_goal_prev)
1089                                 strunzone(wcross_name_goal_prev);
1090                         wcross_name_goal_prev = string_null;
1091                         if(wcross_name_goal_prev_prev)
1092                                 strunzone(wcross_name_goal_prev_prev);
1093                         wcross_name_goal_prev_prev = string_null;
1094                         wcross_name_changestarttime = 0;
1095                         wcross_name_changedonetime = 0;
1096                         wcross_name_alpha_goal_prev = 0;
1097                         wcross_name_alpha_goal_prev_prev = 0;
1098                         wcross_resolution_goal_prev = 0;
1099                         wcross_resolution_goal_prev_prev = 0;
1100                 }
1101         }
1102
1103         if(NextFrameCommand)
1104         {
1105                 localcmd("\n", NextFrameCommand, "\n");
1106                 NextFrameCommand = string_null;
1107         }
1108
1109         // we must do this check AFTER a frame was rendered, or it won't work
1110         if(cs_project_is_b0rked == 0)
1111         {
1112                 string w0, h0;
1113                 w0 = ftos(autocvar_vid_conwidth);
1114                 h0 = ftos(autocvar_vid_conheight);
1115                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1116                 //R_SetView(VF_FOV, '90 90 0');
1117                 R_SetView(VF_ORIGIN, '0 0 0');
1118                 R_SetView(VF_ANGLES, '0 0 0');
1119                 R_SetView(VF_PERSPECTIVE, 1);
1120                 makevectors('0 0 0');
1121                 vector v1, v2;
1122                 cvar_set("vid_conwidth", "800");
1123                 cvar_set("vid_conheight", "600");
1124                 v1 = cs_project(v_forward);
1125                 cvar_set("vid_conwidth", "640");
1126                 cvar_set("vid_conheight", "480");
1127                 v2 = cs_project(v_forward);
1128                 if(v1 == v2)
1129                         cs_project_is_b0rked = 1;
1130                 else
1131                         cs_project_is_b0rked = -1;
1132                 cvar_set("vid_conwidth", w0);
1133                 cvar_set("vid_conheight", h0);
1134         }
1135
1136         if(autocvar__hud_configure)
1137                 HUD_Panel_Mouse();
1138
1139         // let's reset the view back to normal for the end
1140         R_SetView(VF_MIN, '0 0 0');
1141         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1142 }
1143
1144 #define spider_h "gfx/vehicles/hud_bg.tga"
1145 #define spider_b "gfx/vehicles/sbot.tga"
1146 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1147 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1148 #define spider_s "gfx/vehicles/shiled.tga"
1149 #define spider_a1 "gfx/hud/sb_rocket.tga"
1150 #define spider_a2 "gfx/sb_bullets.tga"
1151
1152 void CSQC_SPIDER_HUD()
1153 {
1154         float rockets, reload, heat, hp, shield;
1155         vector picsize, hudloc;
1156
1157     // Fetch health & ammo stats
1158     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1159         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1160         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1161         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1162         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1163
1164     // Draw the crosshairs
1165     picsize = drawgetimagesize(SPIDER_CROSS);
1166     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1167     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1168     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1169
1170     hudloc_y =  4;
1171     hudloc_x = 4;
1172
1173     picsize = drawgetimagesize(spider_h) * 0.5;
1174     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1175
1176     picsize = drawgetimagesize(spider_a2) * 0.5;
1177     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1178
1179     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1180     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1181     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1182
1183     picsize = drawgetimagesize(spider_a1) * 0.85;
1184     if(rockets == 9)
1185     {
1186         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1187         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1188     }
1189     else
1190     {
1191         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1192         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1193     }
1194
1195     picsize = drawgetimagesize(spider_b) * 0.5;
1196     hudloc_y = 10.5;
1197     hudloc_x = 10.5;
1198
1199     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1200     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1201     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1202     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1203
1204
1205         /*
1206         // Draw health bar
1207         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1208         p = p + '0 1 0' * vid_conheight - '0 32 0';
1209         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1210         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1211         p_y += 8;
1212         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1213         p_x += 256 * hp;
1214         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1215
1216         // Draw minigun heat indicator
1217         p = '0.5 0 0' * (vid_conwidth - 256);
1218         p = p + '0 1 0' * vid_conheight - '0 34  0';
1219         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1220         p_x += 256 * (1-heat);
1221         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1222
1223
1224         // Draw rocket icons for loaded/empty tubes.
1225         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1226         pp += '0 1 0' * vid_conheight - '0 64 0';
1227         for(i = 0; i < 8; ++i)
1228         {
1229                 p = pp + '1 0 0' * (rkt_size * i);
1230                 if(rockets == 8)
1231                 {
1232                         if(floor(reload * 8) == i)
1233                         {
1234                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1235                         }
1236                         else if(i < reload * 8)
1237                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1238                         else
1239                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1240                 }
1241                 else
1242                 {
1243                         if(i < rockets)
1244                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1245                         else
1246                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1247                 }
1248         }
1249         */
1250
1251         if (scoreboard_showscores)
1252         {
1253                 HUD_DrawScoreboard();
1254                 HUD_DrawCenterPrint();
1255         }
1256
1257 }
1258
1259 #define raptor_h "gfx/vehicles/hud_bg.tga"
1260 #define raptor_b "gfx/vehicles/raptor.tga"
1261 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1262 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1263 #define raptor_s "gfx/vehicles/shiled.tga"
1264
1265 void CSQC_RAPTOR_HUD()
1266 {
1267         float reload, hp, shield, energy;
1268         vector picsize, hudloc;
1269
1270     // Fetch health & ammo stats
1271     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1272         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1273         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1274         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1275
1276     // Draw the crosshairs
1277     picsize = drawgetimagesize(SPIDER_CROSS);
1278     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1279     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1280     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1281
1282     hudloc_y =  4;
1283     hudloc_x = 4;
1284
1285     picsize = drawgetimagesize(raptor_h) * 0.5;
1286     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1287
1288     picsize = drawgetimagesize(spider_a2) * 0.5;
1289     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1290
1291     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1292     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1293     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1294
1295
1296     picsize = drawgetimagesize(spider_a1) * 0.85;
1297     if(reload == 1)
1298     {
1299         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1300         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1301     }
1302     else
1303     {
1304         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1305         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1306     }
1307
1308     picsize = drawgetimagesize(raptor_b) * 0.5;
1309     hudloc_y = 10.5;
1310     hudloc_x = 10.5;
1311
1312     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1313     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1314     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1315     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1316
1317
1318         if (scoreboard_showscores)
1319         {
1320                 HUD_DrawScoreboard();
1321                 HUD_DrawCenterPrint();
1322         }
1323
1324 }
1325
1326 #define waki_h "gfx/vehicles/hud_bg.tga"
1327 #define waki_b "gfx/vehicles/waki.tga"
1328 #define waki_e "gfx/vehicles/waki_e.tga"
1329 #define waki_g "gfx/vehicles/waki_guns.tga"
1330 #define waki_r "gfx/vehicles/waki_rockets.tga"
1331 #define waki_s "gfx/vehicles/shiled.tga"
1332
1333 #define waki_a1 "gfx/hud/sb_rocket.tga"
1334 #define waki_a2 "gfx/sb_cells.tga"
1335
1336 void CSQC_WAKIZASHI_HUD()
1337 {
1338         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1339         float health, shield, energy, rockets;
1340         vector picsize, hudloc;
1341
1342     picsize = drawgetimagesize(SPIDER_CROSS);
1343     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1344     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1345     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1346
1347 /*
1348 const float STAT_VEHICLESTAT_HEALTH  = 60;
1349 const float STAT_VEHICLESTAT_SHIELD  = 61;
1350 const float STAT_VEHICLESTAT_ENERGY  = 62;
1351 const float STAT_VEHICLESTAT_AMMO1   = 63;
1352 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1353 const float STAT_VEHICLESTAT_AMMO2   = 65;
1354 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1355 */
1356     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1357         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1358         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1359         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1360
1361     hudloc_y =  4;
1362     hudloc_x = 4;
1363
1364     picsize = drawgetimagesize(waki_h) * 0.5;
1365     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1366
1367     picsize = drawgetimagesize(waki_a2) * 0.7;
1368     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1369
1370
1371     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1372     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1373
1374     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1375
1376     picsize = drawgetimagesize(waki_a1) * 0.75;
1377     if(rockets == 1)
1378     {
1379         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1380         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1381     }
1382     else
1383     {
1384         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1385         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1386         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1387     }
1388
1389     picsize = drawgetimagesize(waki_b) * 0.5;
1390     hudloc_y = 10.5;
1391     hudloc_x = 10.5;
1392
1393     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1394     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1395     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1396     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1397
1398
1399
1400         /*
1401         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1402         p = p + '0 1 0' * vid_conheight - '0 32 0';
1403
1404         // Draw health bar
1405         p_y += 8;
1406         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1407         p_x += 256 * health;
1408         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1409
1410         // Draw shiled bar
1411         p_x -= 256 * health;
1412         p_y += 4;
1413         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1414
1415         // Draw energy
1416         //p_x -= 256 * health;
1417         p_y -= 8;
1418         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1419
1420         // Draw rockets bar
1421         p_y += 12;
1422         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1423         */
1424
1425
1426
1427
1428         if (scoreboard_showscores)
1429         {
1430                 HUD_DrawScoreboard();
1431                 HUD_DrawCenterPrint();
1432         }
1433
1434 }
1435
1436
1437 void CSQC_common_hud(void)
1438 {
1439         // HUD_SortFrags(); done in HUD_Draw
1440         float hud;
1441         hud = getstati(STAT_HUD);
1442
1443         //hud = 10;
1444         switch(hud)
1445         {
1446                 case HUD_NORMAL:
1447                         // do some accuracy var caching
1448                         float i;
1449                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1450                         {
1451                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1452                                 {
1453                                         if(acc_color_levels)
1454                                                 strunzone(acc_color_levels);
1455                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1456                                         acc_levels = tokenize(acc_color_levels);
1457                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1458                                                 acc_levels = MAX_ACCURACY_LEVELS;
1459
1460                                         for (i = 0; i < acc_levels; ++i)
1461                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1462                                 }
1463                                 // let know that acc_col[] needs to be loaded
1464                                 acc_col_x[0] = -1;
1465                         }
1466
1467                         HUD_Main(); // always run these functions for alpha checks
1468                         HUD_DrawScoreboard();
1469
1470                         if (scoreboard_active) // scoreboard/accuracy
1471                         {
1472                                 HUD_Reset();
1473                                 // HUD_DrawScoreboard takes care of centerprint_start
1474                         }
1475                         else if (intermission == 2) // map voting screen
1476                         {
1477                                 HUD_FinaleOverlay();
1478                                 HUD_Reset();
1479
1480                                 centerprint_start_x = 0;
1481                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1482                         }
1483                         else // hud
1484                         {
1485                                 centerprint_start_x = 0;
1486                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1487                         }
1488
1489                         HUD_DrawCenterPrint();
1490                         break;
1491
1492                 case HUD_SPIDERBOT:
1493                         CSQC_SPIDER_HUD();
1494                         break;
1495
1496                 case HUD_WAKIZASHI:
1497                         CSQC_WAKIZASHI_HUD();
1498                         break;
1499         }
1500 }
1501
1502
1503 // following vectors must be global to allow seamless switching between camera modes
1504 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1505 void CSQC_Demo_Camera()
1506 {
1507         float speed, attenuation, dimensions;
1508         vector tmp, delta;
1509
1510         if( autocvar_camera_reset || !camera_mode )
1511         {
1512                 camera_offset = '0 0 0';
1513                 current_angles = '0 0 0';
1514                 camera_direction = '0 0 0';
1515                 camera_offset_z += 30;
1516                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1517                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1518                 current_origin = view_origin;
1519                 current_camera_offset  = camera_offset;
1520                 cvar_set("camera_reset", "0");
1521                 camera_mode = CAMERA_CHASE;
1522         }
1523
1524         // Camera angles
1525         if( camera_roll )
1526                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1527
1528         if(autocvar_camera_look_player)
1529         {
1530                 local vector dir;
1531                 local float n;
1532
1533                 dir = normalize(view_origin - current_position);
1534                 n = mouse_angles_z;
1535                 mouse_angles = vectoangles(dir);
1536                 mouse_angles_x = mouse_angles_x * -1;
1537                 mouse_angles_z = n;
1538         }
1539         else
1540         {
1541                 tmp = getmousepos() * 0.1;
1542                 if(vlen(tmp)>autocvar_camera_mouse_treshold)
1543                 {
1544                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1545                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1546                 }
1547         }
1548
1549         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1550         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1551         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1552         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1553
1554         // Fix difference when angles don't have the same sign
1555         delta = '0 0 0';
1556         if(mouse_angles_y < -60 && current_angles_y > 60)
1557                 delta = '0 360 0';
1558         if(mouse_angles_y > 60 && current_angles_y < -60)
1559                 delta = '0 -360 0';
1560
1561         if(autocvar_camera_look_player)
1562                 attenuation = autocvar_camera_look_attenuation;
1563         else
1564                 attenuation = autocvar_camera_speed_attenuation;
1565
1566         attenuation = 1 / max(1, attenuation);
1567         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1568
1569         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1570         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1571         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1572         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1573
1574         // Camera position
1575         tmp = '0 0 0';
1576         dimensions = 0;
1577
1578         if( camera_direction_x )
1579         {
1580                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1581                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1582                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1583                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1584                 ++dimensions;
1585         }
1586
1587         if( camera_direction_y )
1588         {
1589                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1590                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1591                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1592                 ++dimensions;
1593         }
1594
1595         if( camera_direction_z )
1596         {
1597                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1598                 ++dimensions;
1599         }
1600
1601         if(autocvar_camera_free)
1602                 speed = autocvar_camera_speed_free;
1603         else
1604                 speed = autocvar_camera_speed_chase;
1605
1606         if(dimensions)
1607         {
1608                 speed = speed * sqrt(1 / dimensions);
1609                 camera_offset += tmp * speed;
1610         }
1611
1612         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1613
1614         // Camera modes
1615         if( autocvar_camera_free )
1616         {
1617                 if ( camera_mode == CAMERA_CHASE )
1618                 {
1619                         current_camera_offset = current_origin + current_camera_offset;
1620                         camera_offset = current_origin + camera_offset;
1621                 }
1622
1623                 camera_mode = CAMERA_FREE;
1624                 current_position = current_camera_offset;
1625         }
1626         else
1627         {
1628                 if ( camera_mode == CAMERA_FREE )
1629                 {
1630                         current_origin = view_origin;
1631                         camera_offset = camera_offset - current_origin;
1632                         current_camera_offset = current_camera_offset - current_origin;
1633                 }
1634
1635                 camera_mode = CAMERA_CHASE;
1636
1637                 if(autocvar_camera_chase_smoothly)
1638                         current_origin += (view_origin - current_origin) * attenuation;
1639                 else
1640                         current_origin = view_origin;
1641
1642                 current_position = current_origin + current_camera_offset;
1643         }
1644
1645         R_SetView(VF_ANGLES, current_angles);
1646         R_SetView(VF_ORIGIN, current_position);
1647 }