qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 203 {
 204         float fovx, fovy;
 205         float width = (ov_worldmax_x - ov_worldmin_x);
 206         float height = (ov_worldmax_y - ov_worldmin_y);
 207         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 208         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 209         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 210         return '1 0 0' * fovx + '0 1 0' * fovy;
 211 }
 212
 213 // this function must match W_SetupShot!
 214 float zoomscript_caught;
 215
 216 vector wcross_origin;
 217 float wcross_scale_prev, wcross_alpha_prev;
 218 vector wcross_color_prev;
 219 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 220 vector wcross_color_goal_prev;
 221 float wcross_changedonetime;
 222
 223 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 224 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 225 float wcross_name_changestarttime, wcross_name_changedonetime;
 226 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 227
 228 float wcross_ring_prev;
 229
 230 entity trueaim;
 231 entity trueaim_rifle;
 232
 233 #define SHOTTYPE_HITTEAM 1
 234 #define SHOTTYPE_HITOBSTRUCTION 2
 235 #define SHOTTYPE_HITWORLD 3
 236 #define SHOTTYPE_HITENEMY 4
 237
 238 void TrueAim_Init()
 239 {
 240         trueaim = spawn();
 241         trueaim.classname = "trueaim";
 242         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 243         trueaim_rifle = spawn();
 244         trueaim_rifle.classname = "trueaim_rifle";
 245         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 246 }
 247
 248 float EnemyHitCheck()
 249 {
 250         float t, n;
 251         wcross_origin = project_3d_to_2d(trace_endpos);
 252         wcross_origin_z = 0;
 253         if(trace_ent)
 254                 n = trace_ent.entnum;
 255         else
 256                 n = trace_networkentity;
 257         if(n < 1)
 258                 return SHOTTYPE_HITWORLD;
 259         if(n > maxclients)
 260                 return SHOTTYPE_HITWORLD;
 261         t = GetPlayerColor(n - 1);
 262         if(teamplay)
 263                 if(t == myteam)
 264                         return SHOTTYPE_HITTEAM;
 265         if(t == NUM_SPECTATOR)
 266                 return SHOTTYPE_HITWORLD;
 267         return SHOTTYPE_HITENEMY;
 268 }
 269
 270 float TrueAimCheck()
 271 {
 272         float nudge = 1; // added to traceline target and subtracted from result
 273         vector vecs, trueaimpoint, w_shotorg;
 274         vector mi, ma, dv;
 275         float shottype;
 276         entity ta;
 277         float mv;
 278
 279         mi = ma = '0 0 0';
 280         ta = trueaim;
 281         mv = MOVE_NOMONSTERS;
 282
 283         switch(activeweapon)
 284         {
 285                 case WEP_TUBA: // no aim
 286                 case WEP_PORTO: // shoots from eye
 287                 case WEP_HOOK: // no trueaim
 288                 case WEP_GRENADE_LAUNCHER: // toss curve
 289                         return SHOTTYPE_HITWORLD;
 290                 case WEP_NEX:
 291                 case WEP_MINSTANEX:
 292                         mv = MOVE_NORMAL;
 293                         break;
 294                 case WEP_RIFLE:
 295                         ta = trueaim_rifle;
 296                         mv = MOVE_NORMAL;
 297                         if(zoomscript_caught)
 298                         {
 299                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 300                                 return EnemyHitCheck();
 301                         }
 302                         break;
 303                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 304                         mi = '-3 -3 -3';
 305                         ma = '3 3 3';
 306                         break;
 307                 case WEP_FIREBALL: // projectile has a size!
 308                         mi = '-16 -16 -16';
 309                         ma = '16 16 16';
 310                         break;
 311                 case WEP_SEEKER: // projectile has a size!
 312                         mi = '-2 -2 -2';
 313                         ma = '2 2 2';
 314                         break;
 315                 case WEP_ELECTRO: // projectile has a size!
 316                         mi = '0 0 -3';
 317                         ma = '0 0 -3';
 318                         break;
 319         }
 320
 321         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 322
 323         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 324
 325         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 326         trueaimpoint = trace_endpos;
 327
 328         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 329                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 330
 331         if(vecs_x > 0)
 332                 vecs_y = -vecs_y;
 333         else
 334                 vecs = '0 0 0';
 335
 336         dv = view_right * vecs_y + view_up * vecs_z;
 337         w_shotorg = traceorigin + dv;
 338
 339         // now move the vecs forward as much as requested if possible
 340         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 341         w_shotorg = trace_endpos - view_forward * nudge;
 342
 343         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 344         shottype = EnemyHitCheck();
 345         if(shottype != SHOTTYPE_HITWORLD)
 346                 return shottype;
 347
 348 #if 0
 349         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 350         // or rather, I know why, but see no fix
 351         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 352                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 353                 return SHOTTYPE_HITOBSTRUCTION;
 354 #endif
 355
 356         return SHOTTYPE_HITWORLD;
 357 }
 358
 359 void CSQC_common_hud(void);
 360
 361 void PostInit(void);
 362 void CSQC_Demo_Camera();
 363 float HUD_WouldDrawScoreboard();
 364 float camera_mode;
 365 const float CAMERA_FREE = 1;
 366 const float CAMERA_CHASE = 2;
 367 float reticle_type;
 368 string NextFrameCommand;
 369 void CSQC_SPIDER_HUD();
 370 void CSQC_RAPTOR_HUD();
 371
 372 vector freeze_org, freeze_ang;
 373 entity nightvision_noise, nightvision_noise2;
 374
 375 #define MAX_TIME_DIFF 5
 376 float pickup_crosshair_time, pickup_crosshair_size;
 377 float hitsound_time_prev;
 378 float spectatee_status_prev; // for preventing hitsound when switching spectatee
 379 float damage_dealt_total, damage_dealt_total_prev;
 380 float typehit_time, typehit_time_prev;
 381 float hitindication_crosshair_size;
 382 float use_nex_chargepool;
 383
 384 float myhealth, myhealth_prev;
 385 float myhealth_flash;
 386
 387 float old_blurradius, old_bluralpha;
 388 float old_sharpen_intensity;
 389
 390 vector myhealth_gentlergb;
 391
 392 float contentavgalpha, liquidalpha_prev;
 393 vector liquidcolor_prev;
 394
 395 float eventchase_current_distance;
 396
 397 vector damage_blurpostprocess, content_blurpostprocess;
 398
 399 float checkfail[16];
 400
 401 float rainbow_last_flicker;
 402 vector rainbow_prev_color;
 403
 404 #define BUTTON_3 4
 405 #define BUTTON_4 8
 406 float cl_notice_run();
 407 float prev_myteam;
 408 void CSQC_UpdateView(float w, float h)
 409 {
 410         entity e;
 411         float fov;
 412         float f, i, j;
 413         vector v;
 414         vector vf_size, vf_min;
 415         float a;
 416
 417         execute_next_frame();
 418
 419         ++framecount;
 420
 421         hud = getstati(STAT_HUD);
 422
 423         if(autocvar__hud_showbinds_reload) // menu can set this one
 424         {
 425                 db_close(binddb);
 426                 binddb = db_create();
 427                 cvar_set("_hud_showbinds_reload", "0");
 428         }
 429
 430         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 431                 view_quality = getproperty(VF_MINFPS_QUALITY);
 432         else
 433                 view_quality = 1;
 434
 435         button_attack2 = (input_buttons & BUTTON_3);
 436         button_zoom = (input_buttons & BUTTON_4);
 437
 438 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 439         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 440         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 441         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 442         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 443         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 444         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 445         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 446
 447         vf_size = getpropertyvec(VF_SIZE);
 448         vf_min = getpropertyvec(VF_MIN);
 449         vid_width = vf_size_x;
 450         vid_height = vf_size_y;
 451
 452         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 453         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 454
 455         WaypointSprite_Load();
 456
 457         CSQCPlayer_SetCamera();
 458
 459 #ifdef COMPAT_XON050_ENGINE
 460         if(spectatee_status)
 461                 myteam = GetPlayerColor(spectatee_status - 1);
 462         else
 463 #endif
 464                 myteam = GetPlayerColor(player_localentnum - 1);
 465
 466         if(myteam != prev_myteam)
 467         {
 468                 myteamcolors = colormapPaletteColor(myteam, 1);
 469                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 470                         hud_panel[i].update_time = time;
 471                 prev_myteam = myteam;
 472         }
 473
 474         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 475
 476         float is_dead = (getstati(STAT_HEALTH) <= 0);
 477
 478         // FIXME do we need this hack?
 479         if(isdemo())
 480         {
 481                 // in demos, input_buttons do not work
 482                 button_zoom = (autocvar__togglezoom == "-");
 483         }
 484         else if(button_zoom
 485                 && autocvar_cl_unpress_zoom_on_death
 486                 && (spectatee_status >= 0)
 487                 && (is_dead || intermission))
 488         {
 489                 // no zoom while dead or in intermission please
 490                 localcmd("-zoom\n");
 491                 button_zoom = FALSE;
 492         }
 493
 494         // event chase camera
 495         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 496         {
 497                 WepSet weapons_stat = WepSet_GetFromStat();
 498                 if(((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission) && !autocvar_cl_orthoview || (autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(weapons_stat & WepSet_FromWeapon(WEP_PORTO))))
 499                 {
 500                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 501                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 502
 503                         // detect maximum viewoffset and use it
 504                         if(autocvar_cl_eventchase_viewoffset)
 505                         {
 506                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 507                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 508                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 509                         }
 510
 511                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 512                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 513                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 514                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 515
 516                         // make the camera smooth back
 517                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 518                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 519                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 520                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 521
 522                         makevectors(view_angles);
 523
 524                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 525                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 526
 527                         // If the boxtrace fails, revert back to line tracing.
 528                         if(trace_startsolid)
 529                         {
 530                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 531                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 532                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 533                         }
 534                         else { setproperty(VF_ORIGIN, trace_endpos); }
 535
 536                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 537                 }
 538                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 539                 {
 540                         cvar_set("chase_active", "0");
 541                         eventchase_current_distance = 0; // start from 0 next time
 542                 }
 543         }
 544         // workaround for camera stuck between player's legs when using chase_active 1
 545         // because the engine stops updating the chase_active camera when the game ends
 546         else if(intermission)
 547         {
 548                 cvar_settemp("chase_active", "-1");
 549                 eventchase_current_distance = 0;
 550         }
 551
 552         // do lockview after event chase camera so that it still applies whenever necessary.
 553         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 554         {
 555                 setproperty(VF_ORIGIN, freeze_org);
 556                 setproperty(VF_ANGLES, freeze_ang);
 557         }
 558         else
 559         {
 560                 freeze_org = getpropertyvec(VF_ORIGIN);
 561                 freeze_ang = getpropertyvec(VF_ANGLES);
 562         }
 563
 564         WarpZone_FixView();
 565         //WarpZone_FixPMove();
 566
 567         vector ov_org = '0 0 0';
 568         vector ov_mid = '0 0 0';
 569         vector ov_worldmin = '0 0 0';
 570         vector ov_worldmax = '0 0 0';
 571         if(autocvar_cl_orthoview)
 572         {
 573                 ov_worldmin = mi_picmin;
 574                 ov_worldmax = mi_picmax;
 575
 576                 float ov_width = (ov_worldmax_x - ov_worldmin_x);
 577                 float ov_height = (ov_worldmax_y - ov_worldmin_y);
 578                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
 579
 580                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
 581                 ov_org = vec3(ov_mid_x, ov_mid_y, (ov_mid_z + ov_distance));
 582
 583                 float ov_nearest = vlen(ov_org - vec3(
 584                         bound(ov_worldmin_x, ov_org_x, ov_worldmax_x),
 585                         bound(ov_worldmin_y, ov_org_y, ov_worldmax_y),
 586                         bound(ov_worldmin_z, ov_org_z, ov_worldmax_z)
 587                 ));
 588
 589                 float ov_furthest = 0;
 590                 float dist = 0;
 591
 592                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 593                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 594                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 595                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 596                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmin_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 597                 if((dist = vlen(vec3(ov_worldmin_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 598                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmin_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 599                 if((dist = vlen(vec3(ov_worldmax_x, ov_worldmax_y, ov_worldmax_z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
 600
 601                 cvar_settemp("r_nearclip", ftos(ov_nearest));
 602                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
 603                 cvar_settemp("r_farclip_world", "0");
 604                 cvar_settemp("r_novis", "1");
 605                 cvar_settemp("r_useportalculling", "0");
 606                 cvar_settemp("r_useinfinitefarclip", "0");
 607
 608                 setproperty(VF_ORIGIN, ov_org);
 609                 setproperty(VF_ANGLES, '90 0 0');
 610
 611                 #if 0
 612                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
 613                         vtos(ov_org),
 614                         vtos(getpropertyvec(VF_ANGLES)),
 615                         ov_distance,
 616                         ov_nearest,
 617                         ov_furthest);
 618                 #endif
 619         }
 620
 621         // Render the Scene
 622         view_origin = getpropertyvec(VF_ORIGIN);
 623         view_angles = getpropertyvec(VF_ANGLES);
 624         makevectors(view_angles);
 625         view_forward = v_forward;
 626         view_right = v_right;
 627         view_up = v_up;
 628
 629 #ifdef BLURTEST
 630         if(time > blurtest_time0 && time < blurtest_time1)
 631         {
 632                 float r, t;
 633
 634                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 635                 r = t * blurtest_radius;
 636                 f = 1 / pow(t, blurtest_power) - 1;
 637
 638                 cvar_set("r_glsl_postprocess", "1");
 639                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 640         }
 641         else
 642         {
 643                 cvar_set("r_glsl_postprocess", "0");
 644                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 645         }
 646 #endif
 647
 648         TargetMusic_Advance();
 649         Fog_Force();
 650
 651         if(drawtime == 0)
 652                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 653         else
 654                 drawframetime = bound(0.000001, time - drawtime, 1);
 655         drawtime = time;
 656
 657         // watch for gametype changes here...
 658         // in ParseStuffCMD the cmd isn't executed yet :/
 659         // might even be better to add the gametype to TE_CSQC_INIT...?
 660         if(!postinit)
 661                 PostInit();
 662
 663         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 664         {
 665                 if(calledhooks & HOOK_START)
 666                 {
 667                         localcmd("\ncl_hook_gameend\n");
 668                         calledhooks |= HOOK_END;
 669                 }
 670         }
 671
 672         Announcer();
 673
 674         fov = autocvar_fov;
 675         if(fov <= 59.5)
 676         {
 677                 if(!zoomscript_caught)
 678                 {
 679                         localcmd("+button9\n");
 680                         zoomscript_caught = 1;
 681                 }
 682         }
 683         else
 684         {
 685                 if(zoomscript_caught)
 686                 {
 687                         localcmd("-button9\n");
 688                         zoomscript_caught = 0;
 689                 }
 690         }
 691
 692         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 693
 694         // next WANTED weapon (for HUD)
 695         switchweapon = getstati(STAT_SWITCHWEAPON);
 696
 697         // currently switching-to weapon (for crosshair)
 698         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 699
 700         // actually active weapon (for zoom)
 701         activeweapon = getstati(STAT_ACTIVEWEAPON);
 702
 703         f = (serverflags & SERVERFLAG_TEAMPLAY);
 704         if(f != teamplay)
 705         {
 706                 teamplay = f;
 707                 HUD_InitScores();
 708         }
 709
 710         if(last_switchweapon != switchweapon)
 711         {
 712                 weapontime = time;
 713                 last_switchweapon = switchweapon;
 714                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 715                 {
 716                         localcmd("-zoom\n");
 717                         button_zoom = FALSE;
 718                 }
 719                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 720                 {
 721                         localcmd("-fire\n");
 722                         localcmd("-fire2\n");
 723                         button_attack2 = FALSE;
 724                 }
 725         }
 726         if(last_activeweapon != activeweapon)
 727         {
 728                 last_activeweapon = activeweapon;
 729
 730                 e = get_weaponinfo(activeweapon);
 731                 if(e.netname != "")
 732                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 733                 else
 734                         localcmd("\ncl_hook_activeweapon none\n");
 735         }
 736
 737         // ALWAYS Clear Current Scene First
 738         clearscene();
 739 #ifdef WORKAROUND_XON010
 740         if(checkextension("DP_CSQC_ROTATEMOVES"))
 741         {
 742 #endif
 743         setproperty(VF_ORIGIN, view_origin);
 744         setproperty(VF_ANGLES, view_angles);
 745 #ifdef WORKAROUND_XON010
 746         }
 747 #endif
 748
 749         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 750         setproperty(VF_SIZE, vf_size);
 751         setproperty(VF_MIN, vf_min);
 752
 753         // Assign Standard Viewflags
 754         // Draw the World (and sky)
 755         setproperty(VF_DRAWWORLD, 1);
 756
 757         // Set the console size vars
 758         vid_conwidth = autocvar_vid_conwidth;
 759         vid_conheight = autocvar_vid_conheight;
 760         vid_pixelheight = autocvar_vid_pixelheight;
 761
 762         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
 763         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
 764
 765         // Camera for demo playback
 766         if(camera_active)
 767         {
 768                 if(autocvar_camera_enable)
 769                         CSQC_Demo_Camera();
 770                 else
 771                 {
 772                         cvar_set("chase_active", ftos(chase_active_backup));
 773                         cvar_set("cl_demo_mousegrab", "0");
 774                         camera_active = FALSE;
 775                 }
 776         }
 777 #ifdef CAMERATEST
 778         else if(autocvar_camera_enable)
 779 #else
 780         else if(autocvar_camera_enable && isdemo())
 781 #endif
 782         {
 783                 // Enable required Darkplaces cvars
 784                 chase_active_backup = autocvar_chase_active;
 785                 cvar_set("chase_active", "2");
 786                 cvar_set("cl_demo_mousegrab", "1");
 787                 camera_active = TRUE;
 788                 camera_mode = FALSE;
 789         }
 790
 791         // Draw the Crosshair
 792         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 793
 794         // Draw the Engine Status Bar (the default Quake HUD)
 795         setproperty(VF_DRAWENGINESBAR, 0);
 796
 797         // Update the mouse position
 798         /*
 799            mousepos_x = vid_conwidth;
 800            mousepos_y = vid_conheight;
 801            mousepos = mousepos*0.5 + getmousepos();
 802          */
 803
 804         e = self;
 805         for(self = world; (self = nextent(self)); )
 806                 if(self.draw)
 807                         self.draw();
 808         self = e;
 809
 810         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 811         renderscene();
 812
 813         // now switch to 2D drawing mode by calling a 2D drawing function
 814         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 815         // next R_RenderScene call
 816         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 817
 818         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 819         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 820         {
 821                 // apply night vision effect
 822                 vector tc_00, tc_01, tc_10, tc_11;
 823                 vector rgb;
 824                 rgb_x = 0; // fteqcc sucks
 825                 rgb_y = 0; // fteqcc sucks
 826                 rgb_z = 0; // fteqcc sucks
 827
 828                 if(!nightvision_noise)
 829                 {
 830                         nightvision_noise = spawn();
 831                         nightvision_noise.classname = "nightvision_noise";
 832                 }
 833                 if(!nightvision_noise2)
 834                 {
 835                         nightvision_noise2 = spawn();
 836                         nightvision_noise2.classname = "nightvision_noise2";
 837                 }
 838
 839                 // color tint in yellow
 840                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 841
 842                 // draw BG
 843                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 844                 rgb = '1 1 1';
 845                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 846                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 847                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 848                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 849                 tc_11 = tc_01 + tc_10 - tc_00;
 850                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 851                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 852                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 853                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 854                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 855                 R_EndPolygon();
 856
 857                 // draw FG
 858                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 859                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 860                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 861                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 862                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 863                 tc_11 = tc_01 + tc_10 - tc_00;
 864                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 865                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 866                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 867                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 868                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 869                 R_EndPolygon();
 870         }
 871
 872         // Draw the aiming reticle for weapons that use it
 873         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 874         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 875         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 876         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 877                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 878         else if((activeweapon == WEP_NEX || activeweapon == WEP_RIFLE || activeweapon == WEP_MINSTANEX) && (button_zoom || zoomscript_caught))
 879                 reticle_type = 2; // nex zoom
 880         else if(button_zoom || zoomscript_caught)
 881                 reticle_type = 1; // normal zoom
 882         else if((activeweapon == WEP_NEX) && button_attack2)
 883                 reticle_type = 2; // nex zoom
 884
 885         if(reticle_type && autocvar_cl_reticle)
 886         {
 887                 if(autocvar_cl_reticle_stretch)
 888                 {
 889                         reticle_size_x = vid_conwidth;
 890                         reticle_size_y = vid_conheight;
 891                         reticle_pos_x = 0;
 892                         reticle_pos_y = 0;
 893                 }
 894                 else
 895                 {
 896                         reticle_size_x = max(vid_conwidth, vid_conheight);
 897                         reticle_size_y = max(vid_conwidth, vid_conheight);
 898                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 899                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 900                 }
 901
 902                 f = current_zoomfraction;
 903                 if(zoomscript_caught)
 904                         f = 1;
 905                 if(autocvar_cl_reticle_item_normal)
 906                 {
 907                         if(reticle_type == 1 && f)
 908                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 909                 }
 910                 if(autocvar_cl_reticle_item_nex)
 911                 {
 912                         if(reticle_type == 2 && f)
 913                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 914                 }
 915         }
 916
 917
 918         // improved polyblend
 919         if(autocvar_hud_contents)
 920         {
 921                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 922                 vector liquidcolor;
 923
 924                 switch(pointcontents(view_origin))
 925                 {
 926                         case CONTENT_WATER:
 927                                 liquidalpha = autocvar_hud_contents_water_alpha;
 928                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 929                                 incontent = 1;
 930                                 break;
 931
 932                         case CONTENT_LAVA:
 933                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 934                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 935                                 incontent = 1;
 936                                 break;
 937
 938                         case CONTENT_SLIME:
 939                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 940                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 941                                 incontent = 1;
 942                                 break;
 943
 944                         default:
 945                                 liquidalpha = 0;
 946                                 liquidcolor = '0 0 0';
 947                                 incontent = 0;
 948                                 break;
 949                 }
 950
 951                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 952                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 953                         contentfadetime = autocvar_hud_contents_fadeintime;
 954                         liquidalpha_prev = liquidalpha;
 955                         liquidcolor_prev = liquidcolor;
 956                 }
 957                 else
 958                         contentfadetime = autocvar_hud_contents_fadeouttime;
 959
 960                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 961                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 962
 963                 if(contentavgalpha)
 964                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 965
 966                 if(autocvar_hud_postprocessing)
 967                 {
 968                         if(autocvar_hud_contents_blur && contentavgalpha)
 969                         {
 970                                 content_blurpostprocess_x = 1;
 971                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 972                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 973                         }
 974                         else
 975                         {
 976                                 content_blurpostprocess_x = 0;
 977                                 content_blurpostprocess_y = 0;
 978                                 content_blurpostprocess_z = 0;
 979                         }
 980                 }
 981         }
 982
 983         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 984         {
 985                 splash_size_x = max(vid_conwidth, vid_conheight);
 986                 splash_size_y = max(vid_conwidth, vid_conheight);
 987                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 988                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 989
 990                 float myhealth_flash_temp;
 991                 myhealth = getstati(STAT_HEALTH);
 992
 993                 // fade out
 994                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 995                 // add new damage
 996                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 997
 998                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 999                 pain_threshold = autocvar_hud_damage_pain_threshold;
1000                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1001                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1002
1003                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1004                 {
1005                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1006                 }
1007
1008                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1009
1010                 if(myhealth_prev < 1)
1011                 {
1012                         if(myhealth >= 1)
1013                         {
1014                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1015                                 myhealth_flash_temp = 0;
1016                         }
1017                         else
1018                         {
1019                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1020                         }
1021                 }
1022
1023                 if(spectatee_status == -1 || intermission)
1024                 {
1025                         myhealth_flash = 0; // observing, or match ended
1026                         myhealth_flash_temp = 0;
1027                 }
1028
1029                 myhealth_prev = myhealth;
1030
1031                 // IDEA: change damage color/picture based on player model for robot/alien species?
1032                 // pro: matches model better
1033                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1034                 // maybe different reddish pics?
1035                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1036                 {
1037                         if(autocvar_cl_gentle_damage == 2)
1038                         {
1039                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1040                                 {
1041                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1042                                 }
1043                         }
1044                         else
1045                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1046
1047                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1048                 }
1049                 else
1050                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1051
1052                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1053                 {
1054                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1055                         {
1056                                 damage_blurpostprocess_x = 1;
1057                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1058                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1059                         }
1060                         else
1061                         {
1062                                 damage_blurpostprocess_x = 0;
1063                                 damage_blurpostprocess_y = 0;
1064                                 damage_blurpostprocess_z = 0;
1065                         }
1066                 }
1067         }
1068
1069         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1070         float e2 = (autocvar_hud_powerup != 0);
1071         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1072         {
1073                 // enable or disable rendering types if they are used or not
1074                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1075                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1076
1077                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1078                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1079                 {
1080                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1081                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1082                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1083                         {
1084                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1085                                 old_blurradius = blurradius;
1086                                 old_bluralpha = bluralpha;
1087                         }
1088                 }
1089                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1090                 {
1091                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1092                         old_blurradius = 0;
1093                         old_bluralpha = 0;
1094                 }
1095
1096                 // edge detection postprocess handling done second (used by hud_powerup)
1097                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1098                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1099                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1100
1101                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1102
1103                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1104                 {
1105                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1106                         {
1107                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1108                                 old_sharpen_intensity = sharpen_intensity;
1109                         }
1110                 }
1111                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1112                 {
1113                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1114                         old_sharpen_intensity = 0;
1115                 }
1116
1117                 if(cvar("r_glsl_postprocess") == 0)
1118                         cvar_set("r_glsl_postprocess", "2");
1119         }
1120         else if(cvar("r_glsl_postprocess") == 2)
1121                 cvar_set("r_glsl_postprocess", "0");
1122
1123         if(menu_visible)
1124                 menu_show();
1125
1126         /*if(gametype == MAPINFO_TYPE_CTF)
1127           {
1128           ctf_view();
1129           } else */
1130
1131         // draw 2D entities
1132         e = self;
1133         for(self = world; (self = nextent(self)); )
1134                 if(self.draw2d)
1135                         self.draw2d();
1136         self = e;
1137         Draw_ShowNames_All();
1138
1139         scoreboard_active = HUD_WouldDrawScoreboard();
1140
1141         // varying sound pitch
1142         damage_dealt_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
1143
1144         // detect overflow on server side
1145         if (damage_dealt_total < damage_dealt_total_prev)
1146         {
1147                 dprint("resetting dmg total: ", ftos(damage_dealt_total), " prev: ", ftos(damage_dealt_total_prev), "\n");
1148                 damage_dealt_total_prev = 0;
1149         }
1150
1151         // prevent hitsound when switching spectatee
1152         if (spectatee_status != spectatee_status_prev)
1153         {
1154                 damage_dealt_total_prev = damage_dealt_total;
1155         }
1156         spectatee_status_prev = spectatee_status;
1157
1158         // amount of damage since last hit sound
1159         float unaccounted_damage = damage_dealt_total - damage_dealt_total_prev;
1160
1161
1162         if (autocvar_cl_hitsound == 1)
1163         {
1164                 if ( time - hitsound_time_prev > autocvar_cl_hitsound_antispam_time )
1165                 if ( damage_dealt_total > 0 )
1166                 {
1167                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1168                         hitsound_time_prev = time;
1169                 }
1170         }
1171         else if (unaccounted_damage > 0 && autocvar_cl_hitsound > 0 && time - hitsound_time_prev > autocvar_cl_hitsound_antispam_time)
1172         {
1173                 // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
1174                 float a, b, c, x;
1175                 a = autocvar_cl_hitsound_max_pitch;
1176                 b = autocvar_cl_hitsound_min_pitch;
1177                 c = autocvar_cl_hitsound_nom_damage;
1178                 x = unaccounted_damage;
1179                 float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
1180
1181                 // if sound variation is disabled, set pitch_shift to 1
1182                 if (autocvar_cl_hitsound == 1)
1183                 {
1184                         pitch_shift = 1;
1185                 }
1186
1187                 // if pitch shift is reversed, mirror in (max-min)/2 + min
1188                 if (autocvar_cl_hitsound == 3)
1189                 {
1190                         float mirror_value = (a-b)/2 + b;
1191                         pitch_shift = mirror_value + (mirror_value - pitch_shift);
1192                 }
1193
1194                 dprint("dmg total (dmg): ", ftos(damage_dealt_total), " (+", ftos(unaccounted_damage), "), pitch shift: ", ftos(pitch_shift), "\n");
1195
1196                 // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
1197                 // todo: normalize sound pressure levels? seems unnecessary
1198
1199                 // scale to fit function interface
1200                 float param_pitch_shift = pitch_shift * 100;
1201
1202                 // play sound
1203                 sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, param_pitch_shift, 0);
1204
1205                 // track damage accounted for
1206                 damage_dealt_total_prev = damage_dealt_total;
1207
1208                 // remember when this sound was played to prevent sound spam
1209                 hitsound_time_prev = time;
1210         }
1211         else if (autocvar_cl_hitsound == 0)
1212         {
1213                 // forget the damage to prevent hitsound when enabling it
1214                 damage_dealt_total_prev = damage_dealt_total;
1215         }
1216
1217         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1218         if(typehit_time - typehit_time_prev > autocvar_cl_hitsound_antispam_time)
1219         {
1220                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1221                 typehit_time_prev = typehit_time;
1222         }
1223
1224         //else
1225         {
1226                 if(getstati(STAT_FROZEN))
1227                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1228                 else if (getstatf(STAT_HEALING_ORB)>time)
1229                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1230                 if(!intermission)
1231                 if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1232                 {
1233                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1234                         drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1235                 }
1236                 else if(getstatf(STAT_REVIVE_PROGRESS))
1237                 {
1238                         DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1239                         drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1240                 }
1241
1242                 if(autocvar_r_letterbox == 0)
1243                         if(autocvar_viewsize < 120)
1244                                 CSQC_common_hud();
1245
1246                 // crosshair goes VERY LAST
1247                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1248                 {
1249                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1250                                 return;
1251
1252                         string wcross_style;
1253                         float wcross_alpha, wcross_resolution;
1254                         wcross_style = autocvar_crosshair;
1255                         if (wcross_style == "0")
1256                                 return;
1257                         wcross_resolution = autocvar_crosshair_size;
1258                         if (wcross_resolution == 0)
1259                                 return;
1260                         wcross_alpha = autocvar_crosshair_alpha;
1261                         if (wcross_alpha == 0)
1262                                 return;
1263
1264                         // TrueAim check
1265                         float shottype;
1266
1267                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1268                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1269                         wcross_origin_z = 0;
1270                         if(autocvar_crosshair_hittest)
1271                         {
1272                                 vector wcross_oldorigin;
1273                                 wcross_oldorigin = wcross_origin;
1274                                 shottype = TrueAimCheck();
1275                                 if(shottype == SHOTTYPE_HITWORLD)
1276                                 {
1277                                         v = wcross_origin - wcross_oldorigin;
1278                                         v_x /= vid_conwidth;
1279                                         v_y /= vid_conheight;
1280                                         if(vlen(v) > 0.01)
1281                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1282                                 }
1283                                 if(!autocvar_crosshair_hittest_showimpact)
1284                                         wcross_origin = wcross_oldorigin;
1285                         }
1286                         else
1287                                 shottype = SHOTTYPE_HITWORLD;
1288
1289                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1290                         string wcross_wep = "", wcross_name;
1291                         float wcross_scale, wcross_blur;
1292
1293                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1294                         {
1295                                 e = get_weaponinfo(switchingweapon);
1296                                 if (e && e.netname != "")
1297                                 {
1298                                         wcross_wep = e.netname;
1299                                         if(autocvar_crosshair_per_weapon)
1300                                         {
1301                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1302                                                 if (wcross_resolution == 0)
1303                                                         return;
1304                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1305                                                 if (wcross_alpha == 0)
1306                                                         return;
1307
1308                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1309                                                 if(wcross_style == "" || wcross_style == "0")
1310                                                         wcross_style = wcross_wep;
1311                                         }
1312                                 }
1313                         }
1314
1315                         //printf("crosshair style: %s\n", wcross_style);
1316                         wcross_name = strcat("gfx/crosshair", wcross_style);
1317
1318                         // MAIN CROSSHAIR COLOR DECISION
1319                         switch(autocvar_crosshair_color_special)
1320                         {
1321                                 case 1: // crosshair_color_per_weapon
1322                                 {
1323                                         if(wcross_wep != "")
1324                                         {
1325                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1326                                                 break;
1327                                         }
1328                                         else { goto normalcolor; }
1329                                 }
1330
1331                                 case 2: // crosshair_color_by_health
1332                                 {
1333                                         float x = getstati(STAT_HEALTH);
1334
1335                                         //x = red
1336                                         //y = green
1337                                         //z = blue
1338
1339                                         wcross_color_z = 0;
1340
1341                                         if(x > 200)
1342                                         {
1343                                                 wcross_color_x = 0;
1344                                                 wcross_color_y = 1;
1345                                         }
1346                                         else if(x > 150)
1347                                         {
1348                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1349                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1350                                         }
1351                                         else if(x > 100)
1352                                         {
1353                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1354                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1355                                                 wcross_color_z = 1 - (x-100)*0.02;
1356                                         }
1357                                         else if(x > 50)
1358                                         {
1359                                                 wcross_color_x = 1;
1360                                                 wcross_color_y = 1;
1361                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1362                                         }
1363                                         else if(x > 20)
1364                                         {
1365                                                 wcross_color_x = 1;
1366                                                 wcross_color_y = (x-20)*90/27/100;
1367                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1368                                         }
1369                                         else
1370                                         {
1371                                                 wcross_color_x = 1;
1372                                                 wcross_color_y = 0;
1373                                         }
1374                                         break;
1375                                 }
1376
1377                                 case 3: // crosshair_color_rainbow
1378                                 {
1379                                         if(time >= rainbow_last_flicker)
1380                                         {
1381                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1382                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1383                                         }
1384                                         wcross_color = rainbow_prev_color;
1385                                         break;
1386                                 }
1387                                 :normalcolor
1388                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1389                         }
1390
1391                         if(autocvar_crosshair_effect_scalefade)
1392                         {
1393                                 wcross_scale = wcross_resolution;
1394                                 wcross_resolution = 1;
1395                         }
1396                         else
1397                         {
1398                                 wcross_scale = 1;
1399                         }
1400
1401                         if(autocvar_crosshair_pickup)
1402                         {
1403                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1404
1405                                 if(pickup_crosshair_time < stat_pickup_time)
1406                                 {
1407                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1408                                                 pickup_crosshair_size = 1;
1409
1410                                         pickup_crosshair_time = stat_pickup_time;
1411                                 }
1412
1413                                 if(pickup_crosshair_size > 0)
1414                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1415                                 else
1416                                         pickup_crosshair_size = 0;
1417
1418                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1419                         }
1420
1421                         // todo: make crosshair hit indication dependent on damage dealt
1422                         if(autocvar_crosshair_hitindication)
1423                         {
1424                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1425
1426                                 if(unaccounted_damage)
1427                                 {
1428                                         hitindication_crosshair_size = 1;
1429                                 }
1430
1431                                 if(hitindication_crosshair_size > 0)
1432                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1433                                 else
1434                                         hitindication_crosshair_size = 0;
1435
1436                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1437                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1438                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1439                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1440                         }
1441
1442                         if(shottype == SHOTTYPE_HITENEMY)
1443                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1444                         if(shottype == SHOTTYPE_HITTEAM)
1445                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1446
1447                         f = fabs(autocvar_crosshair_effect_time);
1448                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1449                         {
1450                                 wcross_changedonetime = time + f;
1451                         }
1452                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1453                         {
1454                                 wcross_name_changestarttime = time;
1455                                 wcross_name_changedonetime = time + f;
1456                                 if(wcross_name_goal_prev_prev)
1457                                         strunzone(wcross_name_goal_prev_prev);
1458                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1459                                 wcross_name_goal_prev = strzone(wcross_name);
1460                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1461                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1462                                 wcross_resolution_goal_prev = wcross_resolution;
1463                         }
1464
1465                         wcross_scale_goal_prev = wcross_scale;
1466                         wcross_alpha_goal_prev = wcross_alpha;
1467                         wcross_color_goal_prev = wcross_color;
1468
1469                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1470                         {
1471                                 wcross_blur = 1;
1472                                 wcross_alpha *= 0.75;
1473                         }
1474                         else
1475                                 wcross_blur = 0;
1476                         // *_prev is at time-frametime
1477                         // * is at wcross_changedonetime+f
1478                         // what do we have at time?
1479                         if(time < wcross_changedonetime)
1480                         {
1481                                 f = frametime / (wcross_changedonetime - time + frametime);
1482                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1483                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1484                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1485                         }
1486
1487                         wcross_scale_prev = wcross_scale;
1488                         wcross_alpha_prev = wcross_alpha;
1489                         wcross_color_prev = wcross_color;
1490
1491                         wcross_scale *= 1 - autocvar__menu_alpha;
1492                         wcross_alpha *= 1 - autocvar__menu_alpha;
1493                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1494
1495                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1496                         {
1497                                 // crosshair rings for weapon stats
1498                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1499                                 {
1500                                         // declarations and stats
1501                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1502                                         string ring_image = string_null, ring_inner_image = string_null;
1503                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1504
1505                                         ring_scale = autocvar_crosshair_ring_size;
1506
1507                                         float weapon_clipload, weapon_clipsize;
1508                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1509                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1510
1511                                         float nex_charge, nex_chargepool;
1512                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1513                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1514
1515                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1516                                                 nex_charge_movingavg = nex_charge;
1517
1518
1519                                         // handle the values
1520                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1521                                         {
1522                                                 if (nex_chargepool || use_nex_chargepool) {
1523                                                         use_nex_chargepool = 1;
1524                                                         ring_inner_value = nex_chargepool;
1525                                                 } else {
1526                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1527                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1528                                                 }
1529
1530                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1531                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1532                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1533
1534                                                 // draw the outer ring to show the current charge of the weapon
1535                                                 ring_value = nex_charge;
1536                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1537                                                 ring_rgb = wcross_color;
1538                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1539                                         }
1540                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1541                                         {
1542                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1543                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1544                                                 ring_rgb = wcross_color;
1545                                                 ring_image = "gfx/crosshair_ring.tga";
1546                                         }
1547                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1548                                         {
1549                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1550                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1551                                                 ring_rgb = wcross_color;
1552                                                 ring_image = "gfx/crosshair_ring.tga";
1553                                         }
1554
1555                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1556                                         {
1557                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1558                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1559                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1560                                                 ring_rgb = wcross_color;
1561
1562                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1563                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1564                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1565                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1566                                                 else
1567                                                         ring_image = "gfx/crosshair_ring.tga";
1568                                         }
1569
1570                                         // if in weapon switch animation, fade ring out/in
1571                                         if(autocvar_crosshair_effect_time > 0)
1572                                         {
1573                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1574                                                 if (!(f < 1))
1575                                                 {
1576                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1577                                                 }
1578
1579                                                 if(wcross_ring_prev)
1580                                                 {
1581                                                         if(f < 1)
1582                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1583                                                 }
1584                                                 else
1585                                                 {
1586                                                         if(f < 1)
1587                                                                 ring_alpha *= bound(0, f, 1);
1588                                                 }
1589                                         }
1590
1591                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1592                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1593
1594                                         if (ring_value)
1595                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1596                                 }
1597
1598 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1599                                 do \
1600                                 { \
1601                                         if(wcross_blur > 0) \
1602                                         { \
1603                                                 for(i = -2; i <= 2; ++i) \
1604                                                 for(j = -2; j <= 2; ++j) \
1605                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1606                                         } \
1607                                         else \
1608                                         { \
1609                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1610                                         } \
1611                                 } \
1612                                 while(0)
1613
1614 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1615                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1616
1617 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1618                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1619
1620                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1621                                 {
1622                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1623                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1624                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1625                                         f = 1 - f;
1626                                 }
1627                                 else
1628                                 {
1629                                         f = 1;
1630                                 }
1631                                 wcross_name_alpha_goal_prev = f;
1632
1633                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1634                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1635
1636                                 if(autocvar_crosshair_dot)
1637                                 {
1638                                         vector wcross_color_old;
1639                                         wcross_color_old = wcross_color;
1640
1641                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1642                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1643
1644                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1645                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1646                                         wcross_color = wcross_color_old;
1647                                 }
1648                         }
1649                 }
1650                 else
1651                 {
1652                         wcross_scale_prev = 0;
1653                         wcross_alpha_prev = 0;
1654                         wcross_scale_goal_prev = 0;
1655                         wcross_alpha_goal_prev = 0;
1656                         wcross_changedonetime = 0;
1657                         if(wcross_name_goal_prev)
1658                                 strunzone(wcross_name_goal_prev);
1659                         wcross_name_goal_prev = string_null;
1660                         if(wcross_name_goal_prev_prev)
1661                                 strunzone(wcross_name_goal_prev_prev);
1662                         wcross_name_goal_prev_prev = string_null;
1663                         wcross_name_changestarttime = 0;
1664                         wcross_name_changedonetime = 0;
1665                         wcross_name_alpha_goal_prev = 0;
1666                         wcross_name_alpha_goal_prev_prev = 0;
1667                         wcross_resolution_goal_prev = 0;
1668                         wcross_resolution_goal_prev_prev = 0;
1669                 }
1670         }
1671
1672         if(NextFrameCommand)
1673         {
1674                 localcmd("\n", NextFrameCommand, "\n");
1675                 NextFrameCommand = string_null;
1676         }
1677
1678         // we must do this check AFTER a frame was rendered, or it won't work
1679         if(cs_project_is_b0rked == 0)
1680         {
1681                 string w0, h0;
1682                 w0 = ftos(autocvar_vid_conwidth);
1683                 h0 = ftos(autocvar_vid_conheight);
1684                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1685                 //setproperty(VF_FOV, '90 90 0');
1686                 setproperty(VF_ORIGIN, '0 0 0');
1687                 setproperty(VF_ANGLES, '0 0 0');
1688                 setproperty(VF_PERSPECTIVE, 1);
1689                 makevectors('0 0 0');
1690                 vector v1, v2;
1691                 cvar_set("vid_conwidth", "800");
1692                 cvar_set("vid_conheight", "600");
1693                 v1 = cs_project(v_forward);
1694                 cvar_set("vid_conwidth", "640");
1695                 cvar_set("vid_conheight", "480");
1696                 v2 = cs_project(v_forward);
1697                 if(v1 == v2)
1698                         cs_project_is_b0rked = 1;
1699                 else
1700                         cs_project_is_b0rked = -1;
1701                 cvar_set("vid_conwidth", w0);
1702                 cvar_set("vid_conheight", h0);
1703         }
1704
1705         if(autocvar__hud_configure)
1706                 HUD_Panel_Mouse();
1707
1708     if(hud && !intermission)
1709     {
1710         if(hud == HUD_SPIDERBOT)
1711             CSQC_SPIDER_HUD();
1712         else if(hud == HUD_WAKIZASHI)
1713             CSQC_WAKIZASHI_HUD();
1714         else if(hud == HUD_RAPTOR)
1715             CSQC_RAPTOR_HUD();
1716         else if(hud == HUD_BUMBLEBEE)
1717             CSQC_BUMBLE_HUD();
1718         else if(hud == HUD_BUMBLEBEE_GUN)
1719             CSQC_BUMBLE_GUN_HUD();
1720     }
1721
1722         cl_notice_run();
1723
1724         // let's reset the view back to normal for the end
1725         setproperty(VF_MIN, '0 0 0');
1726         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1727 }
1728
1729
1730 void CSQC_common_hud(void)
1731 {
1732         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1733                 Accuracy_LoadLevels();
1734
1735         HUD_Main(); // always run these functions for alpha checks
1736         HUD_DrawScoreboard();
1737
1738         if (scoreboard_active) // scoreboard/accuracy
1739                 HUD_Reset();
1740         else if (intermission == 2) // map voting screen
1741         {
1742                 MapVote_Draw();
1743                 HUD_Reset();
1744         }
1745 }
1746
1747
1748 // following vectors must be global to allow seamless switching between camera modes
1749 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1750 void CSQC_Demo_Camera()
1751 {
1752         float speed, attenuation, dimensions;
1753         vector tmp, delta;
1754
1755         if( autocvar_camera_reset || !camera_mode )
1756         {
1757                 camera_offset = '0 0 0';
1758                 current_angles = '0 0 0';
1759                 camera_direction = '0 0 0';
1760                 camera_offset_z += 30;
1761                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1762                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1763                 current_origin = view_origin;
1764                 current_camera_offset  = camera_offset;
1765                 cvar_set("camera_reset", "0");
1766                 camera_mode = CAMERA_CHASE;
1767         }
1768
1769         // Camera angles
1770         if( camera_roll )
1771                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1772
1773         if(autocvar_camera_look_player)
1774         {
1775                 vector dir;
1776                 float n;
1777
1778                 dir = normalize(view_origin - current_position);
1779                 n = mouse_angles_z;
1780                 mouse_angles = vectoangles(dir);
1781                 mouse_angles_x = mouse_angles_x * -1;
1782                 mouse_angles_z = n;
1783         }
1784         else
1785         {
1786                 tmp = getmousepos() * 0.1;
1787                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1788                 {
1789                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1790                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1791                 }
1792         }
1793
1794         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1795         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1796         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1797         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1798
1799         // Fix difference when angles don't have the same sign
1800         delta = '0 0 0';
1801         if(mouse_angles_y < -60 && current_angles_y > 60)
1802                 delta = '0 360 0';
1803         if(mouse_angles_y > 60 && current_angles_y < -60)
1804                 delta = '0 -360 0';
1805
1806         if(autocvar_camera_look_player)
1807                 attenuation = autocvar_camera_look_attenuation;
1808         else
1809                 attenuation = autocvar_camera_speed_attenuation;
1810
1811         attenuation = 1 / max(1, attenuation);
1812         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1813
1814         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1815         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1816         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1817         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1818
1819         // Camera position
1820         tmp = '0 0 0';
1821         dimensions = 0;
1822
1823         if( camera_direction_x )
1824         {
1825                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1826                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1827                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1828                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1829                 ++dimensions;
1830         }
1831
1832         if( camera_direction_y )
1833         {
1834                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1835                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1836                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1837                 ++dimensions;
1838         }
1839
1840         if( camera_direction_z )
1841         {
1842                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1843                 ++dimensions;
1844         }
1845
1846         if(autocvar_camera_free)
1847                 speed = autocvar_camera_speed_free;
1848         else
1849                 speed = autocvar_camera_speed_chase;
1850
1851         if(dimensions)
1852         {
1853                 speed = speed * sqrt(1 / dimensions);
1854                 camera_offset += tmp * speed;
1855         }
1856
1857         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1858
1859         // Camera modes
1860         if( autocvar_camera_free )
1861         {
1862                 if ( camera_mode == CAMERA_CHASE )
1863                 {
1864                         current_camera_offset = current_origin + current_camera_offset;
1865                         camera_offset = current_origin + camera_offset;
1866                 }
1867
1868                 camera_mode = CAMERA_FREE;
1869                 current_position = current_camera_offset;
1870         }
1871         else
1872         {
1873                 if ( camera_mode == CAMERA_FREE )
1874                 {
1875                         current_origin = view_origin;
1876                         camera_offset = camera_offset - current_origin;
1877                         current_camera_offset = current_camera_offset - current_origin;
1878                 }
1879
1880                 camera_mode = CAMERA_CHASE;
1881
1882                 if(autocvar_camera_chase_smoothly)
1883                         current_origin += (view_origin - current_origin) * attenuation;
1884                 else
1885                         current_origin = view_origin;
1886
1887                 current_position = current_origin + current_camera_offset;
1888         }
1889
1890         setproperty(VF_ANGLES, current_angles);
1891         setproperty(VF_ORIGIN, current_position);
1892 }