qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard ();
 342 float view_set;
 343 float camera_mode;
 344 float reticle_type;
 345 string NextFrameCommand;
 346 void CSQC_SPIDER_HUD();
 347 void CSQC_RAPTOR_HUD();
 348
 349 vector freeze_pmove_org, freeze_input_angles;
 350 entity nightvision_noise, nightvision_noise2;
 351
 352 void CSQC_UpdateView(float w, float h)
 353 {
 354         entity e;
 355         float fov;
 356         float f, i, j;
 357         vector v, vo;
 358         vector vf_size, vf_min;
 359
 360         vf_size = R_SetView3fv(VF_SIZE);
 361         vf_min = R_SetView3fv(VF_MIN);
 362         vid_width = vf_size_x;
 363         vid_height = vf_size_y;
 364
 365         vector reticle_pos, reticle_size;
 366
 367         WaypointSprite_Load();
 368
 369         if(spectatee_status)
 370                 myteam = GetPlayerColor(spectatee_status - 1);
 371         else
 372                 myteam = GetPlayerColor(player_localentnum - 1);
 373
 374         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 375         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 376
 377         warpzone_fixview_origin = pmove_org + vo;
 378         warpzone_fixview_cl_viewangles = input_angles;
 379         warpzone_fixview_angles = view_angles;
 380         WarpZone_FixView();
 381         pmove_org = warpzone_fixview_origin - vo;
 382         input_angles = warpzone_fixview_cl_viewangles;
 383         view_angles = warpzone_fixview_angles;
 384
 385         if(cvar("cl_lockview") || autocvar__hud_configure)
 386         {
 387                 pmove_org = freeze_pmove_org;
 388                 input_angles = view_angles = freeze_input_angles;
 389                 R_SetView(VF_ORIGIN, pmove_org + vo);
 390                 R_SetView(VF_ANGLES, view_angles);
 391                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 392         }
 393         freeze_pmove_org = pmove_org;
 394         freeze_input_angles = input_angles;
 395
 396         // Render the Scene
 397         if(!intermission || !view_set)
 398         {
 399                 view_origin = pmove_org + vo;
 400                 view_angles = input_angles;
 401                 makevectors(view_angles);
 402                 view_forward = v_forward;
 403                 view_right = v_right;
 404                 view_up = v_up;
 405                 view_set = 1;
 406         }
 407
 408 #ifdef BLURTEST
 409         if(time > blurtest_time0 && time < blurtest_time1)
 410         {
 411                 float r, t;
 412
 413                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 414                 r = t * blurtest_radius;
 415                 f = 1 / pow(t, blurtest_power) - 1;
 416
 417                 cvar_set("r_glsl_postprocess", "1");
 418                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 419         }
 420         else
 421         {
 422                 cvar_set("r_glsl_postprocess", "0");
 423                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 424         }
 425 #endif
 426
 427         TargetMusic_Advance();
 428         Fog_Force();
 429
 430         drawframetime = max(0.000001, time - drawtime);
 431         drawtime = time;
 432
 433         // watch for gametype changes here...
 434         // in ParseStuffCMD the cmd isn't executed yet :/
 435         // might even be better to add the gametype to TE_CSQC_INIT...?
 436         if(!postinit)
 437                 PostInit();
 438
 439         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 440                 if(calledhooks & HOOK_START)
 441                 {
 442                         localcmd("\ncl_hook_gameend\n");
 443                         calledhooks |= HOOK_END;
 444                 }
 445
 446         CheckForGamestartChange();
 447         serverAnnouncer();
 448         maptimeAnnouncer();
 449         carrierAnnouncer();
 450
 451         fov = cvar("fov");
 452         if(button_zoom || fov <= 59.5)
 453         {
 454                 if(!zoomscript_caught)
 455                 {
 456                         localcmd("+button4\n");
 457                         zoomscript_caught = 1;
 458                         ignore_plus_zoom += 1;
 459                 }
 460         }
 461         else
 462         {
 463                 if(zoomscript_caught)
 464                 {
 465                         localcmd("-button4\n");
 466                         zoomscript_caught = 0;
 467                         ignore_minus_zoom += 1;
 468                 }
 469         }
 470
 471         hud_accuracy_hud = cvar_or("hud_accuracy_hud", 1);
 472         ColorTranslateMode = cvar("cl_stripcolorcodes");
 473         activeweapon = getstati(STAT_SWITCHWEAPON);
 474         f = cvar("teamplay");
 475         if(f != teamplay)
 476         {
 477                 teamplay = f;
 478                 HUD_InitScores();
 479         }
 480
 481         if(last_weapon != activeweapon) {
 482                 weapontime = time;
 483                 last_weapon = activeweapon;
 484
 485                 e = get_weaponinfo(activeweapon);
 486                 if(e.netname != "")
 487                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 488                 else
 489                         localcmd("\ncl_hook_activeweapon none\n");
 490         }
 491
 492         // ALWAYS Clear Current Scene First
 493         R_ClearScene();
 494
 495         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 496         R_SetView(VF_SIZE, vf_size);
 497         R_SetView(VF_MIN, vf_min);
 498
 499         // Assign Standard Viewflags
 500         // Draw the World (and sky)
 501         R_SetView(VF_DRAWWORLD, 1);
 502
 503         // Set the console size vars
 504         vid_conwidth = cvar("vid_conwidth");
 505         vid_conheight = cvar("vid_conheight");
 506         vid_pixelheight = cvar("vid_pixelheight");
 507
 508         R_SetView(VF_FOV, GetCurrentFov(fov));
 509
 510         // Camera for demo playback
 511         if(camera_active)
 512         {
 513                 if(cvar("camera_enable"))
 514                         CSQC_Demo_Camera();
 515                 else
 516                 {
 517                         cvar_set("chase_active", ftos(chase_active_backup));
 518                         cvar_set("cl_demo_mousegrab", "0");
 519                         camera_active = FALSE;
 520                 }
 521         }
 522 #ifdef CAMERATEST
 523         else if(cvar("camera_enable"))
 524 #else
 525         else if(cvar("camera_enable") && isdemo())
 526 #endif
 527         {
 528                 // Enable required Darkplaces cvars
 529                 chase_active_backup = cvar("chase_active");
 530                 cvar_set("chase_active", "2");
 531                 cvar_set("cl_demo_mousegrab", "1");
 532                 camera_active = TRUE;
 533                 camera_mode = FALSE;
 534         }
 535
 536         // Draw the Crosshair
 537         float scoreboard_active;
 538         scoreboard_active = HUD_WouldDrawScoreboard();
 539         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 540
 541         // Draw the Engine Status Bar (the default Quake HUD)
 542         R_SetView(VF_DRAWENGINEHUD, 0);
 543
 544         // fetch this one only once per frame
 545         hud_showbinds = cvar("hud_showbinds");
 546         hud_showbinds_limit = cvar("hud_showbinds_limit");
 547
 548         // Update the mouse position
 549         /*
 550            mousepos_x = vid_conwidth;
 551            mousepos_y = vid_conheight;
 552            mousepos = mousepos*0.5 + getmousepos();
 553          */
 554
 555         e = self;
 556         for(self = world; (self = nextent(self)); )
 557                 if(self.draw)
 558                         self.draw();
 559         self = e;
 560
 561         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 562         R_RenderScene();
 563
 564         // now switch to 2D drawing mode by calling a 2D drawing function
 565         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 566         // next R_RenderScene call
 567         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 568
 569         if(cvar("r_fakelight") >= 2 || cvar("r_fullbright"))
 570         {
 571                 // apply night vision effect
 572                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 573                 float a;
 574
 575                 if(!nightvision_noise)
 576                 {
 577                         nightvision_noise = spawn();
 578                         nightvision_noise.classname = "nightvision_noise";
 579                 }
 580                 if(!nightvision_noise2)
 581                 {
 582                         nightvision_noise2 = spawn();
 583                         nightvision_noise2.classname = "nightvision_noise2";
 584                 }
 585
 586                 // color tint in yellow
 587                 drawfill('0 0 0', cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 588
 589                 // draw BG
 590                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 591                 rgb = '1 1 1';
 592                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 593                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 594                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 595                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 596                 tc_11 = tc_01 + tc_10 - tc_00;
 597                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 598                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 599                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 600                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 601                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 602                 R_EndPolygon();
 603
 604                 // draw FG
 605                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 606                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 607                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 608                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 609                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 610                 tc_11 = tc_01 + tc_10 - tc_00;
 611                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 612                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 613                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 614                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 615                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 616                 R_EndPolygon();
 617         }
 618
 619         // Draw the aiming reticle for weapons that use it
 620         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 621         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 622         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 623         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 624                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 625         else if(button_zoom || zoomscript_caught)
 626                 reticle_type = 1; // normal zoom
 627         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
 628                 reticle_type = 2; // nex zoom
 629
 630         if(cvar("cl_reticle_stretch"))
 631         {
 632                 reticle_size_x = vid_conwidth;
 633                 reticle_size_y = vid_conheight;
 634                 reticle_pos_x = 0;
 635                 reticle_pos_y = 0;
 636         }
 637         else
 638         {
 639                 reticle_size_x = max(vid_conwidth, vid_conheight);
 640                 reticle_size_y = max(vid_conwidth, vid_conheight);
 641                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 642                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 643         }
 644
 645         f = current_zoomfraction;
 646         if(zoomscript_caught)
 647                 f = 1;
 648         if(cvar("cl_reticle_item_normal"))
 649         {
 650                 precache_pic("gfx/reticle_normal");
 651                 if(reticle_type == 1 && f)
 652                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
 653         }
 654         if(cvar("cl_reticle_item_nex"))
 655         {
 656                 precache_pic("gfx/reticle_nex");
 657                 if(reticle_type == 2 && f)
 658                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
 659         }
 660
 661         // Draw the mouse cursor
 662         // NOTE: drawpic must happen after R_RenderScene for some reason
 663         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 664         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 665         //self = edict_num(player_localnum);
 666         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 667         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 668         // as long as the ctf part isn't in, this is useless
 669         if(menu_visible)
 670                 menu_show();
 671
 672         /*if(gametype == GAME_CTF)
 673           {
 674           ctf_view();
 675           } else */
 676
 677         // draw 2D entities
 678         e = self;
 679         for(self = world; (self = nextent(self)); )
 680                 if(self.draw2d)
 681                         self.draw2d();
 682         self = e;
 683
 684         float hud;
 685         hud = getstati(STAT_HUD);
 686         if(hud == HUD_SPIDERBOT)
 687         {
 688                 CSQC_SPIDER_HUD();
 689         }
 690         else if(hud == HUD_WAKIZASHI)
 691         CSQC_WAKIZASHI_HUD();
 692     else if(hud == HUD_RAPTOR)
 693         CSQC_RAPTOR_HUD();
 694         else
 695         {
 696                 if(cvar("r_letterbox") == 0)
 697                         if(cvar("viewsize") < 120)
 698                                 CSQC_common_hud();
 699
 700
 701                 // ring around crosshair representing velocity-dependent damage for the nex
 702                 if (activeweapon == WEP_NEX)
 703                 {
 704                         float x, y;
 705                         vector ringorigin, ringsize, t;
 706                         ringorigin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 707                         ringsize = 64 * '1 1 0'; // testing only
 708
 709                         // TODO send from server
 710                         float maxvel, minvel, curvel;
 711                         minvel = 400;
 712                         maxvel = 1000;
 713                         curvel = vlen(pmove_vel);
 714
 715                         f = bound(0, (curvel - minvel) / (maxvel - minvel), 1);
 716                         x = cos(f * M_2_PI);
 717                         y = sin(f * M_2_PI);
 718                         f = fabs(x) + fabs(y);
 719                         x /= f;
 720                         y /= f;
 721                         print("x:", ftos(x), " y:", ftos(y), "\n");
 722                         if(x >= 0 && y >= 0) // first quadrant
 723                         {
 724                                 R_BeginPolygon("gfx/nex_ring.tga", DRAWFLAG_ADDITIVE);
 725
 726                                 v = ringorigin;                 t = '0.5 0.5 0';
 727                                 R_PolygonVertex(v, t, '1 1 1', 1);
 728
 729                                 v = ringorigin;                 t = '0.5 0.5 0';
 730                                 v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 731                                 R_PolygonVertex(v, t, '1 1 1', 1);
 732
 733                                 v = ringorigin;                 t = '0.5 0.5 0';
 734                                 v_x += x * 0.5 * ringsize_x;    t += x * '0.5 0.5 0';
 735                                 v_y += y * 0.5 * ringsize_y;    t += y * '0.5 -0.5 0';
 736                                 R_PolygonVertex(v, t, '1 1 1', 1);
 737                                 R_EndPolygon();
 738                         }
 739                 }
 740
 741                 // crosshair goes VERY LAST
 742                 if(!scoreboard_active && !camera_active && intermission != 2) {
 743                         // TrueAim check
 744                         float shottype;
 745                         float bullets, ring_scale;
 746                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 747                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 748                         wcross_origin_z = 0;
 749                         if(cvar("crosshair_hittest"))
 750                         {
 751                                 vector wcross_oldorigin;
 752                                 wcross_oldorigin = wcross_origin;
 753                                 shottype = TrueAimCheck();
 754                                 if(shottype == SHOTTYPE_HITWORLD)
 755                                 {
 756                                         v = wcross_origin - wcross_oldorigin;
 757                                         v_x /= vid_conwidth;
 758                                         v_y /= vid_conheight;
 759                                         if(vlen(v) > 0.01)
 760                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 761                                 }
 762                                 if(!cvar("crosshair_hittest_showimpact"))
 763                                         wcross_origin = wcross_oldorigin;
 764                         }
 765                         else
 766                                 shottype = SHOTTYPE_HITWORLD;
 767
 768                         string wcross_style;
 769                         wcross_style = cvar_string("crosshair");
 770
 771                         if (wcross_style != "0") {
 772                                 vector wcross_color, wcross_size;
 773                                 string wcross_wep, wcross_name;
 774                                 float wcross_alpha, wcross_scale, wcross_blur, wcross_resolution;
 775
 776                                 wcross_color_x = cvar("crosshair_color_red");
 777                                 wcross_color_y = cvar("crosshair_color_green");
 778                                 wcross_color_z = cvar("crosshair_color_blue");
 779                                 wcross_alpha = cvar("crosshair_color_alpha");
 780                                 wcross_resolution = cvar("crosshair_size");
 781                                 if (cvar("crosshair_per_weapon")) {
 782                                         e = get_weaponinfo(activeweapon);
 783                                         if (e && e.netname != "")
 784                                         {
 785                                                 wcross_wep = e.netname;
 786                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 787                                                 if(wcross_style == "")
 788                                                         wcross_style = e.netname;
 789
 790                                                 if(!cvar("crosshair_color_override"))
 791                                                 {
 792                                                         wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 793                                                         wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 794                                                         wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 795                                                 }
 796
 797                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 798                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 799                                         }
 800                                 }
 801
 802                                 wcross_name = strcat("gfx/crosshair", wcross_style);
 803
 804                                 if(cvar("crosshair_effect_scalefade"))
 805                                 {
 806                                         wcross_scale = wcross_resolution;
 807                                         wcross_resolution = 1;
 808                                 }
 809                                 else
 810                                 {
 811                                         wcross_scale = 1;
 812                                 }
 813
 814                                 if(shottype == SHOTTYPE_HITENEMY)
 815                                         wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 816                                 if(shottype == SHOTTYPE_HITTEAM)
 817                                         wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 818
 819                                 f = cvar("crosshair_effect_speed");
 820                                 if(f < 0)
 821                                         f *= -2 * g_weaponswitchdelay;
 822                                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 823                                 {
 824                                         wcross_changedonetime = time + f;
 825                                 }
 826                                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 827                                 {
 828                                         wcross_name_changestarttime = time;
 829                                         wcross_name_changedonetime = time + f;
 830                                         if(wcross_name_goal_prev_prev)
 831                                                 strunzone(wcross_name_goal_prev_prev);
 832                                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 833                                         wcross_name_goal_prev = strzone(wcross_name);
 834                                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 835                                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 836                                         wcross_resolution_goal_prev = wcross_resolution;
 837                                 }
 838
 839                                 wcross_scale_goal_prev = wcross_scale;
 840                                 wcross_alpha_goal_prev = wcross_alpha;
 841                                 wcross_color_goal_prev = wcross_color;
 842
 843                                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 844                                 {
 845                                         wcross_blur = 1;
 846                                         wcross_alpha *= 0.75;
 847                                 }
 848                                 else
 849                                         wcross_blur = 0;
 850                                 // *_prev is at time-frametime
 851                                 // * is at wcross_changedonetime+f
 852                                 // what do we have at time?
 853                                 if(time < wcross_changedonetime)
 854                                 {
 855                                         f = frametime / (wcross_changedonetime - time + frametime);
 856                                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 857                                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 858                                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 859                                 }
 860
 861                                 wcross_scale_prev = wcross_scale;
 862                                 wcross_alpha_prev = wcross_alpha;
 863                                 wcross_color_prev = wcross_color;
 864
 865                                 wcross_scale *= 1 - cvar("_menu_alpha");
 866                                 wcross_alpha *= 1 - cvar("_menu_alpha");
 867
 868                                 // ring around crosshair representing bullets left in camping rifle clip
 869                                 if (activeweapon == WEP_CAMPINGRIFLE)
 870                                 {
 871                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 872                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 4);
 873                                 }
 874                                 else
 875                                         bullets = 0;
 876
 877 #define CROSSHAIR_DRAW_RING(i,j,sz,wcross_name,wcross_alpha) \
 878                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x * ring_scale + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y * ring_scale + j * wcross_blur)), strcat("gfx/rifle_ring_", ftos(bullets)), sz * wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 879
 880 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 881                                 do \
 882                                 { \
 883                                         if(wcross_blur > 0) \
 884                                         { \
 885                                                 for(i = -2; i <= 2; ++i) \
 886                                                         for(j = -2; j <= 2; ++j) \
 887                                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 888                                         } \
 889                                         else \
 890                                         { \
 891                                                 M(0,0,sz,wcross_name,wcross_alpha); \
 892                                         } \
 893                                 } \
 894                                 while(0)
 895
 896 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 897                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 898
 899 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 900                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 901
 902                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 903                                 {
 904                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 905                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 906                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 907                                         f = 1 - f;
 908                                 }
 909                                 else
 910                                 {
 911                                         f = 1;
 912                                 }
 913
 914                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 915                                 if(bullets)
 916                                 {
 917                                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_RING, wcross_resolution, wcross_name, wcross_alpha);
 918                                 }
 919                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 920                                 wcross_name_alpha_goal_prev = f;
 921                         }
 922                 }
 923                 else
 924                 {
 925                         wcross_scale_prev = 0;
 926                         wcross_alpha_prev = 0;
 927                         wcross_scale_goal_prev = 0;
 928                         wcross_alpha_goal_prev = 0;
 929                         wcross_changedonetime = 0;
 930                         if(wcross_name_goal_prev)
 931                                 strunzone(wcross_name_goal_prev);
 932                         wcross_name_goal_prev = string_null;
 933                         if(wcross_name_goal_prev_prev)
 934                                 strunzone(wcross_name_goal_prev_prev);
 935                         wcross_name_goal_prev_prev = string_null;
 936                         wcross_name_changestarttime = 0;
 937                         wcross_name_changedonetime = 0;
 938                         wcross_name_alpha_goal_prev = 0;
 939                         wcross_name_alpha_goal_prev_prev = 0;
 940                         wcross_resolution_goal_prev = 0;
 941                         wcross_resolution_goal_prev_prev = 0;
 942                 }
 943         }
 944
 945         if(NextFrameCommand)
 946         {
 947                 localcmd("\n", NextFrameCommand, "\n");
 948                 NextFrameCommand = string_null;
 949         }
 950
 951         // we must do this check AFTER a frame was rendered, or it won't work
 952         if(cs_project_is_b0rked == 0)
 953         {
 954                 string w0, h0;
 955                 w0 = cvar_string("vid_conwidth");
 956                 h0 = cvar_string("vid_conheight");
 957                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 958                 //R_SetView(VF_FOV, '90 90 0');
 959                 R_SetView(VF_ORIGIN, '0 0 0');
 960                 R_SetView(VF_ANGLES, '0 0 0');
 961                 R_SetView(VF_PERSPECTIVE, 1);
 962                 makevectors('0 0 0');
 963                 vector v1, v2;
 964                 cvar_set("vid_conwidth", "800");
 965                 cvar_set("vid_conheight", "600");
 966                 v1 = cs_project(v_forward);
 967                 cvar_set("vid_conwidth", "640");
 968                 cvar_set("vid_conheight", "480");
 969                 v2 = cs_project(v_forward);
 970                 if(v1 == v2)
 971                         cs_project_is_b0rked = 1;
 972                 else
 973                         cs_project_is_b0rked = -1;
 974                 cvar_set("vid_conwidth", w0);
 975                 cvar_set("vid_conheight", h0);
 976         }
 977
 978         if(autocvar__hud_configure)
 979                 HUD_Panel_Mouse();
 980
 981         // let's reset the view back to normal for the end
 982         R_SetView(VF_MIN, '0 0 0');
 983         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
 984
 985         // be safe against triggerbots until everyone has the fixed engine
 986         // this call is meant to overwrite the trace globals by something
 987         // unsuspicious
 988         traceline('0 0 0', '0 0 0', MOVE_WORLDONLY, world);
 989 }
 990
 991 #define spider_h "gfx/vehicles/hud_bg.tga"
 992 #define spider_b "gfx/vehicles/sbot.tga"
 993 #define spider_r "gfx/vehicles/sbot_rpods.tga"
 994 #define spider_g "gfx/vehicles/sbot_mguns.tga"
 995 #define spider_s "gfx/vehicles/shiled.tga"
 996 #define spider_a1 "gfx/hud/sb_rocket.tga"
 997 #define spider_a2 "gfx/sb_bullets.tga"
 998
 999 void CSQC_SPIDER_HUD()
1000 {
1001         float rockets, reload, heat, hp, shield;
1002         vector picsize, hudloc;
1003
1004     // Fetch health & ammo stats
1005     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1006         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1007         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1008         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1009         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1010
1011     // Draw the crosshairs
1012     picsize = drawgetimagesize(SPIDER_CROSS);
1013     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1014     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1015     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1016
1017     hudloc_y =  4;
1018     hudloc_x = 4;
1019
1020     picsize = drawgetimagesize(spider_h) * 0.5;
1021     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1022
1023     picsize = drawgetimagesize(spider_a2) * 0.5;
1024     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1025
1026     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1027     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1028     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1029
1030     picsize = drawgetimagesize(spider_a1) * 0.85;
1031     if(rockets == 9)
1032     {
1033         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1034         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1035     }
1036     else
1037     {
1038         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1039         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1040     }
1041
1042     picsize = drawgetimagesize(spider_b) * 0.5;
1043     hudloc_y = 10.5;
1044     hudloc_x = 10.5;
1045
1046     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1047     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1048     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1049     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1050
1051
1052         /*
1053         // Draw health bar
1054         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1055         p = p + '0 1 0' * vid_conheight - '0 32 0';
1056         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1057         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1058         p_y += 8;
1059         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1060         p_x += 256 * hp;
1061         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1062
1063         // Draw minigun heat indicator
1064         p = '0.5 0 0' * (vid_conwidth - 256);
1065         p = p + '0 1 0' * vid_conheight - '0 34  0';
1066         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1067         p_x += 256 * (1-heat);
1068         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1069
1070
1071         // Draw rocket icons for loaded/empty tubes.
1072         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1073         pp += '0 1 0' * vid_conheight - '0 64 0';
1074         for(i = 0; i < 8; ++i)
1075         {
1076                 p = pp + '1 0 0' * (rkt_size * i);
1077                 if(rockets == 8)
1078                 {
1079                         if(floor(reload * 8) == i)
1080                         {
1081                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1082                         }
1083                         else if(i < reload * 8)
1084                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1085                         else
1086                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1087                 }
1088                 else
1089                 {
1090                         if(i < rockets)
1091                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1092                         else
1093                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1094                 }
1095         }
1096         */
1097
1098         if (scoreboard_showscores)
1099         {
1100                 HUD_DrawScoreboard();
1101                 HUD_DrawCenterPrint();
1102         }
1103
1104 }
1105
1106 #define raptor_h "gfx/vehicles/hud_bg.tga"
1107 #define raptor_b "gfx/vehicles/raptor.tga"
1108 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1109 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1110 #define raptor_s "gfx/vehicles/shiled.tga"
1111
1112 void CSQC_RAPTOR_HUD()
1113 {
1114         float rockets, reload, heat, hp, shield, energy;
1115         vector picsize, hudloc;
1116
1117     // Fetch health & ammo stats
1118     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1119         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1120         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1121         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1122
1123     // Draw the crosshairs
1124     picsize = drawgetimagesize(SPIDER_CROSS);
1125     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1126     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1127     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1128
1129     hudloc_y =  4;
1130     hudloc_x = 4;
1131
1132     picsize = drawgetimagesize(raptor_h) * 0.5;
1133     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1134
1135     picsize = drawgetimagesize(spider_a2) * 0.5;
1136     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1137
1138     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1139     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1140     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1141
1142
1143     picsize = drawgetimagesize(spider_a1) * 0.85;
1144     if(reload == 1)
1145     {
1146         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1147         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1148     }
1149     else
1150     {
1151         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1152         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1153     }
1154
1155     picsize = drawgetimagesize(raptor_b) * 0.5;
1156     hudloc_y = 10.5;
1157     hudloc_x = 10.5;
1158
1159     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1160     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1161     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1162     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1163
1164
1165         if (scoreboard_showscores)
1166         {
1167                 HUD_DrawScoreboard();
1168                 HUD_DrawCenterPrint();
1169         }
1170
1171 }
1172
1173 #define waki_h "gfx/vehicles/hud_bg.tga"
1174 #define waki_b "gfx/vehicles/waki.tga"
1175 #define waki_e "gfx/vehicles/waki_e.tga"
1176 #define waki_g "gfx/vehicles/waki_guns.tga"
1177 #define waki_r "gfx/vehicles/waki_rockets.tga"
1178 #define waki_s "gfx/vehicles/shiled.tga"
1179
1180 #define waki_a1 "gfx/hud/sb_rocket.tga"
1181 #define waki_a2 "gfx/sb_cells.tga"
1182
1183 void CSQC_WAKIZASHI_HUD()
1184 {
1185         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1186         float health, shield, energy, rockets;
1187         vector picsize, hudloc;
1188
1189     picsize = drawgetimagesize(SPIDER_CROSS);
1190     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1191     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1192     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1193
1194 /*
1195 const float STAT_VEHICLESTAT_HEALTH  = 60;
1196 const float STAT_VEHICLESTAT_SHIELD  = 61;
1197 const float STAT_VEHICLESTAT_ENERGY  = 62;
1198 const float STAT_VEHICLESTAT_AMMO1   = 63;
1199 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1200 const float STAT_VEHICLESTAT_AMMO2   = 65;
1201 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1202 */
1203     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1204         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1205         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1206         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1207
1208     hudloc_y =  4;
1209     hudloc_x = 4;
1210
1211     picsize = drawgetimagesize(waki_h) * 0.5;
1212     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1213
1214     picsize = drawgetimagesize(waki_a2) * 0.7;
1215     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1216
1217
1218     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1219     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1220
1221     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1222
1223     picsize = drawgetimagesize(waki_a1) * 0.75;
1224     if(rockets == 1)
1225     {
1226         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1227         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1228     }
1229     else
1230     {
1231         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1232         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1233         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1234     }
1235
1236     picsize = drawgetimagesize(waki_b) * 0.5;
1237     hudloc_y = 10.5;
1238     hudloc_x = 10.5;
1239
1240     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1241     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1242     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1243     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1244
1245
1246
1247         /*
1248         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1249         p = p + '0 1 0' * vid_conheight - '0 32 0';
1250
1251         // Draw health bar
1252         p_y += 8;
1253         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1254         p_x += 256 * health;
1255         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1256
1257         // Draw shiled bar
1258         p_x -= 256 * health;
1259         p_y += 4;
1260         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1261
1262         // Draw energy
1263         //p_x -= 256 * health;
1264         p_y -= 8;
1265         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1266
1267         // Draw rockets bar
1268         p_y += 12;
1269         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1270         */
1271
1272
1273
1274
1275         if (scoreboard_showscores)
1276         {
1277                 HUD_DrawScoreboard();
1278                 HUD_DrawCenterPrint();
1279         }
1280
1281 }
1282
1283
1284 void CSQC_common_hud(void)
1285 {
1286         // HUD_SortFrags(); done in HUD_Draw
1287         float hud;
1288         hud = getstati(STAT_HUD);
1289
1290         //hud = 10;
1291         switch(hud)
1292         {
1293                 case HUD_NORMAL:
1294                         // do some accuracy var caching
1295                         float i;
1296                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1297                         {
1298                                 acc_levels = tokenize(cvar_string("hud_panel_weapons_accuracy_color_levels"));
1299                                 if (acc_levels > MAX_ACCURACY_LEVELS)
1300                                         acc_levels = MAX_ACCURACY_LEVELS;
1301
1302                                 for (i = 0; i < acc_levels; ++i)
1303                                         acc_lev[i] = stof(argv(i));
1304                         }
1305
1306                         HUD_Main(); // always run these functions for alpha checks
1307                         HUD_DrawScoreboard();
1308
1309                         if (scoreboard_showscores || scoreboard_showscores_force || getstati(STAT_HEALTH) <= 0 || intermission == 1) // scoreboard/accuracy
1310                         {
1311                                 HUD_Reset();
1312                                 // HUD_DrawScoreboard takes care of centerprint_start
1313                         }
1314                         else if (intermission == 2) // map voting screen
1315                         {
1316                                 HUD_FinaleOverlay();
1317                                 HUD_Reset();
1318
1319                                 centerprint_start_x = 0;
1320                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1321                         }
1322                         else // hud
1323                         {
1324                                 centerprint_start_x = 0;
1325                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1326                         }
1327
1328                         HUD_DrawCenterPrint();
1329                         break;
1330
1331                 case HUD_SPIDERBOT:
1332                         CSQC_SPIDER_HUD();
1333                         break;
1334
1335                 case HUD_WAKIZASHI:
1336                         CSQC_WAKIZASHI_HUD();
1337                         break;
1338         }
1339 }
1340
1341
1342 // following vectors must be global to allow seamless switching between camera modes
1343 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1344 void CSQC_Demo_Camera()
1345 {
1346         float speed, attenuation, dimensions;
1347         vector tmp, delta;
1348
1349         if( cvar("camera_reset") || !camera_mode )
1350         {
1351                 camera_offset = '0 0 0';
1352                 current_angles = '0 0 0';
1353                 camera_direction = '0 0 0';
1354                 camera_offset_z += 30;
1355                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1356                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1357                 current_origin = view_origin;
1358                 current_camera_offset  = camera_offset;
1359                 cvar_set("camera_reset", "0");
1360                 camera_mode = CAMERA_CHASE;
1361         }
1362
1363         // Camera angles
1364         if( camera_roll )
1365                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1366
1367         if(cvar("camera_look_player"))
1368         {
1369                 local vector dir;
1370                 local float n;
1371
1372                 dir = normalize(view_origin - current_position);
1373                 n = mouse_angles_z;
1374                 mouse_angles = vectoangles(dir);
1375                 mouse_angles_x = mouse_angles_x * -1;
1376                 mouse_angles_z = n;
1377         }
1378         else
1379         {
1380                 tmp = getmousepos() * 0.1;
1381                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1382                 {
1383                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1384                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1385                 }
1386         }
1387
1388         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1389         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1390         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1391         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1392
1393         // Fix difference when angles don't have the same sign
1394         delta = '0 0 0';
1395         if(mouse_angles_y < -60 && current_angles_y > 60)
1396                 delta = '0 360 0';
1397         if(mouse_angles_y > 60 && current_angles_y < -60)
1398                 delta = '0 -360 0';
1399
1400         if(cvar("camera_look_player"))
1401                 attenuation = cvar("camera_look_attenuation");
1402         else
1403                 attenuation = cvar("camera_speed_attenuation");
1404
1405         attenuation = 1 / max(1, attenuation);
1406         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1407
1408         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1409         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1410         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1411         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1412
1413         // Camera position
1414         tmp = '0 0 0';
1415         dimensions = 0;
1416
1417         if( camera_direction_x )
1418         {
1419                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1420                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1421                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1422                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1423                 ++dimensions;
1424         }
1425
1426         if( camera_direction_y )
1427         {
1428                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1429                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1430                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1431                 ++dimensions;
1432         }
1433
1434         if( camera_direction_z )
1435         {
1436                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1437                 ++dimensions;
1438         }
1439
1440         if(cvar("camera_free"))
1441                 speed = cvar("camera_speed_free");
1442         else
1443                 speed = cvar("camera_speed_chase");
1444
1445         if(dimensions)
1446         {
1447                 speed = speed * sqrt(1 / dimensions);
1448                 camera_offset += tmp * speed;
1449         }
1450
1451         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1452
1453         // Camera modes
1454         if( cvar("camera_free") )
1455         {
1456                 if ( camera_mode == CAMERA_CHASE )
1457                 {
1458                         current_camera_offset = current_origin + current_camera_offset;
1459                         camera_offset = current_origin + camera_offset;
1460                 }
1461
1462                 camera_mode = CAMERA_FREE;
1463                 current_position = current_camera_offset;
1464         }
1465         else
1466         {
1467                 if ( camera_mode == CAMERA_FREE )
1468                 {
1469                         current_origin = view_origin;
1470                         camera_offset = camera_offset - current_origin;
1471                         current_camera_offset = current_camera_offset - current_origin;
1472                 }
1473
1474                 camera_mode = CAMERA_CHASE;
1475
1476                 if(cvar("camera_chase_smoothly"))
1477                         current_origin += (view_origin - current_origin) * attenuation;
1478                 else
1479                         current_origin = view_origin;
1480
1481                 current_position = current_origin + current_camera_offset;
1482         }
1483
1484         R_SetView(VF_ANGLES, current_angles);
1485         R_SetView(VF_ORIGIN, current_position);
1486 }