qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 /**
  82  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  83  *
  84  * TODO: Use a better solution where a common shared entitiy is used that contains
  85  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  86  * and STAT_FRAGLIMIT to be auto-sent)
  87  */
  88 void CheckForGamestartChange() {
  89         float startTime;
  90         startTime = getstatf(STAT_GAMESTARTTIME);
  91         if (previous_game_starttime != startTime) {
  92                 if ((time + 5.0) < startTime) {
  93                         //if connecting to server while restart was active don't always play prepareforbattle
  94                         sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  95                 }
  96                 if (time < startTime) {
  97                         restartAnnouncer = spawn();
  98                         restartAnnouncer.think = restartAnnouncer_Think;
  99                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 100                 }
 101         }
 102         previous_game_starttime = startTime;
 103 }
 104
 105 void Porto_Init()
 106 {
 107         porto = spawn();
 108         porto.classname = "porto";
 109         porto.draw = Porto_Draw;
 110         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 111 }
 112
 113 float drawtime;
 114 float avgspeed;
 115 vector GetCurrentFov(float fov)
 116 {
 117         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 118
 119         zoomsensitivity = autocvar_cl_zoomsensitivity;
 120         zoomfactor = autocvar_cl_zoomfactor;
 121         if(zoomfactor < 1 || zoomfactor > 16)
 122                 zoomfactor = 2.5;
 123         zoomspeed = autocvar_cl_zoomspeed;
 124         if(zoomspeed >= 0)
 125                 if(zoomspeed < 0.5 || zoomspeed > 16)
 126                         zoomspeed = 3.5;
 127
 128         zoomdir = button_zoom;
 129         if(hud == HUD_NORMAL)
 130         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 131                 zoomdir += button_attack2;
 132         if(spectatee_status > 0 || isdemo())
 133         {
 134                 if(spectatorbutton_zoom)
 135                 {
 136                         if(zoomdir)
 137                                 zoomdir = 0;
 138                         else
 139                                 zoomdir = 1;
 140                 }
 141                 // fteqcc failed twice here already, don't optimize this
 142         }
 143
 144         if(zoomdir)
 145                 zoomin_effect = 0;
 146
 147         if(zoomin_effect || camera_active)
 148         {
 149                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 150         }
 151         else
 152         {
 153                 if(zoomspeed < 0) // instant zoom
 154                 {
 155                         if(zoomdir)
 156                                 current_viewzoom = 1 / zoomfactor;
 157                         else
 158                                 current_viewzoom = 1;
 159                 }
 160                 else
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 164                         else
 165                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 166                 }
 167         }
 168
 169         if(almost_equals(current_viewzoom, 1))
 170                 current_zoomfraction = 0;
 171         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 172                 current_zoomfraction = 1;
 173         else
 174                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 175
 176         if(zoomsensitivity < 1)
 177                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 178         else
 179                 setsensitivityscale(1);
 180
 181         if (autocvar_cl_velocityzoom)
 182         {
 183                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 184                 avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 185                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 186                 //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 187         }
 188         else
 189                 velocityzoom = 1;
 190
 191         float frustumx, frustumy, fovx, fovy;
 192         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 193         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 194         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 195         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 196
 197         return '1 0 0' * fovx + '0 1 0' * fovy;
 198 }
 199
 200 // this function must match W_SetupShot!
 201 float zoomscript_caught;
 202
 203 vector wcross_origin;
 204 float wcross_scale_prev, wcross_alpha_prev;
 205 vector wcross_color_prev;
 206 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 207 vector wcross_color_goal_prev;
 208 float wcross_changedonetime;
 209
 210 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 211 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 212 float wcross_name_changestarttime, wcross_name_changedonetime;
 213 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 214 entity trueaim;
 215 entity trueaim_rifle;
 216
 217 #define SHOTTYPE_HITTEAM 1
 218 #define SHOTTYPE_HITOBSTRUCTION 2
 219 #define SHOTTYPE_HITWORLD 3
 220 #define SHOTTYPE_HITENEMY 4
 221
 222 void TrueAim_Init()
 223 {
 224         trueaim = spawn();
 225         trueaim.classname = "trueaim";
 226         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 227         trueaim_rifle = spawn();
 228         trueaim_rifle.classname = "trueaim_rifle";
 229         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230 }
 231
 232 float EnemyHitCheck()
 233 {
 234         float t;
 235         wcross_origin = project_3d_to_2d(trace_endpos);
 236         wcross_origin_z = 0;
 237         if(trace_networkentity < 1)
 238                 return SHOTTYPE_HITWORLD;
 239         if(trace_networkentity > maxclients)
 240                 return SHOTTYPE_HITWORLD;
 241         t = GetPlayerColor(trace_networkentity - 1);
 242         if(teamplay)
 243                 if(t == myteam)
 244                         return SHOTTYPE_HITTEAM;
 245         if(t == COLOR_SPECTATOR)
 246                 return SHOTTYPE_HITWORLD;
 247         return SHOTTYPE_HITENEMY;
 248 }
 249
 250 float TrueAimCheck()
 251 {
 252         float nudge = 1; // added to traceline target and subtracted from result
 253         vector vecs, trueaimpoint, w_shotorg;
 254         vector mi, ma, dv;
 255         float shottype;
 256         entity ta;
 257         float mv;
 258
 259         mi = ma = '0 0 0';
 260         ta = trueaim;
 261         mv = MOVE_NOMONSTERS;
 262
 263         switch(activeweapon)
 264         {
 265                 case WEP_TUBA: // no aim
 266                 case WEP_PORTO: // shoots from eye
 267                 case WEP_HOOK: // no trueaim
 268                 case WEP_GRENADE_LAUNCHER: // toss curve
 269                         return SHOTTYPE_HITWORLD;
 270                 case WEP_NEX:
 271                 case WEP_MINSTANEX:
 272                         mv = MOVE_NORMAL;
 273                         break;
 274                 case WEP_RIFLE:
 275                         ta = trueaim_rifle;
 276                         mv = MOVE_NORMAL;
 277                         if(zoomscript_caught)
 278                         {
 279                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 280                                 return EnemyHitCheck();
 281                         }
 282                         break;
 283                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 284                         mi = '-3 -3 -3';
 285                         ma = '3 3 3';
 286                         break;
 287                 case WEP_FIREBALL: // projectile has a size!
 288                         mi = '-16 -16 -16';
 289                         ma = '16 16 16';
 290                         break;
 291                 case WEP_SEEKER: // projectile has a size!
 292                         mi = '-2 -2 -2';
 293                         ma = '2 2 2';
 294                         break;
 295                 case WEP_ELECTRO: // projectile has a size!
 296                         mi = '0 0 -3';
 297                         ma = '0 0 -3';
 298                         break;
 299         }
 300
 301         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 302
 303         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 304         trueaimpoint = trace_endpos;
 305
 306         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 307                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float camera_mode;
 343 float reticle_type;
 344 string NextFrameCommand;
 345 void CSQC_SPIDER_HUD();
 346 void CSQC_RAPTOR_HUD();
 347
 348 vector freeze_org, freeze_ang;
 349 entity nightvision_noise, nightvision_noise2;
 350
 351 #define MAX_TIME_DIFF 5
 352 float pickup_crosshair_time, pickup_crosshair_size;
 353 float hit_time, typehit_time;
 354 float nextsound_hit_time, nextsound_typehit_time;
 355 float hitindication_crosshair_time, hitindication_crosshair_size;
 356 float use_nex_chargepool;
 357
 358 float myhealth, myhealth_prev;
 359 float myhealth_flash;
 360
 361 float old_blurradius, old_bluralpha;
 362 float old_sharpen_intensity;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 float eventchase_current_distance;
 370
 371 vector damage_blurpostprocess, content_blurpostprocess;
 372
 373 float checkfail[16];
 374
 375 void CSQC_UpdateView(float w, float h)
 376 {
 377         entity e;
 378         float fov;
 379         float f, i, j;
 380         vector v;
 381         vector vf_size, vf_min;
 382         float a;
 383         hud = getstati(STAT_HUD);
 384
 385         button_attack2 = (input_buttons & BUTTON_3);
 386         button_zoom = (input_buttons & BUTTON_4);
 387
 388         // FIXME do we need this hack?
 389         if(isdemo())
 390         {
 391                 // in demos, input_buttons do not work
 392                 button_zoom = (autocvar__togglezoom == "-");
 393         }
 394
 395 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 396         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 397         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 398         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 399         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 400         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 401         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 402
 403         vf_size = R_SetView3fv(VF_SIZE);
 404         vf_min = R_SetView3fv(VF_MIN);
 405         vid_width = vf_size_x;
 406         vid_height = vf_size_y;
 407
 408         vector reticle_pos, reticle_size;
 409         vector splash_pos, splash_size;
 410
 411         WaypointSprite_Load();
 412
 413         if(spectatee_status)
 414                 myteam = GetPlayerColor(spectatee_status - 1);
 415         else
 416                 myteam = GetPlayerColor(player_localentnum - 1);
 417
 418         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 419
 420         // event chase camera
 421         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 422         {
 423                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 424                 {
 425                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 426                         vector current_view_origin = R_SetView3fv(VF_ORIGIN);
 427
 428                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 429                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 430                         if(!autocvar_chase_active)
 431                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 432
 433                         // make the camera smooth back
 434                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 435                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 436                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 437                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 438
 439                         vector eventchase_target_origin;
 440                         makevectors(view_angles);
 441                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 442                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 443                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 444                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 445                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 446                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 447                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 448
 449                         R_SetView(VF_ORIGIN, trace_endpos);
 450                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 451                 }
 452                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 453                 {
 454                         cvar_set("chase_active", "0");
 455                         eventchase_current_distance = 0; // start from 0 next time
 456                 }
 457         }
 458
 459         // do lockview after event chase camera so that it still applies whenever necessary.
 460         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 461         {
 462                 R_SetView(VF_ORIGIN, freeze_org);
 463                 R_SetView(VF_ANGLES, freeze_ang);
 464         }
 465         else
 466         {
 467                 freeze_org = R_SetView3fv(VF_ORIGIN);
 468                 freeze_ang = R_SetView3fv(VF_ANGLES);
 469         }
 470
 471         WarpZone_FixView();
 472         //WarpZone_FixPMove();
 473
 474         // Render the Scene
 475         view_origin = R_SetView3fv(VF_ORIGIN);
 476         view_angles = R_SetView3fv(VF_ANGLES);
 477         makevectors(view_angles);
 478         view_forward = v_forward;
 479         view_right = v_right;
 480         view_up = v_up;
 481
 482 #ifdef BLURTEST
 483         if(time > blurtest_time0 && time < blurtest_time1)
 484         {
 485                 float r, t;
 486
 487                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 488                 r = t * blurtest_radius;
 489                 f = 1 / pow(t, blurtest_power) - 1;
 490
 491                 cvar_set("r_glsl_postprocess", "1");
 492                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 493         }
 494         else
 495         {
 496                 cvar_set("r_glsl_postprocess", "0");
 497                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 498         }
 499 #endif
 500
 501         TargetMusic_Advance();
 502         Fog_Force();
 503
 504         if(drawtime == 0)
 505                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 506         else
 507                 drawframetime = bound(0.000001, time - drawtime, 1);
 508         drawtime = time;
 509
 510         // watch for gametype changes here...
 511         // in ParseStuffCMD the cmd isn't executed yet :/
 512         // might even be better to add the gametype to TE_CSQC_INIT...?
 513         if(!postinit)
 514                 PostInit();
 515
 516         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 517                 if(calledhooks & HOOK_START)
 518                 {
 519                         localcmd("\ncl_hook_gameend\n");
 520                         calledhooks |= HOOK_END;
 521                 }
 522
 523         CheckForGamestartChange();
 524         serverAnnouncer();
 525         maptimeAnnouncer();
 526         carrierAnnouncer();
 527
 528         fov = autocvar_fov;
 529         if(fov <= 59.5)
 530         {
 531                 if(!zoomscript_caught)
 532                 {
 533                         localcmd("+button9\n");
 534                         zoomscript_caught = 1;
 535                 }
 536         }
 537         else
 538         {
 539                 if(zoomscript_caught)
 540                 {
 541                         localcmd("-button9\n");
 542                         zoomscript_caught = 0;
 543                 }
 544         }
 545
 546         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 547
 548         // next WANTED weapon (for HUD)
 549         switchweapon = getstati(STAT_SWITCHWEAPON);
 550
 551         // currently switching-to weapon (for crosshair)
 552         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 553
 554         // actually active weapon (for zoom)
 555         activeweapon = getstati(STAT_ACTIVEWEAPON);
 556
 557         f = (serverflags & SERVERFLAG_TEAMPLAY);
 558         if(f != teamplay)
 559         {
 560                 teamplay = f;
 561                 HUD_InitScores();
 562         }
 563
 564         if(last_switchweapon != switchweapon) {
 565                 weapontime = time;
 566                 last_switchweapon = switchweapon;
 567         }
 568         if(last_activeweapon != activeweapon) {
 569                 last_activeweapon = activeweapon;
 570
 571                 e = get_weaponinfo(activeweapon);
 572                 if(e.netname != "")
 573                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 574                 else
 575                         localcmd("\ncl_hook_activeweapon none\n");
 576         }
 577
 578         // ALWAYS Clear Current Scene First
 579         R_ClearScene();
 580 #ifdef WORKAROUND_XON010
 581         if(checkextension("DP_CSQC_ROTATEMOVES"))
 582         {
 583 #endif
 584         R_SetView(VF_ORIGIN, view_origin);
 585         R_SetView(VF_ANGLES, view_angles);
 586 #ifdef WORKAROUND_XON010
 587         }
 588 #endif
 589
 590         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 591         R_SetView(VF_SIZE, vf_size);
 592         R_SetView(VF_MIN, vf_min);
 593
 594         // Assign Standard Viewflags
 595         // Draw the World (and sky)
 596         R_SetView(VF_DRAWWORLD, 1);
 597
 598         // Set the console size vars
 599         vid_conwidth = autocvar_vid_conwidth;
 600         vid_conheight = autocvar_vid_conheight;
 601         vid_pixelheight = autocvar_vid_pixelheight;
 602
 603         R_SetView(VF_FOV, GetCurrentFov(fov));
 604
 605         // Camera for demo playback
 606         if(camera_active)
 607         {
 608                 if(autocvar_camera_enable)
 609                         CSQC_Demo_Camera();
 610                 else
 611                 {
 612                         cvar_set("chase_active", ftos(chase_active_backup));
 613                         cvar_set("cl_demo_mousegrab", "0");
 614                         camera_active = FALSE;
 615                 }
 616         }
 617 #ifdef CAMERATEST
 618         else if(autocvar_camera_enable)
 619 #else
 620         else if(autocvar_camera_enable && isdemo())
 621 #endif
 622         {
 623                 // Enable required Darkplaces cvars
 624                 chase_active_backup = autocvar_chase_active;
 625                 cvar_set("chase_active", "2");
 626                 cvar_set("cl_demo_mousegrab", "1");
 627                 camera_active = TRUE;
 628                 camera_mode = FALSE;
 629         }
 630
 631         // Draw the Crosshair
 632         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 633
 634         // Draw the Engine Status Bar (the default Quake HUD)
 635         R_SetView(VF_DRAWENGINEHUD, 0);
 636
 637         // Update the mouse position
 638         /*
 639            mousepos_x = vid_conwidth;
 640            mousepos_y = vid_conheight;
 641            mousepos = mousepos*0.5 + getmousepos();
 642          */
 643
 644         e = self;
 645         for(self = world; (self = nextent(self)); )
 646                 if(self.draw)
 647                         self.draw();
 648         self = e;
 649
 650         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 651         R_RenderScene();
 652
 653         // now switch to 2D drawing mode by calling a 2D drawing function
 654         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 655         // next R_RenderScene call
 656         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 657
 658         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 659         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 660         {
 661                 // apply night vision effect
 662                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 663
 664                 if(!nightvision_noise)
 665                 {
 666                         nightvision_noise = spawn();
 667                         nightvision_noise.classname = "nightvision_noise";
 668                 }
 669                 if(!nightvision_noise2)
 670                 {
 671                         nightvision_noise2 = spawn();
 672                         nightvision_noise2.classname = "nightvision_noise2";
 673                 }
 674
 675                 // color tint in yellow
 676                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 677
 678                 // draw BG
 679                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 680                 rgb = '1 1 1';
 681                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 682                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 683                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 684                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 685                 tc_11 = tc_01 + tc_10 - tc_00;
 686                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 687                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 688                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 689                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 690                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 691                 R_EndPolygon();
 692
 693                 // draw FG
 694                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 695                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 696                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 697                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 698                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 699                 tc_11 = tc_01 + tc_10 - tc_00;
 700                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 701                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 702                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 703                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 704                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 705                 R_EndPolygon();
 706         }
 707
 708         // Draw the aiming reticle for weapons that use it
 709         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 710         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 711         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 712         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 713                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 714         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 715                 reticle_type = 2; // nex zoom
 716         else if(button_zoom || zoomscript_caught)
 717                 reticle_type = 1; // normal zoom
 718         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 719                 reticle_type = 2; // nex zoom
 720
 721         if (reticle_type)
 722         {
 723                 if(autocvar_cl_reticle_stretch)
 724                 {
 725                         reticle_size_x = vid_conwidth;
 726                         reticle_size_y = vid_conheight;
 727                         reticle_pos_x = 0;
 728                         reticle_pos_y = 0;
 729                 }
 730                 else
 731                 {
 732                         reticle_size_x = max(vid_conwidth, vid_conheight);
 733                         reticle_size_y = max(vid_conwidth, vid_conheight);
 734                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 735                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 736                 }
 737
 738                 f = current_zoomfraction;
 739                 if(zoomscript_caught)
 740                         f = 1;
 741                 if(autocvar_cl_reticle_item_normal)
 742                 {
 743                         if(reticle_type == 1 && f)
 744                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 745                 }
 746                 if(autocvar_cl_reticle_item_nex)
 747                 {
 748                         if(reticle_type == 2 && f)
 749                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 750                 }
 751         }
 752
 753
 754         // improved polyblend
 755         vector rgb;
 756         if(autocvar_hud_contents)
 757         {
 758                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 759                 vector liquidcolor;
 760
 761                 switch(pointcontents(view_origin))
 762                 {
 763                         case CONTENT_WATER:
 764                                 liquidalpha = autocvar_hud_contents_water_alpha;
 765                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 766                                 incontent = 1;
 767                                 break;
 768
 769                         case CONTENT_LAVA:
 770                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 771                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 772                                 incontent = 1;
 773                                 break;
 774
 775                         case CONTENT_SLIME:
 776                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 777                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 778                                 incontent = 1;
 779                                 break;
 780
 781                         default:
 782                                 liquidalpha = 0;
 783                                 liquidcolor = '0 0 0';
 784                                 incontent = 0;
 785                                 break;
 786                 }
 787
 788                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 789                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 790                         contentfadetime = autocvar_hud_contents_fadeintime;
 791                         liquidalpha_prev = liquidalpha;
 792                         liquidcolor_prev = liquidcolor;
 793                 }
 794                 else
 795                         contentfadetime = autocvar_hud_contents_fadeouttime;
 796
 797                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 798                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 799
 800                 if(contentavgalpha)
 801                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 802
 803                 if(autocvar_hud_postprocessing)
 804                 {
 805                         if(autocvar_hud_contents_blur && contentavgalpha)
 806                         {
 807                                 content_blurpostprocess_x = 1;
 808                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 809                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 810                         }
 811                         else
 812                         {
 813                                 content_blurpostprocess_x = 0;
 814                                 content_blurpostprocess_y = 0;
 815                                 content_blurpostprocess_z = 0;
 816                         }
 817                 }
 818         }
 819
 820         if(autocvar_hud_damage)
 821         {
 822                 splash_size_x = max(vid_conwidth, vid_conheight);
 823                 splash_size_y = max(vid_conwidth, vid_conheight);
 824                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 825                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 826
 827                 float myhealth_flash_temp;
 828                 myhealth = getstati(STAT_HEALTH);
 829
 830                 // fade out
 831                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 832                 // add new damage
 833                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 834
 835                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 836                 pain_threshold = autocvar_hud_damage_pain_threshold;
 837                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 838                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 839
 840                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 841                 {
 842                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 843                 }
 844
 845                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 846
 847                 if(myhealth_prev < 1)
 848                 {
 849                         if(myhealth >= 1)
 850                         {
 851                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 852                                 myhealth_flash_temp = 0;
 853                         }
 854                         else
 855                         {
 856                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 857                         }
 858                 }
 859
 860                 if(spectatee_status == -1 || intermission)
 861                 {
 862                         myhealth_flash = 0; // observing, or match ended
 863                         myhealth_flash_temp = 0;
 864                 }
 865
 866                 myhealth_prev = myhealth;
 867
 868                 // IDEA: change damage color/picture based on player model for robot/alien species?
 869                 // pro: matches model better
 870                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 871                 // maybe different reddish pics?
 872                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 873                 {
 874                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 875                         {
 876                                 if(autocvar_cl_gentle_damage == 2)
 877                                 {
 878                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 879                                         {
 880                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 881                                         }
 882                                 }
 883                                 else
 884                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 885
 886                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 887                         }
 888                         else
 889                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 890                 }
 891
 892                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 893                 {
 894                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 895                         {
 896                                 damage_blurpostprocess_x = 1;
 897                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 898                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 899                         }
 900                         else
 901                         {
 902                                 damage_blurpostprocess_x = 0;
 903                                 damage_blurpostprocess_y = 0;
 904                                 damage_blurpostprocess_z = 0;
 905                         }
 906                 }
 907         }
 908
 909         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 910         {
 911                 // enable or disable rendering types if they are used or not
 912                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 913                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 914
 915                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 916                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 917                 {
 918                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 919                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 920                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 921                         {
 922                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 923                                 old_blurradius = blurradius;
 924                                 old_bluralpha = bluralpha;
 925                         }
 926                 }
 927                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 928                 {
 929                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 930                         old_blurradius = 0;
 931                         old_bluralpha = 0;
 932                 }
 933
 934                 // edge detection postprocess handling done second (used by hud_powerup)
 935                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 936                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 937                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 938
 939                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 940
 941                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 942                 {
 943                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 944                         {
 945                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 946                                 old_sharpen_intensity = sharpen_intensity;
 947                         }
 948                 }
 949                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 950                 {
 951                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 952                         old_sharpen_intensity = 0;
 953                 }
 954         }
 955
 956         if(menu_visible)
 957                 menu_show();
 958
 959         /*if(gametype == GAME_CTF)
 960           {
 961           ctf_view();
 962           } else */
 963
 964         // draw 2D entities
 965         e = self;
 966         for(self = world; (self = nextent(self)); )
 967                 if(self.draw2d)
 968                         self.draw2d();
 969         self = e;
 970         Draw_ShowNames_All();
 971
 972         scoreboard_active = HUD_WouldDrawScoreboard();
 973
 974         hit_time = getstatf(STAT_HIT_TIME);
 975         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 976         {
 977                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 978                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 979
 980                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 981         }
 982         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 983         if(typehit_time > nextsound_typehit_time)
 984         {
 985                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 986                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 987
 988                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 989         }
 990
 991         //else
 992         {
 993                 if(gametype == GAME_FREEZETAG)
 994                 {
 995                         if(getstati(STAT_FROZEN))
 996                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 997                         if(getstatf(STAT_REVIVE_PROGRESS))
 998                         {
 999                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1000                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1001                         }
1002                 }
1003
1004                 if(autocvar_r_letterbox == 0)
1005                         if(autocvar_viewsize < 120)
1006                                 CSQC_common_hud();
1007
1008                 // crosshair goes VERY LAST
1009                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
1010                         string wcross_style;
1011                         float wcross_alpha, wcross_resolution;
1012                         wcross_style = autocvar_crosshair;
1013                         if (wcross_style == "0")
1014                                 return;
1015                         wcross_resolution = autocvar_crosshair_size;
1016                         if (wcross_resolution == 0)
1017                                 return;
1018                         wcross_alpha = autocvar_crosshair_alpha;
1019                         if (wcross_alpha == 0)
1020                                 return;
1021
1022                         // TrueAim check
1023                         float shottype;
1024
1025                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1026                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1027                         wcross_origin_z = 0;
1028                         if(autocvar_crosshair_hittest)
1029                         {
1030                                 vector wcross_oldorigin;
1031                                 wcross_oldorigin = wcross_origin;
1032                                 shottype = TrueAimCheck();
1033                                 if(shottype == SHOTTYPE_HITWORLD)
1034                                 {
1035                                         v = wcross_origin - wcross_oldorigin;
1036                                         v_x /= vid_conwidth;
1037                                         v_y /= vid_conheight;
1038                                         if(vlen(v) > 0.01)
1039                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1040                                 }
1041                                 if(!autocvar_crosshair_hittest_showimpact)
1042                                         wcross_origin = wcross_oldorigin;
1043                         }
1044                         else
1045                                 shottype = SHOTTYPE_HITWORLD;
1046
1047                         vector wcross_color, wcross_size;
1048                         string wcross_wep, wcross_name;
1049                         float wcross_scale, wcross_blur;
1050
1051                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1052                                 e = get_weaponinfo(switchingweapon);
1053                                 if (e && e.netname != "")
1054                                 {
1055                                         wcross_wep = e.netname;
1056                                         if(autocvar_crosshair_per_weapon)
1057                                         {
1058                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1059                                                 if (wcross_resolution == 0)
1060                                                         return;
1061                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1062                                                 if (wcross_alpha == 0)
1063                                                         return;
1064
1065                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1066                                                 if(wcross_style == "" || wcross_style == "0")
1067                                                         wcross_style = wcross_wep;
1068                                         }
1069                                 }
1070                         }
1071                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1072                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1073                         else if(autocvar_crosshair_color_by_health)
1074                         {
1075                                 float x = getstati(STAT_HEALTH);
1076
1077                                 //x = red
1078                                 //y = green
1079                                 //z = blue
1080
1081                                 wcross_color_z = 0;
1082
1083                                 if(x > 200)
1084                                 {
1085                                         wcross_color_x = 0;
1086                                         wcross_color_y = 1;
1087                                 }
1088                                 else if(x > 150)
1089                                 {
1090                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1091                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1092                                 }
1093                                 else if(x > 100)
1094                                 {
1095                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1096                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1097                                         wcross_color_z = 1 - (x-100)*0.02;
1098                                 }
1099                                 else if(x > 50)
1100                                 {
1101                                         wcross_color_x = 1;
1102                                         wcross_color_y = 1;
1103                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1104                                 }
1105                                 else if(x > 20)
1106                                 {
1107                                         wcross_color_x = 1;
1108                                         wcross_color_y = (x-20)*90/27/100;
1109                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1110                                 }
1111                                 else
1112                                 {
1113                                         wcross_color_x = 1;
1114                                         wcross_color_y = 0;
1115                                 }
1116                         }
1117                         else
1118                                 wcross_color = stov(autocvar_crosshair_color);
1119
1120                         wcross_name = strcat("gfx/crosshair", wcross_style);
1121
1122                         if(autocvar_crosshair_effect_scalefade)
1123                         {
1124                                 wcross_scale = wcross_resolution;
1125                                 wcross_resolution = 1;
1126                         }
1127                         else
1128                         {
1129                                 wcross_scale = 1;
1130                         }
1131
1132                         if(autocvar_crosshair_pickup)
1133                         {
1134                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1135
1136                                 if(pickup_crosshair_time < stat_pickup_time)
1137                                 {
1138                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1139                                                 pickup_crosshair_size = 1;
1140
1141                                         pickup_crosshair_time = stat_pickup_time;
1142                                 }
1143
1144                                 if(pickup_crosshair_size > 0)
1145                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1146                                 else
1147                                         pickup_crosshair_size = 0;
1148
1149                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1150                         }
1151
1152                         if(autocvar_crosshair_hitindication)
1153                         {
1154                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1155                                 if(hitindication_crosshair_time < hit_time)
1156                                 {
1157                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1158                                                 hitindication_crosshair_size = 1;
1159
1160                                         hitindication_crosshair_time = hit_time;
1161                                 }
1162
1163                                 if(hitindication_crosshair_size > 0)
1164                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1165                                 else
1166                                         hitindication_crosshair_size = 0;
1167
1168                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1169                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1170                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1171                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1172                         }
1173
1174                         if(shottype == SHOTTYPE_HITENEMY)
1175                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1176                         if(shottype == SHOTTYPE_HITTEAM)
1177                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1178
1179                         f = autocvar_crosshair_effect_speed;
1180                         if(f < 0)
1181                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1182                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1183                         {
1184                                 wcross_changedonetime = time + f;
1185                         }
1186                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1187                         {
1188                                 wcross_name_changestarttime = time;
1189                                 wcross_name_changedonetime = time + f;
1190                                 if(wcross_name_goal_prev_prev)
1191                                         strunzone(wcross_name_goal_prev_prev);
1192                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1193                                 wcross_name_goal_prev = strzone(wcross_name);
1194                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1195                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1196                                 wcross_resolution_goal_prev = wcross_resolution;
1197                         }
1198
1199                         wcross_scale_goal_prev = wcross_scale;
1200                         wcross_alpha_goal_prev = wcross_alpha;
1201                         wcross_color_goal_prev = wcross_color;
1202
1203                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1204                         {
1205                                 wcross_blur = 1;
1206                                 wcross_alpha *= 0.75;
1207                         }
1208                         else
1209                                 wcross_blur = 0;
1210                         // *_prev is at time-frametime
1211                         // * is at wcross_changedonetime+f
1212                         // what do we have at time?
1213                         if(time < wcross_changedonetime)
1214                         {
1215                                 f = frametime / (wcross_changedonetime - time + frametime);
1216                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1217                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1218                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1219                         }
1220
1221                         wcross_scale_prev = wcross_scale;
1222                         wcross_alpha_prev = wcross_alpha;
1223                         wcross_color_prev = wcross_color;
1224
1225                         wcross_scale *= 1 - autocvar__menu_alpha;
1226                         wcross_alpha *= 1 - autocvar__menu_alpha;
1227                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1228
1229                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1230                         {
1231                                 // crosshair rings for weapon stats
1232                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1233                                 {
1234                                         // declarations and stats
1235                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1236                                         string ring_image, ring_inner_image;
1237                                         vector ring_rgb, ring_inner_rgb;
1238
1239                                         ring_scale = autocvar_crosshair_ring_size;
1240
1241                                         float weapon_clipload, weapon_clipsize;
1242                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1243                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1244
1245                                         float nex_charge, nex_chargepool;
1246                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1247                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1248
1249                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1250                                                 nex_charge_movingavg = nex_charge;
1251
1252
1253                                         // handle the values
1254                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1255                                         {
1256                                                 if (nex_chargepool || use_nex_chargepool) {
1257                                                         use_nex_chargepool = 1;
1258                                                         ring_inner_value = nex_chargepool;
1259                                                 } else {
1260                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1261                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1262                                                 }
1263
1264                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1265                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1266                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1267
1268                                                 // draw the outer ring to show the current charge of the weapon
1269                                                 ring_value = nex_charge;
1270                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1271                                                 ring_rgb = wcross_color;
1272                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1273                                         }
1274                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1275                                         {
1276                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1277                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1278                                                 ring_rgb = wcross_color;
1279                                                 ring_image = "gfx/crosshair_ring.tga";
1280                                         }
1281                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1282                                         {
1283                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1284                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1285                                                 ring_rgb = wcross_color;
1286                                                 ring_image = "gfx/crosshair_ring.tga";
1287                                         }
1288
1289                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1290                                         {
1291                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1292                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1293                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1294                                                 ring_rgb = wcross_color;
1295
1296                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1297                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1298                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1299                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1300                                                 else
1301                                                         ring_image = "gfx/crosshair_ring.tga";
1302                                         }
1303
1304                                         // if in weapon switch animation, fade ring out/in
1305                                         if(g_weaponswitchdelay > 0)
1306                                         {
1307                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1308                                                 if(f > 0 && f < 2)
1309                                                         ring_alpha *= fabs(1 - f);
1310                                         }
1311
1312                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1313                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1314
1315                                         if (ring_value)
1316                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1317                                 }
1318
1319 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1320                                 do \
1321                                 { \
1322                                         if(wcross_blur > 0) \
1323                                         { \
1324                                                 for(i = -2; i <= 2; ++i) \
1325                                                 for(j = -2; j <= 2; ++j) \
1326                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1327                                         } \
1328                                         else \
1329                                         { \
1330                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1331                                         } \
1332                                 } \
1333                                 while(0)
1334
1335 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1336                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1337
1338 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1339                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1340
1341                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1342                                 {
1343                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1344                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1345                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1346                                         f = 1 - f;
1347                                 }
1348                                 else
1349                                 {
1350                                         f = 1;
1351                                 }
1352                                 wcross_name_alpha_goal_prev = f;
1353
1354                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1355                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1356
1357                                 if(autocvar_crosshair_dot)
1358                                 {
1359                                         vector wcross_color_old;
1360                                         wcross_color_old = wcross_color;
1361                                         if(autocvar_crosshair_dot_color != "0")
1362                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1363                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1364                                         // FIXME why don't we use wcross_alpha here?
1365                                         wcross_color = wcross_color_old;
1366                                 }
1367                         }
1368                 }
1369                 else
1370                 {
1371                         wcross_scale_prev = 0;
1372                         wcross_alpha_prev = 0;
1373                         wcross_scale_goal_prev = 0;
1374                         wcross_alpha_goal_prev = 0;
1375                         wcross_changedonetime = 0;
1376                         if(wcross_name_goal_prev)
1377                                 strunzone(wcross_name_goal_prev);
1378                         wcross_name_goal_prev = string_null;
1379                         if(wcross_name_goal_prev_prev)
1380                                 strunzone(wcross_name_goal_prev_prev);
1381                         wcross_name_goal_prev_prev = string_null;
1382                         wcross_name_changestarttime = 0;
1383                         wcross_name_changedonetime = 0;
1384                         wcross_name_alpha_goal_prev = 0;
1385                         wcross_name_alpha_goal_prev_prev = 0;
1386                         wcross_resolution_goal_prev = 0;
1387                         wcross_resolution_goal_prev_prev = 0;
1388                 }
1389         }
1390
1391         if(NextFrameCommand)
1392         {
1393                 localcmd("\n", NextFrameCommand, "\n");
1394                 NextFrameCommand = string_null;
1395         }
1396
1397         // we must do this check AFTER a frame was rendered, or it won't work
1398         if(cs_project_is_b0rked == 0)
1399         {
1400                 string w0, h0;
1401                 w0 = ftos(autocvar_vid_conwidth);
1402                 h0 = ftos(autocvar_vid_conheight);
1403                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1404                 //R_SetView(VF_FOV, '90 90 0');
1405                 R_SetView(VF_ORIGIN, '0 0 0');
1406                 R_SetView(VF_ANGLES, '0 0 0');
1407                 R_SetView(VF_PERSPECTIVE, 1);
1408                 makevectors('0 0 0');
1409                 vector v1, v2;
1410                 cvar_set("vid_conwidth", "800");
1411                 cvar_set("vid_conheight", "600");
1412                 v1 = cs_project(v_forward);
1413                 cvar_set("vid_conwidth", "640");
1414                 cvar_set("vid_conheight", "480");
1415                 v2 = cs_project(v_forward);
1416                 if(v1 == v2)
1417                         cs_project_is_b0rked = 1;
1418                 else
1419                         cs_project_is_b0rked = -1;
1420                 cvar_set("vid_conwidth", w0);
1421                 cvar_set("vid_conheight", h0);
1422         }
1423
1424         if(autocvar__hud_configure)
1425                 HUD_Panel_Mouse();
1426
1427     if(hud && !intermission)
1428     {
1429         if(hud == HUD_SPIDERBOT)
1430             CSQC_SPIDER_HUD();
1431         else if(hud == HUD_WAKIZASHI)
1432             CSQC_WAKIZASHI_HUD();
1433         else if(hud == HUD_RAPTOR)
1434             CSQC_RAPTOR_HUD();
1435         else if(hud == HUD_BUMBLEBEE)
1436             CSQC_BUMBLE_HUD();
1437     }
1438         // let's reset the view back to normal for the end
1439         R_SetView(VF_MIN, '0 0 0');
1440         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1441 }
1442
1443
1444 void CSQC_common_hud(void)
1445 {
1446     // do some accuracy var caching
1447     float i;
1448     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1449     {
1450         if(autocvar_accuracy_color_levels != acc_color_levels)
1451         {
1452             if(acc_color_levels)
1453                 strunzone(acc_color_levels);
1454             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1455             acc_levels = tokenize(acc_color_levels);
1456             if (acc_levels > MAX_ACCURACY_LEVELS)
1457                 acc_levels = MAX_ACCURACY_LEVELS;
1458
1459             for (i = 0; i < acc_levels; ++i)
1460                 acc_lev[i] = stof(argv(i)) / 100.0;
1461         }
1462         // let know that acc_col[] needs to be loaded
1463         acc_col_x[0] = -1;
1464     }
1465
1466     HUD_Main(); // always run these functions for alpha checks
1467     HUD_DrawScoreboard();
1468
1469     if (scoreboard_active) // scoreboard/accuracy
1470         HUD_Reset();
1471     else if (intermission == 2) // map voting screen
1472     {
1473         HUD_FinaleOverlay();
1474         HUD_Reset();
1475     }
1476         /*
1477         switch(hud)
1478         {
1479                 case HUD_SPIDERBOT:
1480                         CSQC_SPIDER_HUD();
1481                         break;
1482
1483                 case HUD_WAKIZASHI:
1484                         CSQC_WAKIZASHI_HUD();
1485                         break;
1486
1487         case HUD_BUMBLEBEE:
1488             CSQC_BUMBLE_HUD();
1489             break;
1490         }
1491         */
1492 }
1493
1494
1495 // following vectors must be global to allow seamless switching between camera modes
1496 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1497 void CSQC_Demo_Camera()
1498 {
1499         float speed, attenuation, dimensions;
1500         vector tmp, delta;
1501
1502         if( autocvar_camera_reset || !camera_mode )
1503         {
1504                 camera_offset = '0 0 0';
1505                 current_angles = '0 0 0';
1506                 camera_direction = '0 0 0';
1507                 camera_offset_z += 30;
1508                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1509                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1510                 current_origin = view_origin;
1511                 current_camera_offset  = camera_offset;
1512                 cvar_set("camera_reset", "0");
1513                 camera_mode = CAMERA_CHASE;
1514         }
1515
1516         // Camera angles
1517         if( camera_roll )
1518                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1519
1520         if(autocvar_camera_look_player)
1521         {
1522                 vector dir;
1523                 float n;
1524
1525                 dir = normalize(view_origin - current_position);
1526                 n = mouse_angles_z;
1527                 mouse_angles = vectoangles(dir);
1528                 mouse_angles_x = mouse_angles_x * -1;
1529                 mouse_angles_z = n;
1530         }
1531         else
1532         {
1533                 tmp = getmousepos() * 0.1;
1534                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1535                 {
1536                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1537                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1538                 }
1539         }
1540
1541         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1542         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1543         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1544         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1545
1546         // Fix difference when angles don't have the same sign
1547         delta = '0 0 0';
1548         if(mouse_angles_y < -60 && current_angles_y > 60)
1549                 delta = '0 360 0';
1550         if(mouse_angles_y > 60 && current_angles_y < -60)
1551                 delta = '0 -360 0';
1552
1553         if(autocvar_camera_look_player)
1554                 attenuation = autocvar_camera_look_attenuation;
1555         else
1556                 attenuation = autocvar_camera_speed_attenuation;
1557
1558         attenuation = 1 / max(1, attenuation);
1559         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1560
1561         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1562         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1563         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1564         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1565
1566         // Camera position
1567         tmp = '0 0 0';
1568         dimensions = 0;
1569
1570         if( camera_direction_x )
1571         {
1572                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1573                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1574                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1575                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1576                 ++dimensions;
1577         }
1578
1579         if( camera_direction_y )
1580         {
1581                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1582                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1583                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1584                 ++dimensions;
1585         }
1586
1587         if( camera_direction_z )
1588         {
1589                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1590                 ++dimensions;
1591         }
1592
1593         if(autocvar_camera_free)
1594                 speed = autocvar_camera_speed_free;
1595         else
1596                 speed = autocvar_camera_speed_chase;
1597
1598         if(dimensions)
1599         {
1600                 speed = speed * sqrt(1 / dimensions);
1601                 camera_offset += tmp * speed;
1602         }
1603
1604         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1605
1606         // Camera modes
1607         if( autocvar_camera_free )
1608         {
1609                 if ( camera_mode == CAMERA_CHASE )
1610                 {
1611                         current_camera_offset = current_origin + current_camera_offset;
1612                         camera_offset = current_origin + camera_offset;
1613                 }
1614
1615                 camera_mode = CAMERA_FREE;
1616                 current_position = current_camera_offset;
1617         }
1618         else
1619         {
1620                 if ( camera_mode == CAMERA_FREE )
1621                 {
1622                         current_origin = view_origin;
1623                         camera_offset = camera_offset - current_origin;
1624                         current_camera_offset = current_camera_offset - current_origin;
1625                 }
1626
1627                 camera_mode = CAMERA_CHASE;
1628
1629                 if(autocvar_camera_chase_smoothly)
1630                         current_origin += (view_origin - current_origin) * attenuation;
1631                 else
1632                         current_origin = view_origin;
1633
1634                 current_position = current_origin + current_camera_offset;
1635         }
1636
1637         R_SetView(VF_ANGLES, current_angles);
1638         R_SetView(VF_ORIGIN, current_position);
1639 }