qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 /**
  82  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  83  *
  84  * TODO: Use a better solution where a common shared entitiy is used that contains
  85  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  86  * and STAT_FRAGLIMIT to be auto-sent)
  87  */
  88 void CheckForGamestartChange() {
  89         float startTime;
  90         startTime = getstatf(STAT_GAMESTARTTIME);
  91         if (previous_game_starttime != startTime) {
  92                 if ((time + 5.0) < startTime) {
  93                         //if connecting to server while restart was active don't always play prepareforbattle
  94                         sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  95                 }
  96                 if (time < startTime) {
  97                         restartAnnouncer = spawn();
  98                         restartAnnouncer.think = restartAnnouncer_Think;
  99                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 100                 }
 101         }
 102         previous_game_starttime = startTime;
 103 }
 104
 105 void Porto_Init()
 106 {
 107         porto = spawn();
 108         porto.classname = "porto";
 109         porto.draw = Porto_Draw;
 110         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 111 }
 112
 113 float drawtime;
 114 float avgspeed;
 115 vector GetCurrentFov(float fov)
 116 {
 117         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 118
 119         zoomsensitivity = autocvar_cl_zoomsensitivity;
 120         zoomfactor = autocvar_cl_zoomfactor;
 121         if(zoomfactor < 1 || zoomfactor > 16)
 122                 zoomfactor = 2.5;
 123         zoomspeed = autocvar_cl_zoomspeed;
 124         if(zoomspeed >= 0)
 125                 if(zoomspeed < 0.5 || zoomspeed > 16)
 126                         zoomspeed = 3.5;
 127
 128         zoomdir = button_zoom;
 129         if(hud == HUD_NORMAL)
 130         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 131                 zoomdir += button_attack2;
 132         if(spectatee_status > 0 || isdemo())
 133         {
 134                 if(spectatorbutton_zoom)
 135                         zoomdir = 0 + !zoomdir;
 136                 // do not even THINK about removing this 0
 137                 // _I_ know what I am doing
 138                 // fteqcc does not
 139         }
 140
 141         if(zoomdir)
 142                 zoomin_effect = 0;
 143
 144         if(zoomin_effect || camera_active)
 145         {
 146                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 147         }
 148         else
 149         {
 150                 if(zoomspeed < 0) // instant zoom
 151                 {
 152                         if(zoomdir)
 153                                 current_viewzoom = 1 / zoomfactor;
 154                         else
 155                                 current_viewzoom = 1;
 156                 }
 157                 else
 158                 {
 159                         if(zoomdir)
 160                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 161                         else
 162                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 163                 }
 164         }
 165
 166         if(almost_equals(current_viewzoom, 1))
 167                 current_zoomfraction = 0;
 168         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 169                 current_zoomfraction = 1;
 170         else
 171                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 172
 173         if(zoomsensitivity < 1)
 174                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 175         else
 176                 setsensitivityscale(1);
 177
 178         if (autocvar_cl_velocityzoom)
 179         {
 180                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 181                 avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 182                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 183                 //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 184         }
 185         else
 186                 velocityzoom = 1;
 187
 188         float frustumx, frustumy, fovx, fovy;
 189         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 190         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 191         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 192         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 193
 194         return '1 0 0' * fovx + '0 1 0' * fovy;
 195 }
 196
 197 // this function must match W_SetupShot!
 198 float zoomscript_caught;
 199
 200 vector wcross_origin;
 201 float wcross_scale_prev, wcross_alpha_prev;
 202 vector wcross_color_prev;
 203 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 204 vector wcross_color_goal_prev;
 205 float wcross_changedonetime;
 206
 207 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 208 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 209 float wcross_name_changestarttime, wcross_name_changedonetime;
 210 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 211 entity trueaim;
 212 entity trueaim_rifle;
 213
 214 #define SHOTTYPE_HITTEAM 1
 215 #define SHOTTYPE_HITOBSTRUCTION 2
 216 #define SHOTTYPE_HITWORLD 3
 217 #define SHOTTYPE_HITENEMY 4
 218
 219 void TrueAim_Init()
 220 {
 221         trueaim = spawn();
 222         trueaim.classname = "trueaim";
 223         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 224         trueaim_rifle = spawn();
 225         trueaim_rifle.classname = "trueaim_rifle";
 226         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 227 }
 228
 229 float EnemyHitCheck()
 230 {
 231         float t;
 232         wcross_origin = project_3d_to_2d(trace_endpos);
 233         wcross_origin_z = 0;
 234         if(trace_networkentity < 1)
 235                 return SHOTTYPE_HITWORLD;
 236         if(trace_networkentity > maxclients)
 237                 return SHOTTYPE_HITWORLD;
 238         t = GetPlayerColor(trace_networkentity - 1);
 239         if(teamplay)
 240                 if(t == myteam)
 241                         return SHOTTYPE_HITTEAM;
 242         if(t == COLOR_SPECTATOR)
 243                 return SHOTTYPE_HITWORLD;
 244         return SHOTTYPE_HITENEMY;
 245 }
 246
 247 float TrueAimCheck()
 248 {
 249         float nudge = 1; // added to traceline target and subtracted from result
 250         vector vecs, trueaimpoint, w_shotorg;
 251         vector mi, ma, dv;
 252         float shottype;
 253         entity ta;
 254         float mv;
 255
 256         mi = ma = '0 0 0';
 257         ta = trueaim;
 258         mv = MOVE_NOMONSTERS;
 259
 260         switch(activeweapon)
 261         {
 262                 case WEP_TUBA: // no aim
 263                 case WEP_PORTO: // shoots from eye
 264                 case WEP_HOOK: // no trueaim
 265                 case WEP_GRENADE_LAUNCHER: // toss curve
 266                         return SHOTTYPE_HITWORLD;
 267                 case WEP_NEX:
 268                 case WEP_MINSTANEX:
 269                         mv = MOVE_NORMAL;
 270                         break;
 271                 case WEP_RIFLE:
 272                         ta = trueaim_rifle;
 273                         mv = MOVE_NORMAL;
 274                         if(zoomscript_caught)
 275                         {
 276                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 277                                 return EnemyHitCheck();
 278                         }
 279                         break;
 280                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 281                         mi = '-3 -3 -3';
 282                         ma = '3 3 3';
 283                         break;
 284                 case WEP_FIREBALL: // projectile has a size!
 285                         mi = '-16 -16 -16';
 286                         ma = '16 16 16';
 287                         break;
 288                 case WEP_SEEKER: // projectile has a size!
 289                         mi = '-2 -2 -2';
 290                         ma = '2 2 2';
 291                         break;
 292                 case WEP_ELECTRO: // projectile has a size!
 293                         mi = '0 0 -3';
 294                         ma = '0 0 -3';
 295                         break;
 296         }
 297
 298         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 299
 300         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 301         trueaimpoint = trace_endpos;
 302
 303         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 304                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 305
 306         if(vecs_x > 0)
 307                 vecs_y = -vecs_y;
 308         else
 309                 vecs = '0 0 0';
 310
 311         dv = view_right * vecs_y + view_up * vecs_z;
 312         w_shotorg = view_origin + dv;
 313
 314         // now move the vecs forward as much as requested if possible
 315         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 316         w_shotorg = trace_endpos - view_forward * nudge;
 317
 318         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 319         shottype = EnemyHitCheck();
 320         if(shottype != SHOTTYPE_HITWORLD)
 321                 return shottype;
 322
 323 #if 0
 324         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 325         // or rather, I know why, but see no fix
 326         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 327                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 328                 return SHOTTYPE_HITOBSTRUCTION;
 329 #endif
 330
 331         return SHOTTYPE_HITWORLD;
 332 }
 333
 334 void CSQC_common_hud(void);
 335
 336 void PostInit(void);
 337 void CSQC_Demo_Camera();
 338 float HUD_WouldDrawScoreboard();
 339 float camera_mode;
 340 float reticle_type;
 341 string NextFrameCommand;
 342 void CSQC_SPIDER_HUD();
 343 void CSQC_RAPTOR_HUD();
 344
 345 vector freeze_org, freeze_ang;
 346 entity nightvision_noise, nightvision_noise2;
 347
 348 float pickup_crosshair_time, pickup_crosshair_size;
 349 float hit_time, typehit_time;
 350 float nextsound_hit_time, nextsound_typehit_time;
 351 float hitindication_crosshair_time, hitindication_crosshair_size;
 352 float use_nex_chargepool;
 353
 354 float myhealth, myhealth_prev;
 355 float myhealth_flash;
 356
 357 float old_blurradius, old_bluralpha;
 358 float old_sharpen_intensity;
 359
 360 vector myhealth_gentlergb;
 361
 362 float contentavgalpha, liquidalpha_prev;
 363 vector liquidcolor_prev;
 364
 365 float eventchase_current_distance;
 366
 367 vector damage_blurpostprocess, content_blurpostprocess;
 368
 369 float checkfail[16];
 370
 371 void CSQC_UpdateView(float w, float h)
 372 {
 373         entity e;
 374         float fov;
 375         float f, i, j;
 376         vector v;
 377         vector vf_size, vf_min;
 378         float a;
 379         hud = getstati(STAT_HUD);
 380
 381         button_attack2 = (input_buttons & BUTTON_3);
 382         button_zoom = (input_buttons & BUTTON_4);
 383
 384 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 385         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 386         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 387         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 388         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 389         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 390         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 391
 392         vf_size = R_SetView3fv(VF_SIZE);
 393         vf_min = R_SetView3fv(VF_MIN);
 394         vid_width = vf_size_x;
 395         vid_height = vf_size_y;
 396
 397         vector reticle_pos, reticle_size;
 398         vector splash_pos, splash_size;
 399
 400         WaypointSprite_Load();
 401
 402         if(spectatee_status)
 403                 myteam = GetPlayerColor(spectatee_status - 1);
 404         else
 405                 myteam = GetPlayerColor(player_localentnum - 1);
 406
 407         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 408
 409         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 410         {
 411                 R_SetView(VF_ORIGIN, freeze_org);
 412                 R_SetView(VF_ANGLES, freeze_ang);
 413         }
 414         else
 415         {
 416                 freeze_org = R_SetView3fv(VF_ORIGIN);
 417                 freeze_ang = R_SetView3fv(VF_ANGLES);
 418         }
 419
 420         // event chase camera
 421         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 422         {
 423                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 424                 {
 425                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 426                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 427                         if(!autocvar_chase_active)
 428                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 429
 430                         // make the camera smooth back
 431                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 432                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 433                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 434                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 435
 436                         vector eventchase_target_origin;
 437                         makevectors(view_angles);
 438                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 439                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance;
 440
 441                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 442                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 443                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 444                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 445                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 446
 447                         R_SetView(VF_ORIGIN, trace_endpos);
 448                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 449                 }
 450                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 451                 {
 452                         cvar_set("chase_active", "0");
 453                         eventchase_current_distance = 0; // start from 0 next time
 454                 }
 455         }
 456
 457         WarpZone_FixView();
 458         //WarpZone_FixPMove();
 459
 460         // Render the Scene
 461         view_origin = R_SetView3fv(VF_ORIGIN);
 462         view_angles = R_SetView3fv(VF_ANGLES);
 463         makevectors(view_angles);
 464         view_forward = v_forward;
 465         view_right = v_right;
 466         view_up = v_up;
 467
 468 #ifdef BLURTEST
 469         if(time > blurtest_time0 && time < blurtest_time1)
 470         {
 471                 float r, t;
 472
 473                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 474                 r = t * blurtest_radius;
 475                 f = 1 / pow(t, blurtest_power) - 1;
 476
 477                 cvar_set("r_glsl_postprocess", "1");
 478                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 479         }
 480         else
 481         {
 482                 cvar_set("r_glsl_postprocess", "0");
 483                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 484         }
 485 #endif
 486
 487         TargetMusic_Advance();
 488         Fog_Force();
 489
 490         if(drawtime == 0)
 491                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 492         else
 493                 drawframetime = bound(0.000001, time - drawtime, 1);
 494         drawtime = time;
 495
 496         // watch for gametype changes here...
 497         // in ParseStuffCMD the cmd isn't executed yet :/
 498         // might even be better to add the gametype to TE_CSQC_INIT...?
 499         if(!postinit)
 500                 PostInit();
 501
 502         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 503                 if(calledhooks & HOOK_START)
 504                 {
 505                         localcmd("\ncl_hook_gameend\n");
 506                         calledhooks |= HOOK_END;
 507                 }
 508
 509         CheckForGamestartChange();
 510         serverAnnouncer();
 511         maptimeAnnouncer();
 512         carrierAnnouncer();
 513
 514         fov = autocvar_fov;
 515         if(fov <= 59.5)
 516         {
 517                 if(!zoomscript_caught)
 518                 {
 519                         localcmd("+button9\n");
 520                         zoomscript_caught = 1;
 521                 }
 522         }
 523         else
 524         {
 525                 if(zoomscript_caught)
 526                 {
 527                         localcmd("-button9\n");
 528                         zoomscript_caught = 0;
 529                 }
 530         }
 531
 532         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 533         activeweapon = getstati(STAT_SWITCHWEAPON);
 534         f = (serverflags & SERVERFLAG_TEAMPLAY);
 535         if(f != teamplay)
 536         {
 537                 teamplay = f;
 538                 HUD_InitScores();
 539         }
 540
 541         if(last_weapon != activeweapon) {
 542                 weapontime = time;
 543                 last_weapon = activeweapon;
 544
 545                 e = get_weaponinfo(activeweapon);
 546                 if(e.netname != "")
 547                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 548                 else
 549                         localcmd("\ncl_hook_activeweapon none\n");
 550         }
 551
 552         // ALWAYS Clear Current Scene First
 553         R_ClearScene();
 554 #ifdef WORKAROUND_XON010
 555         if(checkextension("DP_CSQC_ROTATEMOVES"))
 556         {
 557 #endif
 558         R_SetView(VF_ORIGIN, view_origin);
 559         R_SetView(VF_ANGLES, view_angles);
 560 #ifdef WORKAROUND_XON010
 561         }
 562 #endif
 563
 564         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 565         R_SetView(VF_SIZE, vf_size);
 566         R_SetView(VF_MIN, vf_min);
 567
 568         // Assign Standard Viewflags
 569         // Draw the World (and sky)
 570         R_SetView(VF_DRAWWORLD, 1);
 571
 572         // Set the console size vars
 573         vid_conwidth = autocvar_vid_conwidth;
 574         vid_conheight = autocvar_vid_conheight;
 575         vid_pixelheight = autocvar_vid_pixelheight;
 576
 577         R_SetView(VF_FOV, GetCurrentFov(fov));
 578
 579         // Camera for demo playback
 580         if(camera_active)
 581         {
 582                 if(autocvar_camera_enable)
 583                         CSQC_Demo_Camera();
 584                 else
 585                 {
 586                         cvar_set("chase_active", ftos(chase_active_backup));
 587                         cvar_set("cl_demo_mousegrab", "0");
 588                         camera_active = FALSE;
 589                 }
 590         }
 591 #ifdef CAMERATEST
 592         else if(autocvar_camera_enable)
 593 #else
 594         else if(autocvar_camera_enable && isdemo())
 595 #endif
 596         {
 597                 // Enable required Darkplaces cvars
 598                 chase_active_backup = autocvar_chase_active;
 599                 cvar_set("chase_active", "2");
 600                 cvar_set("cl_demo_mousegrab", "1");
 601                 camera_active = TRUE;
 602                 camera_mode = FALSE;
 603         }
 604
 605         // Draw the Crosshair
 606         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 607
 608         // Draw the Engine Status Bar (the default Quake HUD)
 609         R_SetView(VF_DRAWENGINEHUD, 0);
 610
 611         // Update the mouse position
 612         /*
 613            mousepos_x = vid_conwidth;
 614            mousepos_y = vid_conheight;
 615            mousepos = mousepos*0.5 + getmousepos();
 616          */
 617
 618         e = self;
 619         for(self = world; (self = nextent(self)); )
 620                 if(self.draw)
 621                         self.draw();
 622         self = e;
 623
 624         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 625         R_RenderScene();
 626
 627         // now switch to 2D drawing mode by calling a 2D drawing function
 628         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 629         // next R_RenderScene call
 630         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 631
 632         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 633         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 634         {
 635                 // apply night vision effect
 636                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 637
 638                 if(!nightvision_noise)
 639                 {
 640                         nightvision_noise = spawn();
 641                         nightvision_noise.classname = "nightvision_noise";
 642                 }
 643                 if(!nightvision_noise2)
 644                 {
 645                         nightvision_noise2 = spawn();
 646                         nightvision_noise2.classname = "nightvision_noise2";
 647                 }
 648
 649                 // color tint in yellow
 650                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 651
 652                 // draw BG
 653                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 654                 rgb = '1 1 1';
 655                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 656                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 657                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 658                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 659                 tc_11 = tc_01 + tc_10 - tc_00;
 660                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 661                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 662                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 663                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 664                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 665                 R_EndPolygon();
 666
 667                 // draw FG
 668                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 669                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 670                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 671                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 672                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 673                 tc_11 = tc_01 + tc_10 - tc_00;
 674                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 675                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 676                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 677                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 678                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 679                 R_EndPolygon();
 680         }
 681
 682         // Draw the aiming reticle for weapons that use it
 683         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 684         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 685         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 686         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 687                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 688         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 689                 reticle_type = 2; // nex zoom
 690         else if(button_zoom || zoomscript_caught)
 691                 reticle_type = 1; // normal zoom
 692         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 693                 reticle_type = 2; // nex zoom
 694
 695         if (reticle_type)
 696         {
 697                 if(autocvar_cl_reticle_stretch)
 698                 {
 699                         reticle_size_x = vid_conwidth;
 700                         reticle_size_y = vid_conheight;
 701                         reticle_pos_x = 0;
 702                         reticle_pos_y = 0;
 703                 }
 704                 else
 705                 {
 706                         reticle_size_x = max(vid_conwidth, vid_conheight);
 707                         reticle_size_y = max(vid_conwidth, vid_conheight);
 708                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 709                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 710                 }
 711
 712                 f = current_zoomfraction;
 713                 if(zoomscript_caught)
 714                         f = 1;
 715                 if(autocvar_cl_reticle_item_normal)
 716                 {
 717                         if(reticle_type == 1 && f)
 718                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 719                 }
 720                 if(autocvar_cl_reticle_item_nex)
 721                 {
 722                         if(reticle_type == 2 && f)
 723                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 724                 }
 725         }
 726
 727
 728         // improved polyblend
 729         vector rgb;
 730         if(autocvar_hud_contents)
 731         {
 732                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 733                 vector liquidcolor;
 734
 735                 switch(pointcontents(view_origin))
 736                 {
 737                         case CONTENT_WATER:
 738                                 liquidalpha = autocvar_hud_contents_water_alpha;
 739                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 740                                 incontent = 1;
 741                                 break;
 742
 743                         case CONTENT_LAVA:
 744                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 745                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 746                                 incontent = 1;
 747                                 break;
 748
 749                         case CONTENT_SLIME:
 750                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 751                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 752                                 incontent = 1;
 753                                 break;
 754
 755                         default:
 756                                 liquidalpha = 0;
 757                                 liquidcolor = '0 0 0';
 758                                 incontent = 0;
 759                                 break;
 760                 }
 761
 762                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 763                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 764                         contentfadetime = autocvar_hud_contents_fadeintime;
 765                         liquidalpha_prev = liquidalpha;
 766                         liquidcolor_prev = liquidcolor;
 767                 }
 768                 else
 769                         contentfadetime = autocvar_hud_contents_fadeouttime;
 770
 771                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 772                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 773
 774                 if(contentavgalpha)
 775                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 776
 777                 if(autocvar_hud_postprocessing)
 778                 {
 779                         if(autocvar_hud_contents_blur && contentavgalpha)
 780                         {
 781                                 content_blurpostprocess_x = 1;
 782                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 783                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 784                         }
 785                         else
 786                         {
 787                                 content_blurpostprocess_x = 0;
 788                                 content_blurpostprocess_y = 0;
 789                                 content_blurpostprocess_z = 0;
 790                         }
 791                 }
 792         }
 793
 794         if(autocvar_hud_damage && !autocvar_chase_active)
 795
 796         {
 797                 splash_size_x = max(vid_conwidth, vid_conheight);
 798                 splash_size_y = max(vid_conwidth, vid_conheight);
 799                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 800                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 801
 802                 float myhealth_flash_temp;
 803                 myhealth = getstati(STAT_HEALTH);
 804
 805                 // fade out
 806                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 807                 // add new damage
 808                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 809
 810                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 811                 pain_threshold = autocvar_hud_damage_pain_threshold;
 812                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 813                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 814
 815                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 816                 {
 817                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 818                 }
 819
 820                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 821
 822                 if(myhealth_prev < 1)
 823                 {
 824                         if(myhealth >= 1)
 825                         {
 826                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 827                                 myhealth_flash_temp = 0;
 828                         }
 829                         else
 830                         {
 831                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 832                         }
 833                 }
 834
 835                 if(spectatee_status == -1 || intermission)
 836                 {
 837                         myhealth_flash = 0; // observing, or match ended
 838                         myhealth_flash_temp = 0;
 839                 }
 840
 841                 myhealth_prev = myhealth;
 842
 843                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 844                 {
 845                         if(autocvar_cl_gentle_damage == 2)
 846                         {
 847                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 848                                 {
 849                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 850                                 }
 851                         }
 852                         else
 853                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 854
 855                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 856                 }
 857                 else
 858                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 859
 860                 if(autocvar_hud_postprocessing)
 861                 {
 862                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 863                         {
 864                                 damage_blurpostprocess_x = 1;
 865                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 866                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 867                         }
 868                         else
 869                         {
 870                                 damage_blurpostprocess_x = 0;
 871                                 damage_blurpostprocess_y = 0;
 872                                 damage_blurpostprocess_z = 0;
 873                         }
 874                 }
 875         }
 876
 877         if(autocvar_hud_postprocessing)
 878         {
 879                 // all of this should be done in the engine eventually
 880
 881                 // enable or disable rendering types if they are used or not
 882                 if(cvar("r_glsl_postprocess_uservec1_enable") != (cvar("hud_postprocessing_maxbluralpha") != 0))
 883                         cvar_set("r_glsl_postprocess_uservec1_enable", ftos(cvar("hud_postprocessing_maxbluralpha") != 0));
 884                 if(cvar("r_glsl_postprocess_uservec2_enable") != (cvar("hud_powerup") != 0))
 885                         cvar_set("r_glsl_postprocess_uservec2_enable", ftos(cvar("hud_powerup") != 0));
 886
 887                 // lets apply the postprocess effects from the previous two functions if needed
 888                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 889                 {
 890                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 891                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 892                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 893                         {
 894                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 895                                 old_blurradius = blurradius;
 896                                 old_bluralpha = bluralpha;
 897                         }
 898                 }
 899                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 900                 {
 901                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 902                         old_blurradius = 0;
 903                         old_bluralpha = 0;
 904                 }
 905
 906                 float sharpen_intensity;
 907                 if (getstatf(STAT_STRENGTH_FINISHED) - time > 0)
 908                         sharpen_intensity += (getstatf(STAT_STRENGTH_FINISHED) - time);
 909                 if (getstatf(STAT_INVINCIBLE_FINISHED) - time > 0)
 910                         sharpen_intensity += (getstatf(STAT_INVINCIBLE_FINISHED) - time);
 911
 912                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 913                 {
 914                         sharpen_intensity = bound(0, sharpen_intensity, 5); // powerup warning time is 5 seconds, so fade the effect from there
 915
 916                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 917                         {
 918                                 cvar_set("r_glsl_postprocess_uservec2", strcat("0 ", ftos(-sharpen_intensity * cvar("hud_powerup")), " 0 0"));
 919                                 old_sharpen_intensity = sharpen_intensity;
 920                         }
 921                 }
 922                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 923                 {
 924                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 925                         old_sharpen_intensity = 0;
 926                 }
 927         }
 928
 929         if(menu_visible)
 930                 menu_show();
 931
 932         /*if(gametype == GAME_CTF)
 933           {
 934           ctf_view();
 935           } else */
 936
 937         // draw 2D entities
 938         e = self;
 939         for(self = world; (self = nextent(self)); )
 940                 if(self.draw2d)
 941                         self.draw2d();
 942         self = e;
 943         Draw_ShowNames_All();
 944
 945         scoreboard_active = HUD_WouldDrawScoreboard();
 946
 947         hit_time = getstatf(STAT_HIT_TIME);
 948         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 949         {
 950                 sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 951                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 952         }
 953         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 954         if(typehit_time > nextsound_typehit_time)
 955         {
 956                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 957                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 958         }
 959
 960         //else
 961         {
 962                 if(gametype == GAME_FREEZETAG)
 963                 {
 964                         if(getstati(STAT_FROZEN))
 965                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 966                         if(getstatf(STAT_REVIVE_PROGRESS))
 967                         {
 968                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 969                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 970                         }
 971                 }
 972
 973                 if(autocvar_r_letterbox == 0)
 974                         if(autocvar_viewsize < 120)
 975                                 CSQC_common_hud();
 976
 977                 // crosshair goes VERY LAST
 978                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
 979                         string wcross_style;
 980                         float wcross_alpha, wcross_resolution;
 981                         wcross_style = autocvar_crosshair;
 982                         if (wcross_style == "0")
 983                                 return;
 984                         wcross_resolution = autocvar_crosshair_size;
 985                         if (wcross_resolution == 0)
 986                                 return;
 987                         wcross_alpha = autocvar_crosshair_alpha;
 988                         if (wcross_alpha == 0)
 989                                 return;
 990
 991                         // TrueAim check
 992                         float shottype;
 993
 994                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 995                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 996                         wcross_origin_z = 0;
 997                         if(autocvar_crosshair_hittest)
 998                         {
 999                                 vector wcross_oldorigin;
1000                                 wcross_oldorigin = wcross_origin;
1001                                 shottype = TrueAimCheck();
1002                                 if(shottype == SHOTTYPE_HITWORLD)
1003                                 {
1004                                         v = wcross_origin - wcross_oldorigin;
1005                                         v_x /= vid_conwidth;
1006                                         v_y /= vid_conheight;
1007                                         if(vlen(v) > 0.01)
1008                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1009                                 }
1010                                 if(!autocvar_crosshair_hittest_showimpact)
1011                                         wcross_origin = wcross_oldorigin;
1012                         }
1013                         else
1014                                 shottype = SHOTTYPE_HITWORLD;
1015
1016                         vector wcross_color, wcross_size;
1017                         string wcross_wep, wcross_name;
1018                         float wcross_scale, wcross_blur;
1019
1020                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1021                                 e = get_weaponinfo(activeweapon);
1022                                 if (e && e.netname != "")
1023                                 {
1024                                         wcross_wep = e.netname;
1025                                         if(autocvar_crosshair_per_weapon)
1026                                         {
1027                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1028                                                 if (wcross_resolution == 0)
1029                                                         return;
1030                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1031                                                 if (wcross_alpha == 0)
1032                                                         return;
1033
1034                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1035                                                 if(wcross_style == "" || wcross_style == "0")
1036                                                         wcross_style = wcross_wep;
1037                                         }
1038                                 }
1039                         }
1040                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1041                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1042                         else if(autocvar_crosshair_color_by_health)
1043                         {
1044                                 local float x = getstati(STAT_HEALTH);
1045
1046                                 //x = red
1047                                 //y = green
1048                                 //z = blue
1049
1050                                 wcross_color_z = 0;
1051
1052                                 if(x > 200)
1053                                 {
1054                                         wcross_color_x = 0;
1055                                         wcross_color_y = 1;
1056                                 }
1057                                 else if(x > 150)
1058                                 {
1059                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1060                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1061                                 }
1062                                 else if(x > 100)
1063                                 {
1064                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1065                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1066                                         wcross_color_z = 1 - (x-100)*0.02;
1067                                 }
1068                                 else if(x > 50)
1069                                 {
1070                                         wcross_color_x = 1;
1071                                         wcross_color_y = 1;
1072                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1073                                 }
1074                                 else if(x > 20)
1075                                 {
1076                                         wcross_color_x = 1;
1077                                         wcross_color_y = (x-20)*90/27/100;
1078                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1079                                 }
1080                                 else
1081                                 {
1082                                         wcross_color_x = 1;
1083                                         wcross_color_y = 0;
1084                                 }
1085                         }
1086                         else
1087                                 wcross_color = stov(autocvar_crosshair_color);
1088
1089                         wcross_name = strcat("gfx/crosshair", wcross_style);
1090
1091                         if(autocvar_crosshair_effect_scalefade)
1092                         {
1093                                 wcross_scale = wcross_resolution;
1094                                 wcross_resolution = 1;
1095                         }
1096                         else
1097                         {
1098                                 wcross_scale = 1;
1099                         }
1100
1101                         if(autocvar_crosshair_pickup)
1102                         {
1103                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1104                                 {
1105                                         pickup_crosshair_size = 1;
1106                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1107                                 }
1108
1109                                 if(pickup_crosshair_size > 0)
1110                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1111                                 else
1112                                         pickup_crosshair_size = 0;
1113
1114                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1115                         }
1116
1117                         vector hitindication_color;
1118                         if(autocvar_crosshair_hitindication)
1119                         {
1120                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1121                                 if(hitindication_crosshair_time < hit_time)
1122                                 {
1123                                         hitindication_crosshair_size = 1;
1124                                         hitindication_crosshair_time = hit_time;
1125                                 }
1126
1127                                 if(hitindication_crosshair_size > 0)
1128                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1129                                 else
1130                                         hitindication_crosshair_size = 0;
1131
1132                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1133                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1134                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1135                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1136                         }
1137
1138                         if(shottype == SHOTTYPE_HITENEMY)
1139                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1140                         if(shottype == SHOTTYPE_HITTEAM)
1141                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1142
1143                         f = autocvar_crosshair_effect_speed;
1144                         if(f < 0)
1145                                 f *= -2 * g_weaponswitchdelay;
1146                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1147                         {
1148                                 wcross_changedonetime = time + f;
1149                         }
1150                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1151                         {
1152                                 wcross_name_changestarttime = time;
1153                                 wcross_name_changedonetime = time + f;
1154                                 if(wcross_name_goal_prev_prev)
1155                                         strunzone(wcross_name_goal_prev_prev);
1156                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1157                                 wcross_name_goal_prev = strzone(wcross_name);
1158                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1159                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1160                                 wcross_resolution_goal_prev = wcross_resolution;
1161                         }
1162
1163                         wcross_scale_goal_prev = wcross_scale;
1164                         wcross_alpha_goal_prev = wcross_alpha;
1165                         wcross_color_goal_prev = wcross_color;
1166
1167                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1168                         {
1169                                 wcross_blur = 1;
1170                                 wcross_alpha *= 0.75;
1171                         }
1172                         else
1173                                 wcross_blur = 0;
1174                         // *_prev is at time-frametime
1175                         // * is at wcross_changedonetime+f
1176                         // what do we have at time?
1177                         if(time < wcross_changedonetime)
1178                         {
1179                                 f = frametime / (wcross_changedonetime - time + frametime);
1180                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1181                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1182                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1183                         }
1184
1185                         wcross_scale_prev = wcross_scale;
1186                         wcross_alpha_prev = wcross_alpha;
1187                         wcross_color_prev = wcross_color;
1188
1189                         wcross_scale *= 1 - autocvar__menu_alpha;
1190                         wcross_alpha *= 1 - autocvar__menu_alpha;
1191                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1192
1193                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1194                         {
1195                                 // crosshair rings for weapon stats
1196                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1197                                 {
1198                                         // declarations and stats
1199                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1200                                         string ring_image, ring_inner_image;
1201                                         vector ring_rgb, ring_inner_rgb;
1202
1203                                         ring_scale = autocvar_crosshair_ring_size;
1204
1205                                         float weapon_clipload, weapon_clipsize;
1206                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1207                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1208
1209                                         float nex_charge, nex_chargepool;
1210                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1211                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1212
1213                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1214                                                 nex_charge_movingavg = nex_charge;
1215
1216
1217                                         // handle the values
1218                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1219                                         {
1220                                                 if (nex_chargepool || use_nex_chargepool) {
1221                                                         use_nex_chargepool = 1;
1222                                                         ring_inner_value = nex_chargepool;
1223                                                 } else {
1224                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1225                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1226                                                 }
1227
1228                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1229                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1230                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1231
1232                                                 // draw the outer ring to show the current charge of the weapon
1233                                                 ring_value = nex_charge;
1234                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1235                                                 ring_rgb = wcross_color;
1236                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1237                                         }
1238                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1239                                         {
1240                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1241                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1242                                                 ring_rgb = wcross_color;
1243                                                 ring_image = "gfx/crosshair_ring.tga";
1244                                         }
1245                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1246                                         {
1247                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1248                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1249                                                 ring_rgb = wcross_color;
1250                                                 ring_image = "gfx/crosshair_ring.tga";
1251                                         }
1252
1253                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1254                                         {
1255                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1256                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1257                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1258                                                 ring_rgb = wcross_color;
1259
1260                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1261                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1262                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1263                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1264                                                 else
1265                                                         ring_image = "gfx/crosshair_ring.tga";
1266                                         }
1267
1268                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1269                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1270
1271                                         if (ring_value)
1272                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1273                                 }
1274
1275 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1276                                 do \
1277                                 { \
1278                                         if(wcross_blur > 0) \
1279                                         { \
1280                                                 for(i = -2; i <= 2; ++i) \
1281                                                 for(j = -2; j <= 2; ++j) \
1282                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1283                                         } \
1284                                         else \
1285                                         { \
1286                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1287                                         } \
1288                                 } \
1289                                 while(0)
1290
1291 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1292                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1293
1294 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1295                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1296
1297                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1298                                 {
1299                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1300                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1301                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1302                                         f = 1 - f;
1303                                 }
1304                                 else
1305                                 {
1306                                         f = 1;
1307                                 }
1308                                 wcross_name_alpha_goal_prev = f;
1309
1310                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1311                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1312
1313                                 if(autocvar_crosshair_dot)
1314                                 {
1315                                         vector wcross_color_old;
1316                                         wcross_color_old = wcross_color;
1317                                         if(autocvar_crosshair_dot_color != "0")
1318                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1319                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1320                                         // FIXME why don't we use wcross_alpha here?
1321                                         wcross_color = wcross_color_old;
1322                                 }
1323                         }
1324                 }
1325                 else
1326                 {
1327                         wcross_scale_prev = 0;
1328                         wcross_alpha_prev = 0;
1329                         wcross_scale_goal_prev = 0;
1330                         wcross_alpha_goal_prev = 0;
1331                         wcross_changedonetime = 0;
1332                         if(wcross_name_goal_prev)
1333                                 strunzone(wcross_name_goal_prev);
1334                         wcross_name_goal_prev = string_null;
1335                         if(wcross_name_goal_prev_prev)
1336                                 strunzone(wcross_name_goal_prev_prev);
1337                         wcross_name_goal_prev_prev = string_null;
1338                         wcross_name_changestarttime = 0;
1339                         wcross_name_changedonetime = 0;
1340                         wcross_name_alpha_goal_prev = 0;
1341                         wcross_name_alpha_goal_prev_prev = 0;
1342                         wcross_resolution_goal_prev = 0;
1343                         wcross_resolution_goal_prev_prev = 0;
1344                 }
1345         }
1346
1347         if(NextFrameCommand)
1348         {
1349                 localcmd("\n", NextFrameCommand, "\n");
1350                 NextFrameCommand = string_null;
1351         }
1352
1353         // we must do this check AFTER a frame was rendered, or it won't work
1354         if(cs_project_is_b0rked == 0)
1355         {
1356                 string w0, h0;
1357                 w0 = ftos(autocvar_vid_conwidth);
1358                 h0 = ftos(autocvar_vid_conheight);
1359                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1360                 //R_SetView(VF_FOV, '90 90 0');
1361                 R_SetView(VF_ORIGIN, '0 0 0');
1362                 R_SetView(VF_ANGLES, '0 0 0');
1363                 R_SetView(VF_PERSPECTIVE, 1);
1364                 makevectors('0 0 0');
1365                 vector v1, v2;
1366                 cvar_set("vid_conwidth", "800");
1367                 cvar_set("vid_conheight", "600");
1368                 v1 = cs_project(v_forward);
1369                 cvar_set("vid_conwidth", "640");
1370                 cvar_set("vid_conheight", "480");
1371                 v2 = cs_project(v_forward);
1372                 if(v1 == v2)
1373                         cs_project_is_b0rked = 1;
1374                 else
1375                         cs_project_is_b0rked = -1;
1376                 cvar_set("vid_conwidth", w0);
1377                 cvar_set("vid_conheight", h0);
1378         }
1379
1380         if(autocvar__hud_configure)
1381                 HUD_Panel_Mouse();
1382
1383     if(hud && !intermission)
1384     {
1385         if(hud == HUD_SPIDERBOT)
1386             CSQC_SPIDER_HUD();
1387         else if(hud == HUD_WAKIZASHI)
1388             CSQC_WAKIZASHI_HUD();
1389         else if(hud == HUD_RAPTOR)
1390             CSQC_RAPTOR_HUD();
1391         else if(hud == HUD_BUMBLEBEE)
1392             CSQC_BUMBLE_HUD();
1393     }
1394         // let's reset the view back to normal for the end
1395         R_SetView(VF_MIN, '0 0 0');
1396         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1397 }
1398
1399
1400 void CSQC_common_hud(void)
1401 {
1402     // do some accuracy var caching
1403     float i;
1404     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1405     {
1406         if(autocvar_accuracy_color_levels != acc_color_levels)
1407         {
1408             if(acc_color_levels)
1409                 strunzone(acc_color_levels);
1410             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1411             acc_levels = tokenize(acc_color_levels);
1412             if (acc_levels > MAX_ACCURACY_LEVELS)
1413                 acc_levels = MAX_ACCURACY_LEVELS;
1414
1415             for (i = 0; i < acc_levels; ++i)
1416                 acc_lev[i] = stof(argv(i)) / 100.0;
1417         }
1418         // let know that acc_col[] needs to be loaded
1419         acc_col_x[0] = -1;
1420     }
1421
1422     HUD_Main(); // always run these functions for alpha checks
1423     HUD_DrawScoreboard();
1424
1425     if (scoreboard_active) // scoreboard/accuracy
1426     {
1427         HUD_Reset();
1428         // HUD_DrawScoreboard takes care of centerprint_start
1429     }
1430     else if (intermission == 2) // map voting screen
1431     {
1432         HUD_FinaleOverlay();
1433         HUD_Reset();
1434
1435         centerprint_start_x = 0;
1436         centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1437     }
1438     else // hud
1439     {
1440         centerprint_start_x = 0;
1441         centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1442     }
1443
1444         /*
1445         switch(hud)
1446         {
1447                 case HUD_SPIDERBOT:
1448                         CSQC_SPIDER_HUD();
1449                         break;
1450
1451                 case HUD_WAKIZASHI:
1452                         CSQC_WAKIZASHI_HUD();
1453                         break;
1454
1455         case HUD_BUMBLEBEE:
1456             CSQC_BUMBLE_HUD();
1457             break;
1458         }
1459         */
1460
1461     HUD_DrawCenterPrint();
1462
1463 }
1464
1465
1466 // following vectors must be global to allow seamless switching between camera modes
1467 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1468 void CSQC_Demo_Camera()
1469 {
1470         float speed, attenuation, dimensions;
1471         vector tmp, delta;
1472
1473         if( autocvar_camera_reset || !camera_mode )
1474         {
1475                 camera_offset = '0 0 0';
1476                 current_angles = '0 0 0';
1477                 camera_direction = '0 0 0';
1478                 camera_offset_z += 30;
1479                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1480                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1481                 current_origin = view_origin;
1482                 current_camera_offset  = camera_offset;
1483                 cvar_set("camera_reset", "0");
1484                 camera_mode = CAMERA_CHASE;
1485         }
1486
1487         // Camera angles
1488         if( camera_roll )
1489                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1490
1491         if(autocvar_camera_look_player)
1492         {
1493                 local vector dir;
1494                 local float n;
1495
1496                 dir = normalize(view_origin - current_position);
1497                 n = mouse_angles_z;
1498                 mouse_angles = vectoangles(dir);
1499                 mouse_angles_x = mouse_angles_x * -1;
1500                 mouse_angles_z = n;
1501         }
1502         else
1503         {
1504                 tmp = getmousepos() * 0.1;
1505                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1506                 {
1507                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1508                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1509                 }
1510         }
1511
1512         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1513         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1514         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1515         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1516
1517         // Fix difference when angles don't have the same sign
1518         delta = '0 0 0';
1519         if(mouse_angles_y < -60 && current_angles_y > 60)
1520                 delta = '0 360 0';
1521         if(mouse_angles_y > 60 && current_angles_y < -60)
1522                 delta = '0 -360 0';
1523
1524         if(autocvar_camera_look_player)
1525                 attenuation = autocvar_camera_look_attenuation;
1526         else
1527                 attenuation = autocvar_camera_speed_attenuation;
1528
1529         attenuation = 1 / max(1, attenuation);
1530         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1531
1532         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1533         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1534         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1535         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1536
1537         // Camera position
1538         tmp = '0 0 0';
1539         dimensions = 0;
1540
1541         if( camera_direction_x )
1542         {
1543                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1544                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1545                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1546                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1547                 ++dimensions;
1548         }
1549
1550         if( camera_direction_y )
1551         {
1552                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1553                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1554                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1555                 ++dimensions;
1556         }
1557
1558         if( camera_direction_z )
1559         {
1560                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1561                 ++dimensions;
1562         }
1563
1564         if(autocvar_camera_free)
1565                 speed = autocvar_camera_speed_free;
1566         else
1567                 speed = autocvar_camera_speed_chase;
1568
1569         if(dimensions)
1570         {
1571                 speed = speed * sqrt(1 / dimensions);
1572                 camera_offset += tmp * speed;
1573         }
1574
1575         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1576
1577         // Camera modes
1578         if( autocvar_camera_free )
1579         {
1580                 if ( camera_mode == CAMERA_CHASE )
1581                 {
1582                         current_camera_offset = current_origin + current_camera_offset;
1583                         camera_offset = current_origin + camera_offset;
1584                 }
1585
1586                 camera_mode = CAMERA_FREE;
1587                 current_position = current_camera_offset;
1588         }
1589         else
1590         {
1591                 if ( camera_mode == CAMERA_FREE )
1592                 {
1593                         current_origin = view_origin;
1594                         camera_offset = camera_offset - current_origin;
1595                         current_camera_offset = current_camera_offset - current_origin;
1596                 }
1597
1598                 camera_mode = CAMERA_CHASE;
1599
1600                 if(autocvar_camera_chase_smoothly)
1601                         current_origin += (view_origin - current_origin) * attenuation;
1602                 else
1603                         current_origin = view_origin;
1604
1605                 current_position = current_origin + current_camera_offset;
1606         }
1607
1608         R_SetView(VF_ANGLES, current_angles);
1609         R_SetView(VF_ORIGIN, current_position);
1610 }