Merge remote branch 'origin/master' into tzork/vehicles-2
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / View.qc
1 entity porto;
2 vector polyline[16];
3 float trace_dphitcontents;
4 float trace_networkentity;
5 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
6 float DPCONTENTS_SOLID = 1; // blocks player movement
7 float DPCONTENTS_BODY = 32; // blocks player movement
8 float DPCONTENTS_CORPSE = 64; // blocks player movement
9 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
10 void Porto_Draw()
11 {
12         vector p, dir, ang, q, nextdir;
13         float idx, portal_number, portal1_idx;
14
15         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
16                 return;
17         if(intermission == 1)
18                 return;
19         if(intermission == 2)
20                 return;
21         if (getstati(STAT_HEALTH) <= 0)
22                 return;
23
24         dir = view_forward;
25
26         if(angles_held_status)
27         {
28                 makevectors(angles_held);
29                 dir = v_forward;
30         }
31
32         p = view_origin;
33
34         polyline[0] = p;
35         idx = 1;
36         portal_number = 0;
37         nextdir = dir;
38
39         for(;;)
40         {
41                 dir = nextdir;
42                 traceline(p, p + 65536 * dir, TRUE, porto);
43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
44                         return;
45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
46                 p = trace_endpos;
47                 polyline[idx] = p;
48                 ++idx;
49                 if(idx >= 16)
50                         return;
51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
52                         continue;
53                 ++portal_number;
54                 ang = vectoangles2(trace_plane_normal, dir);
55                 ang_x = -ang_x;
56                 makevectors(ang);
57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
58                         return;
59                 if(portal_number == 1)
60                         portal1_idx = idx;
61                 if(portal_number >= 2)
62                         break;
63         }
64
65         while(idx >= 2)
66         {
67                 p = polyline[idx-2];
68                 q = polyline[idx-1];
69                 if(idx == 2)
70                         p = p - view_up * 16;
71                 if(idx-1 >= portal1_idx)
72                 {
73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
74                 }
75                 else
76                 {
77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
78                 }
79                 --idx;
80         }
81 }
82
83 /**
84  * Checks whether the server initiated a map restart (stat_game_starttime changed)
85  *
86  * TODO: Use a better solution where a common shared entitiy is used that contains
87  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
88  * and STAT_FRAGLIMIT to be auto-sent)
89  */
90 void CheckForGamestartChange() {
91         float startTime;
92         startTime = getstatf(STAT_GAMESTARTTIME);
93         if (previous_game_starttime != startTime) {
94                 if ((time + 5.0) < startTime) {
95                         //if connecting to server while restart was active don't always play prepareforbattle
96                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
97                 }
98                 if (time < startTime) {
99                         restartAnnouncer = spawn();
100                         restartAnnouncer.think = restartAnnouncer_Think;
101                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
102                 }
103         }
104         previous_game_starttime = startTime;
105 }
106
107 void Porto_Init()
108 {
109         porto = spawn();
110         porto.classname = "porto";
111         porto.draw = Porto_Draw;
112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
113 }
114
115 float drawtime;
116 float avgspeed;
117 vector GetCurrentFov(float fov)
118 {
119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
120
121         zoomsensitivity = autocvar_cl_zoomsensitivity;
122         zoomfactor = autocvar_cl_zoomfactor;
123         if(zoomfactor < 1 || zoomfactor > 16)
124                 zoomfactor = 2.5;
125         zoomspeed = autocvar_cl_zoomspeed;
126         if(zoomspeed >= 0)
127                 if(zoomspeed < 0.5 || zoomspeed > 16)
128                         zoomspeed = 3.5;
129
130         zoomdir = button_zoom;
131         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
132                 zoomdir += button_attack2;
133         if(spectatee_status > 0 || isdemo())
134         {
135                 if(spectatorbutton_zoom)
136                         zoomdir = 0 + !zoomdir;
137                 // do not even THINK about removing this 0
138                 // _I_ know what I am doing
139                 // fteqcc does not
140         }
141
142         if(zoomdir)
143                 zoomin_effect = 0;
144
145         if(zoomin_effect || camera_active)
146         {
147                 current_viewzoom = min(1, current_viewzoom + drawframetime);
148         }
149         else
150         {
151                 if(zoomspeed < 0) // instant zoom
152                 {
153                         if(zoomdir)
154                                 current_viewzoom = 1 / zoomfactor;
155                         else
156                                 current_viewzoom = 1;
157                 }
158                 else
159                 {
160                         if(zoomdir)
161                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
162                         else
163                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
164                 }
165         }
166
167         if(almost_equals(current_viewzoom, 1))
168                 current_zoomfraction = 0;
169         else if(almost_equals(current_viewzoom, 1/zoomfactor))
170                 current_zoomfraction = 1;
171         else
172                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
173
174         if(zoomsensitivity < 1)
175                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
176         else
177                 setsensitivityscale(1);
178
179         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
180         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
181         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
182
183         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
184
185         float frustumx, frustumy, fovx, fovy;
186         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
187         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
188         fovx = atan2(frustumx, 1) / M_PI * 360.0;
189         fovy = atan2(frustumy, 1) / M_PI * 360.0;
190
191         return '1 0 0' * fovx + '0 1 0' * fovy;
192 }
193
194 // this function must match W_SetupShot!
195 float zoomscript_caught;
196
197 vector wcross_origin;
198 float wcross_scale_prev, wcross_alpha_prev;
199 vector wcross_color_prev;
200 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
201 vector wcross_color_goal_prev;
202 float wcross_changedonetime;
203
204 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
205 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
206 float wcross_name_changestarttime, wcross_name_changedonetime;
207 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
208 entity trueaim;
209 entity trueaim_rifle;
210
211 #define SHOTTYPE_HITTEAM 1
212 #define SHOTTYPE_HITOBSTRUCTION 2
213 #define SHOTTYPE_HITWORLD 3
214 #define SHOTTYPE_HITENEMY 4
215
216 void TrueAim_Init()
217 {
218         trueaim = spawn();
219         trueaim.classname = "trueaim";
220         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
221         trueaim_rifle = spawn();
222         trueaim_rifle.classname = "trueaim_rifle";
223         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
224 }
225
226 float EnemyHitCheck()
227 {
228         float t;
229         wcross_origin = project_3d_to_2d(trace_endpos);
230         wcross_origin_z = 0;
231         if(trace_networkentity < 1)
232                 return SHOTTYPE_HITWORLD;
233         if(trace_networkentity > maxclients)
234                 return SHOTTYPE_HITWORLD;
235         t = GetPlayerColor(trace_networkentity - 1);
236         if(teamplay)
237                 if(t == myteam)
238                         return SHOTTYPE_HITTEAM;
239         if(t == COLOR_SPECTATOR)
240                 return SHOTTYPE_HITWORLD;
241         return SHOTTYPE_HITENEMY;
242 }
243
244 float TrueAimCheck()
245 {
246         float nudge = 1; // added to traceline target and subtracted from result
247         vector vecs, trueaimpoint, w_shotorg;
248         vector mi, ma, dv;
249         float shottype;
250         entity ta;
251         float mv;
252
253         mi = ma = '0 0 0';
254         ta = trueaim;
255         mv = MOVE_NOMONSTERS;
256
257         switch(activeweapon)
258         {
259                 case WEP_TUBA: // no aim
260                 case WEP_PORTO: // shoots from eye
261                 case WEP_HOOK: // no trueaim
262                 case WEP_GRENADE_LAUNCHER: // toss curve
263                         return SHOTTYPE_HITWORLD;
264                 case WEP_NEX:
265                 case WEP_MINSTANEX:
266                         mv = MOVE_NORMAL;
267                         break;
268                 case WEP_RIFLE:
269                         ta = trueaim_rifle;
270                         mv = MOVE_NORMAL;
271                         if(zoomscript_caught)
272                         {
273                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
274                                 return EnemyHitCheck();
275                         }
276                         break;
277                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
278                         mi = '-3 -3 -3';
279                         ma = '3 3 3';
280                         break;
281                 case WEP_FIREBALL: // projectile has a size!
282                         mi = '-16 -16 -16';
283                         ma = '16 16 16';
284                         break;
285                 case WEP_SEEKER: // projectile has a size!
286                         mi = '-2 -2 -2';
287                         ma = '2 2 2';
288                         break;
289                 case WEP_ELECTRO: // projectile has a size!
290                         mi = '0 0 -3';
291                         ma = '0 0 -3';
292                         break;
293         }
294
295         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
296
297         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
298         trueaimpoint = trace_endpos;
299
300         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
301                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
302
303         if(vecs_x > 0)
304                 vecs_y = -vecs_y;
305         else
306                 vecs = '0 0 0';
307
308         dv = view_right * vecs_y + view_up * vecs_z;
309         w_shotorg = view_origin + dv;
310
311         // now move the vecs forward as much as requested if possible
312         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
313         w_shotorg = trace_endpos - view_forward * nudge;
314
315         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
316         shottype = EnemyHitCheck();
317         if(shottype != SHOTTYPE_HITWORLD)
318                 return shottype;
319
320 #if 0
321         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
322         // or rather, I know why, but see no fix
323         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
324                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
325                 return SHOTTYPE_HITOBSTRUCTION;
326 #endif
327
328         return SHOTTYPE_HITWORLD;
329 }
330
331 void CSQC_common_hud(void);
332
333 void PostInit(void);
334 void CSQC_Demo_Camera();
335 float HUD_WouldDrawScoreboard();
336 float camera_mode;
337 float reticle_type;
338 string NextFrameCommand;
339 void CSQC_SPIDER_HUD();
340 void CSQC_RAPTOR_HUD();
341
342 vector freeze_org, freeze_ang;
343 entity nightvision_noise, nightvision_noise2;
344
345 float pickup_crosshair_time, pickup_crosshair_size;
346 float hit_time, typehit_time;
347 float nextsound_hit_time, nextsound_typehit_time;
348 float hitindication_crosshair_time, hitindication_crosshair_size;
349 float use_nex_chargepool;
350
351 float myhealth, myhealth_prev;
352 float myhealth_flash;
353
354 vector myhealth_gentlergb;
355
356 float contentavgalpha, liquidalpha_prev;
357 vector liquidcolor_prev;
358
359 float eventchase_current_distance;
360
361 float checkfail[16];
362
363 void CSQC_UpdateView(float w, float h)
364 {
365         entity e;
366         float fov;
367         float f, i, j;
368         vector v, vo;
369         vector vf_size, vf_min;
370         float a;
371         float hud;
372         hud = getstati(STAT_HUD);
373
374         button_attack2 = (input_buttons & BUTTON_3);
375         button_zoom = (input_buttons & BUTTON_4);
376
377 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
378         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
379         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
380         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
381         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
382         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
383         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
384
385         vf_size = R_SetView3fv(VF_SIZE);
386         vf_min = R_SetView3fv(VF_MIN);
387         vid_width = vf_size_x;
388         vid_height = vf_size_y;
389
390         vector reticle_pos, reticle_size;
391         vector splash_pos, splash_size;
392
393         WaypointSprite_Load();
394
395         if(spectatee_status)
396                 myteam = GetPlayerColor(spectatee_status - 1);
397         else
398                 myteam = GetPlayerColor(player_localentnum - 1);
399
400         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
401         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
402
403         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
404         {
405                 R_SetView(VF_ORIGIN, freeze_org);
406                 R_SetView(VF_ANGLES, freeze_ang);
407         }
408         else
409         {
410                 freeze_org = R_SetView3fv(VF_ORIGIN);
411                 freeze_ang = R_SetView3fv(VF_ANGLES);
412         }
413
414         // event chase camera
415         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
416         {
417                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
418                 {
419                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
420                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
421                         if(!autocvar_chase_active)
422                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
423
424                         // make the camera smooth back
425                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
426                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
427                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
428                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
429
430                         vector eventchase_target_origin;
431                         makevectors(view_angles);
432                         // pass 1, used to check where the camera would go and obtain the trace_fraction
433                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance;
434
435                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
436                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
437                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
438                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
439                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
440
441                         R_SetView(VF_ORIGIN, trace_endpos);
442                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
443                 }
444                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
445                 {
446                         cvar_set("chase_active", "0");
447                         eventchase_current_distance = 0; // start from 0 next time
448                 }
449         }
450
451         WarpZone_FixView();
452         //WarpZone_FixPMove();
453
454         // Render the Scene
455         view_origin = R_SetView3fv(VF_ORIGIN);
456         view_angles = R_SetView3fv(VF_ANGLES);
457         makevectors(view_angles);
458         view_forward = v_forward;
459         view_right = v_right;
460         view_up = v_up;
461
462 #ifdef BLURTEST
463         if(time > blurtest_time0 && time < blurtest_time1)
464         {
465                 float r, t;
466
467                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
468                 r = t * blurtest_radius;
469                 f = 1 / pow(t, blurtest_power) - 1;
470
471                 cvar_set("r_glsl_postprocess", "1");
472                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
473         }
474         else
475         {
476                 cvar_set("r_glsl_postprocess", "0");
477                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
478         }
479 #endif
480
481         TargetMusic_Advance();
482         Fog_Force();
483
484         if(drawtime == 0)
485                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
486         else
487                 drawframetime = bound(0.000001, time - drawtime, 1);
488         drawtime = time;
489
490         // watch for gametype changes here...
491         // in ParseStuffCMD the cmd isn't executed yet :/
492         // might even be better to add the gametype to TE_CSQC_INIT...?
493         if(!postinit)
494                 PostInit();
495
496         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
497                 if(calledhooks & HOOK_START)
498                 {
499                         localcmd("\ncl_hook_gameend\n");
500                         calledhooks |= HOOK_END;
501                 }
502
503         CheckForGamestartChange();
504         serverAnnouncer();
505         maptimeAnnouncer();
506         carrierAnnouncer();
507
508         fov = autocvar_fov;
509         if(fov <= 59.5)
510         {
511                 if(!zoomscript_caught)
512                 {
513                         localcmd("+button9\n");
514                         zoomscript_caught = 1;
515                 }
516         }
517         else
518         {
519                 if(zoomscript_caught)
520                 {
521                         localcmd("-button9\n");
522                         zoomscript_caught = 0;
523                 }
524         }
525
526         ColorTranslateMode = autocvar_cl_stripcolorcodes;
527         activeweapon = getstati(STAT_SWITCHWEAPON);
528         f = (serverflags & SERVERFLAG_TEAMPLAY);
529         if(f != teamplay)
530         {
531                 teamplay = f;
532                 HUD_InitScores();
533         }
534
535         if(last_weapon != activeweapon) {
536                 weapontime = time;
537                 last_weapon = activeweapon;
538
539                 e = get_weaponinfo(activeweapon);
540                 if(e.netname != "")
541                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
542                 else
543                         localcmd("\ncl_hook_activeweapon none\n");
544         }
545
546         // ALWAYS Clear Current Scene First
547         R_ClearScene();
548         R_SetView(VF_ORIGIN, view_origin);
549         R_SetView(VF_ANGLES, view_angles);
550
551         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
552         R_SetView(VF_SIZE, vf_size);
553         R_SetView(VF_MIN, vf_min);
554
555         // Assign Standard Viewflags
556         // Draw the World (and sky)
557         R_SetView(VF_DRAWWORLD, 1);
558
559         // Set the console size vars
560         vid_conwidth = autocvar_vid_conwidth;
561         vid_conheight = autocvar_vid_conheight;
562         vid_pixelheight = autocvar_vid_pixelheight;
563
564         R_SetView(VF_FOV, GetCurrentFov(fov));
565
566         // Camera for demo playback
567         if(camera_active)
568         {
569                 if(autocvar_camera_enable)
570                         CSQC_Demo_Camera();
571                 else
572                 {
573                         cvar_set("chase_active", ftos(chase_active_backup));
574                         cvar_set("cl_demo_mousegrab", "0");
575                         camera_active = FALSE;
576                 }
577         }
578 #ifdef CAMERATEST
579         else if(autocvar_camera_enable)
580 #else
581         else if(autocvar_camera_enable && isdemo())
582 #endif
583         {
584                 // Enable required Darkplaces cvars
585                 chase_active_backup = autocvar_chase_active;
586                 cvar_set("chase_active", "2");
587                 cvar_set("cl_demo_mousegrab", "1");
588                 camera_active = TRUE;
589                 camera_mode = FALSE;
590         }
591
592         // Draw the Crosshair
593         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
594
595         // Draw the Engine Status Bar (the default Quake HUD)
596         R_SetView(VF_DRAWENGINEHUD, 0);
597
598         // Update the mouse position
599         /*
600            mousepos_x = vid_conwidth;
601            mousepos_y = vid_conheight;
602            mousepos = mousepos*0.5 + getmousepos();
603          */
604
605         e = self;
606         for(self = world; (self = nextent(self)); )
607                 if(self.draw)
608                         self.draw();
609         self = e;
610
611         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
612         R_RenderScene();
613
614         // now switch to 2D drawing mode by calling a 2D drawing function
615         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
616         // next R_RenderScene call
617         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
618
619         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
620         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
621         {
622                 // apply night vision effect
623                 vector rgb, tc_00, tc_01, tc_10, tc_11;
624
625                 if(!nightvision_noise)
626                 {
627                         nightvision_noise = spawn();
628                         nightvision_noise.classname = "nightvision_noise";
629                 }
630                 if(!nightvision_noise2)
631                 {
632                         nightvision_noise2 = spawn();
633                         nightvision_noise2.classname = "nightvision_noise2";
634                 }
635
636                 // color tint in yellow
637                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
638
639                 // draw BG
640                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
641                 rgb = '1 1 1';
642                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
643                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
644                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
645                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
646                 tc_11 = tc_01 + tc_10 - tc_00;
647                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
648                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
649                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
650                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
651                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
652                 R_EndPolygon();
653
654                 // draw FG
655                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
656                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
657                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
658                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
659                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
660                 tc_11 = tc_01 + tc_10 - tc_00;
661                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
662                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
663                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
664                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
665                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
666                 R_EndPolygon();
667         }
668
669         // Draw the aiming reticle for weapons that use it
670         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
671         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
672         // the view to go back to normal, so reticle_type would become 0 as we fade out)
673         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
674                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
675         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
676                 reticle_type = 2; // nex zoom
677         else if(button_zoom || zoomscript_caught)
678                 reticle_type = 1; // normal zoom
679         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
680                 reticle_type = 2; // nex zoom
681
682         if (reticle_type)
683         {
684                 if(autocvar_cl_reticle_stretch)
685                 {
686                         reticle_size_x = vid_conwidth;
687                         reticle_size_y = vid_conheight;
688                         reticle_pos_x = 0;
689                         reticle_pos_y = 0;
690                 }
691                 else
692                 {
693                         reticle_size_x = max(vid_conwidth, vid_conheight);
694                         reticle_size_y = max(vid_conwidth, vid_conheight);
695                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
696                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
697                 }
698
699                 f = current_zoomfraction;
700                 if(zoomscript_caught)
701                         f = 1;
702                 if(autocvar_cl_reticle_item_normal)
703                 {
704                         if(reticle_type == 1 && f)
705                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
706                 }
707                 if(autocvar_cl_reticle_item_nex)
708                 {
709                         if(reticle_type == 2 && f)
710                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
711                 }
712         }
713
714
715         // improved polyblend
716         vector rgb;
717         if(autocvar_hud_contents)
718         {
719                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
720                 vector liquidcolor;
721
722                 switch(pointcontents(view_origin))
723                 {
724                         case CONTENT_WATER:
725                                 liquidalpha = autocvar_hud_contents_water_alpha;
726                                 liquidcolor = stov(autocvar_hud_contents_water_color);
727                                 incontent = 1;
728                                 break;
729
730                         case CONTENT_LAVA:
731                                 liquidalpha = autocvar_hud_contents_lava_alpha;
732                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
733                                 incontent = 1;
734                                 break;
735
736                         case CONTENT_SLIME:
737                                 liquidalpha = autocvar_hud_contents_slime_alpha;
738                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
739                                 incontent = 1;
740                                 break;
741
742                         default:
743                                 liquidalpha = 0;
744                                 liquidcolor = '0 0 0';
745                                 incontent = 0;
746                                 break;
747                 }
748
749                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
750                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
751                         contentfadetime = autocvar_hud_contents_fadeintime;
752                         liquidalpha_prev = liquidalpha;
753                         liquidcolor_prev = liquidcolor;
754                 }
755                 else
756                         contentfadetime = autocvar_hud_contents_fadeouttime;
757
758                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
759                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
760
761                 if(contentavgalpha)
762                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
763         }
764         
765         if(autocvar_hud_damage && !autocvar_chase_active)
766
767         {
768                 splash_size_x = max(vid_conwidth, vid_conheight);
769                 splash_size_y = max(vid_conwidth, vid_conheight);
770                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
771                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
772
773                 float myhealth_flash_temp;
774                 myhealth = getstati(STAT_HEALTH);
775
776                 // fade out
777                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
778                 // add new damage
779                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
780
781                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
782                 pain_threshold = autocvar_hud_damage_pain_threshold;
783                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
784                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
785
786                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
787                 {
788                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
789                 }
790
791                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
792
793                 if(myhealth_prev < 1)
794                 {
795                         if(myhealth >= 1)
796                         {
797                                 myhealth_flash = 0; // just spawned, clear the flash immediately
798                                 myhealth_flash_temp = 0;
799                         }
800                         else
801                         {
802                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
803                         }
804                 }
805
806                 if(spectatee_status == -1 || intermission)
807                 {
808                         myhealth_flash = 0; // observing, or match ended
809                         myhealth_flash_temp = 0;
810                 }
811
812                 myhealth_prev = myhealth;
813
814                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
815                 {
816                         if(autocvar_cl_gentle_damage == 2)
817                         {
818                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
819                                 {
820                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
821                                 }
822                         }
823                         else
824                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
825
826                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
827                 }
828                 else
829                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
830         }
831
832         if(menu_visible)
833                 menu_show();
834
835         /*if(gametype == GAME_CTF)
836           {
837           ctf_view();
838           } else */
839
840         // draw 2D entities
841         e = self;
842         for(self = world; (self = nextent(self)); )
843                 if(self.draw2d)
844                         self.draw2d();
845         self = e;
846         Draw_ShowNames_All();
847
848         scoreboard_active = HUD_WouldDrawScoreboard();
849
850         hit_time = getstatf(STAT_HIT_TIME);
851         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
852         {
853                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
854                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
855         }
856         typehit_time = getstatf(STAT_TYPEHIT_TIME);
857         if(typehit_time > nextsound_typehit_time)
858         {
859                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
860                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
861         }
862
863         if(hud == HUD_SPIDERBOT)
864                 CSQC_SPIDER_HUD();
865         else if(hud == HUD_WAKIZASHI)
866         CSQC_WAKIZASHI_HUD();
867     else if(hud == HUD_RAPTOR)
868         CSQC_RAPTOR_HUD();
869     else if(hud == HUD_BUMBLEBEE)
870         CSQC_BUMBLE_HUD();
871         else
872         {
873                 if(gametype == GAME_FREEZETAG)
874                 {
875                         if(getstati(STAT_FROZEN))
876                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
877                         if(getstatf(STAT_REVIVE_PROGRESS))
878                         {
879                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
880                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
881                         }
882                 }
883
884                 if(autocvar_r_letterbox == 0)
885                         if(autocvar_viewsize < 120)
886                                 CSQC_common_hud();
887
888                 // crosshair goes VERY LAST
889                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1) {
890                         string wcross_style;
891                         float wcross_alpha, wcross_resolution;
892                         wcross_style = autocvar_crosshair;
893                         if (wcross_style == "0")
894                                 return;
895                         wcross_resolution = autocvar_crosshair_size;
896                         if (wcross_resolution == 0)
897                                 return;
898                         wcross_alpha = autocvar_crosshair_alpha;
899                         if (wcross_alpha == 0)
900                                 return;
901
902                         // TrueAim check
903                         float shottype;
904
905                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
906                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
907                         wcross_origin_z = 0;
908                         if(autocvar_crosshair_hittest)
909                         {
910                                 vector wcross_oldorigin;
911                                 wcross_oldorigin = wcross_origin;
912                                 shottype = TrueAimCheck();
913                                 if(shottype == SHOTTYPE_HITWORLD)
914                                 {
915                                         v = wcross_origin - wcross_oldorigin;
916                                         v_x /= vid_conwidth;
917                                         v_y /= vid_conheight;
918                                         if(vlen(v) > 0.01)
919                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
920                                 }
921                                 if(!autocvar_crosshair_hittest_showimpact)
922                                         wcross_origin = wcross_oldorigin;
923                         }
924                         else
925                                 shottype = SHOTTYPE_HITWORLD;
926
927                         vector wcross_color, wcross_size;
928                         string wcross_wep, wcross_name;
929                         float wcross_scale, wcross_blur;
930
931                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
932                                 e = get_weaponinfo(activeweapon);
933                                 if (e && e.netname != "")
934                                 {
935                                         wcross_wep = e.netname;
936                                         if(autocvar_crosshair_per_weapon)
937                                         {
938                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
939                                                 if (wcross_resolution == 0)
940                                                         return;
941                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
942                                                 if (wcross_alpha == 0)
943                                                         return;
944
945                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
946                                                 if(wcross_style == "" || wcross_style == "0")
947                                                         wcross_style = wcross_wep;
948                                         }
949                                 }
950                         }
951                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
952                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
953                         else if(autocvar_crosshair_color_by_health)
954                         {
955                                 local float x = getstati(STAT_HEALTH);
956
957                                 //x = red
958                                 //y = green
959                                 //z = blue
960
961                                 wcross_color_z = 0;
962
963                                 if(x > 200)
964                                 {
965                                         wcross_color_x = 0;
966                                         wcross_color_y = 1;
967                                 }
968                                 else if(x > 150)
969                                 {
970                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
971                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
972                                 }
973                                 else if(x > 100)
974                                 {
975                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
976                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
977                                         wcross_color_z = 1 - (x-100)*0.02;
978                                 }
979                                 else if(x > 50)
980                                 {
981                                         wcross_color_x = 1;
982                                         wcross_color_y = 1;
983                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
984                                 }
985                                 else if(x > 20)
986                                 {
987                                         wcross_color_x = 1;
988                                         wcross_color_y = (x-20)*90/27/100;
989                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
990                                 }
991                                 else
992                                 {
993                                         wcross_color_x = 1;
994                                         wcross_color_y = 0;
995                                 }
996                         }
997                         else
998                                 wcross_color = stov(autocvar_crosshair_color);
999
1000                         wcross_name = strcat("gfx/crosshair", wcross_style);
1001
1002                         if(autocvar_crosshair_effect_scalefade)
1003                         {
1004                                 wcross_scale = wcross_resolution;
1005                                 wcross_resolution = 1;
1006                         }
1007                         else
1008                         {
1009                                 wcross_scale = 1;
1010                         }
1011
1012                         if(autocvar_crosshair_pickup)
1013                         {
1014                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1015                                 {
1016                                         pickup_crosshair_size = 1;
1017                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1018                                 }
1019
1020                                 if(pickup_crosshair_size > 0)
1021                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1022                                 else
1023                                         pickup_crosshair_size = 0;
1024
1025                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1026                         }
1027
1028                         vector hitindication_color;
1029                         if(autocvar_crosshair_hitindication)
1030                         {
1031                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1032                                 if(hitindication_crosshair_time < hit_time)
1033                                 {
1034                                         hitindication_crosshair_size = 1;
1035                                         hitindication_crosshair_time = hit_time;
1036                                 }
1037
1038                                 if(hitindication_crosshair_size > 0)
1039                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1040                                 else
1041                                         hitindication_crosshair_size = 0;
1042
1043                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1044                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1045                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1046                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1047                         }
1048
1049                         if(shottype == SHOTTYPE_HITENEMY)
1050                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1051                         if(shottype == SHOTTYPE_HITTEAM)
1052                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1053
1054                         f = autocvar_crosshair_effect_speed;
1055                         if(f < 0)
1056                                 f *= -2 * g_weaponswitchdelay;
1057                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1058                         {
1059                                 wcross_changedonetime = time + f;
1060                         }
1061                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1062                         {
1063                                 wcross_name_changestarttime = time;
1064                                 wcross_name_changedonetime = time + f;
1065                                 if(wcross_name_goal_prev_prev)
1066                                         strunzone(wcross_name_goal_prev_prev);
1067                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1068                                 wcross_name_goal_prev = strzone(wcross_name);
1069                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1070                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1071                                 wcross_resolution_goal_prev = wcross_resolution;
1072                         }
1073
1074                         wcross_scale_goal_prev = wcross_scale;
1075                         wcross_alpha_goal_prev = wcross_alpha;
1076                         wcross_color_goal_prev = wcross_color;
1077
1078                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1079                         {
1080                                 wcross_blur = 1;
1081                                 wcross_alpha *= 0.75;
1082                         }
1083                         else
1084                                 wcross_blur = 0;
1085                         // *_prev is at time-frametime
1086                         // * is at wcross_changedonetime+f
1087                         // what do we have at time?
1088                         if(time < wcross_changedonetime)
1089                         {
1090                                 f = frametime / (wcross_changedonetime - time + frametime);
1091                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1092                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1093                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1094                         }
1095
1096                         wcross_scale_prev = wcross_scale;
1097                         wcross_alpha_prev = wcross_alpha;
1098                         wcross_color_prev = wcross_color;
1099
1100                         wcross_scale *= 1 - autocvar__menu_alpha;
1101                         wcross_alpha *= 1 - autocvar__menu_alpha;
1102                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1103
1104                         // crosshair rings for weapon stats
1105                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1106                         {
1107                                 // declarations and stats
1108                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1109                                 string ring_image, ring_inner_image;
1110                                 vector ring_rgb, ring_inner_rgb;
1111
1112                                 ring_scale = autocvar_crosshair_ring_size;
1113
1114                                 float weapon_clipload, weapon_clipsize;
1115                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1116                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1117
1118                                 float nex_charge, nex_chargepool;
1119                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1120                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1121
1122                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1123                                         nex_charge_movingavg = nex_charge;
1124
1125
1126                                 // handle the values
1127                                 if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1128                                 {
1129                                         if (nex_chargepool || use_nex_chargepool) {
1130                                                 use_nex_chargepool = 1;
1131                                                 ring_inner_value = nex_chargepool;
1132                                         } else {
1133                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1134                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1135                                         }
1136
1137                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1138                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1139                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1140
1141                                         // draw the outer ring to show the current charge of the weapon
1142                                         ring_value = nex_charge;
1143                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1144                                         ring_rgb = wcross_color;
1145                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1146                                 }
1147                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1148                                 {
1149                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1150                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1151                                         ring_rgb = wcross_color;
1152                                         ring_image = "gfx/crosshair_ring.tga";
1153                                 }
1154                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1155                                 {
1156                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1157                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1158                                         ring_rgb = wcross_color;
1159                                         ring_image = "gfx/crosshair_ring.tga";
1160                                 }
1161
1162                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1163                                 {
1164                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1165                                         ring_scale = autocvar_crosshair_ring_reload_size;
1166                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1167                                         ring_rgb = wcross_color;
1168
1169                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1170                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1171                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1172                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1173                                         else
1174                                                 ring_image = "gfx/crosshair_ring.tga";
1175                                 }
1176
1177                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1178                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1179
1180                                 if (ring_value)
1181                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1182                         }
1183
1184 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1185                         do \
1186                         { \
1187                                 if(wcross_blur > 0) \
1188                                 { \
1189                                         for(i = -2; i <= 2; ++i) \
1190                                                 for(j = -2; j <= 2; ++j) \
1191                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1192                                 } \
1193                                 else \
1194                                 { \
1195                                         M(0,0,sz,wcross_name,wcross_alpha); \
1196                                 } \
1197                         } \
1198                         while(0)
1199
1200 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1201                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1202
1203 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1204                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1205
1206                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1207                         {
1208                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1209                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1210                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1211                                 f = 1 - f;
1212                         }
1213                         else
1214                         {
1215                                 f = 1;
1216                         }
1217
1218                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1219                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1220
1221                         if(autocvar_crosshair_dot)
1222             {
1223                 vector wcross_color_old;
1224                 wcross_color_old = wcross_color;
1225                 if(autocvar_crosshair_dot_color != "0")
1226                     wcross_color = stov(autocvar_crosshair_dot_color);
1227                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1228                 wcross_color = wcross_color_old;
1229             }
1230
1231                         wcross_name_alpha_goal_prev = f;
1232                 }
1233                 else
1234                 {
1235                         wcross_scale_prev = 0;
1236                         wcross_alpha_prev = 0;
1237                         wcross_scale_goal_prev = 0;
1238                         wcross_alpha_goal_prev = 0;
1239                         wcross_changedonetime = 0;
1240                         if(wcross_name_goal_prev)
1241                                 strunzone(wcross_name_goal_prev);
1242                         wcross_name_goal_prev = string_null;
1243                         if(wcross_name_goal_prev_prev)
1244                                 strunzone(wcross_name_goal_prev_prev);
1245                         wcross_name_goal_prev_prev = string_null;
1246                         wcross_name_changestarttime = 0;
1247                         wcross_name_changedonetime = 0;
1248                         wcross_name_alpha_goal_prev = 0;
1249                         wcross_name_alpha_goal_prev_prev = 0;
1250                         wcross_resolution_goal_prev = 0;
1251                         wcross_resolution_goal_prev_prev = 0;
1252                 }
1253         }
1254
1255         if(NextFrameCommand)
1256         {
1257                 localcmd("\n", NextFrameCommand, "\n");
1258                 NextFrameCommand = string_null;
1259         }
1260
1261         // we must do this check AFTER a frame was rendered, or it won't work
1262         if(cs_project_is_b0rked == 0)
1263         {
1264                 string w0, h0;
1265                 w0 = ftos(autocvar_vid_conwidth);
1266                 h0 = ftos(autocvar_vid_conheight);
1267                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1268                 //R_SetView(VF_FOV, '90 90 0');
1269                 R_SetView(VF_ORIGIN, '0 0 0');
1270                 R_SetView(VF_ANGLES, '0 0 0');
1271                 R_SetView(VF_PERSPECTIVE, 1);
1272                 makevectors('0 0 0');
1273                 vector v1, v2;
1274                 cvar_set("vid_conwidth", "800");
1275                 cvar_set("vid_conheight", "600");
1276                 v1 = cs_project(v_forward);
1277                 cvar_set("vid_conwidth", "640");
1278                 cvar_set("vid_conheight", "480");
1279                 v2 = cs_project(v_forward);
1280                 if(v1 == v2)
1281                         cs_project_is_b0rked = 1;
1282                 else
1283                         cs_project_is_b0rked = -1;
1284                 cvar_set("vid_conwidth", w0);
1285                 cvar_set("vid_conheight", h0);
1286         }
1287
1288         if(autocvar__hud_configure)
1289                 HUD_Panel_Mouse();
1290
1291         // let's reset the view back to normal for the end
1292         R_SetView(VF_MIN, '0 0 0');
1293         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1294 }
1295
1296
1297 void CSQC_common_hud(void)
1298 {
1299         // HUD_SortFrags(); done in HUD_Draw
1300         float hud;
1301         hud = getstati(STAT_HUD);
1302
1303         //hud = 10;
1304         switch(hud)
1305         {
1306                 case HUD_NORMAL:
1307                         // do some accuracy var caching
1308                         float i;
1309                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1310                         {
1311                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1312                                 {
1313                                         if(acc_color_levels)
1314                                                 strunzone(acc_color_levels);
1315                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1316                                         acc_levels = tokenize(acc_color_levels);
1317                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1318                                                 acc_levels = MAX_ACCURACY_LEVELS;
1319
1320                                         for (i = 0; i < acc_levels; ++i)
1321                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1322                                 }
1323                                 // let know that acc_col[] needs to be loaded
1324                                 acc_col_x[0] = -1;
1325                         }
1326
1327                         HUD_Main(); // always run these functions for alpha checks
1328                         HUD_DrawScoreboard();
1329
1330                         if (scoreboard_active) // scoreboard/accuracy
1331                         {
1332                                 HUD_Reset();
1333                                 // HUD_DrawScoreboard takes care of centerprint_start
1334                         }
1335                         else if (intermission == 2) // map voting screen
1336                         {
1337                                 HUD_FinaleOverlay();
1338                                 HUD_Reset();
1339
1340                                 centerprint_start_x = 0;
1341                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1342                         }
1343                         else // hud
1344                         {
1345                                 centerprint_start_x = 0;
1346                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1347                         }
1348
1349                         HUD_DrawCenterPrint();
1350                         break;
1351
1352                 case HUD_SPIDERBOT:
1353                         CSQC_SPIDER_HUD();
1354                         break;
1355
1356                 case HUD_WAKIZASHI:
1357                         CSQC_WAKIZASHI_HUD();
1358                         break;
1359
1360         case HUD_BUMBLEBEE:
1361             CSQC_BUMBLE_HUD();
1362             break;
1363
1364         }
1365 }
1366
1367
1368 // following vectors must be global to allow seamless switching between camera modes
1369 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1370 void CSQC_Demo_Camera()
1371 {
1372         float speed, attenuation, dimensions;
1373         vector tmp, delta;
1374
1375         if( autocvar_camera_reset || !camera_mode )
1376         {
1377                 camera_offset = '0 0 0';
1378                 current_angles = '0 0 0';
1379                 camera_direction = '0 0 0';
1380                 camera_offset_z += 30;
1381                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1382                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1383                 current_origin = view_origin;
1384                 current_camera_offset  = camera_offset;
1385                 cvar_set("camera_reset", "0");
1386                 camera_mode = CAMERA_CHASE;
1387         }
1388
1389         // Camera angles
1390         if( camera_roll )
1391                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1392
1393         if(autocvar_camera_look_player)
1394         {
1395                 local vector dir;
1396                 local float n;
1397
1398                 dir = normalize(view_origin - current_position);
1399                 n = mouse_angles_z;
1400                 mouse_angles = vectoangles(dir);
1401                 mouse_angles_x = mouse_angles_x * -1;
1402                 mouse_angles_z = n;
1403         }
1404         else
1405         {
1406                 tmp = getmousepos() * 0.1;
1407                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1408                 {
1409                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1410                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1411                 }
1412         }
1413
1414         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1415         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1416         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1417         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1418
1419         // Fix difference when angles don't have the same sign
1420         delta = '0 0 0';
1421         if(mouse_angles_y < -60 && current_angles_y > 60)
1422                 delta = '0 360 0';
1423         if(mouse_angles_y > 60 && current_angles_y < -60)
1424                 delta = '0 -360 0';
1425
1426         if(autocvar_camera_look_player)
1427                 attenuation = autocvar_camera_look_attenuation;
1428         else
1429                 attenuation = autocvar_camera_speed_attenuation;
1430
1431         attenuation = 1 / max(1, attenuation);
1432         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1433
1434         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1435         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1436         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1437         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1438
1439         // Camera position
1440         tmp = '0 0 0';
1441         dimensions = 0;
1442
1443         if( camera_direction_x )
1444         {
1445                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1446                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1447                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1448                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1449                 ++dimensions;
1450         }
1451
1452         if( camera_direction_y )
1453         {
1454                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1455                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1456                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1457                 ++dimensions;
1458         }
1459
1460         if( camera_direction_z )
1461         {
1462                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1463                 ++dimensions;
1464         }
1465
1466         if(autocvar_camera_free)
1467                 speed = autocvar_camera_speed_free;
1468         else
1469                 speed = autocvar_camera_speed_chase;
1470
1471         if(dimensions)
1472         {
1473                 speed = speed * sqrt(1 / dimensions);
1474                 camera_offset += tmp * speed;
1475         }
1476
1477         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1478
1479         // Camera modes
1480         if( autocvar_camera_free )
1481         {
1482                 if ( camera_mode == CAMERA_CHASE )
1483                 {
1484                         current_camera_offset = current_origin + current_camera_offset;
1485                         camera_offset = current_origin + camera_offset;
1486                 }
1487
1488                 camera_mode = CAMERA_FREE;
1489                 current_position = current_camera_offset;
1490         }
1491         else
1492         {
1493                 if ( camera_mode == CAMERA_FREE )
1494                 {
1495                         current_origin = view_origin;
1496                         camera_offset = camera_offset - current_origin;
1497                         current_camera_offset = current_camera_offset - current_origin;
1498                 }
1499
1500                 camera_mode = CAMERA_CHASE;
1501
1502                 if(autocvar_camera_chase_smoothly)
1503                         current_origin += (view_origin - current_origin) * attenuation;
1504                 else
1505                         current_origin = view_origin;
1506
1507                 current_position = current_origin + current_camera_offset;
1508         }
1509
1510         R_SetView(VF_ANGLES, current_angles);
1511         R_SetView(VF_ORIGIN, current_position);
1512 }