qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 void Porto_Init()
  82 {
  83         porto = spawn();
  84         porto.classname = "porto";
  85         porto.draw = Porto_Draw;
  86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  87 }
  88
  89 float drawtime;
  90 float avgspeed;
  91 vector GetCurrentFov(float fov)
  92 {
  93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  94         float velocityzoom, curspeed;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102                 if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir)
 122                 zoomin_effect = 0;
 123
 124         if(zoomin_effect || camera_active)
 125         {
 126                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 127         }
 128         else
 129         {
 130                 if(zoomspeed < 0) // instant zoom
 131                 {
 132                         if(zoomdir)
 133                                 current_viewzoom = 1 / zoomfactor;
 134                         else
 135                                 current_viewzoom = 1;
 136                 }
 137                 else
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 141                         else
 142                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 143                 }
 144         }
 145
 146         if(almost_equals(current_viewzoom, 1))
 147                 current_zoomfraction = 0;
 148         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 149                 current_zoomfraction = 1;
 150         else
 151                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 152
 153         if(zoomsensitivity < 1)
 154                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 155         else
 156                 setsensitivityscale(1);
 157
 158         makevectors(view_angles);
 159
 160         if(autocvar_cl_velocityzoom)
 161         {
 162                 switch(autocvar_cl_velocityzoom_type)
 163                 {
 164                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 165                         case 2: curspeed = (v_forward * pmove_vel); break;
 166                         case 1: default: curspeed = vlen(pmove_vel); break;
 167                 }
 168
 169                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 170                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 171                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 172
 173                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 174         }
 175         else
 176                 velocityzoom = 1;
 177
 178         float frustumx, frustumy, fovx, fovy;
 179         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 180         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 181         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 182         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 183
 184         return '1 0 0' * fovx + '0 1 0' * fovy;
 185 }
 186
 187 // this function must match W_SetupShot!
 188 float zoomscript_caught;
 189
 190 vector wcross_origin;
 191 float wcross_scale_prev, wcross_alpha_prev;
 192 vector wcross_color_prev;
 193 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 194 vector wcross_color_goal_prev;
 195 float wcross_changedonetime;
 196
 197 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 198 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 199 float wcross_name_changestarttime, wcross_name_changedonetime;
 200 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 201 entity trueaim;
 202 entity trueaim_rifle;
 203
 204 #define SHOTTYPE_HITTEAM 1
 205 #define SHOTTYPE_HITOBSTRUCTION 2
 206 #define SHOTTYPE_HITWORLD 3
 207 #define SHOTTYPE_HITENEMY 4
 208
 209 void TrueAim_Init()
 210 {
 211         trueaim = spawn();
 212         trueaim.classname = "trueaim";
 213         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 214         trueaim_rifle = spawn();
 215         trueaim_rifle.classname = "trueaim_rifle";
 216         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 217 }
 218
 219 float EnemyHitCheck()
 220 {
 221         float t;
 222         wcross_origin = project_3d_to_2d(trace_endpos);
 223         wcross_origin_z = 0;
 224         if(trace_networkentity < 1)
 225                 return SHOTTYPE_HITWORLD;
 226         if(trace_networkentity > maxclients)
 227                 return SHOTTYPE_HITWORLD;
 228         t = GetPlayerColor(trace_networkentity - 1);
 229         if(teamplay)
 230                 if(t == myteam)
 231                         return SHOTTYPE_HITTEAM;
 232         if(t == COLOR_SPECTATOR)
 233                 return SHOTTYPE_HITWORLD;
 234         return SHOTTYPE_HITENEMY;
 235 }
 236
 237 float TrueAimCheck()
 238 {
 239         float nudge = 1; // added to traceline target and subtracted from result
 240         vector vecs, trueaimpoint, w_shotorg;
 241         vector mi, ma, dv;
 242         float shottype;
 243         entity ta;
 244         float mv;
 245
 246         mi = ma = '0 0 0';
 247         ta = trueaim;
 248         mv = MOVE_NOMONSTERS;
 249
 250         switch(activeweapon)
 251         {
 252                 case WEP_TUBA: // no aim
 253                 case WEP_PORTO: // shoots from eye
 254                 case WEP_HOOK: // no trueaim
 255                 case WEP_GRENADE_LAUNCHER: // toss curve
 256                         return SHOTTYPE_HITWORLD;
 257                 case WEP_NEX:
 258                 case WEP_MINSTANEX:
 259                         mv = MOVE_NORMAL;
 260                         break;
 261                 case WEP_RIFLE:
 262                         ta = trueaim_rifle;
 263                         mv = MOVE_NORMAL;
 264                         if(zoomscript_caught)
 265                         {
 266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 267                                 return EnemyHitCheck();
 268                         }
 269                         break;
 270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 271                         mi = '-3 -3 -3';
 272                         ma = '3 3 3';
 273                         break;
 274                 case WEP_FIREBALL: // projectile has a size!
 275                         mi = '-16 -16 -16';
 276                         ma = '16 16 16';
 277                         break;
 278                 case WEP_SEEKER: // projectile has a size!
 279                         mi = '-2 -2 -2';
 280                         ma = '2 2 2';
 281                         break;
 282                 case WEP_ELECTRO: // projectile has a size!
 283                         mi = '0 0 -3';
 284                         ma = '0 0 -3';
 285                         break;
 286         }
 287
 288         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 289
 290         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 291         trueaimpoint = trace_endpos;
 292
 293         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 294                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 295
 296         if(vecs_x > 0)
 297                 vecs_y = -vecs_y;
 298         else
 299                 vecs = '0 0 0';
 300
 301         dv = view_right * vecs_y + view_up * vecs_z;
 302         w_shotorg = view_origin + dv;
 303
 304         // now move the vecs forward as much as requested if possible
 305         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 306         w_shotorg = trace_endpos - view_forward * nudge;
 307
 308         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 309         shottype = EnemyHitCheck();
 310         if(shottype != SHOTTYPE_HITWORLD)
 311                 return shottype;
 312
 313 #if 0
 314         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 315         // or rather, I know why, but see no fix
 316         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 317                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 318                 return SHOTTYPE_HITOBSTRUCTION;
 319 #endif
 320
 321         return SHOTTYPE_HITWORLD;
 322 }
 323
 324 void CSQC_common_hud(void);
 325
 326 void PostInit(void);
 327 void CSQC_Demo_Camera();
 328 float HUD_WouldDrawScoreboard();
 329 float camera_mode;
 330 float CAMERA_FREE = 1;
 331 float CAMERA_CHASE = 2;
 332 float reticle_type;
 333 string NextFrameCommand;
 334 void CSQC_SPIDER_HUD();
 335 void CSQC_RAPTOR_HUD();
 336
 337 vector freeze_org, freeze_ang;
 338 entity nightvision_noise, nightvision_noise2;
 339
 340 #define MAX_TIME_DIFF 5
 341 float pickup_crosshair_time, pickup_crosshair_size;
 342 float hit_time, typehit_time;
 343 float nextsound_hit_time, nextsound_typehit_time;
 344 float hitindication_crosshair_time, hitindication_crosshair_size;
 345 float use_nex_chargepool;
 346
 347 float myhealth, myhealth_prev;
 348 float myhealth_flash;
 349
 350 float old_blurradius, old_bluralpha;
 351 float old_sharpen_intensity;
 352
 353 vector myhealth_gentlergb;
 354
 355 float contentavgalpha, liquidalpha_prev;
 356 vector liquidcolor_prev;
 357
 358 float eventchase_current_distance;
 359
 360 vector damage_blurpostprocess, content_blurpostprocess;
 361
 362 float checkfail[16];
 363
 364 #define BUTTON_3 4
 365 #define BUTTON_4 8
 366 void CSQC_UpdateView(float w, float h)
 367 {
 368         entity e;
 369         float fov;
 370         float f, i, j;
 371         vector v;
 372         vector vf_size, vf_min;
 373         float a;
 374
 375         hud = getstati(STAT_HUD);
 376
 377         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 378                 view_quality = getproperty(VF_MINFPS_QUALITY);
 379         else
 380                 view_quality = 1;
 381
 382         button_attack2 = (input_buttons & BUTTON_3);
 383         button_zoom = (input_buttons & BUTTON_4);
 384
 385         // FIXME do we need this hack?
 386         if(isdemo())
 387         {
 388                 // in demos, input_buttons do not work
 389                 button_zoom = (autocvar__togglezoom == "-");
 390         }
 391
 392 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 393         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 394         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 395         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 396         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 397         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 398         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 399         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 400
 401         vf_size = getpropertyvec(VF_SIZE);
 402         vf_min = getpropertyvec(VF_MIN);
 403         vid_width = vf_size_x;
 404         vid_height = vf_size_y;
 405
 406         vector reticle_pos, reticle_size;
 407         vector splash_pos, splash_size;
 408
 409         WaypointSprite_Load();
 410
 411 #ifdef COMPAT_XON050_ENGINE
 412         if(spectatee_status)
 413                 myteam = GetPlayerColor(spectatee_status - 1);
 414         else
 415 #endif
 416                 myteam = GetPlayerColor(player_localentnum - 1);
 417
 418         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 419
 420         // event chase camera
 421         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 422         {
 423                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 424                 {
 425                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 426                         vector current_view_origin = getpropertyvec(VF_ORIGIN);
 427
 428                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 429                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 430                         if(!autocvar_chase_active)
 431                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 432
 433                         // make the camera smooth back
 434                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 435                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 436                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 437                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 438
 439                         vector eventchase_target_origin;
 440                         makevectors(view_angles);
 441                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 442                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 443                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 444                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 445                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 446                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 447                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 448
 449                         setproperty(VF_ORIGIN, trace_endpos);
 450                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 451                 }
 452                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 453                 {
 454                         cvar_set("chase_active", "0");
 455                         eventchase_current_distance = 0; // start from 0 next time
 456                 }
 457         }
 458
 459         // do lockview after event chase camera so that it still applies whenever necessary.
 460         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 461         {
 462                 setproperty(VF_ORIGIN, freeze_org);
 463                 setproperty(VF_ANGLES, freeze_ang);
 464         }
 465         else
 466         {
 467                 freeze_org = getpropertyvec(VF_ORIGIN);
 468                 freeze_ang = getpropertyvec(VF_ANGLES);
 469         }
 470
 471         WarpZone_FixView();
 472         //WarpZone_FixPMove();
 473
 474         // Render the Scene
 475         view_origin = getpropertyvec(VF_ORIGIN);
 476         view_angles = getpropertyvec(VF_ANGLES);
 477         makevectors(view_angles);
 478         view_forward = v_forward;
 479         view_right = v_right;
 480         view_up = v_up;
 481
 482 #ifdef BLURTEST
 483         if(time > blurtest_time0 && time < blurtest_time1)
 484         {
 485                 float r, t;
 486
 487                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 488                 r = t * blurtest_radius;
 489                 f = 1 / pow(t, blurtest_power) - 1;
 490
 491                 cvar_set("r_glsl_postprocess", "1");
 492                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 493         }
 494         else
 495         {
 496                 cvar_set("r_glsl_postprocess", "0");
 497                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 498         }
 499 #endif
 500
 501         TargetMusic_Advance();
 502         Fog_Force();
 503
 504         if(drawtime == 0)
 505                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 506         else
 507                 drawframetime = bound(0.000001, time - drawtime, 1);
 508         drawtime = time;
 509
 510         // watch for gametype changes here...
 511         // in ParseStuffCMD the cmd isn't executed yet :/
 512         // might even be better to add the gametype to TE_CSQC_INIT...?
 513         if(!postinit)
 514                 PostInit();
 515
 516         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 517         {
 518                 if(calledhooks & HOOK_START)
 519                 {
 520                         localcmd("\ncl_hook_gameend\n");
 521                         calledhooks |= HOOK_END;
 522                 }
 523         }
 524
 525   Announcer();
 526
 527         fov = autocvar_fov;
 528         if(fov <= 59.5)
 529         {
 530                 if(!zoomscript_caught)
 531                 {
 532                         localcmd("+button9\n");
 533                         zoomscript_caught = 1;
 534                 }
 535         }
 536         else
 537         {
 538                 if(zoomscript_caught)
 539                 {
 540                         localcmd("-button9\n");
 541                         zoomscript_caught = 0;
 542                 }
 543         }
 544
 545         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 546
 547         // next WANTED weapon (for HUD)
 548         switchweapon = getstati(STAT_SWITCHWEAPON);
 549
 550         // currently switching-to weapon (for crosshair)
 551         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 552
 553         // actually active weapon (for zoom)
 554         activeweapon = getstati(STAT_ACTIVEWEAPON);
 555
 556         f = (serverflags & SERVERFLAG_TEAMPLAY);
 557         if(f != teamplay)
 558         {
 559                 teamplay = f;
 560                 HUD_InitScores();
 561         }
 562
 563         if(last_switchweapon != switchweapon) {
 564                 weapontime = time;
 565                 last_switchweapon = switchweapon;
 566         }
 567         if(last_activeweapon != activeweapon) {
 568                 last_activeweapon = activeweapon;
 569
 570                 e = get_weaponinfo(activeweapon);
 571                 if(e.netname != "")
 572                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 573                 else
 574                         localcmd("\ncl_hook_activeweapon none\n");
 575         }
 576
 577         // ALWAYS Clear Current Scene First
 578         clearscene();
 579 #ifdef WORKAROUND_XON010
 580         if(checkextension("DP_CSQC_ROTATEMOVES"))
 581         {
 582 #endif
 583         setproperty(VF_ORIGIN, view_origin);
 584         setproperty(VF_ANGLES, view_angles);
 585 #ifdef WORKAROUND_XON010
 586         }
 587 #endif
 588
 589         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 590         setproperty(VF_SIZE, vf_size);
 591         setproperty(VF_MIN, vf_min);
 592
 593         // Assign Standard Viewflags
 594         // Draw the World (and sky)
 595         setproperty(VF_DRAWWORLD, 1);
 596
 597         // Set the console size vars
 598         vid_conwidth = autocvar_vid_conwidth;
 599         vid_conheight = autocvar_vid_conheight;
 600         vid_pixelheight = autocvar_vid_pixelheight;
 601
 602         setproperty(VF_FOV, GetCurrentFov(fov));
 603
 604         // Camera for demo playback
 605         if(camera_active)
 606         {
 607                 if(autocvar_camera_enable)
 608                         CSQC_Demo_Camera();
 609                 else
 610                 {
 611                         cvar_set("chase_active", ftos(chase_active_backup));
 612                         cvar_set("cl_demo_mousegrab", "0");
 613                         camera_active = FALSE;
 614                 }
 615         }
 616 #ifdef CAMERATEST
 617         else if(autocvar_camera_enable)
 618 #else
 619         else if(autocvar_camera_enable && isdemo())
 620 #endif
 621         {
 622                 // Enable required Darkplaces cvars
 623                 chase_active_backup = autocvar_chase_active;
 624                 cvar_set("chase_active", "2");
 625                 cvar_set("cl_demo_mousegrab", "1");
 626                 camera_active = TRUE;
 627                 camera_mode = FALSE;
 628         }
 629
 630         // Draw the Crosshair
 631         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 632
 633         // Draw the Engine Status Bar (the default Quake HUD)
 634         setproperty(VF_DRAWENGINESBAR, 0);
 635
 636         // Update the mouse position
 637         /*
 638            mousepos_x = vid_conwidth;
 639            mousepos_y = vid_conheight;
 640            mousepos = mousepos*0.5 + getmousepos();
 641          */
 642
 643         e = self;
 644         for(self = world; (self = nextent(self)); )
 645                 if(self.draw)
 646                         self.draw();
 647         self = e;
 648
 649         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 650         renderscene();
 651
 652         // now switch to 2D drawing mode by calling a 2D drawing function
 653         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 654         // next R_RenderScene call
 655         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 656
 657         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 658         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 659         {
 660                 // apply night vision effect
 661                 vector tc_00, tc_01, tc_10, tc_11;
 662                 vector rgb;
 663                 rgb_x = 0; // fteqcc sucks
 664                 rgb_y = 0; // fteqcc sucks
 665                 rgb_z = 0; // fteqcc sucks
 666
 667                 if(!nightvision_noise)
 668                 {
 669                         nightvision_noise = spawn();
 670                         nightvision_noise.classname = "nightvision_noise";
 671                 }
 672                 if(!nightvision_noise2)
 673                 {
 674                         nightvision_noise2 = spawn();
 675                         nightvision_noise2.classname = "nightvision_noise2";
 676                 }
 677
 678                 // color tint in yellow
 679                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 680
 681                 // draw BG
 682                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 683                 rgb = '1 1 1';
 684                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 685                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 686                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 687                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 688                 tc_11 = tc_01 + tc_10 - tc_00;
 689                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 690                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 691                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 692                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 693                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 694                 R_EndPolygon();
 695
 696                 // draw FG
 697                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 698                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 699                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 700                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 701                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 702                 tc_11 = tc_01 + tc_10 - tc_00;
 703                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 704                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 705                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 706                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 707                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 708                 R_EndPolygon();
 709         }
 710
 711         // Draw the aiming reticle for weapons that use it
 712         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 713         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 714         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 715         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 716                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 717         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 718                 reticle_type = 2; // nex zoom
 719         else if(button_zoom || zoomscript_caught)
 720                 reticle_type = 1; // normal zoom
 721         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 722                 reticle_type = 2; // nex zoom
 723
 724         if(reticle_type && autocvar_cl_reticle)
 725         {
 726                 if(autocvar_cl_reticle_stretch)
 727                 {
 728                         reticle_size_x = vid_conwidth;
 729                         reticle_size_y = vid_conheight;
 730                         reticle_pos_x = 0;
 731                         reticle_pos_y = 0;
 732                 }
 733                 else
 734                 {
 735                         reticle_size_x = max(vid_conwidth, vid_conheight);
 736                         reticle_size_y = max(vid_conwidth, vid_conheight);
 737                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 738                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 739                 }
 740
 741                 f = current_zoomfraction;
 742                 if(zoomscript_caught)
 743                         f = 1;
 744                 if(autocvar_cl_reticle_item_normal)
 745                 {
 746                         if(reticle_type == 1 && f)
 747                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 748                 }
 749                 if(autocvar_cl_reticle_item_nex)
 750                 {
 751                         if(reticle_type == 2 && f)
 752                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 753                 }
 754         }
 755
 756
 757         // improved polyblend
 758         vector rgb;
 759         if(autocvar_hud_contents)
 760         {
 761                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 762                 vector liquidcolor;
 763
 764                 switch(pointcontents(view_origin))
 765                 {
 766                         case CONTENT_WATER:
 767                                 liquidalpha = autocvar_hud_contents_water_alpha;
 768                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 769                                 incontent = 1;
 770                                 break;
 771
 772                         case CONTENT_LAVA:
 773                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 774                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 775                                 incontent = 1;
 776                                 break;
 777
 778                         case CONTENT_SLIME:
 779                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 780                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 781                                 incontent = 1;
 782                                 break;
 783
 784                         default:
 785                                 liquidalpha = 0;
 786                                 liquidcolor = '0 0 0';
 787                                 incontent = 0;
 788                                 break;
 789                 }
 790
 791                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 792                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 793                         contentfadetime = autocvar_hud_contents_fadeintime;
 794                         liquidalpha_prev = liquidalpha;
 795                         liquidcolor_prev = liquidcolor;
 796                 }
 797                 else
 798                         contentfadetime = autocvar_hud_contents_fadeouttime;
 799
 800                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 801                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 802
 803                 if(contentavgalpha)
 804                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 805
 806                 if(autocvar_hud_postprocessing)
 807                 {
 808                         if(autocvar_hud_contents_blur && contentavgalpha)
 809                         {
 810                                 content_blurpostprocess_x = 1;
 811                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 812                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 813                         }
 814                         else
 815                         {
 816                                 content_blurpostprocess_x = 0;
 817                                 content_blurpostprocess_y = 0;
 818                                 content_blurpostprocess_z = 0;
 819                         }
 820                 }
 821         }
 822
 823         if(autocvar_hud_damage)
 824         {
 825                 splash_size_x = max(vid_conwidth, vid_conheight);
 826                 splash_size_y = max(vid_conwidth, vid_conheight);
 827                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 828                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 829
 830                 float myhealth_flash_temp;
 831                 myhealth = getstati(STAT_HEALTH);
 832
 833                 // fade out
 834                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 835                 // add new damage
 836                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 837
 838                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 839                 pain_threshold = autocvar_hud_damage_pain_threshold;
 840                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 841                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 842
 843                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 844                 {
 845                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 846                 }
 847
 848                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 849
 850                 if(myhealth_prev < 1)
 851                 {
 852                         if(myhealth >= 1)
 853                         {
 854                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 855                                 myhealth_flash_temp = 0;
 856                         }
 857                         else
 858                         {
 859                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 860                         }
 861                 }
 862
 863                 if(spectatee_status == -1 || intermission)
 864                 {
 865                         myhealth_flash = 0; // observing, or match ended
 866                         myhealth_flash_temp = 0;
 867                 }
 868
 869                 myhealth_prev = myhealth;
 870
 871                 // IDEA: change damage color/picture based on player model for robot/alien species?
 872                 // pro: matches model better
 873                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 874                 // maybe different reddish pics?
 875                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 876                 {
 877                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 878                         {
 879                                 if(autocvar_cl_gentle_damage == 2)
 880                                 {
 881                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 882                                         {
 883                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 884                                         }
 885                                 }
 886                                 else
 887                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 888
 889                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 890                         }
 891                         else
 892                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 893                 }
 894
 895                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 896                 {
 897                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 898                         {
 899                                 damage_blurpostprocess_x = 1;
 900                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 901                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 902                         }
 903                         else
 904                         {
 905                                 damage_blurpostprocess_x = 0;
 906                                 damage_blurpostprocess_y = 0;
 907                                 damage_blurpostprocess_z = 0;
 908                         }
 909                 }
 910         }
 911
 912         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 913         {
 914                 // enable or disable rendering types if they are used or not
 915                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 916                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 917
 918                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 919                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 920                 {
 921                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 922                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 923                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 924                         {
 925                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 926                                 old_blurradius = blurradius;
 927                                 old_bluralpha = bluralpha;
 928                         }
 929                 }
 930                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 931                 {
 932                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 933                         old_blurradius = 0;
 934                         old_bluralpha = 0;
 935                 }
 936
 937                 // edge detection postprocess handling done second (used by hud_powerup)
 938                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 939                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 940                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 941
 942                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 943
 944                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 945                 {
 946                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 947                         {
 948                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 949                                 old_sharpen_intensity = sharpen_intensity;
 950                         }
 951                 }
 952                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 953                 {
 954                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 955                         old_sharpen_intensity = 0;
 956                 }
 957         }
 958
 959         if(menu_visible)
 960                 menu_show();
 961
 962         /*if(gametype == GAME_CTF)
 963           {
 964           ctf_view();
 965           } else */
 966
 967         // draw 2D entities
 968         e = self;
 969         for(self = world; (self = nextent(self)); )
 970                 if(self.draw2d)
 971                         self.draw2d();
 972         self = e;
 973         Draw_ShowNames_All();
 974
 975         scoreboard_active = HUD_WouldDrawScoreboard();
 976
 977         hit_time = getstatf(STAT_HIT_TIME);
 978         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 979         {
 980                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 981                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 982
 983                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 984         }
 985         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 986         if(typehit_time > nextsound_typehit_time)
 987         {
 988                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 989                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 990
 991                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 992         }
 993
 994         //else
 995         {
 996                 if(gametype == GAME_FREEZETAG)
 997                 {
 998                         if(getstati(STAT_FROZEN))
 999                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1000                         if(getstatf(STAT_REVIVE_PROGRESS))
1001                         {
1002                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1003                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1004                         }
1005                 }
1006
1007                 if(autocvar_r_letterbox == 0)
1008                         if(autocvar_viewsize < 120)
1009                                 CSQC_common_hud();
1010
1011                 // crosshair goes VERY LAST
1012                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
1013                         string wcross_style;
1014                         float wcross_alpha, wcross_resolution;
1015                         wcross_style = autocvar_crosshair;
1016                         if (wcross_style == "0")
1017                                 return;
1018                         wcross_resolution = autocvar_crosshair_size;
1019                         if (wcross_resolution == 0)
1020                                 return;
1021                         wcross_alpha = autocvar_crosshair_alpha;
1022                         if (wcross_alpha == 0)
1023                                 return;
1024
1025                         // TrueAim check
1026                         float shottype;
1027
1028                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1029                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1030                         wcross_origin_z = 0;
1031                         if(autocvar_crosshair_hittest)
1032                         {
1033                                 vector wcross_oldorigin;
1034                                 wcross_oldorigin = wcross_origin;
1035                                 shottype = TrueAimCheck();
1036                                 if(shottype == SHOTTYPE_HITWORLD)
1037                                 {
1038                                         v = wcross_origin - wcross_oldorigin;
1039                                         v_x /= vid_conwidth;
1040                                         v_y /= vid_conheight;
1041                                         if(vlen(v) > 0.01)
1042                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1043                                 }
1044                                 if(!autocvar_crosshair_hittest_showimpact)
1045                                         wcross_origin = wcross_oldorigin;
1046                         }
1047                         else
1048                                 shottype = SHOTTYPE_HITWORLD;
1049
1050                         vector wcross_color, wcross_size;
1051                         string wcross_wep, wcross_name;
1052                         float wcross_scale, wcross_blur;
1053
1054                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1055                                 e = get_weaponinfo(switchingweapon);
1056                                 if (e && e.netname != "")
1057                                 {
1058                                         wcross_wep = e.netname;
1059                                         if(autocvar_crosshair_per_weapon)
1060                                         {
1061                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1062                                                 if (wcross_resolution == 0)
1063                                                         return;
1064                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1065                                                 if (wcross_alpha == 0)
1066                                                         return;
1067
1068                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1069                                                 if(wcross_style == "" || wcross_style == "0")
1070                                                         wcross_style = wcross_wep;
1071                                         }
1072                                 }
1073                         }
1074                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1075                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1076                         else if(autocvar_crosshair_color_by_health)
1077                         {
1078                                 float x = getstati(STAT_HEALTH);
1079
1080                                 //x = red
1081                                 //y = green
1082                                 //z = blue
1083
1084                                 wcross_color_z = 0;
1085
1086                                 if(x > 200)
1087                                 {
1088                                         wcross_color_x = 0;
1089                                         wcross_color_y = 1;
1090                                 }
1091                                 else if(x > 150)
1092                                 {
1093                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1094                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1095                                 }
1096                                 else if(x > 100)
1097                                 {
1098                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1099                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1100                                         wcross_color_z = 1 - (x-100)*0.02;
1101                                 }
1102                                 else if(x > 50)
1103                                 {
1104                                         wcross_color_x = 1;
1105                                         wcross_color_y = 1;
1106                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1107                                 }
1108                                 else if(x > 20)
1109                                 {
1110                                         wcross_color_x = 1;
1111                                         wcross_color_y = (x-20)*90/27/100;
1112                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1113                                 }
1114                                 else
1115                                 {
1116                                         wcross_color_x = 1;
1117                                         wcross_color_y = 0;
1118                                 }
1119                         }
1120                         else
1121                                 wcross_color = stov(autocvar_crosshair_color);
1122
1123                         wcross_name = strcat("gfx/crosshair", wcross_style);
1124
1125                         if(autocvar_crosshair_effect_scalefade)
1126                         {
1127                                 wcross_scale = wcross_resolution;
1128                                 wcross_resolution = 1;
1129                         }
1130                         else
1131                         {
1132                                 wcross_scale = 1;
1133                         }
1134
1135                         if(autocvar_crosshair_pickup)
1136                         {
1137                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1138
1139                                 if(pickup_crosshair_time < stat_pickup_time)
1140                                 {
1141                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1142                                                 pickup_crosshair_size = 1;
1143
1144                                         pickup_crosshair_time = stat_pickup_time;
1145                                 }
1146
1147                                 if(pickup_crosshair_size > 0)
1148                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1149                                 else
1150                                         pickup_crosshair_size = 0;
1151
1152                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1153                         }
1154
1155                         if(autocvar_crosshair_hitindication)
1156                         {
1157                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1158                                 if(hitindication_crosshair_time < hit_time)
1159                                 {
1160                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1161                                                 hitindication_crosshair_size = 1;
1162
1163                                         hitindication_crosshair_time = hit_time;
1164                                 }
1165
1166                                 if(hitindication_crosshair_size > 0)
1167                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1168                                 else
1169                                         hitindication_crosshair_size = 0;
1170
1171                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1172                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1173                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1174                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1175                         }
1176
1177                         if(shottype == SHOTTYPE_HITENEMY)
1178                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1179                         if(shottype == SHOTTYPE_HITTEAM)
1180                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1181
1182                         f = autocvar_crosshair_effect_speed;
1183                         if(f < 0)
1184                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1185                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1186                         {
1187                                 wcross_changedonetime = time + f;
1188                         }
1189                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1190                         {
1191                                 wcross_name_changestarttime = time;
1192                                 wcross_name_changedonetime = time + f;
1193                                 if(wcross_name_goal_prev_prev)
1194                                         strunzone(wcross_name_goal_prev_prev);
1195                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1196                                 wcross_name_goal_prev = strzone(wcross_name);
1197                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1198                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1199                                 wcross_resolution_goal_prev = wcross_resolution;
1200                         }
1201
1202                         wcross_scale_goal_prev = wcross_scale;
1203                         wcross_alpha_goal_prev = wcross_alpha;
1204                         wcross_color_goal_prev = wcross_color;
1205
1206                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1207                         {
1208                                 wcross_blur = 1;
1209                                 wcross_alpha *= 0.75;
1210                         }
1211                         else
1212                                 wcross_blur = 0;
1213                         // *_prev is at time-frametime
1214                         // * is at wcross_changedonetime+f
1215                         // what do we have at time?
1216                         if(time < wcross_changedonetime)
1217                         {
1218                                 f = frametime / (wcross_changedonetime - time + frametime);
1219                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1220                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1221                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1222                         }
1223
1224                         wcross_scale_prev = wcross_scale;
1225                         wcross_alpha_prev = wcross_alpha;
1226                         wcross_color_prev = wcross_color;
1227
1228                         wcross_scale *= 1 - autocvar__menu_alpha;
1229                         wcross_alpha *= 1 - autocvar__menu_alpha;
1230                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1231
1232                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1233                         {
1234                                 // crosshair rings for weapon stats
1235                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1236                                 {
1237                                         // declarations and stats
1238                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1239                                         string ring_image, ring_inner_image;
1240                                         vector ring_rgb, ring_inner_rgb;
1241
1242                                         ring_scale = autocvar_crosshair_ring_size;
1243
1244                                         float weapon_clipload, weapon_clipsize;
1245                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1246                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1247
1248                                         float nex_charge, nex_chargepool;
1249                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1250                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1251
1252                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1253                                                 nex_charge_movingavg = nex_charge;
1254
1255
1256                                         // handle the values
1257                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1258                                         {
1259                                                 if (nex_chargepool || use_nex_chargepool) {
1260                                                         use_nex_chargepool = 1;
1261                                                         ring_inner_value = nex_chargepool;
1262                                                 } else {
1263                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1264                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1265                                                 }
1266
1267                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1268                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1269                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1270
1271                                                 // draw the outer ring to show the current charge of the weapon
1272                                                 ring_value = nex_charge;
1273                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1274                                                 ring_rgb = wcross_color;
1275                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1276                                         }
1277                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1278                                         {
1279                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1280                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1281                                                 ring_rgb = wcross_color;
1282                                                 ring_image = "gfx/crosshair_ring.tga";
1283                                         }
1284                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1285                                         {
1286                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1287                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1288                                                 ring_rgb = wcross_color;
1289                                                 ring_image = "gfx/crosshair_ring.tga";
1290                                         }
1291
1292                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1293                                         {
1294                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1295                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1296                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1297                                                 ring_rgb = wcross_color;
1298
1299                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1300                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1301                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1302                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1303                                                 else
1304                                                         ring_image = "gfx/crosshair_ring.tga";
1305                                         }
1306
1307                                         // if in weapon switch animation, fade ring out/in
1308                                         if(g_weaponswitchdelay > 0)
1309                                         {
1310                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1311                                                 if(f > 0 && f < 2)
1312                                                         ring_alpha *= fabs(1 - f);
1313                                         }
1314
1315                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1316                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1317
1318                                         if (ring_value)
1319                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1320                                 }
1321
1322 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1323                                 do \
1324                                 { \
1325                                         if(wcross_blur > 0) \
1326                                         { \
1327                                                 for(i = -2; i <= 2; ++i) \
1328                                                 for(j = -2; j <= 2; ++j) \
1329                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1330                                         } \
1331                                         else \
1332                                         { \
1333                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1334                                         } \
1335                                 } \
1336                                 while(0)
1337
1338 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1339                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1340
1341 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1342                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1343
1344                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1345                                 {
1346                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1347                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1348                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1349                                         f = 1 - f;
1350                                 }
1351                                 else
1352                                 {
1353                                         f = 1;
1354                                 }
1355                                 wcross_name_alpha_goal_prev = f;
1356
1357                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1358                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1359
1360                                 if(autocvar_crosshair_dot)
1361                                 {
1362                                         vector wcross_color_old;
1363                                         wcross_color_old = wcross_color;
1364                                         if(autocvar_crosshair_dot_color != "0")
1365                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1366                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1367                                         // FIXME why don't we use wcross_alpha here?
1368                                         wcross_color = wcross_color_old;
1369                                 }
1370                         }
1371                 }
1372                 else
1373                 {
1374                         wcross_scale_prev = 0;
1375                         wcross_alpha_prev = 0;
1376                         wcross_scale_goal_prev = 0;
1377                         wcross_alpha_goal_prev = 0;
1378                         wcross_changedonetime = 0;
1379                         if(wcross_name_goal_prev)
1380                                 strunzone(wcross_name_goal_prev);
1381                         wcross_name_goal_prev = string_null;
1382                         if(wcross_name_goal_prev_prev)
1383                                 strunzone(wcross_name_goal_prev_prev);
1384                         wcross_name_goal_prev_prev = string_null;
1385                         wcross_name_changestarttime = 0;
1386                         wcross_name_changedonetime = 0;
1387                         wcross_name_alpha_goal_prev = 0;
1388                         wcross_name_alpha_goal_prev_prev = 0;
1389                         wcross_resolution_goal_prev = 0;
1390                         wcross_resolution_goal_prev_prev = 0;
1391                 }
1392         }
1393
1394         if(NextFrameCommand)
1395         {
1396                 localcmd("\n", NextFrameCommand, "\n");
1397                 NextFrameCommand = string_null;
1398         }
1399
1400         // we must do this check AFTER a frame was rendered, or it won't work
1401         if(cs_project_is_b0rked == 0)
1402         {
1403                 string w0, h0;
1404                 w0 = ftos(autocvar_vid_conwidth);
1405                 h0 = ftos(autocvar_vid_conheight);
1406                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1407                 //setproperty(VF_FOV, '90 90 0');
1408                 setproperty(VF_ORIGIN, '0 0 0');
1409                 setproperty(VF_ANGLES, '0 0 0');
1410                 setproperty(VF_PERSPECTIVE, 1);
1411                 makevectors('0 0 0');
1412                 vector v1, v2;
1413                 cvar_set("vid_conwidth", "800");
1414                 cvar_set("vid_conheight", "600");
1415                 v1 = cs_project(v_forward);
1416                 cvar_set("vid_conwidth", "640");
1417                 cvar_set("vid_conheight", "480");
1418                 v2 = cs_project(v_forward);
1419                 if(v1 == v2)
1420                         cs_project_is_b0rked = 1;
1421                 else
1422                         cs_project_is_b0rked = -1;
1423                 cvar_set("vid_conwidth", w0);
1424                 cvar_set("vid_conheight", h0);
1425         }
1426
1427         if(autocvar__hud_configure)
1428                 HUD_Panel_Mouse();
1429
1430     if(hud && !intermission)
1431     {
1432         if(hud == HUD_SPIDERBOT)
1433             CSQC_SPIDER_HUD();
1434         else if(hud == HUD_WAKIZASHI)
1435             CSQC_WAKIZASHI_HUD();
1436         else if(hud == HUD_RAPTOR)
1437             CSQC_RAPTOR_HUD();
1438         else if(hud == HUD_BUMBLEBEE)
1439             CSQC_BUMBLE_HUD();
1440     }
1441         // let's reset the view back to normal for the end
1442         setproperty(VF_MIN, '0 0 0');
1443         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1444 }
1445
1446
1447 void CSQC_common_hud(void)
1448 {
1449     // do some accuracy var caching
1450     float i;
1451     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1452     {
1453         if(autocvar_accuracy_color_levels != acc_color_levels)
1454         {
1455             if(acc_color_levels)
1456                 strunzone(acc_color_levels);
1457             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1458             acc_levels = tokenize_console(acc_color_levels);
1459             if (acc_levels > MAX_ACCURACY_LEVELS)
1460                 acc_levels = MAX_ACCURACY_LEVELS;
1461
1462             for (i = 0; i < acc_levels; ++i)
1463                 acc_lev[i] = stof(argv(i)) / 100.0;
1464         }
1465         // let know that acc_col[] needs to be loaded
1466         acc_col_x[0] = -1;
1467     }
1468
1469     HUD_Main(); // always run these functions for alpha checks
1470     HUD_DrawScoreboard();
1471
1472     if (scoreboard_active) // scoreboard/accuracy
1473         HUD_Reset();
1474     else if (intermission == 2) // map voting screen
1475     {
1476         HUD_FinaleOverlay();
1477         HUD_Reset();
1478     }
1479         /*
1480         switch(hud)
1481         {
1482                 case HUD_SPIDERBOT:
1483                         CSQC_SPIDER_HUD();
1484                         break;
1485
1486                 case HUD_WAKIZASHI:
1487                         CSQC_WAKIZASHI_HUD();
1488                         break;
1489
1490         case HUD_BUMBLEBEE:
1491             CSQC_BUMBLE_HUD();
1492             break;
1493         }
1494         */
1495 }
1496
1497
1498 // following vectors must be global to allow seamless switching between camera modes
1499 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1500 void CSQC_Demo_Camera()
1501 {
1502         float speed, attenuation, dimensions;
1503         vector tmp, delta;
1504
1505         if( autocvar_camera_reset || !camera_mode )
1506         {
1507                 camera_offset = '0 0 0';
1508                 current_angles = '0 0 0';
1509                 camera_direction = '0 0 0';
1510                 camera_offset_z += 30;
1511                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1512                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1513                 current_origin = view_origin;
1514                 current_camera_offset  = camera_offset;
1515                 cvar_set("camera_reset", "0");
1516                 camera_mode = CAMERA_CHASE;
1517         }
1518
1519         // Camera angles
1520         if( camera_roll )
1521                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1522
1523         if(autocvar_camera_look_player)
1524         {
1525                 vector dir;
1526                 float n;
1527
1528                 dir = normalize(view_origin - current_position);
1529                 n = mouse_angles_z;
1530                 mouse_angles = vectoangles(dir);
1531                 mouse_angles_x = mouse_angles_x * -1;
1532                 mouse_angles_z = n;
1533         }
1534         else
1535         {
1536                 tmp = getmousepos() * 0.1;
1537                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1538                 {
1539                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1540                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1541                 }
1542         }
1543
1544         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1545         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1546         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1547         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1548
1549         // Fix difference when angles don't have the same sign
1550         delta = '0 0 0';
1551         if(mouse_angles_y < -60 && current_angles_y > 60)
1552                 delta = '0 360 0';
1553         if(mouse_angles_y > 60 && current_angles_y < -60)
1554                 delta = '0 -360 0';
1555
1556         if(autocvar_camera_look_player)
1557                 attenuation = autocvar_camera_look_attenuation;
1558         else
1559                 attenuation = autocvar_camera_speed_attenuation;
1560
1561         attenuation = 1 / max(1, attenuation);
1562         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1563
1564         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1565         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1566         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1567         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1568
1569         // Camera position
1570         tmp = '0 0 0';
1571         dimensions = 0;
1572
1573         if( camera_direction_x )
1574         {
1575                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1576                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1577                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1578                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1579                 ++dimensions;
1580         }
1581
1582         if( camera_direction_y )
1583         {
1584                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1585                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1586                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1587                 ++dimensions;
1588         }
1589
1590         if( camera_direction_z )
1591         {
1592                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1593                 ++dimensions;
1594         }
1595
1596         if(autocvar_camera_free)
1597                 speed = autocvar_camera_speed_free;
1598         else
1599                 speed = autocvar_camera_speed_chase;
1600
1601         if(dimensions)
1602         {
1603                 speed = speed * sqrt(1 / dimensions);
1604                 camera_offset += tmp * speed;
1605         }
1606
1607         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1608
1609         // Camera modes
1610         if( autocvar_camera_free )
1611         {
1612                 if ( camera_mode == CAMERA_CHASE )
1613                 {
1614                         current_camera_offset = current_origin + current_camera_offset;
1615                         camera_offset = current_origin + camera_offset;
1616                 }
1617
1618                 camera_mode = CAMERA_FREE;
1619                 current_position = current_camera_offset;
1620         }
1621         else
1622         {
1623                 if ( camera_mode == CAMERA_FREE )
1624                 {
1625                         current_origin = view_origin;
1626                         camera_offset = camera_offset - current_origin;
1627                         current_camera_offset = current_camera_offset - current_origin;
1628                 }
1629
1630                 camera_mode = CAMERA_CHASE;
1631
1632                 if(autocvar_camera_chase_smoothly)
1633                         current_origin += (view_origin - current_origin) * attenuation;
1634                 else
1635                         current_origin = view_origin;
1636
1637                 current_position = current_origin + current_camera_offset;
1638         }
1639
1640         setproperty(VF_ANGLES, current_angles);
1641         setproperty(VF_ORIGIN, current_position);
1642 }