qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                 {
  61                         portal1_idx = idx;
  62                         if(portal_number >= 2)
  63                                 break;
  64                 }
  65         }
  66
  67         while(idx >= 2)
  68         {
  69                 p = polyline[idx-2];
  70                 q = polyline[idx-1];
  71                 if(idx == 2)
  72                         p = p - view_up * 16;
  73                 if(idx-1 >= portal1_idx)
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 else
  78                 {
  79                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  80                 }
  81                 --idx;
  82         }
  83 }
  84
  85 void Porto_Init()
  86 {
  87         porto = spawn();
  88         porto.classname = "porto";
  89         porto.draw = Porto_Draw;
  90         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  91 }
  92
  93 float drawtime;
  94 float avgspeed;
  95 vector GetCurrentFov(float fov)
  96 {
  97         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  98         float velocityzoom, curspeed;
  99         vector v;
 100
 101         zoomsensitivity = autocvar_cl_zoomsensitivity;
 102         zoomfactor = autocvar_cl_zoomfactor;
 103         if(zoomfactor < 1 || zoomfactor > 16)
 104                 zoomfactor = 2.5;
 105         zoomspeed = autocvar_cl_zoomspeed;
 106         if(zoomspeed >= 0)
 107         if(zoomspeed < 0.5 || zoomspeed > 16)
 108                         zoomspeed = 3.5;
 109
 110         zoomdir = button_zoom;
 111         if(hud == HUD_NORMAL)
 112         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 113                 zoomdir += button_attack2;
 114         if(spectatee_status > 0 || isdemo())
 115         {
 116                 if(spectatorbutton_zoom)
 117                 {
 118                         if(zoomdir)
 119                                 zoomdir = 0;
 120                         else
 121                                 zoomdir = 1;
 122                 }
 123                 // fteqcc failed twice here already, don't optimize this
 124         }
 125
 126         if(zoomdir) { zoomin_effect = 0; }
 127
 128         if(camera_active)
 129         {
 130                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 131         }
 132         else if(autocvar_cl_spawnzoom && zoomin_effect)
 133         {
 134                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 135
 136                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 137                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 138                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 139         }
 140         else
 141         {
 142                 if(zoomspeed < 0) // instant zoom
 143                 {
 144                         if(zoomdir)
 145                                 current_viewzoom = 1 / zoomfactor;
 146                         else
 147                                 current_viewzoom = 1;
 148                 }
 149                 else
 150                 {
 151                         if(zoomdir)
 152                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 153                         else
 154                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 155                 }
 156         }
 157
 158         if(almost_equals(current_viewzoom, 1))
 159                 current_zoomfraction = 0;
 160         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 161                 current_zoomfraction = 1;
 162         else
 163                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 164
 165         if(zoomsensitivity < 1)
 166                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 167         else
 168                 setsensitivityscale(1);
 169
 170         makevectors(view_angles);
 171
 172         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 173         {
 174                 v = pmove_vel;
 175                 if(csqcplayer)
 176                         v = csqcplayer.velocity;
 177
 178                 switch(autocvar_cl_velocityzoom_type)
 179                 {
 180                         case 3: curspeed = max(0, v_forward * v); break;
 181                         case 2: curspeed = (v_forward * v); break;
 182                         case 1: default: curspeed = vlen(v); break;
 183                 }
 184
 185                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 186                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 187                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 188
 189                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 190         }
 191         else
 192                 velocityzoom = 1;
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217
 218 float wcross_ring_prev;
 219
 220 entity trueaim;
 221 entity trueaim_rifle;
 222
 223 #define SHOTTYPE_HITTEAM 1
 224 #define SHOTTYPE_HITOBSTRUCTION 2
 225 #define SHOTTYPE_HITWORLD 3
 226 #define SHOTTYPE_HITENEMY 4
 227
 228 void TrueAim_Init()
 229 {
 230         trueaim = spawn();
 231         trueaim.classname = "trueaim";
 232         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233         trueaim_rifle = spawn();
 234         trueaim_rifle.classname = "trueaim_rifle";
 235         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 236 }
 237
 238 float EnemyHitCheck()
 239 {
 240         float t, n;
 241         wcross_origin = project_3d_to_2d(trace_endpos);
 242         wcross_origin_z = 0;
 243         if(trace_ent)
 244                 n = trace_ent.entnum;
 245         else
 246                 n = trace_networkentity;
 247         if(n < 1)
 248                 return SHOTTYPE_HITWORLD;
 249         if(n > maxclients)
 250                 return SHOTTYPE_HITWORLD;
 251         t = GetPlayerColor(n - 1);
 252         if(teamplay)
 253                 if(t == myteam)
 254                         return SHOTTYPE_HITTEAM;
 255         if(t == NUM_SPECTATOR)
 256                 return SHOTTYPE_HITWORLD;
 257         return SHOTTYPE_HITENEMY;
 258 }
 259
 260 float TrueAimCheck()
 261 {
 262         float nudge = 1; // added to traceline target and subtracted from result
 263         vector vecs, trueaimpoint, w_shotorg;
 264         vector mi, ma, dv;
 265         float shottype;
 266         entity ta;
 267         float mv;
 268
 269         mi = ma = '0 0 0';
 270         ta = trueaim;
 271         mv = MOVE_NOMONSTERS;
 272
 273         switch(activeweapon) // WEAPONTODO
 274         {
 275                 case WEP_TUBA: // no aim
 276                 case WEP_PORTO: // shoots from eye
 277                 case WEP_HOOK: // no trueaim
 278                 case WEP_GRENADE_LAUNCHER: // toss curve
 279                         return SHOTTYPE_HITWORLD;
 280                 case WEP_NEX:
 281                 case WEP_MINSTANEX:
 282                         mv = MOVE_NORMAL;
 283                         break;
 284                 case WEP_RIFLE:
 285                         ta = trueaim_rifle;
 286                         mv = MOVE_NORMAL;
 287                         if(zoomscript_caught)
 288                         {
 289                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 290                                 return EnemyHitCheck();
 291                         }
 292                         break;
 293                 case WEP_DEVASTATOR: // projectile has a size!
 294                         mi = '-3 -3 -3';
 295                         ma = '3 3 3';
 296                         break;
 297                 case WEP_FIREBALL: // projectile has a size!
 298                         mi = '-16 -16 -16';
 299                         ma = '16 16 16';
 300                         break;
 301                 case WEP_SEEKER: // projectile has a size!
 302                         mi = '-2 -2 -2';
 303                         ma = '2 2 2';
 304                         break;
 305                 case WEP_ELECTRO: // projectile has a size!
 306                         mi = '0 0 -3';
 307                         ma = '0 0 -3';
 308                         break;
 309         }
 310
 311         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 312
 313         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 314         trueaimpoint = trace_endpos;
 315
 316         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 317                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 318
 319         if(vecs_x > 0)
 320                 vecs_y = -vecs_y;
 321         else
 322                 vecs = '0 0 0';
 323
 324         dv = view_right * vecs_y + view_up * vecs_z;
 325         w_shotorg = view_origin + dv;
 326
 327         // now move the vecs forward as much as requested if possible
 328         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 329         w_shotorg = trace_endpos - view_forward * nudge;
 330
 331         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 332         shottype = EnemyHitCheck();
 333         if(shottype != SHOTTYPE_HITWORLD)
 334                 return shottype;
 335
 336 #if 0
 337         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 338         // or rather, I know why, but see no fix
 339         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 340                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 341                 return SHOTTYPE_HITOBSTRUCTION;
 342 #endif
 343
 344         return SHOTTYPE_HITWORLD;
 345 }
 346
 347 void CSQC_common_hud(void);
 348
 349 void PostInit(void);
 350 void CSQC_Demo_Camera();
 351 float HUD_WouldDrawScoreboard();
 352 float camera_mode;
 353 float CAMERA_FREE = 1;
 354 float CAMERA_CHASE = 2;
 355 float reticle_type;
 356 string NextFrameCommand;
 357 void CSQC_SPIDER_HUD();
 358 void CSQC_RAPTOR_HUD();
 359
 360 vector freeze_org, freeze_ang;
 361 entity nightvision_noise, nightvision_noise2;
 362
 363 #define MAX_TIME_DIFF 5
 364 float pickup_crosshair_time, pickup_crosshair_size;
 365 float hit_time, typehit_time;
 366 float nextsound_hit_time, nextsound_typehit_time;
 367 float hitindication_crosshair_time, hitindication_crosshair_size;
 368 float use_nex_chargepool;
 369
 370 float myhealth, myhealth_prev;
 371 float myhealth_flash;
 372
 373 float old_blurradius, old_bluralpha;
 374 float old_sharpen_intensity;
 375
 376 vector myhealth_gentlergb;
 377
 378 float contentavgalpha, liquidalpha_prev;
 379 vector liquidcolor_prev;
 380
 381 float eventchase_current_distance;
 382
 383 vector damage_blurpostprocess, content_blurpostprocess;
 384
 385 float checkfail[16];
 386
 387 float rainbow_last_flicker;
 388 vector rainbow_prev_color;
 389
 390 #define BUTTON_3 4
 391 #define BUTTON_4 8
 392 float cl_notice_run();
 393 float prev_myteam;
 394 void CSQC_UpdateView(float w, float h)
 395 {
 396         entity e;
 397         float fov;
 398         float f, i, j;
 399         vector v;
 400         vector vf_size, vf_min;
 401         float a;
 402
 403         execute_next_frame();
 404
 405         ++framecount;
 406
 407         hud = getstati(STAT_HUD);
 408
 409         if(autocvar__hud_showbinds_reload) // menu can set this one
 410         {
 411                 db_close(binddb);
 412                 binddb = db_create();
 413                 cvar_set("_hud_showbinds_reload", "0");
 414         }
 415
 416         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 417                 view_quality = getproperty(VF_MINFPS_QUALITY);
 418         else
 419                 view_quality = 1;
 420
 421         button_attack2 = (input_buttons & BUTTON_3);
 422         button_zoom = (input_buttons & BUTTON_4);
 423
 424 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 425         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 426         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 427         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 428         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 429         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 430         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 431         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 432
 433         vf_size = getpropertyvec(VF_SIZE);
 434         vf_min = getpropertyvec(VF_MIN);
 435         vid_width = vf_size_x;
 436         vid_height = vf_size_y;
 437
 438         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 439         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 440
 441         WaypointSprite_Load();
 442
 443         CSQCPlayer_SetCamera();
 444
 445 #ifdef COMPAT_XON050_ENGINE
 446         if(spectatee_status)
 447                 myteam = GetPlayerColor(spectatee_status - 1);
 448         else
 449 #endif
 450                 myteam = GetPlayerColor(player_localentnum - 1);
 451
 452         if(myteam != prev_myteam)
 453         {
 454                 myteamcolors = colormapPaletteColor(myteam, 1);
 455                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 456                         hud_panel[i].update_time = time;
 457                 prev_myteam = myteam;
 458         }
 459
 460         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 461
 462         float is_dead = (getstati(STAT_HEALTH) <= 0);
 463
 464         // FIXME do we need this hack?
 465         if(isdemo())
 466         {
 467                 // in demos, input_buttons do not work
 468                 button_zoom = (autocvar__togglezoom == "-");
 469         }
 470         else if(button_zoom
 471                 && autocvar_cl_unpress_zoom_on_death
 472                 && (spectatee_status >= 0)
 473                 && (is_dead || intermission))
 474         {
 475                 // no zoom while dead or in intermission please
 476                 localcmd("-zoom\n");
 477                 button_zoom = FALSE;
 478         }
 479
 480         // event chase camera
 481         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 482         {
 483                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead) || intermission)
 484                 {
 485                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 486                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 487
 488                         // detect maximum viewoffset and use it
 489                         if(autocvar_cl_eventchase_viewoffset)
 490                         {
 491                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 492                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 493                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 494                         }
 495
 496                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 497                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 498                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 499                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 500
 501                         // make the camera smooth back
 502                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 503                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 504                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 505                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 506
 507                         makevectors(view_angles);
 508
 509                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 510                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 511
 512                         // If the boxtrace fails, revert back to line tracing.
 513                         if(trace_startsolid)
 514                         {
 515                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 516                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 517                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 518                         }
 519                         else { setproperty(VF_ORIGIN, trace_endpos); }
 520
 521                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 522                 }
 523                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 524                 {
 525                         cvar_set("chase_active", "0");
 526                         eventchase_current_distance = 0; // start from 0 next time
 527                 }
 528         }
 529         // workaround for camera stuck between player's legs when using chase_active 1
 530         // because the engine stops updating the chase_active camera when the game ends
 531         else if(intermission)
 532         {
 533                 cvar_settemp("chase_active", "-1");
 534                 eventchase_current_distance = 0;
 535         }
 536
 537         // do lockview after event chase camera so that it still applies whenever necessary.
 538         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 539         {
 540                 setproperty(VF_ORIGIN, freeze_org);
 541                 setproperty(VF_ANGLES, freeze_ang);
 542         }
 543         else
 544         {
 545                 freeze_org = getpropertyvec(VF_ORIGIN);
 546                 freeze_ang = getpropertyvec(VF_ANGLES);
 547         }
 548
 549         WarpZone_FixView();
 550         //WarpZone_FixPMove();
 551
 552         // Render the Scene
 553         view_origin = getpropertyvec(VF_ORIGIN);
 554         view_angles = getpropertyvec(VF_ANGLES);
 555         makevectors(view_angles);
 556         view_forward = v_forward;
 557         view_right = v_right;
 558         view_up = v_up;
 559
 560 #ifdef BLURTEST
 561         if(time > blurtest_time0 && time < blurtest_time1)
 562         {
 563                 float r, t;
 564
 565                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 566                 r = t * blurtest_radius;
 567                 f = 1 / pow(t, blurtest_power) - 1;
 568
 569                 cvar_set("r_glsl_postprocess", "1");
 570                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 571         }
 572         else
 573         {
 574                 cvar_set("r_glsl_postprocess", "0");
 575                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 576         }
 577 #endif
 578
 579         TargetMusic_Advance();
 580         Fog_Force();
 581
 582         if(drawtime == 0)
 583                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 584         else
 585                 drawframetime = bound(0.000001, time - drawtime, 1);
 586         drawtime = time;
 587
 588         // watch for gametype changes here...
 589         // in ParseStuffCMD the cmd isn't executed yet :/
 590         // might even be better to add the gametype to TE_CSQC_INIT...?
 591         if(!postinit)
 592                 PostInit();
 593
 594         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 595         {
 596                 if(calledhooks & HOOK_START)
 597                 {
 598                         localcmd("\ncl_hook_gameend\n");
 599                         calledhooks |= HOOK_END;
 600                 }
 601         }
 602
 603         Announcer();
 604
 605         fov = autocvar_fov;
 606         if(fov <= 59.5)
 607         {
 608                 if(!zoomscript_caught)
 609                 {
 610                         localcmd("+button9\n");
 611                         zoomscript_caught = 1;
 612                 }
 613         }
 614         else
 615         {
 616                 if(zoomscript_caught)
 617                 {
 618                         localcmd("-button9\n");
 619                         zoomscript_caught = 0;
 620                 }
 621         }
 622
 623         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 624
 625         // next WANTED weapon (for HUD)
 626         switchweapon = getstati(STAT_SWITCHWEAPON);
 627
 628         // currently switching-to weapon (for crosshair)
 629         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 630
 631         // actually active weapon (for zoom)
 632         activeweapon = getstati(STAT_ACTIVEWEAPON);
 633
 634         f = (serverflags & SERVERFLAG_TEAMPLAY);
 635         if(f != teamplay)
 636         {
 637                 teamplay = f;
 638                 HUD_InitScores();
 639         }
 640
 641         if(last_switchweapon != switchweapon)
 642         {
 643                 weapontime = time;
 644                 last_switchweapon = switchweapon;
 645                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 646                 {
 647                         localcmd("-zoom\n");
 648                         button_zoom = FALSE;
 649                 }
 650                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 651                 {
 652                         localcmd("-fire\n");
 653                         localcmd("-fire2\n");
 654                         button_attack2 = FALSE;
 655                 }
 656         }
 657         if(last_activeweapon != activeweapon)
 658         {
 659                 last_activeweapon = activeweapon;
 660
 661                 e = get_weaponinfo(activeweapon);
 662                 if(e.netname != "")
 663                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 664                 else
 665                         localcmd("\ncl_hook_activeweapon none\n");
 666         }
 667
 668         // ALWAYS Clear Current Scene First
 669         clearscene();
 670 #ifdef WORKAROUND_XON010
 671         if(checkextension("DP_CSQC_ROTATEMOVES"))
 672         {
 673 #endif
 674         setproperty(VF_ORIGIN, view_origin);
 675         setproperty(VF_ANGLES, view_angles);
 676 #ifdef WORKAROUND_XON010
 677         }
 678 #endif
 679
 680         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 681         setproperty(VF_SIZE, vf_size);
 682         setproperty(VF_MIN, vf_min);
 683
 684         // Assign Standard Viewflags
 685         // Draw the World (and sky)
 686         setproperty(VF_DRAWWORLD, 1);
 687
 688         // Set the console size vars
 689         vid_conwidth = autocvar_vid_conwidth;
 690         vid_conheight = autocvar_vid_conheight;
 691         vid_pixelheight = autocvar_vid_pixelheight;
 692
 693         setproperty(VF_FOV, GetCurrentFov(fov));
 694
 695         // Camera for demo playback
 696         if(camera_active)
 697         {
 698                 if(autocvar_camera_enable)
 699                         CSQC_Demo_Camera();
 700                 else
 701                 {
 702                         cvar_set("chase_active", ftos(chase_active_backup));
 703                         cvar_set("cl_demo_mousegrab", "0");
 704                         camera_active = FALSE;
 705                 }
 706         }
 707 #ifdef CAMERATEST
 708         else if(autocvar_camera_enable)
 709 #else
 710         else if(autocvar_camera_enable && isdemo())
 711 #endif
 712         {
 713                 // Enable required Darkplaces cvars
 714                 chase_active_backup = autocvar_chase_active;
 715                 cvar_set("chase_active", "2");
 716                 cvar_set("cl_demo_mousegrab", "1");
 717                 camera_active = TRUE;
 718                 camera_mode = FALSE;
 719         }
 720
 721         // Draw the Crosshair
 722         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 723
 724         // Draw the Engine Status Bar (the default Quake HUD)
 725         setproperty(VF_DRAWENGINESBAR, 0);
 726
 727         // Update the mouse position
 728         /*
 729            mousepos_x = vid_conwidth;
 730            mousepos_y = vid_conheight;
 731            mousepos = mousepos*0.5 + getmousepos();
 732          */
 733
 734         e = self;
 735         for(self = world; (self = nextent(self)); )
 736                 if(self.draw)
 737                         self.draw();
 738         self = e;
 739
 740         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 741         renderscene();
 742
 743         // now switch to 2D drawing mode by calling a 2D drawing function
 744         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 745         // next R_RenderScene call
 746         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 747
 748         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 749         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 750         {
 751                 // apply night vision effect
 752                 vector tc_00, tc_01, tc_10, tc_11;
 753                 vector rgb;
 754                 rgb_x = 0; // fteqcc sucks
 755                 rgb_y = 0; // fteqcc sucks
 756                 rgb_z = 0; // fteqcc sucks
 757
 758                 if(!nightvision_noise)
 759                 {
 760                         nightvision_noise = spawn();
 761                         nightvision_noise.classname = "nightvision_noise";
 762                 }
 763                 if(!nightvision_noise2)
 764                 {
 765                         nightvision_noise2 = spawn();
 766                         nightvision_noise2.classname = "nightvision_noise2";
 767                 }
 768
 769                 // color tint in yellow
 770                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 771
 772                 // draw BG
 773                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 774                 rgb = '1 1 1';
 775                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 776                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 777                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 778                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 779                 tc_11 = tc_01 + tc_10 - tc_00;
 780                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 781                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 782                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 783                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 784                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 785                 R_EndPolygon();
 786
 787                 // draw FG
 788                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 789                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 790                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 791                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 792                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 793                 tc_11 = tc_01 + tc_10 - tc_00;
 794                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 795                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 796                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 797                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 798                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 799                 R_EndPolygon();
 800         }
 801
 802         // Draw the aiming reticle for weapons that use it
 803         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 804         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 805         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 806         if(spectatee_status || is_dead || hud != HUD_NORMAL)
 807                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 808         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 809                 reticle_type = 2; // nex zoom
 810         else if(button_zoom || zoomscript_caught)
 811                 reticle_type = 1; // normal zoom
 812         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 813                 reticle_type = 2; // nex zoom
 814
 815         if(reticle_type && autocvar_cl_reticle)
 816         {
 817                 if(autocvar_cl_reticle_stretch)
 818                 {
 819                         reticle_size_x = vid_conwidth;
 820                         reticle_size_y = vid_conheight;
 821                         reticle_pos_x = 0;
 822                         reticle_pos_y = 0;
 823                 }
 824                 else
 825                 {
 826                         reticle_size_x = max(vid_conwidth, vid_conheight);
 827                         reticle_size_y = max(vid_conwidth, vid_conheight);
 828                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 829                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 830                 }
 831
 832                 f = current_zoomfraction;
 833                 if(zoomscript_caught)
 834                         f = 1;
 835                 if(autocvar_cl_reticle_item_normal)
 836                 {
 837                         if(reticle_type == 1 && f)
 838                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 839                 }
 840                 if(autocvar_cl_reticle_item_nex)
 841                 {
 842                         if(reticle_type == 2 && f)
 843                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 844                 }
 845         }
 846
 847
 848         // improved polyblend
 849         if(autocvar_hud_contents)
 850         {
 851                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 852                 vector liquidcolor;
 853
 854                 switch(pointcontents(view_origin))
 855                 {
 856                         case CONTENT_WATER:
 857                                 liquidalpha = autocvar_hud_contents_water_alpha;
 858                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 859                                 incontent = 1;
 860                                 break;
 861
 862                         case CONTENT_LAVA:
 863                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 864                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 865                                 incontent = 1;
 866                                 break;
 867
 868                         case CONTENT_SLIME:
 869                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 870                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 871                                 incontent = 1;
 872                                 break;
 873
 874                         default:
 875                                 liquidalpha = 0;
 876                                 liquidcolor = '0 0 0';
 877                                 incontent = 0;
 878                                 break;
 879                 }
 880
 881                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 882                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 883                         contentfadetime = autocvar_hud_contents_fadeintime;
 884                         liquidalpha_prev = liquidalpha;
 885                         liquidcolor_prev = liquidcolor;
 886                 }
 887                 else
 888                         contentfadetime = autocvar_hud_contents_fadeouttime;
 889
 890                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 891                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 892
 893                 if(contentavgalpha)
 894                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 895
 896                 if(autocvar_hud_postprocessing)
 897                 {
 898                         if(autocvar_hud_contents_blur && contentavgalpha)
 899                         {
 900                                 content_blurpostprocess_x = 1;
 901                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 902                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 903                         }
 904                         else
 905                         {
 906                                 content_blurpostprocess_x = 0;
 907                                 content_blurpostprocess_y = 0;
 908                                 content_blurpostprocess_z = 0;
 909                         }
 910                 }
 911         }
 912
 913         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 914         {
 915                 splash_size_x = max(vid_conwidth, vid_conheight);
 916                 splash_size_y = max(vid_conwidth, vid_conheight);
 917                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 918                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 919
 920                 float myhealth_flash_temp;
 921                 myhealth = getstati(STAT_HEALTH);
 922
 923                 // fade out
 924                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 925                 // add new damage
 926                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 927
 928                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 929                 pain_threshold = autocvar_hud_damage_pain_threshold;
 930                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 931                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 932
 933                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 934                 {
 935                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 936                 }
 937
 938                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 939
 940                 if(myhealth_prev < 1)
 941                 {
 942                         if(myhealth >= 1)
 943                         {
 944                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 945                                 myhealth_flash_temp = 0;
 946                         }
 947                         else
 948                         {
 949                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 950                         }
 951                 }
 952
 953                 if(spectatee_status == -1 || intermission)
 954                 {
 955                         myhealth_flash = 0; // observing, or match ended
 956                         myhealth_flash_temp = 0;
 957                 }
 958
 959                 myhealth_prev = myhealth;
 960
 961                 // IDEA: change damage color/picture based on player model for robot/alien species?
 962                 // pro: matches model better
 963                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 964                 // maybe different reddish pics?
 965                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 966                 {
 967                         if(autocvar_cl_gentle_damage == 2)
 968                         {
 969                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 970                                 {
 971                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 972                                 }
 973                         }
 974                         else
 975                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 976
 977                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 978                 }
 979                 else
 980                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 981
 982                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 983                 {
 984                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 985                         {
 986                                 damage_blurpostprocess_x = 1;
 987                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 988                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 989                         }
 990                         else
 991                         {
 992                                 damage_blurpostprocess_x = 0;
 993                                 damage_blurpostprocess_y = 0;
 994                                 damage_blurpostprocess_z = 0;
 995                         }
 996                 }
 997         }
 998
 999         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1000         float e2 = (autocvar_hud_powerup != 0);
1001         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1002         {
1003                 // enable or disable rendering types if they are used or not
1004                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1005                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1006
1007                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1008                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1009                 {
1010                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1011                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1012                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1013                         {
1014                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1015                                 old_blurradius = blurradius;
1016                                 old_bluralpha = bluralpha;
1017                         }
1018                 }
1019                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1020                 {
1021                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1022                         old_blurradius = 0;
1023                         old_bluralpha = 0;
1024                 }
1025
1026                 // edge detection postprocess handling done second (used by hud_powerup)
1027                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1028                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1029                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1030
1031                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1032
1033                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1034                 {
1035                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1036                         {
1037                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1038                                 old_sharpen_intensity = sharpen_intensity;
1039                         }
1040                 }
1041                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1042                 {
1043                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1044                         old_sharpen_intensity = 0;
1045                 }
1046
1047                 if(cvar("r_glsl_postprocess") == 0)
1048                         cvar_set("r_glsl_postprocess", "2");
1049         }
1050         else if(cvar("r_glsl_postprocess") == 2)
1051                 cvar_set("r_glsl_postprocess", "0");
1052
1053         if(menu_visible)
1054                 menu_show();
1055
1056         /*if(gametype == MAPINFO_TYPE_CTF)
1057           {
1058           ctf_view();
1059           } else */
1060
1061         // draw 2D entities
1062         e = self;
1063         for(self = world; (self = nextent(self)); )
1064                 if(self.draw2d)
1065                         self.draw2d();
1066         self = e;
1067         Draw_ShowNames_All();
1068
1069         scoreboard_active = HUD_WouldDrawScoreboard();
1070
1071         hit_time = getstatf(STAT_HIT_TIME);
1072         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1073         {
1074                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1075                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1076
1077                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1078         }
1079         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1080         if(typehit_time > nextsound_typehit_time)
1081         {
1082                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1083                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1084
1085                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1086         }
1087
1088         //else
1089         {
1090                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1091                 {
1092                         if(getstati(STAT_FROZEN))
1093                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1094                         if(getstatf(STAT_REVIVE_PROGRESS))
1095                         {
1096                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1097                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1098                         }
1099                 }
1100
1101                 if(autocvar_r_letterbox == 0)
1102                         if(autocvar_viewsize < 120)
1103                                 CSQC_common_hud();
1104
1105                 // crosshair goes VERY LAST
1106                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1107                 {
1108                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1109                                 return;
1110
1111                         string wcross_style;
1112                         float wcross_alpha, wcross_resolution;
1113                         wcross_style = autocvar_crosshair;
1114                         if (wcross_style == "0")
1115                                 return;
1116                         wcross_resolution = autocvar_crosshair_size;
1117                         if (wcross_resolution == 0)
1118                                 return;
1119                         wcross_alpha = autocvar_crosshair_alpha;
1120                         if (wcross_alpha == 0)
1121                                 return;
1122
1123                         // TrueAim check
1124                         float shottype;
1125
1126                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1127                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1128                         wcross_origin_z = 0;
1129                         if(autocvar_crosshair_hittest)
1130                         {
1131                                 vector wcross_oldorigin;
1132                                 wcross_oldorigin = wcross_origin;
1133                                 shottype = TrueAimCheck();
1134                                 if(shottype == SHOTTYPE_HITWORLD)
1135                                 {
1136                                         v = wcross_origin - wcross_oldorigin;
1137                                         v_x /= vid_conwidth;
1138                                         v_y /= vid_conheight;
1139                                         if(vlen(v) > 0.01)
1140                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1141                                 }
1142                                 if(!autocvar_crosshair_hittest_showimpact)
1143                                         wcross_origin = wcross_oldorigin;
1144                         }
1145                         else
1146                                 shottype = SHOTTYPE_HITWORLD;
1147
1148                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1149                         string wcross_wep = "", wcross_name;
1150                         float wcross_scale, wcross_blur;
1151
1152                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1153                         {
1154                                 e = get_weaponinfo(switchingweapon);
1155                                 if (e && e.netname != "")
1156                                 {
1157                                         wcross_wep = e.netname;
1158                                         if(autocvar_crosshair_per_weapon)
1159                                         {
1160                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1161                                                 if (wcross_resolution == 0)
1162                                                         return;
1163                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1164                                                 if (wcross_alpha == 0)
1165                                                         return;
1166
1167                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1168                                                 if(wcross_style == "" || wcross_style == "0")
1169                                                         wcross_style = wcross_wep;
1170                                         }
1171                                 }
1172                         }
1173
1174                         //print(sprintf("crosshair style: %s\n", wcross_style));
1175                         wcross_name = strcat("gfx/crosshair", wcross_style);
1176
1177                         // MAIN CROSSHAIR COLOR DECISION
1178                         switch(autocvar_crosshair_color_special)
1179                         {
1180                                 case 1: // crosshair_color_per_weapon
1181                                 {
1182                                         if(wcross_wep != "")
1183                                         {
1184                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1185                                                 break;
1186                                         }
1187                                         else { goto normalcolor; }
1188                                 }
1189
1190                                 case 2: // crosshair_color_by_health
1191                                 {
1192                                         float x = getstati(STAT_HEALTH);
1193
1194                                         //x = red
1195                                         //y = green
1196                                         //z = blue
1197
1198                                         wcross_color_z = 0;
1199
1200                                         if(x > 200)
1201                                         {
1202                                                 wcross_color_x = 0;
1203                                                 wcross_color_y = 1;
1204                                         }
1205                                         else if(x > 150)
1206                                         {
1207                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1208                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1209                                         }
1210                                         else if(x > 100)
1211                                         {
1212                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1213                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1214                                                 wcross_color_z = 1 - (x-100)*0.02;
1215                                         }
1216                                         else if(x > 50)
1217                                         {
1218                                                 wcross_color_x = 1;
1219                                                 wcross_color_y = 1;
1220                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1221                                         }
1222                                         else if(x > 20)
1223                                         {
1224                                                 wcross_color_x = 1;
1225                                                 wcross_color_y = (x-20)*90/27/100;
1226                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1227                                         }
1228                                         else
1229                                         {
1230                                                 wcross_color_x = 1;
1231                                                 wcross_color_y = 0;
1232                                         }
1233                                         break;
1234                                 }
1235
1236                                 case 3: // crosshair_color_rainbow
1237                                 {
1238                                         if(time >= rainbow_last_flicker)
1239                                         {
1240                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1241                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1242                                         }
1243                                         wcross_color = rainbow_prev_color;
1244                                         break;
1245                                 }
1246                                 :normalcolor
1247                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1248                         }
1249
1250                         if(autocvar_crosshair_effect_scalefade)
1251                         {
1252                                 wcross_scale = wcross_resolution;
1253                                 wcross_resolution = 1;
1254                         }
1255                         else
1256                         {
1257                                 wcross_scale = 1;
1258                         }
1259
1260                         if(autocvar_crosshair_pickup)
1261                         {
1262                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1263
1264                                 if(pickup_crosshair_time < stat_pickup_time)
1265                                 {
1266                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1267                                                 pickup_crosshair_size = 1;
1268
1269                                         pickup_crosshair_time = stat_pickup_time;
1270                                 }
1271
1272                                 if(pickup_crosshair_size > 0)
1273                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1274                                 else
1275                                         pickup_crosshair_size = 0;
1276
1277                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1278                         }
1279
1280                         if(autocvar_crosshair_hitindication)
1281                         {
1282                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1283
1284                                 if(hitindication_crosshair_time < hit_time)
1285                                 {
1286                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1287                                                 hitindication_crosshair_size = 1;
1288
1289                                         hitindication_crosshair_time = hit_time;
1290                                 }
1291
1292                                 if(hitindication_crosshair_size > 0)
1293                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1294                                 else
1295                                         hitindication_crosshair_size = 0;
1296
1297                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1298                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1299                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1300                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1301                         }
1302
1303                         if(shottype == SHOTTYPE_HITENEMY)
1304                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1305                         if(shottype == SHOTTYPE_HITTEAM)
1306                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1307
1308                         f = fabs(autocvar_crosshair_effect_time);
1309                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1310                         {
1311                                 wcross_changedonetime = time + f;
1312                         }
1313                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1314                         {
1315                                 wcross_name_changestarttime = time;
1316                                 wcross_name_changedonetime = time + f;
1317                                 if(wcross_name_goal_prev_prev)
1318                                         strunzone(wcross_name_goal_prev_prev);
1319                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1320                                 wcross_name_goal_prev = strzone(wcross_name);
1321                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1322                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1323                                 wcross_resolution_goal_prev = wcross_resolution;
1324                         }
1325
1326                         wcross_scale_goal_prev = wcross_scale;
1327                         wcross_alpha_goal_prev = wcross_alpha;
1328                         wcross_color_goal_prev = wcross_color;
1329
1330                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1331                         {
1332                                 wcross_blur = 1;
1333                                 wcross_alpha *= 0.75;
1334                         }
1335                         else
1336                                 wcross_blur = 0;
1337                         // *_prev is at time-frametime
1338                         // * is at wcross_changedonetime+f
1339                         // what do we have at time?
1340                         if(time < wcross_changedonetime)
1341                         {
1342                                 f = frametime / (wcross_changedonetime - time + frametime);
1343                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1344                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1345                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1346                         }
1347
1348                         wcross_scale_prev = wcross_scale;
1349                         wcross_alpha_prev = wcross_alpha;
1350                         wcross_color_prev = wcross_color;
1351
1352                         wcross_scale *= 1 - autocvar__menu_alpha;
1353                         wcross_alpha *= 1 - autocvar__menu_alpha;
1354                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1355
1356                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1357                         {
1358                                 // crosshair rings for weapon stats
1359                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1360                                 {
1361                                         // declarations and stats
1362                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1363                                         string ring_image = string_null, ring_inner_image = string_null;
1364                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1365
1366                                         ring_scale = autocvar_crosshair_ring_size;
1367
1368                                         float weapon_clipload, weapon_clipsize;
1369                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1370                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1371
1372                                         float nex_charge, nex_chargepool;
1373                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1374                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1375
1376                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1377                                                 nex_charge_movingavg = nex_charge;
1378
1379
1380                                         // handle the values
1381                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1382                                         {
1383                                                 if (nex_chargepool || use_nex_chargepool) {
1384                                                         use_nex_chargepool = 1;
1385                                                         ring_inner_value = nex_chargepool;
1386                                                 } else {
1387                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1388                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1389                                                 }
1390
1391                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1392                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1393                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1394
1395                                                 // draw the outer ring to show the current charge of the weapon
1396                                                 ring_value = nex_charge;
1397                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1398                                                 ring_rgb = wcross_color;
1399                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1400                                         }
1401                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1402                                         {
1403                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1404                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1405                                                 ring_rgb = wcross_color;
1406                                                 ring_image = "gfx/crosshair_ring.tga";
1407                                         }
1408                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1409                                         {
1410                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1411                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1412                                                 ring_rgb = wcross_color;
1413                                                 ring_image = "gfx/crosshair_ring.tga";
1414                                         }
1415
1416                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1417                                         {
1418                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1419                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1420                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1421                                                 ring_rgb = wcross_color;
1422
1423                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1424                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1425                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1426                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1427                                                 else
1428                                                         ring_image = "gfx/crosshair_ring.tga";
1429                                         }
1430
1431                                         // if in weapon switch animation, fade ring out/in
1432                                         if(autocvar_crosshair_effect_time > 0)
1433                                         {
1434                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1435                                                 if not(f < 1)
1436                                                 {
1437                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1438                                                 }
1439
1440                                                 if(wcross_ring_prev)
1441                                                 {
1442                                                         if(f < 1)
1443                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1444                                                 }
1445                                                 else
1446                                                 {
1447                                                         if(f < 1)
1448                                                                 ring_alpha *= bound(0, f, 1);
1449                                                 }
1450                                         }
1451
1452                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1453                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1454
1455                                         if (ring_value)
1456                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1457                                 }
1458
1459 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1460                                 do \
1461                                 { \
1462                                         if(wcross_blur > 0) \
1463                                         { \
1464                                                 for(i = -2; i <= 2; ++i) \
1465                                                 for(j = -2; j <= 2; ++j) \
1466                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1467                                         } \
1468                                         else \
1469                                         { \
1470                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1471                                         } \
1472                                 } \
1473                                 while(0)
1474
1475 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1476                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1477
1478 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1479                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1480
1481                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1482                                 {
1483                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1484                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1485                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1486                                         f = 1 - f;
1487                                 }
1488                                 else
1489                                 {
1490                                         f = 1;
1491                                 }
1492                                 wcross_name_alpha_goal_prev = f;
1493
1494                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1495                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1496
1497                                 if(autocvar_crosshair_dot)
1498                                 {
1499                                         vector wcross_color_old;
1500                                         wcross_color_old = wcross_color;
1501
1502                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1503                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1504
1505                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1506                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1507                                         wcross_color = wcross_color_old;
1508                                 }
1509                         }
1510                 }
1511                 else
1512                 {
1513                         wcross_scale_prev = 0;
1514                         wcross_alpha_prev = 0;
1515                         wcross_scale_goal_prev = 0;
1516                         wcross_alpha_goal_prev = 0;
1517                         wcross_changedonetime = 0;
1518                         if(wcross_name_goal_prev)
1519                                 strunzone(wcross_name_goal_prev);
1520                         wcross_name_goal_prev = string_null;
1521                         if(wcross_name_goal_prev_prev)
1522                                 strunzone(wcross_name_goal_prev_prev);
1523                         wcross_name_goal_prev_prev = string_null;
1524                         wcross_name_changestarttime = 0;
1525                         wcross_name_changedonetime = 0;
1526                         wcross_name_alpha_goal_prev = 0;
1527                         wcross_name_alpha_goal_prev_prev = 0;
1528                         wcross_resolution_goal_prev = 0;
1529                         wcross_resolution_goal_prev_prev = 0;
1530                 }
1531         }
1532
1533         if(NextFrameCommand)
1534         {
1535                 localcmd("\n", NextFrameCommand, "\n");
1536                 NextFrameCommand = string_null;
1537         }
1538
1539         // we must do this check AFTER a frame was rendered, or it won't work
1540         if(cs_project_is_b0rked == 0)
1541         {
1542                 string w0, h0;
1543                 w0 = ftos(autocvar_vid_conwidth);
1544                 h0 = ftos(autocvar_vid_conheight);
1545                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1546                 //setproperty(VF_FOV, '90 90 0');
1547                 setproperty(VF_ORIGIN, '0 0 0');
1548                 setproperty(VF_ANGLES, '0 0 0');
1549                 setproperty(VF_PERSPECTIVE, 1);
1550                 makevectors('0 0 0');
1551                 vector v1, v2;
1552                 cvar_set("vid_conwidth", "800");
1553                 cvar_set("vid_conheight", "600");
1554                 v1 = cs_project(v_forward);
1555                 cvar_set("vid_conwidth", "640");
1556                 cvar_set("vid_conheight", "480");
1557                 v2 = cs_project(v_forward);
1558                 if(v1 == v2)
1559                         cs_project_is_b0rked = 1;
1560                 else
1561                         cs_project_is_b0rked = -1;
1562                 cvar_set("vid_conwidth", w0);
1563                 cvar_set("vid_conheight", h0);
1564         }
1565
1566         if(autocvar__hud_configure)
1567                 HUD_Panel_Mouse();
1568
1569     if(hud && !intermission)
1570     {
1571         if(hud == HUD_SPIDERBOT)
1572             CSQC_SPIDER_HUD();
1573         else if(hud == HUD_WAKIZASHI)
1574             CSQC_WAKIZASHI_HUD();
1575         else if(hud == HUD_RAPTOR)
1576             CSQC_RAPTOR_HUD();
1577         else if(hud == HUD_BUMBLEBEE)
1578             CSQC_BUMBLE_HUD();
1579         else if(hud == HUD_BUMBLEBEE_GUN)
1580             CSQC_BUMBLE_GUN_HUD();
1581     }
1582
1583         cl_notice_run();
1584
1585         // let's reset the view back to normal for the end
1586         setproperty(VF_MIN, '0 0 0');
1587         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1588 }
1589
1590
1591 void CSQC_common_hud(void)
1592 {
1593         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1594                 Accuracy_LoadLevels();
1595
1596     HUD_Main(); // always run these functions for alpha checks
1597     HUD_DrawScoreboard();
1598
1599     if (scoreboard_active) // scoreboard/accuracy
1600         HUD_Reset();
1601     else if (intermission == 2) // map voting screen
1602     {
1603         HUD_FinaleOverlay();
1604         HUD_Reset();
1605     }
1606         /*
1607         switch(hud)
1608         {
1609                 case HUD_SPIDERBOT:
1610                         CSQC_SPIDER_HUD();
1611                         break;
1612
1613                 case HUD_WAKIZASHI:
1614                         CSQC_WAKIZASHI_HUD();
1615                         break;
1616
1617         case HUD_BUMBLEBEE:
1618             CSQC_BUMBLE_HUD();
1619             break;
1620         }
1621         */
1622 }
1623
1624
1625 // following vectors must be global to allow seamless switching between camera modes
1626 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1627 void CSQC_Demo_Camera()
1628 {
1629         float speed, attenuation, dimensions;
1630         vector tmp, delta;
1631
1632         if( autocvar_camera_reset || !camera_mode )
1633         {
1634                 camera_offset = '0 0 0';
1635                 current_angles = '0 0 0';
1636                 camera_direction = '0 0 0';
1637                 camera_offset_z += 30;
1638                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1639                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1640                 current_origin = view_origin;
1641                 current_camera_offset  = camera_offset;
1642                 cvar_set("camera_reset", "0");
1643                 camera_mode = CAMERA_CHASE;
1644         }
1645
1646         // Camera angles
1647         if( camera_roll )
1648                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1649
1650         if(autocvar_camera_look_player)
1651         {
1652                 vector dir;
1653                 float n;
1654
1655                 dir = normalize(view_origin - current_position);
1656                 n = mouse_angles_z;
1657                 mouse_angles = vectoangles(dir);
1658                 mouse_angles_x = mouse_angles_x * -1;
1659                 mouse_angles_z = n;
1660         }
1661         else
1662         {
1663                 tmp = getmousepos() * 0.1;
1664                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1665                 {
1666                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1667                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1668                 }
1669         }
1670
1671         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1672         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1673         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1674         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1675
1676         // Fix difference when angles don't have the same sign
1677         delta = '0 0 0';
1678         if(mouse_angles_y < -60 && current_angles_y > 60)
1679                 delta = '0 360 0';
1680         if(mouse_angles_y > 60 && current_angles_y < -60)
1681                 delta = '0 -360 0';
1682
1683         if(autocvar_camera_look_player)
1684                 attenuation = autocvar_camera_look_attenuation;
1685         else
1686                 attenuation = autocvar_camera_speed_attenuation;
1687
1688         attenuation = 1 / max(1, attenuation);
1689         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1690
1691         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1692         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1693         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1694         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1695
1696         // Camera position
1697         tmp = '0 0 0';
1698         dimensions = 0;
1699
1700         if( camera_direction_x )
1701         {
1702                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1703                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1704                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1705                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1706                 ++dimensions;
1707         }
1708
1709         if( camera_direction_y )
1710         {
1711                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1712                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1713                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1714                 ++dimensions;
1715         }
1716
1717         if( camera_direction_z )
1718         {
1719                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1720                 ++dimensions;
1721         }
1722
1723         if(autocvar_camera_free)
1724                 speed = autocvar_camera_speed_free;
1725         else
1726                 speed = autocvar_camera_speed_chase;
1727
1728         if(dimensions)
1729         {
1730                 speed = speed * sqrt(1 / dimensions);
1731                 camera_offset += tmp * speed;
1732         }
1733
1734         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1735
1736         // Camera modes
1737         if( autocvar_camera_free )
1738         {
1739                 if ( camera_mode == CAMERA_CHASE )
1740                 {
1741                         current_camera_offset = current_origin + current_camera_offset;
1742                         camera_offset = current_origin + camera_offset;
1743                 }
1744
1745                 camera_mode = CAMERA_FREE;
1746                 current_position = current_camera_offset;
1747         }
1748         else
1749         {
1750                 if ( camera_mode == CAMERA_FREE )
1751                 {
1752                         current_origin = view_origin;
1753                         camera_offset = camera_offset - current_origin;
1754                         current_camera_offset = current_camera_offset - current_origin;
1755                 }
1756
1757                 camera_mode = CAMERA_CHASE;
1758
1759                 if(autocvar_camera_chase_smoothly)
1760                         current_origin += (view_origin - current_origin) * attenuation;
1761                 else
1762                         current_origin = view_origin;
1763
1764                 current_position = current_origin + current_camera_offset;
1765         }
1766
1767         setproperty(VF_ANGLES, current_angles);
1768         setproperty(VF_ORIGIN, current_position);
1769 }