qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float trace_dphitcontents;
   4 float trace_networkentity;
   5 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   6 float DPCONTENTS_SOLID = 1; // blocks player movement
   7 float DPCONTENTS_BODY = 32; // blocks player movement
   8 float DPCONTENTS_CORPSE = 64; // blocks player movement
   9 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  10 void Porto_Draw()
  11 {
  12         vector p, dir, ang, q, nextdir;
  13         float idx, portal_number, portal1_idx;
  14
  15         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                         portal1_idx = idx;
  61                 if(portal_number >= 2)
  62                         break;
  63         }
  64
  65         while(idx >= 2)
  66         {
  67                 p = polyline[idx-2];
  68                 q = polyline[idx-1];
  69                 if(idx == 2)
  70                         p = p - view_up * 16;
  71                 if(idx-1 >= portal1_idx)
  72                 {
  73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  74                 }
  75                 else
  76                 {
  77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  78                 }
  79                 --idx;
  80         }
  81 }
  82
  83 /**
  84  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  85  *
  86  * TODO: Use a better solution where a common shared entitiy is used that contains
  87  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  88  * and STAT_FRAGLIMIT to be auto-sent)
  89  */
  90 void CheckForGamestartChange() {
  91         float startTime;
  92         startTime = getstatf(STAT_GAMESTARTTIME);
  93         if (previous_game_starttime != startTime) {
  94                 if ((time + 5.0) < startTime) {
  95                         //if connecting to server while restart was active don't always play prepareforbattle
  96                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  97                 }
  98                 if (time < startTime) {
  99                         restartAnnouncer = spawn();
 100                         restartAnnouncer.think = restartAnnouncer_Think;
 101                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 102                 }
 103         }
 104         previous_game_starttime = startTime;
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 120
 121         zoomsensitivity = autocvar_cl_zoomsensitivity;
 122         zoomfactor = autocvar_cl_zoomfactor;
 123         if(zoomfactor < 1 || zoomfactor > 16)
 124                 zoomfactor = 2.5;
 125         zoomspeed = autocvar_cl_zoomspeed;
 126         if(zoomspeed >= 0)
 127                 if(zoomspeed < 0.5 || zoomspeed > 16)
 128                         zoomspeed = 3.5;
 129
 130         zoomdir = button_zoom;
 131         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 132                 zoomdir += button_attack2;
 133         if(spectatee_status > 0 || isdemo())
 134         {
 135                 if(spectatorbutton_zoom)
 136                         zoomdir = 0 + !zoomdir;
 137                 // do not even THINK about removing this 0
 138                 // _I_ know what I am doing
 139                 // fteqcc does not
 140         }
 141
 142         if(zoomdir)
 143                 zoomin_effect = 0;
 144
 145         if(zoomin_effect || camera_active)
 146         {
 147                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 148         }
 149         else
 150         {
 151                 if(zoomspeed < 0) // instant zoom
 152                 {
 153                         if(zoomdir)
 154                                 current_viewzoom = 1 / zoomfactor;
 155                         else
 156                                 current_viewzoom = 1;
 157                 }
 158                 else
 159                 {
 160                         if(zoomdir)
 161                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 162                         else
 163                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 164                 }
 165         }
 166
 167         if(almost_equals(current_viewzoom, 1))
 168                 current_zoomfraction = 0;
 169         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 170                 current_zoomfraction = 1;
 171         else
 172                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 173
 174         if(zoomsensitivity < 1)
 175                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 176         else
 177                 setsensitivityscale(1);
 178
 179         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 180         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 181         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 182
 183         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 184
 185         float frustumx, frustumy, fovx, fovy;
 186         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 187         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 188         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 189         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 190
 191         return '1 0 0' * fovx + '0 1 0' * fovy;
 192 }
 193
 194 // this function must match W_SetupShot!
 195 float zoomscript_caught;
 196
 197 vector wcross_origin;
 198 float wcross_scale_prev, wcross_alpha_prev;
 199 vector wcross_color_prev;
 200 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 201 vector wcross_color_goal_prev;
 202 float wcross_changedonetime;
 203
 204 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 205 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 206 float wcross_name_changestarttime, wcross_name_changedonetime;
 207 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 208 entity trueaim;
 209 entity trueaim_rifle;
 210
 211 #define SHOTTYPE_HITTEAM 1
 212 #define SHOTTYPE_HITOBSTRUCTION 2
 213 #define SHOTTYPE_HITWORLD 3
 214 #define SHOTTYPE_HITENEMY 4
 215
 216 void TrueAim_Init()
 217 {
 218         trueaim = spawn();
 219         trueaim.classname = "trueaim";
 220         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 221         trueaim_rifle = spawn();
 222         trueaim_rifle.classname = "trueaim_rifle";
 223         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 224 }
 225
 226 float EnemyHitCheck()
 227 {
 228         float t;
 229         wcross_origin = project_3d_to_2d(trace_endpos);
 230         wcross_origin_z = 0;
 231         if(trace_networkentity < 1)
 232                 return SHOTTYPE_HITWORLD;
 233         if(trace_networkentity > maxclients)
 234                 return SHOTTYPE_HITWORLD;
 235         t = GetPlayerColor(trace_networkentity - 1);
 236         if(teamplay)
 237                 if(t == myteam)
 238                         return SHOTTYPE_HITTEAM;
 239         if(t == COLOR_SPECTATOR)
 240                 return SHOTTYPE_HITWORLD;
 241         return SHOTTYPE_HITENEMY;
 242 }
 243
 244 float TrueAimCheck()
 245 {
 246         float nudge = 1; // added to traceline target and subtracted from result
 247         vector vecs, trueaimpoint, w_shotorg;
 248         vector mi, ma, dv;
 249         float shottype;
 250         entity ta;
 251         float mv;
 252
 253         mi = ma = '0 0 0';
 254         ta = trueaim;
 255         mv = MOVE_NOMONSTERS;
 256
 257         switch(activeweapon)
 258         {
 259                 case WEP_TUBA: // no aim
 260                 case WEP_PORTO: // shoots from eye
 261                 case WEP_HOOK: // no trueaim
 262                 case WEP_GRENADE_LAUNCHER: // toss curve
 263                         return SHOTTYPE_HITWORLD;
 264                 case WEP_NEX:
 265                 case WEP_MINSTANEX:
 266                         mv = MOVE_NORMAL;
 267                         break;
 268                 case WEP_SNIPERRIFLE:
 269                         ta = trueaim_rifle;
 270                         mv = MOVE_NORMAL;
 271                         if(zoomscript_caught)
 272                         {
 273                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 274                                 return EnemyHitCheck();
 275                         }
 276                         break;
 277                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 278                         mi = '-3 -3 -3';
 279                         ma = '3 3 3';
 280                         break;
 281                 case WEP_FIREBALL: // projectile has a size!
 282                         mi = '-16 -16 -16';
 283                         ma = '16 16 16';
 284                         break;
 285                 case WEP_SEEKER: // projectile has a size!
 286                         mi = '-2 -2 -2';
 287                         ma = '2 2 2';
 288                         break;
 289                 case WEP_ELECTRO: // projectile has a size!
 290                         mi = '0 0 -3';
 291                         ma = '0 0 -3';
 292                         break;
 293         }
 294
 295         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 296
 297         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 298         trueaimpoint = trace_endpos;
 299
 300         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 301                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 302
 303         if(vecs_x > 0)
 304                 vecs_y = -vecs_y;
 305         else
 306                 vecs = '0 0 0';
 307
 308         dv = view_right * vecs_y + view_up * vecs_z;
 309         w_shotorg = view_origin + dv;
 310
 311         // now move the vecs forward as much as requested if possible
 312         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 313         w_shotorg = trace_endpos - view_forward * nudge;
 314
 315         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 316         shottype = EnemyHitCheck();
 317         if(shottype != SHOTTYPE_HITWORLD)
 318                 return shottype;
 319
 320 #if 0
 321         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 322         // or rather, I know why, but see no fix
 323         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 324                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 325                 return SHOTTYPE_HITOBSTRUCTION;
 326 #endif
 327
 328         return SHOTTYPE_HITWORLD;
 329 }
 330
 331 void CSQC_common_hud(void);
 332
 333 void PostInit(void);
 334 void CSQC_Demo_Camera();
 335 float HUD_WouldDrawScoreboard();
 336 float view_set;
 337 float camera_mode;
 338 float reticle_type;
 339 string NextFrameCommand;
 340 void CSQC_SPIDER_HUD();
 341 void CSQC_RAPTOR_HUD();
 342
 343 vector freeze_pmove_org, freeze_input_angles;
 344 entity nightvision_noise, nightvision_noise2;
 345
 346 float pickup_crosshair_time, pickup_crosshair_size;
 347 float hit_time, typehit_time;
 348 float nextsound_hit_time, nextsound_typehit_time;
 349 float hitindication_crosshair_time, hitindication_crosshair_size;
 350 float use_nex_chargepool;
 351
 352 float myhealth, myhealth_prev;
 353 float myhealth_flash;
 354
 355 vector myhealth_gentlergb;
 356
 357 float contentavgalpha, liquidalpha_prev;
 358 vector liquidcolor_prev;
 359
 360 float eventchase_current_distance;
 361
 362 float checkfail[16];
 363
 364 void CSQC_UpdateView(float w, float h)
 365 {
 366         entity e;
 367         float fov;
 368         float f, i, j;
 369         vector v, vo;
 370         vector vf_size, vf_min;
 371         float a;
 372         float hud;
 373         hud = getstati(STAT_HUD);
 374
 375         button_attack2 = (input_buttons & BUTTON_3);
 376         button_zoom = (input_buttons & BUTTON_4);
 377
 378 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 379         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 380         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 381         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 382         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 383         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 384         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 385
 386         vf_size = R_SetView3fv(VF_SIZE);
 387         vf_min = R_SetView3fv(VF_MIN);
 388         vid_width = vf_size_x;
 389         vid_height = vf_size_y;
 390
 391         vector reticle_pos, reticle_size;
 392         vector splash_pos, splash_size;
 393
 394         WaypointSprite_Load();
 395
 396         if(spectatee_status)
 397                 myteam = GetPlayerColor(spectatee_status - 1);
 398         else
 399                 myteam = GetPlayerColor(player_localentnum - 1);
 400
 401         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 402         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 403
 404         warpzone_fixview_origin = pmove_org + vo;
 405         warpzone_fixview_cl_viewangles = input_angles;
 406         warpzone_fixview_angles = view_angles;
 407         WarpZone_FixView();
 408         pmove_org = warpzone_fixview_origin - vo;
 409         input_angles = warpzone_fixview_cl_viewangles;
 410         view_angles = warpzone_fixview_angles;
 411
 412         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 413         {
 414                 pmove_org = freeze_pmove_org;
 415                 input_angles = view_angles = freeze_input_angles;
 416                 R_SetView(VF_ORIGIN, pmove_org + vo);
 417                 R_SetView(VF_ANGLES, view_angles);
 418                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 419         }
 420         freeze_pmove_org = pmove_org;
 421         freeze_input_angles = input_angles;
 422
 423         // event chase camera
 424         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 425         {
 426                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || (autocvar_cl_eventchase_intermission && intermission))
 427                 {
 428                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 429                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 430                         if(!autocvar_chase_active)
 431                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 432
 433                         // make the camera smooth back
 434                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 435                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 436                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 437                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 438
 439                         vector eventchase_target_origin;
 440                         makevectors(view_angles);
 441                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 442                         eventchase_target_origin = pmove_org - v_forward * eventchase_current_distance;
 443
 444                         traceline(pmove_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 445                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 446                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 447                         eventchase_target_origin = pmove_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 448
 449                         R_SetView(VF_ORIGIN, eventchase_target_origin);
 450                         R_SetView(VF_ANGLES, view_angles);
 451                 }
 452                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 453                 {
 454                         cvar_set("chase_active", "0");
 455                         eventchase_current_distance = 0; // start from 0 next time
 456                 }
 457         }
 458
 459         // Render the Scene
 460         if(!intermission || !view_set || (intermission && autocvar_cl_eventchase_intermission))
 461         {
 462             #ifdef VEHICLES_CSQC
 463             if(hud)
 464             {
 465             view_origin = vehicle_hudmodel.origin; //pmove_org + vo + randomvec() * 20;
 466             view_angles = input_angles;
 467             R_SetView(VF_ORIGIN, view_origin);
 468             makevectors(view_angles);
 469             view_forward = v_forward;
 470             view_right = v_right;
 471             view_up = v_up;
 472             view_set = 1;
 473             }
 474             else
 475             {
 476         #endif
 477             view_origin = pmove_org + vo;
 478             view_angles = input_angles;
 479             makevectors(view_angles);
 480             view_forward = v_forward;
 481             view_right = v_right;
 482             view_up = v_up;
 483             view_set = 1;
 484             #ifdef VEHICLES_CSQC
 485             }
 486         #endif
 487         }
 488
 489 #ifdef BLURTEST
 490         if(time > blurtest_time0 && time < blurtest_time1)
 491         {
 492                 float r, t;
 493
 494                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 495                 r = t * blurtest_radius;
 496                 f = 1 / pow(t, blurtest_power) - 1;
 497
 498                 cvar_set("r_glsl_postprocess", "1");
 499                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 500         }
 501         else
 502         {
 503                 cvar_set("r_glsl_postprocess", "0");
 504                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 505         }
 506 #endif
 507
 508         TargetMusic_Advance();
 509         Fog_Force();
 510
 511         drawframetime = max(0.000001, time - drawtime);
 512         drawtime = time;
 513
 514         // watch for gametype changes here...
 515         // in ParseStuffCMD the cmd isn't executed yet :/
 516         // might even be better to add the gametype to TE_CSQC_INIT...?
 517         if(!postinit)
 518                 PostInit();
 519
 520         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 521                 if(calledhooks & HOOK_START)
 522                 {
 523                         localcmd("\ncl_hook_gameend\n");
 524                         calledhooks |= HOOK_END;
 525                 }
 526
 527         CheckForGamestartChange();
 528         serverAnnouncer();
 529         maptimeAnnouncer();
 530         carrierAnnouncer();
 531
 532         fov = autocvar_fov;
 533         if(fov <= 59.5)
 534         {
 535                 if(!zoomscript_caught)
 536                 {
 537                         localcmd("+button9\n");
 538                         zoomscript_caught = 1;
 539                 }
 540         }
 541         else
 542         {
 543                 if(zoomscript_caught)
 544                 {
 545                         localcmd("-button9\n");
 546                         zoomscript_caught = 0;
 547                 }
 548         }
 549
 550         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 551         activeweapon = getstati(STAT_SWITCHWEAPON);
 552         f = (serverflags & SERVERFLAG_TEAMPLAY);
 553         if(f != teamplay)
 554         {
 555                 teamplay = f;
 556                 HUD_InitScores();
 557         }
 558
 559         if(last_weapon != activeweapon) {
 560                 weapontime = time;
 561                 last_weapon = activeweapon;
 562
 563                 e = get_weaponinfo(activeweapon);
 564                 if(e.netname != "")
 565                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 566                 else
 567                         localcmd("\ncl_hook_activeweapon none\n");
 568         }
 569
 570         // ALWAYS Clear Current Scene First
 571         R_ClearScene();
 572
 573         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 574         R_SetView(VF_SIZE, vf_size);
 575         R_SetView(VF_MIN, vf_min);
 576
 577         // Assign Standard Viewflags
 578         // Draw the World (and sky)
 579         R_SetView(VF_DRAWWORLD, 1);
 580
 581         // Set the console size vars
 582         vid_conwidth = autocvar_vid_conwidth;
 583         vid_conheight = autocvar_vid_conheight;
 584         vid_pixelheight = autocvar_vid_pixelheight;
 585
 586         R_SetView(VF_FOV, GetCurrentFov(fov));
 587
 588         // Camera for demo playback
 589         if(camera_active)
 590         {
 591                 if(autocvar_camera_enable)
 592                         CSQC_Demo_Camera();
 593                 else
 594                 {
 595                         cvar_set("chase_active", ftos(chase_active_backup));
 596                         cvar_set("cl_demo_mousegrab", "0");
 597                         camera_active = FALSE;
 598                 }
 599         }
 600 #ifdef CAMERATEST
 601         else if(autocvar_camera_enable)
 602 #else
 603         else if(autocvar_camera_enable && isdemo())
 604 #endif
 605         {
 606                 // Enable required Darkplaces cvars
 607                 chase_active_backup = autocvar_chase_active;
 608                 cvar_set("chase_active", "2");
 609                 cvar_set("cl_demo_mousegrab", "1");
 610                 camera_active = TRUE;
 611                 camera_mode = FALSE;
 612         }
 613
 614         // Draw the Crosshair
 615         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 616
 617         // Draw the Engine Status Bar (the default Quake HUD)
 618         R_SetView(VF_DRAWENGINEHUD, 0);
 619
 620         // Update the mouse position
 621         /*
 622            mousepos_x = vid_conwidth;
 623            mousepos_y = vid_conheight;
 624            mousepos = mousepos*0.5 + getmousepos();
 625          */
 626
 627         e = self;
 628         for(self = world; (self = nextent(self)); )
 629                 if(self.draw)
 630                         self.draw();
 631         self = e;
 632
 633         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 634         R_RenderScene();
 635
 636         // now switch to 2D drawing mode by calling a 2D drawing function
 637         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 638         // next R_RenderScene call
 639         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 640
 641         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 642         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 643         {
 644                 // apply night vision effect
 645                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 646
 647                 if(!nightvision_noise)
 648                 {
 649                         nightvision_noise = spawn();
 650                         nightvision_noise.classname = "nightvision_noise";
 651                 }
 652                 if(!nightvision_noise2)
 653                 {
 654                         nightvision_noise2 = spawn();
 655                         nightvision_noise2.classname = "nightvision_noise2";
 656                 }
 657
 658                 // color tint in yellow
 659                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 660
 661                 // draw BG
 662                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 663                 rgb = '1 1 1';
 664                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 665                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 666                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 667                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 668                 tc_11 = tc_01 + tc_10 - tc_00;
 669                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 670                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 671                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 672                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 673                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 674                 R_EndPolygon();
 675
 676                 // draw FG
 677                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 678                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 679                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 680                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 681                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 682                 tc_11 = tc_01 + tc_10 - tc_00;
 683                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 684                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 685                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 686                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 687                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 688                 R_EndPolygon();
 689         }
 690
 691         // Draw the aiming reticle for weapons that use it
 692         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 693         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 694         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 695         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 696                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 697         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 698                 reticle_type = 2; // nex zoom
 699         else if(button_zoom || zoomscript_caught)
 700                 reticle_type = 1; // normal zoom
 701         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 702                 reticle_type = 2; // nex zoom
 703
 704         if (reticle_type)
 705         {
 706                 if(autocvar_cl_reticle_stretch)
 707                 {
 708                         reticle_size_x = vid_conwidth;
 709                         reticle_size_y = vid_conheight;
 710                         reticle_pos_x = 0;
 711                         reticle_pos_y = 0;
 712                 }
 713                 else
 714                 {
 715                         reticle_size_x = max(vid_conwidth, vid_conheight);
 716                         reticle_size_y = max(vid_conwidth, vid_conheight);
 717                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 718                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 719                 }
 720
 721                 f = current_zoomfraction;
 722                 if(zoomscript_caught)
 723                         f = 1;
 724                 if(autocvar_cl_reticle_item_normal)
 725                 {
 726                         if(reticle_type == 1 && f)
 727                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 728                 }
 729                 if(autocvar_cl_reticle_item_nex)
 730                 {
 731                         if(reticle_type == 2 && f)
 732                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 733                 }
 734         }
 735
 736
 737         // improved polyblend
 738         vector rgb;
 739         if(autocvar_hud_contents)
 740         {
 741                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 742                 vector liquidcolor;
 743
 744                 switch(pointcontents(view_origin))
 745                 {
 746                         case CONTENT_WATER:
 747                                 liquidalpha = autocvar_hud_contents_water_alpha;
 748                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 749                                 incontent = 1;
 750                                 break;
 751
 752                         case CONTENT_LAVA:
 753                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 754                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 755                                 incontent = 1;
 756                                 break;
 757
 758                         case CONTENT_SLIME:
 759                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 760                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 761                                 incontent = 1;
 762                                 break;
 763
 764                         default:
 765                                 liquidalpha = 0;
 766                                 liquidcolor = '0 0 0';
 767                                 incontent = 0;
 768                                 break;
 769                 }
 770
 771                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 772                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 773                         contentfadetime = autocvar_hud_contents_fadeintime;
 774                         liquidalpha_prev = liquidalpha;
 775                         liquidcolor_prev = liquidcolor;
 776                 }
 777                 else
 778                         contentfadetime = autocvar_hud_contents_fadeouttime;
 779
 780                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 781                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 782
 783                 if(contentavgalpha)
 784                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 785         }
 786
 787         if(autocvar_hud_damage)
 788         {
 789                 splash_size_x = max(vid_conwidth, vid_conheight);
 790                 splash_size_y = max(vid_conwidth, vid_conheight);
 791                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 792                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 793
 794                 float myhealth_flash_temp;
 795                 myhealth = getstati(STAT_HEALTH);
 796
 797                 // fade out
 798                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 799                 // add new damage
 800                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 801
 802                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 803                 pain_threshold = autocvar_hud_damage_pain_threshold;
 804                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 805                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 806
 807                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 808                 {
 809                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 810                 }
 811
 812                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 813
 814                 if(myhealth_prev < 1)
 815                 {
 816                         if(myhealth >= 1)
 817                         {
 818                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 819                                 myhealth_flash_temp = 0;
 820                         }
 821                         else
 822                         {
 823                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 824                         }
 825                 }
 826
 827                 if(spectatee_status == -1 || intermission)
 828                 {
 829                         myhealth_flash = 0; // observing, or match ended
 830                         myhealth_flash_temp = 0;
 831                 }
 832
 833                 myhealth_prev = myhealth;
 834
 835                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 836                 {
 837                         if(autocvar_cl_gentle_damage == 2)
 838                         {
 839                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 840                                 {
 841                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 842                                 }
 843                         }
 844                         else
 845                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 846
 847                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 848                 }
 849                 else
 850                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 851         }
 852
 853         // Draw the mouse cursor
 854         // NOTE: drawpic must happen after R_RenderScene for some reason
 855         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 856         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 857         //self = edict_num(player_localnum);
 858         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 859         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 860         // as long as the ctf part isn't in, this is useless
 861         if(menu_visible)
 862                 menu_show();
 863
 864         /*if(gametype == GAME_CTF)
 865           {
 866           ctf_view();
 867           } else */
 868
 869         // draw 2D entities
 870         e = self;
 871         for(self = world; (self = nextent(self)); )
 872                 if(self.draw2d)
 873                         self.draw2d();
 874         self = e;
 875         Draw_ShowNames_All();
 876
 877         scoreboard_active = HUD_WouldDrawScoreboard();
 878
 879         hit_time = getstatf(STAT_HIT_TIME);
 880         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 881         {
 882                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 883                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 884         }
 885         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 886         if(typehit_time > nextsound_typehit_time)
 887         {
 888                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 889                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 890         }
 891
 892         if(hud == HUD_SPIDERBOT)
 893                 CSQC_SPIDER_HUD();
 894         else if(hud == HUD_WAKIZASHI)
 895         CSQC_WAKIZASHI_HUD();
 896     else if(hud == HUD_RAPTOR)
 897         CSQC_RAPTOR_HUD();
 898     else if(hud == HUD_BUMBLEBEE)
 899         CSQC_BUMBLE_HUD();
 900         else
 901         {
 902                 if(gametype == GAME_FREEZETAG)
 903                 {
 904                         if(getstati(STAT_FROZEN))
 905                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 906                         if(getstatf(STAT_REVIVE_PROGRESS))
 907                         {
 908                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 909                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 910                         }
 911                 }
 912
 913                 if(autocvar_r_letterbox == 0)
 914                         if(autocvar_viewsize < 120)
 915                                 CSQC_common_hud();
 916
 917                 // crosshair goes VERY LAST
 918                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1) {
 919                         string wcross_style;
 920                         float wcross_alpha, wcross_resolution;
 921                         wcross_style = autocvar_crosshair;
 922                         if (wcross_style == "0")
 923                                 return;
 924                         wcross_resolution = autocvar_crosshair_size;
 925                         if (wcross_resolution == 0)
 926                                 return;
 927                         wcross_alpha = autocvar_crosshair_alpha;
 928                         if (wcross_alpha == 0)
 929                                 return;
 930
 931                         // TrueAim check
 932                         float shottype;
 933
 934                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 935                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 936                         wcross_origin_z = 0;
 937                         if(autocvar_crosshair_hittest)
 938                         {
 939                                 vector wcross_oldorigin;
 940                                 wcross_oldorigin = wcross_origin;
 941                                 shottype = TrueAimCheck();
 942                                 if(shottype == SHOTTYPE_HITWORLD)
 943                                 {
 944                                         v = wcross_origin - wcross_oldorigin;
 945                                         v_x /= vid_conwidth;
 946                                         v_y /= vid_conheight;
 947                                         if(vlen(v) > 0.01)
 948                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 949                                 }
 950                                 if(!autocvar_crosshair_hittest_showimpact)
 951                                         wcross_origin = wcross_oldorigin;
 952                         }
 953                         else
 954                                 shottype = SHOTTYPE_HITWORLD;
 955
 956                         vector wcross_color, wcross_size;
 957                         string wcross_wep, wcross_name;
 958                         float wcross_scale, wcross_blur;
 959
 960                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 961                                 e = get_weaponinfo(activeweapon);
 962                                 if (e && e.netname != "")
 963                                 {
 964                                         wcross_wep = e.netname;
 965                                         if(autocvar_crosshair_per_weapon)
 966                                         {
 967                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 968                                                 if (wcross_resolution == 0)
 969                                                         return;
 970                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 971                                                 if (wcross_alpha == 0)
 972                                                         return;
 973
 974                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 975                                                 if(wcross_style == "" || wcross_style == "0")
 976                                                         wcross_style = wcross_wep;
 977                                         }
 978                                 }
 979                         }
 980                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 981                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 982                         else if(autocvar_crosshair_color_by_health)
 983                         {
 984                                 local float x = getstati(STAT_HEALTH);
 985
 986                                 //x = red
 987                                 //y = green
 988                                 //z = blue
 989
 990                                 wcross_color_z = 0;
 991
 992                                 if(x > 200)
 993                                 {
 994                                         wcross_color_x = 0;
 995                                         wcross_color_y = 1;
 996                                 }
 997                                 else if(x > 150)
 998                                 {
 999                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1000                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1001                                 }
1002                                 else if(x > 100)
1003                                 {
1004                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1005                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1006                                         wcross_color_z = 1 - (x-100)*0.02;
1007                                 }
1008                                 else if(x > 50)
1009                                 {
1010                                         wcross_color_x = 1;
1011                                         wcross_color_y = 1;
1012                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1013                                 }
1014                                 else if(x > 20)
1015                                 {
1016                                         wcross_color_x = 1;
1017                                         wcross_color_y = (x-20)*90/27/100;
1018                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1019                                 }
1020                                 else
1021                                 {
1022                                         wcross_color_x = 1;
1023                                         wcross_color_y = 0;
1024                                 }
1025                         }
1026                         else
1027                                 wcross_color = stov(autocvar_crosshair_color);
1028
1029                         wcross_name = strcat("gfx/crosshair", wcross_style);
1030
1031                         if(autocvar_crosshair_effect_scalefade)
1032                         {
1033                                 wcross_scale = wcross_resolution;
1034                                 wcross_resolution = 1;
1035                         }
1036                         else
1037                         {
1038                                 wcross_scale = 1;
1039                         }
1040
1041                         if(autocvar_crosshair_pickup)
1042                         {
1043                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1044                                 {
1045                                         pickup_crosshair_size = 1;
1046                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1047                                 }
1048
1049                                 if(pickup_crosshair_size > 0)
1050                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1051                                 else
1052                                         pickup_crosshair_size = 0;
1053
1054                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1055                         }
1056
1057                         vector hitindication_color;
1058                         if(autocvar_crosshair_hitindication)
1059                         {
1060                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1061                                 if(hitindication_crosshair_time < hit_time)
1062                                 {
1063                                         hitindication_crosshair_size = 1;
1064                                         hitindication_crosshair_time = hit_time;
1065                                 }
1066
1067                                 if(hitindication_crosshair_size > 0)
1068                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1069                                 else
1070                                         hitindication_crosshair_size = 0;
1071
1072                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1073                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1074                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1075                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1076                         }
1077
1078                         if(shottype == SHOTTYPE_HITENEMY)
1079                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1080                         if(shottype == SHOTTYPE_HITTEAM)
1081                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1082
1083                         f = autocvar_crosshair_effect_speed;
1084                         if(f < 0)
1085                                 f *= -2 * g_weaponswitchdelay;
1086                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1087                         {
1088                                 wcross_changedonetime = time + f;
1089                         }
1090                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1091                         {
1092                                 wcross_name_changestarttime = time;
1093                                 wcross_name_changedonetime = time + f;
1094                                 if(wcross_name_goal_prev_prev)
1095                                         strunzone(wcross_name_goal_prev_prev);
1096                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1097                                 wcross_name_goal_prev = strzone(wcross_name);
1098                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1099                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1100                                 wcross_resolution_goal_prev = wcross_resolution;
1101                         }
1102
1103                         wcross_scale_goal_prev = wcross_scale;
1104                         wcross_alpha_goal_prev = wcross_alpha;
1105                         wcross_color_goal_prev = wcross_color;
1106
1107                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1108                         {
1109                                 wcross_blur = 1;
1110                                 wcross_alpha *= 0.75;
1111                         }
1112                         else
1113                                 wcross_blur = 0;
1114                         // *_prev is at time-frametime
1115                         // * is at wcross_changedonetime+f
1116                         // what do we have at time?
1117                         if(time < wcross_changedonetime)
1118                         {
1119                                 f = frametime / (wcross_changedonetime - time + frametime);
1120                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1121                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1122                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1123                         }
1124
1125                         wcross_scale_prev = wcross_scale;
1126                         wcross_alpha_prev = wcross_alpha;
1127                         wcross_color_prev = wcross_color;
1128
1129                         wcross_scale *= 1 - autocvar__menu_alpha;
1130                         wcross_alpha *= 1 - autocvar__menu_alpha;
1131                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1132
1133                         // crosshair rings for weapon stats
1134                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1135                         {
1136                                 // declarations and stats
1137                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1138                                 string ring_image, ring_inner_image;
1139                                 vector ring_rgb, ring_inner_rgb;
1140
1141                                 ring_scale = autocvar_crosshair_ring_size;
1142
1143                                 float weapon_clipload, weapon_clipsize;
1144                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1145                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1146
1147                                 float nex_charge, nex_chargepool;
1148                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1149                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1150
1151                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1152                                         nex_charge_movingavg = nex_charge;
1153
1154
1155                                 // handle the values
1156                                 if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1157                                 {
1158                                         if (nex_chargepool || use_nex_chargepool) {
1159                                                 use_nex_chargepool = 1;
1160                                                 ring_inner_value = nex_chargepool;
1161                                         } else {
1162                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1163                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1164                                         }
1165
1166                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1167                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1168                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1169
1170                                         // draw the outer ring to show the current charge of the weapon
1171                                         ring_value = nex_charge;
1172                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1173                                         ring_rgb = wcross_color;
1174                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1175                                 }
1176                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1177                                 {
1178                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1179                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1180                                         ring_rgb = wcross_color;
1181                                         ring_image = "gfx/crosshair_ring.tga";
1182                                 }
1183                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1184                                 {
1185                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1186                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1187                                         ring_rgb = wcross_color;
1188                                         ring_image = "gfx/crosshair_ring.tga";
1189                                 }
1190
1191                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1192                                 {
1193                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1194                                         ring_scale = autocvar_crosshair_ring_reload_size;
1195                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1196                                         ring_rgb = wcross_color;
1197
1198                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1199                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1200                                         if ((activeweapon == WEP_SNIPERRIFLE) && (weapon_clipsize == 80))
1201                                                 ring_image = "gfx/crosshair_ring_sniperrifle.tga";
1202                                         else
1203                                                 ring_image = "gfx/crosshair_ring.tga";
1204                                 }
1205
1206                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1207                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1208
1209                                 if (ring_value)
1210                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1211                         }
1212
1213 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1214                         do \
1215                         { \
1216                                 if(wcross_blur > 0) \
1217                                 { \
1218                                         for(i = -2; i <= 2; ++i) \
1219                                                 for(j = -2; j <= 2; ++j) \
1220                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1221                                 } \
1222                                 else \
1223                                 { \
1224                                         M(0,0,sz,wcross_name,wcross_alpha); \
1225                                 } \
1226                         } \
1227                         while(0)
1228
1229 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1230                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1231
1232 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1233                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1234
1235                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1236                         {
1237                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1238                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1239                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1240                                 f = 1 - f;
1241                         }
1242                         else
1243                         {
1244                                 f = 1;
1245                         }
1246
1247                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1248                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1249
1250                         if(autocvar_crosshair_dot)
1251             {
1252                 vector wcross_color_old;
1253                 wcross_color_old = wcross_color;
1254                 if(autocvar_crosshair_dot_color != "0")
1255                     wcross_color = stov(autocvar_crosshair_dot_color);
1256                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1257                 wcross_color = wcross_color_old;
1258             }
1259
1260                         wcross_name_alpha_goal_prev = f;
1261                 }
1262                 else
1263                 {
1264                         wcross_scale_prev = 0;
1265                         wcross_alpha_prev = 0;
1266                         wcross_scale_goal_prev = 0;
1267                         wcross_alpha_goal_prev = 0;
1268                         wcross_changedonetime = 0;
1269                         if(wcross_name_goal_prev)
1270                                 strunzone(wcross_name_goal_prev);
1271                         wcross_name_goal_prev = string_null;
1272                         if(wcross_name_goal_prev_prev)
1273                                 strunzone(wcross_name_goal_prev_prev);
1274                         wcross_name_goal_prev_prev = string_null;
1275                         wcross_name_changestarttime = 0;
1276                         wcross_name_changedonetime = 0;
1277                         wcross_name_alpha_goal_prev = 0;
1278                         wcross_name_alpha_goal_prev_prev = 0;
1279                         wcross_resolution_goal_prev = 0;
1280                         wcross_resolution_goal_prev_prev = 0;
1281                 }
1282         }
1283
1284         if(NextFrameCommand)
1285         {
1286                 localcmd("\n", NextFrameCommand, "\n");
1287                 NextFrameCommand = string_null;
1288         }
1289
1290         // we must do this check AFTER a frame was rendered, or it won't work
1291         if(cs_project_is_b0rked == 0)
1292         {
1293                 string w0, h0;
1294                 w0 = ftos(autocvar_vid_conwidth);
1295                 h0 = ftos(autocvar_vid_conheight);
1296                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1297                 //R_SetView(VF_FOV, '90 90 0');
1298                 R_SetView(VF_ORIGIN, '0 0 0');
1299                 R_SetView(VF_ANGLES, '0 0 0');
1300                 R_SetView(VF_PERSPECTIVE, 1);
1301                 makevectors('0 0 0');
1302                 vector v1, v2;
1303                 cvar_set("vid_conwidth", "800");
1304                 cvar_set("vid_conheight", "600");
1305                 v1 = cs_project(v_forward);
1306                 cvar_set("vid_conwidth", "640");
1307                 cvar_set("vid_conheight", "480");
1308                 v2 = cs_project(v_forward);
1309                 if(v1 == v2)
1310                         cs_project_is_b0rked = 1;
1311                 else
1312                         cs_project_is_b0rked = -1;
1313                 cvar_set("vid_conwidth", w0);
1314                 cvar_set("vid_conheight", h0);
1315         }
1316
1317         if(autocvar__hud_configure)
1318                 HUD_Panel_Mouse();
1319
1320         // let's reset the view back to normal for the end
1321         R_SetView(VF_MIN, '0 0 0');
1322         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1323 }
1324
1325
1326 void CSQC_common_hud(void)
1327 {
1328         // HUD_SortFrags(); done in HUD_Draw
1329         float hud;
1330         hud = getstati(STAT_HUD);
1331
1332         //hud = 10;
1333         switch(hud)
1334         {
1335                 case HUD_NORMAL:
1336                         // do some accuracy var caching
1337                         float i;
1338                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1339                         {
1340                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1341                                 {
1342                                         if(acc_color_levels)
1343                                                 strunzone(acc_color_levels);
1344                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1345                                         acc_levels = tokenize(acc_color_levels);
1346                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1347                                                 acc_levels = MAX_ACCURACY_LEVELS;
1348
1349                                         for (i = 0; i < acc_levels; ++i)
1350                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1351                                 }
1352                                 // let know that acc_col[] needs to be loaded
1353                                 acc_col_x[0] = -1;
1354                         }
1355
1356                         HUD_Main(); // always run these functions for alpha checks
1357                         HUD_DrawScoreboard();
1358
1359                         if (scoreboard_active) // scoreboard/accuracy
1360                         {
1361                                 HUD_Reset();
1362                                 // HUD_DrawScoreboard takes care of centerprint_start
1363                         }
1364                         else if (intermission == 2) // map voting screen
1365                         {
1366                                 HUD_FinaleOverlay();
1367                                 HUD_Reset();
1368
1369                                 centerprint_start_x = 0;
1370                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1371                         }
1372                         else // hud
1373                         {
1374                                 centerprint_start_x = 0;
1375                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1376                         }
1377
1378                         HUD_DrawCenterPrint();
1379                         break;
1380
1381                 case HUD_SPIDERBOT:
1382                         CSQC_SPIDER_HUD();
1383                         break;
1384
1385                 case HUD_WAKIZASHI:
1386                         CSQC_WAKIZASHI_HUD();
1387                         break;
1388
1389         case HUD_BUMBLEBEE:
1390             CSQC_BUMBLE_HUD();
1391             break;
1392
1393         }
1394 }
1395
1396
1397 // following vectors must be global to allow seamless switching between camera modes
1398 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1399 void CSQC_Demo_Camera()
1400 {
1401         float speed, attenuation, dimensions;
1402         vector tmp, delta;
1403
1404         if( autocvar_camera_reset || !camera_mode )
1405         {
1406                 camera_offset = '0 0 0';
1407                 current_angles = '0 0 0';
1408                 camera_direction = '0 0 0';
1409                 camera_offset_z += 30;
1410                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1411                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1412                 current_origin = view_origin;
1413                 current_camera_offset  = camera_offset;
1414                 cvar_set("camera_reset", "0");
1415                 camera_mode = CAMERA_CHASE;
1416         }
1417
1418         // Camera angles
1419         if( camera_roll )
1420                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1421
1422         if(autocvar_camera_look_player)
1423         {
1424                 local vector dir;
1425                 local float n;
1426
1427                 dir = normalize(view_origin - current_position);
1428                 n = mouse_angles_z;
1429                 mouse_angles = vectoangles(dir);
1430                 mouse_angles_x = mouse_angles_x * -1;
1431                 mouse_angles_z = n;
1432         }
1433         else
1434         {
1435                 tmp = getmousepos() * 0.1;
1436                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1437                 {
1438                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1439                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1440                 }
1441         }
1442
1443         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1444         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1445         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1446         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1447
1448         // Fix difference when angles don't have the same sign
1449         delta = '0 0 0';
1450         if(mouse_angles_y < -60 && current_angles_y > 60)
1451                 delta = '0 360 0';
1452         if(mouse_angles_y > 60 && current_angles_y < -60)
1453                 delta = '0 -360 0';
1454
1455         if(autocvar_camera_look_player)
1456                 attenuation = autocvar_camera_look_attenuation;
1457         else
1458                 attenuation = autocvar_camera_speed_attenuation;
1459
1460         attenuation = 1 / max(1, attenuation);
1461         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1462
1463         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1464         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1465         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1466         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1467
1468         // Camera position
1469         tmp = '0 0 0';
1470         dimensions = 0;
1471
1472         if( camera_direction_x )
1473         {
1474                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1475                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1476                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1477                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1478                 ++dimensions;
1479         }
1480
1481         if( camera_direction_y )
1482         {
1483                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1484                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1485                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1486                 ++dimensions;
1487         }
1488
1489         if( camera_direction_z )
1490         {
1491                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1492                 ++dimensions;
1493         }
1494
1495         if(autocvar_camera_free)
1496                 speed = autocvar_camera_speed_free;
1497         else
1498                 speed = autocvar_camera_speed_chase;
1499
1500         if(dimensions)
1501         {
1502                 speed = speed * sqrt(1 / dimensions);
1503                 camera_offset += tmp * speed;
1504         }
1505
1506         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1507
1508         // Camera modes
1509         if( autocvar_camera_free )
1510         {
1511                 if ( camera_mode == CAMERA_CHASE )
1512                 {
1513                         current_camera_offset = current_origin + current_camera_offset;
1514                         camera_offset = current_origin + camera_offset;
1515                 }
1516
1517                 camera_mode = CAMERA_FREE;
1518                 current_position = current_camera_offset;
1519         }
1520         else
1521         {
1522                 if ( camera_mode == CAMERA_FREE )
1523                 {
1524                         current_origin = view_origin;
1525                         camera_offset = camera_offset - current_origin;
1526                         current_camera_offset = current_camera_offset - current_origin;
1527                 }
1528
1529                 camera_mode = CAMERA_CHASE;
1530
1531                 if(autocvar_camera_chase_smoothly)
1532                         current_origin += (view_origin - current_origin) * attenuation;
1533                 else
1534                         current_origin = view_origin;
1535
1536                 current_position = current_origin + current_camera_offset;
1537         }
1538
1539         R_SetView(VF_ANGLES, current_angles);
1540         R_SetView(VF_ORIGIN, current_position);
1541 }