qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float trace_dphitcontents;
   4 float trace_networkentity;
   5 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   6 float DPCONTENTS_SOLID = 1; // blocks player movement
   7 float DPCONTENTS_BODY = 32; // blocks player movement
   8 float DPCONTENTS_CORPSE = 64; // blocks player movement
   9 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  10 void Porto_Draw()
  11 {
  12         vector p, dir, ang, q, nextdir;
  13         float idx, portal_number, portal1_idx;
  14
  15         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                         portal1_idx = idx;
  61                 if(portal_number >= 2)
  62                         break;
  63         }
  64
  65         while(idx >= 2)
  66         {
  67                 p = polyline[idx-2];
  68                 q = polyline[idx-1];
  69                 if(idx == 2)
  70                         p = p - view_up * 16;
  71                 if(idx-1 >= portal1_idx)
  72                 {
  73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  74                 }
  75                 else
  76                 {
  77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  78                 }
  79                 --idx;
  80         }
  81 }
  82
  83 /**
  84  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  85  *
  86  * TODO: Use a better solution where a common shared entitiy is used that contains
  87  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  88  * and STAT_FRAGLIMIT to be auto-sent)
  89  */
  90 void CheckForGamestartChange() {
  91         float startTime;
  92         startTime = getstatf(STAT_GAMESTARTTIME);
  93         if (previous_game_starttime != startTime) {
  94                 if ((time + 5.0) < startTime) {
  95                         //if connecting to server while restart was active don't always play prepareforbattle
  96                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  97                 }
  98                 if (time < startTime) {
  99                         restartAnnouncer = spawn();
 100                         restartAnnouncer.think = restartAnnouncer_Think;
 101                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 102                 }
 103         }
 104         previous_game_starttime = startTime;
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 120
 121         zoomsensitivity = autocvar_cl_zoomsensitivity;
 122         zoomfactor = autocvar_cl_zoomfactor;
 123         if(zoomfactor < 1 || zoomfactor > 16)
 124                 zoomfactor = 2.5;
 125         zoomspeed = autocvar_cl_zoomspeed;
 126         if(zoomspeed >= 0)
 127                 if(zoomspeed < 0.5 || zoomspeed > 16)
 128                         zoomspeed = 3.5;
 129
 130         zoomdir = button_zoom;
 131         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 132                 zoomdir += button_attack2;
 133         if(spectatee_status > 0 || isdemo())
 134         {
 135                 if(spectatorbutton_zoom)
 136                         zoomdir = 0 + !zoomdir;
 137                 // do not even THINK about removing this 0
 138                 // _I_ know what I am doing
 139                 // fteqcc does not
 140         }
 141
 142         if(zoomdir)
 143                 zoomin_effect = 0;
 144
 145         if(zoomin_effect || camera_active)
 146         {
 147                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 148         }
 149         else
 150         {
 151                 if(zoomspeed < 0) // instant zoom
 152                 {
 153                         if(zoomdir)
 154                                 current_viewzoom = 1 / zoomfactor;
 155                         else
 156                                 current_viewzoom = 1;
 157                 }
 158                 else
 159                 {
 160                         if(zoomdir)
 161                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 162                         else
 163                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 164                 }
 165         }
 166
 167         if(almost_equals(current_viewzoom, 1))
 168                 current_zoomfraction = 0;
 169         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 170                 current_zoomfraction = 1;
 171         else
 172                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 173
 174         if(zoomsensitivity < 1)
 175                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 176         else
 177                 setsensitivityscale(1);
 178
 179         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 180         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 181         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 182
 183         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 184
 185         float frustumx, frustumy, fovx, fovy;
 186         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 187         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 188         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 189         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 190
 191         return '1 0 0' * fovx + '0 1 0' * fovy;
 192 }
 193
 194 // this function must match W_SetupShot!
 195 float zoomscript_caught;
 196
 197 vector wcross_origin;
 198 float wcross_scale_prev, wcross_alpha_prev;
 199 vector wcross_color_prev;
 200 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 201 vector wcross_color_goal_prev;
 202 float wcross_changedonetime;
 203
 204 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 205 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 206 float wcross_name_changestarttime, wcross_name_changedonetime;
 207 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 208 entity trueaim;
 209 entity trueaim_rifle;
 210
 211 #define SHOTTYPE_HITTEAM 1
 212 #define SHOTTYPE_HITOBSTRUCTION 2
 213 #define SHOTTYPE_HITWORLD 3
 214 #define SHOTTYPE_HITENEMY 4
 215
 216 void TrueAim_Init()
 217 {
 218         trueaim = spawn();
 219         trueaim.classname = "trueaim";
 220         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 221         trueaim_rifle = spawn();
 222         trueaim_rifle.classname = "trueaim_rifle";
 223         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 224 }
 225
 226 float EnemyHitCheck()
 227 {
 228         float t;
 229         wcross_origin = project_3d_to_2d(trace_endpos);
 230         wcross_origin_z = 0;
 231         if(trace_networkentity < 1)
 232                 return SHOTTYPE_HITWORLD;
 233         if(trace_networkentity > maxclients)
 234                 return SHOTTYPE_HITWORLD;
 235         t = GetPlayerColor(trace_networkentity - 1);
 236         if(teamplay)
 237                 if(t == myteam)
 238                         return SHOTTYPE_HITTEAM;
 239         if(t == COLOR_SPECTATOR)
 240                 return SHOTTYPE_HITWORLD;
 241         return SHOTTYPE_HITENEMY;
 242 }
 243
 244 float TrueAimCheck()
 245 {
 246         float nudge = 1; // added to traceline target and subtracted from result
 247         vector vecs, trueaimpoint, w_shotorg;
 248         vector mi, ma, dv;
 249         float shottype;
 250         entity ta;
 251         float mv;
 252
 253         mi = ma = '0 0 0';
 254         ta = trueaim;
 255         mv = MOVE_NOMONSTERS;
 256
 257         switch(activeweapon)
 258         {
 259                 case WEP_TUBA: // no aim
 260                 case WEP_PORTO: // shoots from eye
 261                 case WEP_HOOK: // no trueaim
 262                 case WEP_GRENADE_LAUNCHER: // toss curve
 263                         return SHOTTYPE_HITWORLD;
 264                 case WEP_NEX:
 265                 case WEP_MINSTANEX:
 266                         mv = MOVE_NORMAL;
 267                         break;
 268                 case WEP_SNIPERRIFLE:
 269                         ta = trueaim_rifle;
 270                         mv = MOVE_NORMAL;
 271                         if(zoomscript_caught)
 272                         {
 273                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 274                                 return EnemyHitCheck();
 275                         }
 276                         break;
 277                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 278                         mi = '-3 -3 -3';
 279                         ma = '3 3 3';
 280                         break;
 281                 case WEP_FIREBALL: // projectile has a size!
 282                         mi = '-16 -16 -16';
 283                         ma = '16 16 16';
 284                         break;
 285                 case WEP_SEEKER: // projectile has a size!
 286                         mi = '-2 -2 -2';
 287                         ma = '2 2 2';
 288                         break;
 289                 case WEP_ELECTRO: // projectile has a size!
 290                         mi = '0 0 -3';
 291                         ma = '0 0 -3';
 292                         break;
 293         }
 294
 295         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 296
 297         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 298         trueaimpoint = trace_endpos;
 299
 300         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 301                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 302
 303         if(vecs_x > 0)
 304                 vecs_y = -vecs_y;
 305         else
 306                 vecs = '0 0 0';
 307
 308         dv = view_right * vecs_y + view_up * vecs_z;
 309         w_shotorg = view_origin + dv;
 310
 311         // now move the vecs forward as much as requested if possible
 312         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 313         w_shotorg = trace_endpos - view_forward * nudge;
 314
 315         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 316         shottype = EnemyHitCheck();
 317         if(shottype != SHOTTYPE_HITWORLD)
 318                 return shottype;
 319
 320 #if 0
 321         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 322         // or rather, I know why, but see no fix
 323         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 324                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 325                 return SHOTTYPE_HITOBSTRUCTION;
 326 #endif
 327
 328         return SHOTTYPE_HITWORLD;
 329 }
 330
 331 void CSQC_common_hud(void);
 332
 333 void PostInit(void);
 334 void CSQC_Demo_Camera();
 335 float HUD_WouldDrawScoreboard();
 336 float view_set;
 337 float camera_mode;
 338 float reticle_type;
 339 string NextFrameCommand;
 340 void CSQC_SPIDER_HUD();
 341 void CSQC_RAPTOR_HUD();
 342
 343 vector freeze_pmove_org, freeze_input_angles;
 344 entity nightvision_noise, nightvision_noise2;
 345
 346 float pickup_crosshair_time, pickup_crosshair_size;
 347 float hit_time, typehit_time;
 348 float nextsound_hit_time, nextsound_typehit_time;
 349 float hitindication_crosshair_time, hitindication_crosshair_size;
 350 float use_nex_chargepool;
 351
 352 float myhealth, myhealth_prev;
 353 float myhealth_flash;
 354
 355 vector myhealth_gentlergb;
 356
 357 float contentavgalpha, liquidalpha_prev;
 358 vector liquidcolor_prev;
 359
 360 void CSQC_UpdateView(float w, float h)
 361 {
 362         entity e;
 363         float fov;
 364         float f, i, j;
 365         vector v, vo;
 366         vector vf_size, vf_min;
 367         float a;
 368
 369         vf_size = R_SetView3fv(VF_SIZE);
 370         vf_min = R_SetView3fv(VF_MIN);
 371         vid_width = vf_size_x;
 372         vid_height = vf_size_y;
 373
 374         vector reticle_pos, reticle_size;
 375         vector splash_pos, splash_size;
 376
 377         WaypointSprite_Load();
 378
 379         if(spectatee_status)
 380                 myteam = GetPlayerColor(spectatee_status - 1);
 381         else
 382                 myteam = GetPlayerColor(player_localentnum - 1);
 383
 384         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 385         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 386
 387         warpzone_fixview_origin = pmove_org + vo;
 388         warpzone_fixview_cl_viewangles = input_angles;
 389         warpzone_fixview_angles = view_angles;
 390         WarpZone_FixView();
 391         pmove_org = warpzone_fixview_origin - vo;
 392         input_angles = warpzone_fixview_cl_viewangles;
 393         view_angles = warpzone_fixview_angles;
 394
 395         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 396         {
 397                 pmove_org = freeze_pmove_org;
 398                 input_angles = view_angles = freeze_input_angles;
 399                 R_SetView(VF_ORIGIN, pmove_org + vo);
 400                 R_SetView(VF_ANGLES, view_angles);
 401                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 402         }
 403         freeze_pmove_org = pmove_org;
 404         freeze_input_angles = input_angles;
 405
 406         // Render the Scene
 407         if(!intermission || !view_set)
 408         {
 409                 view_origin = pmove_org + vo;
 410                 view_angles = input_angles;
 411                 makevectors(view_angles);
 412                 view_forward = v_forward;
 413                 view_right = v_right;
 414                 view_up = v_up;
 415                 view_set = 1;
 416         }
 417
 418 #ifdef BLURTEST
 419         if(time > blurtest_time0 && time < blurtest_time1)
 420         {
 421                 float r, t;
 422
 423                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 424                 r = t * blurtest_radius;
 425                 f = 1 / pow(t, blurtest_power) - 1;
 426
 427                 cvar_set("r_glsl_postprocess", "1");
 428                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 429         }
 430         else
 431         {
 432                 cvar_set("r_glsl_postprocess", "0");
 433                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 434         }
 435 #endif
 436
 437         TargetMusic_Advance();
 438         Fog_Force();
 439
 440         drawframetime = max(0.000001, time - drawtime);
 441         drawtime = time;
 442
 443         // watch for gametype changes here...
 444         // in ParseStuffCMD the cmd isn't executed yet :/
 445         // might even be better to add the gametype to TE_CSQC_INIT...?
 446         if(!postinit)
 447                 PostInit();
 448
 449         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 450                 if(calledhooks & HOOK_START)
 451                 {
 452                         localcmd("\ncl_hook_gameend\n");
 453                         calledhooks |= HOOK_END;
 454                 }
 455
 456         CheckForGamestartChange();
 457         serverAnnouncer();
 458         maptimeAnnouncer();
 459         carrierAnnouncer();
 460
 461         fov = autocvar_fov;
 462         if(button_zoom || fov <= 59.5)
 463         {
 464                 if(!zoomscript_caught)
 465                 {
 466                         localcmd("+button4\n");
 467                         zoomscript_caught = 1;
 468                         ignore_plus_zoom += 1;
 469                 }
 470         }
 471         else
 472         {
 473                 if(zoomscript_caught)
 474                 {
 475                         localcmd("-button4\n");
 476                         zoomscript_caught = 0;
 477                         ignore_minus_zoom += 1;
 478                 }
 479         }
 480
 481         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 482         activeweapon = getstati(STAT_SWITCHWEAPON);
 483         f = (serverflags & SERVERFLAG_TEAMPLAY);
 484         if(f != teamplay)
 485         {
 486                 teamplay = f;
 487                 HUD_InitScores();
 488         }
 489
 490         if(last_weapon != activeweapon) {
 491                 weapontime = time;
 492                 last_weapon = activeweapon;
 493
 494                 e = get_weaponinfo(activeweapon);
 495                 if(e.netname != "")
 496                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 497                 else
 498                         localcmd("\ncl_hook_activeweapon none\n");
 499         }
 500
 501         // ALWAYS Clear Current Scene First
 502         R_ClearScene();
 503
 504         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 505         R_SetView(VF_SIZE, vf_size);
 506         R_SetView(VF_MIN, vf_min);
 507
 508         // Assign Standard Viewflags
 509         // Draw the World (and sky)
 510         R_SetView(VF_DRAWWORLD, 1);
 511
 512         // Set the console size vars
 513         vid_conwidth = autocvar_vid_conwidth;
 514         vid_conheight = autocvar_vid_conheight;
 515         vid_pixelheight = autocvar_vid_pixelheight;
 516
 517         R_SetView(VF_FOV, GetCurrentFov(fov));
 518
 519         // Camera for demo playback
 520         if(camera_active)
 521         {
 522                 if(autocvar_camera_enable)
 523                         CSQC_Demo_Camera();
 524                 else
 525                 {
 526                         cvar_set("chase_active", ftos(chase_active_backup));
 527                         cvar_set("cl_demo_mousegrab", "0");
 528                         camera_active = FALSE;
 529                 }
 530         }
 531 #ifdef CAMERATEST
 532         else if(autocvar_camera_enable)
 533 #else
 534         else if(autocvar_camera_enable && isdemo())
 535 #endif
 536         {
 537                 // Enable required Darkplaces cvars
 538                 chase_active_backup = autocvar_chase_active;
 539                 cvar_set("chase_active", "2");
 540                 cvar_set("cl_demo_mousegrab", "1");
 541                 camera_active = TRUE;
 542                 camera_mode = FALSE;
 543         }
 544
 545         // Draw the Crosshair
 546         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 547
 548         // Draw the Engine Status Bar (the default Quake HUD)
 549         R_SetView(VF_DRAWENGINEHUD, 0);
 550
 551         // fetch this one only once per frame
 552         hud_showbinds = autocvar_hud_showbinds;
 553         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 554
 555         // Update the mouse position
 556         /*
 557            mousepos_x = vid_conwidth;
 558            mousepos_y = vid_conheight;
 559            mousepos = mousepos*0.5 + getmousepos();
 560          */
 561
 562         e = self;
 563         for(self = world; (self = nextent(self)); )
 564                 if(self.draw)
 565                         self.draw();
 566         self = e;
 567
 568         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 569         R_RenderScene();
 570
 571         // now switch to 2D drawing mode by calling a 2D drawing function
 572         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 573         // next R_RenderScene call
 574         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 575
 576         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 577         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 578         {
 579                 // apply night vision effect
 580                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 581
 582                 if(!nightvision_noise)
 583                 {
 584                         nightvision_noise = spawn();
 585                         nightvision_noise.classname = "nightvision_noise";
 586                 }
 587                 if(!nightvision_noise2)
 588                 {
 589                         nightvision_noise2 = spawn();
 590                         nightvision_noise2.classname = "nightvision_noise2";
 591                 }
 592
 593                 // color tint in yellow
 594                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 595
 596                 // draw BG
 597                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 598                 rgb = '1 1 1';
 599                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 600                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 601                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 602                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 603                 tc_11 = tc_01 + tc_10 - tc_00;
 604                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 605                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 606                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 607                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 608                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 609                 R_EndPolygon();
 610
 611                 // draw FG
 612                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 613                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 614                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 615                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 616                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 617                 tc_11 = tc_01 + tc_10 - tc_00;
 618                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 619                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 620                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 621                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 622                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 623                 R_EndPolygon();
 624         }
 625
 626         // Draw the aiming reticle for weapons that use it
 627         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 628         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 629         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 630         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 631                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 632         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 633                 reticle_type = 2; // nex zoom
 634         else if(button_zoom || zoomscript_caught)
 635                 reticle_type = 1; // normal zoom
 636         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 637                 reticle_type = 2; // nex zoom
 638
 639         if (reticle_type)
 640         {
 641                 if(autocvar_cl_reticle_stretch)
 642                 {
 643                         reticle_size_x = vid_conwidth;
 644                         reticle_size_y = vid_conheight;
 645                         reticle_pos_x = 0;
 646                         reticle_pos_y = 0;
 647                 }
 648                 else
 649                 {
 650                         reticle_size_x = max(vid_conwidth, vid_conheight);
 651                         reticle_size_y = max(vid_conwidth, vid_conheight);
 652                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 653                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 654                 }
 655
 656                 f = current_zoomfraction;
 657                 if(zoomscript_caught)
 658                         f = 1;
 659                 if(autocvar_cl_reticle_item_normal)
 660                 {
 661                         if(reticle_type == 1 && f)
 662                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 663                 }
 664                 if(autocvar_cl_reticle_item_nex)
 665                 {
 666                         if(reticle_type == 2 && f)
 667                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 668                 }
 669         }
 670
 671
 672         // improved polyblend
 673         vector rgb;
 674         if(autocvar_hud_contents)
 675         {
 676                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 677                 vector liquidcolor;
 678
 679                 switch(pointcontents(view_origin))
 680                 {
 681                         case CONTENT_WATER:
 682                                 liquidalpha = autocvar_hud_contents_water_alpha;
 683                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 684                                 incontent = 1;
 685                                 break;
 686
 687                         case CONTENT_LAVA:
 688                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 689                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 690                                 incontent = 1;
 691                                 break;
 692
 693                         case CONTENT_SLIME:
 694                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 695                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 696                                 incontent = 1;
 697                                 break;
 698
 699                         default:
 700                                 liquidalpha = 0;
 701                                 liquidcolor = '0 0 0';
 702                                 incontent = 0;
 703                                 break;
 704                 }
 705
 706                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 707                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 708                         contentfadetime = autocvar_hud_contents_fadeintime;
 709                         liquidalpha_prev = liquidalpha;
 710                         liquidcolor_prev = liquidcolor;
 711                 }
 712                 else
 713                         contentfadetime = autocvar_hud_contents_fadeouttime;
 714
 715                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 716                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 717
 718                 if(contentavgalpha)
 719                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 720         }
 721
 722         if(autocvar_hud_damage)
 723         {
 724                 splash_size_x = max(vid_conwidth, vid_conheight);
 725                 splash_size_y = max(vid_conwidth, vid_conheight);
 726                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 727                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 728
 729                 float myhealth_flash_temp;
 730                 myhealth = getstati(STAT_HEALTH);
 731
 732                 // fade out
 733                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 734                 // add new damage
 735                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 736
 737                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 738                 pain_threshold = autocvar_hud_damage_pain_threshold;
 739                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 740                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 741
 742                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 743                 {
 744                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 745                 }
 746
 747                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 748
 749                 if(myhealth_prev < 1)
 750                 {
 751                         if(myhealth >= 1)
 752                         {
 753                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 754                                 myhealth_flash_temp = 0;
 755                         }
 756                         else
 757                         {
 758                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 759                         }
 760                 }
 761
 762                 if(spectatee_status == -1 || intermission)
 763                 {
 764                         myhealth_flash = 0; // observing, or match ended
 765                         myhealth_flash_temp = 0;
 766                 }
 767
 768                 myhealth_prev = myhealth;
 769
 770                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 771                 {
 772                         if(autocvar_cl_gentle_damage == 2)
 773                         {
 774                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 775                                 {
 776                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 777                                 }
 778                         }
 779                         else
 780                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 781
 782                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 783                 }
 784                 else
 785                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 786         }
 787
 788         // Draw the mouse cursor
 789         // NOTE: drawpic must happen after R_RenderScene for some reason
 790         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 791         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 792         //self = edict_num(player_localnum);
 793         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 794         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 795         // as long as the ctf part isn't in, this is useless
 796         if(menu_visible)
 797                 menu_show();
 798
 799         /*if(gametype == GAME_CTF)
 800           {
 801           ctf_view();
 802           } else */
 803
 804         // draw 2D entities
 805         e = self;
 806         for(self = world; (self = nextent(self)); )
 807                 if(self.draw2d)
 808                         self.draw2d();
 809         self = e;
 810
 811         scoreboard_active = HUD_WouldDrawScoreboard();
 812
 813         hit_time = getstatf(STAT_HIT_TIME);
 814         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 815         {
 816                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 817                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 818         }
 819         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 820         if(typehit_time > nextsound_typehit_time)
 821         {
 822                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 823                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 824         }
 825
 826         float hud;
 827         hud = getstati(STAT_HUD);
 828         if(hud == HUD_SPIDERBOT)
 829                 CSQC_SPIDER_HUD();
 830         else if(hud == HUD_WAKIZASHI)
 831         CSQC_WAKIZASHI_HUD();
 832     else if(hud == HUD_RAPTOR)
 833         CSQC_RAPTOR_HUD();
 834     else if(hud == HUD_BUMBLEBEE)
 835         CSQC_BUMBLE_HUD();
 836         else
 837         {
 838                 if(gametype == GAME_FREEZETAG)
 839                 {
 840                         if(getstati(STAT_FROZEN))
 841                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 842                         if(getstatf(STAT_REVIVE_PROGRESS))
 843                         {
 844                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 845                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 846                         }
 847                 }
 848
 849                 if(autocvar_r_letterbox == 0)
 850                         if(autocvar_viewsize < 120)
 851                                 CSQC_common_hud();
 852
 853                 // crosshair goes VERY LAST
 854                 if(!scoreboard_active && !camera_active && intermission != 2) {
 855                         string wcross_style;
 856                         float wcross_alpha, wcross_resolution;
 857                         wcross_style = autocvar_crosshair;
 858                         if (wcross_style == "0")
 859                                 return;
 860                         wcross_resolution = autocvar_crosshair_size;
 861                         if (wcross_resolution == 0)
 862                                 return;
 863                         wcross_alpha = autocvar_crosshair_alpha;
 864                         if (wcross_alpha == 0)
 865                                 return;
 866
 867                         // TrueAim check
 868                         float shottype;
 869
 870                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 871                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 872                         wcross_origin_z = 0;
 873                         if(autocvar_crosshair_hittest)
 874                         {
 875                                 vector wcross_oldorigin;
 876                                 wcross_oldorigin = wcross_origin;
 877                                 shottype = TrueAimCheck();
 878                                 if(shottype == SHOTTYPE_HITWORLD)
 879                                 {
 880                                         v = wcross_origin - wcross_oldorigin;
 881                                         v_x /= vid_conwidth;
 882                                         v_y /= vid_conheight;
 883                                         if(vlen(v) > 0.01)
 884                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 885                                 }
 886                                 if(!autocvar_crosshair_hittest_showimpact)
 887                                         wcross_origin = wcross_oldorigin;
 888                         }
 889                         else
 890                                 shottype = SHOTTYPE_HITWORLD;
 891
 892                         vector wcross_color, wcross_size;
 893                         string wcross_wep, wcross_name;
 894                         float wcross_scale, wcross_blur;
 895
 896                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 897                                 e = get_weaponinfo(activeweapon);
 898                                 if (e && e.netname != "")
 899                                 {
 900                                         wcross_wep = e.netname;
 901                                         if(autocvar_crosshair_per_weapon)
 902                                         {
 903                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 904                                                 if (wcross_resolution == 0)
 905                                                         return;
 906                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 907                                                 if (wcross_alpha == 0)
 908                                                         return;
 909
 910                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 911                                                 if(wcross_style == "" || wcross_style == "0")
 912                                                         wcross_style = wcross_wep;
 913                                         }
 914                                 }
 915                         }
 916                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 917                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 918                         else if(autocvar_crosshair_color_by_health)
 919                         {
 920                                 local float x = getstati(STAT_HEALTH);
 921
 922                                 //x = red
 923                                 //y = green
 924                                 //z = blue
 925
 926                                 wcross_color_z = 0;
 927
 928                                 if(x > 200)
 929                                 {
 930                                         wcross_color_x = 0;
 931                                         wcross_color_y = 1;
 932                                 }
 933                                 else if(x > 150)
 934                                 {
 935                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 936                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 937                                 }
 938                                 else if(x > 100)
 939                                 {
 940                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 941                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 942                                         wcross_color_z = 1 - (x-100)*0.02;
 943                                 }
 944                                 else if(x > 50)
 945                                 {
 946                                         wcross_color_x = 1;
 947                                         wcross_color_y = 1;
 948                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 949                                 }
 950                                 else if(x > 20)
 951                                 {
 952                                         wcross_color_x = 1;
 953                                         wcross_color_y = (x-20)*90/27/100;
 954                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 955                                 }
 956                                 else
 957                                 {
 958                                         wcross_color_x = 1;
 959                                         wcross_color_y = 0;
 960                                 }
 961                         }
 962                         else
 963                                 wcross_color = stov(autocvar_crosshair_color);
 964
 965                         wcross_name = strcat("gfx/crosshair", wcross_style);
 966
 967                         if(autocvar_crosshair_effect_scalefade)
 968                         {
 969                                 wcross_scale = wcross_resolution;
 970                                 wcross_resolution = 1;
 971                         }
 972                         else
 973                         {
 974                                 wcross_scale = 1;
 975                         }
 976
 977                         if(autocvar_crosshair_pickup)
 978                         {
 979                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
 980                                 {
 981                                         pickup_crosshair_size = 1;
 982                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
 983                                 }
 984
 985                                 if(pickup_crosshair_size > 0)
 986                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 987                                 else
 988                                         pickup_crosshair_size = 0;
 989
 990                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 991                         }
 992
 993                         vector hitindication_color;
 994                         if(autocvar_crosshair_hitindication)
 995                         {
 996                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
 997                                 if(hitindication_crosshair_time < hit_time)
 998                                 {
 999                                         hitindication_crosshair_size = 1;
1000                                         hitindication_crosshair_time = hit_time;
1001                                 }
1002
1003                                 if(hitindication_crosshair_size > 0)
1004                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1005                                 else
1006                                         hitindication_crosshair_size = 0;
1007
1008                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1009                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1010                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1011                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1012                         }
1013
1014                         if(shottype == SHOTTYPE_HITENEMY)
1015                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1016                         if(shottype == SHOTTYPE_HITTEAM)
1017                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1018
1019                         f = autocvar_crosshair_effect_speed;
1020                         if(f < 0)
1021                                 f *= -2 * g_weaponswitchdelay;
1022                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1023                         {
1024                                 wcross_changedonetime = time + f;
1025                         }
1026                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1027                         {
1028                                 wcross_name_changestarttime = time;
1029                                 wcross_name_changedonetime = time + f;
1030                                 if(wcross_name_goal_prev_prev)
1031                                         strunzone(wcross_name_goal_prev_prev);
1032                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1033                                 wcross_name_goal_prev = strzone(wcross_name);
1034                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1035                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1036                                 wcross_resolution_goal_prev = wcross_resolution;
1037                         }
1038
1039                         wcross_scale_goal_prev = wcross_scale;
1040                         wcross_alpha_goal_prev = wcross_alpha;
1041                         wcross_color_goal_prev = wcross_color;
1042
1043                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1044                         {
1045                                 wcross_blur = 1;
1046                                 wcross_alpha *= 0.75;
1047                         }
1048                         else
1049                                 wcross_blur = 0;
1050                         // *_prev is at time-frametime
1051                         // * is at wcross_changedonetime+f
1052                         // what do we have at time?
1053                         if(time < wcross_changedonetime)
1054                         {
1055                                 f = frametime / (wcross_changedonetime - time + frametime);
1056                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1057                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1058                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1059                         }
1060
1061                         wcross_scale_prev = wcross_scale;
1062                         wcross_alpha_prev = wcross_alpha;
1063                         wcross_color_prev = wcross_color;
1064
1065                         wcross_scale *= 1 - autocvar__menu_alpha;
1066                         wcross_alpha *= 1 - autocvar__menu_alpha;
1067                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1068
1069                         // crosshair rings for weapon stats
1070                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1071                         {
1072                                 // declarations and stats
1073                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1074                                 string ring_image, ring_inner_image;
1075                                 vector ring_rgb, ring_inner_rgb;
1076
1077                                 ring_scale = autocvar_crosshair_ring_size;
1078
1079                                 float weapon_clipload, weapon_clipsize;
1080                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1081                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1082
1083                                 float nex_charge, nex_chargepool;
1084                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1085                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1086
1087                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1088                                         nex_charge_movingavg = nex_charge;
1089
1090
1091                                 // handle the values
1092                                 if (activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1093                                 {
1094                                         if (nex_chargepool || use_nex_chargepool) {
1095                                                 use_nex_chargepool = 1;
1096                                                 ring_inner_value = nex_chargepool;
1097                                         } else {
1098                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1099                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1100                                         }
1101
1102                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1103                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1104                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1105
1106                                         // draw the outer ring to show the current charge of the weapon
1107                                         ring_value = nex_charge;
1108                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1109                                         ring_rgb = wcross_color;
1110                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1111                                 }
1112                                 else if (activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1113                                 {
1114                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1115                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1116                                         ring_rgb = wcross_color;
1117                                         ring_image = "gfx/crosshair_ring.tga";
1118                                 }
1119
1120                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1121                                 {
1122                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1123                                         ring_scale = autocvar_crosshair_ring_reload_size;
1124                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1125                                         ring_rgb = wcross_color;
1126
1127                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1128                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1129                                         if ((activeweapon == WEP_SNIPERRIFLE) && (weapon_clipsize == 80))
1130                                                 ring_image = "gfx/crosshair_ring_sniperrifle.tga";
1131                                         else
1132                                                 ring_image = "gfx/crosshair_ring.tga";
1133                                 }
1134
1135                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1136                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1137
1138                                 if (ring_value)
1139                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1140                         }
1141
1142 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1143                         do \
1144                         { \
1145                                 if(wcross_blur > 0) \
1146                                 { \
1147                                         for(i = -2; i <= 2; ++i) \
1148                                                 for(j = -2; j <= 2; ++j) \
1149                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1150                                 } \
1151                                 else \
1152                                 { \
1153                                         M(0,0,sz,wcross_name,wcross_alpha); \
1154                                 } \
1155                         } \
1156                         while(0)
1157
1158 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1159                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1160
1161 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1162                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1163
1164                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1165                         {
1166                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1167                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1168                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1169                                 f = 1 - f;
1170                         }
1171                         else
1172                         {
1173                                 f = 1;
1174                         }
1175
1176                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1177                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1178
1179                         if(autocvar_crosshair_dot)
1180             {
1181                 vector wcross_color_old;
1182                 wcross_color_old = wcross_color;
1183                 if(autocvar_crosshair_dot_color != "0")
1184                     wcross_color = stov(autocvar_crosshair_dot_color);
1185                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1186                 wcross_color = wcross_color_old;
1187             }
1188
1189                         wcross_name_alpha_goal_prev = f;
1190                 }
1191                 else
1192                 {
1193                         wcross_scale_prev = 0;
1194                         wcross_alpha_prev = 0;
1195                         wcross_scale_goal_prev = 0;
1196                         wcross_alpha_goal_prev = 0;
1197                         wcross_changedonetime = 0;
1198                         if(wcross_name_goal_prev)
1199                                 strunzone(wcross_name_goal_prev);
1200                         wcross_name_goal_prev = string_null;
1201                         if(wcross_name_goal_prev_prev)
1202                                 strunzone(wcross_name_goal_prev_prev);
1203                         wcross_name_goal_prev_prev = string_null;
1204                         wcross_name_changestarttime = 0;
1205                         wcross_name_changedonetime = 0;
1206                         wcross_name_alpha_goal_prev = 0;
1207                         wcross_name_alpha_goal_prev_prev = 0;
1208                         wcross_resolution_goal_prev = 0;
1209                         wcross_resolution_goal_prev_prev = 0;
1210                 }
1211         }
1212
1213         if(NextFrameCommand)
1214         {
1215                 localcmd("\n", NextFrameCommand, "\n");
1216                 NextFrameCommand = string_null;
1217         }
1218
1219         // we must do this check AFTER a frame was rendered, or it won't work
1220         if(cs_project_is_b0rked == 0)
1221         {
1222                 string w0, h0;
1223                 w0 = ftos(autocvar_vid_conwidth);
1224                 h0 = ftos(autocvar_vid_conheight);
1225                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1226                 //R_SetView(VF_FOV, '90 90 0');
1227                 R_SetView(VF_ORIGIN, '0 0 0');
1228                 R_SetView(VF_ANGLES, '0 0 0');
1229                 R_SetView(VF_PERSPECTIVE, 1);
1230                 makevectors('0 0 0');
1231                 vector v1, v2;
1232                 cvar_set("vid_conwidth", "800");
1233                 cvar_set("vid_conheight", "600");
1234                 v1 = cs_project(v_forward);
1235                 cvar_set("vid_conwidth", "640");
1236                 cvar_set("vid_conheight", "480");
1237                 v2 = cs_project(v_forward);
1238                 if(v1 == v2)
1239                         cs_project_is_b0rked = 1;
1240                 else
1241                         cs_project_is_b0rked = -1;
1242                 cvar_set("vid_conwidth", w0);
1243                 cvar_set("vid_conheight", h0);
1244         }
1245
1246         if(autocvar__hud_configure)
1247                 HUD_Panel_Mouse();
1248
1249         // let's reset the view back to normal for the end
1250         R_SetView(VF_MIN, '0 0 0');
1251         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1252 }
1253
1254 void CSQC_common_hud(void)
1255 {
1256         // HUD_SortFrags(); done in HUD_Draw
1257         float hud;
1258         hud = getstati(STAT_HUD);
1259
1260         //hud = 10;
1261         switch(hud)
1262         {
1263                 case HUD_NORMAL:
1264                         // do some accuracy var caching
1265                         float i;
1266                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1267                         {
1268                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1269                                 {
1270                                         if(acc_color_levels)
1271                                                 strunzone(acc_color_levels);
1272                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1273                                         acc_levels = tokenize(acc_color_levels);
1274                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1275                                                 acc_levels = MAX_ACCURACY_LEVELS;
1276
1277                                         for (i = 0; i < acc_levels; ++i)
1278                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1279                                 }
1280                                 // let know that acc_col[] needs to be loaded
1281                                 acc_col_x[0] = -1;
1282                         }
1283
1284                         HUD_Main(); // always run these functions for alpha checks
1285                         HUD_DrawScoreboard();
1286
1287                         if (scoreboard_active) // scoreboard/accuracy
1288                         {
1289                                 HUD_Reset();
1290                                 // HUD_DrawScoreboard takes care of centerprint_start
1291                         }
1292                         else if (intermission == 2) // map voting screen
1293                         {
1294                                 HUD_FinaleOverlay();
1295                                 HUD_Reset();
1296
1297                                 centerprint_start_x = 0;
1298                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1299                         }
1300                         else // hud
1301                         {
1302                                 centerprint_start_x = 0;
1303                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1304                         }
1305
1306                         HUD_DrawCenterPrint();
1307                         break;
1308
1309                 case HUD_SPIDERBOT:
1310                         CSQC_SPIDER_HUD();
1311                         break;
1312
1313                 case HUD_WAKIZASHI:
1314                         CSQC_WAKIZASHI_HUD();
1315                         break;
1316
1317         case HUD_BUMBLEBEE:
1318             CSQC_BUMBLE_HUD();
1319             break;
1320
1321         }
1322 }
1323
1324
1325 // following vectors must be global to allow seamless switching between camera modes
1326 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1327 void CSQC_Demo_Camera()
1328 {
1329         float speed, attenuation, dimensions;
1330         vector tmp, delta;
1331
1332         if( autocvar_camera_reset || !camera_mode )
1333         {
1334                 camera_offset = '0 0 0';
1335                 current_angles = '0 0 0';
1336                 camera_direction = '0 0 0';
1337                 camera_offset_z += 30;
1338                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1339                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1340                 current_origin = view_origin;
1341                 current_camera_offset  = camera_offset;
1342                 cvar_set("camera_reset", "0");
1343                 camera_mode = CAMERA_CHASE;
1344         }
1345
1346         // Camera angles
1347         if( camera_roll )
1348                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1349
1350         if(autocvar_camera_look_player)
1351         {
1352                 local vector dir;
1353                 local float n;
1354
1355                 dir = normalize(view_origin - current_position);
1356                 n = mouse_angles_z;
1357                 mouse_angles = vectoangles(dir);
1358                 mouse_angles_x = mouse_angles_x * -1;
1359                 mouse_angles_z = n;
1360         }
1361         else
1362         {
1363                 tmp = getmousepos() * 0.1;
1364                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1365                 {
1366                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1367                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1368                 }
1369         }
1370
1371         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1372         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1373         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1374         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1375
1376         // Fix difference when angles don't have the same sign
1377         delta = '0 0 0';
1378         if(mouse_angles_y < -60 && current_angles_y > 60)
1379                 delta = '0 360 0';
1380         if(mouse_angles_y > 60 && current_angles_y < -60)
1381                 delta = '0 -360 0';
1382
1383         if(autocvar_camera_look_player)
1384                 attenuation = autocvar_camera_look_attenuation;
1385         else
1386                 attenuation = autocvar_camera_speed_attenuation;
1387
1388         attenuation = 1 / max(1, attenuation);
1389         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1390
1391         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1392         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1393         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1394         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1395
1396         // Camera position
1397         tmp = '0 0 0';
1398         dimensions = 0;
1399
1400         if( camera_direction_x )
1401         {
1402                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1403                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1404                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1405                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1406                 ++dimensions;
1407         }
1408
1409         if( camera_direction_y )
1410         {
1411                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1412                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1413                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1414                 ++dimensions;
1415         }
1416
1417         if( camera_direction_z )
1418         {
1419                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1420                 ++dimensions;
1421         }
1422
1423         if(autocvar_camera_free)
1424                 speed = autocvar_camera_speed_free;
1425         else
1426                 speed = autocvar_camera_speed_chase;
1427
1428         if(dimensions)
1429         {
1430                 speed = speed * sqrt(1 / dimensions);
1431                 camera_offset += tmp * speed;
1432         }
1433
1434         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1435
1436         // Camera modes
1437         if( autocvar_camera_free )
1438         {
1439                 if ( camera_mode == CAMERA_CHASE )
1440                 {
1441                         current_camera_offset = current_origin + current_camera_offset;
1442                         camera_offset = current_origin + camera_offset;
1443                 }
1444
1445                 camera_mode = CAMERA_FREE;
1446                 current_position = current_camera_offset;
1447         }
1448         else
1449         {
1450                 if ( camera_mode == CAMERA_FREE )
1451                 {
1452                         current_origin = view_origin;
1453                         camera_offset = camera_offset - current_origin;
1454                         current_camera_offset = current_camera_offset - current_origin;
1455                 }
1456
1457                 camera_mode = CAMERA_CHASE;
1458
1459                 if(autocvar_camera_chase_smoothly)
1460                         current_origin += (view_origin - current_origin) * attenuation;
1461                 else
1462                         current_origin = view_origin;
1463
1464                 current_position = current_origin + current_camera_offset;
1465         }
1466
1467         R_SetView(VF_ANGLES, current_angles);
1468         R_SetView(VF_ORIGIN, current_position);
1469 }