qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float view_set;
 343 float camera_mode;
 344 float reticle_type;
 345 string NextFrameCommand;
 346 void CSQC_SPIDER_HUD();
 347 void CSQC_RAPTOR_HUD();
 348
 349 vector freeze_pmove_org, freeze_input_angles;
 350 entity nightvision_noise, nightvision_noise2;
 351
 352 float pickup_crosshair_time, pickup_crosshair_size;
 353
 354 void CSQC_UpdateView(float w, float h)
 355 {
 356         entity e;
 357         float fov;
 358         float f, i, j;
 359         vector v, vo;
 360         vector vf_size, vf_min;
 361         float a;
 362
 363         vf_size = R_SetView3fv(VF_SIZE);
 364         vf_min = R_SetView3fv(VF_MIN);
 365         vid_width = vf_size_x;
 366         vid_height = vf_size_y;
 367
 368         vector reticle_pos, reticle_size;
 369
 370         WaypointSprite_Load();
 371
 372         if(spectatee_status)
 373                 myteam = GetPlayerColor(spectatee_status - 1);
 374         else
 375                 myteam = GetPlayerColor(player_localentnum - 1);
 376
 377         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 378         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 379
 380         warpzone_fixview_origin = pmove_org + vo;
 381         warpzone_fixview_cl_viewangles = input_angles;
 382         warpzone_fixview_angles = view_angles;
 383         WarpZone_FixView();
 384         pmove_org = warpzone_fixview_origin - vo;
 385         input_angles = warpzone_fixview_cl_viewangles;
 386         view_angles = warpzone_fixview_angles;
 387
 388         if(cvar("cl_lockview") || (autocvar__hud_configure && spectatee_status <= 0))
 389         {
 390                 pmove_org = freeze_pmove_org;
 391                 input_angles = view_angles = freeze_input_angles;
 392                 R_SetView(VF_ORIGIN, pmove_org + vo);
 393                 R_SetView(VF_ANGLES, view_angles);
 394                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 395         }
 396         freeze_pmove_org = pmove_org;
 397         freeze_input_angles = input_angles;
 398
 399         // Render the Scene
 400         if(!intermission || !view_set)
 401         {
 402                 view_origin = pmove_org + vo;
 403                 view_angles = input_angles;
 404                 makevectors(view_angles);
 405                 view_forward = v_forward;
 406                 view_right = v_right;
 407                 view_up = v_up;
 408                 view_set = 1;
 409         }
 410
 411 #ifdef BLURTEST
 412         if(time > blurtest_time0 && time < blurtest_time1)
 413         {
 414                 float r, t;
 415
 416                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 417                 r = t * blurtest_radius;
 418                 f = 1 / pow(t, blurtest_power) - 1;
 419
 420                 cvar_set("r_glsl_postprocess", "1");
 421                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 422         }
 423         else
 424         {
 425                 cvar_set("r_glsl_postprocess", "0");
 426                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 427         }
 428 #endif
 429
 430         TargetMusic_Advance();
 431         Fog_Force();
 432
 433         drawframetime = max(0.000001, time - drawtime);
 434         drawtime = time;
 435
 436         // watch for gametype changes here...
 437         // in ParseStuffCMD the cmd isn't executed yet :/
 438         // might even be better to add the gametype to TE_CSQC_INIT...?
 439         if(!postinit)
 440                 PostInit();
 441
 442         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 443                 if(calledhooks & HOOK_START)
 444                 {
 445                         localcmd("\ncl_hook_gameend\n");
 446                         calledhooks |= HOOK_END;
 447                 }
 448
 449         CheckForGamestartChange();
 450         serverAnnouncer();
 451         maptimeAnnouncer();
 452         carrierAnnouncer();
 453
 454         fov = cvar("fov");
 455         if(button_zoom || fov <= 59.5)
 456         {
 457                 if(!zoomscript_caught)
 458                 {
 459                         localcmd("+button4\n");
 460                         zoomscript_caught = 1;
 461                         ignore_plus_zoom += 1;
 462                 }
 463         }
 464         else
 465         {
 466                 if(zoomscript_caught)
 467                 {
 468                         localcmd("-button4\n");
 469                         zoomscript_caught = 0;
 470                         ignore_minus_zoom += 1;
 471                 }
 472         }
 473
 474         ColorTranslateMode = cvar("cl_stripcolorcodes");
 475         activeweapon = getstati(STAT_SWITCHWEAPON);
 476         f = cvar("teamplay");
 477         if(f != teamplay)
 478         {
 479                 teamplay = f;
 480                 HUD_InitScores();
 481         }
 482
 483         if(last_weapon != activeweapon) {
 484                 weapontime = time;
 485                 last_weapon = activeweapon;
 486
 487                 e = get_weaponinfo(activeweapon);
 488                 if(e.netname != "")
 489                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 490                 else
 491                         localcmd("\ncl_hook_activeweapon none\n");
 492         }
 493
 494         // ALWAYS Clear Current Scene First
 495         R_ClearScene();
 496
 497         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 498         R_SetView(VF_SIZE, vf_size);
 499         R_SetView(VF_MIN, vf_min);
 500
 501         // Assign Standard Viewflags
 502         // Draw the World (and sky)
 503         R_SetView(VF_DRAWWORLD, 1);
 504
 505         // Set the console size vars
 506         vid_conwidth = cvar("vid_conwidth");
 507         vid_conheight = cvar("vid_conheight");
 508         vid_pixelheight = cvar("vid_pixelheight");
 509
 510         R_SetView(VF_FOV, GetCurrentFov(fov));
 511
 512         // Camera for demo playback
 513         if(camera_active)
 514         {
 515                 if(cvar("camera_enable"))
 516                         CSQC_Demo_Camera();
 517                 else
 518                 {
 519                         cvar_set("chase_active", ftos(chase_active_backup));
 520                         cvar_set("cl_demo_mousegrab", "0");
 521                         camera_active = FALSE;
 522                 }
 523         }
 524 #ifdef CAMERATEST
 525         else if(cvar("camera_enable"))
 526 #else
 527         else if(cvar("camera_enable") && isdemo())
 528 #endif
 529         {
 530                 // Enable required Darkplaces cvars
 531                 chase_active_backup = cvar("chase_active");
 532                 cvar_set("chase_active", "2");
 533                 cvar_set("cl_demo_mousegrab", "1");
 534                 camera_active = TRUE;
 535                 camera_mode = FALSE;
 536         }
 537
 538         // Draw the Crosshair
 539         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 540
 541         // Draw the Engine Status Bar (the default Quake HUD)
 542         R_SetView(VF_DRAWENGINEHUD, 0);
 543
 544         // fetch this one only once per frame
 545         hud_showbinds = cvar("hud_showbinds");
 546         hud_showbinds_limit = cvar("hud_showbinds_limit");
 547
 548         // Update the mouse position
 549         /*
 550            mousepos_x = vid_conwidth;
 551            mousepos_y = vid_conheight;
 552            mousepos = mousepos*0.5 + getmousepos();
 553          */
 554
 555         e = self;
 556         for(self = world; (self = nextent(self)); )
 557                 if(self.draw)
 558                         self.draw();
 559         self = e;
 560
 561         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 562         R_RenderScene();
 563
 564         // now switch to 2D drawing mode by calling a 2D drawing function
 565         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 566         // next R_RenderScene call
 567         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 568
 569         if(cvar("r_fakelight") >= 2 || cvar("r_fullbright") >= 1)
 570         {
 571                 // apply night vision effect
 572                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 573
 574                 if(!nightvision_noise)
 575                 {
 576                         nightvision_noise = spawn();
 577                         nightvision_noise.classname = "nightvision_noise";
 578                 }
 579                 if(!nightvision_noise2)
 580                 {
 581                         nightvision_noise2 = spawn();
 582                         nightvision_noise2.classname = "nightvision_noise2";
 583                 }
 584
 585                 // color tint in yellow
 586                 drawfill('0 0 0', cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 587
 588                 // draw BG
 589                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 590                 rgb = '1 1 1';
 591                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 592                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 593                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 594                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 595                 tc_11 = tc_01 + tc_10 - tc_00;
 596                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 597                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 598                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 599                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 600                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 601                 R_EndPolygon();
 602
 603                 // draw FG
 604                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 605                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 606                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 607                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 608                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 609                 tc_11 = tc_01 + tc_10 - tc_00;
 610                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 611                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 612                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 613                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 614                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 615                 R_EndPolygon();
 616         }
 617
 618         // Draw the aiming reticle for weapons that use it
 619         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 620         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 621         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 622         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 623                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 624         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_CAMPINGRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 625                 reticle_type = 2; // nex zoom
 626         else if(button_zoom || zoomscript_caught)
 627                 reticle_type = 1; // normal zoom
 628         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
 629                 reticle_type = 2; // nex zoom
 630
 631         if(cvar("cl_reticle_stretch"))
 632         {
 633                 reticle_size_x = vid_conwidth;
 634                 reticle_size_y = vid_conheight;
 635                 reticle_pos_x = 0;
 636                 reticle_pos_y = 0;
 637         }
 638         else
 639         {
 640                 reticle_size_x = max(vid_conwidth, vid_conheight);
 641                 reticle_size_y = max(vid_conwidth, vid_conheight);
 642                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 643                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 644         }
 645
 646         f = current_zoomfraction;
 647         if(zoomscript_caught)
 648                 f = 1;
 649         if(cvar("cl_reticle_item_normal"))
 650         {
 651                 precache_pic("gfx/reticle_normal");
 652                 if(reticle_type == 1 && f)
 653                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
 654         }
 655         if(cvar("cl_reticle_item_nex"))
 656         {
 657                 precache_pic("gfx/reticle_nex");
 658                 if(reticle_type == 2 && f)
 659                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
 660         }
 661
 662         // Draw the mouse cursor
 663         // NOTE: drawpic must happen after R_RenderScene for some reason
 664         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 665         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 666         //self = edict_num(player_localnum);
 667         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 668         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 669         // as long as the ctf part isn't in, this is useless
 670         if(menu_visible)
 671                 menu_show();
 672
 673         /*if(gametype == GAME_CTF)
 674           {
 675           ctf_view();
 676           } else */
 677
 678         // draw 2D entities
 679         e = self;
 680         for(self = world; (self = nextent(self)); )
 681                 if(self.draw2d)
 682                         self.draw2d();
 683         self = e;
 684
 685         scoreboard_active = HUD_WouldDrawScoreboard();
 686
 687         float hud;
 688         hud = getstati(STAT_HUD);
 689         if(hud == HUD_SPIDERBOT)
 690                 CSQC_SPIDER_HUD();
 691         else if(hud == HUD_WAKIZASHI)
 692         CSQC_WAKIZASHI_HUD();
 693     else if(hud == HUD_RAPTOR)
 694         CSQC_RAPTOR_HUD();
 695         else
 696         {
 697                 if(cvar("r_letterbox") == 0)
 698                         if(cvar("viewsize") < 120)
 699                                 CSQC_common_hud();
 700
 701                 // crosshair goes VERY LAST
 702                 if(!scoreboard_active && !camera_active && intermission != 2) {
 703                         string wcross_style;
 704                         float wcross_alpha, wcross_resolution;
 705                         wcross_style = cvar_string("crosshair");
 706                         if (wcross_style == "0")
 707                                 return;
 708                         wcross_resolution = cvar("crosshair_size");
 709                         if (wcross_resolution == 0)
 710                                 return;
 711                         wcross_alpha = cvar("crosshair_alpha");
 712                         if (wcross_alpha == 0)
 713                                 return;
 714
 715                         // TrueAim check
 716                         float shottype;
 717                         float bullets, ring_scale;
 718                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 719                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 720                         wcross_origin_z = 0;
 721                         if(cvar("crosshair_hittest"))
 722                         {
 723                                 vector wcross_oldorigin;
 724                                 wcross_oldorigin = wcross_origin;
 725                                 shottype = TrueAimCheck();
 726                                 if(shottype == SHOTTYPE_HITWORLD)
 727                                 {
 728                                         v = wcross_origin - wcross_oldorigin;
 729                                         v_x /= vid_conwidth;
 730                                         v_y /= vid_conheight;
 731                                         if(vlen(v) > 0.01)
 732                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 733                                 }
 734                                 if(!cvar("crosshair_hittest_showimpact"))
 735                                         wcross_origin = wcross_oldorigin;
 736                         }
 737                         else
 738                                 shottype = SHOTTYPE_HITWORLD;
 739
 740                         vector wcross_color, wcross_size;
 741                         string wcross_wep, wcross_name;
 742                         float wcross_scale, wcross_blur;
 743
 744                         wcross_color_x = cvar("crosshair_color_red");
 745                         wcross_color_y = cvar("crosshair_color_green");
 746                         wcross_color_z = cvar("crosshair_color_blue");
 747                         if (cvar("crosshair_per_weapon")) {
 748                                 e = get_weaponinfo(activeweapon);
 749                                 if (e && e.netname != "")
 750                                 {
 751                                         wcross_wep = e.netname;
 752                                         wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 753                                         if (wcross_resolution == 0)
 754                                                 return;
 755                                         wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 756                                         if (wcross_alpha == 0)
 757                                                 return;
 758
 759                                         wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 760                                         if(wcross_style == "")
 761                                                 wcross_style = e.netname;
 762
 763                                         if(!cvar("crosshair_color_override"))
 764                                         {
 765                                                 wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 766                                                 wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 767                                                 wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 768                                         }
 769                                 }
 770                         }
 771
 772                         wcross_name = strcat("gfx/crosshair", wcross_style);
 773
 774                         if(cvar("crosshair_effect_scalefade"))
 775                         {
 776                                 wcross_scale = wcross_resolution;
 777                                 wcross_resolution = 1;
 778                         }
 779                         else
 780                         {
 781                                 wcross_scale = 1;
 782                         }
 783
 784                         if(cvar("crosshair_pickup"))
 785                         {
 786                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
 787                                 {
 788                                         pickup_crosshair_size = 1;
 789                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
 790                                 }
 791
 792                                 if(pickup_crosshair_size > 0)
 793                                         pickup_crosshair_size -= cvar("crosshair_pickup_speed") * frametime;
 794                                 else
 795                                         pickup_crosshair_size = 0;
 796
 797                                 wcross_scale += sin(pickup_crosshair_size) * cvar("crosshair_pickup");
 798                         }
 799
 800                         if(shottype == SHOTTYPE_HITENEMY)
 801                                 wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 802                         if(shottype == SHOTTYPE_HITTEAM)
 803                                 wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 804
 805                         f = cvar("crosshair_effect_speed");
 806                         if(f < 0)
 807                                 f *= -2 * g_weaponswitchdelay;
 808                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 809                         {
 810                                 wcross_changedonetime = time + f;
 811                         }
 812                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 813                         {
 814                                 wcross_name_changestarttime = time;
 815                                 wcross_name_changedonetime = time + f;
 816                                 if(wcross_name_goal_prev_prev)
 817                                         strunzone(wcross_name_goal_prev_prev);
 818                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
 819                                 wcross_name_goal_prev = strzone(wcross_name);
 820                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 821                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 822                                 wcross_resolution_goal_prev = wcross_resolution;
 823                         }
 824
 825                         wcross_scale_goal_prev = wcross_scale;
 826                         wcross_alpha_goal_prev = wcross_alpha;
 827                         wcross_color_goal_prev = wcross_color;
 828
 829                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 830                         {
 831                                 wcross_blur = 1;
 832                                 wcross_alpha *= 0.75;
 833                         }
 834                         else
 835                                 wcross_blur = 0;
 836                         // *_prev is at time-frametime
 837                         // * is at wcross_changedonetime+f
 838                         // what do we have at time?
 839                         if(time < wcross_changedonetime)
 840                         {
 841                                 f = frametime / (wcross_changedonetime - time + frametime);
 842                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 843                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 844                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 845                         }
 846
 847                         wcross_scale_prev = wcross_scale;
 848                         wcross_alpha_prev = wcross_alpha;
 849                         wcross_color_prev = wcross_color;
 850
 851                         wcross_scale *= 1 - cvar("_menu_alpha");
 852                         wcross_alpha *= 1 - cvar("_menu_alpha");
 853
 854                         ring_scale = cvar("crosshair_ring_size");
 855
 856                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 857
 858                         float nex_charge;
 859                         nex_charge = getstatf(STAT_NEX_CHARGE);
 860
 861                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 862                                 nex_charge_movingavg = nex_charge;
 863
 864                         // ring around crosshair representing bullets left in camping rifle clip
 865                         if (activeweapon == WEP_CAMPINGRIFLE && cr_maxbullets)
 866                         {
 867                                 bullets = getstati(STAT_BULLETS_LOADED);
 868                                 f = bound(0, bullets / cr_maxbullets, 1);
 869
 870                                 a = cvar("crosshair_campingrifle_bulletcounter_alpha");
 871                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 872                         }
 873                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
 874                         {
 875                                 vector rgb;
 876                                 // indicate how much we're charging right now with an inner circle
 877                                 a = cvar("crosshair_nexvelocity_currentcharge_alpha");
 878                                 nex_charge_movingavg = (1 - cvar("crosshair_nexvelocity_currentcharge_movingavg_rate")) * nex_charge_movingavg + cvar("crosshair_nexvelocity_currentcharge_movingavg_rate") * nex_charge;
 879
 880                                 rgb = eX * cvar("crosshair_nexvelocity_currentcharge_color_red") + eY * cvar("crosshair_nexvelocity_currentcharge_color_green") + eZ * cvar("crosshair_nexvelocity_currentcharge_color_blue");
 881                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, cvar("crosshair_nexvelocity_currentcharge_scale") * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 882
 883                                 // draw the charge
 884                                 a = cvar("crosshair_nexvelocity_alpha");
 885                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 886                         }
 887
 888 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 889                         do \
 890                         { \
 891                                 if(wcross_blur > 0) \
 892                                 { \
 893                                         for(i = -2; i <= 2; ++i) \
 894                                                 for(j = -2; j <= 2; ++j) \
 895                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 896                                 } \
 897                                 else \
 898                                 { \
 899                                         M(0,0,sz,wcross_name,wcross_alpha); \
 900                                 } \
 901                         } \
 902                         while(0)
 903
 904 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 905                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 906
 907 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 908                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 909
 910                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 911                         {
 912                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 913                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 914                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 915                                 f = 1 - f;
 916                         }
 917                         else
 918                         {
 919                                 f = 1;
 920                         }
 921
 922                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 923                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 924
 925                         if(cvar("crosshair_dot"))
 926                                 CROSSHAIR_DRAW(wcross_resolution * cvar("crosshair_dot_size"), "gfx/crosshairdot.tga", wcross_alpha * f * cvar("crosshair_dot_alpha"));
 927
 928                         wcross_name_alpha_goal_prev = f;
 929                 }
 930                 else
 931                 {
 932                         wcross_scale_prev = 0;
 933                         wcross_alpha_prev = 0;
 934                         wcross_scale_goal_prev = 0;
 935                         wcross_alpha_goal_prev = 0;
 936                         wcross_changedonetime = 0;
 937                         if(wcross_name_goal_prev)
 938                                 strunzone(wcross_name_goal_prev);
 939                         wcross_name_goal_prev = string_null;
 940                         if(wcross_name_goal_prev_prev)
 941                                 strunzone(wcross_name_goal_prev_prev);
 942                         wcross_name_goal_prev_prev = string_null;
 943                         wcross_name_changestarttime = 0;
 944                         wcross_name_changedonetime = 0;
 945                         wcross_name_alpha_goal_prev = 0;
 946                         wcross_name_alpha_goal_prev_prev = 0;
 947                         wcross_resolution_goal_prev = 0;
 948                         wcross_resolution_goal_prev_prev = 0;
 949                 }
 950         }
 951
 952         if(NextFrameCommand)
 953         {
 954                 localcmd("\n", NextFrameCommand, "\n");
 955                 NextFrameCommand = string_null;
 956         }
 957
 958         // we must do this check AFTER a frame was rendered, or it won't work
 959         if(cs_project_is_b0rked == 0)
 960         {
 961                 string w0, h0;
 962                 w0 = cvar_string("vid_conwidth");
 963                 h0 = cvar_string("vid_conheight");
 964                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 965                 //R_SetView(VF_FOV, '90 90 0');
 966                 R_SetView(VF_ORIGIN, '0 0 0');
 967                 R_SetView(VF_ANGLES, '0 0 0');
 968                 R_SetView(VF_PERSPECTIVE, 1);
 969                 makevectors('0 0 0');
 970                 vector v1, v2;
 971                 cvar_set("vid_conwidth", "800");
 972                 cvar_set("vid_conheight", "600");
 973                 v1 = cs_project(v_forward);
 974                 cvar_set("vid_conwidth", "640");
 975                 cvar_set("vid_conheight", "480");
 976                 v2 = cs_project(v_forward);
 977                 if(v1 == v2)
 978                         cs_project_is_b0rked = 1;
 979                 else
 980                         cs_project_is_b0rked = -1;
 981                 cvar_set("vid_conwidth", w0);
 982                 cvar_set("vid_conheight", h0);
 983         }
 984
 985         if(autocvar__hud_configure)
 986                 HUD_Panel_Mouse();
 987
 988         // let's reset the view back to normal for the end
 989         R_SetView(VF_MIN, '0 0 0');
 990         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
 991 }
 992
 993 #define spider_h "gfx/vehicles/hud_bg.tga"
 994 #define spider_b "gfx/vehicles/sbot.tga"
 995 #define spider_r "gfx/vehicles/sbot_rpods.tga"
 996 #define spider_g "gfx/vehicles/sbot_mguns.tga"
 997 #define spider_s "gfx/vehicles/shiled.tga"
 998 #define spider_a1 "gfx/hud/sb_rocket.tga"
 999 #define spider_a2 "gfx/sb_bullets.tga"
1000
1001 void CSQC_SPIDER_HUD()
1002 {
1003         float rockets, reload, heat, hp, shield;
1004         vector picsize, hudloc;
1005
1006     // Fetch health & ammo stats
1007     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1008         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1009         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1010         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1011         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1012
1013     // Draw the crosshairs
1014     picsize = drawgetimagesize(SPIDER_CROSS);
1015     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1016     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1017     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1018
1019     hudloc_y =  4;
1020     hudloc_x = 4;
1021
1022     picsize = drawgetimagesize(spider_h) * 0.5;
1023     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1024
1025     picsize = drawgetimagesize(spider_a2) * 0.5;
1026     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1027
1028     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1029     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1030     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1031
1032     picsize = drawgetimagesize(spider_a1) * 0.85;
1033     if(rockets == 9)
1034     {
1035         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1036         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1037     }
1038     else
1039     {
1040         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1041         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1042     }
1043
1044     picsize = drawgetimagesize(spider_b) * 0.5;
1045     hudloc_y = 10.5;
1046     hudloc_x = 10.5;
1047
1048     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1049     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1050     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1051     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1052
1053
1054         /*
1055         // Draw health bar
1056         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1057         p = p + '0 1 0' * vid_conheight - '0 32 0';
1058         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1059         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1060         p_y += 8;
1061         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1062         p_x += 256 * hp;
1063         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1064
1065         // Draw minigun heat indicator
1066         p = '0.5 0 0' * (vid_conwidth - 256);
1067         p = p + '0 1 0' * vid_conheight - '0 34  0';
1068         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1069         p_x += 256 * (1-heat);
1070         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1071
1072
1073         // Draw rocket icons for loaded/empty tubes.
1074         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1075         pp += '0 1 0' * vid_conheight - '0 64 0';
1076         for(i = 0; i < 8; ++i)
1077         {
1078                 p = pp + '1 0 0' * (rkt_size * i);
1079                 if(rockets == 8)
1080                 {
1081                         if(floor(reload * 8) == i)
1082                         {
1083                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1084                         }
1085                         else if(i < reload * 8)
1086                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1087                         else
1088                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1089                 }
1090                 else
1091                 {
1092                         if(i < rockets)
1093                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1094                         else
1095                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1096                 }
1097         }
1098         */
1099
1100         if (scoreboard_showscores)
1101         {
1102                 HUD_DrawScoreboard();
1103                 HUD_DrawCenterPrint();
1104         }
1105
1106 }
1107
1108 #define raptor_h "gfx/vehicles/hud_bg.tga"
1109 #define raptor_b "gfx/vehicles/raptor.tga"
1110 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1111 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1112 #define raptor_s "gfx/vehicles/shiled.tga"
1113
1114 void CSQC_RAPTOR_HUD()
1115 {
1116         float reload, hp, shield, energy;
1117         vector picsize, hudloc;
1118
1119     // Fetch health & ammo stats
1120     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1121         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1122         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1123         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1124
1125     // Draw the crosshairs
1126     picsize = drawgetimagesize(SPIDER_CROSS);
1127     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1128     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1129     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1130
1131     hudloc_y =  4;
1132     hudloc_x = 4;
1133
1134     picsize = drawgetimagesize(raptor_h) * 0.5;
1135     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1136
1137     picsize = drawgetimagesize(spider_a2) * 0.5;
1138     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1139
1140     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1141     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1142     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1143
1144
1145     picsize = drawgetimagesize(spider_a1) * 0.85;
1146     if(reload == 1)
1147     {
1148         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1149         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1150     }
1151     else
1152     {
1153         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1154         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1155     }
1156
1157     picsize = drawgetimagesize(raptor_b) * 0.5;
1158     hudloc_y = 10.5;
1159     hudloc_x = 10.5;
1160
1161     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1162     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1163     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1164     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1165
1166
1167         if (scoreboard_showscores)
1168         {
1169                 HUD_DrawScoreboard();
1170                 HUD_DrawCenterPrint();
1171         }
1172
1173 }
1174
1175 #define waki_h "gfx/vehicles/hud_bg.tga"
1176 #define waki_b "gfx/vehicles/waki.tga"
1177 #define waki_e "gfx/vehicles/waki_e.tga"
1178 #define waki_g "gfx/vehicles/waki_guns.tga"
1179 #define waki_r "gfx/vehicles/waki_rockets.tga"
1180 #define waki_s "gfx/vehicles/shiled.tga"
1181
1182 #define waki_a1 "gfx/hud/sb_rocket.tga"
1183 #define waki_a2 "gfx/sb_cells.tga"
1184
1185 void CSQC_WAKIZASHI_HUD()
1186 {
1187         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1188         float health, shield, energy, rockets;
1189         vector picsize, hudloc;
1190
1191     picsize = drawgetimagesize(SPIDER_CROSS);
1192     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1193     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1194     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1195
1196 /*
1197 const float STAT_VEHICLESTAT_HEALTH  = 60;
1198 const float STAT_VEHICLESTAT_SHIELD  = 61;
1199 const float STAT_VEHICLESTAT_ENERGY  = 62;
1200 const float STAT_VEHICLESTAT_AMMO1   = 63;
1201 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1202 const float STAT_VEHICLESTAT_AMMO2   = 65;
1203 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1204 */
1205     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1206         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1207         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1208         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1209
1210     hudloc_y =  4;
1211     hudloc_x = 4;
1212
1213     picsize = drawgetimagesize(waki_h) * 0.5;
1214     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1215
1216     picsize = drawgetimagesize(waki_a2) * 0.7;
1217     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1218
1219
1220     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1221     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1222
1223     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1224
1225     picsize = drawgetimagesize(waki_a1) * 0.75;
1226     if(rockets == 1)
1227     {
1228         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1229         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1230     }
1231     else
1232     {
1233         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1234         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1235         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1236     }
1237
1238     picsize = drawgetimagesize(waki_b) * 0.5;
1239     hudloc_y = 10.5;
1240     hudloc_x = 10.5;
1241
1242     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1243     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1244     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1245     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1246
1247
1248
1249         /*
1250         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1251         p = p + '0 1 0' * vid_conheight - '0 32 0';
1252
1253         // Draw health bar
1254         p_y += 8;
1255         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1256         p_x += 256 * health;
1257         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1258
1259         // Draw shiled bar
1260         p_x -= 256 * health;
1261         p_y += 4;
1262         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1263
1264         // Draw energy
1265         //p_x -= 256 * health;
1266         p_y -= 8;
1267         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1268
1269         // Draw rockets bar
1270         p_y += 12;
1271         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1272         */
1273
1274
1275
1276
1277         if (scoreboard_showscores)
1278         {
1279                 HUD_DrawScoreboard();
1280                 HUD_DrawCenterPrint();
1281         }
1282
1283 }
1284
1285
1286 void CSQC_common_hud(void)
1287 {
1288         // HUD_SortFrags(); done in HUD_Draw
1289         float hud;
1290         hud = getstati(STAT_HUD);
1291
1292         //hud = 10;
1293         switch(hud)
1294         {
1295                 case HUD_NORMAL:
1296                         // do some accuracy var caching
1297                         float i;
1298                         if(cvar_string("hud_panel_weapons_accuracy_color_levels") != acc_color_levels)
1299                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1300                         {
1301                                 if(acc_color_levels)
1302                                         strunzone(acc_color_levels);
1303                                 acc_color_levels = strzone(cvar_string("hud_panel_weapons_accuracy_color_levels"));
1304                                 acc_levels = tokenize(acc_color_levels);
1305                                 if (acc_levels > MAX_ACCURACY_LEVELS)
1306                                         acc_levels = MAX_ACCURACY_LEVELS;
1307
1308                                 for (i = 0; i < acc_levels; ++i)
1309                                         acc_lev[i] = stof(argv(i));
1310                         }
1311
1312                         HUD_Main(); // always run these functions for alpha checks
1313                         HUD_DrawScoreboard();
1314
1315                         if (scoreboard_active) // scoreboard/accuracy
1316                         {
1317                                 HUD_Reset();
1318                                 // HUD_DrawScoreboard takes care of centerprint_start
1319                         }
1320                         else if (intermission == 2) // map voting screen
1321                         {
1322                                 HUD_FinaleOverlay();
1323                                 HUD_Reset();
1324
1325                                 centerprint_start_x = 0;
1326                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1327                         }
1328                         else // hud
1329                         {
1330                                 centerprint_start_x = 0;
1331                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1332                         }
1333
1334                         HUD_DrawCenterPrint();
1335                         break;
1336
1337                 case HUD_SPIDERBOT:
1338                         CSQC_SPIDER_HUD();
1339                         break;
1340
1341                 case HUD_WAKIZASHI:
1342                         CSQC_WAKIZASHI_HUD();
1343                         break;
1344         }
1345 }
1346
1347
1348 // following vectors must be global to allow seamless switching between camera modes
1349 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1350 void CSQC_Demo_Camera()
1351 {
1352         float speed, attenuation, dimensions;
1353         vector tmp, delta;
1354
1355         if( cvar("camera_reset") || !camera_mode )
1356         {
1357                 camera_offset = '0 0 0';
1358                 current_angles = '0 0 0';
1359                 camera_direction = '0 0 0';
1360                 camera_offset_z += 30;
1361                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1362                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1363                 current_origin = view_origin;
1364                 current_camera_offset  = camera_offset;
1365                 cvar_set("camera_reset", "0");
1366                 camera_mode = CAMERA_CHASE;
1367         }
1368
1369         // Camera angles
1370         if( camera_roll )
1371                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1372
1373         if(cvar("camera_look_player"))
1374         {
1375                 local vector dir;
1376                 local float n;
1377
1378                 dir = normalize(view_origin - current_position);
1379                 n = mouse_angles_z;
1380                 mouse_angles = vectoangles(dir);
1381                 mouse_angles_x = mouse_angles_x * -1;
1382                 mouse_angles_z = n;
1383         }
1384         else
1385         {
1386                 tmp = getmousepos() * 0.1;
1387                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1388                 {
1389                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1390                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1391                 }
1392         }
1393
1394         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1395         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1396         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1397         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1398
1399         // Fix difference when angles don't have the same sign
1400         delta = '0 0 0';
1401         if(mouse_angles_y < -60 && current_angles_y > 60)
1402                 delta = '0 360 0';
1403         if(mouse_angles_y > 60 && current_angles_y < -60)
1404                 delta = '0 -360 0';
1405
1406         if(cvar("camera_look_player"))
1407                 attenuation = cvar("camera_look_attenuation");
1408         else
1409                 attenuation = cvar("camera_speed_attenuation");
1410
1411         attenuation = 1 / max(1, attenuation);
1412         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1413
1414         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1415         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1416         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1417         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1418
1419         // Camera position
1420         tmp = '0 0 0';
1421         dimensions = 0;
1422
1423         if( camera_direction_x )
1424         {
1425                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1426                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1427                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1428                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1429                 ++dimensions;
1430         }
1431
1432         if( camera_direction_y )
1433         {
1434                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1435                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1436                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1437                 ++dimensions;
1438         }
1439
1440         if( camera_direction_z )
1441         {
1442                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1443                 ++dimensions;
1444         }
1445
1446         if(cvar("camera_free"))
1447                 speed = cvar("camera_speed_free");
1448         else
1449                 speed = cvar("camera_speed_chase");
1450
1451         if(dimensions)
1452         {
1453                 speed = speed * sqrt(1 / dimensions);
1454                 camera_offset += tmp * speed;
1455         }
1456
1457         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1458
1459         // Camera modes
1460         if( cvar("camera_free") )
1461         {
1462                 if ( camera_mode == CAMERA_CHASE )
1463                 {
1464                         current_camera_offset = current_origin + current_camera_offset;
1465                         camera_offset = current_origin + camera_offset;
1466                 }
1467
1468                 camera_mode = CAMERA_FREE;
1469                 current_position = current_camera_offset;
1470         }
1471         else
1472         {
1473                 if ( camera_mode == CAMERA_FREE )
1474                 {
1475                         current_origin = view_origin;
1476                         camera_offset = camera_offset - current_origin;
1477                         current_camera_offset = current_camera_offset - current_origin;
1478                 }
1479
1480                 camera_mode = CAMERA_CHASE;
1481
1482                 if(cvar("camera_chase_smoothly"))
1483                         current_origin += (view_origin - current_origin) * attenuation;
1484                 else
1485                         current_origin = view_origin;
1486
1487                 current_position = current_origin + current_camera_offset;
1488         }
1489
1490         R_SetView(VF_ANGLES, current_angles);
1491         R_SetView(VF_ORIGIN, current_position);
1492 }