qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon)
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_GRENADE_LAUNCHER: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_NEX:
 291                 case WEP_MINSTANEX:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string NextFrameCommand;
 369
 370 vector freeze_org, freeze_ang;
 371 entity nightvision_noise, nightvision_noise2;
 372
 373 #define MAX_TIME_DIFF 5
 374 float pickup_crosshair_time, pickup_crosshair_size;
 375 float hitsound_time_prev;
 376 float spectatee_status_prev; // for preventing hitsound when switching spectatee
 377 float damage_dealt_total, damage_dealt_total_prev;
 378 float typehit_time, typehit_time_prev;
 379 float hitindication_crosshair_size;
 380 float use_nex_chargepool;
 381
 382 float myhealth, myhealth_prev;
 383 float myhealth_flash;
 384
 385 float old_blurradius, old_bluralpha;
 386 float old_sharpen_intensity;
 387
 388 vector myhealth_gentlergb;
 389
 390 float contentavgalpha, liquidalpha_prev;
 391 vector liquidcolor_prev;
 392
 393 float eventchase_current_distance;
 394
 395 vector damage_blurpostprocess, content_blurpostprocess;
 396
 397 float checkfail[16];
 398
 399 float rainbow_last_flicker;
 400 vector rainbow_prev_color;
 401
 402 #define BUTTON_3 4
 403 #define BUTTON_4 8
 404 float cl_notice_run();
 405 float prev_myteam;
 406 void CSQC_UpdateView(float w, float h)
 407 {
 408         entity e;
 409         float fov;
 410         float f, i, j;
 411         vector v;
 412         vector vf_size, vf_min;
 413         float a;
 414
 415         execute_next_frame();
 416
 417         ++framecount;
 418
 419         hud = getstati(STAT_HUD);
 420
 421         if(autocvar__hud_showbinds_reload) // menu can set this one
 422         {
 423                 db_close(binddb);
 424                 binddb = db_create();
 425                 cvar_set("_hud_showbinds_reload", "0");
 426         }
 427
 428         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 429                 view_quality = getproperty(VF_MINFPS_QUALITY);
 430         else
 431                 view_quality = 1;
 432
 433         button_attack2 = (input_buttons & BUTTON_3);
 434         button_zoom = (input_buttons & BUTTON_4);
 435
 436 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 437         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 438         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 439         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 440         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 441         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 442         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 443         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 444
 445         vf_size = getpropertyvec(VF_SIZE);
 446         vf_min = getpropertyvec(VF_MIN);
 447         vid_width = vf_size_x;
 448         vid_height = vf_size_y;
 449
 450         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 451         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 452
 453         WaypointSprite_Load();
 454
 455         CSQCPlayer_SetCamera();
 456
 457 #ifdef COMPAT_XON050_ENGINE
 458         if(spectatee_status)
 459                 myteam = GetPlayerColor(spectatee_status - 1);
 460         else
 461 #endif
 462                 myteam = GetPlayerColor(player_localentnum - 1);
 463
 464         if(myteam != prev_myteam)
 465         {
 466                 myteamcolors = colormapPaletteColor(myteam, 1);
 467                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 468                         hud_panel[i].update_time = time;
 469                 prev_myteam = myteam;
 470         }
 471
 472         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 473
 474         float is_dead = (getstati(STAT_HEALTH) <= 0);
 475
 476         // FIXME do we need this hack?
 477         if(isdemo())
 478         {
 479                 // in demos, input_buttons do not work
 480                 button_zoom = (autocvar__togglezoom == "-");
 481         }
 482         else if(button_zoom
 483                 && autocvar_cl_unpress_zoom_on_death
 484                 && (spectatee_status >= 0)
 485                 && (is_dead || intermission))
 486         {
 487                 // no zoom while dead or in intermission please
 488                 localcmd("-zoom\n");
 489                 button_zoom = FALSE;
 490         }
 491
 492         // event chase camera
 493         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 494         {
 495                 WepSet weapons_stat = WepSet_GetFromStat();
 496                 if(((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission) && !autocvar_cl_orthoview || (autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(weapons_stat & WepSet_FromWeapon(WEP_PORTO))))
 497                 {
 498                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 499                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 500
 501                         // detect maximum viewoffset and use it
 502                         if(autocvar_cl_eventchase_viewoffset)
 503                         {
 504                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 505                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 506                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 507                         }
 508
 509                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 510                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 511                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 512                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 513
 514                         // make the camera smooth back
 515                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 516                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 517                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 518                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 519
 520                         makevectors(view_angles);
 521
 522                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 523                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 524
 525                         // If the boxtrace fails, revert back to line tracing.
 526                         if(trace_startsolid)
 527                         {
 528                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 529                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 530                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 531                         }
 532                         else { setproperty(VF_ORIGIN, trace_endpos); }
 533
 534                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 535                 }
 536                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 537                 {
 538                         cvar_set("chase_active", "0");
 539                         eventchase_current_distance = 0; // start from 0 next time
 540                 }
 541         }
 542         // workaround for camera stuck between player's legs when using chase_active 1
 543         // because the engine stops updating the chase_active camera when the game ends
 544         else if(intermission)
 545         {
 546                 cvar_settemp("chase_active", "-1");
 547                 eventchase_current_distance = 0;
 548         }
 549
 550         // do lockview after event chase camera so that it still applies whenever necessary.
 551         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 552         {
 553                 setproperty(VF_ORIGIN, freeze_org);
 554                 setproperty(VF_ANGLES, freeze_ang);
 555         }
 556         else
 557         {
 558                 freeze_org = getpropertyvec(VF_ORIGIN);
 559                 freeze_ang = getpropertyvec(VF_ANGLES);
 560         }
 561
 562         WarpZone_FixView();
 563         //WarpZone_FixPMove();
 564
 565         vector ov_org = '0 0 0';
 566         vector ov_mid = '0 0 0';
 567         vector ov_worldmin = '0 0 0';
 568         vector ov_worldmax = '0 0 0';
 569         if(autocvar_cl_orthoview)
 570         {
 571                 ov_worldmin = mi_picmin;
 572                 ov_worldmax = mi_picmax;
 573
 574                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
 575                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
 576                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
 577
 578                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
 579                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
 580
 581                 float ov_nearest = vlen(ov_org - vec3(
 582                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
 583                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
 584                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
 585                 ));
 586
 587                 float ov_furthest = 0;
 588                 float dist = 0;
 589
 590                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 591                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 592                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 593                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 594                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 595                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 596                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 597                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 598
 599                 cvar_settemp("r_nearclip", ftos(ov_nearest));
 600                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
 601                 cvar_settemp("r_farclip_world", "0");
 602                 cvar_settemp("r_novis", "1");
 603                 cvar_settemp("r_useportalculling", "0");
 604                 cvar_settemp("r_useinfinitefarclip", "0");
 605
 606                 setproperty(VF_ORIGIN, ov_org);
 607                 setproperty(VF_ANGLES, '90 0 0');
 608
 609                 #if 0
 610                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
 611                         vtos(ov_org),
 612                         vtos(getpropertyvec(VF_ANGLES)),
 613                         ov_distance,
 614                         ov_nearest,
 615                         ov_furthest);
 616                 #endif
 617         }
 618
 619         // Render the Scene
 620         view_origin = getpropertyvec(VF_ORIGIN);
 621         view_angles = getpropertyvec(VF_ANGLES);
 622         makevectors(view_angles);
 623         view_forward = v_forward;
 624         view_right = v_right;
 625         view_up = v_up;
 626
 627 #ifdef BLURTEST
 628         if(time > blurtest_time0 && time < blurtest_time1)
 629         {
 630                 float r, t;
 631
 632                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 633                 r = t * blurtest_radius;
 634                 f = 1 / pow(t, blurtest_power) - 1;
 635
 636                 cvar_set("r_glsl_postprocess", "1");
 637                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 638         }
 639         else
 640         {
 641                 cvar_set("r_glsl_postprocess", "0");
 642                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 643         }
 644 #endif
 645
 646         TargetMusic_Advance();
 647         Fog_Force();
 648
 649         if(drawtime == 0)
 650                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 651         else
 652                 drawframetime = bound(0.000001, time - drawtime, 1);
 653         drawtime = time;
 654
 655         // watch for gametype changes here...
 656         // in ParseStuffCMD the cmd isn't executed yet :/
 657         // might even be better to add the gametype to TE_CSQC_INIT...?
 658         if(!postinit)
 659                 PostInit();
 660
 661         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 662         {
 663                 if(calledhooks & HOOK_START)
 664                 {
 665                         localcmd("\ncl_hook_gameend\n");
 666                         calledhooks |= HOOK_END;
 667                 }
 668         }
 669
 670         Announcer();
 671
 672         fov = autocvar_fov;
 673         if(fov <= 59.5)
 674         {
 675                 if(!zoomscript_caught)
 676                 {
 677                         localcmd("+button9\n");
 678                         zoomscript_caught = 1;
 679                 }
 680         }
 681         else
 682         {
 683                 if(zoomscript_caught)
 684                 {
 685                         localcmd("-button9\n");
 686                         zoomscript_caught = 0;
 687                 }
 688         }
 689
 690         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 691
 692         // next WANTED weapon (for HUD)
 693         switchweapon = getstati(STAT_SWITCHWEAPON);
 694
 695         // currently switching-to weapon (for crosshair)
 696         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 697
 698         // actually active weapon (for zoom)
 699         activeweapon = getstati(STAT_ACTIVEWEAPON);
 700
 701         f = (serverflags & SERVERFLAG_TEAMPLAY);
 702         if(f != teamplay)
 703         {
 704                 teamplay = f;
 705                 HUD_InitScores();
 706         }
 707
 708         if(last_switchweapon != switchweapon)
 709         {
 710                 weapontime = time;
 711                 last_switchweapon = switchweapon;
 712                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 713                 {
 714                         localcmd("-zoom\n");
 715                         button_zoom = FALSE;
 716                 }
 717                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 718                 {
 719                         localcmd("-fire\n");
 720                         localcmd("-fire2\n");
 721                         button_attack2 = FALSE;
 722                 }
 723         }
 724         if(last_activeweapon != activeweapon)
 725         {
 726                 last_activeweapon = activeweapon;
 727
 728                 e = get_weaponinfo(activeweapon);
 729                 if(e.netname != "")
 730                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 731                 else
 732                         localcmd("\ncl_hook_activeweapon none\n");
 733         }
 734
 735         // ALWAYS Clear Current Scene First
 736         clearscene();
 737 #ifdef WORKAROUND_XON010
 738         if(checkextension("DP_CSQC_ROTATEMOVES"))
 739         {
 740 #endif
 741         setproperty(VF_ORIGIN, view_origin);
 742         setproperty(VF_ANGLES, view_angles);
 743 #ifdef WORKAROUND_XON010
 744         }
 745 #endif
 746
 747         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 748         setproperty(VF_SIZE, vf_size);
 749         setproperty(VF_MIN, vf_min);
 750
 751         // Assign Standard Viewflags
 752         // Draw the World (and sky)
 753         setproperty(VF_DRAWWORLD, 1);
 754
 755         // Set the console size vars
 756         vid_conwidth = autocvar_vid_conwidth;
 757         vid_conheight = autocvar_vid_conheight;
 758         vid_pixelheight = autocvar_vid_pixelheight;
 759
 760         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
 761         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 762
 763         // Camera for demo playback
 764         if(camera_active)
 765         {
 766                 if(autocvar_camera_enable)
 767                         CSQC_Demo_Camera();
 768                 else
 769                 {
 770                         cvar_set("chase_active", ftos(chase_active_backup));
 771                         cvar_set("cl_demo_mousegrab", "0");
 772                         camera_active = FALSE;
 773                 }
 774         }
 775 #ifdef CAMERATEST
 776         else if(autocvar_camera_enable)
 777 #else
 778         else if(autocvar_camera_enable && isdemo())
 779 #endif
 780         {
 781                 // Enable required Darkplaces cvars
 782                 chase_active_backup = autocvar_chase_active;
 783                 cvar_set("chase_active", "2");
 784                 cvar_set("cl_demo_mousegrab", "1");
 785                 camera_active = TRUE;
 786                 camera_mode = FALSE;
 787         }
 788
 789         // Draw the Crosshair
 790         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 791
 792         // Draw the Engine Status Bar (the default Quake HUD)
 793         setproperty(VF_DRAWENGINESBAR, 0);
 794
 795         // Update the mouse position
 796         /*
 797            mousepos_x = vid_conwidth;
 798            mousepos_y = vid_conheight;
 799            mousepos = mousepos*0.5 + getmousepos();
 800          */
 801
 802         e = self;
 803         for(self = world; (self = nextent(self)); )
 804                 if(self.draw)
 805                         self.draw();
 806         self = e;
 807
 808         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 809         renderscene();
 810
 811         // now switch to 2D drawing mode by calling a 2D drawing function
 812         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 813         // next R_RenderScene call
 814         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 815
 816         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 817         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 818         {
 819                 // apply night vision effect
 820                 vector tc_00, tc_01, tc_10, tc_11;
 821                 vector rgb;
 822                 rgb_x = 0; // fteqcc sucks
 823                 rgb_y = 0; // fteqcc sucks
 824                 rgb_z = 0; // fteqcc sucks
 825
 826                 if(!nightvision_noise)
 827                 {
 828                         nightvision_noise = spawn();
 829                         nightvision_noise.classname = "nightvision_noise";
 830                 }
 831                 if(!nightvision_noise2)
 832                 {
 833                         nightvision_noise2 = spawn();
 834                         nightvision_noise2.classname = "nightvision_noise2";
 835                 }
 836
 837                 // color tint in yellow
 838                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 839
 840                 // draw BG
 841                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 842                 rgb = '1 1 1';
 843                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 844                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 845                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 846                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 847                 tc_11 = tc_01 + tc_10 - tc_00;
 848                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 849                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 850                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 851                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 852                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 853                 R_EndPolygon();
 854
 855                 // draw FG
 856                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 857                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 858                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 859                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 860                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 861                 tc_11 = tc_01 + tc_10 - tc_00;
 862                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 863                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 864                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 865                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 866                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 867                 R_EndPolygon();
 868         }
 869
 870         // Draw the aiming reticle for weapons that use it
 871         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 872         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 873         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 874         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 875                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 876         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
 877                 reticle_type = 2; // nex zoom
 878         else if(button_zoom || zoomscript_caught)
 879                 reticle_type = 1; // normal zoom
 880         else if((activeweapon == WEP_NEX) && button_attack2)
 881                 reticle_type = 2; // nex zoom
 882
 883         if(reticle_type && autocvar_cl_reticle)
 884         {
 885                 if(autocvar_cl_reticle_stretch)
 886                 {
 887                         reticle_size_x = vid_conwidth;
 888                         reticle_size_y = vid_conheight;
 889                         reticle_pos_x = 0;
 890                         reticle_pos_y = 0;
 891                 }
 892                 else
 893                 {
 894                         reticle_size_x = max(vid_conwidth, vid_conheight);
 895                         reticle_size_y = max(vid_conwidth, vid_conheight);
 896                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 897                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 898                 }
 899
 900                 f = current_zoomfraction;
 901                 if(zoomscript_caught)
 902                         f = 1;
 903                 if(autocvar_cl_reticle_item_normal)
 904                 {
 905                         if(reticle_type == 1 && f)
 906                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 907                 }
 908                 if(autocvar_cl_reticle_item_nex)
 909                 {
 910                         if(reticle_type == 2 && f)
 911                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 912                 }
 913         }
 914
 915
 916         // improved polyblend
 917         if(autocvar_hud_contents)
 918         {
 919                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 920                 vector liquidcolor;
 921
 922                 switch(pointcontents(view_origin))
 923                 {
 924                         case CONTENT_WATER:
 925                                 liquidalpha = autocvar_hud_contents_water_alpha;
 926                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 927                                 incontent = 1;
 928                                 break;
 929
 930                         case CONTENT_LAVA:
 931                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 932                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 933                                 incontent = 1;
 934                                 break;
 935
 936                         case CONTENT_SLIME:
 937                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 938                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 939                                 incontent = 1;
 940                                 break;
 941
 942                         default:
 943                                 liquidalpha = 0;
 944                                 liquidcolor = '0 0 0';
 945                                 incontent = 0;
 946                                 break;
 947                 }
 948
 949                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 950                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 951                         contentfadetime = autocvar_hud_contents_fadeintime;
 952                         liquidalpha_prev = liquidalpha;
 953                         liquidcolor_prev = liquidcolor;
 954                 }
 955                 else
 956                         contentfadetime = autocvar_hud_contents_fadeouttime;
 957
 958                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 959                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 960
 961                 if(contentavgalpha)
 962                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 963
 964                 if(autocvar_hud_postprocessing)
 965                 {
 966                         if(autocvar_hud_contents_blur && contentavgalpha)
 967                         {
 968                                 content_blurpostprocess_x = 1;
 969                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 970                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 971                         }
 972                         else
 973                         {
 974                                 content_blurpostprocess_x = 0;
 975                                 content_blurpostprocess_y = 0;
 976                                 content_blurpostprocess_z = 0;
 977                         }
 978                 }
 979         }
 980
 981         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 982         {
 983                 splash_size_x = max(vid_conwidth, vid_conheight);
 984                 splash_size_y = max(vid_conwidth, vid_conheight);
 985                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 986                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 987
 988                 float myhealth_flash_temp;
 989                 myhealth = getstati(STAT_HEALTH);
 990
 991                 // fade out
 992                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 993                 // add new damage
 994                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 995
 996                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 997                 pain_threshold = autocvar_hud_damage_pain_threshold;
 998                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 999                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1000
1001                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1002                 {
1003                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1004                 }
1005
1006                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1007
1008                 if(myhealth_prev < 1)
1009                 {
1010                         if(myhealth >= 1)
1011                         {
1012                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1013                                 myhealth_flash_temp = 0;
1014                         }
1015                         else
1016                         {
1017                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1018                         }
1019                 }
1020
1021                 if(spectatee_status == -1 || intermission)
1022                 {
1023                         myhealth_flash = 0; // observing, or match ended
1024                         myhealth_flash_temp = 0;
1025                 }
1026
1027                 myhealth_prev = myhealth;
1028
1029                 // IDEA: change damage color/picture based on player model for robot/alien species?
1030                 // pro: matches model better
1031                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1032                 // maybe different reddish pics?
1033                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1034                 {
1035                         if(autocvar_cl_gentle_damage == 2)
1036                         {
1037                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1038                                 {
1039                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1040                                 }
1041                         }
1042                         else
1043                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1044
1045                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1046                 }
1047                 else
1048                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1049
1050                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1051                 {
1052                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1053                         {
1054                                 damage_blurpostprocess_x = 1;
1055                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1056                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1057                         }
1058                         else
1059                         {
1060                                 damage_blurpostprocess_x = 0;
1061                                 damage_blurpostprocess_y = 0;
1062                                 damage_blurpostprocess_z = 0;
1063                         }
1064                 }
1065         }
1066
1067         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1068         float e2 = (autocvar_hud_powerup != 0);
1069         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1070         {
1071                 // enable or disable rendering types if they are used or not
1072                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1073                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1074
1075                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1076                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1077                 {
1078                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1079                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1080                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1081                         {
1082                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1083                                 old_blurradius = blurradius;
1084                                 old_bluralpha = bluralpha;
1085                         }
1086                 }
1087                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1088                 {
1089                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1090                         old_blurradius = 0;
1091                         old_bluralpha = 0;
1092                 }
1093
1094                 // edge detection postprocess handling done second (used by hud_powerup)
1095                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1096                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1097                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1098
1099                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1100
1101                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1102                 {
1103                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1104                         {
1105                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1106                                 old_sharpen_intensity = sharpen_intensity;
1107                         }
1108                 }
1109                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1110                 {
1111                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1112                         old_sharpen_intensity = 0;
1113                 }
1114
1115                 if(cvar("r_glsl_postprocess") == 0)
1116                         cvar_set("r_glsl_postprocess", "2");
1117         }
1118         else if(cvar("r_glsl_postprocess") == 2)
1119                 cvar_set("r_glsl_postprocess", "0");
1120
1121         if(menu_visible)
1122                 menu_show();
1123
1124         /*if(gametype == MAPINFO_TYPE_CTF)
1125           {
1126           ctf_view();
1127           } else */
1128
1129         // draw 2D entities
1130         e = self;
1131         for(self = world; (self = nextent(self)); )
1132                 if(self.draw2d)
1133                         self.draw2d();
1134         self = e;
1135         Draw_ShowNames_All();
1136
1137         scoreboard_active = HUD_WouldDrawScoreboard();
1138
1139         // varying sound pitch
1140         damage_dealt_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
1141
1142         // detect overflow on server side
1143         if (damage_dealt_total < damage_dealt_total_prev)
1144         {
1145                 dprint("resetting dmg total: ", ftos(damage_dealt_total), " prev: ", ftos(damage_dealt_total_prev), "\n");
1146                 damage_dealt_total_prev = 0;
1147         }
1148
1149         // prevent hitsound when switching spectatee
1150         if (spectatee_status != spectatee_status_prev)
1151         {
1152                 damage_dealt_total_prev = damage_dealt_total;
1153         }
1154         spectatee_status_prev = spectatee_status;
1155
1156         // amount of damage since last hit sound
1157         float unaccounted_damage = damage_dealt_total - damage_dealt_total_prev;
1158
1159
1160         if (autocvar_cl_hitsound == 1)
1161         {
1162                 if ( time - hitsound_time_prev > autocvar_cl_hitsound_antispam_time )
1163                 if ( damage_dealt_total > 0 )
1164                 {
1165                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1166                         hitsound_time_prev = time;
1167                 }
1168         }
1169         else if (unaccounted_damage > 0 && autocvar_cl_hitsound > 0 && time - hitsound_time_prev > autocvar_cl_hitsound_antispam_time)
1170         {
1171                 // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
1172                 float a, b, c, x;
1173                 a = autocvar_cl_hitsound_max_pitch;
1174                 b = autocvar_cl_hitsound_min_pitch;
1175                 c = autocvar_cl_hitsound_nom_damage;
1176                 x = unaccounted_damage;
1177                 float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
1178
1179                 // if sound variation is disabled, set pitch_shift to 1
1180                 if (autocvar_cl_hitsound == 1)
1181                 {
1182                         pitch_shift = 1;
1183                 }
1184
1185                 // if pitch shift is reversed, mirror in (max-min)/2 + min
1186                 if (autocvar_cl_hitsound == 3)
1187                 {
1188                         float mirror_value = (a-b)/2 + b;
1189                         pitch_shift = mirror_value + (mirror_value - pitch_shift);
1190                 }
1191
1192                 dprint("dmg total (dmg): ", ftos(damage_dealt_total), " (+", ftos(unaccounted_damage), "), pitch shift: ", ftos(pitch_shift), "\n");
1193
1194                 // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
1195                 // todo: normalize sound pressure levels? seems unnecessary
1196
1197                 // scale to fit function interface
1198                 float param_pitch_shift = pitch_shift * 100;
1199
1200                 // play sound
1201                 sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, param_pitch_shift, 0);
1202
1203                 // track damage accounted for
1204                 damage_dealt_total_prev = damage_dealt_total;
1205
1206                 // remember when this sound was played to prevent sound spam
1207                 hitsound_time_prev = time;
1208         }
1209         else if (autocvar_cl_hitsound == 0)
1210         {
1211                 // forget the damage to prevent hitsound when enabling it
1212                 damage_dealt_total_prev = damage_dealt_total;
1213         }
1214
1215         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1216         if(typehit_time - typehit_time_prev > autocvar_cl_hitsound_antispam_time)
1217         {
1218                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1219                 typehit_time_prev = typehit_time;
1220         }
1221
1222         //else
1223         {
1224                 if(getstati(STAT_FROZEN))
1225                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1226                 else if (getstatf(STAT_HEALING_ORB)>time)
1227                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1228                 if(!intermission)
1229                 if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1230                 {
1231                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1232                         drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1233                 }
1234                 else if(getstatf(STAT_REVIVE_PROGRESS))
1235                 {
1236                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1237                         drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1238                 }
1239
1240                 if(autocvar_r_letterbox == 0)
1241                         if(autocvar_viewsize < 120)
1242                                 CSQC_common_hud();
1243
1244                 // crosshair goes VERY LAST
1245                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1246                 {
1247                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1248                                 return;
1249
1250                         string wcross_style;
1251                         float wcross_alpha, wcross_resolution;
1252                         wcross_style = autocvar_crosshair;
1253                         if (wcross_style == "0")
1254                                 return;
1255                         wcross_resolution = autocvar_crosshair_size;
1256                         if (wcross_resolution == 0)
1257                                 return;
1258                         wcross_alpha = autocvar_crosshair_alpha;
1259                         if (wcross_alpha == 0)
1260                                 return;
1261
1262                         // TrueAim check
1263                         float shottype;
1264
1265                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1266                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1267                         wcross_origin_z = 0;
1268                         if(autocvar_crosshair_hittest)
1269                         {
1270                                 vector wcross_oldorigin;
1271                                 wcross_oldorigin = wcross_origin;
1272                                 shottype = TrueAimCheck();
1273                                 if(shottype == SHOTTYPE_HITWORLD)
1274                                 {
1275                                         v = wcross_origin - wcross_oldorigin;
1276                                         v_x /= vid_conwidth;
1277                                         v_y /= vid_conheight;
1278                                         if(vlen(v) > 0.01)
1279                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1280                                 }
1281                                 if(!autocvar_crosshair_hittest_showimpact)
1282                                         wcross_origin = wcross_oldorigin;
1283                         }
1284                         else
1285                                 shottype = SHOTTYPE_HITWORLD;
1286
1287                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1288                         string wcross_wep = "", wcross_name;
1289                         float wcross_scale, wcross_blur;
1290
1291                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1292                         {
1293                                 e = get_weaponinfo(switchingweapon);
1294                                 if (e && e.netname != "")
1295                                 {
1296                                         wcross_wep = e.netname;
1297                                         if(autocvar_crosshair_per_weapon)
1298                                         {
1299                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1300                                                 if (wcross_resolution == 0)
1301                                                         return;
1302                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1303                                                 if (wcross_alpha == 0)
1304                                                         return;
1305
1306                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1307                                                 if(wcross_style == "" || wcross_style == "0")
1308                                                         wcross_style = wcross_wep;
1309                                         }
1310                                 }
1311                         }
1312
1313                         //printf("crosshair style: %s\n", wcross_style);
1314                         wcross_name = strcat("gfx/crosshair", wcross_style);
1315
1316                         // MAIN CROSSHAIR COLOR DECISION
1317                         switch(autocvar_crosshair_color_special)
1318                         {
1319                                 case 1: // crosshair_color_per_weapon
1320                                 {
1321                                         if(wcross_wep != "")
1322                                         {
1323                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1324                                                 break;
1325                                         }
1326                                         else { goto normalcolor; }
1327                                 }
1328
1329                                 case 2: // crosshair_color_by_health
1330                                 {
1331                                         float x = getstati(STAT_HEALTH);
1332
1333                                         //x = red
1334                                         //y = green
1335                                         //z = blue
1336
1337                                         wcross_color_z = 0;
1338
1339                                         if(x > 200)
1340                                         {
1341                                                 wcross_color_x = 0;
1342                                                 wcross_color_y = 1;
1343                                         }
1344                                         else if(x > 150)
1345                                         {
1346                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1347                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1348                                         }
1349                                         else if(x > 100)
1350                                         {
1351                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1352                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1353                                                 wcross_color_z = 1 - (x-100)*0.02;
1354                                         }
1355                                         else if(x > 50)
1356                                         {
1357                                                 wcross_color_x = 1;
1358                                                 wcross_color_y = 1;
1359                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1360                                         }
1361                                         else if(x > 20)
1362                                         {
1363                                                 wcross_color_x = 1;
1364                                                 wcross_color_y = (x-20)*90/27/100;
1365                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1366                                         }
1367                                         else
1368                                         {
1369                                                 wcross_color_x = 1;
1370                                                 wcross_color_y = 0;
1371                                         }
1372                                         break;
1373                                 }
1374
1375                                 case 3: // crosshair_color_rainbow
1376                                 {
1377                                         if(time >= rainbow_last_flicker)
1378                                         {
1379                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1380                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1381                                         }
1382                                         wcross_color = rainbow_prev_color;
1383                                         break;
1384                                 }
1385                                 :normalcolor
1386                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1387                         }
1388
1389                         if(autocvar_crosshair_effect_scalefade)
1390                         {
1391                                 wcross_scale = wcross_resolution;
1392                                 wcross_resolution = 1;
1393                         }
1394                         else
1395                         {
1396                                 wcross_scale = 1;
1397                         }
1398
1399                         if(autocvar_crosshair_pickup)
1400                         {
1401                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1402
1403                                 if(pickup_crosshair_time < stat_pickup_time)
1404                                 {
1405                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1406                                                 pickup_crosshair_size = 1;
1407
1408                                         pickup_crosshair_time = stat_pickup_time;
1409                                 }
1410
1411                                 if(pickup_crosshair_size > 0)
1412                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1413                                 else
1414                                         pickup_crosshair_size = 0;
1415
1416                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1417                         }
1418
1419                         // todo: make crosshair hit indication dependent on damage dealt
1420                         if(autocvar_crosshair_hitindication)
1421                         {
1422                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1423
1424                                 if(unaccounted_damage)
1425                                 {
1426                                         hitindication_crosshair_size = 1;
1427                                 }
1428
1429                                 if(hitindication_crosshair_size > 0)
1430                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1431                                 else
1432                                         hitindication_crosshair_size = 0;
1433
1434                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1435                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1436                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1437                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1438                         }
1439
1440                         if(shottype == SHOTTYPE_HITENEMY)
1441                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1442                         if(shottype == SHOTTYPE_HITTEAM)
1443                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1444
1445                         f = fabs(autocvar_crosshair_effect_time);
1446                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1447                         {
1448                                 wcross_changedonetime = time + f;
1449                         }
1450                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1451                         {
1452                                 wcross_name_changestarttime = time;
1453                                 wcross_name_changedonetime = time + f;
1454                                 if(wcross_name_goal_prev_prev)
1455                                         strunzone(wcross_name_goal_prev_prev);
1456                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1457                                 wcross_name_goal_prev = strzone(wcross_name);
1458                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1459                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1460                                 wcross_resolution_goal_prev = wcross_resolution;
1461                         }
1462
1463                         wcross_scale_goal_prev = wcross_scale;
1464                         wcross_alpha_goal_prev = wcross_alpha;
1465                         wcross_color_goal_prev = wcross_color;
1466
1467                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1468                         {
1469                                 wcross_blur = 1;
1470                                 wcross_alpha *= 0.75;
1471                         }
1472                         else
1473                                 wcross_blur = 0;
1474                         // *_prev is at time-frametime
1475                         // * is at wcross_changedonetime+f
1476                         // what do we have at time?
1477                         if(time < wcross_changedonetime)
1478                         {
1479                                 f = frametime / (wcross_changedonetime - time + frametime);
1480                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1481                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1482                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1483                         }
1484
1485                         wcross_scale_prev = wcross_scale;
1486                         wcross_alpha_prev = wcross_alpha;
1487                         wcross_color_prev = wcross_color;
1488
1489                         wcross_scale *= 1 - autocvar__menu_alpha;
1490                         wcross_alpha *= 1 - autocvar__menu_alpha;
1491                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1492
1493                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1494                         {
1495                                 // crosshair rings for weapon stats
1496                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1497                                 {
1498                                         // declarations and stats
1499                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1500                                         string ring_image = string_null, ring_inner_image = string_null;
1501                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1502
1503                                         ring_scale = autocvar_crosshair_ring_size;
1504
1505                                         float weapon_clipload, weapon_clipsize;
1506                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1507                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1508
1509                                         float nex_charge, nex_chargepool;
1510                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1511                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1512
1513                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1514                                                 nex_charge_movingavg = nex_charge;
1515
1516
1517                                         // handle the values
1518                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1519                                         {
1520                                                 if (nex_chargepool || use_nex_chargepool) {
1521                                                         use_nex_chargepool = 1;
1522                                                         ring_inner_value = nex_chargepool;
1523                                                 } else {
1524                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1525                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1526                                                 }
1527
1528                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1529                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1530                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1531
1532                                                 // draw the outer ring to show the current charge of the weapon
1533                                                 ring_value = nex_charge;
1534                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1535                                                 ring_rgb = wcross_color;
1536                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1537                                         }
1538                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1539                                         {
1540                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1541                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1542                                                 ring_rgb = wcross_color;
1543                                                 ring_image = "gfx/crosshair_ring.tga";
1544                                         }
1545                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1546                                         {
1547                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1548                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1549                                                 ring_rgb = wcross_color;
1550                                                 ring_image = "gfx/crosshair_ring.tga";
1551                                         }
1552
1553                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1554                                         {
1555                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1556                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1557                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1558                                                 ring_rgb = wcross_color;
1559
1560                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1561                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1562                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1563                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1564                                                 else
1565                                                         ring_image = "gfx/crosshair_ring.tga";
1566                                         }
1567
1568                                         // if in weapon switch animation, fade ring out/in
1569                                         if(autocvar_crosshair_effect_time > 0)
1570                                         {
1571                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1572                                                 if (!(f < 1))
1573                                                 {
1574                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1575                                                 }
1576
1577                                                 if(wcross_ring_prev)
1578                                                 {
1579                                                         if(f < 1)
1580                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1581                                                 }
1582                                                 else
1583                                                 {
1584                                                         if(f < 1)
1585                                                                 ring_alpha *= bound(0, f, 1);
1586                                                 }
1587                                         }
1588
1589                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1590                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1591
1592                                         if (ring_value)
1593                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1594                                 }
1595
1596 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1597                                 do \
1598                                 { \
1599                                         if(wcross_blur > 0) \
1600                                         { \
1601                                                 for(i = -2; i <= 2; ++i) \
1602                                                 for(j = -2; j <= 2; ++j) \
1603                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1604                                         } \
1605                                         else \
1606                                         { \
1607                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1608                                         } \
1609                                 } \
1610                                 while(0)
1611
1612 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1613                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1614
1615 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1616                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1617
1618                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1619                                 {
1620                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1621                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1622                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1623                                         f = 1 - f;
1624                                 }
1625                                 else
1626                                 {
1627                                         f = 1;
1628                                 }
1629                                 wcross_name_alpha_goal_prev = f;
1630
1631                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1632                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1633
1634                                 if(autocvar_crosshair_dot)
1635                                 {
1636                                         vector wcross_color_old;
1637                                         wcross_color_old = wcross_color;
1638
1639                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1640                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1641
1642                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1643                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1644                                         wcross_color = wcross_color_old;
1645                                 }
1646                         }
1647                 }
1648                 else
1649                 {
1650                         wcross_scale_prev = 0;
1651                         wcross_alpha_prev = 0;
1652                         wcross_scale_goal_prev = 0;
1653                         wcross_alpha_goal_prev = 0;
1654                         wcross_changedonetime = 0;
1655                         if(wcross_name_goal_prev)
1656                                 strunzone(wcross_name_goal_prev);
1657                         wcross_name_goal_prev = string_null;
1658                         if(wcross_name_goal_prev_prev)
1659                                 strunzone(wcross_name_goal_prev_prev);
1660                         wcross_name_goal_prev_prev = string_null;
1661                         wcross_name_changestarttime = 0;
1662                         wcross_name_changedonetime = 0;
1663                         wcross_name_alpha_goal_prev = 0;
1664                         wcross_name_alpha_goal_prev_prev = 0;
1665                         wcross_resolution_goal_prev = 0;
1666                         wcross_resolution_goal_prev_prev = 0;
1667                 }
1668         }
1669
1670         if(NextFrameCommand)
1671         {
1672                 localcmd("\n", NextFrameCommand, "\n");
1673                 NextFrameCommand = string_null;
1674         }
1675
1676         // we must do this check AFTER a frame was rendered, or it won't work
1677         if(cs_project_is_b0rked == 0)
1678         {
1679                 string w0, h0;
1680                 w0 = ftos(autocvar_vid_conwidth);
1681                 h0 = ftos(autocvar_vid_conheight);
1682                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1683                 //setproperty(VF_FOV, '90 90 0');
1684                 setproperty(VF_ORIGIN, '0 0 0');
1685                 setproperty(VF_ANGLES, '0 0 0');
1686                 setproperty(VF_PERSPECTIVE, 1);
1687                 makevectors('0 0 0');
1688                 vector v1, v2;
1689                 cvar_set("vid_conwidth", "800");
1690                 cvar_set("vid_conheight", "600");
1691                 v1 = cs_project(v_forward);
1692                 cvar_set("vid_conwidth", "640");
1693                 cvar_set("vid_conheight", "480");
1694                 v2 = cs_project(v_forward);
1695                 if(v1 == v2)
1696                         cs_project_is_b0rked = 1;
1697                 else
1698                         cs_project_is_b0rked = -1;
1699                 cvar_set("vid_conwidth", w0);
1700                 cvar_set("vid_conheight", h0);
1701         }
1702
1703         if(autocvar__hud_configure)
1704                 HUD_Panel_Mouse();
1705
1706     if(hud && !intermission)
1707     if(hud == HUD_BUMBLEBEE_GUN)
1708         CSQC_BUMBLE_GUN_HUD();
1709     else
1710                 VEH_ACTION(hud, VR_HUD);
1711
1712         cl_notice_run();
1713
1714         // let's reset the view back to normal for the end
1715         setproperty(VF_MIN, '0 0 0');
1716         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1717 }
1718
1719
1720 void CSQC_common_hud(void)
1721 {
1722         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1723                 Accuracy_LoadLevels();
1724
1725         HUD_Main(); // always run these functions for alpha checks
1726         HUD_DrawScoreboard();
1727
1728         if (scoreboard_active) // scoreboard/accuracy
1729                 HUD_Reset();
1730         else if (intermission == 2) // map voting screen
1731         {
1732                 MapVote_Draw();
1733                 HUD_Reset();
1734         }
1735 }
1736
1737
1738 // following vectors must be global to allow seamless switching between camera modes
1739 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1740 void CSQC_Demo_Camera()
1741 {
1742         float speed, attenuation, dimensions;
1743         vector tmp, delta;
1744
1745         if( autocvar_camera_reset || !camera_mode )
1746         {
1747                 camera_offset = '0 0 0';
1748                 current_angles = '0 0 0';
1749                 camera_direction = '0 0 0';
1750                 camera_offset_z += 30;
1751                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1752                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1753                 current_origin = view_origin;
1754                 current_camera_offset  = camera_offset;
1755                 cvar_set("camera_reset", "0");
1756                 camera_mode = CAMERA_CHASE;
1757         }
1758
1759         // Camera angles
1760         if( camera_roll )
1761                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1762
1763         if(autocvar_camera_look_player)
1764         {
1765                 vector dir;
1766                 float n;
1767
1768                 dir = normalize(view_origin - current_position);
1769                 n = mouse_angles_z;
1770                 mouse_angles = vectoangles(dir);
1771                 mouse_angles_x = mouse_angles_x * -1;
1772                 mouse_angles_z = n;
1773         }
1774         else
1775         {
1776                 tmp = getmousepos() * 0.1;
1777                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1778                 {
1779                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1780                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1781                 }
1782         }
1783
1784         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1785         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1786         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1787         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1788
1789         // Fix difference when angles don't have the same sign
1790         delta = '0 0 0';
1791         if(mouse_angles_y < -60 && current_angles_y > 60)
1792                 delta = '0 360 0';
1793         if(mouse_angles_y > 60 && current_angles_y < -60)
1794                 delta = '0 -360 0';
1795
1796         if(autocvar_camera_look_player)
1797                 attenuation = autocvar_camera_look_attenuation;
1798         else
1799                 attenuation = autocvar_camera_speed_attenuation;
1800
1801         attenuation = 1 / max(1, attenuation);
1802         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1803
1804         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1805         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1806         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1807         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1808
1809         // Camera position
1810         tmp = '0 0 0';
1811         dimensions = 0;
1812
1813         if( camera_direction_x )
1814         {
1815                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1816                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1817                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1818                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1819                 ++dimensions;
1820         }
1821
1822         if( camera_direction_y )
1823         {
1824                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1825                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1826                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1827                 ++dimensions;
1828         }
1829
1830         if( camera_direction_z )
1831         {
1832                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1833                 ++dimensions;
1834         }
1835
1836         if(autocvar_camera_free)
1837                 speed = autocvar_camera_speed_free;
1838         else
1839                 speed = autocvar_camera_speed_chase;
1840
1841         if(dimensions)
1842         {
1843                 speed = speed * sqrt(1 / dimensions);
1844                 camera_offset += tmp * speed;
1845         }
1846
1847         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1848
1849         // Camera modes
1850         if( autocvar_camera_free )
1851         {
1852                 if ( camera_mode == CAMERA_CHASE )
1853                 {
1854                         current_camera_offset = current_origin + current_camera_offset;
1855                         camera_offset = current_origin + camera_offset;
1856                 }
1857
1858                 camera_mode = CAMERA_FREE;
1859                 current_position = current_camera_offset;
1860         }
1861         else
1862         {
1863                 if ( camera_mode == CAMERA_FREE )
1864                 {
1865                         current_origin = view_origin;
1866                         camera_offset = camera_offset - current_origin;
1867                         current_camera_offset = current_camera_offset - current_origin;
1868                 }
1869
1870                 camera_mode = CAMERA_CHASE;
1871
1872                 if(autocvar_camera_chase_smoothly)
1873                         current_origin += (view_origin - current_origin) * attenuation;
1874                 else
1875                         current_origin = view_origin;
1876
1877                 current_position = current_origin + current_camera_offset;
1878         }
1879
1880         setproperty(VF_ANGLES, current_angles);
1881         setproperty(VF_ORIGIN, current_position);
1882 }