qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float hit_time, typehit_time;
 357 float nextsound_hit_time, nextsound_typehit_time;
 358 float hitindication_crosshair_time, hitindication_crosshair_size;
 359 float use_nex_chargepool;
 360
 361 float myhealth, myhealth_prev;
 362 float myhealth_flash;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 void CSQC_UpdateView(float w, float h)
 370 {
 371         entity e;
 372         float fov;
 373         float f, i, j;
 374         vector v, vo;
 375         vector vf_size, vf_min;
 376         float a;
 377
 378         vf_size = R_SetView3fv(VF_SIZE);
 379         vf_min = R_SetView3fv(VF_MIN);
 380         vid_width = vf_size_x;
 381         vid_height = vf_size_y;
 382
 383         vector reticle_pos, reticle_size;
 384         vector splash_pos, splash_size;
 385
 386         WaypointSprite_Load();
 387
 388         if(spectatee_status)
 389                 myteam = GetPlayerColor(spectatee_status - 1);
 390         else
 391                 myteam = GetPlayerColor(player_localentnum - 1);
 392
 393         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 394         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 395
 396         warpzone_fixview_origin = pmove_org + vo;
 397         warpzone_fixview_cl_viewangles = input_angles;
 398         warpzone_fixview_angles = view_angles;
 399         WarpZone_FixView();
 400         pmove_org = warpzone_fixview_origin - vo;
 401         input_angles = warpzone_fixview_cl_viewangles;
 402         view_angles = warpzone_fixview_angles;
 403
 404         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 405         {
 406                 pmove_org = freeze_pmove_org;
 407                 input_angles = view_angles = freeze_input_angles;
 408                 R_SetView(VF_ORIGIN, pmove_org + vo);
 409                 R_SetView(VF_ANGLES, view_angles);
 410                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 411         }
 412         freeze_pmove_org = pmove_org;
 413         freeze_input_angles = input_angles;
 414
 415         // Render the Scene
 416         if(!intermission || !view_set)
 417         {
 418                 view_origin = pmove_org + vo;
 419                 view_angles = input_angles;
 420                 makevectors(view_angles);
 421                 view_forward = v_forward;
 422                 view_right = v_right;
 423                 view_up = v_up;
 424                 view_set = 1;
 425         }
 426
 427 #ifdef BLURTEST
 428         if(time > blurtest_time0 && time < blurtest_time1)
 429         {
 430                 float r, t;
 431
 432                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 433                 r = t * blurtest_radius;
 434                 f = 1 / pow(t, blurtest_power) - 1;
 435
 436                 cvar_set("r_glsl_postprocess", "1");
 437                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 438         }
 439         else
 440         {
 441                 cvar_set("r_glsl_postprocess", "0");
 442                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 443         }
 444 #endif
 445
 446         TargetMusic_Advance();
 447         Fog_Force();
 448
 449         drawframetime = max(0.000001, time - drawtime);
 450         drawtime = time;
 451
 452         // watch for gametype changes here...
 453         // in ParseStuffCMD the cmd isn't executed yet :/
 454         // might even be better to add the gametype to TE_CSQC_INIT...?
 455         if(!postinit)
 456                 PostInit();
 457
 458         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 459                 if(calledhooks & HOOK_START)
 460                 {
 461                         localcmd("\ncl_hook_gameend\n");
 462                         calledhooks |= HOOK_END;
 463                 }
 464
 465         CheckForGamestartChange();
 466         serverAnnouncer();
 467         maptimeAnnouncer();
 468         carrierAnnouncer();
 469
 470         fov = autocvar_fov;
 471         if(button_zoom || fov <= 59.5)
 472         {
 473                 if(!zoomscript_caught)
 474                 {
 475                         localcmd("+button4\n");
 476                         zoomscript_caught = 1;
 477                         ignore_plus_zoom += 1;
 478                 }
 479         }
 480         else
 481         {
 482                 if(zoomscript_caught)
 483                 {
 484                         localcmd("-button4\n");
 485                         zoomscript_caught = 0;
 486                         ignore_minus_zoom += 1;
 487                 }
 488         }
 489
 490         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 491         activeweapon = getstati(STAT_SWITCHWEAPON);
 492         f = (serverflags & SERVERFLAG_TEAMPLAY);
 493         if(f != teamplay)
 494         {
 495                 teamplay = f;
 496                 HUD_InitScores();
 497         }
 498
 499         if(last_weapon != activeweapon) {
 500                 weapontime = time;
 501                 last_weapon = activeweapon;
 502
 503                 e = get_weaponinfo(activeweapon);
 504                 if(e.netname != "")
 505                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 506                 else
 507                         localcmd("\ncl_hook_activeweapon none\n");
 508         }
 509
 510         // ALWAYS Clear Current Scene First
 511         R_ClearScene();
 512
 513         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 514         R_SetView(VF_SIZE, vf_size);
 515         R_SetView(VF_MIN, vf_min);
 516
 517         // Assign Standard Viewflags
 518         // Draw the World (and sky)
 519         R_SetView(VF_DRAWWORLD, 1);
 520
 521         // Set the console size vars
 522         vid_conwidth = autocvar_vid_conwidth;
 523         vid_conheight = autocvar_vid_conheight;
 524         vid_pixelheight = autocvar_vid_pixelheight;
 525
 526         R_SetView(VF_FOV, GetCurrentFov(fov));
 527
 528         // Camera for demo playback
 529         if(camera_active)
 530         {
 531                 if(autocvar_camera_enable)
 532                         CSQC_Demo_Camera();
 533                 else
 534                 {
 535                         cvar_set("chase_active", ftos(chase_active_backup));
 536                         cvar_set("cl_demo_mousegrab", "0");
 537                         camera_active = FALSE;
 538                 }
 539         }
 540 #ifdef CAMERATEST
 541         else if(autocvar_camera_enable)
 542 #else
 543         else if(autocvar_camera_enable && isdemo())
 544 #endif
 545         {
 546                 // Enable required Darkplaces cvars
 547                 chase_active_backup = autocvar_chase_active;
 548                 cvar_set("chase_active", "2");
 549                 cvar_set("cl_demo_mousegrab", "1");
 550                 camera_active = TRUE;
 551                 camera_mode = FALSE;
 552         }
 553
 554         // Draw the Crosshair
 555         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 556
 557         // Draw the Engine Status Bar (the default Quake HUD)
 558         R_SetView(VF_DRAWENGINEHUD, 0);
 559
 560         // fetch this one only once per frame
 561         hud_showbinds = autocvar_hud_showbinds;
 562         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 563
 564         // Update the mouse position
 565         /*
 566            mousepos_x = vid_conwidth;
 567            mousepos_y = vid_conheight;
 568            mousepos = mousepos*0.5 + getmousepos();
 569          */
 570
 571         e = self;
 572         for(self = world; (self = nextent(self)); )
 573                 if(self.draw)
 574                         self.draw();
 575         self = e;
 576
 577         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 578         R_RenderScene();
 579
 580         // now switch to 2D drawing mode by calling a 2D drawing function
 581         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 582         // next R_RenderScene call
 583         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 584
 585         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 586         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 587         {
 588                 // apply night vision effect
 589                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 590
 591                 if(!nightvision_noise)
 592                 {
 593                         nightvision_noise = spawn();
 594                         nightvision_noise.classname = "nightvision_noise";
 595                 }
 596                 if(!nightvision_noise2)
 597                 {
 598                         nightvision_noise2 = spawn();
 599                         nightvision_noise2.classname = "nightvision_noise2";
 600                 }
 601
 602                 // color tint in yellow
 603                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 604
 605                 // draw BG
 606                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 607                 rgb = '1 1 1';
 608                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 609                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 610                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 611                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 612                 tc_11 = tc_01 + tc_10 - tc_00;
 613                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 614                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 615                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 616                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 617                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 618                 R_EndPolygon();
 619
 620                 // draw FG
 621                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 622                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 623                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 624                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 625                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 626                 tc_11 = tc_01 + tc_10 - tc_00;
 627                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 628                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 629                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 630                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 631                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 632                 R_EndPolygon();
 633         }
 634
 635         // Draw the aiming reticle for weapons that use it
 636         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 637         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 638         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 639         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 640                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 641         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 642                 reticle_type = 2; // nex zoom
 643         else if(button_zoom || zoomscript_caught)
 644                 reticle_type = 1; // normal zoom
 645         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 646                 reticle_type = 2; // nex zoom
 647
 648         if (reticle_type)
 649         {
 650                 if(autocvar_cl_reticle_stretch)
 651                 {
 652                         reticle_size_x = vid_conwidth;
 653                         reticle_size_y = vid_conheight;
 654                         reticle_pos_x = 0;
 655                         reticle_pos_y = 0;
 656                 }
 657                 else
 658                 {
 659                         reticle_size_x = max(vid_conwidth, vid_conheight);
 660                         reticle_size_y = max(vid_conwidth, vid_conheight);
 661                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 662                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 663                 }
 664
 665                 f = current_zoomfraction;
 666                 if(zoomscript_caught)
 667                         f = 1;
 668                 if(autocvar_cl_reticle_item_normal)
 669                 {
 670                         if(reticle_type == 1 && f)
 671                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 672                 }
 673                 if(autocvar_cl_reticle_item_nex)
 674                 {
 675                         if(reticle_type == 2 && f)
 676                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 677                 }
 678         }
 679
 680
 681         // improved polyblend
 682         vector rgb;
 683         if(autocvar_hud_contents)
 684         {
 685                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 686                 vector liquidcolor;
 687
 688                 switch(pointcontents(view_origin))
 689                 {
 690                         case CONTENT_WATER:
 691                                 liquidalpha = autocvar_hud_contents_water_alpha;
 692                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 693                                 incontent = 1;
 694                                 break;
 695
 696                         case CONTENT_LAVA:
 697                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 698                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 699                                 incontent = 1;
 700                                 break;
 701
 702                         case CONTENT_SLIME:
 703                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 704                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 705                                 incontent = 1;
 706                                 break;
 707
 708                         default:
 709                                 liquidalpha = 0;
 710                                 liquidcolor = '0 0 0';
 711                                 incontent = 0;
 712                                 break;
 713                 }
 714
 715                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 716                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 717                         contentfadetime = autocvar_hud_contents_fadeintime;
 718                         liquidalpha_prev = liquidalpha;
 719                         liquidcolor_prev = liquidcolor;
 720                 }
 721                 else
 722                         contentfadetime = autocvar_hud_contents_fadeouttime;
 723
 724                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 725                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 726
 727                 if(contentavgalpha)
 728                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 729         }
 730
 731         if(autocvar_hud_damage)
 732         {
 733                 splash_size_x = max(vid_conwidth, vid_conheight);
 734                 splash_size_y = max(vid_conwidth, vid_conheight);
 735                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 736                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 737
 738                 float myhealth_flash_temp;
 739                 myhealth = getstati(STAT_HEALTH);
 740
 741                 // fade out
 742                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 743                 // add new damage
 744                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 745
 746                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 747                 pain_threshold = autocvar_hud_damage_pain_threshold;
 748                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 749                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 750
 751                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 752                 {
 753                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 754                 }
 755
 756                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 757
 758                 if(myhealth_prev < 1)
 759                 {
 760                         if(myhealth >= 1)
 761                         {
 762                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 763                                 myhealth_flash_temp = 0;
 764                         }
 765                         else
 766                         {
 767                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 768                         }
 769                 }
 770
 771                 if(spectatee_status == -1 || intermission)
 772                 {
 773                         myhealth_flash = 0; // observing, or match ended
 774                         myhealth_flash_temp = 0;
 775                 }
 776
 777                 myhealth_prev = myhealth;
 778
 779                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 780                 {
 781                         if(autocvar_cl_gentle_damage == 2)
 782                         {
 783                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 784                                 {
 785                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 786                                 }
 787                         }
 788                         else
 789                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 790
 791                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 792                 }
 793                 else
 794                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 795         }
 796
 797         // Draw the mouse cursor
 798         // NOTE: drawpic must happen after R_RenderScene for some reason
 799         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 800         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 801         //self = edict_num(player_localnum);
 802         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 803         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 804         // as long as the ctf part isn't in, this is useless
 805         if(menu_visible)
 806                 menu_show();
 807
 808         /*if(gametype == GAME_CTF)
 809           {
 810           ctf_view();
 811           } else */
 812
 813         // draw 2D entities
 814         e = self;
 815         for(self = world; (self = nextent(self)); )
 816                 if(self.draw2d)
 817                         self.draw2d();
 818         self = e;
 819
 820         scoreboard_active = HUD_WouldDrawScoreboard();
 821
 822         hit_time = getstatf(STAT_HIT_TIME);
 823         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 824         {
 825                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 826                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 827         }
 828         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 829         if(typehit_time > nextsound_typehit_time)
 830         {
 831                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 832                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 833         }
 834
 835         float hud;
 836         hud = getstati(STAT_HUD);
 837         if(hud == HUD_SPIDERBOT)
 838                 CSQC_SPIDER_HUD();
 839         else if(hud == HUD_WAKIZASHI)
 840         CSQC_WAKIZASHI_HUD();
 841     else if(hud == HUD_RAPTOR)
 842         CSQC_RAPTOR_HUD();
 843         else
 844         {
 845                 if(gametype == GAME_FREEZETAG)
 846                 {
 847                         if(getstati(STAT_FROZEN))
 848                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 849                         if(getstatf(STAT_REVIVE_PROGRESS))
 850                         {
 851                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 852                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 853                         }
 854                 }
 855
 856                 if(autocvar_r_letterbox == 0)
 857                         if(autocvar_viewsize < 120)
 858                                 CSQC_common_hud();
 859
 860                 // crosshair goes VERY LAST
 861                 if(!scoreboard_active && !camera_active && intermission != 2) {
 862                         string wcross_style;
 863                         float wcross_alpha, wcross_resolution;
 864                         wcross_style = autocvar_crosshair;
 865                         if (wcross_style == "0")
 866                                 return;
 867                         wcross_resolution = autocvar_crosshair_size;
 868                         if (wcross_resolution == 0)
 869                                 return;
 870                         wcross_alpha = autocvar_crosshair_alpha;
 871                         if (wcross_alpha == 0)
 872                                 return;
 873
 874                         // TrueAim check
 875                         float shottype;
 876
 877                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 878                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 879                         wcross_origin_z = 0;
 880                         if(autocvar_crosshair_hittest)
 881                         {
 882                                 vector wcross_oldorigin;
 883                                 wcross_oldorigin = wcross_origin;
 884                                 shottype = TrueAimCheck();
 885                                 if(shottype == SHOTTYPE_HITWORLD)
 886                                 {
 887                                         v = wcross_origin - wcross_oldorigin;
 888                                         v_x /= vid_conwidth;
 889                                         v_y /= vid_conheight;
 890                                         if(vlen(v) > 0.01)
 891                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 892                                 }
 893                                 if(!autocvar_crosshair_hittest_showimpact)
 894                                         wcross_origin = wcross_oldorigin;
 895                         }
 896                         else
 897                                 shottype = SHOTTYPE_HITWORLD;
 898
 899                         vector wcross_color, wcross_size;
 900                         string wcross_wep, wcross_name;
 901                         float wcross_scale, wcross_blur;
 902
 903                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 904                                 e = get_weaponinfo(activeweapon);
 905                                 if (e && e.netname != "")
 906                                 {
 907                                         wcross_wep = e.netname;
 908                                         if(autocvar_crosshair_per_weapon)
 909                                         {
 910                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 911                                                 if (wcross_resolution == 0)
 912                                                         return;
 913                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 914                                                 if (wcross_alpha == 0)
 915                                                         return;
 916
 917                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 918                                                 if(wcross_style == "" || wcross_style == "0")
 919                                                         wcross_style = wcross_wep;
 920                                         }
 921                                 }
 922                         }
 923                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 924                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 925                         else if(autocvar_crosshair_color_by_health)
 926                         {
 927                                 local float x = getstati(STAT_HEALTH);
 928
 929                                 //x = red
 930                                 //y = green
 931                                 //z = blue
 932
 933                                 wcross_color_z = 0;
 934
 935                                 if(x > 200)
 936                                 {
 937                                         wcross_color_x = 0;
 938                                         wcross_color_y = 1;
 939                                 }
 940                                 else if(x > 150)
 941                                 {
 942                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 943                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 944                                 }
 945                                 else if(x > 100)
 946                                 {
 947                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 948                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 949                                         wcross_color_z = 1 - (x-100)*0.02;
 950                                 }
 951                                 else if(x > 50)
 952                                 {
 953                                         wcross_color_x = 1;
 954                                         wcross_color_y = 1;
 955                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 956                                 }
 957                                 else if(x > 20)
 958                                 {
 959                                         wcross_color_x = 1;
 960                                         wcross_color_y = (x-20)*90/27/100;
 961                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 962                                 }
 963                                 else
 964                                 {
 965                                         wcross_color_x = 1;
 966                                         wcross_color_y = 0;
 967                                 }
 968                         }
 969                         else
 970                                 wcross_color = stov(autocvar_crosshair_color);
 971
 972                         wcross_name = strcat("gfx/crosshair", wcross_style);
 973
 974                         if(autocvar_crosshair_effect_scalefade)
 975                         {
 976                                 wcross_scale = wcross_resolution;
 977                                 wcross_resolution = 1;
 978                         }
 979                         else
 980                         {
 981                                 wcross_scale = 1;
 982                         }
 983
 984                         if(autocvar_crosshair_pickup)
 985                         {
 986                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
 987                                 {
 988                                         pickup_crosshair_size = 1;
 989                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
 990                                 }
 991
 992                                 if(pickup_crosshair_size > 0)
 993                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 994                                 else
 995                                         pickup_crosshair_size = 0;
 996
 997                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 998                         }
 999
1000                         vector hitindication_color;
1001                         if(autocvar_crosshair_hitindication)
1002                         {
1003                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1004                                 if(hitindication_crosshair_time < hit_time)
1005                                 {
1006                                         hitindication_crosshair_size = 1;
1007                                         hitindication_crosshair_time = hit_time;
1008                                 }
1009
1010                                 if(hitindication_crosshair_size > 0)
1011                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1012                                 else
1013                                         hitindication_crosshair_size = 0;
1014
1015                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1016                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1017                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1018                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1019                         }
1020
1021                         if(shottype == SHOTTYPE_HITENEMY)
1022                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1023                         if(shottype == SHOTTYPE_HITTEAM)
1024                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1025
1026                         f = autocvar_crosshair_effect_speed;
1027                         if(f < 0)
1028                                 f *= -2 * g_weaponswitchdelay;
1029                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1030                         {
1031                                 wcross_changedonetime = time + f;
1032                         }
1033                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1034                         {
1035                                 wcross_name_changestarttime = time;
1036                                 wcross_name_changedonetime = time + f;
1037                                 if(wcross_name_goal_prev_prev)
1038                                         strunzone(wcross_name_goal_prev_prev);
1039                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1040                                 wcross_name_goal_prev = strzone(wcross_name);
1041                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1042                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1043                                 wcross_resolution_goal_prev = wcross_resolution;
1044                         }
1045
1046                         wcross_scale_goal_prev = wcross_scale;
1047                         wcross_alpha_goal_prev = wcross_alpha;
1048                         wcross_color_goal_prev = wcross_color;
1049
1050                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1051                         {
1052                                 wcross_blur = 1;
1053                                 wcross_alpha *= 0.75;
1054                         }
1055                         else
1056                                 wcross_blur = 0;
1057                         // *_prev is at time-frametime
1058                         // * is at wcross_changedonetime+f
1059                         // what do we have at time?
1060                         if(time < wcross_changedonetime)
1061                         {
1062                                 f = frametime / (wcross_changedonetime - time + frametime);
1063                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1064                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1065                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1066                         }
1067
1068                         wcross_scale_prev = wcross_scale;
1069                         wcross_alpha_prev = wcross_alpha;
1070                         wcross_color_prev = wcross_color;
1071
1072                         wcross_scale *= 1 - autocvar__menu_alpha;
1073                         wcross_alpha *= 1 - autocvar__menu_alpha;
1074                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1075
1076                         // crosshair rings for weapon stats
1077                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1078                         {
1079                                 // declarations and stats
1080                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1081                                 string ring_image, ring_inner_image;
1082                                 vector ring_rgb, ring_inner_rgb;
1083
1084                                 ring_scale = autocvar_crosshair_ring_size;
1085
1086                                 float weapon_clipload, weapon_clipsize;
1087                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1088                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1089
1090                                 float nex_charge, nex_chargepool;
1091                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1092                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1093
1094                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1095                                         nex_charge_movingavg = nex_charge;
1096
1097
1098                                 // handle the values
1099                                 if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1100                                 {
1101                                         if (nex_chargepool || use_nex_chargepool) {
1102                                                 use_nex_chargepool = 1;
1103                                                 ring_inner_value = nex_chargepool;
1104                                         } else {
1105                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1106                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1107                                         }
1108
1109                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1110                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1111                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1112
1113                                         // draw the outer ring to show the current charge of the weapon
1114                                         ring_value = nex_charge;
1115                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1116                                         ring_rgb = wcross_color;
1117                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1118                                 }
1119                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1120                                 {
1121                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1122                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1123                                         ring_rgb = wcross_color;
1124                                         ring_image = "gfx/crosshair_ring.tga";
1125                                 }
1126                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1127                                 {
1128                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1129                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1130                                         ring_rgb = wcross_color;
1131                                         ring_image = "gfx/crosshair_ring.tga";
1132                                 }
1133
1134                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1135                                 {
1136                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1137                                         ring_scale = autocvar_crosshair_ring_reload_size;
1138                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1139                                         ring_rgb = wcross_color;
1140
1141                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1142                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1143                                         if ((activeweapon == WEP_SNIPERRIFLE) && (weapon_clipsize == 80))
1144                                                 ring_image = "gfx/crosshair_ring_sniperrifle.tga";
1145                                         else
1146                                                 ring_image = "gfx/crosshair_ring.tga";
1147                                 }
1148
1149                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1150                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1151
1152                                 if (ring_value)
1153                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1154                         }
1155
1156 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1157                         do \
1158                         { \
1159                                 if(wcross_blur > 0) \
1160                                 { \
1161                                         for(i = -2; i <= 2; ++i) \
1162                                                 for(j = -2; j <= 2; ++j) \
1163                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1164                                 } \
1165                                 else \
1166                                 { \
1167                                         M(0,0,sz,wcross_name,wcross_alpha); \
1168                                 } \
1169                         } \
1170                         while(0)
1171
1172 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1173                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1174
1175 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1176                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1177
1178                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1179                         {
1180                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1181                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1182                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1183                                 f = 1 - f;
1184                         }
1185                         else
1186                         {
1187                                 f = 1;
1188                         }
1189
1190                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1191                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1192
1193                         if(autocvar_crosshair_dot)
1194             {
1195                 vector wcross_color_old;
1196                 wcross_color_old = wcross_color;
1197                 if(autocvar_crosshair_dot_color != "0")
1198                     wcross_color = stov(autocvar_crosshair_dot_color);
1199                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1200                 wcross_color = wcross_color_old;
1201             }
1202
1203                         wcross_name_alpha_goal_prev = f;
1204                 }
1205                 else
1206                 {
1207                         wcross_scale_prev = 0;
1208                         wcross_alpha_prev = 0;
1209                         wcross_scale_goal_prev = 0;
1210                         wcross_alpha_goal_prev = 0;
1211                         wcross_changedonetime = 0;
1212                         if(wcross_name_goal_prev)
1213                                 strunzone(wcross_name_goal_prev);
1214                         wcross_name_goal_prev = string_null;
1215                         if(wcross_name_goal_prev_prev)
1216                                 strunzone(wcross_name_goal_prev_prev);
1217                         wcross_name_goal_prev_prev = string_null;
1218                         wcross_name_changestarttime = 0;
1219                         wcross_name_changedonetime = 0;
1220                         wcross_name_alpha_goal_prev = 0;
1221                         wcross_name_alpha_goal_prev_prev = 0;
1222                         wcross_resolution_goal_prev = 0;
1223                         wcross_resolution_goal_prev_prev = 0;
1224                 }
1225         }
1226
1227         if(NextFrameCommand)
1228         {
1229                 localcmd("\n", NextFrameCommand, "\n");
1230                 NextFrameCommand = string_null;
1231         }
1232
1233         // we must do this check AFTER a frame was rendered, or it won't work
1234         if(cs_project_is_b0rked == 0)
1235         {
1236                 string w0, h0;
1237                 w0 = ftos(autocvar_vid_conwidth);
1238                 h0 = ftos(autocvar_vid_conheight);
1239                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1240                 //R_SetView(VF_FOV, '90 90 0');
1241                 R_SetView(VF_ORIGIN, '0 0 0');
1242                 R_SetView(VF_ANGLES, '0 0 0');
1243                 R_SetView(VF_PERSPECTIVE, 1);
1244                 makevectors('0 0 0');
1245                 vector v1, v2;
1246                 cvar_set("vid_conwidth", "800");
1247                 cvar_set("vid_conheight", "600");
1248                 v1 = cs_project(v_forward);
1249                 cvar_set("vid_conwidth", "640");
1250                 cvar_set("vid_conheight", "480");
1251                 v2 = cs_project(v_forward);
1252                 if(v1 == v2)
1253                         cs_project_is_b0rked = 1;
1254                 else
1255                         cs_project_is_b0rked = -1;
1256                 cvar_set("vid_conwidth", w0);
1257                 cvar_set("vid_conheight", h0);
1258         }
1259
1260         if(autocvar__hud_configure)
1261                 HUD_Panel_Mouse();
1262
1263         // let's reset the view back to normal for the end
1264         R_SetView(VF_MIN, '0 0 0');
1265         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1266 }
1267
1268 #define spider_h "gfx/vehicles/hud_bg.tga"
1269 #define spider_b "gfx/vehicles/sbot.tga"
1270 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1271 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1272 #define spider_s "gfx/vehicles/shiled.tga"
1273 #define spider_a1 "gfx/hud/sb_rocket.tga"
1274 #define spider_a2 "gfx/sb_bullets.tga"
1275
1276 void CSQC_SPIDER_HUD()
1277 {
1278         float rockets, reload, heat, hp, shield;
1279         vector picsize, hudloc;
1280
1281     // Fetch health & ammo stats
1282     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1283         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1284         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1285         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1286         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1287
1288     // Draw the crosshairs
1289     picsize = drawgetimagesize(SPIDER_CROSS);
1290     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1291     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1292     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1293
1294     hudloc_y =  4;
1295     hudloc_x = 4;
1296
1297     picsize = drawgetimagesize(spider_h) * 0.5;
1298     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1299
1300     picsize = drawgetimagesize(spider_a2) * 0.5;
1301     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1302
1303     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1304     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1305     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1306
1307     picsize = drawgetimagesize(spider_a1) * 0.85;
1308     if(rockets == 9)
1309     {
1310         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1311         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1312     }
1313     else
1314     {
1315         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1316         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1317     }
1318
1319     picsize = drawgetimagesize(spider_b) * 0.5;
1320     hudloc_y = 10.5;
1321     hudloc_x = 10.5;
1322
1323     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1324     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1325     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1326     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1327
1328
1329         /*
1330         // Draw health bar
1331         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1332         p = p + '0 1 0' * vid_conheight - '0 32 0';
1333         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1334         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1335         p_y += 8;
1336         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1337         p_x += 256 * hp;
1338         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1339
1340         // Draw minigun heat indicator
1341         p = '0.5 0 0' * (vid_conwidth - 256);
1342         p = p + '0 1 0' * vid_conheight - '0 34  0';
1343         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1344         p_x += 256 * (1-heat);
1345         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1346
1347
1348         // Draw rocket icons for loaded/empty tubes.
1349         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1350         pp += '0 1 0' * vid_conheight - '0 64 0';
1351         for(i = 0; i < 8; ++i)
1352         {
1353                 p = pp + '1 0 0' * (rkt_size * i);
1354                 if(rockets == 8)
1355                 {
1356                         if(floor(reload * 8) == i)
1357                         {
1358                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1359                         }
1360                         else if(i < reload * 8)
1361                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1362                         else
1363                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1364                 }
1365                 else
1366                 {
1367                         if(i < rockets)
1368                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1369                         else
1370                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1371                 }
1372         }
1373         */
1374
1375         if (scoreboard_showscores)
1376         {
1377                 HUD_DrawScoreboard();
1378                 HUD_DrawCenterPrint();
1379         }
1380
1381 }
1382
1383 #define raptor_h "gfx/vehicles/hud_bg.tga"
1384 #define raptor_b "gfx/vehicles/raptor.tga"
1385 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1386 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1387 #define raptor_s "gfx/vehicles/shiled.tga"
1388
1389 void CSQC_RAPTOR_HUD()
1390 {
1391         float reload, hp, shield, energy;
1392         vector picsize, hudloc;
1393
1394     // Fetch health & ammo stats
1395     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1396         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1397         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1398         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1399
1400     // Draw the crosshairs
1401     picsize = drawgetimagesize(SPIDER_CROSS);
1402     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1403     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1404     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1405
1406     hudloc_y =  4;
1407     hudloc_x = 4;
1408
1409     picsize = drawgetimagesize(raptor_h) * 0.5;
1410     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1411
1412     picsize = drawgetimagesize(spider_a2) * 0.5;
1413     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1414
1415     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1416     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1417     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1418
1419
1420     picsize = drawgetimagesize(spider_a1) * 0.85;
1421     if(reload == 1)
1422     {
1423         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1424         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1425     }
1426     else
1427     {
1428         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1429         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1430     }
1431
1432     picsize = drawgetimagesize(raptor_b) * 0.5;
1433     hudloc_y = 10.5;
1434     hudloc_x = 10.5;
1435
1436     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1437     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1438     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1439     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1440
1441
1442         if (scoreboard_showscores)
1443         {
1444                 HUD_DrawScoreboard();
1445                 HUD_DrawCenterPrint();
1446         }
1447
1448 }
1449
1450 #define waki_h "gfx/vehicles/hud_bg.tga"
1451 #define waki_b "gfx/vehicles/waki.tga"
1452 #define waki_e "gfx/vehicles/waki_e.tga"
1453 #define waki_g "gfx/vehicles/waki_guns.tga"
1454 #define waki_r "gfx/vehicles/waki_rockets.tga"
1455 #define waki_s "gfx/vehicles/shiled.tga"
1456
1457 #define waki_a1 "gfx/hud/sb_rocket.tga"
1458 #define waki_a2 "gfx/sb_cells.tga"
1459
1460 void CSQC_WAKIZASHI_HUD()
1461 {
1462         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1463         float health, shield, energy, rockets;
1464         vector picsize, hudloc;
1465
1466     picsize = drawgetimagesize(SPIDER_CROSS);
1467     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1468     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1469     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1470
1471 /*
1472 const float STAT_VEHICLESTAT_HEALTH  = 60;
1473 const float STAT_VEHICLESTAT_SHIELD  = 61;
1474 const float STAT_VEHICLESTAT_ENERGY  = 62;
1475 const float STAT_VEHICLESTAT_AMMO1   = 63;
1476 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1477 const float STAT_VEHICLESTAT_AMMO2   = 65;
1478 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1479 */
1480     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1481         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1482         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1483         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1484
1485     hudloc_y =  4;
1486     hudloc_x = 4;
1487
1488     picsize = drawgetimagesize(waki_h) * 0.5;
1489     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1490
1491     picsize = drawgetimagesize(waki_a2) * 0.7;
1492     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1493
1494
1495     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1496     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1497
1498     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1499
1500     picsize = drawgetimagesize(waki_a1) * 0.75;
1501     if(rockets == 1)
1502     {
1503         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1504         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1505     }
1506     else
1507     {
1508         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1509         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1510         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1511     }
1512
1513     picsize = drawgetimagesize(waki_b) * 0.5;
1514     hudloc_y = 10.5;
1515     hudloc_x = 10.5;
1516
1517     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1518     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1519     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1520     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1521
1522
1523
1524         /*
1525         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1526         p = p + '0 1 0' * vid_conheight - '0 32 0';
1527
1528         // Draw health bar
1529         p_y += 8;
1530         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1531         p_x += 256 * health;
1532         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1533
1534         // Draw shiled bar
1535         p_x -= 256 * health;
1536         p_y += 4;
1537         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1538
1539         // Draw energy
1540         //p_x -= 256 * health;
1541         p_y -= 8;
1542         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1543
1544         // Draw rockets bar
1545         p_y += 12;
1546         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1547         */
1548
1549
1550
1551
1552         if (scoreboard_showscores)
1553         {
1554                 HUD_DrawScoreboard();
1555                 HUD_DrawCenterPrint();
1556         }
1557
1558 }
1559
1560
1561 void CSQC_common_hud(void)
1562 {
1563         // HUD_SortFrags(); done in HUD_Draw
1564         float hud;
1565         hud = getstati(STAT_HUD);
1566
1567         //hud = 10;
1568         switch(hud)
1569         {
1570                 case HUD_NORMAL:
1571                         // do some accuracy var caching
1572                         float i;
1573                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1574                         {
1575                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1576                                 {
1577                                         if(acc_color_levels)
1578                                                 strunzone(acc_color_levels);
1579                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1580                                         acc_levels = tokenize(acc_color_levels);
1581                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1582                                                 acc_levels = MAX_ACCURACY_LEVELS;
1583
1584                                         for (i = 0; i < acc_levels; ++i)
1585                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1586                                 }
1587                                 // let know that acc_col[] needs to be loaded
1588                                 acc_col_x[0] = -1;
1589                         }
1590
1591                         HUD_Main(); // always run these functions for alpha checks
1592                         HUD_DrawScoreboard();
1593
1594                         if (scoreboard_active) // scoreboard/accuracy
1595                         {
1596                                 HUD_Reset();
1597                                 // HUD_DrawScoreboard takes care of centerprint_start
1598                         }
1599                         else if (intermission == 2) // map voting screen
1600                         {
1601                                 HUD_FinaleOverlay();
1602                                 HUD_Reset();
1603
1604                                 centerprint_start_x = 0;
1605                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1606                         }
1607                         else // hud
1608                         {
1609                                 centerprint_start_x = 0;
1610                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1611                         }
1612
1613                         HUD_DrawCenterPrint();
1614                         break;
1615
1616                 case HUD_SPIDERBOT:
1617                         CSQC_SPIDER_HUD();
1618                         break;
1619
1620                 case HUD_WAKIZASHI:
1621                         CSQC_WAKIZASHI_HUD();
1622                         break;
1623         }
1624 }
1625
1626
1627 // following vectors must be global to allow seamless switching between camera modes
1628 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1629 void CSQC_Demo_Camera()
1630 {
1631         float speed, attenuation, dimensions;
1632         vector tmp, delta;
1633
1634         if( autocvar_camera_reset || !camera_mode )
1635         {
1636                 camera_offset = '0 0 0';
1637                 current_angles = '0 0 0';
1638                 camera_direction = '0 0 0';
1639                 camera_offset_z += 30;
1640                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1641                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1642                 current_origin = view_origin;
1643                 current_camera_offset  = camera_offset;
1644                 cvar_set("camera_reset", "0");
1645                 camera_mode = CAMERA_CHASE;
1646         }
1647
1648         // Camera angles
1649         if( camera_roll )
1650                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1651
1652         if(autocvar_camera_look_player)
1653         {
1654                 local vector dir;
1655                 local float n;
1656
1657                 dir = normalize(view_origin - current_position);
1658                 n = mouse_angles_z;
1659                 mouse_angles = vectoangles(dir);
1660                 mouse_angles_x = mouse_angles_x * -1;
1661                 mouse_angles_z = n;
1662         }
1663         else
1664         {
1665                 tmp = getmousepos() * 0.1;
1666                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1667                 {
1668                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1669                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1670                 }
1671         }
1672
1673         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1674         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1675         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1676         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1677
1678         // Fix difference when angles don't have the same sign
1679         delta = '0 0 0';
1680         if(mouse_angles_y < -60 && current_angles_y > 60)
1681                 delta = '0 360 0';
1682         if(mouse_angles_y > 60 && current_angles_y < -60)
1683                 delta = '0 -360 0';
1684
1685         if(autocvar_camera_look_player)
1686                 attenuation = autocvar_camera_look_attenuation;
1687         else
1688                 attenuation = autocvar_camera_speed_attenuation;
1689
1690         attenuation = 1 / max(1, attenuation);
1691         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1692
1693         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1694         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1695         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1696         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1697
1698         // Camera position
1699         tmp = '0 0 0';
1700         dimensions = 0;
1701
1702         if( camera_direction_x )
1703         {
1704                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1705                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1706                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1707                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1708                 ++dimensions;
1709         }
1710
1711         if( camera_direction_y )
1712         {
1713                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1714                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1715                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1716                 ++dimensions;
1717         }
1718
1719         if( camera_direction_z )
1720         {
1721                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1722                 ++dimensions;
1723         }
1724
1725         if(autocvar_camera_free)
1726                 speed = autocvar_camera_speed_free;
1727         else
1728                 speed = autocvar_camera_speed_chase;
1729
1730         if(dimensions)
1731         {
1732                 speed = speed * sqrt(1 / dimensions);
1733                 camera_offset += tmp * speed;
1734         }
1735
1736         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1737
1738         // Camera modes
1739         if( autocvar_camera_free )
1740         {
1741                 if ( camera_mode == CAMERA_CHASE )
1742                 {
1743                         current_camera_offset = current_origin + current_camera_offset;
1744                         camera_offset = current_origin + camera_offset;
1745                 }
1746
1747                 camera_mode = CAMERA_FREE;
1748                 current_position = current_camera_offset;
1749         }
1750         else
1751         {
1752                 if ( camera_mode == CAMERA_FREE )
1753                 {
1754                         current_origin = view_origin;
1755                         camera_offset = camera_offset - current_origin;
1756                         current_camera_offset = current_camera_offset - current_origin;
1757                 }
1758
1759                 camera_mode = CAMERA_CHASE;
1760
1761                 if(autocvar_camera_chase_smoothly)
1762                         current_origin += (view_origin - current_origin) * attenuation;
1763                 else
1764                         current_origin = view_origin;
1765
1766                 current_position = current_origin + current_camera_offset;
1767         }
1768
1769         R_SetView(VF_ANGLES, current_angles);
1770         R_SetView(VF_ORIGIN, current_position);
1771 }