qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 void Porto_Init()
  82 {
  83         porto = spawn();
  84         porto.classname = "porto";
  85         porto.draw = Porto_Draw;
  86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  87 }
  88
  89 float drawtime;
  90 float avgspeed;
  91 vector GetCurrentFov(float fov)
  92 {
  93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  94         float velocityzoom, curspeed;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102                 if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir)
 122                 zoomin_effect = 0;
 123
 124         if(zoomin_effect || camera_active)
 125         {
 126                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 127         }
 128         else
 129         {
 130                 if(zoomspeed < 0) // instant zoom
 131                 {
 132                         if(zoomdir)
 133                                 current_viewzoom = 1 / zoomfactor;
 134                         else
 135                                 current_viewzoom = 1;
 136                 }
 137                 else
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 141                         else
 142                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 143                 }
 144         }
 145
 146         if(almost_equals(current_viewzoom, 1))
 147                 current_zoomfraction = 0;
 148         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 149                 current_zoomfraction = 1;
 150         else
 151                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 152
 153         if(zoomsensitivity < 1)
 154                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 155         else
 156                 setsensitivityscale(1);
 157
 158         makevectors(view_angles);
 159
 160         if(autocvar_cl_velocityzoom)
 161         {
 162                 switch(autocvar_cl_velocityzoom_type)
 163                 {
 164                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 165                         case 2: curspeed = (v_forward * pmove_vel); break;
 166                         case 1: default: curspeed = vlen(pmove_vel); break;
 167                 }
 168
 169                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 170                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 171                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 172
 173                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 174         }
 175         else
 176                 velocityzoom = 1;
 177
 178         float frustumx, frustumy, fovx, fovy;
 179         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 180         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 181         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 182         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 183
 184         return '1 0 0' * fovx + '0 1 0' * fovy;
 185 }
 186
 187 // this function must match W_SetupShot!
 188 float zoomscript_caught;
 189
 190 vector wcross_origin;
 191 float wcross_scale_prev, wcross_alpha_prev;
 192 vector wcross_color_prev;
 193 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 194 vector wcross_color_goal_prev;
 195 float wcross_changedonetime;
 196
 197 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 198 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 199 float wcross_name_changestarttime, wcross_name_changedonetime;
 200 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 201 entity trueaim;
 202 entity trueaim_rifle;
 203
 204 #define SHOTTYPE_HITTEAM 1
 205 #define SHOTTYPE_HITOBSTRUCTION 2
 206 #define SHOTTYPE_HITWORLD 3
 207 #define SHOTTYPE_HITENEMY 4
 208
 209 void TrueAim_Init()
 210 {
 211         trueaim = spawn();
 212         trueaim.classname = "trueaim";
 213         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 214         trueaim_rifle = spawn();
 215         trueaim_rifle.classname = "trueaim_rifle";
 216         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 217 }
 218
 219 float EnemyHitCheck()
 220 {
 221         float t;
 222         wcross_origin = project_3d_to_2d(trace_endpos);
 223         wcross_origin_z = 0;
 224         if(trace_networkentity < 1)
 225                 return SHOTTYPE_HITWORLD;
 226         if(trace_networkentity > maxclients)
 227                 return SHOTTYPE_HITWORLD;
 228         t = GetPlayerColor(trace_networkentity - 1);
 229         if(teamplay)
 230                 if(t == myteam)
 231                         return SHOTTYPE_HITTEAM;
 232         if(t == COLOR_SPECTATOR)
 233                 return SHOTTYPE_HITWORLD;
 234         return SHOTTYPE_HITENEMY;
 235 }
 236
 237 float TrueAimCheck()
 238 {
 239         float nudge = 1; // added to traceline target and subtracted from result
 240         vector vecs, trueaimpoint, w_shotorg;
 241         vector mi, ma, dv;
 242         float shottype;
 243         entity ta;
 244         float mv;
 245
 246         mi = ma = '0 0 0';
 247         ta = trueaim;
 248         mv = MOVE_NOMONSTERS;
 249
 250         switch(activeweapon)
 251         {
 252                 case WEP_TUBA: // no aim
 253                 case WEP_PORTO: // shoots from eye
 254                 case WEP_HOOK: // no trueaim
 255                 case WEP_GRENADE_LAUNCHER: // toss curve
 256                         return SHOTTYPE_HITWORLD;
 257                 case WEP_NEX:
 258                 case WEP_MINSTANEX:
 259                         mv = MOVE_NORMAL;
 260                         break;
 261                 case WEP_RIFLE:
 262                         ta = trueaim_rifle;
 263                         mv = MOVE_NORMAL;
 264                         if(zoomscript_caught)
 265                         {
 266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 267                                 return EnemyHitCheck();
 268                         }
 269                         break;
 270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 271                         mi = '-3 -3 -3';
 272                         ma = '3 3 3';
 273                         break;
 274                 case WEP_FIREBALL: // projectile has a size!
 275                         mi = '-16 -16 -16';
 276                         ma = '16 16 16';
 277                         break;
 278                 case WEP_SEEKER: // projectile has a size!
 279                         mi = '-2 -2 -2';
 280                         ma = '2 2 2';
 281                         break;
 282                 case WEP_ELECTRO: // projectile has a size!
 283                         mi = '0 0 -3';
 284                         ma = '0 0 -3';
 285                         break;
 286         }
 287
 288         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 289
 290         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 291         trueaimpoint = trace_endpos;
 292
 293         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 294                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 295
 296         if(vecs_x > 0)
 297                 vecs_y = -vecs_y;
 298         else
 299                 vecs = '0 0 0';
 300
 301         dv = view_right * vecs_y + view_up * vecs_z;
 302         w_shotorg = view_origin + dv;
 303
 304         // now move the vecs forward as much as requested if possible
 305         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 306         w_shotorg = trace_endpos - view_forward * nudge;
 307
 308         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 309         shottype = EnemyHitCheck();
 310         if(shottype != SHOTTYPE_HITWORLD)
 311                 return shottype;
 312
 313 #if 0
 314         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 315         // or rather, I know why, but see no fix
 316         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 317                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 318                 return SHOTTYPE_HITOBSTRUCTION;
 319 #endif
 320
 321         return SHOTTYPE_HITWORLD;
 322 }
 323
 324 void CSQC_common_hud(void);
 325
 326 void PostInit(void);
 327 void CSQC_Demo_Camera();
 328 float HUD_WouldDrawScoreboard();
 329 float camera_mode;
 330 float CAMERA_FREE = 1;
 331 float CAMERA_CHASE = 2;
 332 float reticle_type;
 333 string NextFrameCommand;
 334 void CSQC_SPIDER_HUD();
 335 void CSQC_RAPTOR_HUD();
 336
 337 vector freeze_org, freeze_ang;
 338 entity nightvision_noise, nightvision_noise2;
 339
 340 #define MAX_TIME_DIFF 5
 341 float pickup_crosshair_time, pickup_crosshair_size;
 342 float hit_time, typehit_time;
 343 float nextsound_hit_time, nextsound_typehit_time;
 344 float hitindication_crosshair_time, hitindication_crosshair_size;
 345 float use_nex_chargepool;
 346
 347 float myhealth, myhealth_prev;
 348 float myhealth_flash;
 349
 350 float old_blurradius, old_bluralpha;
 351 float old_sharpen_intensity;
 352
 353 vector myhealth_gentlergb;
 354
 355 float contentavgalpha, liquidalpha_prev;
 356 vector liquidcolor_prev;
 357
 358 float eventchase_current_distance;
 359
 360 vector damage_blurpostprocess, content_blurpostprocess;
 361
 362 float checkfail[16];
 363
 364 #define BUTTON_3 4
 365 #define BUTTON_4 8
 366 void CSQC_UpdateView(float w, float h)
 367 {
 368         entity e;
 369         float fov;
 370         float f, i, j;
 371         vector v;
 372         vector vf_size, vf_min;
 373         float a;
 374
 375         hud = getstati(STAT_HUD);
 376
 377         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 378                 view_quality = getproperty(VF_MINFPS_QUALITY);
 379         else
 380                 view_quality = 1;
 381
 382         button_attack2 = (input_buttons & BUTTON_3);
 383         button_zoom = (input_buttons & BUTTON_4);
 384
 385         // FIXME do we need this hack?
 386         if(isdemo())
 387         {
 388                 // in demos, input_buttons do not work
 389                 button_zoom = (autocvar__togglezoom == "-");
 390         }
 391
 392 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 393         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 394         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 395         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 396         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 397         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 398         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 399         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 400
 401         vf_size = getpropertyvec(VF_SIZE);
 402         vf_min = getpropertyvec(VF_MIN);
 403         vid_width = vf_size_x;
 404         vid_height = vf_size_y;
 405
 406         vector reticle_pos, reticle_size;
 407         vector splash_pos, splash_size;
 408
 409         WaypointSprite_Load();
 410
 411         CSQCPlayer_SetCamera();
 412
 413 #ifdef COMPAT_XON050_ENGINE
 414         if(spectatee_status)
 415                 myteam = GetPlayerColor(spectatee_status - 1);
 416         else
 417 #endif
 418                 myteam = GetPlayerColor(player_localentnum - 1);
 419
 420         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 421
 422         // event chase camera
 423         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 424         {
 425                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 426                 {
 427                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 428                         vector current_view_origin = getpropertyvec(VF_ORIGIN);
 429
 430                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 431                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 432                         if(!autocvar_chase_active)
 433                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 434
 435                         // make the camera smooth back
 436                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 437                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 438                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 439                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 440
 441                         vector eventchase_target_origin;
 442                         makevectors(view_angles);
 443                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 444                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 445                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 446                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 447                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 448                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 449                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 450
 451                         setproperty(VF_ORIGIN, trace_endpos);
 452                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 453                 }
 454                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 455                 {
 456                         cvar_set("chase_active", "0");
 457                         eventchase_current_distance = 0; // start from 0 next time
 458                 }
 459         }
 460
 461         // do lockview after event chase camera so that it still applies whenever necessary.
 462         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 463         {
 464                 setproperty(VF_ORIGIN, freeze_org);
 465                 setproperty(VF_ANGLES, freeze_ang);
 466         }
 467         else
 468         {
 469                 freeze_org = getpropertyvec(VF_ORIGIN);
 470                 freeze_ang = getpropertyvec(VF_ANGLES);
 471         }
 472
 473         WarpZone_FixView();
 474         //WarpZone_FixPMove();
 475
 476         // Render the Scene
 477         view_origin = getpropertyvec(VF_ORIGIN);
 478         view_angles = getpropertyvec(VF_ANGLES);
 479         makevectors(view_angles);
 480         view_forward = v_forward;
 481         view_right = v_right;
 482         view_up = v_up;
 483
 484 #ifdef BLURTEST
 485         if(time > blurtest_time0 && time < blurtest_time1)
 486         {
 487                 float r, t;
 488
 489                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 490                 r = t * blurtest_radius;
 491                 f = 1 / pow(t, blurtest_power) - 1;
 492
 493                 cvar_set("r_glsl_postprocess", "1");
 494                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 495         }
 496         else
 497         {
 498                 cvar_set("r_glsl_postprocess", "0");
 499                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 500         }
 501 #endif
 502
 503         TargetMusic_Advance();
 504         Fog_Force();
 505
 506         if(drawtime == 0)
 507                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 508         else
 509                 drawframetime = bound(0.000001, time - drawtime, 1);
 510         drawtime = time;
 511
 512         // watch for gametype changes here...
 513         // in ParseStuffCMD the cmd isn't executed yet :/
 514         // might even be better to add the gametype to TE_CSQC_INIT...?
 515         if(!postinit)
 516                 PostInit();
 517
 518         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 519         {
 520                 if(calledhooks & HOOK_START)
 521                 {
 522                         localcmd("\ncl_hook_gameend\n");
 523                         calledhooks |= HOOK_END;
 524                 }
 525         }
 526
 527   Announcer();
 528
 529         fov = autocvar_fov;
 530         if(fov <= 59.5)
 531         {
 532                 if(!zoomscript_caught)
 533                 {
 534                         localcmd("+button9\n");
 535                         zoomscript_caught = 1;
 536                 }
 537         }
 538         else
 539         {
 540                 if(zoomscript_caught)
 541                 {
 542                         localcmd("-button9\n");
 543                         zoomscript_caught = 0;
 544                 }
 545         }
 546
 547         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 548
 549         // next WANTED weapon (for HUD)
 550         switchweapon = getstati(STAT_SWITCHWEAPON);
 551
 552         // currently switching-to weapon (for crosshair)
 553         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 554
 555         // actually active weapon (for zoom)
 556         activeweapon = getstati(STAT_ACTIVEWEAPON);
 557
 558         f = (serverflags & SERVERFLAG_TEAMPLAY);
 559         if(f != teamplay)
 560         {
 561                 teamplay = f;
 562                 HUD_InitScores();
 563         }
 564
 565         if(last_switchweapon != switchweapon) {
 566                 weapontime = time;
 567                 last_switchweapon = switchweapon;
 568         }
 569         if(last_activeweapon != activeweapon) {
 570                 last_activeweapon = activeweapon;
 571
 572                 e = get_weaponinfo(activeweapon);
 573                 if(e.netname != "")
 574                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 575                 else
 576                         localcmd("\ncl_hook_activeweapon none\n");
 577         }
 578
 579         // ALWAYS Clear Current Scene First
 580         clearscene();
 581 #ifdef WORKAROUND_XON010
 582         if(checkextension("DP_CSQC_ROTATEMOVES"))
 583         {
 584 #endif
 585         setproperty(VF_ORIGIN, view_origin);
 586         setproperty(VF_ANGLES, view_angles);
 587 #ifdef WORKAROUND_XON010
 588         }
 589 #endif
 590
 591         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 592         setproperty(VF_SIZE, vf_size);
 593         setproperty(VF_MIN, vf_min);
 594
 595         // Assign Standard Viewflags
 596         // Draw the World (and sky)
 597         setproperty(VF_DRAWWORLD, 1);
 598
 599         // Set the console size vars
 600         vid_conwidth = autocvar_vid_conwidth;
 601         vid_conheight = autocvar_vid_conheight;
 602         vid_pixelheight = autocvar_vid_pixelheight;
 603
 604         setproperty(VF_FOV, GetCurrentFov(fov));
 605
 606         // Camera for demo playback
 607         if(camera_active)
 608         {
 609                 if(autocvar_camera_enable)
 610                         CSQC_Demo_Camera();
 611                 else
 612                 {
 613                         cvar_set("chase_active", ftos(chase_active_backup));
 614                         cvar_set("cl_demo_mousegrab", "0");
 615                         camera_active = FALSE;
 616                 }
 617         }
 618 #ifdef CAMERATEST
 619         else if(autocvar_camera_enable)
 620 #else
 621         else if(autocvar_camera_enable && isdemo())
 622 #endif
 623         {
 624                 // Enable required Darkplaces cvars
 625                 chase_active_backup = autocvar_chase_active;
 626                 cvar_set("chase_active", "2");
 627                 cvar_set("cl_demo_mousegrab", "1");
 628                 camera_active = TRUE;
 629                 camera_mode = FALSE;
 630         }
 631
 632         // Draw the Crosshair
 633         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 634
 635         // Draw the Engine Status Bar (the default Quake HUD)
 636         setproperty(VF_DRAWENGINESBAR, 0);
 637
 638         // Update the mouse position
 639         /*
 640            mousepos_x = vid_conwidth;
 641            mousepos_y = vid_conheight;
 642            mousepos = mousepos*0.5 + getmousepos();
 643          */
 644
 645         e = self;
 646         for(self = world; (self = nextent(self)); )
 647                 if(self.draw)
 648                         self.draw();
 649         self = e;
 650
 651         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 652         renderscene();
 653
 654         // now switch to 2D drawing mode by calling a 2D drawing function
 655         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 656         // next R_RenderScene call
 657         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 658
 659         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 660         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 661         {
 662                 // apply night vision effect
 663                 vector tc_00, tc_01, tc_10, tc_11;
 664                 vector rgb;
 665                 rgb_x = 0; // fteqcc sucks
 666                 rgb_y = 0; // fteqcc sucks
 667                 rgb_z = 0; // fteqcc sucks
 668
 669                 if(!nightvision_noise)
 670                 {
 671                         nightvision_noise = spawn();
 672                         nightvision_noise.classname = "nightvision_noise";
 673                 }
 674                 if(!nightvision_noise2)
 675                 {
 676                         nightvision_noise2 = spawn();
 677                         nightvision_noise2.classname = "nightvision_noise2";
 678                 }
 679
 680                 // color tint in yellow
 681                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 682
 683                 // draw BG
 684                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 685                 rgb = '1 1 1';
 686                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 687                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 688                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 689                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 690                 tc_11 = tc_01 + tc_10 - tc_00;
 691                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 692                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 693                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 694                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 695                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 696                 R_EndPolygon();
 697
 698                 // draw FG
 699                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 700                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 701                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 702                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 703                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 704                 tc_11 = tc_01 + tc_10 - tc_00;
 705                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 706                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 707                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 708                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 709                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 710                 R_EndPolygon();
 711         }
 712
 713         // Draw the aiming reticle for weapons that use it
 714         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 715         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 716         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 717         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 718                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 719         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 720                 reticle_type = 2; // nex zoom
 721         else if(button_zoom || zoomscript_caught)
 722                 reticle_type = 1; // normal zoom
 723         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 724                 reticle_type = 2; // nex zoom
 725
 726         if(reticle_type && autocvar_cl_reticle)
 727         {
 728                 if(autocvar_cl_reticle_stretch)
 729                 {
 730                         reticle_size_x = vid_conwidth;
 731                         reticle_size_y = vid_conheight;
 732                         reticle_pos_x = 0;
 733                         reticle_pos_y = 0;
 734                 }
 735                 else
 736                 {
 737                         reticle_size_x = max(vid_conwidth, vid_conheight);
 738                         reticle_size_y = max(vid_conwidth, vid_conheight);
 739                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 740                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 741                 }
 742
 743                 f = current_zoomfraction;
 744                 if(zoomscript_caught)
 745                         f = 1;
 746                 if(autocvar_cl_reticle_item_normal)
 747                 {
 748                         if(reticle_type == 1 && f)
 749                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 750                 }
 751                 if(autocvar_cl_reticle_item_nex)
 752                 {
 753                         if(reticle_type == 2 && f)
 754                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 755                 }
 756         }
 757
 758
 759         // improved polyblend
 760         vector rgb;
 761         if(autocvar_hud_contents)
 762         {
 763                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 764                 vector liquidcolor;
 765
 766                 switch(pointcontents(view_origin))
 767                 {
 768                         case CONTENT_WATER:
 769                                 liquidalpha = autocvar_hud_contents_water_alpha;
 770                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 771                                 incontent = 1;
 772                                 break;
 773
 774                         case CONTENT_LAVA:
 775                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 776                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 777                                 incontent = 1;
 778                                 break;
 779
 780                         case CONTENT_SLIME:
 781                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 782                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 783                                 incontent = 1;
 784                                 break;
 785
 786                         default:
 787                                 liquidalpha = 0;
 788                                 liquidcolor = '0 0 0';
 789                                 incontent = 0;
 790                                 break;
 791                 }
 792
 793                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 794                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 795                         contentfadetime = autocvar_hud_contents_fadeintime;
 796                         liquidalpha_prev = liquidalpha;
 797                         liquidcolor_prev = liquidcolor;
 798                 }
 799                 else
 800                         contentfadetime = autocvar_hud_contents_fadeouttime;
 801
 802                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 803                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 804
 805                 if(contentavgalpha)
 806                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 807
 808                 if(autocvar_hud_postprocessing)
 809                 {
 810                         if(autocvar_hud_contents_blur && contentavgalpha)
 811                         {
 812                                 content_blurpostprocess_x = 1;
 813                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 814                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 815                         }
 816                         else
 817                         {
 818                                 content_blurpostprocess_x = 0;
 819                                 content_blurpostprocess_y = 0;
 820                                 content_blurpostprocess_z = 0;
 821                         }
 822                 }
 823         }
 824
 825         if(autocvar_hud_damage)
 826         {
 827                 splash_size_x = max(vid_conwidth, vid_conheight);
 828                 splash_size_y = max(vid_conwidth, vid_conheight);
 829                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 830                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 831
 832                 float myhealth_flash_temp;
 833                 myhealth = getstati(STAT_HEALTH);
 834
 835                 // fade out
 836                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 837                 // add new damage
 838                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 839
 840                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 841                 pain_threshold = autocvar_hud_damage_pain_threshold;
 842                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 843                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 844
 845                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 846                 {
 847                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 848                 }
 849
 850                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 851
 852                 if(myhealth_prev < 1)
 853                 {
 854                         if(myhealth >= 1)
 855                         {
 856                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 857                                 myhealth_flash_temp = 0;
 858                         }
 859                         else
 860                         {
 861                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 862                         }
 863                 }
 864
 865                 if(spectatee_status == -1 || intermission)
 866                 {
 867                         myhealth_flash = 0; // observing, or match ended
 868                         myhealth_flash_temp = 0;
 869                 }
 870
 871                 myhealth_prev = myhealth;
 872
 873                 // IDEA: change damage color/picture based on player model for robot/alien species?
 874                 // pro: matches model better
 875                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 876                 // maybe different reddish pics?
 877                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 878                 {
 879                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 880                         {
 881                                 if(autocvar_cl_gentle_damage == 2)
 882                                 {
 883                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 884                                         {
 885                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 886                                         }
 887                                 }
 888                                 else
 889                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 890
 891                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 892                         }
 893                         else
 894                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 895                 }
 896
 897                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 898                 {
 899                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 900                         {
 901                                 damage_blurpostprocess_x = 1;
 902                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 903                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 904                         }
 905                         else
 906                         {
 907                                 damage_blurpostprocess_x = 0;
 908                                 damage_blurpostprocess_y = 0;
 909                                 damage_blurpostprocess_z = 0;
 910                         }
 911                 }
 912         }
 913
 914         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 915         {
 916                 // enable or disable rendering types if they are used or not
 917                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 918                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 919
 920                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 921                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 922                 {
 923                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 924                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 925                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 926                         {
 927                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 928                                 old_blurradius = blurradius;
 929                                 old_bluralpha = bluralpha;
 930                         }
 931                 }
 932                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 933                 {
 934                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 935                         old_blurradius = 0;
 936                         old_bluralpha = 0;
 937                 }
 938
 939                 // edge detection postprocess handling done second (used by hud_powerup)
 940                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 941                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 942                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 943
 944                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 945
 946                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 947                 {
 948                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 949                         {
 950                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 951                                 old_sharpen_intensity = sharpen_intensity;
 952                         }
 953                 }
 954                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 955                 {
 956                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 957                         old_sharpen_intensity = 0;
 958                 }
 959         }
 960
 961         if(menu_visible)
 962                 menu_show();
 963
 964         /*if(gametype == GAME_CTF)
 965           {
 966           ctf_view();
 967           } else */
 968
 969         // draw 2D entities
 970         e = self;
 971         for(self = world; (self = nextent(self)); )
 972                 if(self.draw2d)
 973                         self.draw2d();
 974         self = e;
 975         Draw_ShowNames_All();
 976
 977         scoreboard_active = HUD_WouldDrawScoreboard();
 978
 979         hit_time = getstatf(STAT_HIT_TIME);
 980         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 981         {
 982                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 983                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 984
 985                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 986         }
 987         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 988         if(typehit_time > nextsound_typehit_time)
 989         {
 990                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 991                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 992
 993                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 994         }
 995
 996         //else
 997         {
 998                 if(gametype == GAME_FREEZETAG)
 999                 {
1000                         if(getstati(STAT_FROZEN))
1001                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1002                         if(getstatf(STAT_REVIVE_PROGRESS))
1003                         {
1004                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1005                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1006                         }
1007                 }
1008
1009                 if(autocvar_r_letterbox == 0)
1010                         if(autocvar_viewsize < 120)
1011                                 CSQC_common_hud();
1012
1013                 // crosshair goes VERY LAST
1014                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
1015                         string wcross_style;
1016                         float wcross_alpha, wcross_resolution;
1017                         wcross_style = autocvar_crosshair;
1018                         if (wcross_style == "0")
1019                                 return;
1020                         wcross_resolution = autocvar_crosshair_size;
1021                         if (wcross_resolution == 0)
1022                                 return;
1023                         wcross_alpha = autocvar_crosshair_alpha;
1024                         if (wcross_alpha == 0)
1025                                 return;
1026
1027                         // TrueAim check
1028                         float shottype;
1029
1030                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1031                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1032                         wcross_origin_z = 0;
1033                         if(autocvar_crosshair_hittest)
1034                         {
1035                                 vector wcross_oldorigin;
1036                                 wcross_oldorigin = wcross_origin;
1037                                 shottype = TrueAimCheck();
1038                                 if(shottype == SHOTTYPE_HITWORLD)
1039                                 {
1040                                         v = wcross_origin - wcross_oldorigin;
1041                                         v_x /= vid_conwidth;
1042                                         v_y /= vid_conheight;
1043                                         if(vlen(v) > 0.01)
1044                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1045                                 }
1046                                 if(!autocvar_crosshair_hittest_showimpact)
1047                                         wcross_origin = wcross_oldorigin;
1048                         }
1049                         else
1050                                 shottype = SHOTTYPE_HITWORLD;
1051
1052                         vector wcross_color, wcross_size;
1053                         string wcross_wep, wcross_name;
1054                         float wcross_scale, wcross_blur;
1055
1056                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1057                                 e = get_weaponinfo(switchingweapon);
1058                                 if (e && e.netname != "")
1059                                 {
1060                                         wcross_wep = e.netname;
1061                                         if(autocvar_crosshair_per_weapon)
1062                                         {
1063                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1064                                                 if (wcross_resolution == 0)
1065                                                         return;
1066                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1067                                                 if (wcross_alpha == 0)
1068                                                         return;
1069
1070                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1071                                                 if(wcross_style == "" || wcross_style == "0")
1072                                                         wcross_style = wcross_wep;
1073                                         }
1074                                 }
1075                         }
1076                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1077                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1078                         else if(autocvar_crosshair_color_by_health)
1079                         {
1080                                 float x = getstati(STAT_HEALTH);
1081
1082                                 //x = red
1083                                 //y = green
1084                                 //z = blue
1085
1086                                 wcross_color_z = 0;
1087
1088                                 if(x > 200)
1089                                 {
1090                                         wcross_color_x = 0;
1091                                         wcross_color_y = 1;
1092                                 }
1093                                 else if(x > 150)
1094                                 {
1095                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1096                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1097                                 }
1098                                 else if(x > 100)
1099                                 {
1100                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1101                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1102                                         wcross_color_z = 1 - (x-100)*0.02;
1103                                 }
1104                                 else if(x > 50)
1105                                 {
1106                                         wcross_color_x = 1;
1107                                         wcross_color_y = 1;
1108                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1109                                 }
1110                                 else if(x > 20)
1111                                 {
1112                                         wcross_color_x = 1;
1113                                         wcross_color_y = (x-20)*90/27/100;
1114                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1115                                 }
1116                                 else
1117                                 {
1118                                         wcross_color_x = 1;
1119                                         wcross_color_y = 0;
1120                                 }
1121                         }
1122                         else
1123                                 wcross_color = stov(autocvar_crosshair_color);
1124
1125                         wcross_name = strcat("gfx/crosshair", wcross_style);
1126
1127                         if(autocvar_crosshair_effect_scalefade)
1128                         {
1129                                 wcross_scale = wcross_resolution;
1130                                 wcross_resolution = 1;
1131                         }
1132                         else
1133                         {
1134                                 wcross_scale = 1;
1135                         }
1136
1137                         if(autocvar_crosshair_pickup)
1138                         {
1139                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1140
1141                                 if(pickup_crosshair_time < stat_pickup_time)
1142                                 {
1143                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1144                                                 pickup_crosshair_size = 1;
1145
1146                                         pickup_crosshair_time = stat_pickup_time;
1147                                 }
1148
1149                                 if(pickup_crosshair_size > 0)
1150                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1151                                 else
1152                                         pickup_crosshair_size = 0;
1153
1154                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1155                         }
1156
1157                         if(autocvar_crosshair_hitindication)
1158                         {
1159                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1160                                 if(hitindication_crosshair_time < hit_time)
1161                                 {
1162                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1163                                                 hitindication_crosshair_size = 1;
1164
1165                                         hitindication_crosshair_time = hit_time;
1166                                 }
1167
1168                                 if(hitindication_crosshair_size > 0)
1169                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1170                                 else
1171                                         hitindication_crosshair_size = 0;
1172
1173                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1174                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1175                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1176                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1177                         }
1178
1179                         if(shottype == SHOTTYPE_HITENEMY)
1180                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1181                         if(shottype == SHOTTYPE_HITTEAM)
1182                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1183
1184                         f = autocvar_crosshair_effect_speed;
1185                         if(f < 0)
1186                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1187                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1188                         {
1189                                 wcross_changedonetime = time + f;
1190                         }
1191                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1192                         {
1193                                 wcross_name_changestarttime = time;
1194                                 wcross_name_changedonetime = time + f;
1195                                 if(wcross_name_goal_prev_prev)
1196                                         strunzone(wcross_name_goal_prev_prev);
1197                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1198                                 wcross_name_goal_prev = strzone(wcross_name);
1199                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1200                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1201                                 wcross_resolution_goal_prev = wcross_resolution;
1202                         }
1203
1204                         wcross_scale_goal_prev = wcross_scale;
1205                         wcross_alpha_goal_prev = wcross_alpha;
1206                         wcross_color_goal_prev = wcross_color;
1207
1208                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1209                         {
1210                                 wcross_blur = 1;
1211                                 wcross_alpha *= 0.75;
1212                         }
1213                         else
1214                                 wcross_blur = 0;
1215                         // *_prev is at time-frametime
1216                         // * is at wcross_changedonetime+f
1217                         // what do we have at time?
1218                         if(time < wcross_changedonetime)
1219                         {
1220                                 f = frametime / (wcross_changedonetime - time + frametime);
1221                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1222                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1223                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1224                         }
1225
1226                         wcross_scale_prev = wcross_scale;
1227                         wcross_alpha_prev = wcross_alpha;
1228                         wcross_color_prev = wcross_color;
1229
1230                         wcross_scale *= 1 - autocvar__menu_alpha;
1231                         wcross_alpha *= 1 - autocvar__menu_alpha;
1232                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1233
1234                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1235                         {
1236                                 // crosshair rings for weapon stats
1237                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1238                                 {
1239                                         // declarations and stats
1240                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1241                                         string ring_image, ring_inner_image;
1242                                         vector ring_rgb, ring_inner_rgb;
1243
1244                                         ring_scale = autocvar_crosshair_ring_size;
1245
1246                                         float weapon_clipload, weapon_clipsize;
1247                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1248                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1249
1250                                         float nex_charge, nex_chargepool;
1251                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1252                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1253
1254                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1255                                                 nex_charge_movingavg = nex_charge;
1256
1257
1258                                         // handle the values
1259                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1260                                         {
1261                                                 if (nex_chargepool || use_nex_chargepool) {
1262                                                         use_nex_chargepool = 1;
1263                                                         ring_inner_value = nex_chargepool;
1264                                                 } else {
1265                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1266                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1267                                                 }
1268
1269                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1270                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1271                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1272
1273                                                 // draw the outer ring to show the current charge of the weapon
1274                                                 ring_value = nex_charge;
1275                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1276                                                 ring_rgb = wcross_color;
1277                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1278                                         }
1279                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1280                                         {
1281                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1282                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1283                                                 ring_rgb = wcross_color;
1284                                                 ring_image = "gfx/crosshair_ring.tga";
1285                                         }
1286                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1287                                         {
1288                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1289                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1290                                                 ring_rgb = wcross_color;
1291                                                 ring_image = "gfx/crosshair_ring.tga";
1292                                         }
1293
1294                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1295                                         {
1296                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1297                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1298                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1299                                                 ring_rgb = wcross_color;
1300
1301                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1302                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1303                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1304                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1305                                                 else
1306                                                         ring_image = "gfx/crosshair_ring.tga";
1307                                         }
1308
1309                                         // if in weapon switch animation, fade ring out/in
1310                                         if(g_weaponswitchdelay > 0)
1311                                         {
1312                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1313                                                 if(f > 0 && f < 2)
1314                                                         ring_alpha *= fabs(1 - f);
1315                                         }
1316
1317                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1318                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1319
1320                                         if (ring_value)
1321                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1322                                 }
1323
1324 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1325                                 do \
1326                                 { \
1327                                         if(wcross_blur > 0) \
1328                                         { \
1329                                                 for(i = -2; i <= 2; ++i) \
1330                                                 for(j = -2; j <= 2; ++j) \
1331                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1332                                         } \
1333                                         else \
1334                                         { \
1335                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1336                                         } \
1337                                 } \
1338                                 while(0)
1339
1340 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1341                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1342
1343 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1344                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1345
1346                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1347                                 {
1348                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1349                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1350                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1351                                         f = 1 - f;
1352                                 }
1353                                 else
1354                                 {
1355                                         f = 1;
1356                                 }
1357                                 wcross_name_alpha_goal_prev = f;
1358
1359                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1360                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1361
1362                                 if(autocvar_crosshair_dot)
1363                                 {
1364                                         vector wcross_color_old;
1365                                         wcross_color_old = wcross_color;
1366                                         if(autocvar_crosshair_dot_color != "0")
1367                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1368                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1369                                         // FIXME why don't we use wcross_alpha here?
1370                                         wcross_color = wcross_color_old;
1371                                 }
1372                         }
1373                 }
1374                 else
1375                 {
1376                         wcross_scale_prev = 0;
1377                         wcross_alpha_prev = 0;
1378                         wcross_scale_goal_prev = 0;
1379                         wcross_alpha_goal_prev = 0;
1380                         wcross_changedonetime = 0;
1381                         if(wcross_name_goal_prev)
1382                                 strunzone(wcross_name_goal_prev);
1383                         wcross_name_goal_prev = string_null;
1384                         if(wcross_name_goal_prev_prev)
1385                                 strunzone(wcross_name_goal_prev_prev);
1386                         wcross_name_goal_prev_prev = string_null;
1387                         wcross_name_changestarttime = 0;
1388                         wcross_name_changedonetime = 0;
1389                         wcross_name_alpha_goal_prev = 0;
1390                         wcross_name_alpha_goal_prev_prev = 0;
1391                         wcross_resolution_goal_prev = 0;
1392                         wcross_resolution_goal_prev_prev = 0;
1393                 }
1394         }
1395
1396         if(NextFrameCommand)
1397         {
1398                 localcmd("\n", NextFrameCommand, "\n");
1399                 NextFrameCommand = string_null;
1400         }
1401
1402         // we must do this check AFTER a frame was rendered, or it won't work
1403         if(cs_project_is_b0rked == 0)
1404         {
1405                 string w0, h0;
1406                 w0 = ftos(autocvar_vid_conwidth);
1407                 h0 = ftos(autocvar_vid_conheight);
1408                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1409                 //setproperty(VF_FOV, '90 90 0');
1410                 setproperty(VF_ORIGIN, '0 0 0');
1411                 setproperty(VF_ANGLES, '0 0 0');
1412                 setproperty(VF_PERSPECTIVE, 1);
1413                 makevectors('0 0 0');
1414                 vector v1, v2;
1415                 cvar_set("vid_conwidth", "800");
1416                 cvar_set("vid_conheight", "600");
1417                 v1 = cs_project(v_forward);
1418                 cvar_set("vid_conwidth", "640");
1419                 cvar_set("vid_conheight", "480");
1420                 v2 = cs_project(v_forward);
1421                 if(v1 == v2)
1422                         cs_project_is_b0rked = 1;
1423                 else
1424                         cs_project_is_b0rked = -1;
1425                 cvar_set("vid_conwidth", w0);
1426                 cvar_set("vid_conheight", h0);
1427         }
1428
1429         if(autocvar__hud_configure)
1430                 HUD_Panel_Mouse();
1431
1432     if(hud && !intermission)
1433     {
1434         if(hud == HUD_SPIDERBOT)
1435             CSQC_SPIDER_HUD();
1436         else if(hud == HUD_WAKIZASHI)
1437             CSQC_WAKIZASHI_HUD();
1438         else if(hud == HUD_RAPTOR)
1439             CSQC_RAPTOR_HUD();
1440         else if(hud == HUD_BUMBLEBEE)
1441             CSQC_BUMBLE_HUD();
1442     }
1443         // let's reset the view back to normal for the end
1444         setproperty(VF_MIN, '0 0 0');
1445         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1446 }
1447
1448
1449 void CSQC_common_hud(void)
1450 {
1451     // do some accuracy var caching
1452     float i;
1453     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1454     {
1455         if(autocvar_accuracy_color_levels != acc_color_levels)
1456         {
1457             if(acc_color_levels)
1458                 strunzone(acc_color_levels);
1459             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1460             acc_levels = tokenize_console(acc_color_levels);
1461             if (acc_levels > MAX_ACCURACY_LEVELS)
1462                 acc_levels = MAX_ACCURACY_LEVELS;
1463
1464             for (i = 0; i < acc_levels; ++i)
1465                 acc_lev[i] = stof(argv(i)) / 100.0;
1466         }
1467         // let know that acc_col[] needs to be loaded
1468         acc_col_x[0] = -1;
1469     }
1470
1471     HUD_Main(); // always run these functions for alpha checks
1472     HUD_DrawScoreboard();
1473
1474     if (scoreboard_active) // scoreboard/accuracy
1475         HUD_Reset();
1476     else if (intermission == 2) // map voting screen
1477     {
1478         HUD_FinaleOverlay();
1479         HUD_Reset();
1480     }
1481         /*
1482         switch(hud)
1483         {
1484                 case HUD_SPIDERBOT:
1485                         CSQC_SPIDER_HUD();
1486                         break;
1487
1488                 case HUD_WAKIZASHI:
1489                         CSQC_WAKIZASHI_HUD();
1490                         break;
1491
1492         case HUD_BUMBLEBEE:
1493             CSQC_BUMBLE_HUD();
1494             break;
1495         }
1496         */
1497 }
1498
1499
1500 // following vectors must be global to allow seamless switching between camera modes
1501 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1502 void CSQC_Demo_Camera()
1503 {
1504         float speed, attenuation, dimensions;
1505         vector tmp, delta;
1506
1507         if( autocvar_camera_reset || !camera_mode )
1508         {
1509                 camera_offset = '0 0 0';
1510                 current_angles = '0 0 0';
1511                 camera_direction = '0 0 0';
1512                 camera_offset_z += 30;
1513                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1514                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1515                 current_origin = view_origin;
1516                 current_camera_offset  = camera_offset;
1517                 cvar_set("camera_reset", "0");
1518                 camera_mode = CAMERA_CHASE;
1519         }
1520
1521         // Camera angles
1522         if( camera_roll )
1523                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1524
1525         if(autocvar_camera_look_player)
1526         {
1527                 vector dir;
1528                 float n;
1529
1530                 dir = normalize(view_origin - current_position);
1531                 n = mouse_angles_z;
1532                 mouse_angles = vectoangles(dir);
1533                 mouse_angles_x = mouse_angles_x * -1;
1534                 mouse_angles_z = n;
1535         }
1536         else
1537         {
1538                 tmp = getmousepos() * 0.1;
1539                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1540                 {
1541                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1542                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1543                 }
1544         }
1545
1546         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1547         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1548         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1549         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1550
1551         // Fix difference when angles don't have the same sign
1552         delta = '0 0 0';
1553         if(mouse_angles_y < -60 && current_angles_y > 60)
1554                 delta = '0 360 0';
1555         if(mouse_angles_y > 60 && current_angles_y < -60)
1556                 delta = '0 -360 0';
1557
1558         if(autocvar_camera_look_player)
1559                 attenuation = autocvar_camera_look_attenuation;
1560         else
1561                 attenuation = autocvar_camera_speed_attenuation;
1562
1563         attenuation = 1 / max(1, attenuation);
1564         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1565
1566         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1567         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1568         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1569         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1570
1571         // Camera position
1572         tmp = '0 0 0';
1573         dimensions = 0;
1574
1575         if( camera_direction_x )
1576         {
1577                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1578                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1579                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1580                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1581                 ++dimensions;
1582         }
1583
1584         if( camera_direction_y )
1585         {
1586                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1587                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1588                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1589                 ++dimensions;
1590         }
1591
1592         if( camera_direction_z )
1593         {
1594                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1595                 ++dimensions;
1596         }
1597
1598         if(autocvar_camera_free)
1599                 speed = autocvar_camera_speed_free;
1600         else
1601                 speed = autocvar_camera_speed_chase;
1602
1603         if(dimensions)
1604         {
1605                 speed = speed * sqrt(1 / dimensions);
1606                 camera_offset += tmp * speed;
1607         }
1608
1609         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1610
1611         // Camera modes
1612         if( autocvar_camera_free )
1613         {
1614                 if ( camera_mode == CAMERA_CHASE )
1615                 {
1616                         current_camera_offset = current_origin + current_camera_offset;
1617                         camera_offset = current_origin + camera_offset;
1618                 }
1619
1620                 camera_mode = CAMERA_FREE;
1621                 current_position = current_camera_offset;
1622         }
1623         else
1624         {
1625                 if ( camera_mode == CAMERA_FREE )
1626                 {
1627                         current_origin = view_origin;
1628                         camera_offset = camera_offset - current_origin;
1629                         current_camera_offset = current_camera_offset - current_origin;
1630                 }
1631
1632                 camera_mode = CAMERA_CHASE;
1633
1634                 if(autocvar_camera_chase_smoothly)
1635                         current_origin += (view_origin - current_origin) * attenuation;
1636                 else
1637                         current_origin = view_origin;
1638
1639                 current_position = current_origin + current_camera_offset;
1640         }
1641
1642         setproperty(VF_ANGLES, current_angles);
1643         setproperty(VF_ORIGIN, current_position);
1644 }