qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 // this function must match W_SetupShot!
 203 float zoomscript_caught;
 204
 205 vector wcross_origin;
 206 float wcross_scale_prev, wcross_alpha_prev;
 207 vector wcross_color_prev;
 208 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 209 vector wcross_color_goal_prev;
 210 float wcross_changedonetime;
 211
 212 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 213 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 214 float wcross_name_changestarttime, wcross_name_changedonetime;
 215 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 216
 217 float wcross_ring_prev;
 218
 219 entity trueaim;
 220 entity trueaim_rifle;
 221
 222 #define SHOTTYPE_HITTEAM 1
 223 #define SHOTTYPE_HITOBSTRUCTION 2
 224 #define SHOTTYPE_HITWORLD 3
 225 #define SHOTTYPE_HITENEMY 4
 226
 227 void TrueAim_Init()
 228 {
 229         trueaim = spawn();
 230         trueaim.classname = "trueaim";
 231         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 232         trueaim_rifle = spawn();
 233         trueaim_rifle.classname = "trueaim_rifle";
 234         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 235 }
 236
 237 float EnemyHitCheck()
 238 {
 239         float t, n;
 240         wcross_origin = project_3d_to_2d(trace_endpos);
 241         wcross_origin_z = 0;
 242         if(trace_ent)
 243                 n = trace_ent.entnum;
 244         else
 245                 n = trace_networkentity;
 246         if(n < 1)
 247                 return SHOTTYPE_HITWORLD;
 248         if(n > maxclients)
 249                 return SHOTTYPE_HITWORLD;
 250         t = GetPlayerColor(n - 1);
 251         if(teamplay)
 252                 if(t == myteam)
 253                         return SHOTTYPE_HITTEAM;
 254         if(t == NUM_SPECTATOR)
 255                 return SHOTTYPE_HITWORLD;
 256         return SHOTTYPE_HITENEMY;
 257 }
 258
 259 float TrueAimCheck()
 260 {
 261         float nudge = 1; // added to traceline target and subtracted from result
 262         vector vecs, trueaimpoint, w_shotorg;
 263         vector mi, ma, dv;
 264         float shottype;
 265         entity ta;
 266         float mv;
 267
 268         mi = ma = '0 0 0';
 269         ta = trueaim;
 270         mv = MOVE_NOMONSTERS;
 271
 272         switch(activeweapon)
 273         {
 274                 case WEP_TUBA: // no aim
 275                 case WEP_PORTO: // shoots from eye
 276                 case WEP_HOOK: // no trueaim
 277                 case WEP_GRENADE_LAUNCHER: // toss curve
 278                         return SHOTTYPE_HITWORLD;
 279                 case WEP_NEX:
 280                 case WEP_MINSTANEX:
 281                         mv = MOVE_NORMAL;
 282                         break;
 283                 case WEP_RIFLE:
 284                         ta = trueaim_rifle;
 285                         mv = MOVE_NORMAL;
 286                         if(zoomscript_caught)
 287                         {
 288                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 289                                 return EnemyHitCheck();
 290                         }
 291                         break;
 292                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 293                         mi = '-3 -3 -3';
 294                         ma = '3 3 3';
 295                         break;
 296                 case WEP_FIREBALL: // projectile has a size!
 297                         mi = '-16 -16 -16';
 298                         ma = '16 16 16';
 299                         break;
 300                 case WEP_SEEKER: // projectile has a size!
 301                         mi = '-2 -2 -2';
 302                         ma = '2 2 2';
 303                         break;
 304                 case WEP_ELECTRO: // projectile has a size!
 305                         mi = '0 0 -3';
 306                         ma = '0 0 -3';
 307                         break;
 308         }
 309
 310         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 311
 312         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 313         trueaimpoint = trace_endpos;
 314
 315         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 316                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 317
 318         if(vecs_x > 0)
 319                 vecs_y = -vecs_y;
 320         else
 321                 vecs = '0 0 0';
 322
 323         dv = view_right * vecs_y + view_up * vecs_z;
 324         w_shotorg = view_origin + dv;
 325
 326         // now move the vecs forward as much as requested if possible
 327         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 328         w_shotorg = trace_endpos - view_forward * nudge;
 329
 330         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 331         shottype = EnemyHitCheck();
 332         if(shottype != SHOTTYPE_HITWORLD)
 333                 return shottype;
 334
 335 #if 0
 336         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 337         // or rather, I know why, but see no fix
 338         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 339                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 340                 return SHOTTYPE_HITOBSTRUCTION;
 341 #endif
 342
 343         return SHOTTYPE_HITWORLD;
 344 }
 345
 346 void CSQC_common_hud(void);
 347
 348 void PostInit(void);
 349 void CSQC_Demo_Camera();
 350 float HUD_WouldDrawScoreboard();
 351 float camera_mode;
 352 const float CAMERA_FREE = 1;
 353 const float CAMERA_CHASE = 2;
 354 float reticle_type;
 355 string NextFrameCommand;
 356 void CSQC_SPIDER_HUD();
 357 void CSQC_RAPTOR_HUD();
 358
 359 vector freeze_org, freeze_ang;
 360 entity nightvision_noise, nightvision_noise2;
 361
 362 #define MAX_TIME_DIFF 5
 363 float pickup_crosshair_time, pickup_crosshair_size;
 364 float hit_time, typehit_time;
 365 float nextsound_hit_time, nextsound_typehit_time;
 366 float hitindication_crosshair_time, hitindication_crosshair_size;
 367 float use_nex_chargepool;
 368
 369 float myhealth, myhealth_prev;
 370 float myhealth_flash;
 371
 372 float old_blurradius, old_bluralpha;
 373 float old_sharpen_intensity;
 374
 375 vector myhealth_gentlergb;
 376
 377 float contentavgalpha, liquidalpha_prev;
 378 vector liquidcolor_prev;
 379
 380 float eventchase_current_distance;
 381
 382 vector damage_blurpostprocess, content_blurpostprocess;
 383
 384 float checkfail[16];
 385
 386 float rainbow_last_flicker;
 387 vector rainbow_prev_color;
 388
 389 #define BUTTON_3 4
 390 #define BUTTON_4 8
 391 float cl_notice_run();
 392 float prev_myteam;
 393 void CSQC_UpdateView(float w, float h)
 394 {
 395         entity e;
 396         float fov;
 397         float f, i, j;
 398         vector v;
 399         vector vf_size, vf_min;
 400         float a;
 401
 402         execute_next_frame();
 403
 404         ++framecount;
 405
 406         hud = getstati(STAT_HUD);
 407
 408         if(autocvar__hud_showbinds_reload) // menu can set this one
 409         {
 410                 db_close(binddb);
 411                 binddb = db_create();
 412                 cvar_set("_hud_showbinds_reload", "0");
 413         }
 414
 415         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 416                 view_quality = getproperty(VF_MINFPS_QUALITY);
 417         else
 418                 view_quality = 1;
 419
 420         button_attack2 = (input_buttons & BUTTON_3);
 421         button_zoom = (input_buttons & BUTTON_4);
 422
 423 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 424         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 425         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 426         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 427         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 428         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 429         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 430         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 431
 432         vf_size = getpropertyvec(VF_SIZE);
 433         vf_min = getpropertyvec(VF_MIN);
 434         vid_width = vf_size_x;
 435         vid_height = vf_size_y;
 436
 437         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 438         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 439
 440         WaypointSprite_Load();
 441
 442         CSQCPlayer_SetCamera();
 443
 444 #ifdef COMPAT_XON050_ENGINE
 445         if(spectatee_status)
 446                 myteam = GetPlayerColor(spectatee_status - 1);
 447         else
 448 #endif
 449                 myteam = GetPlayerColor(player_localentnum - 1);
 450
 451         if(myteam != prev_myteam)
 452         {
 453                 myteamcolors = colormapPaletteColor(myteam, 1);
 454                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 455                         hud_panel[i].update_time = time;
 456                 prev_myteam = myteam;
 457         }
 458
 459         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 460
 461         float is_dead = (getstati(STAT_HEALTH) <= 0);
 462
 463         // FIXME do we need this hack?
 464         if(isdemo())
 465         {
 466                 // in demos, input_buttons do not work
 467                 button_zoom = (autocvar__togglezoom == "-");
 468         }
 469         else if(button_zoom
 470                 && autocvar_cl_unpress_zoom_on_death
 471                 && (spectatee_status >= 0)
 472                 && (is_dead || intermission))
 473         {
 474                 // no zoom while dead or in intermission please
 475                 localcmd("-zoom\n");
 476                 button_zoom = FALSE;
 477         }
 478
 479         // event chase camera
 480         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 481         {
 482                 if((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission)
 483                 {
 484                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 485                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 486
 487                         // detect maximum viewoffset and use it
 488                         if(autocvar_cl_eventchase_viewoffset)
 489                         {
 490                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 491                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 492                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 493                         }
 494
 495                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 496                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 497                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 498                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 499
 500                         // make the camera smooth back
 501                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 502                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 503                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 504                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 505
 506                         makevectors(view_angles);
 507
 508                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 509                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 510
 511                         // If the boxtrace fails, revert back to line tracing.
 512                         if(trace_startsolid)
 513                         {
 514                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 515                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 516                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 517                         }
 518                         else { setproperty(VF_ORIGIN, trace_endpos); }
 519
 520                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 521                 }
 522                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 523                 {
 524                         cvar_set("chase_active", "0");
 525                         eventchase_current_distance = 0; // start from 0 next time
 526                 }
 527         }
 528         // workaround for camera stuck between player's legs when using chase_active 1
 529         // because the engine stops updating the chase_active camera when the game ends
 530         else if(intermission)
 531         {
 532                 cvar_settemp("chase_active", "-1");
 533                 eventchase_current_distance = 0;
 534         }
 535
 536         // do lockview after event chase camera so that it still applies whenever necessary.
 537         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 538         {
 539                 setproperty(VF_ORIGIN, freeze_org);
 540                 setproperty(VF_ANGLES, freeze_ang);
 541         }
 542         else
 543         {
 544                 freeze_org = getpropertyvec(VF_ORIGIN);
 545                 freeze_ang = getpropertyvec(VF_ANGLES);
 546         }
 547
 548         WarpZone_FixView();
 549         //WarpZone_FixPMove();
 550
 551         // Render the Scene
 552         view_origin = getpropertyvec(VF_ORIGIN);
 553         view_angles = getpropertyvec(VF_ANGLES);
 554         makevectors(view_angles);
 555         view_forward = v_forward;
 556         view_right = v_right;
 557         view_up = v_up;
 558
 559 #ifdef BLURTEST
 560         if(time > blurtest_time0 && time < blurtest_time1)
 561         {
 562                 float r, t;
 563
 564                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 565                 r = t * blurtest_radius;
 566                 f = 1 / pow(t, blurtest_power) - 1;
 567
 568                 cvar_set("r_glsl_postprocess", "1");
 569                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 570         }
 571         else
 572         {
 573                 cvar_set("r_glsl_postprocess", "0");
 574                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 575         }
 576 #endif
 577
 578         TargetMusic_Advance();
 579         Fog_Force();
 580
 581         if(drawtime == 0)
 582                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 583         else
 584                 drawframetime = bound(0.000001, time - drawtime, 1);
 585         drawtime = time;
 586
 587         // watch for gametype changes here...
 588         // in ParseStuffCMD the cmd isn't executed yet :/
 589         // might even be better to add the gametype to TE_CSQC_INIT...?
 590         if(!postinit)
 591                 PostInit();
 592
 593         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 594         {
 595                 if(calledhooks & HOOK_START)
 596                 {
 597                         localcmd("\ncl_hook_gameend\n");
 598                         calledhooks |= HOOK_END;
 599                 }
 600         }
 601
 602         Announcer();
 603
 604         fov = autocvar_fov;
 605         if(fov <= 59.5)
 606         {
 607                 if(!zoomscript_caught)
 608                 {
 609                         localcmd("+button9\n");
 610                         zoomscript_caught = 1;
 611                 }
 612         }
 613         else
 614         {
 615                 if(zoomscript_caught)
 616                 {
 617                         localcmd("-button9\n");
 618                         zoomscript_caught = 0;
 619                 }
 620         }
 621
 622         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 623
 624         // next WANTED weapon (for HUD)
 625         switchweapon = getstati(STAT_SWITCHWEAPON);
 626
 627         // currently switching-to weapon (for crosshair)
 628         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 629
 630         // actually active weapon (for zoom)
 631         activeweapon = getstati(STAT_ACTIVEWEAPON);
 632
 633         f = (serverflags & SERVERFLAG_TEAMPLAY);
 634         if(f != teamplay)
 635         {
 636                 teamplay = f;
 637                 HUD_InitScores();
 638         }
 639
 640         if(last_switchweapon != switchweapon)
 641         {
 642                 weapontime = time;
 643                 last_switchweapon = switchweapon;
 644                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 645                 {
 646                         localcmd("-zoom\n");
 647                         button_zoom = FALSE;
 648                 }
 649                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 650                 {
 651                         localcmd("-fire\n");
 652                         localcmd("-fire2\n");
 653                         button_attack2 = FALSE;
 654                 }
 655         }
 656         if(last_activeweapon != activeweapon)
 657         {
 658                 last_activeweapon = activeweapon;
 659
 660                 e = get_weaponinfo(activeweapon);
 661                 if(e.netname != "")
 662                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 663                 else
 664                         localcmd("\ncl_hook_activeweapon none\n");
 665         }
 666
 667         // ALWAYS Clear Current Scene First
 668         clearscene();
 669 #ifdef WORKAROUND_XON010
 670         if(checkextension("DP_CSQC_ROTATEMOVES"))
 671         {
 672 #endif
 673         setproperty(VF_ORIGIN, view_origin);
 674         setproperty(VF_ANGLES, view_angles);
 675 #ifdef WORKAROUND_XON010
 676         }
 677 #endif
 678
 679         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 680         setproperty(VF_SIZE, vf_size);
 681         setproperty(VF_MIN, vf_min);
 682
 683         // Assign Standard Viewflags
 684         // Draw the World (and sky)
 685         setproperty(VF_DRAWWORLD, 1);
 686
 687         // Set the console size vars
 688         vid_conwidth = autocvar_vid_conwidth;
 689         vid_conheight = autocvar_vid_conheight;
 690         vid_pixelheight = autocvar_vid_pixelheight;
 691
 692         setproperty(VF_FOV, GetCurrentFov(fov));
 693
 694         // Camera for demo playback
 695         if(camera_active)
 696         {
 697                 if(autocvar_camera_enable)
 698                         CSQC_Demo_Camera();
 699                 else
 700                 {
 701                         cvar_set("chase_active", ftos(chase_active_backup));
 702                         cvar_set("cl_demo_mousegrab", "0");
 703                         camera_active = FALSE;
 704                 }
 705         }
 706 #ifdef CAMERATEST
 707         else if(autocvar_camera_enable)
 708 #else
 709         else if(autocvar_camera_enable && isdemo())
 710 #endif
 711         {
 712                 // Enable required Darkplaces cvars
 713                 chase_active_backup = autocvar_chase_active;
 714                 cvar_set("chase_active", "2");
 715                 cvar_set("cl_demo_mousegrab", "1");
 716                 camera_active = TRUE;
 717                 camera_mode = FALSE;
 718         }
 719
 720         // Draw the Crosshair
 721         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 722
 723         // Draw the Engine Status Bar (the default Quake HUD)
 724         setproperty(VF_DRAWENGINESBAR, 0);
 725
 726         // Update the mouse position
 727         /*
 728            mousepos_x = vid_conwidth;
 729            mousepos_y = vid_conheight;
 730            mousepos = mousepos*0.5 + getmousepos();
 731          */
 732
 733         e = self;
 734         for(self = world; (self = nextent(self)); )
 735                 if(self.draw)
 736                         self.draw();
 737         self = e;
 738
 739         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 740         renderscene();
 741
 742         // now switch to 2D drawing mode by calling a 2D drawing function
 743         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 744         // next R_RenderScene call
 745         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 746
 747         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 748         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 749         {
 750                 // apply night vision effect
 751                 vector tc_00, tc_01, tc_10, tc_11;
 752                 vector rgb;
 753                 rgb_x = 0; // fteqcc sucks
 754                 rgb_y = 0; // fteqcc sucks
 755                 rgb_z = 0; // fteqcc sucks
 756
 757                 if(!nightvision_noise)
 758                 {
 759                         nightvision_noise = spawn();
 760                         nightvision_noise.classname = "nightvision_noise";
 761                 }
 762                 if(!nightvision_noise2)
 763                 {
 764                         nightvision_noise2 = spawn();
 765                         nightvision_noise2.classname = "nightvision_noise2";
 766                 }
 767
 768                 // color tint in yellow
 769                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 770
 771                 // draw BG
 772                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 773                 rgb = '1 1 1';
 774                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 775                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 776                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 777                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 778                 tc_11 = tc_01 + tc_10 - tc_00;
 779                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 780                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 781                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 782                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 783                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 784                 R_EndPolygon();
 785
 786                 // draw FG
 787                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 788                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 789                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 790                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 791                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 792                 tc_11 = tc_01 + tc_10 - tc_00;
 793                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 794                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 795                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 796                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 797                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 798                 R_EndPolygon();
 799         }
 800
 801         // Draw the aiming reticle for weapons that use it
 802         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 803         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 804         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 805         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 806                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 807         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
 808                 reticle_type = 2; // nex zoom
 809         else if(button_zoom || zoomscript_caught)
 810                 reticle_type = 1; // normal zoom
 811         else if((activeweapon == WEP_NEX) && button_attack2)
 812                 reticle_type = 2; // nex zoom
 813
 814         if(reticle_type && autocvar_cl_reticle)
 815         {
 816                 if(autocvar_cl_reticle_stretch)
 817                 {
 818                         reticle_size_x = vid_conwidth;
 819                         reticle_size_y = vid_conheight;
 820                         reticle_pos_x = 0;
 821                         reticle_pos_y = 0;
 822                 }
 823                 else
 824                 {
 825                         reticle_size_x = max(vid_conwidth, vid_conheight);
 826                         reticle_size_y = max(vid_conwidth, vid_conheight);
 827                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 828                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 829                 }
 830
 831                 f = current_zoomfraction;
 832                 if(zoomscript_caught)
 833                         f = 1;
 834                 if(autocvar_cl_reticle_item_normal)
 835                 {
 836                         if(reticle_type == 1 && f)
 837                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 838                 }
 839                 if(autocvar_cl_reticle_item_nex)
 840                 {
 841                         if(reticle_type == 2 && f)
 842                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 843                 }
 844         }
 845
 846
 847         // improved polyblend
 848         if(autocvar_hud_contents)
 849         {
 850                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 851                 vector liquidcolor;
 852
 853                 switch(pointcontents(view_origin))
 854                 {
 855                         case CONTENT_WATER:
 856                                 liquidalpha = autocvar_hud_contents_water_alpha;
 857                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 858                                 incontent = 1;
 859                                 break;
 860
 861                         case CONTENT_LAVA:
 862                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 863                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 864                                 incontent = 1;
 865                                 break;
 866
 867                         case CONTENT_SLIME:
 868                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 869                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 870                                 incontent = 1;
 871                                 break;
 872
 873                         default:
 874                                 liquidalpha = 0;
 875                                 liquidcolor = '0 0 0';
 876                                 incontent = 0;
 877                                 break;
 878                 }
 879
 880                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 881                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 882                         contentfadetime = autocvar_hud_contents_fadeintime;
 883                         liquidalpha_prev = liquidalpha;
 884                         liquidcolor_prev = liquidcolor;
 885                 }
 886                 else
 887                         contentfadetime = autocvar_hud_contents_fadeouttime;
 888
 889                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 890                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 891
 892                 if(contentavgalpha)
 893                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 894
 895                 if(autocvar_hud_postprocessing)
 896                 {
 897                         if(autocvar_hud_contents_blur && contentavgalpha)
 898                         {
 899                                 content_blurpostprocess_x = 1;
 900                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 901                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 902                         }
 903                         else
 904                         {
 905                                 content_blurpostprocess_x = 0;
 906                                 content_blurpostprocess_y = 0;
 907                                 content_blurpostprocess_z = 0;
 908                         }
 909                 }
 910         }
 911
 912         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 913         {
 914                 splash_size_x = max(vid_conwidth, vid_conheight);
 915                 splash_size_y = max(vid_conwidth, vid_conheight);
 916                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 917                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 918
 919                 float myhealth_flash_temp;
 920                 myhealth = getstati(STAT_HEALTH);
 921
 922                 // fade out
 923                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 924                 // add new damage
 925                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 926
 927                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 928                 pain_threshold = autocvar_hud_damage_pain_threshold;
 929                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 930                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 931
 932                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 933                 {
 934                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 935                 }
 936
 937                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 938
 939                 if(myhealth_prev < 1)
 940                 {
 941                         if(myhealth >= 1)
 942                         {
 943                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 944                                 myhealth_flash_temp = 0;
 945                         }
 946                         else
 947                         {
 948                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 949                         }
 950                 }
 951
 952                 if(spectatee_status == -1 || intermission)
 953                 {
 954                         myhealth_flash = 0; // observing, or match ended
 955                         myhealth_flash_temp = 0;
 956                 }
 957
 958                 myhealth_prev = myhealth;
 959
 960                 // IDEA: change damage color/picture based on player model for robot/alien species?
 961                 // pro: matches model better
 962                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 963                 // maybe different reddish pics?
 964                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 965                 {
 966                         if(autocvar_cl_gentle_damage == 2)
 967                         {
 968                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 969                                 {
 970                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 971                                 }
 972                         }
 973                         else
 974                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 975
 976                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 977                 }
 978                 else
 979                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 980
 981                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 982                 {
 983                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 984                         {
 985                                 damage_blurpostprocess_x = 1;
 986                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 987                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 988                         }
 989                         else
 990                         {
 991                                 damage_blurpostprocess_x = 0;
 992                                 damage_blurpostprocess_y = 0;
 993                                 damage_blurpostprocess_z = 0;
 994                         }
 995                 }
 996         }
 997
 998         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 999         float e2 = (autocvar_hud_powerup != 0);
1000         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1001         {
1002                 // enable or disable rendering types if they are used or not
1003                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1004                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1005
1006                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1007                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1008                 {
1009                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1010                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1011                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1012                         {
1013                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1014                                 old_blurradius = blurradius;
1015                                 old_bluralpha = bluralpha;
1016                         }
1017                 }
1018                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1019                 {
1020                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1021                         old_blurradius = 0;
1022                         old_bluralpha = 0;
1023                 }
1024
1025                 // edge detection postprocess handling done second (used by hud_powerup)
1026                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1027                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1028                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1029
1030                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1031
1032                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1033                 {
1034                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1035                         {
1036                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1037                                 old_sharpen_intensity = sharpen_intensity;
1038                         }
1039                 }
1040                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1041                 {
1042                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1043                         old_sharpen_intensity = 0;
1044                 }
1045
1046                 if(cvar("r_glsl_postprocess") == 0)
1047                         cvar_set("r_glsl_postprocess", "2");
1048         }
1049         else if(cvar("r_glsl_postprocess") == 2)
1050                 cvar_set("r_glsl_postprocess", "0");
1051
1052         if(menu_visible)
1053                 menu_show();
1054
1055         /*if(gametype == MAPINFO_TYPE_CTF)
1056           {
1057           ctf_view();
1058           } else */
1059
1060         // draw 2D entities
1061         e = self;
1062         for(self = world; (self = nextent(self)); )
1063                 if(self.draw2d)
1064                         self.draw2d();
1065         self = e;
1066         Draw_ShowNames_All();
1067
1068         scoreboard_active = HUD_WouldDrawScoreboard();
1069
1070         hit_time = getstatf(STAT_HIT_TIME);
1071         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1072         {
1073                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1074                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1075
1076                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1077         }
1078         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1079         if(typehit_time > nextsound_typehit_time)
1080         {
1081                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1082                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1083
1084                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1085         }
1086
1087         //else
1088         {
1089                 if(getstati(STAT_FROZEN))
1090                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1091                 if(getstatf(STAT_REVIVE_PROGRESS))
1092                 {
1093                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1094                         drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1095                 }
1096
1097                 if(autocvar_r_letterbox == 0)
1098                         if(autocvar_viewsize < 120)
1099                                 CSQC_common_hud();
1100
1101                 // crosshair goes VERY LAST
1102                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1103                 {
1104                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1105                                 return;
1106
1107                         string wcross_style;
1108                         float wcross_alpha, wcross_resolution;
1109                         wcross_style = autocvar_crosshair;
1110                         if (wcross_style == "0")
1111                                 return;
1112                         wcross_resolution = autocvar_crosshair_size;
1113                         if (wcross_resolution == 0)
1114                                 return;
1115                         wcross_alpha = autocvar_crosshair_alpha;
1116                         if (wcross_alpha == 0)
1117                                 return;
1118
1119                         // TrueAim check
1120                         float shottype;
1121
1122                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1123                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1124                         wcross_origin_z = 0;
1125                         if(autocvar_crosshair_hittest)
1126                         {
1127                                 vector wcross_oldorigin;
1128                                 wcross_oldorigin = wcross_origin;
1129                                 shottype = TrueAimCheck();
1130                                 if(shottype == SHOTTYPE_HITWORLD)
1131                                 {
1132                                         v = wcross_origin - wcross_oldorigin;
1133                                         v_x /= vid_conwidth;
1134                                         v_y /= vid_conheight;
1135                                         if(vlen(v) > 0.01)
1136                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1137                                 }
1138                                 if(!autocvar_crosshair_hittest_showimpact)
1139                                         wcross_origin = wcross_oldorigin;
1140                         }
1141                         else
1142                                 shottype = SHOTTYPE_HITWORLD;
1143
1144                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1145                         string wcross_wep = "", wcross_name;
1146                         float wcross_scale, wcross_blur;
1147
1148                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1149                         {
1150                                 e = get_weaponinfo(switchingweapon);
1151                                 if (e && e.netname != "")
1152                                 {
1153                                         wcross_wep = e.netname;
1154                                         if(autocvar_crosshair_per_weapon)
1155                                         {
1156                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1157                                                 if (wcross_resolution == 0)
1158                                                         return;
1159                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1160                                                 if (wcross_alpha == 0)
1161                                                         return;
1162
1163                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1164                                                 if(wcross_style == "" || wcross_style == "0")
1165                                                         wcross_style = wcross_wep;
1166                                         }
1167                                 }
1168                         }
1169
1170                         //print(sprintf("crosshair style: %s\n", wcross_style));
1171                         wcross_name = strcat("gfx/crosshair", wcross_style);
1172
1173                         // MAIN CROSSHAIR COLOR DECISION
1174                         switch(autocvar_crosshair_color_special)
1175                         {
1176                                 case 1: // crosshair_color_per_weapon
1177                                 {
1178                                         if(wcross_wep != "")
1179                                         {
1180                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1181                                                 break;
1182                                         }
1183                                         else { goto normalcolor; }
1184                                 }
1185
1186                                 case 2: // crosshair_color_by_health
1187                                 {
1188                                         float x = getstati(STAT_HEALTH);
1189
1190                                         //x = red
1191                                         //y = green
1192                                         //z = blue
1193
1194                                         wcross_color_z = 0;
1195
1196                                         if(x > 200)
1197                                         {
1198                                                 wcross_color_x = 0;
1199                                                 wcross_color_y = 1;
1200                                         }
1201                                         else if(x > 150)
1202                                         {
1203                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1204                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1205                                         }
1206                                         else if(x > 100)
1207                                         {
1208                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1209                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1210                                                 wcross_color_z = 1 - (x-100)*0.02;
1211                                         }
1212                                         else if(x > 50)
1213                                         {
1214                                                 wcross_color_x = 1;
1215                                                 wcross_color_y = 1;
1216                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1217                                         }
1218                                         else if(x > 20)
1219                                         {
1220                                                 wcross_color_x = 1;
1221                                                 wcross_color_y = (x-20)*90/27/100;
1222                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1223                                         }
1224                                         else
1225                                         {
1226                                                 wcross_color_x = 1;
1227                                                 wcross_color_y = 0;
1228                                         }
1229                                         break;
1230                                 }
1231
1232                                 case 3: // crosshair_color_rainbow
1233                                 {
1234                                         if(time >= rainbow_last_flicker)
1235                                         {
1236                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1237                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1238                                         }
1239                                         wcross_color = rainbow_prev_color;
1240                                         break;
1241                                 }
1242                                 :normalcolor
1243                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1244                         }
1245
1246                         if(autocvar_crosshair_effect_scalefade)
1247                         {
1248                                 wcross_scale = wcross_resolution;
1249                                 wcross_resolution = 1;
1250                         }
1251                         else
1252                         {
1253                                 wcross_scale = 1;
1254                         }
1255
1256                         if(autocvar_crosshair_pickup)
1257                         {
1258                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1259
1260                                 if(pickup_crosshair_time < stat_pickup_time)
1261                                 {
1262                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1263                                                 pickup_crosshair_size = 1;
1264
1265                                         pickup_crosshair_time = stat_pickup_time;
1266                                 }
1267
1268                                 if(pickup_crosshair_size > 0)
1269                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1270                                 else
1271                                         pickup_crosshair_size = 0;
1272
1273                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1274                         }
1275
1276                         if(autocvar_crosshair_hitindication)
1277                         {
1278                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1279
1280                                 if(hitindication_crosshair_time < hit_time)
1281                                 {
1282                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1283                                                 hitindication_crosshair_size = 1;
1284
1285                                         hitindication_crosshair_time = hit_time;
1286                                 }
1287
1288                                 if(hitindication_crosshair_size > 0)
1289                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1290                                 else
1291                                         hitindication_crosshair_size = 0;
1292
1293                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1294                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1295                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1296                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1297                         }
1298
1299                         if(shottype == SHOTTYPE_HITENEMY)
1300                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1301                         if(shottype == SHOTTYPE_HITTEAM)
1302                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1303
1304                         f = fabs(autocvar_crosshair_effect_time);
1305                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1306                         {
1307                                 wcross_changedonetime = time + f;
1308                         }
1309                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1310                         {
1311                                 wcross_name_changestarttime = time;
1312                                 wcross_name_changedonetime = time + f;
1313                                 if(wcross_name_goal_prev_prev)
1314                                         strunzone(wcross_name_goal_prev_prev);
1315                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1316                                 wcross_name_goal_prev = strzone(wcross_name);
1317                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1318                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1319                                 wcross_resolution_goal_prev = wcross_resolution;
1320                         }
1321
1322                         wcross_scale_goal_prev = wcross_scale;
1323                         wcross_alpha_goal_prev = wcross_alpha;
1324                         wcross_color_goal_prev = wcross_color;
1325
1326                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1327                         {
1328                                 wcross_blur = 1;
1329                                 wcross_alpha *= 0.75;
1330                         }
1331                         else
1332                                 wcross_blur = 0;
1333                         // *_prev is at time-frametime
1334                         // * is at wcross_changedonetime+f
1335                         // what do we have at time?
1336                         if(time < wcross_changedonetime)
1337                         {
1338                                 f = frametime / (wcross_changedonetime - time + frametime);
1339                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1340                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1341                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1342                         }
1343
1344                         wcross_scale_prev = wcross_scale;
1345                         wcross_alpha_prev = wcross_alpha;
1346                         wcross_color_prev = wcross_color;
1347
1348                         wcross_scale *= 1 - autocvar__menu_alpha;
1349                         wcross_alpha *= 1 - autocvar__menu_alpha;
1350                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1351
1352                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1353                         {
1354                                 // crosshair rings for weapon stats
1355                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1356                                 {
1357                                         // declarations and stats
1358                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1359                                         string ring_image = string_null, ring_inner_image = string_null;
1360                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1361
1362                                         ring_scale = autocvar_crosshair_ring_size;
1363
1364                                         float weapon_clipload, weapon_clipsize;
1365                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1366                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1367
1368                                         float nex_charge, nex_chargepool;
1369                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1370                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1371
1372                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1373                                                 nex_charge_movingavg = nex_charge;
1374
1375
1376                                         // handle the values
1377                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1378                                         {
1379                                                 if (nex_chargepool || use_nex_chargepool) {
1380                                                         use_nex_chargepool = 1;
1381                                                         ring_inner_value = nex_chargepool;
1382                                                 } else {
1383                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1384                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1385                                                 }
1386
1387                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1388                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1389                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1390
1391                                                 // draw the outer ring to show the current charge of the weapon
1392                                                 ring_value = nex_charge;
1393                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1394                                                 ring_rgb = wcross_color;
1395                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1396                                         }
1397                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1398                                         {
1399                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1400                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1401                                                 ring_rgb = wcross_color;
1402                                                 ring_image = "gfx/crosshair_ring.tga";
1403                                         }
1404                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1405                                         {
1406                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1407                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1408                                                 ring_rgb = wcross_color;
1409                                                 ring_image = "gfx/crosshair_ring.tga";
1410                                         }
1411
1412                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1413                                         {
1414                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1415                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1416                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1417                                                 ring_rgb = wcross_color;
1418
1419                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1420                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1421                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1422                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1423                                                 else
1424                                                         ring_image = "gfx/crosshair_ring.tga";
1425                                         }
1426
1427                                         // if in weapon switch animation, fade ring out/in
1428                                         if(autocvar_crosshair_effect_time > 0)
1429                                         {
1430                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1431                                                 if not(f < 1)
1432                                                 {
1433                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1434                                                 }
1435
1436                                                 if(wcross_ring_prev)
1437                                                 {
1438                                                         if(f < 1)
1439                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1440                                                 }
1441                                                 else
1442                                                 {
1443                                                         if(f < 1)
1444                                                                 ring_alpha *= bound(0, f, 1);
1445                                                 }
1446                                         }
1447
1448                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1449                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1450
1451                                         if (ring_value)
1452                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1453                                 }
1454
1455 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1456                                 do \
1457                                 { \
1458                                         if(wcross_blur > 0) \
1459                                         { \
1460                                                 for(i = -2; i <= 2; ++i) \
1461                                                 for(j = -2; j <= 2; ++j) \
1462                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1463                                         } \
1464                                         else \
1465                                         { \
1466                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1467                                         } \
1468                                 } \
1469                                 while(0)
1470
1471 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1472                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1473
1474 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1475                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1476
1477                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1478                                 {
1479                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1480                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1481                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1482                                         f = 1 - f;
1483                                 }
1484                                 else
1485                                 {
1486                                         f = 1;
1487                                 }
1488                                 wcross_name_alpha_goal_prev = f;
1489
1490                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1491                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1492
1493                                 if(autocvar_crosshair_dot)
1494                                 {
1495                                         vector wcross_color_old;
1496                                         wcross_color_old = wcross_color;
1497
1498                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1499                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1500
1501                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1502                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1503                                         wcross_color = wcross_color_old;
1504                                 }
1505                         }
1506                 }
1507                 else
1508                 {
1509                         wcross_scale_prev = 0;
1510                         wcross_alpha_prev = 0;
1511                         wcross_scale_goal_prev = 0;
1512                         wcross_alpha_goal_prev = 0;
1513                         wcross_changedonetime = 0;
1514                         if(wcross_name_goal_prev)
1515                                 strunzone(wcross_name_goal_prev);
1516                         wcross_name_goal_prev = string_null;
1517                         if(wcross_name_goal_prev_prev)
1518                                 strunzone(wcross_name_goal_prev_prev);
1519                         wcross_name_goal_prev_prev = string_null;
1520                         wcross_name_changestarttime = 0;
1521                         wcross_name_changedonetime = 0;
1522                         wcross_name_alpha_goal_prev = 0;
1523                         wcross_name_alpha_goal_prev_prev = 0;
1524                         wcross_resolution_goal_prev = 0;
1525                         wcross_resolution_goal_prev_prev = 0;
1526                 }
1527         }
1528
1529         if(NextFrameCommand)
1530         {
1531                 localcmd("\n", NextFrameCommand, "\n");
1532                 NextFrameCommand = string_null;
1533         }
1534
1535         // we must do this check AFTER a frame was rendered, or it won't work
1536         if(cs_project_is_b0rked == 0)
1537         {
1538                 string w0, h0;
1539                 w0 = ftos(autocvar_vid_conwidth);
1540                 h0 = ftos(autocvar_vid_conheight);
1541                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1542                 //setproperty(VF_FOV, '90 90 0');
1543                 setproperty(VF_ORIGIN, '0 0 0');
1544                 setproperty(VF_ANGLES, '0 0 0');
1545                 setproperty(VF_PERSPECTIVE, 1);
1546                 makevectors('0 0 0');
1547                 vector v1, v2;
1548                 cvar_set("vid_conwidth", "800");
1549                 cvar_set("vid_conheight", "600");
1550                 v1 = cs_project(v_forward);
1551                 cvar_set("vid_conwidth", "640");
1552                 cvar_set("vid_conheight", "480");
1553                 v2 = cs_project(v_forward);
1554                 if(v1 == v2)
1555                         cs_project_is_b0rked = 1;
1556                 else
1557                         cs_project_is_b0rked = -1;
1558                 cvar_set("vid_conwidth", w0);
1559                 cvar_set("vid_conheight", h0);
1560         }
1561
1562         if(autocvar__hud_configure)
1563                 HUD_Panel_Mouse();
1564
1565     if(hud && !intermission)
1566     {
1567         if(hud == HUD_SPIDERBOT)
1568             CSQC_SPIDER_HUD();
1569         else if(hud == HUD_WAKIZASHI)
1570             CSQC_WAKIZASHI_HUD();
1571         else if(hud == HUD_RAPTOR)
1572             CSQC_RAPTOR_HUD();
1573         else if(hud == HUD_BUMBLEBEE)
1574             CSQC_BUMBLE_HUD();
1575         else if(hud == HUD_BUMBLEBEE_GUN)
1576             CSQC_BUMBLE_GUN_HUD();
1577     }
1578
1579         cl_notice_run();
1580
1581         // let's reset the view back to normal for the end
1582         setproperty(VF_MIN, '0 0 0');
1583         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1584 }
1585
1586
1587 void CSQC_common_hud(void)
1588 {
1589         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1590                 Accuracy_LoadLevels();
1591
1592     HUD_Main(); // always run these functions for alpha checks
1593     HUD_DrawScoreboard();
1594
1595     if (scoreboard_active) // scoreboard/accuracy
1596         HUD_Reset();
1597     else if (intermission == 2) // map voting screen
1598     {
1599         HUD_FinaleOverlay();
1600         HUD_Reset();
1601     }
1602         /*
1603         switch(hud)
1604         {
1605                 case HUD_SPIDERBOT:
1606                         CSQC_SPIDER_HUD();
1607                         break;
1608
1609                 case HUD_WAKIZASHI:
1610                         CSQC_WAKIZASHI_HUD();
1611                         break;
1612
1613         case HUD_BUMBLEBEE:
1614             CSQC_BUMBLE_HUD();
1615             break;
1616         }
1617         */
1618 }
1619
1620
1621 // following vectors must be global to allow seamless switching between camera modes
1622 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1623 void CSQC_Demo_Camera()
1624 {
1625         float speed, attenuation, dimensions;
1626         vector tmp, delta;
1627
1628         if( autocvar_camera_reset || !camera_mode )
1629         {
1630                 camera_offset = '0 0 0';
1631                 current_angles = '0 0 0';
1632                 camera_direction = '0 0 0';
1633                 camera_offset_z += 30;
1634                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1635                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1636                 current_origin = view_origin;
1637                 current_camera_offset  = camera_offset;
1638                 cvar_set("camera_reset", "0");
1639                 camera_mode = CAMERA_CHASE;
1640         }
1641
1642         // Camera angles
1643         if( camera_roll )
1644                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1645
1646         if(autocvar_camera_look_player)
1647         {
1648                 vector dir;
1649                 float n;
1650
1651                 dir = normalize(view_origin - current_position);
1652                 n = mouse_angles_z;
1653                 mouse_angles = vectoangles(dir);
1654                 mouse_angles_x = mouse_angles_x * -1;
1655                 mouse_angles_z = n;
1656         }
1657         else
1658         {
1659                 tmp = getmousepos() * 0.1;
1660                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1661                 {
1662                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1663                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1664                 }
1665         }
1666
1667         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1668         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1669         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1670         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1671
1672         // Fix difference when angles don't have the same sign
1673         delta = '0 0 0';
1674         if(mouse_angles_y < -60 && current_angles_y > 60)
1675                 delta = '0 360 0';
1676         if(mouse_angles_y > 60 && current_angles_y < -60)
1677                 delta = '0 -360 0';
1678
1679         if(autocvar_camera_look_player)
1680                 attenuation = autocvar_camera_look_attenuation;
1681         else
1682                 attenuation = autocvar_camera_speed_attenuation;
1683
1684         attenuation = 1 / max(1, attenuation);
1685         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1686
1687         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1688         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1689         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1690         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1691
1692         // Camera position
1693         tmp = '0 0 0';
1694         dimensions = 0;
1695
1696         if( camera_direction_x )
1697         {
1698                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1699                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1700                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1701                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1702                 ++dimensions;
1703         }
1704
1705         if( camera_direction_y )
1706         {
1707                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1708                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1709                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1710                 ++dimensions;
1711         }
1712
1713         if( camera_direction_z )
1714         {
1715                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1716                 ++dimensions;
1717         }
1718
1719         if(autocvar_camera_free)
1720                 speed = autocvar_camera_speed_free;
1721         else
1722                 speed = autocvar_camera_speed_chase;
1723
1724         if(dimensions)
1725         {
1726                 speed = speed * sqrt(1 / dimensions);
1727                 camera_offset += tmp * speed;
1728         }
1729
1730         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1731
1732         // Camera modes
1733         if( autocvar_camera_free )
1734         {
1735                 if ( camera_mode == CAMERA_CHASE )
1736                 {
1737                         current_camera_offset = current_origin + current_camera_offset;
1738                         camera_offset = current_origin + camera_offset;
1739                 }
1740
1741                 camera_mode = CAMERA_FREE;
1742                 current_position = current_camera_offset;
1743         }
1744         else
1745         {
1746                 if ( camera_mode == CAMERA_FREE )
1747                 {
1748                         current_origin = view_origin;
1749                         camera_offset = camera_offset - current_origin;
1750                         current_camera_offset = current_camera_offset - current_origin;
1751                 }
1752
1753                 camera_mode = CAMERA_CHASE;
1754
1755                 if(autocvar_camera_chase_smoothly)
1756                         current_origin += (view_origin - current_origin) * attenuation;
1757                 else
1758                         current_origin = view_origin;
1759
1760                 current_position = current_origin + current_camera_offset;
1761         }
1762
1763         setproperty(VF_ANGLES, current_angles);
1764         setproperty(VF_ORIGIN, current_position);
1765 }